ext/Encode/lib/Encode/JP/JIS7.pm

   1 package Encode::JP::JIS7;
   2 use strict;
   3
   4 our $VERSION = do { my @r = (q$Revision: 1.6 $ =~ /\d+/g); sprintf "%d."."%02d" x $#r, @r };
   5
   6 use Encode qw(:fallbacks);
   7
   8 for my $name ('7bit-jis', 'iso-2022-jp', 'iso-2022-jp-1'){
   9     my $h2z     = ($name eq '7bit-jis')    ? 0 : 1;
  10     my $jis0212 = ($name eq 'iso-2022-jp') ? 0 : 1;
  11
  12     $Encode::Encoding{$name} =
  13         bless {
  14                Name      =>   $name,
  15                h2z       =>   $h2z,
  16                jis0212   =>   $jis0212,
  17               } => __PACKAGE__;
  18 }
  19
  20 sub name { shift->{'Name'} }
  21
  22 sub new_sequence { $_[0] }
  23
  24 sub needs_lines { 1 }
  25
  26 sub perlio_ok {
  27     eval{ require PerlIO::encoding };
  28     if ($@){
  29         return 0;
  30     }else{
  31         return (PerlIO::encoding->VERSION >= 0.03);
  32     }
  33 }
  34
  35 use Encode::CJKConstants qw(:all);
  36
  37 our $DEBUG = 0;
  38
  39 #
  40 # decode is identical for all 2022 variants
  41 #
  42
  43 sub decode($$;$)
  44 {
  45     my ($obj,$str,$chk) = @_;
  46     my $residue = jis_euc(\$str);
  47     # This is for PerlIO
  48     $_[1] = $residue if $chk;
  49     return Encode::decode('euc-jp', $str, FB_PERLQQ);
  50 }
  51
  52 #
  53 # encode is different
  54 #
  55
  56 sub encode($$;$)
  57 {
  58     require Encode::JP::H2Z;
  59     my ($obj, $utf8, $chk) = @_;
  60     # empty the input string in the stack so perlio is ok
  61     $_[1] = '' if $chk;
  62     my ($h2z, $jis0212) = @$obj{qw(h2z jis0212)};
  63     my $octet = Encode::encode('euc-jp', $utf8, FB_PERLQQ) ;
  64     $h2z and &Encode::JP::H2Z::h2z(\$octet);
  65     euc_jis(\$octet, $jis0212);
  66     return $octet;
  67 }
  68
  69
  70 # JIS<->EUC
  71
  72 sub jis_euc {
  73     my $r_str = shift;
  74     $$r_str =~ s(
  75                  ($RE{JIS_0212}|$RE{JIS_0208}|$RE{ISO_ASC}|$RE{JIS_KANA})
  76                  ([^\e]*)
  77                  )
  78     {
  79         my ($esc, $chunk) = ($1, $2);
  80         if ($esc !~ /$RE{ISO_ASC}/o) {
  81             $chunk =~ tr/\x21-\x7e/\xa1-\xfe/;
  82             if ($esc =~ /$RE{JIS_KANA}/o) {
  83                 $chunk =~ s/([\xa1-\xdf])/\x8e$1/og;
  84             }
  85             elsif ($esc =~ /$RE{JIS_0212}/o) {
  86                 $chunk =~ s/([\xa1-\xfe][\xa1-\xfe])/\x8f$1/og;
  87             }
  88         }
  89         $chunk;
  90     }geox;
  91     my ($residue) = ($$r_str =~ s/(\e.*)$//so);
  92     return $residue;
  93 }
  94
  95 sub euc_jis{
  96     no warnings qw(uninitialized);
  97     my $r_str = shift;
  98     my $jis0212 = shift;
  99     $$r_str =~ s{
 100         ((?:$RE{EUC_C})+|(?:$RE{EUC_KANA})+|(?:$RE{EUC_0212})+)
 101         }{
 102             my $chunk = $1;
 103             my $esc =
 104                 ( $chunk =~ tr/\x8E//d ) ? $ESC{KANA} :
 105                     ( $chunk =~ tr/\x8F//d ) ? $ESC{JIS_0212} :
 106                         $ESC{JIS_0208};
 107             if ($esc eq $ESC{JIS_0212} && !$jis0212){
 108                 # fallback to '?'
 109                 $chunk =~ tr/\xA1-\xFE/\x3F/;
 110             }else{
 111                 $chunk =~ tr/\xA1-\xFE/\x21-\x7E/;
 112             }
 113             $esc . $chunk . $ESC{ASC};
 114         }geox;
 115     $$r_str =~
 116         s/\Q$ESC{ASC}\E
 117             (\Q$ESC{KANA}\E|\Q$ESC{JIS_0212}\E|\Q$ESC{JIS_0208}\E)/$1/gox;
 118     $$r_str;
 119 }
 120
 121 1;
 122 __END__
 123
 124
 125 =head1 NAME
 126
 127 Encode::JP::JIS7 -- internally used by Encode::JP
 128
 129 =cut