ext/IO/lib/IO/File.pm

   1 #
   2
   3 package IO::File;
   4
   5 =head1 NAME
   6
   7 IO::File - supply object methods for filehandles
   8
   9 =head1 SYNOPSIS
  10
  11     use IO::File;
  12
  13     $fh = new IO::File;
  14     if ($fh->open("< file")) {
  15         print <$fh>;
  16         $fh->close;
  17     }
  18
  19     $fh = new IO::File "> file";
  20     if (defined $fh) {
  21         print $fh "bar\n";
  22         $fh->close;
  23     }
  24
  25     $fh = new IO::File "file", "r";
  26     if (defined $fh) {
  27         print <$fh>;
  28         undef $fh;       # automatically closes the file
  29     }
  30
  31     $fh = new IO::File "file", O_WRONLY|O_APPEND;
  32     if (defined $fh) {
  33         print $fh "corge\n";
  34
  35         $pos = $fh->getpos;
  36         $fh->setpos($pos);
  37
  38         undef $fh;       # automatically closes the file
  39     }
  40
  41     autoflush STDOUT 1;
  42
  43 =head1 DESCRIPTION
  44
  45 C<IO::File> inherits from C<IO::Handle> and C<IO::Seekable>. It extends
  46 these classes with methods that are specific to file handles.
  47
  48 =head1 CONSTRUCTOR
  49
  50 =over 4
  51
  52 =item new ([ ARGS ] )
  53
  54 Creates a C<IO::File>.  If it receives any parameters, they are passed to
  55 the method C<open>; if the open fails, the object is destroyed.  Otherwise,
  56 it is returned to the caller.
  57
  58 =back
  59
  60 =head1 METHODS
  61
  62 =over 4
  63
  64 =item open( FILENAME [,MODE [,PERMS]] )
  65
  66 C<open> accepts one, two or three parameters.  With one parameter,
  67 it is just a front end for the built-in C<open> function.  With two
  68 parameters, the first parameter is a filename that may include
  69 whitespace or other special characters, and the second parameter is
  70 the open mode, optionally followed by a file permission value.
  71
  72 If C<IO::File::open> receives a Perl mode string ("E<gt>", "+E<lt>", etc.)
  73 or a POSIX fopen() mode string ("w", "r+", etc.), it uses the basic
  74 Perl C<open> operator.
  75
  76 If C<IO::File::open> is given a numeric mode, it passes that mode
  77 and the optional permissions value to the Perl C<sysopen> operator.
  78 For convenience, C<IO::File::import> tries to import the O_XXX
  79 constants from the Fcntl module.  If dynamic loading is not available,
  80 this may fail, but the rest of IO::File will still work.
  81
  82 =back
  83
  84 =head1 SEE ALSO
  85
  86 L<perlfunc>,
  87 L<perlop/"I/O Operators">,
  88 L<IO::Handle>
  89 L<IO::Seekable>
  90
  91 =head1 HISTORY
  92
  93 Derived from FileHandle.pm by Graham Barr E<lt>F<bodg@tiuk.ti.com>E<gt>.
  94
  95 =cut
  96
  97 require 5.000;
  98 use strict;
  99 use vars qw($VERSION @EXPORT @EXPORT_OK $AUTOLOAD @ISA);
 100 use Carp;
 101 use Symbol;
 102 use SelectSaver;
 103 use IO::Handle qw(_open_mode_string);
 104 use IO::Seekable;
 105
 106 require Exporter;
 107 require DynaLoader;
 108
 109 @ISA = qw(IO::Handle IO::Seekable Exporter DynaLoader);
 110
 111 $VERSION = "1.06";
 112
 113 @EXPORT = @IO::Seekable::EXPORT;
 114
 115 sub import {
 116     my $pkg = shift;
 117     my $callpkg = caller;
 118     Exporter::export $pkg, $callpkg, @_;
 119
 120     #
 121     # If the Fcntl extension is available,
 122     #  export its constants for sysopen().
 123     #
 124     eval {
 125         require Fcntl;
 126         Exporter::export 'Fcntl', $callpkg, '/^O_/';
 127     };
 128 }
 129
 130
 131 ################################################
 132 ## Constructor
 133 ##
 134
 135 sub new {
 136     my $type = shift;
 137     my $class = ref($type) || $type || "IO::File";
 138     @_ >= 0 && @_ <= 3
 139         or croak "usage: new $class [FILENAME [,MODE [,PERMS]]]";
 140     my $fh = $class->SUPER::new();
 141     if (@_) {
 142         $fh->open(@_)
 143             or return undef;
 144     }
 145     $fh;
 146 }
 147
 148 ################################################
 149 ## Open
 150 ##
 151
 152 sub open {
 153     @_ >= 2 && @_ <= 4 or croak 'usage: $fh->open(FILENAME [,MODE [,PERMS]])';
 154     my ($fh, $file) = @_;
 155     if (@_ > 2) {
 156         my ($mode, $perms) = @_[2, 3];
 157         if ($mode =~ /^\d+$/) {
 158             defined $perms or $perms = 0666;
 159             return sysopen($fh, $file, $mode, $perms);
 160         }
 161         $file = "./" . $file unless $file =~ m#^/#;
 162         $file = _open_mode_string($mode) . " $file\0";
 163     }
 164     open($fh, $file);
 165 }
 166
 167 1;