ext/Encode/lib/Encode/Guess.pm

   1 package Encode::Guess;
   2 use strict;
   3
   4 use Encode qw(:fallbacks find_encoding);
   5 our $VERSION = do { my @r = (q$Revision: 1.4 $ =~ /\d+/g); sprintf "%d."."%02d" x $#r, @r };
   6
   7 my $Canon = 'Guess';
   8 our $DEBUG = 0;
   9 our %DEF_SUSPECTS = map { $_ => find_encoding($_) } qw(ascii utf8);
  10 $Encode::Encoding{$Canon} =
  11     bless {
  12            Name       => $Canon,
  13            Suspects => { %DEF_SUSPECTS },
  14           } => __PACKAGE__;
  15
  16 use base qw(Encode::Encoding);
  17 sub needs_lines { 1 }
  18 sub perlio_ok { 0 }
  19
  20 our @EXPORT = qw(guess_encoding);
  21
  22 sub import { # Exporter not used so we do it on our own
  23     my $callpkg = caller;
  24     for my $item (@EXPORT){
  25         no strict 'refs';
  26         *{"$callpkg\::$item"} = \&{"$item"};
  27     }
  28     set_suspects(@_);
  29 }
  30
  31 sub set_suspects{
  32     my $class = shift;
  33     my $self = ref($class) ? $class : $Encode::Encoding{$Canon};
  34     $self->{Suspects} = { %DEF_SUSPECTS };
  35     $self->add_suspects(@_);
  36 }
  37
  38 sub add_suspects{
  39     my $class = shift;
  40     my $self = ref($class) ? $class : $Encode::Encoding{$Canon};
  41     for my $c (@_){
  42         my $e = find_encoding($c) or die "Unknown encoding: $c";
  43         $self->{Suspects}{$e->name} = $e;
  44         $DEBUG and warn "Added: ", $e->name;
  45     }
  46 }
  47
  48 sub decode($$;$){
  49     my ($obj, $octet, $chk) = @_;
  50     my $guessed = guess($obj, $octet);
  51     unless (ref($guessed)){
  52         require Carp;
  53         Carp::croak($guessed);
  54     }
  55     my $utf8 = $guessed->decode($octet, $chk);
  56     $_[1] = $octet if $chk;
  57     return $utf8;
  58 }
  59
  60 sub guess_encoding{
  61     guess($Encode::Encoding{$Canon}, @_);
  62 }
  63
  64 sub guess {
  65     my $class = shift;
  66     my $obj   = ref($class) ? $class : $Encode::Encoding{$Canon};
  67     my $octet = shift;
  68     # cheat 0: utf8 flag;
  69     Encode::is_utf8($octet) and return find_encoding('utf8');
  70     # cheat 1: BOM
  71     use Encode::Unicode;
  72     my $BOM = unpack('n', $octet);
  73     return find_encoding('UTF-16')
  74         if ($BOM == 0xFeFF or $BOM == 0xFFFe);
  75     $BOM = unpack('N', $octet);
  76     return find_encoding('UTF-32')
  77         if ($BOM == 0xFeFF or $BOM == 0xFFFe0000);
  78
  79     my %try =  %{$obj->{Suspects}};
  80     for my $c (@_){
  81         my $e = find_encoding($c) or die "Unknown encoding: $c";
  82         $try{$e->name} = $e;
  83         $DEBUG and warn "Added: ", $e->name;
  84     }
  85     my $nline = 1;
  86     for my $line (split /\r|\n|\r\n/, $octet){
  87         # cheat 2 -- \e in the string
  88         if ($line =~ /\e/o){
  89             my @keys = keys %try;
  90             delete @try{qw/utf8 ascii/};
  91             for my $k (@keys){
  92                 ref($try{$k}) eq 'Encode::XS' and delete $try{$k};
  93             }
  94         }
  95         my %ok = %try;
  96         # warn join(",", keys %try);
  97         for my $k (keys %try){
  98             my $scratch = $line;
  99             $try{$k}->decode($scratch, FB_QUIET);
 100             if ($scratch eq ''){
 101                 $DEBUG and warn sprintf("%4d:%-24s ok\n", $nline, $k);
 102             }else{
 103                 use bytes ();
 104                 $DEBUG and
 105                     warn sprintf("%4d:%-24s not ok; %d bytes left\n",
 106                                  $nline, $k, bytes::length($scratch));
 107                 delete $ok{$k};
 108
 109             }
 110         }
 111         %ok or return "No appropriate encodings found!";
 112         if (scalar(keys(%ok)) == 1){
 113             my ($retval) = values(%ok);
 114             return $retval;
 115         }
 116         %try = %ok; $nline++;
 117     }
 118     $try{ascii} or
 119         return  "Encodings too ambiguous: ", join(" or ", keys %try);
 120     return $try{ascii};
 121 }
 122
 123
 124
 125 1;
 126 __END__
 127
 128 =head1 NAME
 129
 130 Encode::Guess -- Guesses encoding from data
 131
 132 =head1 SYNOPSIS
 133
 134   # if you are sure $data won't contain anything bogus
 135
 136   use Encode;
 137   use Encode::Guess qw/euc-jp shiftjis 7bit-jis/;
 138   my $utf8 = decode("Guess", $data);
 139   my $data = encode("Guess", $utf8);   # this doesn't work!
 140
 141   # more elaborate way
 142   use Encode::Guess,
 143   my $enc = guess_encoding($data, qw/euc-jp shiftjis 7bit-jis/);
 144   ref($enc) or die "Can't guess: $enc"; # trap error this way
 145   $utf8 = $enc->decode($data);
 146   # or
 147   $utf8 = decode($enc->name, $data)
 148
 149 =head1 ABSTRACT
 150
 151 Encode::Guess enables you to guess in what encoding a given data is
 152 encoded, or at least tries to.
 153
 154 =head1 DESCRIPTION
 155
 156 By default, it checks only ascii, utf8 and UTF-16/32 with BOM.
 157
 158   use Encode::Guess; # ascii/utf8/BOMed UTF
 159
 160 To use it more practically, you have to give the names of encodings to
 161 check (I<suspects> as follows).  The name of suspects can either be
 162 canonical names or aliases.
 163
 164  # tries all major Japanese Encodings as well
 165   use Encode::Guess qw/euc-jp shiftjis 7bit-jis/;
 166
 167 =over 4
 168
 169 =item Encode::Guess->set_suspects
 170
 171 You can also change the internal suspects list via C<set_suspects>
 172 method.
 173
 174   use Encode::Guess;
 175   Encode::Guess->set_suspects(qw/euc-jp shiftjis 7bit-jis/);
 176
 177 =item Encode::Guess->add_suspects
 178
 179 Or you can use C<add_suspects> method.  The difference is that
 180 C<set_suspects> flushes the current suspects list while
 181 C<add_suspects> adds.
 182
 183   use Encode::Guess;
 184   Encode::Guess->add_suspects(qw/euc-jp shiftjis 7bit-jis/);
 185   # now the suspects are euc-jp,shiftjis,7bit-jis, AND
 186   # euc-kr,euc-cn, and big5-eten
 187   Encode::Guess->add_suspects(qw/euc-kr euc-cn big5-eten/);
 188
 189 =item Encode::decode("Guess" ...)
 190
 191 When you are content with suspects list, you can now
 192
 193   my $utf8 = Encode::decode("Guess", $data);
 194
 195 =item Encode::Guess->guess($data)
 196
 197 But it will croak if Encode::Guess fails to eliminate all other
 198 suspects but the right one or no suspect was good.  So you should
 199 instead try this;
 200
 201   my $decoder = Encode::Guess->guess($data);
 202
 203 On success, $decoder is an object that is documented in
 204 L<Encode::Encoding>.  So you can now do this;
 205
 206   my $utf8 = $decoder->decode($data);
 207
 208 On failure, $decoder now contains an error message so the whole thing
 209 would be as follows;
 210
 211   my $decoder = Encode::Guess->guess($data);
 212   die $decoder unless ref($decoder);
 213   my $utf8 = $decoder->decode($data);
 214
 215 =item guess_encoding($data, [, I<list of suspects>])
 216
 217 You can also try C<guess_encoding> function which is exported by
 218 default.  It takes $data to check and it also takes the list of
 219 suspects by option.  The optional suspect list is I<not reflected> to
 220 the internal suspects list.
 221
 222   my $decoder = guess_encoding($data, qw/euc-jp euc-kr euc-cn/);
 223   die $decoder unless ref($decoder);
 224   my $utf8 = $decoder->decode($data);
 225   # check only ascii and utf8
 226   my $decoder = guess_encoding($data);
 227
 228 =back
 229
 230 =head1 CAVEATS
 231
 232 =over 4
 233
 234 =item *
 235
 236 Because of the algorithm used, ISO-8859 series and other single-byte
 237 encodings do not work well unless either one of ISO-8859 is the only
 238 one suspect (besides ascii and utf8).
 239
 240   use Encode::Guess;
 241   # perhaps ok
 242   my $decoder = guess_encoding($data, 'latin1');
 243   # definitely NOT ok
 244   my $decoder = guess_encoding($data, qw/latin1 greek/);
 245
 246 The reason is that Encode::Guess guesses encoding by trial and error.
 247 It first splits $data into lines and tries to decode the line for each
 248 suspect.  It keeps it going until all but one encoding was eliminated
 249 out of suspects list.  ISO-8859 series is just too successful for most
 250 cases (because it fills almost all code points in \x00-\xff).
 251
 252 =item *
 253
 254 Do not mix national standard encodings and the corresponding vendor
 255 encodings.
 256
 257   # a very bad idea
 258   my $decoder
 259      = guess_encoding($data, qw/shiftjis MacJapanese cp932/);
 260
 261 The reason is that vendor encoding is usually a superset of national
 262 standard so it becomes too ambiguous for most cases.
 263
 264 =item *
 265
 266 On the other hand, mixing various national standard encodings
 267 automagically works unless $data is too short to allow for guessing.
 268
 269  # This is ok if $data is long enough
 270  my $decoder =
 271   guess_encoding($data, qw/euc-cn
 272                            euc-jp shiftjis 7bit-jis
 273                            euc-kr
 274                            big5-eten/);
 275
 276 =item *
 277
 278 DO NOT PUT TOO MANY SUSPECTS!  Don't you try something like this!
 279
 280   my $decoder = guess_encoding($data,
 281                                Encode->encodings(":all"));
 282
 283 =back
 284
 285 It is, after all, just a guess.  You should alway be explicit when it
 286 comes to encodings.  But there are some, especially Japanese,
 287 environment that guess-coding is a must.  Use this module with care.
 288
 289 =head1 SEE ALSO
 290
 291 L<Encode>, L<Encode::Encoding>
 292
 293 =cut
 294