ext/Encode/Encode.pm

   1 package Encode;
   2 use strict;
   3 our $VERSION = '0.40';
   4
   5 require DynaLoader;
   6 require Exporter;
   7
   8 our @ISA = qw(Exporter DynaLoader);
   9
  10 # Public, encouraged API is exported by default
  11 our @EXPORT = qw (
  12   encode
  13   decode
  14   encode_utf8
  15   decode_utf8
  16   find_encoding
  17   encodings
  18 );
  19
  20 our @EXPORT_OK =
  21     qw(
  22        define_encoding
  23        define_alias
  24        from_to
  25        is_utf8
  26        is_8bit
  27        is_16bit
  28        utf8_upgrade
  29        utf8_downgrade
  30        _utf8_on
  31        _utf8_off
  32       );
  33
  34 bootstrap Encode ();
  35
  36 # Documentation moved after __END__ for speed - NI-S
  37
  38 use Carp;
  39
  40 # Make a %encoding package variable to allow a certain amount of cheating
  41 our %encoding;
  42 my @alias;  # ordered matching list
  43 my %alias;  # cached known aliases
  44
  45                      # 0  1  2  3  4  5   6   7   8   9  10
  46 our @latin2iso_num = ( 0, 1, 2, 3, 4, 9, 10, 13, 14, 15, 16 );
  47
  48 our %winlatin2cp   = (
  49                       'Latin1'     => 1252,
  50                       'Latin2'     => 1250,
  51                       'Cyrillic'   => 1251,
  52                       'Greek'      => 1253,
  53                       'Turkish'    => 1254,
  54                       'Hebrew'     => 1255,
  55                       'Arabic'     => 1256,
  56                       'Baltic'     => 1257,
  57                       'Vietnamese' => 1258,
  58                      );
  59
  60 sub encodings
  61 {
  62  my ($class) = @_;
  63  return
  64      map { $_->[0] }
  65          sort { $a->[1] cmp $b->[1] }
  66                map { [$_, lc $_] }
  67                    grep { $_ ne 'Internal' }
  68                         keys %encoding;
  69 }
  70
  71 sub findAlias
  72 {
  73     my $class = shift;
  74     local $_ = shift;
  75     # print "# findAlias $_\n";
  76     unless (exists $alias{$_})
  77     {
  78         for (my $i=0; $i < @alias; $i += 2)
  79         {
  80             my $alias = $alias[$i];
  81             my $val   = $alias[$i+1];
  82             my $new;
  83             if (ref($alias) eq 'Regexp' && $_ =~ $alias)
  84             {
  85                 $new = eval $val;
  86             }
  87             elsif (ref($alias) eq 'CODE')
  88             {
  89                 $new = &{$alias}($val)
  90                 }
  91             elsif (lc($_) eq lc($alias))
  92             {
  93                 $new = $val;
  94             }
  95             if (defined($new))
  96             {
  97                 next if $new eq $_; # avoid (direct) recursion on bugs
  98                 my $enc = (ref($new)) ? $new : find_encoding($new);
  99                 if ($enc)
 100                 {
 101                     $alias{$_} = $enc;
 102                     last;
 103                 }
 104             }
 105         }
 106     }
 107     return $alias{$_};
 108 }
 109
 110 sub define_alias
 111 {
 112     while (@_)
 113     {
 114         my ($alias,$name) = splice(@_,0,2);
 115         push(@alias, $alias => $name);
 116     }
 117 }
 118
 119 # Allow variants of iso-8859-1 etc.
 120 define_alias( qr/^iso[-_]?(\d+)[-_](\d+)$/i => '"iso-$1-$2"' );
 121
 122 # At least HP-UX has these.
 123 define_alias( qr/^iso8859(\d+)$/i => '"iso-8859-$1"' );
 124
 125 # More HP stuff.
 126 define_alias( qr/^(?:hp-)?(arabic|greek|hebrew|kana|roman|thai|turkish)8$/i => '"${1}8"' );
 127
 128 # The Official name of ASCII.
 129 define_alias( qr/^ANSI[-_]?X3\.4[-_]?1968$/i => '"ascii"' );
 130
 131 # This is a font issue, not an encoding issue.
 132 # (The currency symbol of the Latin 1 upper half
 133 #  has been redefined as the euro symbol.)
 134 define_alias( qr/^(.+)\@euro$/i => '"$1"' );
 135
 136 # Allow latin-1 style names as well
 137 define_alias( qr/^(?:iso[-_]?)?latin[-_]?(\d+)$/i => '"iso-8859-$latin2iso_num[$1]"' );
 138
 139 # Allow winlatin1 style names as well
 140 define_alias( qr/^win(latin[12]|cyrillic|baltic|greek|turkish|hebrew|arabic|baltic|vietnamese)$/i => '"cp$winlatin2cp{\u$1}"' );
 141
 142 # Common names for non-latin prefered MIME names
 143 define_alias( 'ascii'    => 'US-ascii',
 144               'cyrillic' => 'iso-8859-5',
 145               'arabic'   => 'iso-8859-6',
 146               'greek'    => 'iso-8859-7',
 147               'hebrew'   => 'iso-8859-8',
 148               'thai'     => 'iso-8859-11',
 149               'tis620'   => 'iso-8859-11',
 150             );
 151
 152 # At least AIX has IBM-NNN (surprisingly...) instead of cpNNN.
 153 # And Microsoft has their own naming (again, surprisingly).
 154 define_alias( qr/^(?:ibm|ms)[-_]?(\d\d\d\d?)$/i => '"cp$1"');
 155
 156 # Sometimes seen with a leading zero.
 157 define_alias( qr/^cp037$/i => '"cp37"');
 158
 159 # Ououououou.
 160 define_alias( qr/^macRomanian$/i => '"macRumanian"');
 161
 162 # Standardize on the dashed versions.
 163 define_alias( qr/^utf8$/i  => 'utf-8' );
 164 define_alias( qr/^koi8r$/i => 'koi8-r' );
 165 define_alias( qr/^koi8u$/i => 'koi8-u' );
 166
 167 # Seen in some Linuxes.
 168 define_alias( qr/^ujis$/i => 'euc-jp' );
 169
 170 # TODO: HP-UX '8' encodings arabic8 greek8 hebrew8 kana8 thai8 turkish8
 171 # TODO: HP-UX '15' encodings japanese15 korean15 roi15
 172 # TODO: Cyrillic encoding ISO-IR-111 (useful?)
 173 # TODO: Chinese encodings GB18030 EUC-TW HZ
 174 # TODO: Armenian encoding ARMSCII-8
 175 # TODO: Hebrew encoding ISO-8859-8-1
 176 # TODO: Thai encoding TCVN
 177 # TODO: Korean encoding Johab
 178 # TODO: Vietnamese encodings VPS
 179 # TODO: Japanese encoding JIS (not the same as SJIS)
 180 # TODO: Mac Asian+African encodings: Arabic Armenian Bengali Burmese
 181 #       ChineseSimp ChineseTrad Devanagari Ethiopic ExtArabic
 182 #       Farsi Georgian Gujarati Gurmukhi Hebrew Japanese
 183 #       Kannada Khmer Korean Laotian Malayalam Mongolian
 184 #       Oriya Sinhalese Symbol Tamil Telugu Tibetan Vietnamese
 185
 186 # Map white space and _ to '-'
 187 define_alias( qr/^(\S+)[\s_]+(.*)$/i => '"$1-$2"' );
 188
 189 sub define_encoding
 190 {
 191     my $obj  = shift;
 192     my $name = shift;
 193     $encoding{$name} = $obj;
 194     my $lc = lc($name);
 195     define_alias($lc => $obj) unless $lc eq $name;
 196     while (@_)
 197     {
 198         my $alias = shift;
 199         define_alias($alias,$obj);
 200     }
 201     return $obj;
 202 }
 203
 204 sub getEncoding
 205 {
 206     my ($class,$name) = @_;
 207     my $enc;
 208     if (ref($name) && $name->can('new_sequence'))
 209     {
 210         return $name;
 211     }
 212     my $lc = lc $name;
 213     if (exists $encoding{$name})
 214     {
 215         return $encoding{$name};
 216     }
 217     if (exists $encoding{$lc})
 218     {
 219         return $encoding{$lc};
 220     }
 221
 222     my $oc = $class->findAlias($name);
 223     return $oc if defined $oc;
 224     return $class->findAlias($lc) if $lc ne $name;
 225
 226     return;
 227 }
 228
 229 sub find_encoding
 230 {
 231     my ($name) = @_;
 232     return __PACKAGE__->getEncoding($name);
 233 }
 234
 235 sub encode
 236 {
 237     my ($name,$string,$check) = @_;
 238     my $enc = find_encoding($name);
 239     croak("Unknown encoding '$name'") unless defined $enc;
 240     my $octets = $enc->encode($string,$check);
 241     return undef if ($check && length($string));
 242     return $octets;
 243 }
 244
 245 sub decode
 246 {
 247     my ($name,$octets,$check) = @_;
 248     my $enc = find_encoding($name);
 249     croak("Unknown encoding '$name'") unless defined $enc;
 250     my $string = $enc->decode($octets,$check);
 251     $_[1] = $octets if $check;
 252     return $string;
 253 }
 254
 255 sub from_to
 256 {
 257     my ($string,$from,$to,$check) = @_;
 258     my $f = find_encoding($from);
 259     croak("Unknown encoding '$from'") unless defined $f;
 260     my $t = find_encoding($to);
 261     croak("Unknown encoding '$to'") unless defined $t;
 262     my $uni = $f->decode($string,$check);
 263     return undef if ($check && length($string));
 264     $string = $t->encode($uni,$check);
 265     return undef if ($check && length($uni));
 266     return length($_[0] = $string);
 267 }
 268
 269 sub encode_utf8
 270 {
 271     my ($str) = @_;
 272   utf8::encode($str);
 273     return $str;
 274 }
 275
 276 sub decode_utf8
 277 {
 278     my ($str) = @_;
 279     return undef unless utf8::decode($str);
 280     return $str;
 281 }
 282
 283 require Encode::Encoding;
 284 require Encode::XS;
 285 require Encode::Internal;
 286 require Encode::Unicode;
 287 require Encode::utf8;
 288 require Encode::iso10646_1;
 289 require Encode::ucs2_le;
 290
 291 1;
 292
 293 __END__
 294
 295 =head1 NAME
 296
 297 Encode - character encodings
 298
 299 =head1 SYNOPSIS
 300
 301     use Encode;
 302
 303     use Encode::TW; # for Taiwan-based Chinese encodings
 304     use Encode::CN; # for China-based Chinese encodings
 305     use Encode::JP; # for Japanese encodings
 306     use Encode::KR; # for Korean encodings
 307
 308 =head1 DESCRIPTION
 309
 310 The C<Encode> module provides the interfaces between Perl's strings
 311 and the rest of the system.  Perl strings are sequences of B<characters>.
 312
 313 The repertoire of characters that Perl can represent is at least that
 314 defined by the Unicode Consortium. On most platforms the ordinal
 315 values of the characters (as returned by C<ord(ch)>) is the "Unicode
 316 codepoint" for the character (the exceptions are those platforms where
 317 the legacy encoding is some variant of EBCDIC rather than a super-set
 318 of ASCII - see L<perlebcdic>).
 319
 320 Traditionaly computer data has been moved around in 8-bit chunks
 321 often called "bytes". These chunks are also known as "octets" in
 322 networking standards. Perl is widely used to manipulate data of
 323 many types - not only strings of characters representing human or
 324 computer languages but also "binary" data being the machines representation
 325 of numbers, pixels in an image - or just about anything.
 326
 327 When Perl is processing "binary data" the programmer wants Perl to process
 328 "sequences of bytes". This is not a problem for Perl - as a byte has 256
 329 possible values it easily fits in Perl's much larger "logical character".
 330
 331 Due to size concerns, before using B<CJK> (Chinese, Japanese & Korean)
 332 encodings, you have to C<use> the corresponding
 333 B<Encode::>(B<TW>|B<CN>|B<JP>|B<KR>) modules first.
 334
 335 =head2 TERMINOLOGY
 336
 337 =over 4
 338
 339 =item *
 340
 341 I<character>: a character in the range 0..(2**32-1) (or more).
 342 (What Perl's strings are made of.)
 343
 344 =item *
 345
 346 I<byte>: a character in the range 0..255
 347 (A special case of a Perl character.)
 348
 349 =item *
 350
 351 I<octet>: 8 bits of data, with ordinal values 0..255
 352 (Term for bytes passed to or from a non-Perl context, e.g. disk file.)
 353
 354 =back
 355
 356 The marker [INTERNAL] marks Internal Implementation Details, in
 357 general meant only for those who think they know what they are doing,
 358 and such details may change in future releases.
 359
 360 =head1 ENCODINGS
 361
 362 =head2 Characteristics of an Encoding
 363
 364 An encoding has a "repertoire" of characters that it can represent,
 365 and for each representable character there is at least one sequence of
 366 octets that represents it.
 367
 368 =head2 Types of Encodings
 369
 370 Encodings can be divided into the following types:
 371
 372 =over 4
 373
 374 =item * Fixed length 8-bit (or less) encodings.
 375
 376 Each character is a single octet so may have a repertoire of up to
 377 256 characters. ASCII and iso-8859-* are typical examples.
 378
 379 =item * Fixed length 16-bit encodings
 380
 381 Each character is two octets so may have a repertoire of up to
 382 65 536 characters.  Unicode's UCS-2 is an example.  Also used for
 383 encodings for East Asian languages.
 384
 385 =item * Fixed length 32-bit encodings.
 386
 387 Not really very "encoded" encodings. The Unicode code points
 388 are just represented as 4-octet integers. None the less because
 389 different architectures use different representations of integers
 390 (so called "endian") there at least two disctinct encodings.
 391
 392 =item * Multi-byte encodings
 393
 394 The number of octets needed to represent a character varies.
 395 UTF-8 is a particularly complex but regular case of a multi-byte
 396 encoding. Several East Asian countries use a multi-byte encoding
 397 where 1-octet is used to cover western roman characters and Asian
 398 characters get 2-octets.
 399 (UTF-16 is strictly a multi-byte encoding taking either 2 or 4 octets
 400 to represent a Unicode code point.)
 401
 402 =item * "Escape" encodings.
 403
 404 These encodings embed "escape sequences" into the octet sequence
 405 which describe how the following octets are to be interpreted.
 406 The iso-2022-* family is typical. Following the escape sequence
 407 octets are encoded by an "embedded" encoding (which will be one
 408 of the above types) until another escape sequence switches to
 409 a different "embedded" encoding.
 410
 411 These schemes are very flexible and can handle mixed languages but are
 412 very complex to process (and have state).  No escape encodings are
 413 implemented for Perl yet.
 414
 415 =back
 416
 417 =head2 Specifying Encodings
 418
 419 Encodings can be specified to the API described below in two ways:
 420
 421 =over 4
 422
 423 =item 1. By name
 424
 425 Encoding names are strings with characters taken from a restricted
 426 repertoire.  See L</"Encoding Names">.
 427
 428 =item 2. As an object
 429
 430 Encoding objects are returned by C<find_encoding($name)>.
 431
 432 =back
 433
 434 =head2 Encoding Names
 435
 436 Encoding names are case insensitive. White space in names is ignored.
 437 In addition an encoding may have aliases. Each encoding has one
 438 "canonical" name.  The "canonical" name is chosen from the names of
 439 the encoding by picking the first in the following sequence:
 440
 441 =over 4
 442
 443 =item * The MIME name as defined in IETF RFCs.
 444
 445 =item * The name in the IANA registry.
 446
 447 =item * The name used by the organization that defined it.
 448
 449 =back
 450
 451 Because of all the alias issues, and because in the general case
 452 encodings have state C<Encode> uses the encoding object internally
 453 once an operation is in progress.
 454
 455 As of Perl 5.8.0, at least the following encodings are recognized
 456 (the => marks aliases):
 457
 458   ASCII
 459
 460   US-ASCII => ASCII
 461
 462 The Unicode:
 463
 464   UTF-8
 465   UTF-16
 466   UCS-2
 467
 468   ISO 10646-1 => UCS-2
 469
 470 The ISO 8859 and KOI:
 471
 472   ISO 8859-1  ISO 8859-6   ISO 8859-11         KOI8-F
 473   ISO 8859-2  ISO 8859-7   (12 doesn't exist)  KOI8-R
 474   ISO 8859-3  ISO 8859-8   ISO 8859-13         KOI8-U
 475   ISO 8859-4  ISO 8859-9   ISO 8859-14
 476   ISO 8859-5  ISO 8859-10  ISO 8859-15
 477                            ISO 8859-16
 478
 479   Latin1  => 8859-1  Latin6  => 8859-10
 480   Latin2  => 8859-2  Latin7  => 8859-13
 481   Latin3  => 8859-3  Latin8  => 8859-14
 482   Latin4  => 8859-4  Latin9  => 8859-15
 483   Latin5  => 8859-9  Latin10 => 8859-16
 484
 485   Cyrillic => 8859-5
 486   Arabic   => 8859-6
 487   Greek    => 8859-7
 488   Hebrew   => 8859-8
 489   Thai     => 8859-11
 490   TIS620   => 8859-11
 491
 492 The CJKV: Chinese, Japanese, Korean, Vietnamese:
 493
 494   ISO 2022     ISO 2022 JP-1  JIS 0201  GB 1988   Big5       EUC-CN
 495   ISO 2022 CN  ISO 2022 JP-2  JIS 0208  GB 2312   HZ         EUC-JP
 496   ISO 2022 JP  ISO 2022 KR    JIS 0210  GB 12345  CNS 11643  EUC-JP-0212
 497   Shift-JIS                             GBK       Big5-HKSCS EUC-KR
 498   VISCII                                ISO-IR-165
 499
 500 (Due to size concerns, additional Chinese encodings including C<GB 18030>,
 501 C<EUC-TW> and C<BIG5PLUS> are distributed separately on CPAN, under the name
 502 L<Encode::HanExtra>.)
 503
 504 The PC codepages:
 505
 506   CP37   CP852  CP861  CP866  CP949   CP1251  CP1256
 507   CP424  CP855  CP862  CP869  CP950   CP1252  CP1257
 508   CP737  CP856  CP863  CP874  CP1006  CP1253  CP1258
 509   CP775  CP857  CP864  CP932  CP1047  CP1254
 510   CP850  CP860  CP865  CP936  CP1250  CP1255
 511
 512   WinLatin1     => CP1252
 513   WinLatin2     => CP1250
 514   WinCyrillic   => CP1251
 515   WinGreek      => CP1253
 516   WinTurkiskh   => CP1254
 517   WinHebrew     => CP1255
 518   WinArabic     => CP1256
 519   WinBaltic     => CP1257
 520   WinVietnamese => CP1258
 521
 522 (All the CPI<NNN...> are available also as IBMI<NNN...>.)
 523
 524 The Mac codepages:
 525
 526   MacCentralEuropean   MacJapanese
 527   MacCroatian          MacRoman
 528   MacCyrillic          MacRomanian
 529   MacDingbats          MacSami
 530   MacGreek             MacThai
 531   MacIcelandic         MacTurkish
 532                        MacUkraine
 533
 534 Miscellaneous:
 535
 536   7bit-greek  IR-197
 537   7bit-kana   NeXTstep
 538   7bit-latin1 POSIX-BC
 539   DingBats    Roman8
 540   GSM 0338    Symbol
 541
 542 =head1 PERL ENCODING API
 543
 544 =head2 Generic Encoding Interface
 545
 546 =over 4
 547
 548 =item *
 549
 550         $bytes  = encode(ENCODING, $string[, CHECK])
 551
 552 Encodes string from Perl's internal form into I<ENCODING> and returns
 553 a sequence of octets.  For CHECK see L</"Handling Malformed Data">.
 554
 555 For example to convert (internally UTF-8 encoded) Unicode data
 556 to octets:
 557
 558         $octets = encode("utf8", $unicode);
 559
 560 =item *
 561
 562         $string = decode(ENCODING, $bytes[, CHECK])
 563
 564 Decode sequence of octets assumed to be in I<ENCODING> into Perl's
 565 internal form and returns the resulting string.  For CHECK see
 566 L</"Handling Malformed Data">.
 567
 568 For example to convert ISO 8859-1 data to UTF-8:
 569
 570         $utf8 = decode("latin1", $latin1);
 571
 572 =item *
 573
 574         from_to($string, FROM_ENCODING, TO_ENCODING[, CHECK])
 575
 576 Convert B<in-place> the data between two encodings.  How did the data
 577 in $string originally get to be in FROM_ENCODING?  Either using
 578 encode() or through PerlIO: See L</"Encoding and IO">.  For CHECK
 579 see L</"Handling Malformed Data">.
 580
 581 For example to convert ISO 8859-1 data to UTF-8:
 582
 583         from_to($data, "iso-8859-1", "utf-8");
 584
 585 and to convert it back:
 586
 587         from_to($data, "utf-8", "iso-8859-1");
 588
 589 Note that because the conversion happens in place, the data to be
 590 converted cannot be a string constant, it must be a scalar variable.
 591
 592 =back
 593
 594 =head2 Handling Malformed Data
 595
 596 If CHECK is not set, C<undef> is returned.  If the data is supposed to
 597 be UTF-8, an optional lexical warning (category utf8) is given.  If
 598 CHECK is true but not a code reference, dies.
 599
 600 It would desirable to have a way to indicate that transform should use
 601 the encodings "replacement character" - no such mechanism is defined yet.
 602
 603 It is also planned to allow I<CHECK> to be a code reference.
 604
 605 This is not yet implemented as there are design issues with what its
 606 arguments should be and how it returns its results.
 607
 608 =over 4
 609
 610 =item Scheme 1
 611
 612 Passed remaining fragment of string being processed.
 613 Modifies it in place to remove bytes/characters it can understand
 614 and returns a string used to represent them.
 615 e.g.
 616
 617  sub fixup {
 618    my $ch = substr($_[0],0,1,'');
 619    return sprintf("\x{%02X}",ord($ch);
 620  }
 621
 622 This scheme is close to how underlying C code for Encode works, but gives
 623 the fixup routine very little context.
 624
 625 =item Scheme 2
 626
 627 Passed original string, and an index into it of the problem area, and
 628 output string so far.  Appends what it will to output string and
 629 returns new index into original string.  For example:
 630
 631  sub fixup {
 632    # my ($s,$i,$d) = @_;
 633    my $ch = substr($_[0],$_[1],1);
 634    $_[2] .= sprintf("\x{%02X}",ord($ch);
 635    return $_[1]+1;
 636  }
 637
 638 This scheme gives maximal control to the fixup routine but is more
 639 complicated to code, and may need internals of Encode to be tweaked to
 640 keep original string intact.
 641
 642 =item Other Schemes
 643
 644 Hybrids of above.
 645
 646 Multiple return values rather than in-place modifications.
 647
 648 Index into the string could be pos($str) allowing s/\G...//.
 649
 650 =back
 651
 652 =head2 UTF-8 / utf8
 653
 654 The Unicode consortium defines the UTF-8 standard as a way of encoding
 655 the entire Unicode repertiore as sequences of octets.  This encoding is
 656 expected to become very widespread. Perl can use this form internaly
 657 to represent strings, so conversions to and from this form are
 658 particularly efficient (as octets in memory do not have to change,
 659 just the meta-data that tells Perl how to treat them).
 660
 661 =over 4
 662
 663 =item *
 664
 665         $bytes = encode_utf8($string);
 666
 667 The characters that comprise string are encoded in Perl's superset of UTF-8
 668 and the resulting octets returned as a sequence of bytes. All possible
 669 characters have a UTF-8 representation so this function cannot fail.
 670
 671 =item *
 672
 673         $string = decode_utf8($bytes [,CHECK]);
 674
 675 The sequence of octets represented by $bytes is decoded from UTF-8
 676 into a sequence of logical characters. Not all sequences of octets
 677 form valid UTF-8 encodings, so it is possible for this call to fail.
 678 For CHECK see L</"Handling Malformed Data">.
 679
 680 =back
 681
 682 =head2 Other Encodings of Unicode
 683
 684 UTF-16 is similar to UCS-2, 16 bit or 2-byte chunks.  UCS-2 can only
 685 represent 0..0xFFFF, while UTF-16 has a I<surrogate pair> scheme which
 686 allows it to cover the whole Unicode range.
 687
 688 Surrogates are code points set aside to encode the 0x01000..0x10FFFF
 689 range of Unicode code points in pairs of 16-bit units.  The I<high
 690 surrogates> are the range 0xD800..0xDBFF, and the I<low surrogates>
 691 are the range 0xDC00..0xDFFFF.  The surrogate encoding is
 692
 693         $hi = ($uni - 0x10000) / 0x400 + 0xD800;
 694         $lo = ($uni - 0x10000) % 0x400 + 0xDC00;
 695
 696 and the decoding is
 697
 698         $uni = 0x10000 + ($hi - 0xD8000) * 0x400 + ($lo - 0xDC00);
 699
 700 Encode implements big-endian UCS-2 aliased to "iso-10646-1" as that
 701 happens to be the name used by that representation when used with X11
 702 fonts.
 703
 704 UTF-32 or UCS-4 is 32-bit or 4-byte chunks.  Perl's logical characters
 705 can be considered as being in this form without encoding. An encoding
 706 to transfer strings in this form (e.g. to write them to a file) would
 707 need to
 708
 709      pack('L*', unpack('U*', $string));  # native
 710   or
 711      pack('V*', unpack('U*', $string));  # little-endian
 712   or
 713      pack('N*', unpack('U*', $string));  # big-endian
 714
 715 depending on the endianness required.
 716
 717 No UTF-32 encodings are implemented yet.
 718
 719 Both UCS-2 and UCS-4 style encodings can have "byte order marks" by
 720 representing the code point 0xFFFE as the very first thing in a file.
 721
 722 =head2 Listing available encodings
 723
 724   use Encode qw(encodings);
 725   @list = encodings();
 726
 727 Returns a list of the canonical names of the available encodings.
 728
 729 =head2 Defining Aliases
 730
 731   use Encode qw(define_alias);
 732   define_alias( newName => ENCODING);
 733
 734 Allows newName to be used as am alias for ENCODING. ENCODING may be
 735 either the name of an encoding or and encoding object (as above).
 736
 737 Currently I<newName> can be specified in the following ways:
 738
 739 =over 4
 740
 741 =item As a simple string.
 742
 743 =item As a qr// compiled regular expression, e.g.:
 744
 745   define_alias( qr/^iso8859-(\d+)$/i => '"iso-8859-$1"' );
 746
 747 In this case if I<ENCODING> is not a reference it is C<eval>-ed to
 748 allow C<$1> etc. to be subsituted.  The example is one way to names as
 749 used in X11 font names to alias the MIME names for the iso-8859-*
 750 family.
 751
 752 =item As a code reference, e.g.:
 753
 754   define_alias( sub { return /^iso8859-(\d+)$/i ? "iso-8859-$1" : undef } , '');
 755
 756 In this case C<$_> will be set to the name that is being looked up and
 757 I<ENCODING> is passed to the sub as its first argument.  The example
 758 is another way to names as used in X11 font names to alias the MIME
 759 names for the iso-8859-* family.
 760
 761 =back
 762
 763 =head2 Defining Encodings
 764
 765     use Encode qw(define_alias);
 766     define_encoding( $object, 'canonicalName' [,alias...]);
 767
 768 Causes I<canonicalName> to be associated with I<$object>.  The object
 769 should provide the interface described in L</"IMPLEMENTATION CLASSES">
 770 below.  If more than two arguments are provided then additional
 771 arguments are taken as aliases for I<$object> as for C<define_alias>.
 772
 773 =head1 Encoding and IO
 774
 775 It is very common to want to do encoding transformations when
 776 reading or writing files, network connections, pipes etc.
 777 If Perl is configured to use the new 'perlio' IO system then
 778 C<Encode> provides a "layer" (See L<perliol>) which can transform
 779 data as it is read or written.
 780
 781 Here is how the blind poet would modernise the encoding:
 782
 783     use Encode;
 784     open(my $iliad,'<:encoding(iso-8859-7)','iliad.greek');
 785     open(my $utf8,'>:utf8','iliad.utf8');
 786     my @epic = <$iliad>;
 787     print $utf8 @epic;
 788     close($utf8);
 789     close($illiad);
 790
 791 In addition the new IO system can also be configured to read/write
 792 UTF-8 encoded characters (as noted above this is efficient):
 793
 794     open(my $fh,'>:utf8','anything');
 795     print $fh "Any \x{0021} string \N{SMILEY FACE}\n";
 796
 797 Either of the above forms of "layer" specifications can be made the default
 798 for a lexical scope with the C<use open ...> pragma. See L<open>.
 799
 800 Once a handle is open is layers can be altered using C<binmode>.
 801
 802 Without any such configuration, or if Perl itself is built using
 803 system's own IO, then write operations assume that file handle accepts
 804 only I<bytes> and will C<die> if a character larger than 255 is
 805 written to the handle. When reading, each octet from the handle
 806 becomes a byte-in-a-character. Note that this default is the same
 807 behaviour as bytes-only languages (including Perl before v5.6) would
 808 have, and is sufficient to handle native 8-bit encodings
 809 e.g. iso-8859-1, EBCDIC etc. and any legacy mechanisms for handling
 810 other encodings and binary data.
 811
 812 In other cases it is the programs responsibility to transform
 813 characters into bytes using the API above before doing writes, and to
 814 transform the bytes read from a handle into characters before doing
 815 "character operations" (e.g. C<lc>, C</\W+/>, ...).
 816
 817 You can also use PerlIO to convert larger amounts of data you don't
 818 want to bring into memory.  For example to convert between ISO 8859-1
 819 (Latin 1) and UTF-8 (or UTF-EBCDIC in EBCDIC machines):
 820
 821     open(F, "<:encoding(iso-8859-1)", "data.txt") or die $!;
 822     open(G, ">:utf8",                 "data.utf") or die $!;
 823     while (<F>) { print G }
 824
 825     # Could also do "print G <F>" but that would pull
 826     # the whole file into memory just to write it out again.
 827
 828 More examples:
 829
 830     open(my $f, "<:encoding(cp1252)")
 831     open(my $g, ">:encoding(iso-8859-2)")
 832     open(my $h, ">:encoding(latin9)")       # iso-8859-15
 833
 834 See L<PerlIO> for more information.
 835
 836 See also L<encoding> for how to change the default encoding of the
 837 data in your script.
 838
 839 =head1 Encoding How to ...
 840
 841 To do:
 842
 843 =over 4
 844
 845 =item * IO with mixed content (faking iso-2020-*)
 846
 847 =item * MIME's Content-Length:
 848
 849 =item * UTF-8 strings in binary data.
 850
 851 =item * Perl/Encode wrappers on non-Unicode XS modules.
 852
 853 =back
 854
 855 =head1 Messing with Perl's Internals
 856
 857 The following API uses parts of Perl's internals in the current
 858 implementation.  As such they are efficient, but may change.
 859
 860 =over 4
 861
 862 =item * is_utf8(STRING [, CHECK])
 863
 864 [INTERNAL] Test whether the UTF-8 flag is turned on in the STRING.
 865 If CHECK is true, also checks the data in STRING for being well-formed
 866 UTF-8.  Returns true if successful, false otherwise.
 867
 868 =item * valid_utf8(STRING)
 869
 870 [INTERNAL] Test whether STRING is in a consistent state.  Will return
 871 true if string is held as bytes, or is well-formed UTF-8 and has the
 872 UTF-8 flag on.  Main reason for this routine is to allow Perl's
 873 testsuite to check that operations have left strings in a consistent
 874 state.
 875
 876 =item *
 877
 878         _utf8_on(STRING)
 879
 880 [INTERNAL] Turn on the UTF-8 flag in STRING.  The data in STRING is
 881 B<not> checked for being well-formed UTF-8.  Do not use unless you
 882 B<know> that the STRING is well-formed UTF-8.  Returns the previous
 883 state of the UTF-8 flag (so please don't test the return value as
 884 I<not> success or failure), or C<undef> if STRING is not a string.
 885
 886 =item *
 887
 888         _utf8_off(STRING)
 889
 890 [INTERNAL] Turn off the UTF-8 flag in STRING.  Do not use frivolously.
 891 Returns the previous state of the UTF-8 flag (so please don't test the
 892 return value as I<not> success or failure), or C<undef> if STRING is
 893 not a string.
 894
 895 =back
 896
 897 =head1 IMPLEMENTATION CLASSES
 898
 899 As mentioned above encodings are (in the current implementation at least)
 900 defined by objects. The mapping of encoding name to object is via the
 901 C<%encodings> hash.
 902
 903 The values of the hash can currently be either strings or objects.
 904 The string form may go away in the future. The string form occurs
 905 when C<encodings()> has scanned C<@INC> for loadable encodings but has
 906 not actually loaded the encoding in question. This is because the
 907 current "loading" process is all Perl and a bit slow.
 908
 909 Once an encoding is loaded then value of the hash is object which
 910 implements the encoding. The object should provide the following
 911 interface:
 912
 913 =over 4
 914
 915 =item -E<gt>name
 916
 917 Should return the string representing the canonical name of the encoding.
 918
 919 =item -E<gt>new_sequence
 920
 921 This is a placeholder for encodings with state. It should return an
 922 object which implements this interface, all current implementations
 923 return the original object.
 924
 925 =item -E<gt>encode($string,$check)
 926
 927 Should return the octet sequence representing I<$string>. If I<$check>
 928 is true it should modify I<$string> in place to remove the converted
 929 part (i.e.  the whole string unless there is an error).  If an error
 930 occurs it should return the octet sequence for the fragment of string
 931 that has been converted, and modify $string in-place to remove the
 932 converted part leaving it starting with the problem fragment.
 933
 934 If check is is false then C<encode> should make a "best effort" to
 935 convert the string - for example by using a replacement character.
 936
 937 =item -E<gt>decode($octets,$check)
 938
 939 Should return the string that I<$octets> represents. If I<$check> is
 940 true it should modify I<$octets> in place to remove the converted part
 941 (i.e.  the whole sequence unless there is an error).  If an error
 942 occurs it should return the fragment of string that has been
 943 converted, and modify $octets in-place to remove the converted part
 944 leaving it starting with the problem fragment.
 945
 946 If check is is false then C<decode> should make a "best effort" to
 947 convert the string - for example by using Unicode's "\x{FFFD}" as a
 948 replacement character.
 949
 950 =back
 951
 952 It should be noted that the check behaviour is different from the
 953 outer public API. The logic is that the "unchecked" case is useful
 954 when encoding is part of a stream which may be reporting errors
 955 (e.g. STDERR).  In such cases it is desirable to get everything
 956 through somehow without causing additional errors which obscure the
 957 original one. Also the encoding is best placed to know what the
 958 correct replacement character is, so if that is the desired behaviour
 959 then letting low level code do it is the most efficient.
 960
 961 In contrast if check is true, the scheme above allows the encoding to
 962 do as much as it can and tell layer above how much that was. What is
 963 lacking at present is a mechanism to report what went wrong. The most
 964 likely interface will be an additional method call to the object, or
 965 perhaps (to avoid forcing per-stream objects on otherwise stateless
 966 encodings) and additional parameter.
 967
 968 It is also highly desirable that encoding classes inherit from
 969 C<Encode::Encoding> as a base class. This allows that class to define
 970 additional behaviour for all encoding objects. For example built in
 971 Unicode, UCS-2 and UTF-8 classes use :
 972
 973   package Encode::MyEncoding;
 974   use base qw(Encode::Encoding);
 975
 976   __PACKAGE__->Define(qw(myCanonical myAlias));
 977
 978 To create an object with bless {Name => ...},$class, and call
 979 define_encoding.  They inherit their C<name> method from
 980 C<Encode::Encoding>.
 981
 982 =head2 Compiled Encodings
 983
 984 F<Encode.xs> provides a class C<Encode::XS> which provides the
 985 interface described above. It calls a generic octet-sequence to
 986 octet-sequence "engine" that is driven by tables (defined in
 987 F<encengine.c>). The same engine is used for both encode and
 988 decode. C<Encode:XS>'s C<encode> forces Perl's characters to their
 989 UTF-8 form and then treats them as just another multibyte
 990 encoding. C<Encode:XS>'s C<decode> transforms the sequence and then
 991 turns the UTF-8-ness flag as that is the form that the tables are
 992 defined to produce. For details of the engine see the comments in
 993 F<encengine.c>.
 994
 995 The tables are produced by the Perl script F<compile> (the name needs
 996 to change so we can eventually install it somewhere). F<compile> can
 997 currently read two formats:
 998
 999 =over 4
1000
1001 =item *.enc
1002
1003 This is a coined format used by Tcl. It is documented in
1004 Encode/EncodeFormat.pod.
1005
1006 =item *.ucm
1007
1008 This is the semi-standard format used by IBM's ICU package.
1009
1010 =back
1011
1012 F<compile> can write the following forms:
1013
1014 =over 4
1015
1016 =item *.ucm
1017
1018 See above - the F<Encode/*.ucm> files provided with the distribution have
1019 been created from the original Tcl .enc files using this approach.
1020
1021 =item *.c
1022
1023 Produces tables as C data structures - this is used to build in encodings
1024 into F<Encode.so>/F<Encode.dll>.
1025
1026 =item *.xs
1027
1028 In theory this allows encodings to be stand-alone loadable Perl
1029 extensions.  The process has not yet been tested. The plan is to use
1030 this approach for large East Asian encodings.
1031
1032 =back
1033
1034 The set of encodings built-in to F<Encode.so>/F<Encode.dll> is
1035 determined by F<Makefile.PL>.  The current set is as follows:
1036
1037 =over 4
1038
1039 =item ascii and iso-8859-*
1040
1041 That is all the common 8-bit "western" encodings.
1042
1043 =item IBM-1047 and two other variants of EBCDIC.
1044
1045 These are the same variants that are supported by EBCDIC Perl as
1046 "native" encodings.  They are included to prove "reversibility" of
1047 some constructs in EBCDIC Perl.
1048
1049 =item symbol and dingbats as used by Tk on X11.
1050
1051 (The reason Encode got started was to support Perl/Tk.)
1052
1053 =back
1054
1055 That set is rather ad hoc and has been driven by the needs of the
1056 tests rather than the needs of typical applications. It is likely
1057 to be rationalized.
1058
1059 =head1 SEE ALSO
1060
1061 L<perlunicode>, L<perlebcdic>, L<perlfunc/open>, L<PerlIO>, L<encoding>
1062
1063 =cut
1064