ext/Encode/lib/Encode/Guess.pm

   1 package Encode::Guess;
   2 use strict;
   3
   4 use Encode qw(:fallbacks find_encoding);
   5 our $VERSION = do { my @r = (q$Revision: 1.3 $ =~ /\d+/g); sprintf "%d."."%02d" x $#r, @r };
   6
   7 my $Canon = 'Guess';
   8 our $DEBUG = 0;
   9 our %DEF_SUSPECTS = map { $_ => find_encoding($_) } qw(ascii utf8);
  10 $Encode::Encoding{$Canon} =
  11     bless {
  12            Name       => $Canon,
  13            Suspects => { %DEF_SUSPECTS },
  14           } => __PACKAGE__;
  15
  16 use base qw(Encode::Encoding);
  17 sub needs_lines { 1 }
  18 sub perlio_ok { 0 }
  19
  20 our @EXPORT = qw(guess_encoding);
  21
  22 sub import { # Exporter not used so we do it on our own
  23     my $callpkg = caller;
  24     for my $item (@EXPORT){
  25         no strict 'refs';
  26         *{"$callpkg\::$item"} = \&{"$item"};
  27     }
  28     set_suspects(@_);
  29 }
  30
  31 sub set_suspects{
  32     my $class = shift;
  33     my $self = ref($class) ? $class : $Encode::Encoding{$Canon};
  34     $self->{Suspects} = { %DEF_SUSPECTS };
  35     $self->add_suspects(@_);
  36 }
  37
  38 sub add_suspects{
  39     my $class = shift;
  40     my $self = ref($class) ? $class : $Encode::Encoding{$Canon};
  41     for my $c (@_){
  42         my $e = find_encoding($c) or die "Unknown encoding: $c";
  43         $self->{Suspects}{$e->name} = $e;
  44         $DEBUG and warn "Added: ", $e->name;
  45     }
  46 }
  47
  48 sub decode($$;$){
  49     my ($obj, $octet, $chk) = @_;
  50     my $guessed = guess($obj, $octet);
  51     unless (ref($guessed)){
  52         require Carp;
  53         Carp::croak($guessed);
  54     }
  55     my $utf8 = $guessed->decode($octet, $chk);
  56     $_[1] = $octet if $chk;
  57     return $utf8;
  58 }
  59
  60 sub guess_encoding{
  61     guess($Encode::Encoding{$Canon}, @_);
  62 }
  63
  64 sub guess {
  65     my $class = shift;
  66     my $obj   = ref($class) ? $class : $Encode::Encoding{$Canon};
  67     my $octet = shift;
  68     # cheat 0: utf8 flag;
  69     Encode::is_utf8($octet) and return find_encoding('utf8');
  70     # cheat 1: BOM
  71     use Encode::Unicode;
  72     my $BOM = unpack('n', $octet);
  73     return find_encoding('UTF-16')
  74         if ($BOM == 0xFeFF or $BOM == 0xFFFe);
  75     $BOM = unpack('N', $octet);
  76     return find_encoding('UTF-32')
  77         if ($BOM == 0xFeFF or $BOM == 0xFFFe0000);
  78
  79     my %try =  %{$obj->{Suspects}};
  80     for my $c (@_){
  81         my $e = find_encoding($c) or die "Unknown encoding: $c";
  82         $try{$e->name} = $e;
  83         $DEBUG and warn "Added: ", $e->name;
  84     }
  85     my $nline = 1;
  86     for my $line (split /\r|\n|\r\n/, $octet){
  87         # cheat 2 -- \e in the string
  88         if ($line =~ /\e/o){
  89             my @keys = keys %try;
  90             delete @try{qw/utf8 ascii/};
  91             for my $k (@keys){
  92                 ref($try{$k}) eq 'Encode::XS' and delete $try{$k};
  93             }
  94         }
  95         my %ok = %try;
  96         # warn join(",", keys %try);
  97         for my $k (keys %try){
  98             my $scratch = $line;
  99             $try{$k}->decode($scratch, FB_QUIET);
 100             if ($scratch eq ''){
 101                 $DEBUG and warn sprintf("%4d:%-24s ok\n", $nline, $k);
 102             }else{
 103                 use bytes ();
 104                 $DEBUG and
 105                     warn sprintf("%4d:%-24s not ok; %d bytes left\n",
 106                                  $nline, $k, bytes::length($scratch));
 107                 delete $ok{$k};
 108
 109             }
 110         }
 111         %ok or return "No appropriate encodings found!";
 112         if (scalar(keys(%ok)) == 1){
 113             my ($retval) = values(%ok);
 114             return $retval;
 115         }
 116         %try = %ok; $nline++;
 117     }
 118     $try{ascii} or
 119         return  "Encodings too ambiguous: ", join(" or ", keys %try);
 120     return $try{ascii};
 121 }
 122
 123
 124
 125 1;
 126 __END__
 127
 128 =head1 NAME
 129
 130 Encode::Guess -- Guesses encoding from data
 131
 132 =head1 SYNOPSIS
 133
 134   # if you are sure $data won't contain anything bogus
 135
 136   use Encode::Guess qw/euc-jp shiftjis 7bit-jis/;
 137   my $utf8 = decode("Guess", $data);
 138   my $data = encode("Guess", $utf8);   # this doesn't work!
 139
 140   # more elaborate way
 141   use Encode::Guess,
 142   my $enc = guess_encoding($data, qw/euc-jp shiftjis 7bit-jis/);
 143   ref($enc) or die "Can't guess: $enc"; # trap error this way
 144   $utf8 = $enc->decode($data);
 145   # or
 146   $utf8 = decode($enc->name, $data)
 147
 148 =head1 ABSTRACT
 149
 150 Encode::Guess enables you to guess in what encoding a given data is
 151 encoded, or at least tries to.
 152
 153 =head1 DESCRIPTION
 154
 155 By default, it checks only ascii, utf8 and UTF-16/32 with BOM.
 156
 157   use Encode::Guess; # ascii/utf8/BOMed UTF
 158
 159 To use it more practically, you have to give the names of encodings to
 160 check (I<suspects> as follows).  The name of suspects can either be
 161 canonical names or aliases.
 162
 163  # tries all major Japanese Encodings as well
 164   use Encode::Guess qw/euc-jp shiftjis 7bit-jis/;
 165
 166 =over 4
 167
 168 =item Encode::Guess->set_suspects
 169
 170 You can also change the internal suspects list via C<set_suspects>
 171 method.
 172
 173   use Encode::Guess;
 174   Encode::Guess->set_suspects(qw/euc-jp shiftjis 7bit-jis/);
 175
 176 =item Encode::Guess->add_suspects
 177
 178 Or you can use C<add_suspects> method.  The difference is that
 179 C<set_suspects> flushes the current suspects list while
 180 C<add_suspects> adds.
 181
 182   use Encode::Guess;
 183   Encode::Guess->add_suspects(qw/euc-jp shiftjis 7bit-jis/);
 184   # now the suspects are euc-jp,shiftjis,7bit-jis, AND
 185   # euc-kr,euc-cn, and big5-eten
 186   Encode::Guess->add_suspects(qw/euc-kr euc-cn big5-eten/);
 187
 188 =item Encode::decode("Guess" ...)
 189
 190 When you are content with suspects list, you can now
 191
 192   my $utf8 = Encode::decode("Guess", $data);
 193
 194 =item Encode::Guess->guess($data)
 195
 196 But it will croak if Encode::Guess fails to eliminate all other
 197 suspects but the right one or no suspect was good.  So you should
 198 instead try this;
 199
 200   my $decoder = Encode::Guess->guess($data);
 201
 202 On success, $decoder is an object that is documented in
 203 L<Encode::Encoding>.  So you can now do this;
 204
 205   my $utf8 = $decoder->decode($data);
 206
 207 On failure, $decoder now contains an error message so the whole thing
 208 would be as follows;
 209
 210   my $decoder = Encode::Guess->guess($data);
 211   die $decoder unless ref($decoder);
 212   my $utf8 = $decoder->decode($data);
 213
 214 =item guess_encoding($data, [, I<list of suspects>])
 215
 216 You can also try C<guess_encoding> function which is exported by
 217 default.  It takes $data to check and it also takes the list of
 218 suspects by option.  The optional suspect list is I<not reflected> to
 219 the internal suspects list.
 220
 221   my $decoder = guess_encoding($data, qw/euc-jp euc-kr euc-cn/);
 222   die $decoder unless ref($decoder);
 223   my $utf8 = $decoder->decode($data);
 224   # check only ascii and utf8
 225   my $decoder = guess_encoding($data);
 226
 227 =back
 228
 229 =head1 CAVEATS
 230
 231 =over 4
 232
 233 =item *
 234
 235 Because of the algorithm used, ISO-8859 series and other single-byte
 236 encodings do not work well unless either one of ISO-8859 is the only
 237 one suspect (besides ascii and utf8).
 238
 239   use Encode::Guess;
 240   # perhaps ok
 241   my $decoder = guess_encoding($data, 'latin1');
 242   # definitely NOT ok
 243   my $decoder = guess_encoding($data, qw/latin1 greek/);
 244
 245 The reason is that Encode::Guess guesses encoding by trial and error.
 246 It first splits $data into lines and tries to decode the line for each
 247 suspect.  It keeps it going until all but one encoding was eliminated
 248 out of suspects list.  ISO-8859 series is just too successful for most
 249 cases (because it fills almost all code points in \x00-\xff).
 250
 251 =item *
 252
 253 Do not mix national standard encodings and the corresponding vendor
 254 encodings.
 255
 256   # a very bad idea
 257   my $decoder
 258      = guess_encoding($data, qw/shiftjis MacJapanese cp932/);
 259
 260 The reason is that vendor encoding is usually a superset of national
 261 standard so it becomes too ambiguous for most cases.
 262
 263 =item *
 264
 265 On the other hand, mixing various national standard encodings
 266 automagically works unless $data is too short to allow for guessing.
 267
 268  # This is ok if $data is long enough
 269  my $decoder =
 270   guess_encoding($data, qw/euc-cn
 271                            euc-jp shiftjis 7bit-jis
 272                            euc-kr
 273                            big5-eten/);
 274
 275 =item *
 276
 277 DO NOT PUT TOO MANY SUSPECTS!  Don't you try something like this!
 278
 279   my $decoder = guess_encoding($data,
 280                                Encode->encodings(":all"));
 281
 282 =back
 283
 284 It is, after all, just a guess.  You should alway be explicit when it
 285 comes to encodings.  But there are some, especially Japanese,
 286 environment that guess-coding is a must.  Use this module with care.
 287
 288 =head1 SEE ALSO
 289
 290 L<Encode>, L<Encode::Encoding>
 291
 292 =cut
 293