ext/IO/t/io_udp.t

   1 #!./perl
   2
   3 BEGIN {
   4     unless(grep /blib/, @INC) {
   5         chdir 't' if -d 't';
   6         @INC = '../lib';
   7     }
   8 }
   9
  10 use Config;
  11
  12 BEGIN {
  13     my $reason;
  14
  15     if ($ENV{PERL_CORE} and $Config{'extensions'} !~ /\bSocket\b/) {
  16       $reason = 'Socket was not built';
  17     }
  18     elsif ($ENV{PERL_CORE} and $Config{'extensions'} !~ /\bIO\b/) {
  19       $reason = 'IO was not built';
  20     }
  21     elsif ($^O eq 'apollo') {
  22       $reason = "unknown *FIXME*";
  23     }
  24     undef $reason if $^O eq 'VMS' and $Config{d_socket};
  25     if ($reason) {
  26         print "1..0 # Skip: $reason\n";
  27         exit 0;
  28     }
  29 }
  30
  31 sub compare_addr {
  32     no utf8;
  33     my $a = shift;
  34     my $b = shift;
  35     if (length($a) != length $b) {
  36         my $min = (length($a) < length $b) ? length($a) : length $b;
  37         if ($min and substr($a, 0, $min) eq substr($b, 0, $min)) {
  38             printf "# Apparently: %d bytes junk at the end of %s\n# %s\n",
  39                 abs(length($a) - length ($b)),
  40                 $_[length($a) < length ($b) ? 1 : 0],
  41                 "consider decreasing bufsize of recfrom.";
  42             substr($a, $min) = "";
  43             substr($b, $min) = "";
  44         }
  45         return 0;
  46     }
  47     my @a = unpack_sockaddr_in($a);
  48     my @b = unpack_sockaddr_in($b);
  49     "$a[0]$a[1]" eq "$b[0]$b[1]";
  50 }
  51
  52 $| = 1;
  53 print "1..7\n";
  54
  55 use Socket;
  56 use IO::Socket qw(AF_INET SOCK_DGRAM INADDR_ANY);
  57
  58 $udpa = IO::Socket::INET->new(Proto => 'udp', LocalAddr => 'localhost')
  59      || IO::Socket::INET->new(Proto => 'udp', LocalAddr => '127.0.0.1')
  60     or die "$! (maybe your system does not have a localhost at all, 'localhost' or 127.0.0.1)";
  61
  62 print "ok 1\n";
  63
  64 $udpb = IO::Socket::INET->new(Proto => 'udp', LocalAddr => 'localhost')
  65      || IO::Socket::INET->new(Proto => 'udp', LocalAddr => '127.0.0.1')
  66     or die "$! (maybe your system does not have a localhost at all, 'localhost' or 127.0.0.1)";
  67
  68 print "ok 2\n";
  69
  70 $udpa->send("ok 4\n",0,$udpb->sockname);
  71
  72 print "not "
  73   unless compare_addr($udpa->peername,$udpb->sockname, 'peername', 'sockname');
  74 print "ok 3\n";
  75
  76 my $where = $udpb->recv($buf="",5);
  77 print $buf;
  78
  79 my @xtra = ();
  80
  81 unless(compare_addr($where,$udpa->sockname, 'recv name', 'sockname')) {
  82     print "not ";
  83     @xtra = (0,$udpa->sockname);
  84 }
  85 print "ok 5\n";
  86
  87 $udpb->send("ok 6\n",@xtra);
  88 $udpa->recv($buf="",5);
  89 print $buf;
  90
  91 print "not " if $udpa->connected;
  92 print "ok 7\n";