ext/Encode/Encode.pm

   1 #
   2 # $Id: Encode.pm,v 1.64 2002/04/29 06:54:06 dankogai Exp $
   3 #
   4 package Encode;
   5 use strict;
   6 our $VERSION = do { my @r = (q$Revision: 1.64 $ =~ /\d+/g); sprintf "%d."."%02d" x $#r, @r };
   7 our $DEBUG = 0;
   8 use XSLoader ();
   9 XSLoader::load(__PACKAGE__, $VERSION);
  10
  11 require Exporter;
  12 use base qw/Exporter/;
  13
  14 # Public, encouraged API is exported by default
  15
  16 our @EXPORT = qw(
  17   decode  decode_utf8  encode  encode_utf8
  18   encodings  find_encoding
  19 );
  20
  21 our @FB_FLAGS  = qw(DIE_ON_ERR WARN_ON_ERR RETURN_ON_ERR LEAVE_SRC
  22                     PERLQQ HTMLCREF XMLCREF);
  23 our @FB_CONSTS = qw(FB_DEFAULT FB_CROAK FB_QUIET FB_WARN
  24                     FB_PERLQQ FB_HTMLCREF FB_XMLCREF);
  25
  26 our @EXPORT_OK =
  27     (
  28      qw(
  29        _utf8_off _utf8_on define_encoding from_to is_16bit is_8bit
  30        is_utf8 perlio_ok resolve_alias utf8_downgrade utf8_upgrade
  31       ),
  32      @FB_FLAGS, @FB_CONSTS,
  33     );
  34
  35 our %EXPORT_TAGS =
  36     (
  37      all          =>  [ @EXPORT, @EXPORT_OK ],
  38      fallbacks    =>  [ @FB_CONSTS ],
  39      fallback_all =>  [ @FB_CONSTS, @FB_FLAGS ],
  40     );
  41
  42 # Documentation moved after __END__ for speed - NI-S
  43
  44 our $ON_EBCDIC = (ord("A") == 193);
  45
  46 use Encode::Alias;
  47
  48 # Make a %Encoding package variable to allow a certain amount of cheating
  49 our %Encoding;
  50 our %ExtModule;
  51 require Encode::Config;
  52 eval { require Encode::ConfigLocal };
  53
  54 sub encodings
  55 {
  56     my $class = shift;
  57     my %enc;
  58     if (@_ and $_[0] eq ":all"){
  59         %enc = ( %Encoding, %ExtModule );
  60     }else{
  61         %enc = %Encoding;
  62         for my $mod (map {m/::/o ? $_ : "Encode::$_" } @_){
  63             $DEBUG and warn $mod;
  64             for my $enc (keys %ExtModule){
  65                 $ExtModule{$enc} eq $mod and $enc{$enc} = $mod;
  66             }
  67         }
  68     }
  69     return
  70         sort { lc $a cmp lc $b }
  71              grep {!/^(?:Internal|Unicode|Guess)$/o} keys %enc;
  72 }
  73
  74 sub perlio_ok{
  75     my $obj = ref($_[0]) ? $_[0] : find_encoding($_[0]);
  76     $obj->can("perlio_ok") and return $obj->perlio_ok();
  77     return 0; # safety net
  78 }
  79
  80 sub define_encoding
  81 {
  82     my $obj  = shift;
  83     my $name = shift;
  84     $Encoding{$name} = $obj;
  85     my $lc = lc($name);
  86     define_alias($lc => $obj) unless $lc eq $name;
  87     while (@_){
  88         my $alias = shift;
  89         define_alias($alias, $obj);
  90     }
  91     return $obj;
  92 }
  93
  94 sub getEncoding
  95 {
  96     my ($class, $name, $skip_external) = @_;
  97
  98     ref($name) && $name->can('new_sequence') and return $name;
  99     exists $Encoding{$name} and return $Encoding{$name};
 100     my $lc = lc $name;
 101     exists $Encoding{$lc} and return $Encoding{$lc};
 102
 103     my $oc = $class->find_alias($name);
 104     defined($oc) and return $oc;
 105     $lc ne $name and $oc = $class->find_alias($lc);
 106     defined($oc) and return $oc;
 107
 108     unless ($skip_external)
 109     {
 110         if (my $mod = $ExtModule{$name} || $ExtModule{$lc}){
 111             $mod =~ s,::,/,g ; $mod .= '.pm';
 112             eval{ require $mod; };
 113             exists $Encoding{$name} and return $Encoding{$name};
 114         }
 115     }
 116     return;
 117 }
 118
 119 sub find_encoding
 120 {
 121     my ($name, $skip_external) = @_;
 122     return __PACKAGE__->getEncoding($name,$skip_external);
 123 }
 124
 125 sub resolve_alias {
 126     my $obj = find_encoding(shift);
 127     defined $obj and return $obj->name;
 128     return;
 129 }
 130
 131 sub encode($$;$)
 132 {
 133     my ($name,$string,$check) = @_;
 134     $check ||=0;
 135     my $enc = find_encoding($name);
 136     unless(defined $enc){
 137         require Carp;
 138         Carp::croak("Unknown encoding '$name'");
 139     }
 140     my $octets = $enc->encode($string,$check);
 141     return undef if ($check && length($string));
 142     return $octets;
 143 }
 144
 145 sub decode($$;$)
 146 {
 147     my ($name,$octets,$check) = @_;
 148     $check ||=0;
 149     my $enc = find_encoding($name);
 150     unless(defined $enc){
 151         require Carp;
 152         Carp::croak("Unknown encoding '$name'");
 153     }
 154     my $string = $enc->decode($octets,$check);
 155     $_[1] = $octets if $check;
 156     return $string;
 157 }
 158
 159 sub from_to($$$;$)
 160 {
 161     my ($string,$from,$to,$check) = @_;
 162     $check ||=0;
 163     my $f = find_encoding($from);
 164     unless (defined $f){
 165         require Carp;
 166         Carp::croak("Unknown encoding '$from'");
 167     }
 168     my $t = find_encoding($to);
 169     unless (defined $t){
 170         require Carp;
 171         Carp::croak("Unknown encoding '$to'");
 172     }
 173     my $uni = $f->decode($string,$check);
 174     return undef if ($check && length($string));
 175     $string =  $t->encode($uni,$check);
 176     return undef if ($check && length($uni));
 177     return defined($_[0] = $string) ? length($string) : undef ;
 178 }
 179
 180 sub encode_utf8($)
 181 {
 182     my ($str) = @_;
 183     utf8::encode($str);
 184     return $str;
 185 }
 186
 187 sub decode_utf8($)
 188 {
 189     my ($str) = @_;
 190     return undef unless utf8::decode($str);
 191     return $str;
 192 }
 193
 194 predefine_encodings();
 195
 196 #
 197 # This is to restore %Encoding if really needed;
 198 #
 199
 200 sub predefine_encodings{
 201     use Encode::Encoding;
 202     if ($ON_EBCDIC) {
 203         # was in Encode::UTF_EBCDIC
 204         package Encode::UTF_EBCDIC;
 205         push @Encode::UTF_EBCDIC::ISA, 'Encode::Encoding';
 206         *decode = sub{
 207             my ($obj,$str,$chk) = @_;
 208             my $res = '';
 209             for (my $i = 0; $i < length($str); $i++) {
 210                 $res .=
 211                     chr(utf8::unicode_to_native(ord(substr($str,$i,1))));
 212             }
 213             $_[1] = '' if $chk;
 214             return $res;
 215         };
 216         *encode = sub{
 217             my ($obj,$str,$chk) = @_;
 218             my $res = '';
 219             for (my $i = 0; $i < length($str); $i++) {
 220                 $res .=
 221                     chr(utf8::native_to_unicode(ord(substr($str,$i,1))));
 222             }
 223             $_[1] = '' if $chk;
 224             return $res;
 225         };
 226         $Encode::Encoding{Unicode} =
 227             bless {Name => "UTF_EBCDIC"} => "Encode::UTF_EBCDIC";
 228     } else {
 229         package Encode::Internal;
 230         push @Encode::Internal::ISA, 'Encode::Encoding';
 231         *decode = sub{
 232             my ($obj,$str,$chk) = @_;
 233             utf8::upgrade($str);
 234             $_[1] = '' if $chk;
 235             return $str;
 236         };
 237         *encode = \&decode;
 238         $Encode::Encoding{Unicode} =
 239             bless {Name => "Internal"} => "Encode::Internal";
 240     }
 241
 242     {
 243         # was in Encode::utf8
 244         package Encode::utf8;
 245         push @Encode::utf8::ISA, 'Encode::Encoding';
 246         *decode = sub{
 247             my ($obj,$octets,$chk) = @_;
 248             my $str = Encode::decode_utf8($octets);
 249             if (defined $str) {
 250                 $_[1] = '' if $chk;
 251                 return $str;
 252             }
 253             return undef;
 254         };
 255         *encode = sub {
 256             my ($obj,$string,$chk) = @_;
 257             my $octets = Encode::encode_utf8($string);
 258             $_[1] = '' if $chk;
 259             return $octets;
 260         };
 261         $Encode::Encoding{utf8} =
 262             bless {Name => "utf8"} => "Encode::utf8";
 263     }
 264 }
 265
 266 1;
 267
 268 __END__
 269
 270 =head1 NAME
 271
 272 Encode - character encodings
 273
 274 =head1 SYNOPSIS
 275
 276     use Encode;
 277
 278 =head2 Table of Contents
 279
 280 Encode consists of a collection of modules whose details are too big
 281 to fit in one document.  This POD itself explains the top-level APIs
 282 and general topics at a glance.  For other topics and more details,
 283 see the PODs below:
 284
 285   Name                          Description
 286   --------------------------------------------------------
 287   Encode::Alias         Alias definitions to encodings
 288   Encode::Encoding      Encode Implementation Base Class
 289   Encode::Supported     List of Supported Encodings
 290   Encode::CN            Simplified Chinese Encodings
 291   Encode::JP            Japanese Encodings
 292   Encode::KR            Korean Encodings
 293   Encode::TW            Traditional Chinese Encodings
 294   --------------------------------------------------------
 295
 296 =head1 DESCRIPTION
 297
 298 The C<Encode> module provides the interfaces between Perl's strings
 299 and the rest of the system.  Perl strings are sequences of
 300 B<characters>.
 301
 302 The repertoire of characters that Perl can represent is at least that
 303 defined by the Unicode Consortium. On most platforms the ordinal
 304 values of the characters (as returned by C<ord(ch)>) is the "Unicode
 305 codepoint" for the character (the exceptions are those platforms where
 306 the legacy encoding is some variant of EBCDIC rather than a super-set
 307 of ASCII - see L<perlebcdic>).
 308
 309 Traditionally, computer data has been moved around in 8-bit chunks
 310 often called "bytes". These chunks are also known as "octets" in
 311 networking standards. Perl is widely used to manipulate data of many
 312 types - not only strings of characters representing human or computer
 313 languages but also "binary" data being the machine's representation of
 314 numbers, pixels in an image - or just about anything.
 315
 316 When Perl is processing "binary data", the programmer wants Perl to
 317 process "sequences of bytes". This is not a problem for Perl - as a
 318 byte has 256 possible values, it easily fits in Perl's much larger
 319 "logical character".
 320
 321 =head2 TERMINOLOGY
 322
 323 =over 2
 324
 325 =item *
 326
 327 I<character>: a character in the range 0..(2**32-1) (or more).
 328 (What Perl's strings are made of.)
 329
 330 =item *
 331
 332 I<byte>: a character in the range 0..255
 333 (A special case of a Perl character.)
 334
 335 =item *
 336
 337 I<octet>: 8 bits of data, with ordinal values 0..255
 338 (Term for bytes passed to or from a non-Perl context, e.g. a disk file.)
 339
 340 =back
 341
 342 =head1 PERL ENCODING API
 343
 344 =over 2
 345
 346 =item $octets  = encode(ENCODING, $string [, CHECK])
 347
 348 Encodes a string from Perl's internal form into I<ENCODING> and returns
 349 a sequence of octets.  ENCODING can be either a canonical name or
 350 an alias.  For encoding names and aliases, see L</"Defining Aliases">.
 351 For CHECK, see L</"Handling Malformed Data">.
 352
 353 For example, to convert a string from Perl's internal format to
 354 iso-8859-1 (also known as Latin1),
 355
 356   $octets = encode("iso-8859-1", $string);
 357
 358 B<CAVEAT>: When you run C<$octets = encode("utf8", $string)>, then $octets
 359 B<may not be equal to> $string.  Though they both contain the same data, the utf8 flag
 360 for $octets is B<always> off.  When you encode anything, utf8 flag of
 361 the result is always off, even when it contains completely valid utf8
 362 string. See L</"The UTF-8 flag"> below.
 363
 364 =item $string = decode(ENCODING, $octets [, CHECK])
 365
 366 Decodes a sequence of octets assumed to be in I<ENCODING> into Perl's
 367 internal form and returns the resulting string.  As in encode(),
 368 ENCODING can be either a canonical name or an alias. For encoding names
 369 and aliases, see L</"Defining Aliases">.  For CHECK, see
 370 L</"Handling Malformed Data">.
 371
 372 For example, to convert ISO-8859-1 data to a string in Perl's internal format:
 373
 374   $string = decode("iso-8859-1", $octets);
 375
 376 B<CAVEAT>: When you run C<$string = decode("utf8", $octets)>, then $string
 377 B<may not be equal to> $octets.  Though they both contain the same data,
 378 the utf8 flag for $string is on unless $octets entirely consists of
 379 ASCII data (or EBCDIC on EBCDIC machines).  See L</"The UTF-8 flag">
 380 below.
 381
 382 =item [$length =] from_to($octets, FROM_ENC, TO_ENC [, CHECK])
 383
 384 Converts B<in-place> data between two encodings. The data in $octets
 385 must be encoded as octets and not as characters in Perl's internal
 386 format. For example, to convert ISO-8859-1 data to Microsoft's CP1250 encoding:
 387
 388   from_to($octets, "iso-8859-1", "cp1250");
 389
 390 and to convert it back:
 391
 392   from_to($octets, "cp1250", "iso-8859-1");
 393
 394 Note that because the conversion happens in place, the data to be
 395 converted cannot be a string constant; it must be a scalar variable.
 396
 397 from_to() returns the length of the converted string in octets on success, undef
 398 otherwise.
 399
 400 B<CAVEAT>: The following operations look the same but are not quite so;
 401
 402   from_to($data, "iso-8859-1", "utf8"); #1
 403   $data = decode("iso-8859-1", $data);  #2
 404
 405 Both #1 and #2 make $data consist of a completely valid UTF-8 string
 406 but only #2 turns utf8 flag on.  #1 is equivalent to
 407
 408   $data = encode("utf8", decode("iso-8859-1", $data));
 409
 410 See L</"The UTF-8 flag"> below.
 411
 412 =item $octets = encode_utf8($string);
 413
 414 Equivalent to C<$octets = encode("utf8", $string);> The characters
 415 that comprise $string are encoded in Perl's internal format and the
 416 result is returned as a sequence of octets. All possible
 417 characters have a UTF-8 representation so this function cannot fail.
 418
 419
 420 =item $string = decode_utf8($octets [, CHECK]);
 421
 422 equivalent to C<$string = decode("utf8", $octets [, CHECK])>.
 423 The sequence of octets represented by
 424 $octets is decoded from UTF-8 into a sequence of logical
 425 characters. Not all sequences of octets form valid UTF-8 encodings, so
 426 it is possible for this call to fail.  For CHECK, see
 427 L</"Handling Malformed Data">.
 428
 429 =back
 430
 431 =head2 Listing available encodings
 432
 433   use Encode;
 434   @list = Encode->encodings();
 435
 436 Returns a list of the canonical names of the available encodings that
 437 are loaded.  To get a list of all available encodings including the
 438 ones that are not loaded yet, say
 439
 440   @all_encodings = Encode->encodings(":all");
 441
 442 Or you can give the name of a specific module.
 443
 444   @with_jp = Encode->encodings("Encode::JP");
 445
 446 When "::" is not in the name, "Encode::" is assumed.
 447
 448   @ebcdic = Encode->encodings("EBCDIC");
 449
 450 To find out in detail which encodings are supported by this package,
 451 see L<Encode::Supported>.
 452
 453 =head2 Defining Aliases
 454
 455 To add a new alias to a given encoding, use:
 456
 457   use Encode;
 458   use Encode::Alias;
 459   define_alias(newName => ENCODING);
 460
 461 After that, newName can be used as an alias for ENCODING.
 462 ENCODING may be either the name of an encoding or an
 463 I<encoding object>
 464
 465 But before you do so, make sure the alias is nonexistent with
 466 C<resolve_alias()>, which returns the canonical name thereof.
 467 i.e.
 468
 469   Encode::resolve_alias("latin1") eq "iso-8859-1" # true
 470   Encode::resolve_alias("iso-8859-12")   # false; nonexistent
 471   Encode::resolve_alias($name) eq $name  # true if $name is canonical
 472
 473 resolve_alias() does not need C<use Encode::Alias>; it can be
 474 exported via C<use Encode qw(resolve_alias)>.
 475
 476 See L<Encode::Alias> for details.
 477
 478 =head1 Encoding via PerlIO
 479
 480 If your perl supports I<PerlIO> (which is the default), you can use a PerlIO layer to decode
 481 and encode directly via a filehandle.  The following two examples
 482 are totally identical in their functionality.
 483
 484   # via PerlIO
 485   open my $in,  "<:encoding(shiftjis)", $infile  or die;
 486   open my $out, ">:encoding(euc-jp)",   $outfile or die;
 487   while(<$in>){ print $out $_; }
 488
 489   # via from_to
 490   open my $in,  "<", $infile  or die;
 491   open my $out, ">", $outfile or die;
 492   while(<$in>){
 493     from_to($_, "shiftjis", "euc-jp", 1);
 494     print $out $_;
 495   }
 496
 497 Unfortunately, it may be that encodings are PerlIO-savvy.  You can check
 498 if your encoding is supported by PerlIO by calling the C<perlio_ok>
 499 method.
 500
 501   Encode::perlio_ok("hz");             # False
 502   find_encoding("euc-cn")->perlio_ok;  # True where PerlIO is available
 503
 504   use Encode qw(perlio_ok);            # exported upon request
 505   perlio_ok("euc-jp")
 506
 507 Fortunately, all encodings that come with Encode core are PerlIO-savvy
 508 except for hz and ISO-2022-kr.  For gory details, see L<Encode::Encoding> and L<Encode::PerlIO>.
 509
 510 =head1 Handling Malformed Data
 511
 512 =over 2
 513
 514 The I<CHECK> argument is used as follows.  When you omit it,
 515 the behaviour is the same as if you had passed a value of 0 for
 516 I<CHECK>.
 517
 518 =item I<CHECK> = Encode::FB_DEFAULT ( == 0)
 519
 520 If I<CHECK> is 0, (en|de)code will put a I<substitution character>
 521 in place of a malformed character.  For UCM-based encodings,
 522 E<lt>subcharE<gt> will be used.  For Unicode, the code point C<0xFFFD> is used.
 523 If the data is supposed to be UTF-8, an optional lexical warning
 524 (category utf8) is given.
 525
 526 =item I<CHECK> = Encode::FB_CROAK ( == 1)
 527
 528 If I<CHECK> is 1, methods will die on error immediately with an error
 529 message.  Therefore, when I<CHECK> is set to 1,  you should trap the
 530 fatal error with eval{} unless you really want to let it die on error.
 531
 532 =item I<CHECK> = Encode::FB_QUIET
 533
 534 If I<CHECK> is set to Encode::FB_QUIET, (en|de)code will immediately
 535 return the portion of the data that has been processed so far when
 536 an error occurs. The data argument will be overwritten with
 537 everything after that point (that is, the unprocessed part of data).
 538 This is handy when you have to call decode repeatedly in the case
 539 where your source data may contain partial multi-byte character
 540 sequences, for example because you are reading with a fixed-width
 541 buffer. Here is some sample code that does exactly this:
 542
 543   my $data = ''; my $utf8 = '';
 544   while(defined(read $fh, $buffer, 256)){
 545     # buffer may end in a partial character so we append
 546     $data .= $buffer;
 547     $utf8 .= decode($encoding, $data, ENCODE::FB_QUIET);
 548     # $data now contains the unprocessed partial character
 549   }
 550
 551 =item I<CHECK> = Encode::FB_WARN
 552
 553 This is the same as above, except that it warns on error.  Handy when
 554 you are debugging the mode above.
 555
 556 =item perlqq mode (I<CHECK> = Encode::FB_PERLQQ)
 557
 558 =item HTML charref mode (I<CHECK> = Encode::FB_HTMLCREF)
 559
 560 =item XML charref mode (I<CHECK> = Encode::FB_XMLCREF)
 561
 562 For encodings that are implemented by Encode::XS, CHECK ==
 563 Encode::FB_PERLQQ turns (en|de)code into C<perlqq> fallback mode.
 564
 565 When you decode, C<\xI<HH>> will be inserted for a malformed character,
 566 where I<HH> is the hex representation of the octet  that could not be
 567 decoded to utf8.  And when you encode, C<\x{I<HHHH>}> will be inserted,
 568 where I<HHHH> is the Unicode ID of the character that cannot be found
 569 in the character repertoire of the encoding.
 570
 571 HTML/XML character reference modes are about the same, in place of
 572 C<\x{I<HHHH>}>, HTML uses C<&#I<NNNN>>; where I<NNNN> is a decimal digit and
 573 XML uses C<&#xI<HHHH>>; where I<HHHH> is the hexadecimal digit.
 574
 575 =item The bitmask
 576
 577 These modes are actually set via a bitmask.  Here is how the FB_XX
 578 constants are laid out.  You can import the FB_XX constants via
 579 C<use Encode qw(:fallbacks)>; you can import the generic bitmask
 580 constants via C<use Encode qw(:fallback_all)>.
 581
 582                      FB_DEFAULT FB_CROAK FB_QUIET FB_WARN  FB_PERLQQ
 583  DIE_ON_ERR    0x0001             X
 584  WARN_ON_ER    0x0002                               X
 585  RETURN_ON_ERR 0x0004                      X        X
 586  LEAVE_SRC     0x0008
 587  PERLQQ        0x0100                                        X
 588  HTMLCREF      0x0200
 589  XMLCREF       0x0400
 590
 591 =head2 Unimplemented fallback schemes
 592
 593 In the future, you will be able to use a code reference to a callback
 594 function for the value of I<CHECK> but its API is still undecided.
 595
 596 =head1 Defining Encodings
 597
 598 To define a new encoding, use:
 599
 600     use Encode qw(define_encoding);
 601     define_encoding($object, 'canonicalName' [, alias...]);
 602
 603 I<canonicalName> will be associated with I<$object>.  The object
 604 should provide the interface described in L<Encode::Encoding>.
 605 If more than two arguments are provided then additional
 606 arguments are taken as aliases for I<$object>.
 607
 608 See L<Encode::Encoding> for more details.
 609
 610 =head1 The UTF-8 flag
 611
 612 Before the introduction of utf8 support in perl, The C<eq> operator
 613 just compared the strings represented by two scalars. Beginning with
 614 perl 5.8, C<eq> compares two strings with simultaneous consideration
 615 of I<the utf8 flag>. To explain why we made it so, I will quote page
 616 402 of C<Programming Perl, 3rd ed.>
 617
 618 =over 2
 619
 620 =item Goal #1:
 621
 622 Old byte-oriented programs should not spontaneously break on the old
 623 byte-oriented data they used to work on.
 624
 625 =item Goal #2:
 626
 627 Old byte-oriented programs should magically start working on the new
 628 character-oriented data when appropriate.
 629
 630 =item Goal #3:
 631
 632 Programs should run just as fast in the new character-oriented mode
 633 as in the old byte-oriented mode.
 634
 635 =item Goal #4:
 636
 637 Perl should remain one language, rather than forking into a
 638 byte-oriented Perl and a character-oriented Perl.
 639
 640 =back
 641
 642 Back when C<Programming Perl, 3rd ed.> was written, not even Perl 5.6.0
 643 was born and many features documented in the book remained
 644 unimplemented for a long time.  Perl 5.8 corrected this and the introduction
 645 of the UTF-8 flag is one of them.  You can think of this perl notion as of a
 646 byte-oriented mode (utf8 flag off) and a character-oriented mode (utf8
 647 flag on).
 648
 649 Here is how Encode takes care of the utf8 flag.
 650
 651 =over 2
 652
 653 =item *
 654
 655 When you encode, the resulting utf8 flag is always off.
 656
 657 =item
 658
 659 When you decode, the resulting utf8 flag is on unless you can
 660 unambiguously represent data.  Here is the definition of
 661 dis-ambiguity.
 662
 663 After C<$utf8 = decode('foo', $octet);>,
 664
 665   When $octet is...   The utf8 flag in $utf8 is
 666   ---------------------------------------------
 667   In ASCII only (or EBCDIC only)            OFF
 668   In ISO-8859-1                              ON
 669   In any other Encoding                      ON
 670   ---------------------------------------------
 671
 672 As you see, there is one exception, In ASCII.  That way you can assue
 673 Goal #1.  And with Encode Goal #2 is assumed but you still have to be
 674 careful in such cases mentioned in B<CAVEAT> paragraphs.
 675
 676 This utf8 flag is not visible in perl scripts, exactly for the same
 677 reason you cannot (or you I<don't have to>) see if a scalar contains a
 678 string, integer, or floating point number.   But you can still peek
 679 and poke these if you will.  See the section below.
 680
 681 =back
 682
 683 =head2 Messing with Perl's Internals
 684
 685 The following API uses parts of Perl's internals in the current
 686 implementation.  As such, they are efficient but may change.
 687
 688 =over 2
 689
 690 =item is_utf8(STRING [, CHECK])
 691
 692 [INTERNAL] Tests whether the UTF-8 flag is turned on in the STRING.
 693 If CHECK is true, also checks the data in STRING for being well-formed
 694 UTF-8.  Returns true if successful, false otherwise.
 695
 696 =item _utf8_on(STRING)
 697
 698 [INTERNAL] Turns on the UTF-8 flag in STRING.  The data in STRING is
 699 B<not> checked for being well-formed UTF-8.  Do not use unless you
 700 B<know> that the STRING is well-formed UTF-8.  Returns the previous
 701 state of the UTF-8 flag (so please don't treat the return value as
 702 indicating success or failure), or C<undef> if STRING is not a string.
 703
 704 =item _utf8_off(STRING)
 705
 706 [INTERNAL] Turns off the UTF-8 flag in STRING.  Do not use frivolously.
 707 Returns the previous state of the UTF-8 flag (so please don't treat the
 708 return value as indicating success or failure), or C<undef> if STRING is
 709 not a string.
 710
 711 =back
 712
 713 =head1 SEE ALSO
 714
 715 L<Encode::Encoding>,
 716 L<Encode::Supported>,
 717 L<Encode::PerlIO>,
 718 L<encoding>,
 719 L<perlebcdic>,
 720 L<perlfunc/open>,
 721 L<perlunicode>,
 722 L<utf8>,
 723 the Perl Unicode Mailing List E<lt>perl-unicode@perl.orgE<gt>
 724
 725 =head1 MAINTAINER
 726
 727 This project was originated by Nick Ing-Simmons and later maintained
 728 by Dan Kogai E<lt>dankogai@dan.co.jpE<gt>.  See AUTHORS for a full
 729 list of people involved.  For any questions, use
 730 E<lt>perl-unicode@perl.orgE<gt> so we can all share.
 731
 732 =cut