ext/Encode/Encode.pm

   1 package Encode;
   2 use strict;
   3 our $VERSION = do { my @r = (q$Revision: 1.51 $ =~ /\d+/g); sprintf "%d."."%02d" x $#r, @r };
   4 our $DEBUG = 0;
   5 use XSLoader ();
   6 XSLoader::load 'Encode';
   7
   8 require Exporter;
   9 our @ISA = qw(Exporter);
  10
  11 # Public, encouraged API is exported by default
  12
  13 our @EXPORT = qw(
  14   decode  decode_utf8  encode  encode_utf8
  15   encodings  find_encoding
  16 );
  17
  18 our @FB_FLAGS  = qw(DIE_ON_ERR WARN_ON_ERR RETURN_ON_ERR LEAVE_SRC PERLQQ);
  19 our @FB_CONSTS = qw(FB_DEFAULT FB_QUIET FB_WARN FB_PERLQQ FB_CROAK);
  20
  21 our @EXPORT_OK =
  22     (
  23      qw(
  24        _utf8_off _utf8_on define_encoding from_to is_16bit is_8bit
  25        is_utf8 perlio_ok resolve_alias utf8_downgrade utf8_upgrade
  26       ),
  27      @FB_FLAGS, @FB_CONSTS,
  28     );
  29
  30 our %EXPORT_TAGS =
  31     (
  32      all          =>  [ @EXPORT, @EXPORT_OK ],
  33      fallbacks    =>  [ @FB_CONSTS ],
  34      fallback_all =>  [ @FB_CONSTS, @FB_FLAGS ],
  35     );
  36
  37 # Documentation moved after __END__ for speed - NI-S
  38
  39 use Carp;
  40
  41 our $ON_EBCDIC = (ord("A") == 193);
  42
  43 use Encode::Alias;
  44
  45 # Make a %Encoding package variable to allow a certain amount of cheating
  46 our %Encoding;
  47 our %ExtModule;
  48 require Encode::Config;
  49 eval { require Encode::ConfigLocal };
  50
  51 sub encodings
  52 {
  53     my $class = shift;
  54     my @modules = (@_ and $_[0] eq ":all") ? values %ExtModule : @_;
  55     for my $mod (@modules){
  56         $mod =~ s,::,/,g or $mod = "Encode/$mod";
  57         $mod .= '.pm';
  58         $DEBUG and warn "about to require $mod;";
  59         eval { require $mod; };
  60     }
  61     my %modules = map {$_ => 1} @modules;
  62     return
  63         sort { lc $a cmp lc $b }
  64              grep {!/^(?:Internal|Unicode)$/o} keys %Encoding;
  65 }
  66
  67 sub perlio_ok{
  68     exists $INC{"PerlIO/encoding.pm"} or return 0;
  69     my $stash = ref($_[0]);
  70     $stash ||= ref(find_encoding($_[0]));
  71     return ($stash eq "Encode::XS" || $stash eq "Encode::Unicode");
  72 }
  73
  74 sub define_encoding
  75 {
  76     my $obj  = shift;
  77     my $name = shift;
  78     $Encoding{$name} = $obj;
  79     my $lc = lc($name);
  80     define_alias($lc => $obj) unless $lc eq $name;
  81     while (@_)
  82     {
  83         my $alias = shift;
  84         define_alias($alias,$obj);
  85     }
  86     return $obj;
  87 }
  88
  89 sub getEncoding
  90 {
  91     my ($class,$name,$skip_external) = @_;
  92     my $enc;
  93     if (ref($name) && $name->can('new_sequence'))
  94     {
  95         return $name;
  96     }
  97     my $lc = lc $name;
  98     if (exists $Encoding{$name})
  99     {
 100         return $Encoding{$name};
 101     }
 102     if (exists $Encoding{$lc})
 103     {
 104         return $Encoding{$lc};
 105     }
 106
 107     my $oc = $class->find_alias($name);
 108     return $oc if defined $oc;
 109
 110     $oc = $class->find_alias($lc) if $lc ne $name;
 111     return $oc if defined $oc;
 112
 113     unless ($skip_external)
 114     {
 115         if (my $mod = $ExtModule{$name} || $ExtModule{$lc}){
 116             $mod =~ s,::,/,g ; $mod .= '.pm';
 117             eval{ require $mod; };
 118             return $Encoding{$name} if exists $Encoding{$name};
 119         }
 120     }
 121     return;
 122 }
 123
 124 sub find_encoding
 125 {
 126     my ($name,$skip_external) = @_;
 127     return __PACKAGE__->getEncoding($name,$skip_external);
 128 }
 129
 130 sub resolve_alias {
 131     my $obj = find_encoding(shift);
 132     defined $obj and return $obj->name;
 133     return;
 134 }
 135
 136 sub encode($$;$)
 137 {
 138     my ($name,$string,$check) = @_;
 139     $check ||=0;
 140     my $enc = find_encoding($name);
 141     croak("Unknown encoding '$name'") unless defined $enc;
 142     my $octets = $enc->encode($string,$check);
 143     return undef if ($check && length($string));
 144     return $octets;
 145 }
 146
 147 sub decode($$;$)
 148 {
 149     my ($name,$octets,$check) = @_;
 150     $check ||=0;
 151     my $enc = find_encoding($name);
 152     croak("Unknown encoding '$name'") unless defined $enc;
 153     my $string = $enc->decode($octets,$check);
 154     $_[1] = $octets if $check;
 155     return $string;
 156 }
 157
 158 sub from_to($$$;$)
 159 {
 160     my ($string,$from,$to,$check) = @_;
 161     $check ||=0;
 162     my $f = find_encoding($from);
 163     croak("Unknown encoding '$from'") unless defined $f;
 164     my $t = find_encoding($to);
 165     croak("Unknown encoding '$to'") unless defined $t;
 166     my $uni = $f->decode($string,$check);
 167     return undef if ($check && length($string));
 168     $string =  $t->encode($uni,$check);
 169     return undef if ($check && length($uni));
 170     return defined($_[0] = $string) ? length($string) : undef ;
 171 }
 172
 173 sub encode_utf8($)
 174 {
 175     my ($str) = @_;
 176     utf8::encode($str);
 177     return $str;
 178 }
 179
 180 sub decode_utf8($)
 181 {
 182     my ($str) = @_;
 183     return undef unless utf8::decode($str);
 184     return $str;
 185 }
 186
 187 predefine_encodings();
 188
 189 #
 190 # This is to restore %Encoding if really needed;
 191 #
 192 sub predefine_encodings{
 193     if ($ON_EBCDIC) {
 194         # was in Encode::UTF_EBCDIC
 195         package Encode::UTF_EBCDIC;
 196         *name         = sub{ shift->{'Name'} };
 197         *new_sequence = sub{ return $_[0] };
 198         *decode = sub{
 199             my ($obj,$str,$chk) = @_;
 200             my $res = '';
 201             for (my $i = 0; $i < length($str); $i++) {
 202                 $res .=
 203                     chr(utf8::unicode_to_native(ord(substr($str,$i,1))));
 204             }
 205             $_[1] = '' if $chk;
 206             return $res;
 207         };
 208         *encode = sub{
 209             my ($obj,$str,$chk) = @_;
 210             my $res = '';
 211             for (my $i = 0; $i < length($str); $i++) {
 212                 $res .=
 213                     chr(utf8::native_to_unicode(ord(substr($str,$i,1))));
 214             }
 215             $_[1] = '' if $chk;
 216             return $res;
 217         };
 218         $Encode::Encoding{Unicode} =
 219             bless {Name => "UTF_EBCDIC"} => "Encode::UTF_EBCDIC";
 220     } else {
 221         # was in Encode::UTF_EBCDIC
 222         package Encode::Internal;
 223         *name         = sub{ shift->{'Name'} };
 224         *new_sequence = sub{ return $_[0] };
 225         *decode = sub{
 226             my ($obj,$str,$chk) = @_;
 227             utf8::upgrade($str);
 228             $_[1] = '' if $chk;
 229             return $str;
 230         };
 231         *encode = \&decode;
 232         $Encode::Encoding{Unicode} =
 233             bless {Name => "Internal"} => "Encode::Internal";
 234     }
 235
 236     {
 237         # was in Encode::utf8
 238         package Encode::utf8;
 239         *name         = sub{ shift->{'Name'} };
 240         *new_sequence = sub{ return $_[0] };
 241         *decode = sub{
 242             my ($obj,$octets,$chk) = @_;
 243             my $str = Encode::decode_utf8($octets);
 244             if (defined $str) {
 245                 $_[1] = '' if $chk;
 246                 return $str;
 247             }
 248             return undef;
 249         };
 250         *encode = sub {
 251             my ($obj,$string,$chk) = @_;
 252             my $octets = Encode::encode_utf8($string);
 253             $_[1] = '' if $chk;
 254             return $octets;
 255         };
 256         $Encode::Encoding{utf8} =
 257             bless {Name => "utf8"} => "Encode::utf8";
 258     }
 259 }
 260
 261 require Encode::Encoding;
 262 @Encode::XS::ISA = qw(Encode::Encoding);
 263
 264 # This is very dodgy - PerlIO::encoding does "use Encode" and  _BEFORE_ it gets a
 265 # chance to set its VERSION we potentially delete it from %INC so it will be re-loaded
 266 # NI-S
 267 eval {
 268     require PerlIO::encoding;
 269     unless (PerlIO::encoding->VERSION >= 0.02){
 270         delete $INC{"PerlIO/encoding.pm"};
 271     }
 272 };
 273 # warn $@ if $@;
 274
 275 1;
 276
 277 __END__
 278
 279 =head1 NAME
 280
 281 Encode - character encodings
 282
 283 =head1 SYNOPSIS
 284
 285     use Encode;
 286
 287
 288 =head2 Table of Contents
 289
 290 Encode consists of a collection of modules which details are too big
 291 to fit in one document.  This POD itself explains the top-level APIs
 292 and general topics at a glance.  For other topics and more details,
 293 see the PODs below;
 294
 295   Name                          Description
 296   --------------------------------------------------------
 297   Encode::Alias         Alias definitions to encodings
 298   Encode::Encoding      Encode Implementation Base Class
 299   Encode::Supported     List of Supported Encodings
 300   Encode::CN            Simplified Chinese Encodings
 301   Encode::JP            Japanese Encodings
 302   Encode::KR            Korean Encodings
 303   Encode::TW            Traditional Chinese Encodings
 304   --------------------------------------------------------
 305
 306 =head1 DESCRIPTION
 307
 308 The C<Encode> module provides the interfaces between Perl's strings
 309 and the rest of the system.  Perl strings are sequences of
 310 B<characters>.
 311
 312 The repertoire of characters that Perl can represent is at least that
 313 defined by the Unicode Consortium. On most platforms the ordinal
 314 values of the characters (as returned by C<ord(ch)>) is the "Unicode
 315 codepoint" for the character (the exceptions are those platforms where
 316 the legacy encoding is some variant of EBCDIC rather than a super-set
 317 of ASCII - see L<perlebcdic>).
 318
 319 Traditionally computer data has been moved around in 8-bit chunks
 320 often called "bytes". These chunks are also known as "octets" in
 321 networking standards. Perl is widely used to manipulate data of many
 322 types - not only strings of characters representing human or computer
 323 languages but also "binary" data being the machines representation of
 324 numbers, pixels in an image - or just about anything.
 325
 326 When Perl is processing "binary data" the programmer wants Perl to
 327 process "sequences of bytes". This is not a problem for Perl - as a
 328 byte has 256 possible values it easily fits in Perl's much larger
 329 "logical character".
 330
 331 =head2 TERMINOLOGY
 332
 333 =over 4
 334
 335 =item *
 336
 337 I<character>: a character in the range 0..(2**32-1) (or more).
 338 (What Perl's strings are made of.)
 339
 340 =item *
 341
 342 I<byte>: a character in the range 0..255
 343 (A special case of a Perl character.)
 344
 345 =item *
 346
 347 I<octet>: 8 bits of data, with ordinal values 0..255
 348 (Term for bytes passed to or from a non-Perl context, e.g. disk file.)
 349
 350 =back
 351
 352 The marker [INTERNAL] marks Internal Implementation Details, in
 353 general meant only for those who think they know what they are doing,
 354 and such details may change in future releases.
 355
 356 =head1 PERL ENCODING API
 357
 358 =over 4
 359
 360 =item $octets  = encode(ENCODING, $string[, CHECK])
 361
 362 Encodes string from Perl's internal form into I<ENCODING> and returns
 363 a sequence of octets.  ENCODING can be either a canonical name or
 364 alias.  For encoding names and aliases, see L</"Defining Aliases">.
 365 For CHECK see L</"Handling Malformed Data">.
 366
 367 For example to convert (internally UTF-8 encoded) Unicode string to
 368 iso-8859-1 (also known as Latin1),
 369
 370   $octets = encode("iso-8859-1", $unicode);
 371
 372 =item $string = decode(ENCODING, $octets[, CHECK])
 373
 374 Decode sequence of octets assumed to be in I<ENCODING> into Perl's
 375 internal form and returns the resulting string.  as in encode(),
 376 ENCODING can be either a canonical name or alias. For encoding names
 377 and aliases, see L</"Defining Aliases">.  For CHECK see
 378 L</"Handling Malformed Data">.
 379
 380 For example to convert ISO-8859-1 data to UTF-8:
 381
 382   $utf8 = decode("iso-8859-1", $latin1);
 383
 384 =item [$length =] from_to($string, FROM_ENCODING, TO_ENCODING [,CHECK])
 385
 386 Convert B<in-place> the data between two encodings.
 387 For example to convert ISO-8859-1 data to UTF-8:
 388
 389         from_to($data, "iso-8859-1", "utf-8");
 390
 391 and to convert it back:
 392
 393         from_to($data, "utf-8", "iso-8859-1");
 394
 395 Note that because the conversion happens in place, the data to be
 396 converted cannot be a string constant, it must be a scalar variable.
 397
 398 from_to() return the length of the converted string on success, undef
 399 otherwise.
 400
 401 =back
 402
 403 =head2 UTF-8 / utf8
 404
 405 The Unicode consortium defines the UTF-8 standard as a way of encoding
 406 the entire Unicode repertoire as sequences of octets.  This encoding is
 407 expected to become very widespread. Perl can use this form internally
 408 to represent strings, so conversions to and from this form are
 409 particularly efficient (as octets in memory do not have to change,
 410 just the meta-data that tells Perl how to treat them).
 411
 412 =over 4
 413
 414 =item $octets = encode_utf8($string);
 415
 416 The characters that comprise string are encoded in Perl's superset of UTF-8
 417 and the resulting octets returned as a sequence of bytes. All possible
 418 characters have a UTF-8 representation so this function cannot fail.
 419
 420 =item $string = decode_utf8($octets [, CHECK]);
 421
 422 The sequence of octets represented by $octets is decoded from UTF-8
 423 into a sequence of logical characters. Not all sequences of octets
 424 form valid UTF-8 encodings, so it is possible for this call to fail.
 425 For CHECK see L</"Handling Malformed Data">.
 426
 427 =back
 428
 429 =head2 Listing available encodings
 430
 431   use Encode;
 432   @list = Encode->encodings();
 433
 434 Returns a list of the canonical names of the available encodings that
 435 are loaded.  To get a list of all available encodings including the
 436 ones that are not loaded yet, say
 437
 438   @all_encodings = Encode->encodings(":all");
 439
 440 Or you can give the name of specific module.
 441
 442   @with_jp = Encode->encodings("Encode::JP");
 443
 444 When "::" is not in the name, "Encode::" is assumed.
 445
 446   @ebcdic = Encode->encodings("EBCDIC");
 447
 448 To find which encodings are supported by this package in details,
 449 see L<Encode::Supported>.
 450
 451 =head2 Defining Aliases
 452
 453 To add new alias to a given encoding,  Use;
 454
 455   use Encode;
 456   use Encode::Alias;
 457   define_alias(newName => ENCODING);
 458
 459 After that, newName can be used as an alias for ENCODING.
 460 ENCODING may be either the name of an encoding or an
 461 I<encoding object>
 462
 463 But before you do so, make sure the alias is nonexistent with
 464 C<resolve_alias()>, which returns the canonical name thereof.
 465 i.e.
 466
 467   Encode::resolve_alias("latin1") eq "iso-8859-1" # true
 468   Encode::resolve_alias("iso-8859-12")   # false; nonexistent
 469   Encode::resolve_alias($name) eq $name  # true if $name is canonical
 470
 471 This resolve_alias() does not need C<use Encode::Alias> and is
 472 exported via C<use encode qw(resolve_alias)>.
 473
 474 See L<Encode::Alias> on details.
 475
 476 =head1 Encoding via PerlIO
 477
 478 If your perl supports I<PerlIO>, you can use PerlIO layer to directly
 479 decode and encode via filehandle.  The following two examples are
 480 totally identical by functionality.
 481
 482   # via PerlIO
 483   open my $in,  "<:encoding(shiftjis)", $infile  or die;
 484   open my $out, ">:encoding(euc-jp)",   $outfile or die;
 485   while(<>){ print; }
 486
 487   # via from_to
 488   open my $in,  $infile  or die;
 489   open my $out, $outfile or die;
 490   while(<>){
 491     from_to($_, "shiftjis", "euc", 1);
 492   }
 493
 494 Unfortunately, not all encodings are PerlIO-savvy.  You can check if
 495 your encoding is supported by PerlIO by C<perlio_ok> method.
 496
 497   Encode::perlio_ok("iso-20220jp");        # false
 498   find_encoding("iso-2022-jp")->perlio_ok; # false
 499   use Encode qw(perlio_ok);                # exported upon request
 500   perlio_ok("euc-jp")                      # true if PerlIO is enabled
 501
 502 For gory details, see L<Encode::PerlIO>;
 503
 504 =head1 Handling Malformed Data
 505
 506 =over 4
 507
 508 THE I<CHECK> argument is used as follows.  When you omit it, it is
 509 identical to I<CHECK> = 0.
 510
 511 =item I<CHECK> = Encode::FB_DEFAULT ( == 0)
 512
 513 If I<CHECK> is 0, (en|de)code will put I<substitution character> in
 514 place of the malformed character.  for UCM-based encodings,
 515 E<lt>subcharE<gt> will be used.  For Unicode, \xFFFD is used.  If the
 516 data is supposed to be UTF-8, an optional lexical warning (category
 517 utf8) is given.
 518
 519 =item I<CHECK> = Encode::DIE_ON_ERROR (== 1)
 520
 521 If I<CHECK> is 1, methods will die immediately  with an error
 522 message.  so when I<CHECK> is set,  you should trap the fatal error
 523 with eval{} unless you really want to let it die on error.
 524
 525 =item I<CHECK> = Encode::FB_QUIET
 526
 527 If I<CHECK> is set to Encode::FB_QUIET, (en|de)code will immediately
 528 return processed part on error, with data passed via argument
 529 overwritten with unprocessed part.  This is handy when have to
 530 repeatedly call because the source data is chopped in the middle for
 531 some reasons, such as fixed-width buffer.  Here is a sample code that
 532 just does this.
 533
 534   my $data = '';
 535   while(defined(read $fh, $buffer, 256)){
 536     # buffer may end in partial character so we append
 537     $data .= $buffer;
 538     $utf8 .= decode($encoding, $data, ENCODE::FB_QUIET);
 539     # $data now contains unprocessed partial character
 540   }
 541
 542 =item I<CHECK> = Encode::FB_WARN
 543
 544 This is the same as above, except it warns on error.  Handy when you
 545 are debugging the mode above.
 546
 547 =item perlqq mode (I<CHECK> = Encode::FB_PERLQQ)
 548
 549 For encodings that are implemented by Encode::XS, CHECK ==
 550 Encode::FB_PERLQQ turns (en|de)code into C<perlqq> fallback mode.
 551
 552 When you decode, '\xI<XX>' will be placed where I<XX> is the hex
 553 representation of the octet  that could not be decoded to utf8.  And
 554 when you encode, '\x{I<xxxx>}' will be placed where I<xxxx> is the
 555 Unicode ID of the character that cannot be found in the character
 556 repertoire of the encoding.
 557
 558 =item The bitmask
 559
 560 These modes are actually set via bitmask.  here is how FB_XX are laid
 561 out.  for FB_XX you can import via C<use Encode qw(:fallbacks)> for
 562 generic bitmask constants, you can import via
 563  C<use Encode qw(:fallback_all)>.
 564
 565                      FB_DEFAULT FB_CROAK FB_QUIET FB_WARN  FB_PERLQQ
 566  DIE_ON_ERR    0x0001             X
 567  WARN_ON_ER    0x0002                               X
 568  RETURN_ON_ERR 0x0004                      X        X
 569  LEAVE_SRC     0x0008
 570  PERLQQ        0x0100                                        X
 571
 572 =head2 Unemplemented fallback schemes
 573
 574 In future you will be able to use a code reference to a callback
 575 function for the value of I<CHECK> but its API is still undecided.
 576
 577 =head1 Defining Encodings
 578
 579 To define a new encoding, use:
 580
 581     use Encode qw(define_alias);
 582     define_encoding($object, 'canonicalName' [, alias...]);
 583
 584 I<canonicalName> will be associated with I<$object>.  The object
 585 should provide the interface described in L<Encode::Encoding>
 586 If more than two arguments are provided then additional
 587 arguments are taken as aliases for I<$object> as for C<define_alias>.
 588
 589 See L<Encode::Encoding> for more details.
 590
 591 =head1 Messing with Perl's Internals
 592
 593 The following API uses parts of Perl's internals in the current
 594 implementation.  As such they are efficient, but may change.
 595
 596 =over 4
 597
 598 =item is_utf8(STRING [, CHECK])
 599
 600 [INTERNAL] Test whether the UTF-8 flag is turned on in the STRING.
 601 If CHECK is true, also checks the data in STRING for being well-formed
 602 UTF-8.  Returns true if successful, false otherwise.
 603
 604 =item _utf8_on(STRING)
 605
 606 [INTERNAL] Turn on the UTF-8 flag in STRING.  The data in STRING is
 607 B<not> checked for being well-formed UTF-8.  Do not use unless you
 608 B<know> that the STRING is well-formed UTF-8.  Returns the previous
 609 state of the UTF-8 flag (so please don't test the return value as
 610 I<not> success or failure), or C<undef> if STRING is not a string.
 611
 612 =item _utf8_off(STRING)
 613
 614 [INTERNAL] Turn off the UTF-8 flag in STRING.  Do not use frivolously.
 615 Returns the previous state of the UTF-8 flag (so please don't test the
 616 return value as I<not> success or failure), or C<undef> if STRING is
 617 not a string.
 618
 619 =back
 620
 621 =head1 SEE ALSO
 622
 623 L<Encode::Encoding>,
 624 L<Encode::Supported>,
 625 L<Encode::PerlIO>,
 626 L<encoding>,
 627 L<perlebcdic>,
 628 L<perlfunc/open>,
 629 L<perlunicode>,
 630 L<utf8>,
 631 the Perl Unicode Mailing List E<lt>perl-unicode@perl.orgE<gt>
 632
 633 =head1 MAINTAINER
 634
 635 This project was originated by Nick Ing-Simmons and later maintained
 636 by Dan Kogai E<lt>dankogai@dan.co.jpE<gt>.  See AUTHORS for full list
 637 of people involved.  For any questions, use
 638 E<lt>perl-unicode@perl.orgE<gt> so others can share.
 639
 640 =cut