ext/Encode/Encode.pm

   1 #
   2 # $Id: Encode.pm,v 1.92 2003/03/31 03:46:47 dankogai Exp $
   3 #
   4 package Encode;
   5 use strict;
   6 our $VERSION = do { my @r = (q$Revision: 1.92 $ =~ /\d+/g); sprintf "%d."."%02d" x $#r, @r };
   7 our $DEBUG = 0;
   8 use XSLoader ();
   9 XSLoader::load(__PACKAGE__, $VERSION);
  10
  11 require Exporter;
  12 use base qw/Exporter/;
  13
  14 # Public, encouraged API is exported by default
  15
  16 our @EXPORT = qw(
  17   decode  decode_utf8  encode  encode_utf8
  18   encodings  find_encoding
  19 );
  20
  21 our @FB_FLAGS  = qw(DIE_ON_ERR WARN_ON_ERR RETURN_ON_ERR LEAVE_SRC
  22                     PERLQQ HTMLCREF XMLCREF);
  23 our @FB_CONSTS = qw(FB_DEFAULT FB_CROAK FB_QUIET FB_WARN
  24                     FB_PERLQQ FB_HTMLCREF FB_XMLCREF);
  25
  26 our @EXPORT_OK =
  27     (
  28      qw(
  29        _utf8_off _utf8_on define_encoding from_to is_16bit is_8bit
  30        is_utf8 perlio_ok resolve_alias utf8_downgrade utf8_upgrade
  31       ),
  32      @FB_FLAGS, @FB_CONSTS,
  33     );
  34
  35 our %EXPORT_TAGS =
  36     (
  37      all          =>  [ @EXPORT, @EXPORT_OK ],
  38      fallbacks    =>  [ @FB_CONSTS ],
  39      fallback_all =>  [ @FB_CONSTS, @FB_FLAGS ],
  40     );
  41
  42 # Documentation moved after __END__ for speed - NI-S
  43
  44 our $ON_EBCDIC = (ord("A") == 193);
  45
  46 use Encode::Alias;
  47
  48 # Make a %Encoding package variable to allow a certain amount of cheating
  49 our %Encoding;
  50 our %ExtModule;
  51 require Encode::Config;
  52 eval { require Encode::ConfigLocal };
  53
  54 sub encodings
  55 {
  56     my $class = shift;
  57     my %enc;
  58     if (@_ and $_[0] eq ":all"){
  59         %enc = ( %Encoding, %ExtModule );
  60     }else{
  61         %enc = %Encoding;
  62         for my $mod (map {m/::/o ? $_ : "Encode::$_" } @_){
  63             $DEBUG and warn $mod;
  64             for my $enc (keys %ExtModule){
  65                 $ExtModule{$enc} eq $mod and $enc{$enc} = $mod;
  66             }
  67         }
  68     }
  69     return
  70         sort { lc $a cmp lc $b }
  71              grep {!/^(?:Internal|Unicode|Guess)$/o} keys %enc;
  72 }
  73
  74 sub perlio_ok{
  75     my $obj = ref($_[0]) ? $_[0] : find_encoding($_[0]);
  76     $obj->can("perlio_ok") and return $obj->perlio_ok();
  77     return 0; # safety net
  78 }
  79
  80 sub define_encoding
  81 {
  82     my $obj  = shift;
  83     my $name = shift;
  84     $Encoding{$name} = $obj;
  85     my $lc = lc($name);
  86     define_alias($lc => $obj) unless $lc eq $name;
  87     while (@_){
  88         my $alias = shift;
  89         define_alias($alias, $obj);
  90     }
  91     return $obj;
  92 }
  93
  94 sub getEncoding
  95 {
  96     my ($class, $name, $skip_external) = @_;
  97
  98     ref($name) && $name->can('new_sequence') and return $name;
  99     exists $Encoding{$name} and return $Encoding{$name};
 100     my $lc = lc $name;
 101     exists $Encoding{$lc} and return $Encoding{$lc};
 102
 103     my $oc = $class->find_alias($name);
 104     defined($oc) and return $oc;
 105     $lc ne $name and $oc = $class->find_alias($lc);
 106     defined($oc) and return $oc;
 107
 108     unless ($skip_external)
 109     {
 110         if (my $mod = $ExtModule{$name} || $ExtModule{$lc}){
 111             $mod =~ s,::,/,g ; $mod .= '.pm';
 112             eval{ require $mod; };
 113             exists $Encoding{$name} and return $Encoding{$name};
 114         }
 115     }
 116     return;
 117 }
 118
 119 sub find_encoding
 120 {
 121     my ($name, $skip_external) = @_;
 122     return __PACKAGE__->getEncoding($name,$skip_external);
 123 }
 124
 125 sub resolve_alias {
 126     my $obj = find_encoding(shift);
 127     defined $obj and return $obj->name;
 128     return;
 129 }
 130
 131 sub encode($$;$)
 132 {
 133     my ($name, $string, $check) = @_;
 134     return undef unless defined $string;
 135     $check ||=0;
 136     my $enc = find_encoding($name);
 137     unless(defined $enc){
 138         require Carp;
 139         Carp::croak("Unknown encoding '$name'");
 140     }
 141     my $octets = $enc->encode($string,$check);
 142     return undef if ($check && length($string));
 143     return $octets;
 144 }
 145
 146 sub decode($$;$)
 147 {
 148     my ($name,$octets,$check) = @_;
 149     return undef unless defined $octets;
 150     $check ||=0;
 151     my $enc = find_encoding($name);
 152     unless(defined $enc){
 153         require Carp;
 154         Carp::croak("Unknown encoding '$name'");
 155     }
 156     my $string = $enc->decode($octets,$check);
 157     $_[1] = $octets if $check;
 158     return $string;
 159 }
 160
 161 sub from_to($$$;$)
 162 {
 163     my ($string,$from,$to,$check) = @_;
 164     return undef unless defined $string;
 165     $check ||=0;
 166     my $f = find_encoding($from);
 167     unless (defined $f){
 168         require Carp;
 169         Carp::croak("Unknown encoding '$from'");
 170     }
 171     my $t = find_encoding($to);
 172     unless (defined $t){
 173         require Carp;
 174         Carp::croak("Unknown encoding '$to'");
 175     }
 176     my $uni = $f->decode($string,$check);
 177     return undef if ($check && length($string));
 178     $string =  $t->encode($uni,$check);
 179     return undef if ($check && length($uni));
 180     return defined($_[0] = $string) ? length($string) : undef ;
 181 }
 182
 183 sub encode_utf8($)
 184 {
 185     my ($str) = @_;
 186     utf8::encode($str);
 187     return $str;
 188 }
 189
 190 sub decode_utf8($)
 191 {
 192     my ($str) = @_;
 193     return undef unless utf8::decode($str);
 194     return $str;
 195 }
 196
 197 predefine_encodings(1);
 198
 199 #
 200 # This is to restore %Encoding if really needed;
 201 #
 202
 203 sub predefine_encodings{
 204     use Encode::Encoding;
 205     no warnings 'redefine';
 206     my $use_xs = shift;
 207     if ($ON_EBCDIC) {
 208         # was in Encode::UTF_EBCDIC
 209         package Encode::UTF_EBCDIC;
 210         push @Encode::UTF_EBCDIC::ISA, 'Encode::Encoding';
 211         *decode = sub{
 212             my ($obj,$str,$chk) = @_;
 213             my $res = '';
 214             for (my $i = 0; $i < length($str); $i++) {
 215                 $res .=
 216                     chr(utf8::unicode_to_native(ord(substr($str,$i,1))));
 217             }
 218             $_[1] = '' if $chk;
 219             return $res;
 220         };
 221         *encode = sub{
 222             my ($obj,$str,$chk) = @_;
 223             my $res = '';
 224             for (my $i = 0; $i < length($str); $i++) {
 225                 $res .=
 226                     chr(utf8::native_to_unicode(ord(substr($str,$i,1))));
 227             }
 228             $_[1] = '' if $chk;
 229             return $res;
 230         };
 231         $Encode::Encoding{Unicode} =
 232             bless {Name => "UTF_EBCDIC"} => "Encode::UTF_EBCDIC";
 233     } else {
 234         package Encode::Internal;
 235         push @Encode::Internal::ISA, 'Encode::Encoding';
 236         *decode = sub{
 237             my ($obj,$str,$chk) = @_;
 238             utf8::upgrade($str);
 239             $_[1] = '' if $chk;
 240             return $str;
 241         };
 242         *encode = \&decode;
 243         $Encode::Encoding{Unicode} =
 244             bless {Name => "Internal"} => "Encode::Internal";
 245     }
 246
 247     {
 248         # was in Encode::utf8
 249         package Encode::utf8;
 250         push @Encode::utf8::ISA, 'Encode::Encoding';
 251         #
 252         if ($use_xs){
 253             $DEBUG and warn __PACKAGE__, " XS on";
 254             *decode = \&decode_xs;
 255             *encode = \&encode_xs;
 256         }else{
 257             $DEBUG and warn __PACKAGE__, " XS off";
 258             *decode = sub{
 259                 my ($obj,$octets,$chk) = @_;
 260                 my $str = Encode::decode_utf8($octets);
 261                 if (defined $str) {
 262                     $_[1] = '' if $chk;
 263                     return $str;
 264                 }
 265                 return undef;
 266             };
 267             *encode = sub {
 268                 my ($obj,$string,$chk) = @_;
 269                 my $octets = Encode::encode_utf8($string);
 270                 $_[1] = '' if $chk;
 271                 return $octets;
 272             };
 273         }
 274         *cat_decode = sub{ # ($obj, $dst, $src, $pos, $trm, $chk)
 275             my ($obj, undef, undef, $pos, $trm) = @_; # currently ignores $chk
 276             my ($rdst, $rsrc, $rpos) = \@_[1,2,3];
 277             use bytes;
 278             if ((my $npos = index($$rsrc, $trm, $pos)) >= 0) {
 279                 $$rdst .= substr($$rsrc, $pos, $npos - $pos + length($trm));
 280                 $$rpos = $npos + length($trm);
 281                 return 1;
 282             }
 283             $$rdst .= substr($$rsrc, $pos);
 284             $$rpos = length($$rsrc);
 285             return '';
 286         };
 287         $Encode::Encoding{utf8} =
 288             bless {Name => "utf8"} => "Encode::utf8";
 289     }
 290 }
 291
 292 1;
 293
 294 __END__
 295
 296 =head1 NAME
 297
 298 Encode - character encodings
 299
 300 =head1 SYNOPSIS
 301
 302     use Encode;
 303
 304 =head2 Table of Contents
 305
 306 Encode consists of a collection of modules whose details are too big
 307 to fit in one document.  This POD itself explains the top-level APIs
 308 and general topics at a glance.  For other topics and more details,
 309 see the PODs below:
 310
 311   Name                          Description
 312   --------------------------------------------------------
 313   Encode::Alias         Alias definitions to encodings
 314   Encode::Encoding      Encode Implementation Base Class
 315   Encode::Supported     List of Supported Encodings
 316   Encode::CN            Simplified Chinese Encodings
 317   Encode::JP            Japanese Encodings
 318   Encode::KR            Korean Encodings
 319   Encode::TW            Traditional Chinese Encodings
 320   --------------------------------------------------------
 321
 322 =head1 DESCRIPTION
 323
 324 The C<Encode> module provides the interfaces between Perl's strings
 325 and the rest of the system.  Perl strings are sequences of
 326 B<characters>.
 327
 328 The repertoire of characters that Perl can represent is at least that
 329 defined by the Unicode Consortium. On most platforms the ordinal
 330 values of the characters (as returned by C<ord(ch)>) is the "Unicode
 331 codepoint" for the character (the exceptions are those platforms where
 332 the legacy encoding is some variant of EBCDIC rather than a super-set
 333 of ASCII - see L<perlebcdic>).
 334
 335 Traditionally, computer data has been moved around in 8-bit chunks
 336 often called "bytes". These chunks are also known as "octets" in
 337 networking standards. Perl is widely used to manipulate data of many
 338 types - not only strings of characters representing human or computer
 339 languages but also "binary" data being the machine's representation of
 340 numbers, pixels in an image - or just about anything.
 341
 342 When Perl is processing "binary data", the programmer wants Perl to
 343 process "sequences of bytes". This is not a problem for Perl - as a
 344 byte has 256 possible values, it easily fits in Perl's much larger
 345 "logical character".
 346
 347 =head2 TERMINOLOGY
 348
 349 =over 2
 350
 351 =item *
 352
 353 I<character>: a character in the range 0..(2**32-1) (or more).
 354 (What Perl's strings are made of.)
 355
 356 =item *
 357
 358 I<byte>: a character in the range 0..255
 359 (A special case of a Perl character.)
 360
 361 =item *
 362
 363 I<octet>: 8 bits of data, with ordinal values 0..255
 364 (Term for bytes passed to or from a non-Perl context, e.g. a disk file.)
 365
 366 =back
 367
 368 =head1 PERL ENCODING API
 369
 370 =over 2
 371
 372 =item $octets  = encode(ENCODING, $string [, CHECK])
 373
 374 Encodes a string from Perl's internal form into I<ENCODING> and returns
 375 a sequence of octets.  ENCODING can be either a canonical name or
 376 an alias.  For encoding names and aliases, see L</"Defining Aliases">.
 377 For CHECK, see L</"Handling Malformed Data">.
 378
 379 For example, to convert a string from Perl's internal format to
 380 iso-8859-1 (also known as Latin1),
 381
 382   $octets = encode("iso-8859-1", $string);
 383
 384 B<CAVEAT>: When you run C<$octets = encode("utf8", $string)>, then $octets
 385 B<may not be equal to> $string.  Though they both contain the same data, the utf8 flag
 386 for $octets is B<always> off.  When you encode anything, utf8 flag of
 387 the result is always off, even when it contains completely valid utf8
 388 string. See L</"The UTF-8 flag"> below.
 389
 390 encode($valid_encoding, undef) is harmless but warns you for
 391 C<Use of uninitialized value in subroutine entry>.
 392 encode($valid_encoding, '') is harmless and warnless.
 393
 394 =item $string = decode(ENCODING, $octets [, CHECK])
 395
 396 Decodes a sequence of octets assumed to be in I<ENCODING> into Perl's
 397 internal form and returns the resulting string.  As in encode(),
 398 ENCODING can be either a canonical name or an alias. For encoding names
 399 and aliases, see L</"Defining Aliases">.  For CHECK, see
 400 L</"Handling Malformed Data">.
 401
 402 For example, to convert ISO-8859-1 data to a string in Perl's internal format:
 403
 404   $string = decode("iso-8859-1", $octets);
 405
 406 B<CAVEAT>: When you run C<$string = decode("utf8", $octets)>, then $string
 407 B<may not be equal to> $octets.  Though they both contain the same data,
 408 the utf8 flag for $string is on unless $octets entirely consists of
 409 ASCII data (or EBCDIC on EBCDIC machines).  See L</"The UTF-8 flag">
 410 below.
 411
 412 decode($valid_encoding, undef) is harmless but warns you for
 413 C<Use of uninitialized value in subroutine entry>.
 414 decode($valid_encoding, '') is harmless and warnless.
 415
 416 =item [$length =] from_to($octets, FROM_ENC, TO_ENC [, CHECK])
 417
 418 Converts B<in-place> data between two encodings. The data in $octets
 419 must be encoded as octets and not as characters in Perl's internal
 420 format. For example, to convert ISO-8859-1 data to Microsoft's CP1250 encoding:
 421
 422   from_to($octets, "iso-8859-1", "cp1250");
 423
 424 and to convert it back:
 425
 426   from_to($octets, "cp1250", "iso-8859-1");
 427
 428 Note that because the conversion happens in place, the data to be
 429 converted cannot be a string constant; it must be a scalar variable.
 430
 431 from_to() returns the length of the converted string in octets on success, undef
 432 otherwise.
 433
 434 B<CAVEAT>: The following operations look the same but are not quite so;
 435
 436   from_to($data, "iso-8859-1", "utf8"); #1
 437   $data = decode("iso-8859-1", $data);  #2
 438
 439 Both #1 and #2 make $data consist of a completely valid UTF-8 string
 440 but only #2 turns utf8 flag on.  #1 is equivalent to
 441
 442   $data = encode("utf8", decode("iso-8859-1", $data));
 443
 444 See L</"The UTF-8 flag"> below.
 445
 446 =item $octets = encode_utf8($string);
 447
 448 Equivalent to C<$octets = encode("utf8", $string);> The characters
 449 that comprise $string are encoded in Perl's internal format and the
 450 result is returned as a sequence of octets. All possible
 451 characters have a UTF-8 representation so this function cannot fail.
 452
 453
 454 =item $string = decode_utf8($octets [, CHECK]);
 455
 456 equivalent to C<$string = decode("utf8", $octets [, CHECK])>.
 457 The sequence of octets represented by
 458 $octets is decoded from UTF-8 into a sequence of logical
 459 characters. Not all sequences of octets form valid UTF-8 encodings, so
 460 it is possible for this call to fail.  For CHECK, see
 461 L</"Handling Malformed Data">.
 462
 463 =back
 464
 465 =head2 Listing available encodings
 466
 467   use Encode;
 468   @list = Encode->encodings();
 469
 470 Returns a list of the canonical names of the available encodings that
 471 are loaded.  To get a list of all available encodings including the
 472 ones that are not loaded yet, say
 473
 474   @all_encodings = Encode->encodings(":all");
 475
 476 Or you can give the name of a specific module.
 477
 478   @with_jp = Encode->encodings("Encode::JP");
 479
 480 When "::" is not in the name, "Encode::" is assumed.
 481
 482   @ebcdic = Encode->encodings("EBCDIC");
 483
 484 To find out in detail which encodings are supported by this package,
 485 see L<Encode::Supported>.
 486
 487 =head2 Defining Aliases
 488
 489 To add a new alias to a given encoding, use:
 490
 491   use Encode;
 492   use Encode::Alias;
 493   define_alias(newName => ENCODING);
 494
 495 After that, newName can be used as an alias for ENCODING.
 496 ENCODING may be either the name of an encoding or an
 497 I<encoding object>
 498
 499 But before you do so, make sure the alias is nonexistent with
 500 C<resolve_alias()>, which returns the canonical name thereof.
 501 i.e.
 502
 503   Encode::resolve_alias("latin1") eq "iso-8859-1" # true
 504   Encode::resolve_alias("iso-8859-12")   # false; nonexistent
 505   Encode::resolve_alias($name) eq $name  # true if $name is canonical
 506
 507 resolve_alias() does not need C<use Encode::Alias>; it can be
 508 exported via C<use Encode qw(resolve_alias)>.
 509
 510 See L<Encode::Alias> for details.
 511
 512 =head1 Encoding via PerlIO
 513
 514 If your perl supports I<PerlIO> (which is the default), you can use a PerlIO layer to decode
 515 and encode directly via a filehandle.  The following two examples
 516 are totally identical in their functionality.
 517
 518   # via PerlIO
 519   open my $in,  "<:encoding(shiftjis)", $infile  or die;
 520   open my $out, ">:encoding(euc-jp)",   $outfile or die;
 521   while(<$in>){ print $out $_; }
 522
 523   # via from_to
 524   open my $in,  "<", $infile  or die;
 525   open my $out, ">", $outfile or die;
 526   while(<$in>){
 527     from_to($_, "shiftjis", "euc-jp", 1);
 528     print $out $_;
 529   }
 530
 531 Unfortunately, it may be that encodings are PerlIO-savvy.  You can check
 532 if your encoding is supported by PerlIO by calling the C<perlio_ok>
 533 method.
 534
 535   Encode::perlio_ok("hz");             # False
 536   find_encoding("euc-cn")->perlio_ok;  # True where PerlIO is available
 537
 538   use Encode qw(perlio_ok);            # exported upon request
 539   perlio_ok("euc-jp")
 540
 541 Fortunately, all encodings that come with Encode core are PerlIO-savvy
 542 except for hz and ISO-2022-kr.  For gory details, see L<Encode::Encoding> and L<Encode::PerlIO>.
 543
 544 =head1 Handling Malformed Data
 545
 546 The I<CHECK> argument is used as follows.  When you omit it,
 547 the behaviour is the same as if you had passed a value of 0 for
 548 I<CHECK>.
 549
 550 =over 2
 551
 552 =item I<CHECK> = Encode::FB_DEFAULT ( == 0)
 553
 554 If I<CHECK> is 0, (en|de)code will put a I<substitution character>
 555 in place of a malformed character.  For UCM-based encodings,
 556 E<lt>subcharE<gt> will be used.  For Unicode, the code point C<0xFFFD> is used.
 557 If the data is supposed to be UTF-8, an optional lexical warning
 558 (category utf8) is given.
 559
 560 =item I<CHECK> = Encode::FB_CROAK ( == 1)
 561
 562 If I<CHECK> is 1, methods will die on error immediately with an error
 563 message.  Therefore, when I<CHECK> is set to 1,  you should trap the
 564 fatal error with eval{} unless you really want to let it die on error.
 565
 566 =item I<CHECK> = Encode::FB_QUIET
 567
 568 If I<CHECK> is set to Encode::FB_QUIET, (en|de)code will immediately
 569 return the portion of the data that has been processed so far when
 570 an error occurs. The data argument will be overwritten with
 571 everything after that point (that is, the unprocessed part of data).
 572 This is handy when you have to call decode repeatedly in the case
 573 where your source data may contain partial multi-byte character
 574 sequences, for example because you are reading with a fixed-width
 575 buffer. Here is some sample code that does exactly this:
 576
 577   my $data = ''; my $utf8 = '';
 578   while(defined(read $fh, $buffer, 256)){
 579     # buffer may end in a partial character so we append
 580     $data .= $buffer;
 581     $utf8 .= decode($encoding, $data, Encode::FB_QUIET);
 582     # $data now contains the unprocessed partial character
 583   }
 584
 585 =item I<CHECK> = Encode::FB_WARN
 586
 587 This is the same as above, except that it warns on error.  Handy when
 588 you are debugging the mode above.
 589
 590 =item perlqq mode (I<CHECK> = Encode::FB_PERLQQ)
 591
 592 =item HTML charref mode (I<CHECK> = Encode::FB_HTMLCREF)
 593
 594 =item XML charref mode (I<CHECK> = Encode::FB_XMLCREF)
 595
 596 For encodings that are implemented by Encode::XS, CHECK ==
 597 Encode::FB_PERLQQ turns (en|de)code into C<perlqq> fallback mode.
 598
 599 When you decode, C<\xI<HH>> will be inserted for a malformed character,
 600 where I<HH> is the hex representation of the octet  that could not be
 601 decoded to utf8.  And when you encode, C<\x{I<HHHH>}> will be inserted,
 602 where I<HHHH> is the Unicode ID of the character that cannot be found
 603 in the character repertoire of the encoding.
 604
 605 HTML/XML character reference modes are about the same, in place of
 606 C<\x{I<HHHH>}>, HTML uses C<&#I<NNNN>>; where I<NNNN> is a decimal digit and
 607 XML uses C<&#xI<HHHH>>; where I<HHHH> is the hexadecimal digit.
 608
 609 =item The bitmask
 610
 611 These modes are actually set via a bitmask.  Here is how the FB_XX
 612 constants are laid out.  You can import the FB_XX constants via
 613 C<use Encode qw(:fallbacks)>; you can import the generic bitmask
 614 constants via C<use Encode qw(:fallback_all)>.
 615
 616                      FB_DEFAULT FB_CROAK FB_QUIET FB_WARN  FB_PERLQQ
 617  DIE_ON_ERR    0x0001             X
 618  WARN_ON_ERR   0x0002                               X
 619  RETURN_ON_ERR 0x0004                      X        X
 620  LEAVE_SRC     0x0008
 621  PERLQQ        0x0100                                        X
 622  HTMLCREF      0x0200
 623  XMLCREF       0x0400
 624
 625 =back
 626
 627 =head2 Unimplemented fallback schemes
 628
 629 In the future, you will be able to use a code reference to a callback
 630 function for the value of I<CHECK> but its API is still undecided.
 631
 632 The fallback scheme does not work on EBCDIC platforms.
 633
 634 =head1 Defining Encodings
 635
 636 To define a new encoding, use:
 637
 638     use Encode qw(define_encoding);
 639     define_encoding($object, 'canonicalName' [, alias...]);
 640
 641 I<canonicalName> will be associated with I<$object>.  The object
 642 should provide the interface described in L<Encode::Encoding>.
 643 If more than two arguments are provided then additional
 644 arguments are taken as aliases for I<$object>.
 645
 646 See L<Encode::Encoding> for more details.
 647
 648 =head1 The UTF-8 flag
 649
 650 Before the introduction of utf8 support in perl, The C<eq> operator
 651 just compared the strings represented by two scalars. Beginning with
 652 perl 5.8, C<eq> compares two strings with simultaneous consideration
 653 of I<the utf8 flag>. To explain why we made it so, I will quote page
 654 402 of C<Programming Perl, 3rd ed.>
 655
 656 =over 2
 657
 658 =item Goal #1:
 659
 660 Old byte-oriented programs should not spontaneously break on the old
 661 byte-oriented data they used to work on.
 662
 663 =item Goal #2:
 664
 665 Old byte-oriented programs should magically start working on the new
 666 character-oriented data when appropriate.
 667
 668 =item Goal #3:
 669
 670 Programs should run just as fast in the new character-oriented mode
 671 as in the old byte-oriented mode.
 672
 673 =item Goal #4:
 674
 675 Perl should remain one language, rather than forking into a
 676 byte-oriented Perl and a character-oriented Perl.
 677
 678 =back
 679
 680 Back when C<Programming Perl, 3rd ed.> was written, not even Perl 5.6.0
 681 was born and many features documented in the book remained
 682 unimplemented for a long time.  Perl 5.8 corrected this and the introduction
 683 of the UTF-8 flag is one of them.  You can think of this perl notion as of a
 684 byte-oriented mode (utf8 flag off) and a character-oriented mode (utf8
 685 flag on).
 686
 687 Here is how Encode takes care of the utf8 flag.
 688
 689 =over 2
 690
 691 =item *
 692
 693 When you encode, the resulting utf8 flag is always off.
 694
 695 =item *
 696
 697 When you decode, the resulting utf8 flag is on unless you can
 698 unambiguously represent data.  Here is the definition of
 699 dis-ambiguity.
 700
 701 After C<$utf8 = decode('foo', $octet);>,
 702
 703   When $octet is...   The utf8 flag in $utf8 is
 704   ---------------------------------------------
 705   In ASCII only (or EBCDIC only)            OFF
 706   In ISO-8859-1                              ON
 707   In any other Encoding                      ON
 708   ---------------------------------------------
 709
 710 As you see, there is one exception, In ASCII.  That way you can assue
 711 Goal #1.  And with Encode Goal #2 is assumed but you still have to be
 712 careful in such cases mentioned in B<CAVEAT> paragraphs.
 713
 714 This utf8 flag is not visible in perl scripts, exactly for the same
 715 reason you cannot (or you I<don't have to>) see if a scalar contains a
 716 string, integer, or floating point number.   But you can still peek
 717 and poke these if you will.  See the section below.
 718
 719 =back
 720
 721 =head2 Messing with Perl's Internals
 722
 723 The following API uses parts of Perl's internals in the current
 724 implementation.  As such, they are efficient but may change.
 725
 726 =over 2
 727
 728 =item is_utf8(STRING [, CHECK])
 729
 730 [INTERNAL] Tests whether the UTF-8 flag is turned on in the STRING.
 731 If CHECK is true, also checks the data in STRING for being well-formed
 732 UTF-8.  Returns true if successful, false otherwise.
 733
 734 =item _utf8_on(STRING)
 735
 736 [INTERNAL] Turns on the UTF-8 flag in STRING.  The data in STRING is
 737 B<not> checked for being well-formed UTF-8.  Do not use unless you
 738 B<know> that the STRING is well-formed UTF-8.  Returns the previous
 739 state of the UTF-8 flag (so please don't treat the return value as
 740 indicating success or failure), or C<undef> if STRING is not a string.
 741
 742 =item _utf8_off(STRING)
 743
 744 [INTERNAL] Turns off the UTF-8 flag in STRING.  Do not use frivolously.
 745 Returns the previous state of the UTF-8 flag (so please don't treat the
 746 return value as indicating success or failure), or C<undef> if STRING is
 747 not a string.
 748
 749 =back
 750
 751 =head1 SEE ALSO
 752
 753 L<Encode::Encoding>,
 754 L<Encode::Supported>,
 755 L<Encode::PerlIO>,
 756 L<encoding>,
 757 L<perlebcdic>,
 758 L<perlfunc/open>,
 759 L<perlunicode>,
 760 L<utf8>,
 761 the Perl Unicode Mailing List E<lt>perl-unicode@perl.orgE<gt>
 762
 763 =head1 MAINTAINER
 764
 765 This project was originated by Nick Ing-Simmons and later maintained
 766 by Dan Kogai E<lt>dankogai@dan.co.jpE<gt>.  See AUTHORS for a full
 767 list of people involved.  For any questions, use
 768 E<lt>perl-unicode@perl.orgE<gt> so we can all share.
 769
 770 =cut