ext/Encode/encoding.pm

   1 package encoding;
   2 our $VERSION = do { my @r = (q$Revision: 1.35 $ =~ /\d+/g); sprintf "%d."."%02d" x $#r, @r };
   3
   4 use Encode;
   5 use strict;
   6
   7 BEGIN {
   8     if (ord("A") == 193) {
   9         require Carp;
  10         Carp::croak("encoding pragma does not support EBCDIC platforms");
  11     }
  12 }
  13
  14 our $HAS_PERLIO = 0;
  15 eval { require PerlIO::encoding };
  16 unless ($@){
  17     $HAS_PERLIO = (PerlIO::encoding->VERSION >= 0.02);
  18 }
  19
  20 sub import {
  21     my $class = shift;
  22     my $name  = shift;
  23     my %arg = @_;
  24     $name ||= $ENV{PERL_ENCODING};
  25
  26     my $enc = find_encoding($name);
  27     unless (defined $enc) {
  28         require Carp;
  29         Carp::croak("Unknown encoding '$name'");
  30     }
  31     unless ($arg{Filter}){
  32         ${^ENCODING} = $enc; # this is all you need, actually.
  33         $HAS_PERLIO or return 1;
  34         for my $h (qw(STDIN STDOUT)){
  35             if ($arg{$h}){
  36                 unless (defined find_encoding($arg{$h})) {
  37                     require Carp;
  38                     Carp::croak("Unknown encoding for $h, '$arg{$h}'");
  39                 }
  40                 eval { binmode($h, ":encoding($arg{$h})") };
  41             }else{
  42                 unless (exists $arg{$h}){
  43                     eval {
  44                         no warnings 'uninitialized';
  45                         binmode($h, ":encoding($name)");
  46                     };
  47                 }
  48             }
  49             if ($@){
  50                 require Carp;
  51                 Carp::croak($@);
  52             }
  53         }
  54     }else{
  55         defined(${^ENCODING}) and undef ${^ENCODING};
  56         eval {
  57             require Filter::Util::Call ;
  58             Filter::Util::Call->import ;
  59             binmode(STDIN);
  60             binmode(STDOUT);
  61             filter_add(sub{
  62                            my $status;
  63                            if (($status = filter_read()) > 0){
  64                                $_ = $enc->decode($_, 1);
  65                                # warn $_;
  66                            }
  67                            $status ;
  68                        });
  69         };
  70         # warn "Filter installed";
  71     }
  72     return 1; # I doubt if we need it, though
  73 }
  74
  75 sub unimport{
  76     no warnings;
  77     undef ${^ENCODING};
  78     if ($HAS_PERLIO){
  79         binmode(STDIN,  ":raw");
  80         binmode(STDOUT, ":raw");
  81     }else{
  82     binmode(STDIN);
  83     binmode(STDOUT);
  84     }
  85     if ($INC{"Filter/Util/Call.pm"}){
  86         eval { filter_del() };
  87     }
  88 }
  89
  90 1;
  91 __END__
  92
  93 =pod
  94
  95 =head1 NAME
  96
  97 encoding - allows you to write your script in non-ascii or non-utf8
  98
  99 =head1 SYNOPSIS
 100
 101   use encoding "greek";  # Perl like Greek to you?
 102   use encoding "euc-jp"; # Jperl!
 103
 104   # or you can even do this if your shell supports your native encoding
 105
 106   perl -Mencoding=latin2 -e '...' # Feeling centrally European?
 107   perl -Mencoding=euc-kr -e '...' # Or Korean?
 108
 109   # or from the shebang line
 110
 111   #!/your/path/to/perl -Mencoding="8859-6" # Arabian Nights
 112   #!/your/path/to/perl -Mencoding=big5     # Taiwanese
 113
 114   # more control
 115
 116   # A simple euc-cn => utf-8 converter
 117   use encoding "euc-cn", STDOUT => "utf8";  while(<>){print};
 118
 119   # "no encoding;" supported (but not scoped!)
 120   no encoding;
 121
 122   # an alternate way, Filter
 123   use encoding "euc-jp", Filter=>1;
 124   use utf8;
 125   # now you can use kanji identifiers -- in euc-jp!
 126
 127 =head1 ABSTRACT
 128
 129 Let's start with a bit of history: Perl 5.6.0 introduced Unicode
 130 support.  You could apply C<substr()> and regexes even to complex CJK
 131 characters -- so long as the script was written in UTF-8.  But back
 132 then, text editors that supported UTF-8 were still rare and many users
 133 instead chose to write scripts in legacy encodings, giving up a whole
 134 new feature of Perl 5.6.
 135
 136 Rewind to the future: starting from perl 5.8.0 with the B<encoding>
 137 pragma, you can write your script in any encoding you like (so long
 138 as the C<Encode> module supports it) and still enjoy Unicode support.
 139 You can write code in EUC-JP as follows:
 140
 141   my $Rakuda = "\xF1\xD1\xF1\xCC"; # Camel in Kanji
 142                #<-char-><-char->   # 4 octets
 143   s/\bCamel\b/$Rakuda/;
 144
 145 And with C<use encoding "euc-jp"> in effect, it is the same thing as
 146 the code in UTF-8:
 147
 148   my $Rakuda = "\x{99F1}\x{99DD}"; # two Unicode Characters
 149   s/\bCamel\b/$Rakuda/;
 150
 151 The B<encoding> pragma also modifies the filehandle disciplines of
 152 STDIN, STDOUT, and STDERR to the specified encoding.  Therefore,
 153
 154   use encoding "euc-jp";
 155   my $message = "Camel is the symbol of perl.\n";
 156   my $Rakuda = "\xF1\xD1\xF1\xCC"; # Camel in Kanji
 157   $message =~ s/\bCamel\b/$Rakuda/;
 158   print $message;
 159
 160 Will print "\xF1\xD1\xF1\xCC is the symbol of perl.\n",
 161 not "\x{99F1}\x{99DD} is the symbol of perl.\n".
 162
 163 You can override this by giving extra arguments; see below.
 164
 165 =head1 USAGE
 166
 167 =over 4
 168
 169 =item use encoding [I<ENCNAME>] ;
 170
 171 Sets the script encoding to I<ENCNAME>. Filehandle disciplines of
 172 STDIN and STDOUT are set to ":encoding(I<ENCNAME>)".  Note that STDERR
 173 will not be changed.
 174
 175 If no encoding is specified, the environment variable L<PERL_ENCODING>
 176 is consulted.  If no encoding can be found, the error C<Unknown encoding
 177 'I<ENCNAME>'> will be thrown.
 178
 179 Note that non-STD file handles remain unaffected.  Use C<use open> or
 180 C<binmode> to change disciplines of those.
 181
 182 =item use encoding I<ENCNAME> [ STDIN =E<gt> I<ENCNAME_IN> ...] ;
 183
 184 You can also individually set encodings of STDIN and STDOUT via the
 185 C<< STDIN => I<ENCNAME> >> form.  In this case, you cannot omit the
 186 first I<ENCNAME>.  C<< STDIN => undef >> turns the IO transcoding
 187 completely off.
 188
 189 =item no encoding;
 190
 191 Unsets the script encoding. The disciplines of STDIN, STDOUT are
 192 reset to ":raw" (the default unprocessed raw stream of bytes).
 193
 194 =back
 195
 196 =head1 CAVEATS
 197
 198 =head2 NOT SCOPED
 199
 200 The pragma is a per script, not a per block lexical.  Only the last
 201 C<use encoding> or C<no encoding> matters, and it affects
 202 B<the whole script>.  However, the <no encoding> pragma is supported and
 203 B<use encoding> can appear as many times as you want in a given script.
 204 The multiple use of this pragma is discouraged.
 205
 206 Because of this nature, the use of this pragma inside the module is
 207 strongly discouraged (because the influence of this pragma lasts not
 208 only for the module but the script that uses).  But if you have to,
 209 make sure you say C<no encoding> at the end of the module so you
 210 contain the influence of the pragma within the module.
 211
 212 =head2 DO NOT MIX MULTIPLE ENCODINGS
 213
 214 Notice that only literals (string or regular expression) having only
 215 legacy code points are affected: if you mix data like this
 216
 217         \xDF\x{100}
 218
 219 the data is assumed to be in (Latin 1 and) Unicode, not in your native
 220 encoding.  In other words, this will match in "greek":
 221
 222         "\xDF" =~ /\x{3af}/
 223
 224 but this will not
 225
 226         "\xDF\x{100}" =~ /\x{3af}\x{100}/
 227
 228 since the C<\xDF> (ISO 8859-7 GREEK SMALL LETTER IOTA WITH TONOS) on
 229 the left will B<not> be upgraded to C<\x{3af}> (Unicode GREEK SMALL
 230 LETTER IOTA WITH TONOS) because of the C<\x{100}> on the left.  You
 231 should not be mixing your legacy data and Unicode in the same string.
 232
 233 This pragma also affects encoding of the 0x80..0xFF code point range:
 234 normally characters in that range are left as eight-bit bytes (unless
 235 they are combined with characters with code points 0x100 or larger,
 236 in which case all characters need to become UTF-8 encoded), but if
 237 the C<encoding> pragma is present, even the 0x80..0xFF range always
 238 gets UTF-8 encoded.
 239
 240 After all, the best thing about this pragma is that you don't have to
 241 resort to \x{....} just to spell your name in a native encoding.
 242 So feel free to put your strings in your encoding in quotes and
 243 regexes.
 244
 245 =head1 Non-ASCII Identifiers and Filter option
 246
 247 The magic of C<use encoding> is not applied to the names of
 248 identifiers.  In order to make C<${"\x{4eba}"}++> ($human++, where human
 249 is a single Han ideograph) work, you still need to write your script
 250 in UTF-8 or use a source filter.
 251
 252 In other words, the same restriction as with Jperl applies.
 253
 254 If you dare to experiment, however, you can try the Filter option.
 255
 256 =over 4
 257
 258 =item use encoding I<ENCNAME> Filter=E<gt>1;
 259
 260 This turns the encoding pragma into a source filter.  While the default
 261 approach just decodes interpolated literals (in qq() and qr()), this
 262 will apply a source filter to the entire source code.  In this case,
 263 STDIN and STDOUT remain untouched.
 264
 265 =back
 266
 267 What does this mean?  Your source code behaves as if it is written in
 268 UTF-8.  So even if your editor only supports Shift_JIS, for example,
 269 you can still try examples in Chapter 15 of C<Programming Perl, 3rd
 270 Ed.>.  For instance, you can use UTF-8 identifiers.
 271
 272 This option is significantly slower and (as of this writing) non-ASCII
 273 identifiers are not very stable WITHOUT this option and with the
 274 source code written in UTF-8.
 275
 276 To make your script in legacy encoding work with minimum effort,
 277 do not use Filter=E<gt>1.
 278
 279 =head1 EXAMPLE - Greekperl
 280
 281     use encoding "iso 8859-7";
 282
 283     # \xDF in ISO 8859-7 (Greek) is \x{3af} in Unicode.
 284
 285     $a = "\xDF";
 286     $b = "\x{100}";
 287
 288     printf "%#x\n", ord($a); # will print 0x3af, not 0xdf
 289
 290     $c = $a . $b;
 291
 292     # $c will be "\x{3af}\x{100}", not "\x{df}\x{100}".
 293
 294     # chr() is affected, and ...
 295
 296     print "mega\n"  if ord(chr(0xdf)) == 0x3af;
 297
 298     # ... ord() is affected by the encoding pragma ...
 299
 300     print "tera\n" if ord(pack("C", 0xdf)) == 0x3af;
 301
 302     # ... as are eq and cmp ...
 303
 304     print "peta\n" if "\x{3af}" eq  pack("C", 0xdf);
 305     print "exa\n"  if "\x{3af}" cmp pack("C", 0xdf) == 0;
 306
 307     # ... but pack/unpack C are not affected, in case you still
 308     # want to go back to your native encoding
 309
 310     print "zetta\n" if unpack("C", (pack("C", 0xdf))) == 0xdf;
 311
 312 =head1 KNOWN PROBLEMS
 313
 314 For native multibyte encodings (either fixed or variable length),
 315 the current implementation of the regular expressions may introduce
 316 recoding errors for regular expression literals longer than 127 bytes.
 317
 318 The encoding pragma is not supported on EBCDIC platforms.
 319 (Porters who are willing and able to remove this limitation are
 320 welcome.)
 321
 322 =head1 SEE ALSO
 323
 324 L<perlunicode>, L<Encode>, L<open>, L<Filter::Util::Call>,
 325
 326 Ch. 15 of C<Programming Perl (3rd Edition)>
 327 by Larry Wall, Tom Christiansen, Jon Orwant;
 328 O'Reilly & Associates; ISBN 0-596-00027-8
 329
 330 =cut