ext/IO/lib/IO/File.pm

   1 #
   2
   3 package IO::File;
   4
   5 =head1 NAME
   6
   7 IO::File - supply object methods for filehandles
   8
   9 =head1 SYNOPSIS
  10
  11     use IO::File;
  12
  13     $fh = new IO::File;
  14     if ($fh->open "< file") {
  15         print <$fh>;
  16         $fh->close;
  17     }
  18
  19     $fh = new IO::File "> FOO";
  20     if (defined $fh) {
  21         print $fh "bar\n";
  22         $fh->close;
  23     }
  24
  25     $fh = new IO::File "file", "r";
  26     if (defined $fh) {
  27         print <$fh>;
  28         undef $fh;       # automatically closes the file
  29     }
  30
  31     $fh = new IO::File "file", O_WRONLY|O_APPEND;
  32     if (defined $fh) {
  33         print $fh "corge\n";
  34         undef $fh;       # automatically closes the file
  35     }
  36
  37     $pos = $fh->getpos;
  38     $fh->setpos $pos;
  39
  40     $fh->setvbuf($buffer_var, _IOLBF, 1024);
  41
  42     autoflush STDOUT 1;
  43
  44 =head1 DESCRIPTION
  45
  46 C<IO::File> inherits from C<IO::Handle> and C<IO::Seekable>. It extends
  47 these classes with methods that are specific to file handles.
  48
  49 =head1 CONSTRUCTOR
  50
  51 =over 4
  52
  53 =item new ([ ARGS ] )
  54
  55 Creates a C<IO::File>.  If it receives any parameters, they are passed to
  56 the method C<open>; if the open fails, the object is destroyed.  Otherwise,
  57 it is returned to the caller.
  58
  59 =back
  60
  61 =head1 METHODS
  62
  63 =over 4
  64
  65 =item open( FILENAME [,MODE [,PERMS]] )
  66
  67 C<open> accepts one, two or three parameters.  With one parameter,
  68 it is just a front end for the built-in C<open> function.  With two
  69 parameters, the first parameter is a filename that may include
  70 whitespace or other special characters, and the second parameter is
  71 the open mode, optionally followed by a file permission value.
  72
  73 If C<IO::File::open> receives a Perl mode string ("E<gt>", "+E<lt>", etc.)
  74 or a POSIX fopen() mode string ("w", "r+", etc.), it uses the basic
  75 Perl C<open> operator.
  76
  77 If C<IO::File::open> is given a numeric mode, it passes that mode
  78 and the optional permissions value to the Perl C<sysopen> operator.
  79 For convenience, C<IO::File::import> tries to import the O_XXX
  80 constants from the Fcntl module.  If dynamic loading is not available,
  81 this may fail, but the rest of IO::File will still work.
  82
  83 =back
  84
  85 =head1 SEE ALSO
  86
  87 L<perlfunc>,
  88 L<perlop/"I/O Operators">,
  89 L<IO::Handle>
  90 L<IO::Seekable>
  91
  92 =head1 HISTORY
  93
  94 Derived from FileHandle.pm by Graham Barr E<lt>F<bodg@tiuk.ti.com>E<gt>.
  95
  96 =cut
  97
  98 require 5.000;
  99 use strict;
 100 use vars qw($VERSION @EXPORT @EXPORT_OK $AUTOLOAD @ISA);
 101 use Carp;
 102 use Symbol;
 103 use SelectSaver;
 104 use IO::Handle qw(_open_mode_string);
 105 use IO::Seekable;
 106
 107 require Exporter;
 108 require DynaLoader;
 109
 110 @ISA = qw(IO::Handle IO::Seekable Exporter DynaLoader);
 111
 112 $VERSION = "1.06";
 113
 114 @EXPORT = @IO::Seekable::EXPORT;
 115
 116 sub import {
 117     my $pkg = shift;
 118     my $callpkg = caller;
 119     Exporter::export $pkg, $callpkg, @_;
 120
 121     #
 122     # If the Fcntl extension is available,
 123     #  export its constants for sysopen().
 124     #
 125     eval {
 126         require Fcntl;
 127         Exporter::export 'Fcntl', $callpkg, '/^O_/';
 128     };
 129 }
 130
 131
 132 ################################################
 133 ## Constructor
 134 ##
 135
 136 sub new {
 137     my $type = shift;
 138     my $class = ref($type) || $type || "IO::File";
 139     @_ >= 0 && @_ <= 3
 140         or croak "usage: new $class [FILENAME [,MODE [,PERMS]]]";
 141     my $fh = $class->SUPER::new();
 142     if (@_) {
 143         $fh->open(@_)
 144             or return undef;
 145     }
 146     $fh;
 147 }
 148
 149 ################################################
 150 ## Open
 151 ##
 152
 153 sub open {
 154     @_ >= 2 && @_ <= 4 or croak 'usage: $fh->open(FILENAME [,MODE [,PERMS]])';
 155     my ($fh, $file) = @_;
 156     if (@_ > 2) {
 157         my ($mode, $perms) = @_[2, 3];
 158         if ($mode =~ /^\d+$/) {
 159             defined $perms or $perms = 0666;
 160             return sysopen($fh, $file, $mode, $perms);
 161         }
 162         $file = "./" . $file unless $file =~ m#^/#;
 163         $file = _open_mode_string($mode) . " $file\0";
 164     }
 165     open($fh, $file);
 166 }
 167
 168 1;