ext/Encode/Encode.pm

   1 #
   2 # $Id: Encode.pm,v 2.25 2008/05/07 20:56:05 dankogai Exp dankogai $
   3 #
   4 package Encode;
   5 use strict;
   6 use warnings;
   7 our $VERSION = sprintf "%d.%02d", q$Revision: 2.25 $ =~ /(\d+)/g;
   8 sub DEBUG () { 0 }
   9 use XSLoader ();
  10 XSLoader::load( __PACKAGE__, $VERSION );
  11
  12 require Exporter;
  13 use base qw/Exporter/;
  14
  15 # Public, encouraged API is exported by default
  16
  17 our @EXPORT = qw(
  18   decode  decode_utf8  encode  encode_utf8 str2bytes bytes2str
  19   encodings  find_encoding clone_encoding
  20 );
  21 our @FB_FLAGS = qw(
  22   DIE_ON_ERR WARN_ON_ERR RETURN_ON_ERR LEAVE_SRC
  23   PERLQQ HTMLCREF XMLCREF STOP_AT_PARTIAL
  24 );
  25 our @FB_CONSTS = qw(
  26   FB_DEFAULT FB_CROAK FB_QUIET FB_WARN
  27   FB_PERLQQ FB_HTMLCREF FB_XMLCREF
  28 );
  29 our @EXPORT_OK = (
  30     qw(
  31       _utf8_off _utf8_on define_encoding from_to is_16bit is_8bit
  32       is_utf8 perlio_ok resolve_alias utf8_downgrade utf8_upgrade
  33       ),
  34     @FB_FLAGS, @FB_CONSTS,
  35 );
  36
  37 our %EXPORT_TAGS = (
  38     all          => [ @EXPORT,    @EXPORT_OK ],
  39     default      => [ @EXPORT ],
  40     fallbacks    => [ @FB_CONSTS ],
  41     fallback_all => [ @FB_CONSTS, @FB_FLAGS ],
  42 );
  43
  44 # Documentation moved after __END__ for speed - NI-S
  45
  46 our $ON_EBCDIC = ( ord("A") == 193 );
  47
  48 use Encode::Alias;
  49
  50 # Make a %Encoding package variable to allow a certain amount of cheating
  51 our %Encoding;
  52 our %ExtModule;
  53 require Encode::Config;
  54 eval { require Encode::ConfigLocal };
  55
  56 sub encodings {
  57     my $class = shift;
  58     my %enc;
  59     if ( @_ and $_[0] eq ":all" ) {
  60         %enc = ( %Encoding, %ExtModule );
  61     }
  62     else {
  63         %enc = %Encoding;
  64         for my $mod ( map { m/::/o ? $_ : "Encode::$_" } @_ ) {
  65             DEBUG and warn $mod;
  66             for my $enc ( keys %ExtModule ) {
  67                 $ExtModule{$enc} eq $mod and $enc{$enc} = $mod;
  68             }
  69         }
  70     }
  71     return sort { lc $a cmp lc $b }
  72       grep      { !/^(?:Internal|Unicode|Guess)$/o } keys %enc;
  73 }
  74
  75 sub perlio_ok {
  76     my $obj = ref( $_[0] ) ? $_[0] : find_encoding( $_[0] );
  77     $obj->can("perlio_ok") and return $obj->perlio_ok();
  78     return 0;    # safety net
  79 }
  80
  81 sub define_encoding {
  82     my $obj  = shift;
  83     my $name = shift;
  84     $Encoding{$name} = $obj;
  85     my $lc = lc($name);
  86     define_alias( $lc => $obj ) unless $lc eq $name;
  87     while (@_) {
  88         my $alias = shift;
  89         define_alias( $alias, $obj );
  90     }
  91     return $obj;
  92 }
  93
  94 sub getEncoding {
  95     my ( $class, $name, $skip_external ) = @_;
  96
  97     ref($name) && $name->can('renew') and return $name;
  98     exists $Encoding{$name} and return $Encoding{$name};
  99     my $lc = lc $name;
 100     exists $Encoding{$lc} and return $Encoding{$lc};
 101
 102     my $oc = $class->find_alias($name);
 103     defined($oc) and return $oc;
 104     $lc ne $name and $oc = $class->find_alias($lc);
 105     defined($oc) and return $oc;
 106
 107     unless ($skip_external) {
 108         if ( my $mod = $ExtModule{$name} || $ExtModule{$lc} ) {
 109             $mod =~ s,::,/,g;
 110             $mod .= '.pm';
 111             eval { require $mod; };
 112             exists $Encoding{$name} and return $Encoding{$name};
 113         }
 114     }
 115     return;
 116 }
 117
 118 sub find_encoding($;$) {
 119     my ( $name, $skip_external ) = @_;
 120     return __PACKAGE__->getEncoding( $name, $skip_external );
 121 }
 122
 123 sub resolve_alias($) {
 124     my $obj = find_encoding(shift);
 125     defined $obj and return $obj->name;
 126     return;
 127 }
 128
 129 sub clone_encoding($) {
 130     my $obj = find_encoding(shift);
 131     ref $obj or return;
 132     eval { require Storable };
 133     $@ and return;
 134     return Storable::dclone($obj);
 135 }
 136
 137 sub encode($$;$) {
 138     my ( $name, $string, $check ) = @_;
 139     return undef unless defined $string;
 140     $string .= '' if ref $string;    # stringify;
 141     $check ||= 0;
 142     my $enc = find_encoding($name);
 143     unless ( defined $enc ) {
 144         require Carp;
 145         Carp::croak("Unknown encoding '$name'");
 146     }
 147     my $octets = $enc->encode( $string, $check );
 148     $_[1] = $string if $check and !ref $check and !( $check & LEAVE_SRC() );
 149     return $octets;
 150 }
 151 *str2bytes = \&encode;
 152
 153 sub decode($$;$) {
 154     my ( $name, $octets, $check ) = @_;
 155     return undef unless defined $octets;
 156     $octets .= '' if ref $octets;
 157     $check ||= 0;
 158     my $enc = find_encoding($name);
 159     unless ( defined $enc ) {
 160         require Carp;
 161         Carp::croak("Unknown encoding '$name'");
 162     }
 163     my $string = $enc->decode( $octets, $check );
 164     $_[1] = $octets if $check and !ref $check and !( $check & LEAVE_SRC() );
 165     return $string;
 166 }
 167 *bytes2str = \&decode;
 168
 169 sub from_to($$$;$) {
 170     my ( $string, $from, $to, $check ) = @_;
 171     return undef unless defined $string;
 172     $check ||= 0;
 173     my $f = find_encoding($from);
 174     unless ( defined $f ) {
 175         require Carp;
 176         Carp::croak("Unknown encoding '$from'");
 177     }
 178     my $t = find_encoding($to);
 179     unless ( defined $t ) {
 180         require Carp;
 181         Carp::croak("Unknown encoding '$to'");
 182     }
 183     my $uni = $f->decode($string);
 184     $_[0] = $string = $t->encode( $uni, $check );
 185     return undef if ( $check && length($uni) );
 186     return defined( $_[0] ) ? length($string) : undef;
 187 }
 188
 189 sub encode_utf8($) {
 190     my ($str) = @_;
 191     utf8::encode($str);
 192     return $str;
 193 }
 194
 195 sub decode_utf8($;$) {
 196     my ( $str, $check ) = @_;
 197     return $str if is_utf8($str);
 198     if ($check) {
 199         return decode( "utf8", $str, $check );
 200     }
 201     else {
 202         return decode( "utf8", $str );
 203         return $str;
 204     }
 205 }
 206
 207 predefine_encodings(1);
 208
 209 #
 210 # This is to restore %Encoding if really needed;
 211 #
 212
 213 sub predefine_encodings {
 214     require Encode::Encoding;
 215     no warnings 'redefine';
 216     my $use_xs = shift;
 217     if ($ON_EBCDIC) {
 218
 219         # was in Encode::UTF_EBCDIC
 220         package Encode::UTF_EBCDIC;
 221         push @Encode::UTF_EBCDIC::ISA, 'Encode::Encoding';
 222         *decode = sub {
 223             my ( $obj, $str, $chk ) = @_;
 224             my $res = '';
 225             for ( my $i = 0 ; $i < length($str) ; $i++ ) {
 226                 $res .=
 227                   chr(
 228                     utf8::unicode_to_native( ord( substr( $str, $i, 1 ) ) )
 229                   );
 230             }
 231             $_[1] = '' if $chk;
 232             return $res;
 233         };
 234         *encode = sub {
 235             my ( $obj, $str, $chk ) = @_;
 236             my $res = '';
 237             for ( my $i = 0 ; $i < length($str) ; $i++ ) {
 238                 $res .=
 239                   chr(
 240                     utf8::native_to_unicode( ord( substr( $str, $i, 1 ) ) )
 241                   );
 242             }
 243             $_[1] = '' if $chk;
 244             return $res;
 245         };
 246         $Encode::Encoding{Unicode} =
 247           bless { Name => "UTF_EBCDIC" } => "Encode::UTF_EBCDIC";
 248     }
 249     else {
 250
 251         package Encode::Internal;
 252         push @Encode::Internal::ISA, 'Encode::Encoding';
 253         *decode = sub {
 254             my ( $obj, $str, $chk ) = @_;
 255             utf8::upgrade($str);
 256             $_[1] = '' if $chk;
 257             return $str;
 258         };
 259         *encode = \&decode;
 260         $Encode::Encoding{Unicode} =
 261           bless { Name => "Internal" } => "Encode::Internal";
 262     }
 263
 264     {
 265
 266         # was in Encode::utf8
 267         package Encode::utf8;
 268         push @Encode::utf8::ISA, 'Encode::Encoding';
 269
 270         #
 271         if ($use_xs) {
 272             Encode::DEBUG and warn __PACKAGE__, " XS on";
 273             *decode = \&decode_xs;
 274             *encode = \&encode_xs;
 275         }
 276         else {
 277             Encode::DEBUG and warn __PACKAGE__, " XS off";
 278             *decode = sub {
 279                 my ( $obj, $octets, $chk ) = @_;
 280                 my $str = Encode::decode_utf8($octets);
 281                 if ( defined $str ) {
 282                     $_[1] = '' if $chk;
 283                     return $str;
 284                 }
 285                 return undef;
 286             };
 287             *encode = sub {
 288                 my ( $obj, $string, $chk ) = @_;
 289                 my $octets = Encode::encode_utf8($string);
 290                 $_[1] = '' if $chk;
 291                 return $octets;
 292             };
 293         }
 294         *cat_decode = sub {    # ($obj, $dst, $src, $pos, $trm, $chk)
 295                                # currently ignores $chk
 296             my ( $obj, undef, undef, $pos, $trm ) = @_;
 297             my ( $rdst, $rsrc, $rpos ) = \@_[ 1, 2, 3 ];
 298             use bytes;
 299             if ( ( my $npos = index( $$rsrc, $trm, $pos ) ) >= 0 ) {
 300                 $$rdst .=
 301                   substr( $$rsrc, $pos, $npos - $pos + length($trm) );
 302                 $$rpos = $npos + length($trm);
 303                 return 1;
 304             }
 305             $$rdst .= substr( $$rsrc, $pos );
 306             $$rpos = length($$rsrc);
 307             return '';
 308         };
 309         $Encode::Encoding{utf8} =
 310           bless { Name => "utf8" } => "Encode::utf8";
 311         $Encode::Encoding{"utf-8-strict"} =
 312           bless { Name => "utf-8-strict", strict_utf8 => 1 } =>
 313           "Encode::utf8";
 314     }
 315 }
 316
 317 1;
 318
 319 __END__
 320
 321 =head1 NAME
 322
 323 Encode - character encodings
 324
 325 =head1 SYNOPSIS
 326
 327     use Encode;
 328
 329 =head2 Table of Contents
 330
 331 Encode consists of a collection of modules whose details are too big
 332 to fit in one document.  This POD itself explains the top-level APIs
 333 and general topics at a glance.  For other topics and more details,
 334 see the PODs below:
 335
 336   Name                          Description
 337   --------------------------------------------------------
 338   Encode::Alias         Alias definitions to encodings
 339   Encode::Encoding      Encode Implementation Base Class
 340   Encode::Supported     List of Supported Encodings
 341   Encode::CN            Simplified Chinese Encodings
 342   Encode::JP            Japanese Encodings
 343   Encode::KR            Korean Encodings
 344   Encode::TW            Traditional Chinese Encodings
 345   --------------------------------------------------------
 346
 347 =head1 DESCRIPTION
 348
 349 The C<Encode> module provides the interfaces between Perl's strings
 350 and the rest of the system.  Perl strings are sequences of
 351 B<characters>.
 352
 353 The repertoire of characters that Perl can represent is at least that
 354 defined by the Unicode Consortium. On most platforms the ordinal
 355 values of the characters (as returned by C<ord(ch)>) is the "Unicode
 356 codepoint" for the character (the exceptions are those platforms where
 357 the legacy encoding is some variant of EBCDIC rather than a super-set
 358 of ASCII - see L<perlebcdic>).
 359
 360 Traditionally, computer data has been moved around in 8-bit chunks
 361 often called "bytes". These chunks are also known as "octets" in
 362 networking standards. Perl is widely used to manipulate data of many
 363 types - not only strings of characters representing human or computer
 364 languages but also "binary" data being the machine's representation of
 365 numbers, pixels in an image - or just about anything.
 366
 367 When Perl is processing "binary data", the programmer wants Perl to
 368 process "sequences of bytes". This is not a problem for Perl - as a
 369 byte has 256 possible values, it easily fits in Perl's much larger
 370 "logical character".
 371
 372 =head2 TERMINOLOGY
 373
 374 =over 2
 375
 376 =item *
 377
 378 I<character>: a character in the range 0..(2**32-1) (or more).
 379 (What Perl's strings are made of.)
 380
 381 =item *
 382
 383 I<byte>: a character in the range 0..255
 384 (A special case of a Perl character.)
 385
 386 =item *
 387
 388 I<octet>: 8 bits of data, with ordinal values 0..255
 389 (Term for bytes passed to or from a non-Perl context, e.g. a disk file.)
 390
 391 =back
 392
 393 =head1 PERL ENCODING API
 394
 395 =over 2
 396
 397 =item $octets  = encode(ENCODING, $string [, CHECK])
 398
 399 Encodes a string from Perl's internal form into I<ENCODING> and returns
 400 a sequence of octets.  ENCODING can be either a canonical name or
 401 an alias.  For encoding names and aliases, see L</"Defining Aliases">.
 402 For CHECK, see L</"Handling Malformed Data">.
 403
 404 For example, to convert a string from Perl's internal format to
 405 iso-8859-1 (also known as Latin1),
 406
 407   $octets = encode("iso-8859-1", $string);
 408
 409 B<CAVEAT>: When you run C<$octets = encode("utf8", $string)>, then
 410 $octets B<may not be equal to> $string.  Though they both contain the
 411 same data, the UTF8 flag for $octets is B<always> off.  When you
 412 encode anything, UTF8 flag of the result is always off, even when it
 413 contains completely valid utf8 string. See L</"The UTF8 flag"> below.
 414
 415 If the $string is C<undef> then C<undef> is returned.
 416
 417 =item $string = decode(ENCODING, $octets [, CHECK])
 418
 419 Decodes a sequence of octets assumed to be in I<ENCODING> into Perl's
 420 internal form and returns the resulting string.  As in encode(),
 421 ENCODING can be either a canonical name or an alias. For encoding names
 422 and aliases, see L</"Defining Aliases">.  For CHECK, see
 423 L</"Handling Malformed Data">.
 424
 425 For example, to convert ISO-8859-1 data to a string in Perl's internal format:
 426
 427   $string = decode("iso-8859-1", $octets);
 428
 429 B<CAVEAT>: When you run C<$string = decode("utf8", $octets)>, then $string
 430 B<may not be equal to> $octets.  Though they both contain the same data,
 431 the UTF8 flag for $string is on unless $octets entirely consists of
 432 ASCII data (or EBCDIC on EBCDIC machines).  See L</"The UTF8 flag">
 433 below.
 434
 435 If the $string is C<undef> then C<undef> is returned.
 436
 437 =item [$obj =] find_encoding(ENCODING)
 438
 439 Returns the I<encoding object> corresponding to ENCODING.  Returns
 440 undef if no matching ENCODING is find.
 441
 442 This object is what actually does the actual (en|de)coding.
 443
 444   $utf8 = decode($name, $bytes);
 445
 446 is in fact
 447
 448   $utf8 = do{
 449     $obj = find_encoding($name);
 450     croak qq(encoding "$name" not found) unless ref $obj;
 451     $obj->decode($bytes)
 452   };
 453
 454 with more error checking.
 455
 456 Therefore you can save time by reusing this object as follows;
 457
 458   my $enc = find_encoding("iso-8859-1");
 459   while(<>){
 460      my $utf8 = $enc->decode($_);
 461      # and do someting with $utf8;
 462   }
 463
 464 Besides C<< ->decode >> and C<< ->encode >>, other methods are
 465 available as well.  For instance, C<< -> name >> returns the canonical
 466 name of the encoding object.
 467
 468   find_encoding("latin1")->name; # iso-8859-1
 469
 470 See L<Encode::Encoding> for details.
 471
 472 =item [$length =] from_to($octets, FROM_ENC, TO_ENC [, CHECK])
 473
 474 Converts B<in-place> data between two encodings. The data in $octets
 475 must be encoded as octets and not as characters in Perl's internal
 476 format. For example, to convert ISO-8859-1 data to Microsoft's CP1250
 477 encoding:
 478
 479   from_to($octets, "iso-8859-1", "cp1250");
 480
 481 and to convert it back:
 482
 483   from_to($octets, "cp1250", "iso-8859-1");
 484
 485 Note that because the conversion happens in place, the data to be
 486 converted cannot be a string constant; it must be a scalar variable.
 487
 488 from_to() returns the length of the converted string in octets on
 489 success, I<undef> on error.
 490
 491 B<CAVEAT>: The following operations look the same but are not quite so;
 492
 493   from_to($data, "iso-8859-1", "utf8"); #1
 494   $data = decode("iso-8859-1", $data);  #2
 495
 496 Both #1 and #2 make $data consist of a completely valid UTF-8 string
 497 but only #2 turns UTF8 flag on.  #1 is equivalent to
 498
 499   $data = encode("utf8", decode("iso-8859-1", $data));
 500
 501 See L</"The UTF8 flag"> below.
 502
 503 Also note that
 504
 505   from_to($octets, $from, $to, $check);
 506
 507 is equivalent to
 508
 509   $octets = encode($to, decode($from, $octets), $check);
 510
 511 Yes, it does not respect the $check during decoding.  It is
 512 deliberately done that way.  If you need minute control, C<decode>
 513 then C<encode> as follows;
 514
 515   $octets = encode($to, decode($from, $octets, $check_from), $check_to);
 516
 517 =item $octets = encode_utf8($string);
 518
 519 Equivalent to C<$octets = encode("utf8", $string);> The characters
 520 that comprise $string are encoded in Perl's internal format and the
 521 result is returned as a sequence of octets. All possible
 522 characters have a UTF-8 representation so this function cannot fail.
 523
 524
 525 =item $string = decode_utf8($octets [, CHECK]);
 526
 527 equivalent to C<$string = decode("utf8", $octets [, CHECK])>.
 528 The sequence of octets represented by
 529 $octets is decoded from UTF-8 into a sequence of logical
 530 characters. Not all sequences of octets form valid UTF-8 encodings, so
 531 it is possible for this call to fail.  For CHECK, see
 532 L</"Handling Malformed Data">.
 533
 534 =back
 535
 536 =head2 Listing available encodings
 537
 538   use Encode;
 539   @list = Encode->encodings();
 540
 541 Returns a list of the canonical names of the available encodings that
 542 are loaded.  To get a list of all available encodings including the
 543 ones that are not loaded yet, say
 544
 545   @all_encodings = Encode->encodings(":all");
 546
 547 Or you can give the name of a specific module.
 548
 549   @with_jp = Encode->encodings("Encode::JP");
 550
 551 When "::" is not in the name, "Encode::" is assumed.
 552
 553   @ebcdic = Encode->encodings("EBCDIC");
 554
 555 To find out in detail which encodings are supported by this package,
 556 see L<Encode::Supported>.
 557
 558 =head2 Defining Aliases
 559
 560 To add a new alias to a given encoding, use:
 561
 562   use Encode;
 563   use Encode::Alias;
 564   define_alias(newName => ENCODING);
 565
 566 After that, newName can be used as an alias for ENCODING.
 567 ENCODING may be either the name of an encoding or an
 568 I<encoding object>
 569
 570 But before you do so, make sure the alias is nonexistent with
 571 C<resolve_alias()>, which returns the canonical name thereof.
 572 i.e.
 573
 574   Encode::resolve_alias("latin1") eq "iso-8859-1" # true
 575   Encode::resolve_alias("iso-8859-12")   # false; nonexistent
 576   Encode::resolve_alias($name) eq $name  # true if $name is canonical
 577
 578 resolve_alias() does not need C<use Encode::Alias>; it can be
 579 exported via C<use Encode qw(resolve_alias)>.
 580
 581 See L<Encode::Alias> for details.
 582
 583 =head2 Finding IANA Character Set Registry names
 584
 585 The canonical name of a given encoding does not necessarily agree with
 586 IANA IANA Character Set Registry, commonly seen as C<< Content-Type:
 587 text/plain; charset=I<whatever> >>.  For most cases canonical names
 588 work but sometimes it does not (notably 'utf-8-strict').
 589
 590 Therefore as of Encode version 2.21, a new method C<mime_name()> is added.
 591
 592   use Encode;
 593   my $enc = find_encoding('UTF-8');
 594   warn $enc->name;      # utf-8-strict
 595   warn $enc->mime_name; # UTF-8
 596
 597 See also:  L<Encode::Encoding>
 598
 599 =head1 Encoding via PerlIO
 600
 601 If your perl supports I<PerlIO> (which is the default), you can use a
 602 PerlIO layer to decode and encode directly via a filehandle.  The
 603 following two examples are totally identical in their functionality.
 604
 605   # via PerlIO
 606   open my $in,  "<:encoding(shiftjis)", $infile  or die;
 607   open my $out, ">:encoding(euc-jp)",   $outfile or die;
 608   while(<$in>){ print $out $_; }
 609
 610   # via from_to
 611   open my $in,  "<", $infile  or die;
 612   open my $out, ">", $outfile or die;
 613   while(<$in>){
 614     from_to($_, "shiftjis", "euc-jp", 1);
 615     print $out $_;
 616   }
 617
 618 Unfortunately, it may be that encodings are PerlIO-savvy.  You can check
 619 if your encoding is supported by PerlIO by calling the C<perlio_ok>
 620 method.
 621
 622   Encode::perlio_ok("hz");             # False
 623   find_encoding("euc-cn")->perlio_ok;  # True where PerlIO is available
 624
 625   use Encode qw(perlio_ok);            # exported upon request
 626   perlio_ok("euc-jp")
 627
 628 Fortunately, all encodings that come with Encode core are PerlIO-savvy
 629 except for hz and ISO-2022-kr.  For gory details, see
 630 L<Encode::Encoding> and L<Encode::PerlIO>.
 631
 632 =head1 Handling Malformed Data
 633
 634 The optional I<CHECK> argument tells Encode what to do when it
 635 encounters malformed data.  Without CHECK, Encode::FB_DEFAULT ( == 0 )
 636 is assumed.
 637
 638 As of version 2.12 Encode supports coderef values for CHECK.  See below.
 639
 640 =over 2
 641
 642 =item B<NOTE:> Not all encoding support this feature
 643
 644 Some encodings ignore I<CHECK> argument.  For example,
 645 L<Encode::Unicode> ignores I<CHECK> and it always croaks on error.
 646
 647 =back
 648
 649 Now here is the list of I<CHECK> values available
 650
 651 =over 2
 652
 653 =item I<CHECK> = Encode::FB_DEFAULT ( == 0)
 654
 655 If I<CHECK> is 0, (en|de)code will put a I<substitution character> in
 656 place of a malformed character.  When you encode, E<lt>subcharE<gt>
 657 will be used.  When you decode the code point C<0xFFFD> is used.  If
 658 the data is supposed to be UTF-8, an optional lexical warning
 659 (category utf8) is given.
 660
 661 =item I<CHECK> = Encode::FB_CROAK ( == 1)
 662
 663 If I<CHECK> is 1, methods will die on error immediately with an error
 664 message.  Therefore, when I<CHECK> is set to 1,  you should trap the
 665 error with eval{} unless you really want to let it die.
 666
 667 =item I<CHECK> = Encode::FB_QUIET
 668
 669 If I<CHECK> is set to Encode::FB_QUIET, (en|de)code will immediately
 670 return the portion of the data that has been processed so far when an
 671 error occurs. The data argument will be overwritten with everything
 672 after that point (that is, the unprocessed part of data).  This is
 673 handy when you have to call decode repeatedly in the case where your
 674 source data may contain partial multi-byte character sequences,
 675 (i.e. you are reading with a fixed-width buffer). Here is a sample
 676 code that does exactly this:
 677
 678   my $buffer = ''; my $string = '';
 679   while(read $fh, $buffer, 256, length($buffer)){
 680     $string .= decode($encoding, $buffer, Encode::FB_QUIET);
 681     # $buffer now contains the unprocessed partial character
 682   }
 683
 684 =item I<CHECK> = Encode::FB_WARN
 685
 686 This is the same as above, except that it warns on error.  Handy when
 687 you are debugging the mode above.
 688
 689 =item perlqq mode (I<CHECK> = Encode::FB_PERLQQ)
 690
 691 =item HTML charref mode (I<CHECK> = Encode::FB_HTMLCREF)
 692
 693 =item XML charref mode (I<CHECK> = Encode::FB_XMLCREF)
 694
 695 For encodings that are implemented by Encode::XS, CHECK ==
 696 Encode::FB_PERLQQ turns (en|de)code into C<perlqq> fallback mode.
 697
 698 When you decode, C<\xI<HH>> will be inserted for a malformed character,
 699 where I<HH> is the hex representation of the octet  that could not be
 700 decoded to utf8.  And when you encode, C<\x{I<HHHH>}> will be inserted,
 701 where I<HHHH> is the Unicode ID of the character that cannot be found
 702 in the character repertoire of the encoding.
 703
 704 HTML/XML character reference modes are about the same, in place of
 705 C<\x{I<HHHH>}>, HTML uses C<&#I<NNN>;> where I<NNN> is a decimal number and
 706 XML uses C<&#xI<HHHH>;> where I<HHHH> is the hexadecimal number.
 707
 708 In Encode 2.10 or later, C<LEAVE_SRC> is also implied.
 709
 710 =item The bitmask
 711
 712 These modes are actually set via a bitmask.  Here is how the FB_XX
 713 constants are laid out.  You can import the FB_XX constants via
 714 C<use Encode qw(:fallbacks)>; you can import the generic bitmask
 715 constants via C<use Encode qw(:fallback_all)>.
 716
 717                      FB_DEFAULT FB_CROAK FB_QUIET FB_WARN  FB_PERLQQ
 718  DIE_ON_ERR    0x0001             X
 719  WARN_ON_ERR   0x0002                               X
 720  RETURN_ON_ERR 0x0004                      X        X
 721  LEAVE_SRC     0x0008                                        X
 722  PERLQQ        0x0100                                        X
 723  HTMLCREF      0x0200
 724  XMLCREF       0x0400
 725
 726 =back
 727
 728 =over 2
 729
 730 =item Encode::LEAVE_SRC
 731
 732 If the C<Encode::LEAVE_SRC> bit is not set, but I<CHECK> is, then the second
 733 argument to C<encode()> or C<decode()> may be assigned to by the functions. If
 734 you're not interested in this, then bitwise-or the bitmask with it.
 735
 736 =back
 737
 738 =head2 coderef for CHECK
 739
 740 As of Encode 2.12 CHECK can also be a code reference which takes the
 741 ord value of unmapped caharacter as an argument and returns a string
 742 that represents the fallback character.  For instance,
 743
 744   $ascii = encode("ascii", $utf8, sub{ sprintf "<U+%04X>", shift });
 745
 746 Acts like FB_PERLQQ but E<lt>U+I<XXXX>E<gt> is used instead of
 747 \x{I<XXXX>}.
 748
 749 =head1 Defining Encodings
 750
 751 To define a new encoding, use:
 752
 753     use Encode qw(define_encoding);
 754     define_encoding($object, 'canonicalName' [, alias...]);
 755
 756 I<canonicalName> will be associated with I<$object>.  The object
 757 should provide the interface described in L<Encode::Encoding>.
 758 If more than two arguments are provided then additional
 759 arguments are taken as aliases for I<$object>.
 760
 761 See L<Encode::Encoding> for more details.
 762
 763 =head1 The UTF8 flag
 764
 765 Before the introduction of Unicode support in perl, The C<eq> operator
 766 just compared the strings represented by two scalars. Beginning with
 767 perl 5.8, C<eq> compares two strings with simultaneous consideration of
 768 I<the UTF8 flag>. To explain why we made it so, I will quote page 402 of
 769 C<Programming Perl, 3rd ed.>
 770
 771 =over 2
 772
 773 =item Goal #1:
 774
 775 Old byte-oriented programs should not spontaneously break on the old
 776 byte-oriented data they used to work on.
 777
 778 =item Goal #2:
 779
 780 Old byte-oriented programs should magically start working on the new
 781 character-oriented data when appropriate.
 782
 783 =item Goal #3:
 784
 785 Programs should run just as fast in the new character-oriented mode
 786 as in the old byte-oriented mode.
 787
 788 =item Goal #4:
 789
 790 Perl should remain one language, rather than forking into a
 791 byte-oriented Perl and a character-oriented Perl.
 792
 793 =back
 794
 795 Back when C<Programming Perl, 3rd ed.> was written, not even Perl 5.6.0
 796 was born and many features documented in the book remained
 797 unimplemented for a long time.  Perl 5.8 corrected this and the introduction
 798 of the UTF8 flag is one of them.  You can think of this perl notion as of a
 799 byte-oriented mode (UTF8 flag off) and a character-oriented mode (UTF8
 800 flag on).
 801
 802 Here is how Encode takes care of the UTF8 flag.
 803
 804 =over 2
 805
 806 =item *
 807
 808 When you encode, the resulting UTF8 flag is always off.
 809
 810 =item *
 811
 812 When you decode, the resulting UTF8 flag is on unless you can
 813 unambiguously represent data.  Here is the definition of
 814 dis-ambiguity.
 815
 816 After C<$utf8 = decode('foo', $octet);>,
 817
 818   When $octet is...   The UTF8 flag in $utf8 is
 819   ---------------------------------------------
 820   In ASCII only (or EBCDIC only)            OFF
 821   In ISO-8859-1                              ON
 822   In any other Encoding                      ON
 823   ---------------------------------------------
 824
 825 As you see, there is one exception, In ASCII.  That way you can assume
 826 Goal #1.  And with Encode Goal #2 is assumed but you still have to be
 827 careful in such cases mentioned in B<CAVEAT> paragraphs.
 828
 829 This UTF8 flag is not visible in perl scripts, exactly for the same
 830 reason you cannot (or you I<don't have to>) see if a scalar contains a
 831 string, integer, or floating point number.   But you can still peek
 832 and poke these if you will.  See the section below.
 833
 834 =back
 835
 836 =head2 Messing with Perl's Internals
 837
 838 The following API uses parts of Perl's internals in the current
 839 implementation.  As such, they are efficient but may change.
 840
 841 =over 2
 842
 843 =item is_utf8(STRING [, CHECK])
 844
 845 [INTERNAL] Tests whether the UTF8 flag is turned on in the STRING.
 846 If CHECK is true, also checks the data in STRING for being well-formed
 847 UTF-8.  Returns true if successful, false otherwise.
 848
 849 As of perl 5.8.1, L<utf8> also has utf8::is_utf8().
 850
 851 =item _utf8_on(STRING)
 852
 853 [INTERNAL] Turns on the UTF8 flag in STRING.  The data in STRING is
 854 B<not> checked for being well-formed UTF-8.  Do not use unless you
 855 B<know> that the STRING is well-formed UTF-8.  Returns the previous
 856 state of the UTF8 flag (so please don't treat the return value as
 857 indicating success or failure), or C<undef> if STRING is not a string.
 858
 859 =item _utf8_off(STRING)
 860
 861 [INTERNAL] Turns off the UTF8 flag in STRING.  Do not use frivolously.
 862 Returns the previous state of the UTF8 flag (so please don't treat the
 863 return value as indicating success or failure), or C<undef> if STRING is
 864 not a string.
 865
 866 =back
 867
 868 =head1 UTF-8 vs. utf8 vs. UTF8
 869
 870   ....We now view strings not as sequences of bytes, but as sequences
 871   of numbers in the range 0 .. 2**32-1 (or in the case of 64-bit
 872   computers, 0 .. 2**64-1) -- Programming Perl, 3rd ed.
 873
 874 That has been the perl's notion of UTF-8 but official UTF-8 is more
 875 strict; Its ranges is much narrower (0 .. 10FFFF), some sequences are
 876 not allowed (i.e. Those used in the surrogate pair, 0xFFFE, et al).
 877
 878 Now that is overruled by Larry Wall himself.
 879
 880   From: Larry Wall <larry@wall.org>
 881   Date: December 04, 2004 11:51:58 JST
 882   To: perl-unicode@perl.org
 883   Subject: Re: Make Encode.pm support the real UTF-8
 884   Message-Id: <20041204025158.GA28754@wall.org>
 885
 886   On Fri, Dec 03, 2004 at 10:12:12PM +0000, Tim Bunce wrote:
 887   : I've no problem with 'utf8' being perl's unrestricted uft8 encoding,
 888   : but "UTF-8" is the name of the standard and should give the
 889   : corresponding behaviour.
 890
 891   For what it's worth, that's how I've always kept them straight in my
 892   head.
 893
 894   Also for what it's worth, Perl 6 will mostly default to strict but
 895   make it easy to switch back to lax.
 896
 897   Larry
 898
 899 Do you copy?  As of Perl 5.8.7, B<UTF-8> means strict, official UTF-8
 900 while B<utf8> means liberal, lax, version thereof.  And Encode version
 901 2.10 or later thus groks the difference between C<UTF-8> and C"utf8".
 902
 903   encode("utf8",  "\x{FFFF_FFFF}", 1); # okay
 904   encode("UTF-8", "\x{FFFF_FFFF}", 1); # croaks
 905
 906 C<UTF-8> in Encode is actually a canonical name for C<utf-8-strict>.
 907 Yes, the hyphen between "UTF" and "8" is important.  Without it Encode
 908 goes "liberal"
 909
 910   find_encoding("UTF-8")->name # is 'utf-8-strict'
 911   find_encoding("utf-8")->name # ditto. names are case insensitive
 912   find_encoding("utf_8")->name  # ditto. "_" are treated as "-"
 913   find_encoding("UTF8")->name  # is 'utf8'.
 914
 915 The UTF8 flag is internally called UTF8, without a hyphen. It indicates
 916 whether a string is internally encoded as utf8, also without a hypen.
 917
 918 =head1 SEE ALSO
 919
 920 L<Encode::Encoding>,
 921 L<Encode::Supported>,
 922 L<Encode::PerlIO>,
 923 L<encoding>,
 924 L<perlebcdic>,
 925 L<perlfunc/open>,
 926 L<perlunicode>, L<perluniintro>, L<perlunifaq>, L<perlunitut>
 927 L<utf8>,
 928 the Perl Unicode Mailing List E<lt>perl-unicode@perl.orgE<gt>
 929
 930 =head1 MAINTAINER
 931
 932 This project was originated by Nick Ing-Simmons and later maintained
 933 by Dan Kogai E<lt>dankogai@dan.co.jpE<gt>.  See AUTHORS for a full
 934 list of people involved.  For any questions, use
 935 E<lt>perl-unicode@perl.orgE<gt> so we can all share.
 936
 937 While Dan Kogai retains the copyright as a maintainer, the credit
 938 should go to all those involoved.  See AUTHORS for those submitted
 939 codes.
 940
 941 =head1 COPYRIGHT
 942
 943 Copyright 2002-2006 Dan Kogai E<lt>dankogai@dan.co.jpE<gt>
 944
 945 This library is free software; you can redistribute it and/or modify
 946 it under the same terms as Perl itself.
 947
 948 =cut