ext/Encode/lib/Encode/JP/JIS7.pm

   1 package Encode::JP::JIS7;
   2 use strict;
   3
   4 our $VERSION = do { my @r = (q$Revision: 1.5 $ =~ /\d+/g); sprintf "%d."."%02d" x $#r, @r };
   5
   6 use Encode qw(:fallbacks);
   7
   8 for my $name ('7bit-jis', 'iso-2022-jp', 'iso-2022-jp-1'){
   9     my $h2z     = ($name eq '7bit-jis')    ? 0 : 1;
  10     my $jis0212 = ($name eq 'iso-2022-jp') ? 0 : 1;
  11
  12     $Encode::Encoding{$name} =
  13         bless {
  14                Name      =>   $name,
  15                h2z       =>   $h2z,
  16                jis0212   =>   $jis0212,
  17               } => __PACKAGE__;
  18 }
  19
  20 sub name { shift->{'Name'} }
  21
  22 sub new_sequence { $_[0] }
  23
  24 sub needs_lines { 1 }
  25
  26 sub perlio_ok {
  27     exists $INC{"PerlIO/encoding.pm"} or return 0;
  28     PerlIO::encoding->VERSION >= 0.03 and return 1;
  29     return 0;
  30 }
  31
  32 use Encode::CJKConstants qw(:all);
  33
  34 our $DEBUG = 0;
  35
  36 #
  37 # decode is identical for all 2022 variants
  38 #
  39
  40 sub decode($$;$)
  41 {
  42     my ($obj,$str,$chk) = @_;
  43     my $residue = jis_euc(\$str);
  44     # This is for PerlIO
  45     $_[1] = $residue if $chk;
  46     return Encode::decode('euc-jp', $str, FB_PERLQQ);
  47 }
  48
  49 #
  50 # encode is different
  51 #
  52
  53 sub encode($$;$)
  54 {
  55     require Encode::JP::H2Z;
  56     my ($obj, $utf8, $chk) = @_;
  57     # empty the input string in the stack so perlio is ok
  58     $_[1] = '' if $chk;
  59     my ($h2z, $jis0212) = @$obj{qw(h2z jis0212)};
  60     my $octet = Encode::encode('euc-jp', $utf8, FB_PERLQQ) ;
  61     $h2z and &Encode::JP::H2Z::h2z(\$octet);
  62     euc_jis(\$octet, $jis0212);
  63     return $octet;
  64 }
  65
  66
  67 # JIS<->EUC
  68
  69 sub jis_euc {
  70     my $r_str = shift;
  71     $$r_str =~ s(
  72                  ($RE{JIS_0212}|$RE{JIS_0208}|$RE{ISO_ASC}|$RE{JIS_KANA})
  73                  ([^\e]*)
  74                  )
  75     {
  76         my ($esc, $chunk) = ($1, $2);
  77         if ($esc !~ /$RE{ISO_ASC}/o) {
  78             $chunk =~ tr/\x21-\x7e/\xa1-\xfe/;
  79             if ($esc =~ /$RE{JIS_KANA}/o) {
  80                 $chunk =~ s/([\xa1-\xdf])/\x8e$1/og;
  81             }
  82             elsif ($esc =~ /$RE{JIS_0212}/o) {
  83                 $chunk =~ s/([\xa1-\xfe][\xa1-\xfe])/\x8f$1/og;
  84             }
  85         }
  86         $chunk;
  87     }geox;
  88     my ($residue) = ($$r_str =~ s/(\e.*)$//so);
  89     return $residue;
  90 }
  91
  92 sub euc_jis{
  93     no warnings qw(uninitialized);
  94     my $r_str = shift;
  95     my $jis0212 = shift;
  96     $$r_str =~ s{
  97         ((?:$RE{EUC_C})+|(?:$RE{EUC_KANA})+|(?:$RE{EUC_0212})+)
  98         }{
  99             my $chunk = $1;
 100             my $esc =
 101                 ( $chunk =~ tr/\x8E//d ) ? $ESC{KANA} :
 102                     ( $chunk =~ tr/\x8F//d ) ? $ESC{JIS_0212} :
 103                         $ESC{JIS_0208};
 104             if ($esc eq $ESC{JIS_0212} && !$jis0212){
 105                 # fallback to '?'
 106                 $chunk =~ tr/\xA1-\xFE/\x3F/;
 107             }else{
 108                 $chunk =~ tr/\xA1-\xFE/\x21-\x7E/;
 109             }
 110             $esc . $chunk . $ESC{ASC};
 111         }geox;
 112     $$r_str =~
 113         s/\Q$ESC{ASC}\E
 114             (\Q$ESC{KANA}\E|\Q$ESC{JIS_0212}\E|\Q$ESC{JIS_0208}\E)/$1/gox;
 115     $$r_str;
 116 }
 117
 118 1;
 119 __END__
 120
 121
 122 =head1 NAME
 123
 124 Encode::JP::JIS7 -- internally used by Encode::JP
 125
 126 =cut