ext/Encode/t/Aliases.t

   1 #!../perl
   2
   3 BEGIN {
   4     if ($ENV{'PERL_CORE'}){
   5     chdir 't';
   6     unshift @INC, '../lib';
   7     }
   8     require Config; import Config;
   9     if ($Config{'extensions'} !~ /\bEncode\b/) {
  10     print "1..0 # Skip: Encode was not built\n";
  11         exit 0;
  12     }
  13 }
  14
  15 use strict;
  16 use Encode;
  17 use Encode::Alias;
  18 my %a2c;
  19 my $ON_EBCDIC;
  20
  21 sub init_a2c{
  22     %a2c = (
  23         'US-ascii' => 'ascii',
  24         'ISO-646-US' => 'ascii',
  25         'UTF-8'    => 'utf-8-strict',
  26         'UCS-2'    => 'UCS-2BE',
  27         'UCS2'     => 'UCS-2BE',
  28         'iso-10646-1' => 'UCS-2BE',
  29         'ucs2-le'  => 'UCS-2LE',
  30         'ucs2-be'  => 'UCS-2BE',
  31         'utf16'    => 'UTF-16',
  32         'utf32'    => 'UTF-32',
  33         'utf16-be'  => 'UTF-16BE',
  34         'utf32-be'  => 'UTF-32BE',
  35         'utf16-le'  => 'UTF-16LE',
  36         'utf32-le'  => 'UTF-32LE',
  37         'UCS4-BE'   => 'UTF-32BE',
  38         'UCS-4-LE'  => 'UTF-32LE',
  39         'cyrillic' => 'iso-8859-5',
  40         'arabic'   => 'iso-8859-6',
  41         'greek'    => 'iso-8859-7',
  42         'hebrew'   => 'iso-8859-8',
  43         'thai'     => 'iso-8859-11',
  44         'tis620'   => 'iso-8859-11',
  45         'tis-620'   => 'iso-8859-11',
  46         'WinLatin1'     => 'cp1252',
  47         'WinLatin2'     => 'cp1250',
  48         'WinCyrillic'   => 'cp1251',
  49         'WinGreek'      => 'cp1253',
  50         'WinTurkish'    => 'cp1254',
  51         'WinHebrew'     => 'cp1255',
  52         'WinArabic'     => 'cp1256',
  53         'WinBaltic'     => 'cp1257',
  54         'WinVietnamese' => 'cp1258',
  55         'Macintosh'     => 'MacRoman',
  56         'koi8r'         => 'koi8-r',
  57         'koi8u'         => 'koi8-u',
  58         'ja_JP.euc'         => $ON_EBCDIC ? '' : 'euc-jp',
  59         'x-euc-jp'          => $ON_EBCDIC ? '' : 'euc-jp',
  60         'zh_CN.euc'         => $ON_EBCDIC ? '' : 'euc-cn',
  61         'x-euc-cn'          => $ON_EBCDIC ? '' : 'euc-cn',
  62         'ko_KR.euc'         => $ON_EBCDIC ? '' : 'euc-kr',
  63         'x-euc-kr'          => $ON_EBCDIC ? '' : 'euc-kr',
  64         'ujis'      => $ON_EBCDIC ? '' : 'euc-jp',
  65         'Shift_JIS'         => $ON_EBCDIC ? '' : 'shiftjis',
  66         'x-sjis'            => $ON_EBCDIC ? '' : 'shiftjis',
  67         'jis'       => $ON_EBCDIC ? '' : '7bit-jis',
  68         'big-5'     => $ON_EBCDIC ? '' : 'big5-eten',
  69         'zh_TW.Big5'    => $ON_EBCDIC ? '' : 'big5-eten',
  70         'tca-big5'          => $ON_EBCDIC ? '' : 'big5-eten',
  71         'big5-hk'           => $ON_EBCDIC ? '' : 'big5-hkscs',
  72         'hkscs-big5'    => $ON_EBCDIC ? '' : 'big5-hkscs',
  73         'GB_2312-80'    => $ON_EBCDIC ? '' : 'euc-cn',
  74         'KS_C_5601-1987'    => $ON_EBCDIC ? '' : 'cp949',
  75         #
  76         'gb12345-raw'   => $ON_EBCDIC ? '' : 'gb12345-raw',
  77         'gb2312-raw'    => $ON_EBCDIC ? '' : 'gb2312-raw',
  78         'jis0201-raw'   => $ON_EBCDIC ? '' : 'jis0201-raw',
  79         'jis0208-raw'   => $ON_EBCDIC ? '' : 'jis0208-raw',
  80         'jis0212-raw'   => $ON_EBCDIC ? '' : 'jis0212-raw',
  81         'ksc5601-raw'   => $ON_EBCDIC ? '' : 'ksc5601-raw',
  82        );
  83
  84     for my $i (1..11,13..16){
  85     $a2c{"ISO 8859 $i"} = "iso-8859-$i";
  86     }
  87     for my $i (1..10){
  88     $a2c{"ISO Latin $i"} = "iso-8859-$Encode::Alias::Latin2iso[$i]";
  89     }
  90     for my $k (keys %Encode::Alias::Winlatin2cp){
  91     my $v = $Encode::Alias::Winlatin2cp{$k};
  92     $a2c{"Win" . ucfirst($k)} = "cp" . $v;
  93     $a2c{"IBM-$v"} = $a2c{"MS-$v"} = "cp" . $v;
  94     $a2c{"cp-" . $v} = "cp" . $v;
  95     }
  96     my @a2c = keys %a2c;
  97     for my $k (@a2c){
  98     $a2c{uc($k)} = $a2c{$k};
  99     $a2c{lc($k)} = $a2c{$k};
 100     $a2c{lcfirst($k)} = $a2c{$k};
 101     $a2c{ucfirst($k)} = $a2c{$k};
 102     }
 103 }
 104
 105 BEGIN{
 106     $ON_EBCDIC = ord("A") == 193;
 107     @ARGV and $ON_EBCDIC = $ARGV[0] eq 'EBCDIC';
 108     $Encode::ON_EBCDIC = $ON_EBCDIC;
 109     init_a2c();
 110 }
 111
 112 if ($ON_EBCDIC){
 113     delete @Encode::ExtModule{
 114     qw(euc-cn gb2312 gb12345 gbk cp936 iso-ir-165 MacChineseSimp
 115        euc-jp iso-2022-jp 7bit-jis shiftjis MacJapanese cp932
 116        euc-kr ksc5601 cp949 MacKorean
 117        big5     big5-hkscs cp950 MacChineseTrad
 118        gb18030 big5plus euc-tw)
 119     };
 120 }
 121
 122 use Test::More tests => (scalar keys %a2c) * 4;
 123
 124 print "# alias test;  \$ON_EBCDIC == $ON_EBCDIC\n";
 125
 126 foreach my $a (keys %a2c){
 127     print "# $a => $a2c{$a}\n";
 128     my $e = Encode::find_encoding($a);
 129     is((defined($e) and $e->name), $a2c{$a},$a)
 130     or warn "alias was $a";;
 131 }
 132
 133 # now we override some of the aliases and see if it works fine
 134
 135 define_alias(
 136          qr/ascii/i    => 'WinLatin1',
 137          qr/cyrillic/i => 'WinCyrillic',
 138          qr/arabic/i   => 'WinArabic',
 139          qr/greek/i    => 'WinGreek',
 140          qr/hebrew/i   => 'WinHebrew'
 141         );
 142
 143 print "# alias test with alias overrides\n";
 144
 145 foreach my $a (keys %a2c){
 146     print "# $a => $a2c{$a}\n";
 147     my $e = Encode::find_encoding($a);
 148     is((defined($e) and $e->name), $a2c{$a}, "Override $a")
 149     or warn "alias was $a";
 150 }
 151
 152 print "# alias undef test\n";
 153
 154 Encode::Alias->undef_aliases;
 155 foreach my $a (keys %a2c){
 156     my $e = Encode::find_encoding($a);
 157     ok(!defined($e) || $e->name =~ /-raw$/o,"Undef $a")
 158     or warn "alias was $a";
 159 }
 160
 161 print "# alias reinit test\n";
 162
 163 Encode::Alias->init_aliases;
 164 init_a2c();
 165 foreach my $a (keys %a2c){
 166     my $e = Encode::find_encoding($a);
 167     is((defined($e) and $e->name), $a2c{$a}, "Reinit $a")
 168     or warn "alias was $a";
 169 }
 170 __END__
 171 for my $k (keys %a2c){
 172     $k =~ /[A-Z]/ and next;
 173     print "$k => $a2c{$k}\n";
 174 }
 175
 176
 177