ext/Encode/lib/Encode/JP/JIS7.pm

   1 package Encode::JP::JIS7;
   2 use strict;
   3
   4 our $VERSION = do { my @r = (q$Revision: 1.3 $ =~ /\d+/g); sprintf "%d."."%02d" x $#r, @r };
   5
   6 use Encode qw(:fallbacks);
   7
   8 for my $name ('7bit-jis', 'iso-2022-jp', 'iso-2022-jp-1'){
   9     my $h2z     = ($name eq '7bit-jis')    ? 0 : 1;
  10     my $jis0212 = ($name eq 'iso-2022-jp') ? 0 : 1;
  11
  12     $Encode::Encoding{$name} =
  13         bless {
  14                Name      =>   $name,
  15                h2z       =>   $h2z,
  16                jis0212   =>   $jis0212,
  17               } => __PACKAGE__;
  18 }
  19
  20 sub name { shift->{'Name'} }
  21
  22 sub new_sequence { $_[0] }
  23
  24 sub needs_lines { 1 }
  25
  26 use Encode::CJKConstants qw(:all);
  27
  28 our $DEBUG = 0;
  29
  30 #
  31 # decode is identical for all 2022 variants
  32 #
  33
  34 sub decode($$;$)
  35 {
  36     my ($obj,$str,$chk) = @_;
  37     my $residue = jis_euc(\$str);
  38     # This is for PerlIO
  39     $_[1] = $residue if $chk;
  40     # use perlqq fallback for euc-jp -> utf8
  41     return Encode::decode('euc-jp', $str, FB_PERLQQ);
  42 }
  43
  44 #
  45 # encode is different
  46 #
  47
  48 sub encode($$;$)
  49 {
  50     require Encode::JP::H2Z;
  51     my ($obj, $utf8, $chk) = @_;
  52     # empty the input string in the stack so perlio is ok
  53     $_[1] = '' if $chk;
  54     my ($h2z, $jis0212) = @$obj{qw(h2z jis0212)};
  55     my $octet = Encode::encode('euc-jp', $utf8, FB_PERLQQ) ;
  56     $h2z and &Encode::JP::H2Z::h2z(\$octet);
  57     euc_jis(\$octet, $jis0212);
  58     return $octet;
  59 }
  60
  61
  62 # JIS<->EUC
  63
  64 sub jis_euc {
  65     my $r_str = shift;
  66     $$r_str =~ s(
  67                  ($RE{JIS_0212}|$RE{JIS_0208}|$RE{ISO_ASC}|$RE{JIS_KANA})
  68                  ([^\e]*)
  69                  )
  70     {
  71         my ($esc, $chunk) = ($1, $2);
  72         if ($esc !~ /$RE{ISO_ASC}/o) {
  73             $chunk =~ tr/\x21-\x7e/\xa1-\xfe/;
  74             if ($esc =~ /$RE{JIS_KANA}/o) {
  75                 $chunk =~ s/([\xa1-\xdf])/\x8e$1/og;
  76             }
  77             elsif ($esc =~ /$RE{JIS_0212}/o) {
  78                 $chunk =~ s/([\xa1-\xfe][\xa1-\xfe])/\x8f$1/og;
  79             }
  80         }
  81         $chunk;
  82     }geox;
  83     my ($residue) = ($$r_str =~ s/(\e.*)$//so);
  84     return $residue;
  85 }
  86
  87 sub euc_jis{
  88     my $r_str = shift;
  89     my $jis0212 = shift;
  90     $$r_str =~ s{
  91         ((?:$RE{EUC_C})+|(?:$RE{EUC_KANA})+|(?:$RE{EUC_0212})+)
  92         }{
  93             my $chunk = $1;
  94             my $esc =
  95                 ( $chunk =~ tr/\x8E//d ) ? $ESC{KANA} :
  96                     ( $chunk =~ tr/\x8F//d ) ? $ESC{JIS_0212} :
  97                         $ESC{JIS_0208};
  98             if ($esc eq $ESC{JIS_0212} && !$jis0212){
  99                 # fallback to '?'
 100                 $chunk =~ tr/\xA1-\xFE/\x3F/;
 101             }else{
 102                 $chunk =~ tr/\xA1-\xFE/\x21-\x7E/;
 103             }
 104             $esc . $chunk . $ESC{ASC};
 105         }geox;
 106     $$r_str =~
 107         s/\Q$ESC{ASC}\E
 108             (\Q$ESC{KANA}\E|\Q$ESC{JIS_0212}\E|\Q$ESC{JIS_0208}\E)/$1/gox;
 109     $$r_str;
 110 }
 111
 112 1;
 113 __END__
 114
 115
 116 =head1 NAME
 117
 118 Encode::JP::JIS7 -- internally used by Encode::JP
 119
 120 =cut