ext/Encode/t/Aliases.t

   1 #!../perl
   2
   3 BEGIN {
   4     if ($ENV{'PERL_CORE'}){
   5         chdir 't';
   6         unshift @INC, '../lib';
   7     }
   8     require Config; import Config;
   9     if ($Config{'extensions'} !~ /\bEncode\b/) {
  10         print "1..0 # Skip: Encode was not built\n";
  11             exit 0;
  12     }
  13 }
  14
  15 use strict;
  16 use Encode;
  17 use Encode::Alias;
  18 my %a2c;
  19 my $ON_EBCDIC;
  20
  21 BEGIN{
  22     $ON_EBCDIC = ord("A") == 193;
  23     @ARGV and $ON_EBCDIC = $ARGV[0] eq 'EBCDIC';
  24     $Encode::ON_EBCDIC = $ON_EBCDIC;
  25
  26     %a2c = (
  27             'ascii'    => 'US-ascii',
  28             'cyrillic' => 'iso-8859-5',
  29             'arabic'   => 'iso-8859-6',
  30             'greek'    => 'iso-8859-7',
  31             'hebrew'   => 'iso-8859-8',
  32             'thai'     => 'iso-8859-11',
  33             'tis620'   => 'iso-8859-11',
  34             'WinLatin1'     => 'cp1252',
  35             'WinLatin2'     => 'cp1250',
  36             'WinCyrillic'   => 'cp1251',
  37             'WinGreek'      => 'cp1253',
  38             'WinTurkish'    => 'cp1254',
  39             'WinHebrew'     => 'cp1255',
  40             'WinArabic'     => 'cp1256',
  41             'WinBaltic'     => 'cp1257',
  42             'WinVietnamese' => 'cp1258',
  43             'ja_JP.euc'     => $ON_EBCDIC ? '' : 'euc-jp',
  44             'x-euc-jp'      => $ON_EBCDIC ? '' : 'euc-jp',
  45             'zh_CN.euc'     => $ON_EBCDIC ? '' : 'euc-cn',
  46             'x-euc-cn'      => $ON_EBCDIC ? '' : 'euc-cn',
  47             'ko_KR.euc'     => $ON_EBCDIC ? '' : 'euc-kr',
  48             'x-euc-kr'      => $ON_EBCDIC ? '' : 'euc-kr',
  49             'ujis'          => $ON_EBCDIC ? '' : 'euc-jp',
  50             'Shift_JIS'     => $ON_EBCDIC ? '' : 'shiftjis',
  51             'x-sjis'        => $ON_EBCDIC ? '' : 'shiftjis',
  52             'jis'           => $ON_EBCDIC ? '' : '7bit-jis',
  53             'big-5'         => $ON_EBCDIC ? '' : 'big5',
  54             'zh_TW.Big5'    => $ON_EBCDIC ? '' : 'big5',
  55             'big5-hk'       => $ON_EBCDIC ? '' : 'big5-hkscs',
  56             'GB_2312-80'    => $ON_EBCDIC ? '' : 'euc-cn',
  57             'gb2312-raw'    => $ON_EBCDIC ? '' : 'gb2312-raw',
  58             'gb12345-raw'   => $ON_EBCDIC ? '' : 'gb12345-raw',
  59             'KS_C_5601-1987'    => $ON_EBCDIC ? '' : 'cp949',
  60             'ksc5601-raw'       => $ON_EBCDIC ? '' : 'ksc5601-raw',
  61             );
  62
  63     for my $i (1..11,13..16){
  64         $a2c{"ISO 8859 $i"} = "iso-8859-$i";
  65     }
  66     for my $i (1..10){
  67         $a2c{"ISO Latin $i"} = "iso-8859-$Encode::Alias::Latin2iso[$i]";
  68     }
  69     for my $k (keys %Encode::Alias::Winlatin2cp){
  70         my $v = $Encode::Alias::Winlatin2cp{$k};
  71         $a2c{"Win" . ucfirst($k)} = "cp" . $v;
  72         $a2c{"IBM-$v"} = $a2c{"MS-$v"} = "cp" . $v;
  73     }
  74 }
  75
  76 if ($ON_EBCDIC){
  77     delete @Encode::ExtModule{
  78         qw(euc-cn gb2312 gb12345 gbk cp936 iso-ir-165
  79            euc-jp iso-2022-jp 7bit-jis shiftjis MacJapanese cp932
  80            euc-kr ksc5601 cp949
  81            big5 big5-hkscs cp950
  82            gb18030 big5plus euc-tw)
  83         };
  84 }
  85
  86 use Test::More tests => (scalar keys %a2c) * 3;
  87
  88 print "# alias test;  \$ON_EBCDIC == $ON_EBCDIC\n";
  89
  90 foreach my $a (keys %a2c){
  91     my $e = Encode::find_encoding($a);
  92     is((defined($e) and $e->name), $a2c{$a});
  93 }
  94
  95 # now we override some of the aliases and see if it works fine
  96
  97 define_alias(ascii    => 'WinLatin1',
  98              cyrillic => 'WinCyrillic',
  99              arabic   => 'WinArabic',
 100              greek    => 'WinGreek',
 101              hebrew   => 'WinHebrew');
 102
 103 @a2c{qw(ascii cyrillic arabic greek hebrew)} =
 104     qw(cp1252 cp1251 cp1256 cp1253 cp1255);
 105
 106 unless ($ON_EBCDIC){
 107     define_alias( qr/shift.*jis$/i  => '"MacJapanese"',
 108                   qr/sjis$/i        => '"cp932"' );
 109     @a2c{qw(Shift_JIS x-sjis)} = qw(MacJapanese cp932);
 110 }
 111
 112 print "# alias test with alias overrides\n";
 113
 114 foreach my $a (keys %a2c){
 115     my $e = Encode::find_encoding($a);
 116     is((defined($e) and $e->name), $a2c{$a})
 117         or warn "alias was $a";
 118 }
 119
 120 print "# alias undef test\n";
 121
 122 Encode::Alias->undef_aliases;
 123 foreach my $a (keys %a2c){
 124     my $e = Encode::find_encoding($a);
 125     ok(!defined($e) || $e->name =~ /-raw$/o);
 126 }
 127
 128 __END__
 129 for (my $i = 0; $i < @Encode::Alias::Alias; $i+=2){
 130     my ($k, $v) = @Encode::Alias::Alias[$i, $i+1];
 131     print "$k => $v\n";
 132 }
 133
 134