ext/Encode/Encode.pm

   1 package Encode;
   2 use strict;
   3 our $VERSION = do {my @r=(q$Revision: 0.30 $ =~ /\d+/g); sprintf "%d."."%02d" x $#r, @r};
   4
   5 require DynaLoader;
   6 require Exporter;
   7
   8 our @ISA = qw(Exporter DynaLoader);
   9
  10 # Public, encouraged API is exported by default
  11 our @EXPORT = qw (
  12   encode
  13   decode
  14   encode_utf8
  15   decode_utf8
  16   find_encoding
  17   encodings
  18 );
  19
  20 our @EXPORT_OK =
  21     qw(
  22        define_encoding
  23        define_alias
  24        from_to
  25        is_utf8
  26        is_8bit
  27        is_16bit
  28        utf8_upgrade
  29        utf8_downgrade
  30        _utf8_on
  31        _utf8_off
  32       );
  33
  34 bootstrap Encode ();
  35
  36 # Documentation moved after __END__ for speed - NI-S
  37
  38 use Carp;
  39
  40 # Make a %encoding package variable to allow a certain amount of cheating
  41 our %encoding;
  42 my @alias;  # ordered matching list
  43 my %alias;  # cached known aliases
  44
  45                      # 0  1  2  3  4  5   6   7   8   9  10
  46 our @latin2iso_num = ( 0, 1, 2, 3, 4, 9, 10, 13, 14, 15, 16 );
  47
  48 our %winlatin2cp   = (
  49                       'Latin1'     => 1252,
  50                       'Latin2'     => 1250,
  51                       'Cyrillic'   => 1251,
  52                       'Greek'      => 1253,
  53                       'Turkish'    => 1254,
  54                       'Hebrew'     => 1255,
  55                       'Arabic'     => 1256,
  56                       'Baltic'     => 1257,
  57                       'Vietnamese' => 1258,
  58                      );
  59
  60 sub encodings
  61 {
  62  my ($class) = @_;
  63  return
  64      map { $_->[0] }
  65          sort { $a->[1] cmp $b->[1] }
  66                map { [$_, lc $_] }
  67                    grep { $_ ne 'Internal' }
  68                         keys %encoding;
  69 }
  70
  71 sub findAlias
  72 {
  73     my $class = shift;
  74     local $_ = shift;
  75     # print "# findAlias $_\n";
  76     unless (exists $alias{$_})
  77     {
  78         for (my $i=0; $i < @alias; $i += 2)
  79         {
  80             my $alias = $alias[$i];
  81             my $val   = $alias[$i+1];
  82             my $new;
  83             if (ref($alias) eq 'Regexp' && $_ =~ $alias)
  84             {
  85                 $new = eval $val;
  86             }
  87             elsif (ref($alias) eq 'CODE')
  88             {
  89                 $new = &{$alias}($val)
  90                 }
  91             elsif (lc($_) eq lc($alias))
  92             {
  93                 $new = $val;
  94             }
  95             if (defined($new))
  96             {
  97                 next if $new eq $_; # avoid (direct) recursion on bugs
  98                 my $enc = (ref($new)) ? $new : find_encoding($new);
  99                 if ($enc)
 100                 {
 101                     $alias{$_} = $enc;
 102                     last;
 103                 }
 104             }
 105         }
 106     }
 107     return $alias{$_};
 108 }
 109
 110 sub define_alias
 111 {
 112     while (@_)
 113     {
 114         my ($alias,$name) = splice(@_,0,2);
 115         push(@alias, $alias => $name);
 116     }
 117 }
 118
 119 # Allow variants of iso-8859-1 etc.
 120 define_alias( qr/^iso[-_]?(\d+)[-_](\d+)$/i => '"iso-$1-$2"' );
 121
 122 # At least HP-UX has these.
 123 define_alias( qr/^iso8859(\d+)$/i => '"iso-8859-$1"' );
 124
 125 # More HP stuff.
 126 define_alias( qr/^(?:hp-)?(arabic|greek|hebrew|kana|roman|thai|turkish)8$/i => '"${1}8"' );
 127
 128 # The Official name of ASCII.
 129 define_alias( qr/^ANSI[-_]?X3\.4[-_]?1968$/i => '"ascii"' );
 130
 131 # This is a font issue, not an encoding issue.
 132 # (The currency symbol of the Latin 1 upper half
 133 #  has been redefined as the euro symbol.)
 134 define_alias( qr/^(.+)\@euro$/i => '"$1"' );
 135
 136 # Allow latin-1 style names as well
 137 define_alias( qr/^(?:iso[-_]?)?latin[-_]?(\d+)$/i => '"iso-8859-$latin2iso_num[$1]"' );
 138
 139 # Allow winlatin1 style names as well
 140 define_alias( qr/^win(latin[12]|cyrillic|baltic|greek|turkish|hebrew|arabic|baltic|vietnamese)$/i => '"cp$winlatin2cp{\u$1}"' );
 141
 142 # Common names for non-latin prefered MIME names
 143 define_alias( 'ascii'    => 'US-ascii',
 144               'cyrillic' => 'iso-8859-5',
 145               'arabic'   => 'iso-8859-6',
 146               'greek'    => 'iso-8859-7',
 147               'hebrew'   => 'iso-8859-8',
 148               'thai'     => 'iso-8859-11',
 149               'tis620'   => 'iso-8859-11',
 150             );
 151
 152 # At least AIX has IBM-NNN (surprisingly...) instead of cpNNN.
 153 define_alias( qr/^ibm[-_]?(\d\d\d\d?)$/i => '"cp$1"');
 154
 155 # Standardize on the dashed versions.
 156 define_alias( qr/^utf8$/i  => 'utf-8' );
 157 define_alias( qr/^koi8r$/i => 'koi8-r' );
 158 define_alias( qr/^koi8u$/i => 'koi8-u' );
 159
 160 # TODO: HP-UX '8' encodings arabic8 greek8 hebrew8 kana8 thai8 turkish8
 161 # TODO: HP-UX '15' encodings japanese15 korean15 roi15
 162 # TODO: Cyrillic encoding ISO-IR-111 (useful?)
 163 # TODO: Chinese encodings GB18030 GBK Big5-HSKCS EUC-TW
 164 # TODO: Armenian encoding ARMSCII-8
 165 # TODO: Hebrew encoding ISO-8859-8-1
 166 # TODO: Thai encoding TCVN
 167 # TODO: Korean encoding Johab
 168 # TODO: Vietnamese encodings VPS
 169 # TODO: Japanese encoding JIS (not the same as SJIS)
 170 # TODO: Mac Asian+African encodings: Arabic Armenian Bengali Burmese
 171 #       ChineseSimp ChineseTrad Devanagari Ethiopic ExtArabic
 172 #       Farsi Georgian Gujarati Gurmukhi Hebrew Japanese
 173 #       Kannada Khmer Korean Laotian Malayalam Mongolian
 174 #       Oriya Sinhalese Symbol Tamil Telugu Tibetan Vietnamese
 175 # TODO: what is the Japanese 'UJIS' encoding seen in some Linuxes?
 176 #       Answer: euc-jp <dankogai@dan.co.jp>
 177 # Map white space and _ to '-'
 178
 179 define_alias( qr/^(\S+)[\s_]+(.*)$/i => '"$1-$2"' );
 180
 181 sub define_encoding
 182 {
 183     my $obj  = shift;
 184     my $name = shift;
 185     $encoding{$name} = $obj;
 186     my $lc = lc($name);
 187     define_alias($lc => $obj) unless $lc eq $name;
 188     while (@_)
 189     {
 190         my $alias = shift;
 191         define_alias($alias,$obj);
 192     }
 193     return $obj;
 194 }
 195
 196 sub getEncoding
 197 {
 198     my ($class,$name) = @_;
 199     my $enc;
 200     if (ref($name) && $name->can('new_sequence'))
 201     {
 202         return $name;
 203     }
 204     my $lc = lc $name;
 205     if (exists $encoding{$name})
 206     {
 207         return $encoding{$name};
 208     }
 209     if (exists $encoding{$lc})
 210     {
 211         return $encoding{$lc};
 212     }
 213
 214     my $oc = $class->findAlias($name);
 215     return $oc if defined $oc;
 216     return $class->findAlias($lc) if $lc ne $name;
 217
 218     return;
 219 }
 220
 221 sub find_encoding
 222 {
 223     my ($name) = @_;
 224     return __PACKAGE__->getEncoding($name);
 225 }
 226
 227 sub encode
 228 {
 229     my ($name,$string,$check) = @_;
 230     my $enc = find_encoding($name);
 231     croak("Unknown encoding '$name'") unless defined $enc;
 232     my $octets = $enc->encode($string,$check);
 233     return undef if ($check && length($string));
 234     return $octets;
 235 }
 236
 237 sub decode
 238 {
 239     my ($name,$octets,$check) = @_;
 240     my $enc = find_encoding($name);
 241     croak("Unknown encoding '$name'") unless defined $enc;
 242     my $string = $enc->decode($octets,$check);
 243     $_[1] = $octets if $check;
 244     return $string;
 245 }
 246
 247 sub from_to
 248 {
 249     my ($string,$from,$to,$check) = @_;
 250     my $f = find_encoding($from);
 251     croak("Unknown encoding '$from'") unless defined $f;
 252     my $t = find_encoding($to);
 253     croak("Unknown encoding '$to'") unless defined $t;
 254     my $uni = $f->decode($string,$check);
 255     return undef if ($check && length($string));
 256     $string = $t->encode($uni,$check);
 257     return undef if ($check && length($uni));
 258     return length($_[0] = $string);
 259 }
 260
 261 sub encode_utf8
 262 {
 263     my ($str) = @_;
 264   utf8::encode($str);
 265     return $str;
 266 }
 267
 268 sub decode_utf8
 269 {
 270     my ($str) = @_;
 271     return undef unless utf8::decode($str);
 272     return $str;
 273 }
 274
 275 require Encode::Encoding;
 276 require Encode::XS;
 277 require Encode::Internal;
 278 require Encode::Unicode;
 279 require Encode::utf8;
 280 require Encode::iso10646_1;
 281 require Encode::ucs2_le;
 282
 283 1;
 284
 285 __END__
 286
 287 =head1 NAME
 288
 289 Encode - character encodings
 290
 291 =head1 SYNOPSIS
 292
 293     use Encode;
 294
 295 =head1 DESCRIPTION
 296
 297 The C<Encode> module provides the interfaces between Perl's strings
 298 and the rest of the system.  Perl strings are sequences of B<characters>.
 299
 300 The repertoire of characters that Perl can represent is at least that
 301 defined by the Unicode Consortium. On most platforms the ordinal
 302 values of the characters (as returned by C<ord(ch)>) is the "Unicode
 303 codepoint" for the character (the exceptions are those platforms where
 304 the legacy encoding is some variant of EBCDIC rather than a super-set
 305 of ASCII - see L<perlebcdic>).
 306
 307 Traditionaly computer data has been moved around in 8-bit chunks
 308 often called "bytes". These chunks are also known as "octets" in
 309 networking standards. Perl is widely used to manipulate data of
 310 many types - not only strings of characters representing human or
 311 computer languages but also "binary" data being the machines representation
 312 of numbers, pixels in an image - or just about anything.
 313
 314 When Perl is processing "binary data" the programmer wants Perl to process
 315 "sequences of bytes". This is not a problem for Perl - as a byte has 256
 316 possible values it easily fits in Perl's much larger "logical character".
 317
 318 =head2 TERMINOLOGY
 319
 320 =over 4
 321
 322 =item *
 323
 324 I<character>: a character in the range 0..(2**32-1) (or more).
 325 (What Perl's strings are made of.)
 326
 327 =item *
 328
 329 I<byte>: a character in the range 0..255
 330 (A special case of a Perl character.)
 331
 332 =item *
 333
 334 I<octet>: 8 bits of data, with ordinal values 0..255
 335 (Term for bytes passed to or from a non-Perl context, e.g. disk file.)
 336
 337 =back
 338
 339 The marker [INTERNAL] marks Internal Implementation Details, in
 340 general meant only for those who think they know what they are doing,
 341 and such details may change in future releases.
 342
 343 =head1 ENCODINGS
 344
 345 =head2 Characteristics of an Encoding
 346
 347 An encoding has a "repertoire" of characters that it can represent,
 348 and for each representable character there is at least one sequence of
 349 octets that represents it.
 350
 351 =head2 Types of Encodings
 352
 353 Encodings can be divided into the following types:
 354
 355 =over 4
 356
 357 =item * Fixed length 8-bit (or less) encodings.
 358
 359 Each character is a single octet so may have a repertoire of up to
 360 256 characters. ASCII and iso-8859-* are typical examples.
 361
 362 =item * Fixed length 16-bit encodings
 363
 364 Each character is two octets so may have a repertoire of up to
 365 65 536 characters.  Unicode's UCS-2 is an example.  Also used for
 366 encodings for East Asian languages.
 367
 368 =item * Fixed length 32-bit encodings.
 369
 370 Not really very "encoded" encodings. The Unicode code points
 371 are just represented as 4-octet integers. None the less because
 372 different architectures use different representations of integers
 373 (so called "endian") there at least two disctinct encodings.
 374
 375 =item * Multi-byte encodings
 376
 377 The number of octets needed to represent a character varies.
 378 UTF-8 is a particularly complex but regular case of a multi-byte
 379 encoding. Several East Asian countries use a multi-byte encoding
 380 where 1-octet is used to cover western roman characters and Asian
 381 characters get 2-octets.
 382 (UTF-16 is strictly a multi-byte encoding taking either 2 or 4 octets
 383 to represent a Unicode code point.)
 384
 385 =item * "Escape" encodings.
 386
 387 These encodings embed "escape sequences" into the octet sequence
 388 which describe how the following octets are to be interpreted.
 389 The iso-2022-* family is typical. Following the escape sequence
 390 octets are encoded by an "embedded" encoding (which will be one
 391 of the above types) until another escape sequence switches to
 392 a different "embedded" encoding.
 393
 394 These schemes are very flexible and can handle mixed languages but are
 395 very complex to process (and have state).  No escape encodings are
 396 implemented for Perl yet.
 397
 398 =back
 399
 400 =head2 Specifying Encodings
 401
 402 Encodings can be specified to the API described below in two ways:
 403
 404 =over 4
 405
 406 =item 1. By name
 407
 408 Encoding names are strings with characters taken from a restricted
 409 repertoire.  See L</"Encoding Names">.
 410
 411 =item 2. As an object
 412
 413 Encoding objects are returned by C<find_encoding($name)>.
 414
 415 =back
 416
 417 =head2 Encoding Names
 418
 419 Encoding names are case insensitive. White space in names is ignored.
 420 In addition an encoding may have aliases. Each encoding has one
 421 "canonical" name.  The "canonical" name is chosen from the names of
 422 the encoding by picking the first in the following sequence:
 423
 424 =over 4
 425
 426 =item * The MIME name as defined in IETF RFCs.
 427
 428 =item * The name in the IANA registry.
 429
 430 =item * The name used by the organization that defined it.
 431
 432 =back
 433
 434 Because of all the alias issues, and because in the general case
 435 encodings have state C<Encode> uses the encoding object internally
 436 once an operation is in progress.
 437
 438 As of Perl 5.8.0, at least the following encodings are recognized
 439 (the => marks aliases):
 440
 441   ASCII
 442
 443   US-ASCII => ASCII
 444
 445 The Unicode:
 446
 447   UTF-8
 448   UTF-16
 449   UCS-2
 450
 451   ISO 10646-1 => UCS-2
 452
 453 The ISO 8859 and KOI:
 454
 455   ISO 8859-1  ISO 8859-6   ISO 8859-11         KOI8-F
 456   ISO 8859-2  ISO 8859-7   (12 doesn't exist)  KOI8-R
 457   ISO 8859-3  ISO 8859-8   ISO 8859-13         KOI8-U
 458   ISO 8859-4  ISO 8859-9   ISO 8859-14
 459   ISO 8859-5  ISO 8859-10  ISO 8859-15
 460                            ISO 8859-16
 461
 462   Latin1  => 8859-1  Latin6  => 8859-10
 463   Latin2  => 8859-2  Latin7  => 8859-13
 464   Latin3  => 8859-3  Latin8  => 8859-14
 465   Latin4  => 8859-4  Latin9  => 8859-15
 466   Latin5  => 8859-9  Latin10 => 8859-16
 467
 468   Cyrillic => 8859-5
 469   Arabic   => 8859-6
 470   Greek    => 8859-7
 471   Hebrew   => 8859-8
 472   Thai     => 8859-11
 473   TIS620   => 8859-11
 474
 475 The CJKV: Chinese, Japanese, Korean, Vietnamese:
 476
 477   ISO 2022     ISO 2022 JP-1  JIS 0201  GB 1988   Big5       EUC-CN
 478   ISO 2022 CN  ISO 2022 JP-2  JIS 0208  GB 2312   HZ         EUC-JP
 479   ISO 2022 JP  ISO 2022 KR    JIS 0210  GB 12345  CNS 11643  EUC-JP-0212
 480   Shift-JIS                                                  EUC-KR
 481   VISCII
 482
 483 The PC codepages:
 484
 485   CP37   CP852  CP861  CP866  CP949   CP1251  CP1256
 486   CP424  CP855  CP862  CP869  CP950   CP1252  CP1257
 487   CP737  CP856  CP863  CP874  CP1006  CP1253  CP1258
 488   CP775  CP857  CP864  CP932  CP1047  CP1254
 489   CP850  CP860  CP865  CP936  CP1250  CP1255
 490
 491   WinLatin1     => CP1252
 492   WinLatin2     => CP1250
 493   WinCyrillic   => CP1251
 494   WinGreek      => CP1253
 495   WinTurkiskh   => CP1254
 496   WinHebrew     => CP1255
 497   WinArabic     => CP1256
 498   WinBaltic     => CP1257
 499   WinVietnamese => CP1258
 500
 501 (All the CPI<NNN...> are available also as IBMI<NNN...>.)
 502
 503 The Mac codepages:
 504
 505   MacCentralEuropean   MacJapanese
 506   MacCroatian          MacRoman
 507   MacCyrillic          MacRumanian
 508   MacDingbats          MacSami
 509   MacGreek             MacThai
 510   MacIcelandic         MacTurkish
 511                        MacUkraine
 512
 513 Miscellaneous:
 514
 515   7bit-greek  IR-197
 516   7bit-kana   NeXTstep
 517   7bit-latin1 POSIX-BC
 518   DingBats    Roman8
 519   GSM 0338    Symbol
 520
 521 =head1 PERL ENCODING API
 522
 523 =head2 Generic Encoding Interface
 524
 525 =over 4
 526
 527 =item *
 528
 529         $bytes  = encode(ENCODING, $string[, CHECK])
 530
 531 Encodes string from Perl's internal form into I<ENCODING> and returns
 532 a sequence of octets.  For CHECK see L</"Handling Malformed Data">.
 533
 534 For example to convert (internally UTF-8 encoded) Unicode data
 535 to octets:
 536
 537         $octets = encode("utf8", $unicode);
 538
 539 =item *
 540
 541         $string = decode(ENCODING, $bytes[, CHECK])
 542
 543 Decode sequence of octets assumed to be in I<ENCODING> into Perl's
 544 internal form and returns the resulting string.  For CHECK see
 545 L</"Handling Malformed Data">.
 546
 547 For example to convert ISO 8859-1 data to UTF-8:
 548
 549         $utf8 = decode("latin1", $latin1);
 550
 551 =item *
 552
 553         from_to($string, FROM_ENCODING, TO_ENCODING[, CHECK])
 554
 555 Convert B<in-place> the data between two encodings.  How did the data
 556 in $string originally get to be in FROM_ENCODING?  Either using
 557 encode() or through PerlIO: See L</"Encoding and IO">.  For CHECK
 558 see L</"Handling Malformed Data">.
 559
 560 For example to convert ISO 8859-1 data to UTF-8:
 561
 562         from_to($data, "iso-8859-1", "utf-8");
 563
 564 and to convert it back:
 565
 566         from_to($data, "utf-8", "iso-8859-1");
 567
 568 Note that because the conversion happens in place, the data to be
 569 converted cannot be a string constant, it must be a scalar variable.
 570
 571 =back
 572
 573 =head2 Handling Malformed Data
 574
 575 If CHECK is not set, C<undef> is returned.  If the data is supposed to
 576 be UTF-8, an optional lexical warning (category utf8) is given.  If
 577 CHECK is true but not a code reference, dies.
 578
 579 It would desirable to have a way to indicate that transform should use
 580 the encodings "replacement character" - no such mechanism is defined yet.
 581
 582 It is also planned to allow I<CHECK> to be a code reference.
 583
 584 This is not yet implemented as there are design issues with what its
 585 arguments should be and how it returns its results.
 586
 587 =over 4
 588
 589 =item Scheme 1
 590
 591 Passed remaining fragment of string being processed.
 592 Modifies it in place to remove bytes/characters it can understand
 593 and returns a string used to represent them.
 594 e.g.
 595
 596  sub fixup {
 597    my $ch = substr($_[0],0,1,'');
 598    return sprintf("\x{%02X}",ord($ch);
 599  }
 600
 601 This scheme is close to how underlying C code for Encode works, but gives
 602 the fixup routine very little context.
 603
 604 =item Scheme 2
 605
 606 Passed original string, and an index into it of the problem area, and
 607 output string so far.  Appends what it will to output string and
 608 returns new index into original string.  For example:
 609
 610  sub fixup {
 611    # my ($s,$i,$d) = @_;
 612    my $ch = substr($_[0],$_[1],1);
 613    $_[2] .= sprintf("\x{%02X}",ord($ch);
 614    return $_[1]+1;
 615  }
 616
 617 This scheme gives maximal control to the fixup routine but is more
 618 complicated to code, and may need internals of Encode to be tweaked to
 619 keep original string intact.
 620
 621 =item Other Schemes
 622
 623 Hybrids of above.
 624
 625 Multiple return values rather than in-place modifications.
 626
 627 Index into the string could be pos($str) allowing s/\G...//.
 628
 629 =back
 630
 631 =head2 UTF-8 / utf8
 632
 633 The Unicode consortium defines the UTF-8 standard as a way of encoding
 634 the entire Unicode repertiore as sequences of octets.  This encoding is
 635 expected to become very widespread. Perl can use this form internaly
 636 to represent strings, so conversions to and from this form are
 637 particularly efficient (as octets in memory do not have to change,
 638 just the meta-data that tells Perl how to treat them).
 639
 640 =over 4
 641
 642 =item *
 643
 644         $bytes = encode_utf8($string);
 645
 646 The characters that comprise string are encoded in Perl's superset of UTF-8
 647 and the resulting octets returned as a sequence of bytes. All possible
 648 characters have a UTF-8 representation so this function cannot fail.
 649
 650 =item *
 651
 652         $string = decode_utf8($bytes [,CHECK]);
 653
 654 The sequence of octets represented by $bytes is decoded from UTF-8
 655 into a sequence of logical characters. Not all sequences of octets
 656 form valid UTF-8 encodings, so it is possible for this call to fail.
 657 For CHECK see L</"Handling Malformed Data">.
 658
 659 =back
 660
 661 =head2 Other Encodings of Unicode
 662
 663 UTF-16 is similar to UCS-2, 16 bit or 2-byte chunks.  UCS-2 can only
 664 represent 0..0xFFFF, while UTF-16 has a I<surrogate pair> scheme which
 665 allows it to cover the whole Unicode range.
 666
 667 Surrogates are code points set aside to encode the 0x01000..0x10FFFF
 668 range of Unicode code points in pairs of 16-bit units.  The I<high
 669 surrogates> are the range 0xD800..0xDBFF, and the I<low surrogates>
 670 are the range 0xDC00..0xDFFFF.  The surrogate encoding is
 671
 672         $hi = ($uni - 0x10000) / 0x400 + 0xD800;
 673         $lo = ($uni - 0x10000) % 0x400 + 0xDC00;
 674
 675 and the decoding is
 676
 677         $uni = 0x10000 + ($hi - 0xD8000) * 0x400 + ($lo - 0xDC00);
 678
 679 Encode implements big-endian UCS-2 aliased to "iso-10646-1" as that
 680 happens to be the name used by that representation when used with X11
 681 fonts.
 682
 683 UTF-32 or UCS-4 is 32-bit or 4-byte chunks.  Perl's logical characters
 684 can be considered as being in this form without encoding. An encoding
 685 to transfer strings in this form (e.g. to write them to a file) would
 686 need to
 687
 688      pack('L*', unpack('U*', $string));  # native
 689   or
 690      pack('V*', unpack('U*', $string));  # little-endian
 691   or
 692      pack('N*', unpack('U*', $string));  # big-endian
 693
 694 depending on the endianness required.
 695
 696 No UTF-32 encodings are implemented yet.
 697
 698 Both UCS-2 and UCS-4 style encodings can have "byte order marks" by
 699 representing the code point 0xFFFE as the very first thing in a file.
 700
 701 =head2 Listing available encodings
 702
 703   use Encode qw(encodings);
 704   @list = encodings();
 705
 706 Returns a list of the canonical names of the available encodings.
 707
 708 =head2 Defining Aliases
 709
 710   use Encode qw(define_alias);
 711   define_alias( newName => ENCODING);
 712
 713 Allows newName to be used as am alias for ENCODING. ENCODING may be
 714 either the name of an encoding or and encoding object (as above).
 715
 716 Currently I<newName> can be specified in the following ways:
 717
 718 =over 4
 719
 720 =item As a simple string.
 721
 722 =item As a qr// compiled regular expression, e.g.:
 723
 724   define_alias( qr/^iso8859-(\d+)$/i => '"iso-8859-$1"' );
 725
 726 In this case if I<ENCODING> is not a reference it is C<eval>-ed to
 727 allow C<$1> etc. to be subsituted.  The example is one way to names as
 728 used in X11 font names to alias the MIME names for the iso-8859-*
 729 family.
 730
 731 =item As a code reference, e.g.:
 732
 733   define_alias( sub { return /^iso8859-(\d+)$/i ? "iso-8859-$1" : undef } , '');
 734
 735 In this case C<$_> will be set to the name that is being looked up and
 736 I<ENCODING> is passed to the sub as its first argument.  The example
 737 is another way to names as used in X11 font names to alias the MIME
 738 names for the iso-8859-* family.
 739
 740 =back
 741
 742 =head2 Defining Encodings
 743
 744     use Encode qw(define_alias);
 745     define_encoding( $object, 'canonicalName' [,alias...]);
 746
 747 Causes I<canonicalName> to be associated with I<$object>.  The object
 748 should provide the interface described in L</"IMPLEMENTATION CLASSES">
 749 below.  If more than two arguments are provided then additional
 750 arguments are taken as aliases for I<$object> as for C<define_alias>.
 751
 752 =head1 Encoding and IO
 753
 754 It is very common to want to do encoding transformations when
 755 reading or writing files, network connections, pipes etc.
 756 If Perl is configured to use the new 'perlio' IO system then
 757 C<Encode> provides a "layer" (See L<perliol>) which can transform
 758 data as it is read or written.
 759
 760 Here is how the blind poet would modernise the encoding:
 761
 762     use Encode;
 763     open(my $iliad,'<:encoding(iso-8859-7)','iliad.greek');
 764     open(my $utf8,'>:utf8','iliad.utf8');
 765     my @epic = <$iliad>;
 766     print $utf8 @epic;
 767     close($utf8);
 768     close($illiad);
 769
 770 In addition the new IO system can also be configured to read/write
 771 UTF-8 encoded characters (as noted above this is efficient):
 772
 773     open(my $fh,'>:utf8','anything');
 774     print $fh "Any \x{0021} string \N{SMILEY FACE}\n";
 775
 776 Either of the above forms of "layer" specifications can be made the default
 777 for a lexical scope with the C<use open ...> pragma. See L<open>.
 778
 779 Once a handle is open is layers can be altered using C<binmode>.
 780
 781 Without any such configuration, or if Perl itself is built using
 782 system's own IO, then write operations assume that file handle accepts
 783 only I<bytes> and will C<die> if a character larger than 255 is
 784 written to the handle. When reading, each octet from the handle
 785 becomes a byte-in-a-character. Note that this default is the same
 786 behaviour as bytes-only languages (including Perl before v5.6) would
 787 have, and is sufficient to handle native 8-bit encodings
 788 e.g. iso-8859-1, EBCDIC etc. and any legacy mechanisms for handling
 789 other encodings and binary data.
 790
 791 In other cases it is the programs responsibility to transform
 792 characters into bytes using the API above before doing writes, and to
 793 transform the bytes read from a handle into characters before doing
 794 "character operations" (e.g. C<lc>, C</\W+/>, ...).
 795
 796 You can also use PerlIO to convert larger amounts of data you don't
 797 want to bring into memory.  For example to convert between ISO 8859-1
 798 (Latin 1) and UTF-8 (or UTF-EBCDIC in EBCDIC machines):
 799
 800     open(F, "<:encoding(iso-8859-1)", "data.txt") or die $!;
 801     open(G, ">:utf8",                 "data.utf") or die $!;
 802     while (<F>) { print G }
 803
 804     # Could also do "print G <F>" but that would pull
 805     # the whole file into memory just to write it out again.
 806
 807 More examples:
 808
 809     open(my $f, "<:encoding(cp1252)")
 810     open(my $g, ">:encoding(iso-8859-2)")
 811     open(my $h, ">:encoding(latin9)")       # iso-8859-15
 812
 813 See L<PerlIO> for more information.
 814
 815 See also L<encoding> for how to change the default encoding of the
 816 data in your script.
 817
 818 =head1 Encoding How to ...
 819
 820 To do:
 821
 822 =over 4
 823
 824 =item * IO with mixed content (faking iso-2020-*)
 825
 826 =item * MIME's Content-Length:
 827
 828 =item * UTF-8 strings in binary data.
 829
 830 =item * Perl/Encode wrappers on non-Unicode XS modules.
 831
 832 =back
 833
 834 =head1 Messing with Perl's Internals
 835
 836 The following API uses parts of Perl's internals in the current
 837 implementation.  As such they are efficient, but may change.
 838
 839 =over 4
 840
 841 =item * is_utf8(STRING [, CHECK])
 842
 843 [INTERNAL] Test whether the UTF-8 flag is turned on in the STRING.
 844 If CHECK is true, also checks the data in STRING for being well-formed
 845 UTF-8.  Returns true if successful, false otherwise.
 846
 847 =item * valid_utf8(STRING)
 848
 849 [INTERNAL] Test whether STRING is in a consistent state.  Will return
 850 true if string is held as bytes, or is well-formed UTF-8 and has the
 851 UTF-8 flag on.  Main reason for this routine is to allow Perl's
 852 testsuite to check that operations have left strings in a consistent
 853 state.
 854
 855 =item *
 856
 857         _utf8_on(STRING)
 858
 859 [INTERNAL] Turn on the UTF-8 flag in STRING.  The data in STRING is
 860 B<not> checked for being well-formed UTF-8.  Do not use unless you
 861 B<know> that the STRING is well-formed UTF-8.  Returns the previous
 862 state of the UTF-8 flag (so please don't test the return value as
 863 I<not> success or failure), or C<undef> if STRING is not a string.
 864
 865 =item *
 866
 867         _utf8_off(STRING)
 868
 869 [INTERNAL] Turn off the UTF-8 flag in STRING.  Do not use frivolously.
 870 Returns the previous state of the UTF-8 flag (so please don't test the
 871 return value as I<not> success or failure), or C<undef> if STRING is
 872 not a string.
 873
 874 =back
 875
 876 =head1 IMPLEMENTATION CLASSES
 877
 878 As mentioned above encodings are (in the current implementation at least)
 879 defined by objects. The mapping of encoding name to object is via the
 880 C<%encodings> hash.
 881
 882 The values of the hash can currently be either strings or objects.
 883 The string form may go away in the future. The string form occurs
 884 when C<encodings()> has scanned C<@INC> for loadable encodings but has
 885 not actually loaded the encoding in question. This is because the
 886 current "loading" process is all Perl and a bit slow.
 887
 888 Once an encoding is loaded then value of the hash is object which
 889 implements the encoding. The object should provide the following
 890 interface:
 891
 892 =over 4
 893
 894 =item -E<gt>name
 895
 896 Should return the string representing the canonical name of the encoding.
 897
 898 =item -E<gt>new_sequence
 899
 900 This is a placeholder for encodings with state. It should return an
 901 object which implements this interface, all current implementations
 902 return the original object.
 903
 904 =item -E<gt>encode($string,$check)
 905
 906 Should return the octet sequence representing I<$string>. If I<$check>
 907 is true it should modify I<$string> in place to remove the converted
 908 part (i.e.  the whole string unless there is an error).  If an error
 909 occurs it should return the octet sequence for the fragment of string
 910 that has been converted, and modify $string in-place to remove the
 911 converted part leaving it starting with the problem fragment.
 912
 913 If check is is false then C<encode> should make a "best effort" to
 914 convert the string - for example by using a replacement character.
 915
 916 =item -E<gt>decode($octets,$check)
 917
 918 Should return the string that I<$octets> represents. If I<$check> is
 919 true it should modify I<$octets> in place to remove the converted part
 920 (i.e.  the whole sequence unless there is an error).  If an error
 921 occurs it should return the fragment of string that has been
 922 converted, and modify $octets in-place to remove the converted part
 923 leaving it starting with the problem fragment.
 924
 925 If check is is false then C<decode> should make a "best effort" to
 926 convert the string - for example by using Unicode's "\x{FFFD}" as a
 927 replacement character.
 928
 929 =back
 930
 931 It should be noted that the check behaviour is different from the
 932 outer public API. The logic is that the "unchecked" case is useful
 933 when encoding is part of a stream which may be reporting errors
 934 (e.g. STDERR).  In such cases it is desirable to get everything
 935 through somehow without causing additional errors which obscure the
 936 original one. Also the encoding is best placed to know what the
 937 correct replacement character is, so if that is the desired behaviour
 938 then letting low level code do it is the most efficient.
 939
 940 In contrast if check is true, the scheme above allows the encoding to
 941 do as much as it can and tell layer above how much that was. What is
 942 lacking at present is a mechanism to report what went wrong. The most
 943 likely interface will be an additional method call to the object, or
 944 perhaps (to avoid forcing per-stream objects on otherwise stateless
 945 encodings) and additional parameter.
 946
 947 It is also highly desirable that encoding classes inherit from
 948 C<Encode::Encoding> as a base class. This allows that class to define
 949 additional behaviour for all encoding objects. For example built in
 950 Unicode, UCS-2 and UTF-8 classes use :
 951
 952   package Encode::MyEncoding;
 953   use base qw(Encode::Encoding);
 954
 955   __PACKAGE__->Define(qw(myCanonical myAlias));
 956
 957 To create an object with bless {Name => ...},$class, and call
 958 define_encoding.  They inherit their C<name> method from
 959 C<Encode::Encoding>.
 960
 961 =head2 Compiled Encodings
 962
 963 F<Encode.xs> provides a class C<Encode::XS> which provides the
 964 interface described above. It calls a generic octet-sequence to
 965 octet-sequence "engine" that is driven by tables (defined in
 966 F<encengine.c>). The same engine is used for both encode and
 967 decode. C<Encode:XS>'s C<encode> forces Perl's characters to their
 968 UTF-8 form and then treats them as just another multibyte
 969 encoding. C<Encode:XS>'s C<decode> transforms the sequence and then
 970 turns the UTF-8-ness flag as that is the form that the tables are
 971 defined to produce. For details of the engine see the comments in
 972 F<encengine.c>.
 973
 974 The tables are produced by the Perl script F<compile> (the name needs
 975 to change so we can eventually install it somewhere). F<compile> can
 976 currently read two formats:
 977
 978 =over 4
 979
 980 =item *.enc
 981
 982 This is a coined format used by Tcl. It is documented in
 983 Encode/EncodeFormat.pod.
 984
 985 =item *.ucm
 986
 987 This is the semi-standard format used by IBM's ICU package.
 988
 989 =back
 990
 991 F<compile> can write the following forms:
 992
 993 =over 4
 994
 995 =item *.ucm
 996
 997 See above - the F<Encode/*.ucm> files provided with the distribution have
 998 been created from the original Tcl .enc files using this approach.
 999
1000 =item *.c
1001
1002 Produces tables as C data structures - this is used to build in encodings
1003 into F<Encode.so>/F<Encode.dll>.
1004
1005 =item *.xs
1006
1007 In theory this allows encodings to be stand-alone loadable Perl
1008 extensions.  The process has not yet been tested. The plan is to use
1009 this approach for large East Asian encodings.
1010
1011 =back
1012
1013 The set of encodings built-in to F<Encode.so>/F<Encode.dll> is
1014 determined by F<Makefile.PL>.  The current set is as follows:
1015
1016 =over 4
1017
1018 =item ascii and iso-8859-*
1019
1020 That is all the common 8-bit "western" encodings.
1021
1022 =item IBM-1047 and two other variants of EBCDIC.
1023
1024 These are the same variants that are supported by EBCDIC Perl as
1025 "native" encodings.  They are included to prove "reversibility" of
1026 some constructs in EBCDIC Perl.
1027
1028 =item symbol and dingbats as used by Tk on X11.
1029
1030 (The reason Encode got started was to support Perl/Tk.)
1031
1032 =back
1033
1034 That set is rather ad hoc and has been driven by the needs of the
1035 tests rather than the needs of typical applications. It is likely
1036 to be rationalized.
1037
1038 =head1 SEE ALSO
1039
1040 L<perlunicode>, L<perlebcdic>, L<perlfunc/open>, L<PerlIO>, L<encoding>
1041
1042 =cut
1043