ext/Encode/Encode.pm

   1 package Encode;
   2 use strict;
   3 our $VERSION = do { my @r = (q$Revision: 1.56 $ =~ /\d+/g); sprintf "%d."."%02d" x $#r, @r };
   4 our $DEBUG = 0;
   5 use XSLoader ();
   6 XSLoader::load 'Encode';
   7
   8 require Exporter;
   9 our @ISA = qw(Exporter);
  10
  11 # Public, encouraged API is exported by default
  12
  13 our @EXPORT = qw(
  14   decode  decode_utf8  encode  encode_utf8
  15   encodings  find_encoding
  16 );
  17
  18 our @FB_FLAGS  = qw(DIE_ON_ERR WARN_ON_ERR RETURN_ON_ERR LEAVE_SRC PERLQQ);
  19 our @FB_CONSTS = qw(FB_DEFAULT FB_QUIET FB_WARN FB_PERLQQ FB_CROAK);
  20
  21 our @EXPORT_OK =
  22     (
  23      qw(
  24        _utf8_off _utf8_on define_encoding from_to is_16bit is_8bit
  25        is_utf8 perlio_ok resolve_alias utf8_downgrade utf8_upgrade
  26       ),
  27      @FB_FLAGS, @FB_CONSTS,
  28     );
  29
  30 our %EXPORT_TAGS =
  31     (
  32      all          =>  [ @EXPORT, @EXPORT_OK ],
  33      fallbacks    =>  [ @FB_CONSTS ],
  34      fallback_all =>  [ @FB_CONSTS, @FB_FLAGS ],
  35     );
  36
  37 # Documentation moved after __END__ for speed - NI-S
  38
  39 use Carp;
  40
  41 our $ON_EBCDIC = (ord("A") == 193);
  42
  43 use Encode::Alias;
  44
  45 # Make a %Encoding package variable to allow a certain amount of cheating
  46 our %Encoding;
  47 our %ExtModule;
  48 require Encode::Config;
  49 eval { require Encode::ConfigLocal };
  50
  51 sub encodings
  52 {
  53     my $class = shift;
  54     my @modules = (@_ and $_[0] eq ":all") ? values %ExtModule : @_;
  55     for my $mod (@modules){
  56         $mod =~ s,::,/,g or $mod = "Encode/$mod";
  57         $mod .= '.pm';
  58         $DEBUG and warn "about to require $mod;";
  59         eval { require $mod; };
  60     }
  61     my %modules = map {$_ => 1} @modules;
  62     return
  63         sort { lc $a cmp lc $b }
  64              grep {!/^(?:Internal|Unicode)$/o} keys %Encoding;
  65 }
  66
  67 sub perlio_ok{
  68     exists $INC{"PerlIO/encoding.pm"} or return 0;
  69     my $obj = ref($_[0]) ? $_[0] : find_encoding($_[0]);
  70     $obj->can("perlio_ok") and return $obj->perlio_ok() unless $@;
  71     return 0; # safety net
  72 }
  73
  74 sub define_encoding
  75 {
  76     my $obj  = shift;
  77     my $name = shift;
  78     $Encoding{$name} = $obj;
  79     my $lc = lc($name);
  80     define_alias($lc => $obj) unless $lc eq $name;
  81     while (@_)
  82     {
  83         my $alias = shift;
  84         define_alias($alias,$obj);
  85     }
  86     return $obj;
  87 }
  88
  89 sub getEncoding
  90 {
  91     my ($class,$name,$skip_external) = @_;
  92     my $enc;
  93     if (ref($name) && $name->can('new_sequence'))
  94     {
  95         return $name;
  96     }
  97     my $lc = lc $name;
  98     if (exists $Encoding{$name})
  99     {
 100         return $Encoding{$name};
 101     }
 102     if (exists $Encoding{$lc})
 103     {
 104         return $Encoding{$lc};
 105     }
 106
 107     my $oc = $class->find_alias($name);
 108     return $oc if defined $oc;
 109
 110     $oc = $class->find_alias($lc) if $lc ne $name;
 111     return $oc if defined $oc;
 112
 113     unless ($skip_external)
 114     {
 115         if (my $mod = $ExtModule{$name} || $ExtModule{$lc}){
 116             $mod =~ s,::,/,g ; $mod .= '.pm';
 117             eval{ require $mod; };
 118             return $Encoding{$name} if exists $Encoding{$name};
 119         }
 120     }
 121     return;
 122 }
 123
 124 sub find_encoding
 125 {
 126     my ($name,$skip_external) = @_;
 127     return __PACKAGE__->getEncoding($name,$skip_external);
 128 }
 129
 130 sub resolve_alias {
 131     my $obj = find_encoding(shift);
 132     defined $obj and return $obj->name;
 133     return;
 134 }
 135
 136 sub encode($$;$)
 137 {
 138     my ($name,$string,$check) = @_;
 139     $check ||=0;
 140     my $enc = find_encoding($name);
 141     croak("Unknown encoding '$name'") unless defined $enc;
 142     my $octets = $enc->encode($string,$check);
 143     return undef if ($check && length($string));
 144     return $octets;
 145 }
 146
 147 sub decode($$;$)
 148 {
 149     my ($name,$octets,$check) = @_;
 150     $check ||=0;
 151     my $enc = find_encoding($name);
 152     croak("Unknown encoding '$name'") unless defined $enc;
 153     my $string = $enc->decode($octets,$check);
 154     $_[1] = $octets if $check;
 155     return $string;
 156 }
 157
 158 sub from_to($$$;$)
 159 {
 160     my ($string,$from,$to,$check) = @_;
 161     $check ||=0;
 162     my $f = find_encoding($from);
 163     croak("Unknown encoding '$from'") unless defined $f;
 164     my $t = find_encoding($to);
 165     croak("Unknown encoding '$to'") unless defined $t;
 166     my $uni = $f->decode($string,$check);
 167     return undef if ($check && length($string));
 168     $string =  $t->encode($uni,$check);
 169     return undef if ($check && length($uni));
 170     return defined($_[0] = $string) ? length($string) : undef ;
 171 }
 172
 173 sub encode_utf8($)
 174 {
 175     my ($str) = @_;
 176     utf8::encode($str);
 177     return $str;
 178 }
 179
 180 sub decode_utf8($)
 181 {
 182     my ($str) = @_;
 183     return undef unless utf8::decode($str);
 184     return $str;
 185 }
 186
 187 predefine_encodings();
 188
 189 #
 190 # This is to restore %Encoding if really needed;
 191 #
 192 sub predefine_encodings{
 193     if ($ON_EBCDIC) {
 194         # was in Encode::UTF_EBCDIC
 195         package Encode::UTF_EBCDIC;
 196         *name         = sub{ shift->{'Name'} };
 197         *new_sequence = sub{ return $_[0] };
 198         *decode = sub{
 199             my ($obj,$str,$chk) = @_;
 200             my $res = '';
 201             for (my $i = 0; $i < length($str); $i++) {
 202                 $res .=
 203                     chr(utf8::unicode_to_native(ord(substr($str,$i,1))));
 204             }
 205             $_[1] = '' if $chk;
 206             return $res;
 207         };
 208         *encode = sub{
 209             my ($obj,$str,$chk) = @_;
 210             my $res = '';
 211             for (my $i = 0; $i < length($str); $i++) {
 212                 $res .=
 213                     chr(utf8::native_to_unicode(ord(substr($str,$i,1))));
 214             }
 215             $_[1] = '' if $chk;
 216             return $res;
 217         };
 218         $Encode::Encoding{Unicode} =
 219             bless {Name => "UTF_EBCDIC"} => "Encode::UTF_EBCDIC";
 220     } else {
 221         # was in Encode::UTF_EBCDIC
 222         package Encode::Internal;
 223         *name         = sub{ shift->{'Name'} };
 224         *new_sequence = sub{ return $_[0] };
 225         *decode = sub{
 226             my ($obj,$str,$chk) = @_;
 227             utf8::upgrade($str);
 228             $_[1] = '' if $chk;
 229             return $str;
 230         };
 231         *encode = \&decode;
 232         $Encode::Encoding{Unicode} =
 233             bless {Name => "Internal"} => "Encode::Internal";
 234     }
 235
 236     {
 237         # was in Encode::utf8
 238         package Encode::utf8;
 239         *name         = sub{ shift->{'Name'} };
 240         *new_sequence = sub{ return $_[0] };
 241         *decode = sub{
 242             my ($obj,$octets,$chk) = @_;
 243             my $str = Encode::decode_utf8($octets);
 244             if (defined $str) {
 245                 $_[1] = '' if $chk;
 246                 return $str;
 247             }
 248             return undef;
 249         };
 250         *encode = sub {
 251             my ($obj,$string,$chk) = @_;
 252             my $octets = Encode::encode_utf8($string);
 253             $_[1] = '' if $chk;
 254             return $octets;
 255         };
 256         $Encode::Encoding{utf8} =
 257             bless {Name => "utf8"} => "Encode::utf8";
 258     }
 259 }
 260
 261 1;
 262
 263 __END__
 264
 265 =head1 NAME
 266
 267 Encode - character encodings
 268
 269 =head1 SYNOPSIS
 270
 271     use Encode;
 272
 273 =head2 Table of Contents
 274
 275 Encode consists of a collection of modules whose details are too big
 276 to fit in one document.  This POD itself explains the top-level APIs
 277 and general topics at a glance.  For other topics and more details,
 278 see the PODs below:
 279
 280   Name                          Description
 281   --------------------------------------------------------
 282   Encode::Alias         Alias definitions to encodings
 283   Encode::Encoding      Encode Implementation Base Class
 284   Encode::Supported     List of Supported Encodings
 285   Encode::CN            Simplified Chinese Encodings
 286   Encode::JP            Japanese Encodings
 287   Encode::KR            Korean Encodings
 288   Encode::TW            Traditional Chinese Encodings
 289   --------------------------------------------------------
 290
 291 =head1 DESCRIPTION
 292
 293 The C<Encode> module provides the interfaces between Perl's strings
 294 and the rest of the system.  Perl strings are sequences of
 295 B<characters>.
 296
 297 The repertoire of characters that Perl can represent is at least that
 298 defined by the Unicode Consortium. On most platforms the ordinal
 299 values of the characters (as returned by C<ord(ch)>) is the "Unicode
 300 codepoint" for the character (the exceptions are those platforms where
 301 the legacy encoding is some variant of EBCDIC rather than a super-set
 302 of ASCII - see L<perlebcdic>).
 303
 304 Traditionally, computer data has been moved around in 8-bit chunks
 305 often called "bytes". These chunks are also known as "octets" in
 306 networking standards. Perl is widely used to manipulate data of many
 307 types - not only strings of characters representing human or computer
 308 languages but also "binary" data being the machine's representation of
 309 numbers, pixels in an image - or just about anything.
 310
 311 When Perl is processing "binary data", the programmer wants Perl to
 312 process "sequences of bytes". This is not a problem for Perl - as a
 313 byte has 256 possible values, it easily fits in Perl's much larger
 314 "logical character".
 315
 316 =head2 TERMINOLOGY
 317
 318 =over 4
 319
 320 =item *
 321
 322 I<character>: a character in the range 0..(2**32-1) (or more).
 323 (What Perl's strings are made of.)
 324
 325 =item *
 326
 327 I<byte>: a character in the range 0..255
 328 (A special case of a Perl character.)
 329
 330 =item *
 331
 332 I<octet>: 8 bits of data, with ordinal values 0..255
 333 (Term for bytes passed to or from a non-Perl context, e.g. a disk file.)
 334
 335 =back
 336
 337 The marker [INTERNAL] marks Internal Implementation Details, in
 338 general meant only for those who think they know what they are doing,
 339 and such details may change in future releases.
 340
 341 =head1 PERL ENCODING API
 342
 343 =over 4
 344
 345 =item $octets  = encode(ENCODING, $string[, CHECK])
 346
 347 Encodes a string from Perl's internal form into I<ENCODING> and returns
 348 a sequence of octets.  ENCODING can be either a canonical name or
 349 an alias.  For encoding names and aliases, see L</"Defining Aliases">.
 350 For CHECK, see L</"Handling Malformed Data">.
 351
 352 For example, to convert (internally UTF-8 encoded) Unicode string to
 353 iso-8859-1 (also known as Latin1),
 354
 355   $octets = encode("iso-8859-1", $unicode);
 356
 357 =item $string = decode(ENCODING, $octets[, CHECK])
 358
 359 Decodes a sequence of octets assumed to be in I<ENCODING> into Perl's
 360 internal form and returns the resulting string.  As in encode(),
 361 ENCODING can be either a canonical name or an alias. For encoding names
 362 and aliases, see L</"Defining Aliases">.  For CHECK, see
 363 L</"Handling Malformed Data">.
 364
 365 For example, to convert ISO-8859-1 data to UTF-8:
 366
 367   $utf8 = decode("iso-8859-1", $latin1);
 368
 369 =item [$length =] from_to($string, FROM_ENCODING, TO_ENCODING [,CHECK])
 370
 371 Converts B<in-place> data between two encodings.
 372 For example, to convert ISO-8859-1 data to UTF-8:
 373
 374         from_to($data, "iso-8859-1", "utf-8");
 375
 376 and to convert it back:
 377
 378         from_to($data, "utf-8", "iso-8859-1");
 379
 380 Note that because the conversion happens in place, the data to be
 381 converted cannot be a string constant; it must be a scalar variable.
 382
 383 from_to() returns the length of the converted string on success, undef
 384 otherwise.
 385
 386 =back
 387
 388 =head2 UTF-8 / utf8
 389
 390 The Unicode Consortium defines the UTF-8 transformation format as a
 391 way of encoding the entire Unicode repertoire as sequences of octets.
 392 This encoding is expected to become very widespread. Perl can use this
 393 form internally to represent strings, so conversions to and from this
 394 form are particularly efficient (as octets in memory do not have to
 395 change, just the meta-data that tells Perl how to treat them).
 396
 397 =over 4
 398
 399 =item $octets = encode_utf8($string);
 400
 401 The characters that comprise $string are encoded in Perl's superset of
 402 UTF-8 and the resulting octets are returned as a sequence of bytes. All
 403 possible characters have a UTF-8 representation so this function cannot
 404 fail.
 405
 406 =item $string = decode_utf8($octets [, CHECK]);
 407
 408 The sequence of octets represented by $octets is decoded from UTF-8
 409 into a sequence of logical characters. Not all sequences of octets
 410 form valid UTF-8 encodings, so it is possible for this call to fail.
 411 For CHECK, see L</"Handling Malformed Data">.
 412
 413 =back
 414
 415 =head2 Listing available encodings
 416
 417   use Encode;
 418   @list = Encode->encodings();
 419
 420 Returns a list of the canonical names of the available encodings that
 421 are loaded.  To get a list of all available encodings including the
 422 ones that are not loaded yet, say
 423
 424   @all_encodings = Encode->encodings(":all");
 425
 426 Or you can give the name of a specific module.
 427
 428   @with_jp = Encode->encodings("Encode::JP");
 429
 430 When "::" is not in the name, "Encode::" is assumed.
 431
 432   @ebcdic = Encode->encodings("EBCDIC");
 433
 434 To find out in detail which encodings are supported by this package,
 435 see L<Encode::Supported>.
 436
 437 =head2 Defining Aliases
 438
 439 To add a new alias to a given encoding, use:
 440
 441   use Encode;
 442   use Encode::Alias;
 443   define_alias(newName => ENCODING);
 444
 445 After that, newName can be used as an alias for ENCODING.
 446 ENCODING may be either the name of an encoding or an
 447 I<encoding object>
 448
 449 But before you do so, make sure the alias is nonexistent with
 450 C<resolve_alias()>, which returns the canonical name thereof.
 451 i.e.
 452
 453   Encode::resolve_alias("latin1") eq "iso-8859-1" # true
 454   Encode::resolve_alias("iso-8859-12")   # false; nonexistent
 455   Encode::resolve_alias($name) eq $name  # true if $name is canonical
 456
 457 resolve_alias() does not need C<use Encode::Alias>; it can be
 458 exported via C<use Encode qw(resolve_alias)>.
 459
 460 See L<Encode::Alias> for details.
 461
 462 =head1 Encoding via PerlIO
 463
 464 If your perl supports I<PerlIO>, you can use a PerlIO layer to decode
 465 and encode directly via a filehandle.  The following two examples
 466 are totally identical in their functionality.
 467
 468   # via PerlIO
 469   open my $in,  "<:encoding(shiftjis)", $infile  or die;
 470   open my $out, ">:encoding(euc-jp)",   $outfile or die;
 471   while(<>){ print; }
 472
 473   # via from_to
 474   open my $in,  "<", $infile  or die;
 475   open my $out, ">", $outfile or die;
 476   while(<>){
 477     from_to($_, "shiftjis", "euc-jp", 1);
 478   }
 479
 480 Unfortunately, there may be encodings are PerlIO-savvy.  You can check
 481 if your encoding is supported by PerlIO by calling the C<perlio_ok>
 482 method.
 483
 484   Encode::perlio_ok("hz");             # False
 485   find_encoding("euc-cn")->perlio_ok;  # True where PerlIO is available
 486
 487   use Encode qw(perlio_ok);            # exported upon request
 488   perlio_ok("euc-jp")
 489
 490 Fortunately, all encodings that come with Encode core are PerlIO-savvy
 491 except for hz and ISO-2022-kr.  See L<Encode::Encoding> for details.
 492
 493 For gory details, see L<Encode::PerlIO>.
 494
 495 =head1 Handling Malformed Data
 496
 497 =over 4
 498
 499 The I<CHECK> argument is used as follows.  When you omit it,
 500 the behaviour is the same as if you had passed a value of 0 for
 501 I<CHECK>.
 502
 503 =item I<CHECK> = Encode::FB_DEFAULT ( == 0)
 504
 505 If I<CHECK> is 0, (en|de)code will put a I<substitution character>
 506 in place of a malformed character.  For UCM-based encodings,
 507 E<lt>subcharE<gt> will be used.  For Unicode, "\x{FFFD}" is used.
 508 If the data is supposed to be UTF-8, an optional lexical warning
 509 (category utf8) is given.
 510
 511 =item I<CHECK> = Encode::DIE_ON_ERROR (== 1)
 512
 513 If I<CHECK> is 1, methods will die immediately with an error
 514 message.  Therefore, when I<CHECK> is set to 1,  you should trap the
 515 fatal error with eval{} unless you really want to let it die on error.
 516
 517 =item I<CHECK> = Encode::FB_QUIET
 518
 519 If I<CHECK> is set to Encode::FB_QUIET, (en|de)code will immediately
 520 return the portion of the data that has been processed so far when
 521 an error occurs. The data argument will be overwritten with
 522 everything after that point (that is, the unprocessed part of data).
 523 This is handy when you have to call decode repeatedly in the case
 524 where your source data may contain partial multi-byte character
 525 sequences, for example because you are reading with a fixed-width
 526 buffer. Here is some sample code that does exactly this:
 527
 528   my $data = '';
 529   while(defined(read $fh, $buffer, 256)){
 530     # buffer may end in a partial character so we append
 531     $data .= $buffer;
 532     $utf8 .= decode($encoding, $data, ENCODE::FB_QUIET);
 533     # $data now contains the unprocessed partial character
 534   }
 535
 536 =item I<CHECK> = Encode::FB_WARN
 537
 538 This is the same as above, except that it warns on error.  Handy when
 539 you are debugging the mode above.
 540
 541 =item perlqq mode (I<CHECK> = Encode::FB_PERLQQ)
 542
 543 For encodings that are implemented by Encode::XS, CHECK ==
 544 Encode::FB_PERLQQ turns (en|de)code into C<perlqq> fallback mode.
 545
 546 When you decode, '\xI<XX>' will be inserted for a malformed character,
 547 where I<XX> is the hex representation of the octet  that could not be
 548 decoded to utf8.  And when you encode, '\x{I<xxxx>}' will be inserted,
 549 where I<xxxx> is the Unicode ID of the character that cannot be found
 550 in the character repertoire of the encoding.
 551
 552 =item The bitmask
 553
 554 These modes are actually set via a bitmask.  Here is how the FB_XX
 555 constants are laid out.  You can import the FB_XX constants via
 556 C<use Encode qw(:fallbacks)>; you can import the generic bitmask
 557 constants via C<use Encode qw(:fallback_all)>.
 558
 559                      FB_DEFAULT FB_CROAK FB_QUIET FB_WARN  FB_PERLQQ
 560  DIE_ON_ERR    0x0001             X
 561  WARN_ON_ER    0x0002                               X
 562  RETURN_ON_ERR 0x0004                      X        X
 563  LEAVE_SRC     0x0008
 564  PERLQQ        0x0100                                        X
 565
 566 =head2 Unimplemented fallback schemes
 567
 568 In the future, you will be able to use a code reference to a callback
 569 function for the value of I<CHECK> but its API is still undecided.
 570
 571 =head1 Defining Encodings
 572
 573 To define a new encoding, use:
 574
 575     use Encode qw(define_alias);
 576     define_encoding($object, 'canonicalName' [, alias...]);
 577
 578 I<canonicalName> will be associated with I<$object>.  The object
 579 should provide the interface described in L<Encode::Encoding>.
 580 If more than two arguments are provided then additional
 581 arguments are taken as aliases for I<$object>, as for C<define_alias>.
 582
 583 See L<Encode::Encoding> for more details.
 584
 585 =head1 Messing with Perl's Internals
 586
 587 The following API uses parts of Perl's internals in the current
 588 implementation.  As such, they are efficient but may change.
 589
 590 =over 4
 591
 592 =item is_utf8(STRING [, CHECK])
 593
 594 [INTERNAL] Tests whether the UTF-8 flag is turned on in the STRING.
 595 If CHECK is true, also checks the data in STRING for being well-formed
 596 UTF-8.  Returns true if successful, false otherwise.
 597
 598 =item _utf8_on(STRING)
 599
 600 [INTERNAL] Turns on the UTF-8 flag in STRING.  The data in STRING is
 601 B<not> checked for being well-formed UTF-8.  Do not use unless you
 602 B<know> that the STRING is well-formed UTF-8.  Returns the previous
 603 state of the UTF-8 flag (so please don't treat the return value as
 604 indicating success or failure), or C<undef> if STRING is not a string.
 605
 606 =item _utf8_off(STRING)
 607
 608 [INTERNAL] Turns off the UTF-8 flag in STRING.  Do not use frivolously.
 609 Returns the previous state of the UTF-8 flag (so please don't treat the
 610 return value as indicating success or failure), or C<undef> if STRING is
 611 not a string.
 612
 613 =back
 614
 615 =head1 SEE ALSO
 616
 617 L<Encode::Encoding>,
 618 L<Encode::Supported>,
 619 L<Encode::PerlIO>,
 620 L<encoding>,
 621 L<perlebcdic>,
 622 L<perlfunc/open>,
 623 L<perlunicode>,
 624 L<utf8>,
 625 the Perl Unicode Mailing List E<lt>perl-unicode@perl.orgE<gt>
 626
 627 =head1 MAINTAINER
 628
 629 This project was originated by Nick Ing-Simmons and later maintained
 630 by Dan Kogai E<lt>dankogai@dan.co.jpE<gt>.  See AUTHORS for a full list
 631 of people involved.  For any questions, use
 632 E<lt>perl-unicode@perl.orgE<gt> so others can share.
 633
 634 =cut