ext/Encode/lib/Encode/JP/JIS7.pm

   1 package Encode::JP::JIS7;
   2 use strict;
   3
   4 our $VERSION = do { my @r = (q$Revision: 1.1 $ =~ /\d+/g); sprintf "%d."."%02d" x $#r, @r };
   5
   6 require Encode;
   7 for my $name ('7bit-jis', 'iso-2022-jp', 'iso-2022-jp-1'){
   8     my $h2z     = ($name eq '7bit-jis')    ? 0 : 1;
   9     my $jis0212 = ($name eq 'iso-2022-jp') ? 0 : 1;
  10
  11     $Encode::Encoding{$name} =
  12         bless {
  13                Name      =>   $name,
  14                h2z       =>   $h2z,
  15                jis0212   =>   $jis0212,
  16               } => __PACKAGE__;
  17 }
  18
  19 sub name { shift->{'Name'} }
  20 sub new_sequence { $_[0] };
  21
  22 use Encode::CJKConstants qw(:all);
  23
  24 #
  25 # decode is identical for all 2022 variants
  26 #
  27
  28 sub decode
  29 {
  30     my ($obj,$str,$chk) = @_;
  31     jis_euc(\$str);
  32     return Encode::decode('euc-jp', $str, $chk);
  33 }
  34
  35 #
  36 # encode is different
  37 #
  38
  39 sub encode
  40 {
  41     require Encode::JP::H2Z;
  42     my ($obj,$str,$chk) = @_;
  43     my ($h2z, $jis0212) = @$obj{qw(h2z jis0212)};
  44     my $result = Encode::encode('euc-jp', $str, $chk);
  45     $h2z and &Encode::JP::H2Z::h2z(\$result);
  46     euc_jis(\$result, $jis0212);
  47     return $result;
  48 }
  49
  50
  51 # JIS<->EUC
  52
  53 sub jis_euc {
  54     my $r_str = shift;
  55     $$r_str =~ s(
  56                  ($RE{JIS_0212}|$RE{JIS_0208}|$RE{ISO_ASC}|$RE{JIS_KANA})
  57                  ([^\e]*)
  58                  )
  59     {
  60         my ($esc, $str) = ($1, $2);
  61         if ($esc !~ /$RE{ISO_ASC}/o) {
  62             $str =~ tr/\x21-\x7e/\xa1-\xfe/;
  63             if ($esc =~ /$RE{JIS_KANA}/o) {
  64                 $str =~ s/([\xa1-\xdf])/\x8e$1/og;
  65             }
  66             elsif ($esc =~ /$RE{JIS_0212}/o) {
  67                 $str =~ s/([\xa1-\xfe][\xa1-\xfe])/\x8f$1/og;
  68             }
  69         }
  70         $str;
  71     }geox;
  72     $$r_str;
  73 }
  74
  75 sub euc_jis{
  76     my $r_str = shift;
  77     my $jis0212 = shift;
  78     $$r_str =~ s{
  79         ((?:$RE{EUC_C})+|(?:$RE{EUC_KANA})+|(?:$RE{EUC_0212})+)
  80         }{
  81             my $str = $1;
  82             my $esc =
  83                 ( $str =~ tr/\x8E//d ) ? $ESC{KANA} :
  84                     ( $str =~ tr/\x8F//d ) ? $ESC{JIS_0212} :
  85                         $ESC{JIS_0208};
  86             if ($esc eq $ESC{JIS_0212} && !$jis0212){
  87                 # fallback to '?'
  88                 $str =~ tr/\xA1-\xFE/\x3F/;
  89             }else{
  90                 $str =~ tr/\xA1-\xFE/\x21-\x7E/;
  91             }
  92             $esc . $str . $ESC{ASC};
  93         }geox;
  94     $$r_str =~
  95         s/\Q$ESC{ASC}\E
  96             (\Q$ESC{KANA}\E|\Q$ESC{JIS_0212}\E|\Q$ESC{JIS_0208}\E)/$1/gox;
  97     $$r_str;
  98 }
  99
 100 1;
 101 __END__
 102
 103
 104 =head1 NAME
 105
 106 Encode::JP::JIS7 -- internally used by Encode::JP
 107
 108 =cut