ext/Encode/Encode.pm

   1 package Encode;
   2 use strict;
   3 our $VERSION = '0.40';
   4
   5 require DynaLoader;
   6 require Exporter;
   7
   8 our @ISA = qw(Exporter DynaLoader);
   9
  10 # Public, encouraged API is exported by default
  11 our @EXPORT = qw (
  12   encode
  13   decode
  14   encode_utf8
  15   decode_utf8
  16   find_encoding
  17   encodings
  18 );
  19
  20 our @EXPORT_OK =
  21     qw(
  22        define_encoding
  23        define_alias
  24        from_to
  25        is_utf8
  26        is_8bit
  27        is_16bit
  28        utf8_upgrade
  29        utf8_downgrade
  30        _utf8_on
  31        _utf8_off
  32       );
  33
  34 bootstrap Encode ();
  35
  36 # Documentation moved after __END__ for speed - NI-S
  37
  38 use Carp;
  39
  40 # Make a %encoding package variable to allow a certain amount of cheating
  41 our %encoding;
  42 my @alias;  # ordered matching list
  43 my %alias;  # cached known aliases
  44
  45                      # 0  1  2  3  4  5   6   7   8   9  10
  46 our @latin2iso_num = ( 0, 1, 2, 3, 4, 9, 10, 13, 14, 15, 16 );
  47
  48 our %winlatin2cp   = (
  49                       'Latin1'     => 1252,
  50                       'Latin2'     => 1250,
  51                       'Cyrillic'   => 1251,
  52                       'Greek'      => 1253,
  53                       'Turkish'    => 1254,
  54                       'Hebrew'     => 1255,
  55                       'Arabic'     => 1256,
  56                       'Baltic'     => 1257,
  57                       'Vietnamese' => 1258,
  58                      );
  59
  60 our %external_tables =
  61     (
  62         'euc-cn'        => 'Encode/CN.pm',
  63         gb2312          => 'Encode/CN.pm',
  64         gb12345         => 'Encode/CN.pm',
  65         gbk             => 'Encode/CN.pm',
  66         cp936           => 'Encode/CN.pm',
  67         'iso-ir-165'    => 'Encode/CN.pm',
  68         'euc-jp'        => 'Encode/JP.pm',
  69         shiftjis        => 'Encode/JP.pm',
  70         macjapan        => 'Encode/JP.pm',
  71         cp932           => 'Encode/JP.pm',
  72         'euc-kr'        => 'Encode/KR.pm',
  73         ksc5601         => 'Encode/KR.pm',
  74         cp949           => 'Encode/KR.pm',
  75         big5            => 'Encode/TW.pm',
  76         'big5-hkscs'    => 'Encode/TW.pm',
  77         cp950           => 'Encode/TW.pm',
  78         gb18030         => 'Encode/HanExtra.pm',
  79         big5plus        => 'Encode/HanExtra.pm',
  80         'euc-tw'        => 'Encode/HanExtra.pm',
  81     );
  82
  83 sub encodings
  84 {
  85  my ($class) = @_;
  86  return
  87      map { $_->[0] }
  88          sort { $a->[1] cmp $b->[1] }
  89                map { [$_, lc $_] }
  90                    grep { $_ ne 'Internal' }
  91                         keys %encoding;
  92 }
  93
  94 sub findAlias
  95 {
  96     my $class = shift;
  97     local $_ = shift;
  98     # print "# findAlias $_\n";
  99     unless (exists $alias{$_})
 100     {
 101         for (my $i=0; $i < @alias; $i += 2)
 102         {
 103             my $alias = $alias[$i];
 104             my $val   = $alias[$i+1];
 105             my $new;
 106             if (ref($alias) eq 'Regexp' && $_ =~ $alias)
 107             {
 108                 $new = eval $val;
 109             }
 110             elsif (ref($alias) eq 'CODE')
 111             {
 112                 $new = &{$alias}($val)
 113                 }
 114             elsif (lc($_) eq lc($alias))
 115             {
 116                 $new = $val;
 117             }
 118             if (defined($new))
 119             {
 120                 next if $new eq $_; # avoid (direct) recursion on bugs
 121                 my $enc = (ref($new)) ? $new : find_encoding($new);
 122                 if ($enc)
 123                 {
 124                     $alias{$_} = $enc;
 125                     last;
 126                 }
 127             }
 128         }
 129     }
 130     return $alias{$_};
 131 }
 132
 133 sub define_alias
 134 {
 135     while (@_)
 136     {
 137         my ($alias,$name) = splice(@_,0,2);
 138         push(@alias, $alias => $name);
 139     }
 140 }
 141
 142 # Allow variants of iso-8859-1 etc.
 143 define_alias( qr/^iso[-_]?(\d+)[-_](\d+)$/i => '"iso-$1-$2"' );
 144
 145 # At least HP-UX has these.
 146 define_alias( qr/^iso8859(\d+)$/i => '"iso-8859-$1"' );
 147
 148 # More HP stuff.
 149 define_alias( qr/^(?:hp-)?(arabic|greek|hebrew|kana|roman|thai|turkish)8$/i => '"${1}8"' );
 150
 151 # The Official name of ASCII.
 152 define_alias( qr/^ANSI[-_]?X3\.4[-_]?1968$/i => '"ascii"' );
 153
 154 # This is a font issue, not an encoding issue.
 155 # (The currency symbol of the Latin 1 upper half
 156 #  has been redefined as the euro symbol.)
 157 define_alias( qr/^(.+)\@euro$/i => '"$1"' );
 158
 159 # Allow latin-1 style names as well
 160 define_alias( qr/^(?:iso[-_]?)?latin[-_]?(\d+)$/i => '"iso-8859-$latin2iso_num[$1]"' );
 161
 162 # Allow winlatin1 style names as well
 163 define_alias( qr/^win(latin[12]|cyrillic|baltic|greek|turkish|hebrew|arabic|baltic|vietnamese)$/i => '"cp$winlatin2cp{\u$1}"' );
 164
 165 # Common names for non-latin prefered MIME names
 166 define_alias( 'ascii'    => 'US-ascii',
 167               'cyrillic' => 'iso-8859-5',
 168               'arabic'   => 'iso-8859-6',
 169               'greek'    => 'iso-8859-7',
 170               'hebrew'   => 'iso-8859-8',
 171               'thai'     => 'iso-8859-11',
 172               'tis620'   => 'iso-8859-11',
 173             );
 174
 175 # At least AIX has IBM-NNN (surprisingly...) instead of cpNNN.
 176 # And Microsoft has their own naming (again, surprisingly).
 177 define_alias( qr/^(?:ibm|ms)[-_]?(\d\d\d\d?)$/i => '"cp$1"');
 178
 179 # Sometimes seen with a leading zero.
 180 define_alias( qr/^cp037$/i => '"cp37"');
 181
 182 # Ououououou.
 183 define_alias( qr/^macRomanian$/i => '"macRumanian"');
 184
 185 # Standardize on the dashed versions.
 186 define_alias( qr/^utf8$/i  => 'utf-8' );
 187 define_alias( qr/^koi8r$/i => 'koi8-r' );
 188 define_alias( qr/^koi8u$/i => 'koi8-u' );
 189
 190 # Seen in some Linuxes.
 191 define_alias( qr/^ujis$/i => 'euc-jp' );
 192
 193 # CP936 doesn't have vendor-addon for GBK, so they're identical.
 194 define_alias( qr/^gbk$/i => '"cp936"');
 195
 196 # TODO: HP-UX '8' encodings arabic8 greek8 hebrew8 kana8 thai8 turkish8
 197 # TODO: HP-UX '15' encodings japanese15 korean15 roi15
 198 # TODO: Cyrillic encoding ISO-IR-111 (useful?)
 199 # TODO: Armenian encoding ARMSCII-8
 200 # TODO: Hebrew encoding ISO-8859-8-1
 201 # TODO: Thai encoding TCVN
 202 # TODO: Korean encoding Johab
 203 # TODO: Vietnamese encodings VPS
 204 # TODO: Japanese encoding JIS (not the same as SJIS)
 205 # TODO: Mac Asian+African encodings: Arabic Armenian Bengali Burmese
 206 #       ChineseSimp ChineseTrad Devanagari Ethiopic ExtArabic
 207 #       Farsi Georgian Gujarati Gurmukhi Hebrew Japanese
 208 #       Kannada Khmer Korean Laotian Malayalam Mongolian
 209 #       Oriya Sinhalese Symbol Tamil Telugu Tibetan Vietnamese
 210
 211 # Map white space and _ to '-'
 212 define_alias( qr/^(\S+)[\s_]+(.*)$/i => '"$1-$2"' );
 213
 214 sub define_encoding
 215 {
 216     my $obj  = shift;
 217     my $name = shift;
 218     $encoding{$name} = $obj;
 219     my $lc = lc($name);
 220     define_alias($lc => $obj) unless $lc eq $name;
 221     while (@_)
 222     {
 223         my $alias = shift;
 224         define_alias($alias,$obj);
 225     }
 226     return $obj;
 227 }
 228
 229 sub getEncoding
 230 {
 231     my ($class,$name,$skip_external) = @_;
 232     my $enc;
 233     if (ref($name) && $name->can('new_sequence'))
 234     {
 235         return $name;
 236     }
 237     my $lc = lc $name;
 238     if (exists $encoding{$name})
 239     {
 240         return $encoding{$name};
 241     }
 242     if (exists $encoding{$lc})
 243     {
 244         return $encoding{$lc};
 245     }
 246
 247     my $oc = $class->findAlias($name);
 248     return $oc if defined $oc;
 249
 250     $oc = $class->findAlias($lc) if $lc ne $name;
 251     return $oc if defined $oc;
 252
 253     if (!$skip_external and exists $external_tables{$lc})
 254     {
 255         require $external_tables{$lc};
 256         return $encoding{$name} if exists $encoding{$name};
 257     }
 258
 259     return;
 260 }
 261
 262 sub find_encoding
 263 {
 264     my ($name,$skip_external) = @_;
 265     return __PACKAGE__->getEncoding($name,$skip_external);
 266 }
 267
 268 sub encode
 269 {
 270     my ($name,$string,$check) = @_;
 271     my $enc = find_encoding($name);
 272     croak("Unknown encoding '$name'") unless defined $enc;
 273     my $octets = $enc->encode($string,$check);
 274     return undef if ($check && length($string));
 275     return $octets;
 276 }
 277
 278 sub decode
 279 {
 280     my ($name,$octets,$check) = @_;
 281     my $enc = find_encoding($name);
 282     croak("Unknown encoding '$name'") unless defined $enc;
 283     my $string = $enc->decode($octets,$check);
 284     $_[1] = $octets if $check;
 285     return $string;
 286 }
 287
 288 sub from_to
 289 {
 290     my ($string,$from,$to,$check) = @_;
 291     my $f = find_encoding($from);
 292     croak("Unknown encoding '$from'") unless defined $f;
 293     my $t = find_encoding($to);
 294     croak("Unknown encoding '$to'") unless defined $t;
 295     my $uni = $f->decode($string,$check);
 296     return undef if ($check && length($string));
 297     $string = $t->encode($uni,$check);
 298     return undef if ($check && length($uni));
 299     return length($_[0] = $string);
 300 }
 301
 302 sub encode_utf8
 303 {
 304     my ($str) = @_;
 305   utf8::encode($str);
 306     return $str;
 307 }
 308
 309 sub decode_utf8
 310 {
 311     my ($str) = @_;
 312     return undef unless utf8::decode($str);
 313     return $str;
 314 }
 315
 316 require Encode::Encoding;
 317 require Encode::XS;
 318 require Encode::Internal;
 319 require Encode::Unicode;
 320 require Encode::utf8;
 321 require Encode::iso10646_1;
 322 require Encode::ucs2_le;
 323
 324 1;
 325
 326 __END__
 327
 328 =head1 NAME
 329
 330 Encode - character encodings
 331
 332 =head1 SYNOPSIS
 333
 334     use Encode;
 335
 336 =head1 DESCRIPTION
 337
 338 The C<Encode> module provides the interfaces between Perl's strings
 339 and the rest of the system.  Perl strings are sequences of B<characters>.
 340
 341 The repertoire of characters that Perl can represent is at least that
 342 defined by the Unicode Consortium. On most platforms the ordinal
 343 values of the characters (as returned by C<ord(ch)>) is the "Unicode
 344 codepoint" for the character (the exceptions are those platforms where
 345 the legacy encoding is some variant of EBCDIC rather than a super-set
 346 of ASCII - see L<perlebcdic>).
 347
 348 Traditionaly computer data has been moved around in 8-bit chunks
 349 often called "bytes". These chunks are also known as "octets" in
 350 networking standards. Perl is widely used to manipulate data of
 351 many types - not only strings of characters representing human or
 352 computer languages but also "binary" data being the machines representation
 353 of numbers, pixels in an image - or just about anything.
 354
 355 When Perl is processing "binary data" the programmer wants Perl to process
 356 "sequences of bytes". This is not a problem for Perl - as a byte has 256
 357 possible values it easily fits in Perl's much larger "logical character".
 358
 359 Due to size concerns, each of B<CJK> (Chinese, Japanese & Korean) modules
 360 are not loaded in memory until the first time they're used. Although you
 361 don't have to C<use> the corresponding B<Encode::>(B<TW>|B<CN>|B<JP>|B<KR>)
 362 modules first, be aware that those encodings will not be in C<%encodings>
 363 until their module is loaded (either implicitly through using encodings
 364 contained in the same module, or via an explicit C<use>).
 365
 366 =head2 TERMINOLOGY
 367
 368 =over 4
 369
 370 =item *
 371
 372 I<character>: a character in the range 0..(2**32-1) (or more).
 373 (What Perl's strings are made of.)
 374
 375 =item *
 376
 377 I<byte>: a character in the range 0..255
 378 (A special case of a Perl character.)
 379
 380 =item *
 381
 382 I<octet>: 8 bits of data, with ordinal values 0..255
 383 (Term for bytes passed to or from a non-Perl context, e.g. disk file.)
 384
 385 =back
 386
 387 The marker [INTERNAL] marks Internal Implementation Details, in
 388 general meant only for those who think they know what they are doing,
 389 and such details may change in future releases.
 390
 391 =head1 ENCODINGS
 392
 393 =head2 Characteristics of an Encoding
 394
 395 An encoding has a "repertoire" of characters that it can represent,
 396 and for each representable character there is at least one sequence of
 397 octets that represents it.
 398
 399 =head2 Types of Encodings
 400
 401 Encodings can be divided into the following types:
 402
 403 =over 4
 404
 405 =item * Fixed length 8-bit (or less) encodings.
 406
 407 Each character is a single octet so may have a repertoire of up to
 408 256 characters. ASCII and iso-8859-* are typical examples.
 409
 410 =item * Fixed length 16-bit encodings
 411
 412 Each character is two octets so may have a repertoire of up to
 413 65 536 characters.  Unicode's UCS-2 is an example.  Also used for
 414 encodings for East Asian languages.
 415
 416 =item * Fixed length 32-bit encodings.
 417
 418 Not really very "encoded" encodings. The Unicode code points
 419 are just represented as 4-octet integers. None the less because
 420 different architectures use different representations of integers
 421 (so called "endian") there at least two disctinct encodings.
 422
 423 =item * Multi-byte encodings
 424
 425 The number of octets needed to represent a character varies.
 426 UTF-8 is a particularly complex but regular case of a multi-byte
 427 encoding. Several East Asian countries use a multi-byte encoding
 428 where 1-octet is used to cover western roman characters and Asian
 429 characters get 2-octets.
 430 (UTF-16 is strictly a multi-byte encoding taking either 2 or 4 octets
 431 to represent a Unicode code point.)
 432
 433 =item * "Escape" encodings.
 434
 435 These encodings embed "escape sequences" into the octet sequence
 436 which describe how the following octets are to be interpreted.
 437 The iso-2022-* family is typical. Following the escape sequence
 438 octets are encoded by an "embedded" encoding (which will be one
 439 of the above types) until another escape sequence switches to
 440 a different "embedded" encoding.
 441
 442 These schemes are very flexible and can handle mixed languages but are
 443 very complex to process (and have state).  No escape encodings are
 444 implemented for Perl yet.
 445
 446 =back
 447
 448 =head2 Specifying Encodings
 449
 450 Encodings can be specified to the API described below in two ways:
 451
 452 =over 4
 453
 454 =item 1. By name
 455
 456 Encoding names are strings with characters taken from a restricted
 457 repertoire.  See L</"Encoding Names">.
 458
 459 =item 2. As an object
 460
 461 Encoding objects are returned by C<find_encoding($name, [$skip_external])>.
 462 If the second parameter is true, Encode will refrain from loading external
 463 modules for CJK encodings.
 464
 465 =back
 466
 467 =head2 Encoding Names
 468
 469 Encoding names are case insensitive. White space in names is ignored.
 470 In addition an encoding may have aliases. Each encoding has one
 471 "canonical" name.  The "canonical" name is chosen from the names of
 472 the encoding by picking the first in the following sequence:
 473
 474 =over 4
 475
 476 =item * The MIME name as defined in IETF RFCs.
 477
 478 =item * The name in the IANA registry.
 479
 480 =item * The name used by the organization that defined it.
 481
 482 =back
 483
 484 Because of all the alias issues, and because in the general case
 485 encodings have state C<Encode> uses the encoding object internally
 486 once an operation is in progress.
 487
 488 As of Perl 5.8.0, at least the following encodings are recognized
 489 (the => marks aliases):
 490
 491   ASCII
 492
 493   US-ASCII => ASCII
 494
 495 The Unicode:
 496
 497   UTF-8
 498   UTF-16
 499   UCS-2
 500
 501   ISO 10646-1 => UCS-2
 502
 503 The ISO 8859 and KOI:
 504
 505   ISO 8859-1  ISO 8859-6   ISO 8859-11         KOI8-F
 506   ISO 8859-2  ISO 8859-7   (12 doesn't exist)  KOI8-R
 507   ISO 8859-3  ISO 8859-8   ISO 8859-13         KOI8-U
 508   ISO 8859-4  ISO 8859-9   ISO 8859-14
 509   ISO 8859-5  ISO 8859-10  ISO 8859-15
 510                            ISO 8859-16
 511
 512   Latin1  => 8859-1  Latin6  => 8859-10
 513   Latin2  => 8859-2  Latin7  => 8859-13
 514   Latin3  => 8859-3  Latin8  => 8859-14
 515   Latin4  => 8859-4  Latin9  => 8859-15
 516   Latin5  => 8859-9  Latin10 => 8859-16
 517
 518   Cyrillic => 8859-5
 519   Arabic   => 8859-6
 520   Greek    => 8859-7
 521   Hebrew   => 8859-8
 522   Thai     => 8859-11
 523   TIS620   => 8859-11
 524
 525 The CJKV: Chinese, Japanese, Korean, Vietnamese:
 526
 527   ISO 2022     ISO 2022 JP-1  JIS 0201  GB 1988   Big5       EUC-CN
 528   ISO 2022 CN  ISO 2022 JP-2  JIS 0208  GB 2312   HZ         EUC-JP
 529   ISO 2022 JP  ISO 2022 KR    JIS 0210  GB 12345  CNS 11643  EUC-JP-0212
 530   Shift-JIS                             GBK       Big5-HKSCS EUC-KR
 531   VISCII                                ISO-IR-165
 532
 533 (Due to size concerns, additional Chinese encodings including C<GB 18030>,
 534 C<EUC-TW> and C<BIG5PLUS> are distributed separately on CPAN, under the name
 535 L<Encode::HanExtra>.)
 536
 537 The PC codepages:
 538
 539   CP37   CP852  CP861  CP866  CP949   CP1251  CP1256
 540   CP424  CP855  CP862  CP869  CP950   CP1252  CP1257
 541   CP737  CP856  CP863  CP874  CP1006  CP1253  CP1258
 542   CP775  CP857  CP864  CP932  CP1047  CP1254
 543   CP850  CP860  CP865  CP936  CP1250  CP1255
 544
 545   WinLatin1     => CP1252
 546   WinLatin2     => CP1250
 547   WinCyrillic   => CP1251
 548   WinGreek      => CP1253
 549   WinTurkiskh   => CP1254
 550   WinHebrew     => CP1255
 551   WinArabic     => CP1256
 552   WinBaltic     => CP1257
 553   WinVietnamese => CP1258
 554
 555 (All the CPI<NNN...> are available also as IBMI<NNN...>.)
 556
 557 The Mac codepages:
 558
 559   MacCentralEuropean   MacJapanese
 560   MacCroatian          MacRoman
 561   MacCyrillic          MacRomanian
 562   MacDingbats          MacSami
 563   MacGreek             MacThai
 564   MacIcelandic         MacTurkish
 565                        MacUkraine
 566
 567 Miscellaneous:
 568
 569   7bit-greek  IR-197
 570   7bit-kana   NeXTstep
 571   7bit-latin1 POSIX-BC
 572   DingBats    Roman8
 573   GSM 0338    Symbol
 574
 575 =head1 PERL ENCODING API
 576
 577 =head2 Generic Encoding Interface
 578
 579 =over 4
 580
 581 =item *
 582
 583         $bytes  = encode(ENCODING, $string[, CHECK])
 584
 585 Encodes string from Perl's internal form into I<ENCODING> and returns
 586 a sequence of octets.  For CHECK see L</"Handling Malformed Data">.
 587
 588 For example to convert (internally UTF-8 encoded) Unicode data
 589 to octets:
 590
 591         $octets = encode("utf8", $unicode);
 592
 593 =item *
 594
 595         $string = decode(ENCODING, $bytes[, CHECK])
 596
 597 Decode sequence of octets assumed to be in I<ENCODING> into Perl's
 598 internal form and returns the resulting string.  For CHECK see
 599 L</"Handling Malformed Data">.
 600
 601 For example to convert ISO 8859-1 data to UTF-8:
 602
 603         $utf8 = decode("latin1", $latin1);
 604
 605 =item *
 606
 607         from_to($string, FROM_ENCODING, TO_ENCODING[, CHECK])
 608
 609 Convert B<in-place> the data between two encodings.  How did the data
 610 in $string originally get to be in FROM_ENCODING?  Either using
 611 encode() or through PerlIO: See L</"Encoding and IO">.  For CHECK
 612 see L</"Handling Malformed Data">.
 613
 614 For example to convert ISO 8859-1 data to UTF-8:
 615
 616         from_to($data, "iso-8859-1", "utf-8");
 617
 618 and to convert it back:
 619
 620         from_to($data, "utf-8", "iso-8859-1");
 621
 622 Note that because the conversion happens in place, the data to be
 623 converted cannot be a string constant, it must be a scalar variable.
 624
 625 =back
 626
 627 =head2 Handling Malformed Data
 628
 629 If CHECK is not set, C<undef> is returned.  If the data is supposed to
 630 be UTF-8, an optional lexical warning (category utf8) is given.  If
 631 CHECK is true but not a code reference, dies.
 632
 633 It would desirable to have a way to indicate that transform should use
 634 the encodings "replacement character" - no such mechanism is defined yet.
 635
 636 It is also planned to allow I<CHECK> to be a code reference.
 637
 638 This is not yet implemented as there are design issues with what its
 639 arguments should be and how it returns its results.
 640
 641 =over 4
 642
 643 =item Scheme 1
 644
 645 Passed remaining fragment of string being processed.
 646 Modifies it in place to remove bytes/characters it can understand
 647 and returns a string used to represent them.
 648 e.g.
 649
 650  sub fixup {
 651    my $ch = substr($_[0],0,1,'');
 652    return sprintf("\x{%02X}",ord($ch);
 653  }
 654
 655 This scheme is close to how underlying C code for Encode works, but gives
 656 the fixup routine very little context.
 657
 658 =item Scheme 2
 659
 660 Passed original string, and an index into it of the problem area, and
 661 output string so far.  Appends what it will to output string and
 662 returns new index into original string.  For example:
 663
 664  sub fixup {
 665    # my ($s,$i,$d) = @_;
 666    my $ch = substr($_[0],$_[1],1);
 667    $_[2] .= sprintf("\x{%02X}",ord($ch);
 668    return $_[1]+1;
 669  }
 670
 671 This scheme gives maximal control to the fixup routine but is more
 672 complicated to code, and may need internals of Encode to be tweaked to
 673 keep original string intact.
 674
 675 =item Other Schemes
 676
 677 Hybrids of above.
 678
 679 Multiple return values rather than in-place modifications.
 680
 681 Index into the string could be pos($str) allowing s/\G...//.
 682
 683 =back
 684
 685 =head2 UTF-8 / utf8
 686
 687 The Unicode consortium defines the UTF-8 standard as a way of encoding
 688 the entire Unicode repertiore as sequences of octets.  This encoding is
 689 expected to become very widespread. Perl can use this form internaly
 690 to represent strings, so conversions to and from this form are
 691 particularly efficient (as octets in memory do not have to change,
 692 just the meta-data that tells Perl how to treat them).
 693
 694 =over 4
 695
 696 =item *
 697
 698         $bytes = encode_utf8($string);
 699
 700 The characters that comprise string are encoded in Perl's superset of UTF-8
 701 and the resulting octets returned as a sequence of bytes. All possible
 702 characters have a UTF-8 representation so this function cannot fail.
 703
 704 =item *
 705
 706         $string = decode_utf8($bytes [,CHECK]);
 707
 708 The sequence of octets represented by $bytes is decoded from UTF-8
 709 into a sequence of logical characters. Not all sequences of octets
 710 form valid UTF-8 encodings, so it is possible for this call to fail.
 711 For CHECK see L</"Handling Malformed Data">.
 712
 713 =back
 714
 715 =head2 Other Encodings of Unicode
 716
 717 UTF-16 is similar to UCS-2, 16 bit or 2-byte chunks.  UCS-2 can only
 718 represent 0..0xFFFF, while UTF-16 has a I<surrogate pair> scheme which
 719 allows it to cover the whole Unicode range.
 720
 721 Surrogates are code points set aside to encode the 0x01000..0x10FFFF
 722 range of Unicode code points in pairs of 16-bit units.  The I<high
 723 surrogates> are the range 0xD800..0xDBFF, and the I<low surrogates>
 724 are the range 0xDC00..0xDFFFF.  The surrogate encoding is
 725
 726         $hi = ($uni - 0x10000) / 0x400 + 0xD800;
 727         $lo = ($uni - 0x10000) % 0x400 + 0xDC00;
 728
 729 and the decoding is
 730
 731         $uni = 0x10000 + ($hi - 0xD8000) * 0x400 + ($lo - 0xDC00);
 732
 733 Encode implements big-endian UCS-2 aliased to "iso-10646-1" as that
 734 happens to be the name used by that representation when used with X11
 735 fonts.
 736
 737 UTF-32 or UCS-4 is 32-bit or 4-byte chunks.  Perl's logical characters
 738 can be considered as being in this form without encoding. An encoding
 739 to transfer strings in this form (e.g. to write them to a file) would
 740 need to
 741
 742      pack('L*', unpack('U*', $string));  # native
 743   or
 744      pack('V*', unpack('U*', $string));  # little-endian
 745   or
 746      pack('N*', unpack('U*', $string));  # big-endian
 747
 748 depending on the endianness required.
 749
 750 No UTF-32 encodings are implemented yet.
 751
 752 Both UCS-2 and UCS-4 style encodings can have "byte order marks" by
 753 representing the code point 0xFFFE as the very first thing in a file.
 754
 755 =head2 Listing available encodings
 756
 757   use Encode qw(encodings);
 758   @list = encodings();
 759
 760 Returns a list of the canonical names of the available encodings.
 761
 762 =head2 Defining Aliases
 763
 764   use Encode qw(define_alias);
 765   define_alias( newName => ENCODING);
 766
 767 Allows newName to be used as am alias for ENCODING. ENCODING may be
 768 either the name of an encoding or and encoding object (as above).
 769
 770 Currently I<newName> can be specified in the following ways:
 771
 772 =over 4
 773
 774 =item As a simple string.
 775
 776 =item As a qr// compiled regular expression, e.g.:
 777
 778   define_alias( qr/^iso8859-(\d+)$/i => '"iso-8859-$1"' );
 779
 780 In this case if I<ENCODING> is not a reference it is C<eval>-ed to
 781 allow C<$1> etc. to be subsituted.  The example is one way to names as
 782 used in X11 font names to alias the MIME names for the iso-8859-*
 783 family.
 784
 785 =item As a code reference, e.g.:
 786
 787   define_alias( sub { return /^iso8859-(\d+)$/i ? "iso-8859-$1" : undef } , '');
 788
 789 In this case C<$_> will be set to the name that is being looked up and
 790 I<ENCODING> is passed to the sub as its first argument.  The example
 791 is another way to names as used in X11 font names to alias the MIME
 792 names for the iso-8859-* family.
 793
 794 =back
 795
 796 =head2 Defining Encodings
 797
 798     use Encode qw(define_alias);
 799     define_encoding( $object, 'canonicalName' [,alias...]);
 800
 801 Causes I<canonicalName> to be associated with I<$object>.  The object
 802 should provide the interface described in L</"IMPLEMENTATION CLASSES">
 803 below.  If more than two arguments are provided then additional
 804 arguments are taken as aliases for I<$object> as for C<define_alias>.
 805
 806 =head1 Encoding and IO
 807
 808 It is very common to want to do encoding transformations when
 809 reading or writing files, network connections, pipes etc.
 810 If Perl is configured to use the new 'perlio' IO system then
 811 C<Encode> provides a "layer" (See L<perliol>) which can transform
 812 data as it is read or written.
 813
 814 Here is how the blind poet would modernise the encoding:
 815
 816     use Encode;
 817     open(my $iliad,'<:encoding(iso-8859-7)','iliad.greek');
 818     open(my $utf8,'>:utf8','iliad.utf8');
 819     my @epic = <$iliad>;
 820     print $utf8 @epic;
 821     close($utf8);
 822     close($illiad);
 823
 824 In addition the new IO system can also be configured to read/write
 825 UTF-8 encoded characters (as noted above this is efficient):
 826
 827     open(my $fh,'>:utf8','anything');
 828     print $fh "Any \x{0021} string \N{SMILEY FACE}\n";
 829
 830 Either of the above forms of "layer" specifications can be made the default
 831 for a lexical scope with the C<use open ...> pragma. See L<open>.
 832
 833 Once a handle is open is layers can be altered using C<binmode>.
 834
 835 Without any such configuration, or if Perl itself is built using
 836 system's own IO, then write operations assume that file handle accepts
 837 only I<bytes> and will C<die> if a character larger than 255 is
 838 written to the handle. When reading, each octet from the handle
 839 becomes a byte-in-a-character. Note that this default is the same
 840 behaviour as bytes-only languages (including Perl before v5.6) would
 841 have, and is sufficient to handle native 8-bit encodings
 842 e.g. iso-8859-1, EBCDIC etc. and any legacy mechanisms for handling
 843 other encodings and binary data.
 844
 845 In other cases it is the programs responsibility to transform
 846 characters into bytes using the API above before doing writes, and to
 847 transform the bytes read from a handle into characters before doing
 848 "character operations" (e.g. C<lc>, C</\W+/>, ...).
 849
 850 You can also use PerlIO to convert larger amounts of data you don't
 851 want to bring into memory.  For example to convert between ISO 8859-1
 852 (Latin 1) and UTF-8 (or UTF-EBCDIC in EBCDIC machines):
 853
 854     open(F, "<:encoding(iso-8859-1)", "data.txt") or die $!;
 855     open(G, ">:utf8",                 "data.utf") or die $!;
 856     while (<F>) { print G }
 857
 858     # Could also do "print G <F>" but that would pull
 859     # the whole file into memory just to write it out again.
 860
 861 More examples:
 862
 863     open(my $f, "<:encoding(cp1252)")
 864     open(my $g, ">:encoding(iso-8859-2)")
 865     open(my $h, ">:encoding(latin9)")       # iso-8859-15
 866
 867 See L<PerlIO> for more information.
 868
 869 See also L<encoding> for how to change the default encoding of the
 870 data in your script.
 871
 872 =head1 Encoding How to ...
 873
 874 To do:
 875
 876 =over 4
 877
 878 =item * IO with mixed content (faking iso-2020-*)
 879
 880 =item * MIME's Content-Length:
 881
 882 =item * UTF-8 strings in binary data.
 883
 884 =item * Perl/Encode wrappers on non-Unicode XS modules.
 885
 886 =back
 887
 888 =head1 Messing with Perl's Internals
 889
 890 The following API uses parts of Perl's internals in the current
 891 implementation.  As such they are efficient, but may change.
 892
 893 =over 4
 894
 895 =item * is_utf8(STRING [, CHECK])
 896
 897 [INTERNAL] Test whether the UTF-8 flag is turned on in the STRING.
 898 If CHECK is true, also checks the data in STRING for being well-formed
 899 UTF-8.  Returns true if successful, false otherwise.
 900
 901 =item * valid_utf8(STRING)
 902
 903 [INTERNAL] Test whether STRING is in a consistent state.  Will return
 904 true if string is held as bytes, or is well-formed UTF-8 and has the
 905 UTF-8 flag on.  Main reason for this routine is to allow Perl's
 906 testsuite to check that operations have left strings in a consistent
 907 state.
 908
 909 =item *
 910
 911         _utf8_on(STRING)
 912
 913 [INTERNAL] Turn on the UTF-8 flag in STRING.  The data in STRING is
 914 B<not> checked for being well-formed UTF-8.  Do not use unless you
 915 B<know> that the STRING is well-formed UTF-8.  Returns the previous
 916 state of the UTF-8 flag (so please don't test the return value as
 917 I<not> success or failure), or C<undef> if STRING is not a string.
 918
 919 =item *
 920
 921         _utf8_off(STRING)
 922
 923 [INTERNAL] Turn off the UTF-8 flag in STRING.  Do not use frivolously.
 924 Returns the previous state of the UTF-8 flag (so please don't test the
 925 return value as I<not> success or failure), or C<undef> if STRING is
 926 not a string.
 927
 928 =back
 929
 930 =head1 IMPLEMENTATION CLASSES
 931
 932 As mentioned above encodings are (in the current implementation at least)
 933 defined by objects. The mapping of encoding name to object is via the
 934 C<%encodings> hash.
 935
 936 The values of the hash can currently be either strings or objects.
 937 The string form may go away in the future. The string form occurs
 938 when C<encodings()> has scanned C<@INC> for loadable encodings but has
 939 not actually loaded the encoding in question. This is because the
 940 current "loading" process is all Perl and a bit slow.
 941
 942 Once an encoding is loaded then value of the hash is object which
 943 implements the encoding. The object should provide the following
 944 interface:
 945
 946 =over 4
 947
 948 =item -E<gt>name
 949
 950 Should return the string representing the canonical name of the encoding.
 951
 952 =item -E<gt>new_sequence
 953
 954 This is a placeholder for encodings with state. It should return an
 955 object which implements this interface, all current implementations
 956 return the original object.
 957
 958 =item -E<gt>encode($string,$check)
 959
 960 Should return the octet sequence representing I<$string>. If I<$check>
 961 is true it should modify I<$string> in place to remove the converted
 962 part (i.e.  the whole string unless there is an error).  If an error
 963 occurs it should return the octet sequence for the fragment of string
 964 that has been converted, and modify $string in-place to remove the
 965 converted part leaving it starting with the problem fragment.
 966
 967 If check is is false then C<encode> should make a "best effort" to
 968 convert the string - for example by using a replacement character.
 969
 970 =item -E<gt>decode($octets,$check)
 971
 972 Should return the string that I<$octets> represents. If I<$check> is
 973 true it should modify I<$octets> in place to remove the converted part
 974 (i.e.  the whole sequence unless there is an error).  If an error
 975 occurs it should return the fragment of string that has been
 976 converted, and modify $octets in-place to remove the converted part
 977 leaving it starting with the problem fragment.
 978
 979 If check is is false then C<decode> should make a "best effort" to
 980 convert the string - for example by using Unicode's "\x{FFFD}" as a
 981 replacement character.
 982
 983 =back
 984
 985 It should be noted that the check behaviour is different from the
 986 outer public API. The logic is that the "unchecked" case is useful
 987 when encoding is part of a stream which may be reporting errors
 988 (e.g. STDERR).  In such cases it is desirable to get everything
 989 through somehow without causing additional errors which obscure the
 990 original one. Also the encoding is best placed to know what the
 991 correct replacement character is, so if that is the desired behaviour
 992 then letting low level code do it is the most efficient.
 993
 994 In contrast if check is true, the scheme above allows the encoding to
 995 do as much as it can and tell layer above how much that was. What is
 996 lacking at present is a mechanism to report what went wrong. The most
 997 likely interface will be an additional method call to the object, or
 998 perhaps (to avoid forcing per-stream objects on otherwise stateless
 999 encodings) and additional parameter.
1000
1001 It is also highly desirable that encoding classes inherit from
1002 C<Encode::Encoding> as a base class. This allows that class to define
1003 additional behaviour for all encoding objects. For example built in
1004 Unicode, UCS-2 and UTF-8 classes use :
1005
1006   package Encode::MyEncoding;
1007   use base qw(Encode::Encoding);
1008
1009   __PACKAGE__->Define(qw(myCanonical myAlias));
1010
1011 To create an object with bless {Name => ...},$class, and call
1012 define_encoding.  They inherit their C<name> method from
1013 C<Encode::Encoding>.
1014
1015 =head2 Compiled Encodings
1016
1017 F<Encode.xs> provides a class C<Encode::XS> which provides the
1018 interface described above. It calls a generic octet-sequence to
1019 octet-sequence "engine" that is driven by tables (defined in
1020 F<encengine.c>). The same engine is used for both encode and
1021 decode. C<Encode:XS>'s C<encode> forces Perl's characters to their
1022 UTF-8 form and then treats them as just another multibyte
1023 encoding. C<Encode:XS>'s C<decode> transforms the sequence and then
1024 turns the UTF-8-ness flag as that is the form that the tables are
1025 defined to produce. For details of the engine see the comments in
1026 F<encengine.c>.
1027
1028 The tables are produced by the Perl script F<compile> (the name needs
1029 to change so we can eventually install it somewhere). F<compile> can
1030 currently read two formats:
1031
1032 =over 4
1033
1034 =item *.enc
1035
1036 This is a coined format used by Tcl. It is documented in
1037 Encode/EncodeFormat.pod.
1038
1039 =item *.ucm
1040
1041 This is the semi-standard format used by IBM's ICU package.
1042
1043 =back
1044
1045 F<compile> can write the following forms:
1046
1047 =over 4
1048
1049 =item *.ucm
1050
1051 See above - the F<Encode/*.ucm> files provided with the distribution have
1052 been created from the original Tcl .enc files using this approach.
1053
1054 =item *.c
1055
1056 Produces tables as C data structures - this is used to build in encodings
1057 into F<Encode.so>/F<Encode.dll>.
1058
1059 =item *.xs
1060
1061 In theory this allows encodings to be stand-alone loadable Perl
1062 extensions.  The process has not yet been tested. The plan is to use
1063 this approach for large East Asian encodings.
1064
1065 =back
1066
1067 The set of encodings built-in to F<Encode.so>/F<Encode.dll> is
1068 determined by F<Makefile.PL>.  The current set is as follows:
1069
1070 =over 4
1071
1072 =item ascii and iso-8859-*
1073
1074 That is all the common 8-bit "western" encodings.
1075
1076 =item IBM-1047 and two other variants of EBCDIC.
1077
1078 These are the same variants that are supported by EBCDIC Perl as
1079 "native" encodings.  They are included to prove "reversibility" of
1080 some constructs in EBCDIC Perl.
1081
1082 =item symbol and dingbats as used by Tk on X11.
1083
1084 (The reason Encode got started was to support Perl/Tk.)
1085
1086 =back
1087
1088 That set is rather ad hoc and has been driven by the needs of the
1089 tests rather than the needs of typical applications. It is likely
1090 to be rationalized.
1091
1092 =head1 SEE ALSO
1093
1094 L<perlunicode>, L<perlebcdic>, L<perlfunc/open>, L<PerlIO>, L<encoding>
1095
1096 =cut
1097