ext/Encode/Encode.pm

   1 package Encode;
   2 use strict;
   3 our $VERSION = '0.40';
   4
   5 require DynaLoader;
   6 require Exporter;
   7
   8 our @ISA = qw(Exporter DynaLoader);
   9
  10 # Public, encouraged API is exported by default
  11 our @EXPORT = qw (
  12   encode
  13   decode
  14   encode_utf8
  15   decode_utf8
  16   find_encoding
  17   encodings
  18 );
  19
  20 our @EXPORT_OK =
  21     qw(
  22        define_encoding
  23        define_alias
  24        from_to
  25        is_utf8
  26        is_8bit
  27        is_16bit
  28        utf8_upgrade
  29        utf8_downgrade
  30        _utf8_on
  31        _utf8_off
  32       );
  33
  34 bootstrap Encode ();
  35
  36 # Documentation moved after __END__ for speed - NI-S
  37
  38 use Carp;
  39
  40 # Make a %encoding package variable to allow a certain amount of cheating
  41 our %encoding;
  42 my @alias;  # ordered matching list
  43 my %alias;  # cached known aliases
  44
  45                      # 0  1  2  3  4  5   6   7   8   9  10
  46 our @latin2iso_num = ( 0, 1, 2, 3, 4, 9, 10, 13, 14, 15, 16 );
  47
  48 our %winlatin2cp   = (
  49                       'Latin1'     => 1252,
  50                       'Latin2'     => 1250,
  51                       'Cyrillic'   => 1251,
  52                       'Greek'      => 1253,
  53                       'Turkish'    => 1254,
  54                       'Hebrew'     => 1255,
  55                       'Arabic'     => 1256,
  56                       'Baltic'     => 1257,
  57                       'Vietnamese' => 1258,
  58                      );
  59
  60 sub encodings
  61 {
  62  my ($class) = @_;
  63  return
  64      map { $_->[0] }
  65          sort { $a->[1] cmp $b->[1] }
  66                map { [$_, lc $_] }
  67                    grep { $_ ne 'Internal' }
  68                         keys %encoding;
  69 }
  70
  71 sub findAlias
  72 {
  73     my $class = shift;
  74     local $_ = shift;
  75     # print "# findAlias $_\n";
  76     unless (exists $alias{$_})
  77     {
  78         for (my $i=0; $i < @alias; $i += 2)
  79         {
  80             my $alias = $alias[$i];
  81             my $val   = $alias[$i+1];
  82             my $new;
  83             if (ref($alias) eq 'Regexp' && $_ =~ $alias)
  84             {
  85                 $new = eval $val;
  86             }
  87             elsif (ref($alias) eq 'CODE')
  88             {
  89                 $new = &{$alias}($val)
  90                 }
  91             elsif (lc($_) eq lc($alias))
  92             {
  93                 $new = $val;
  94             }
  95             if (defined($new))
  96             {
  97                 next if $new eq $_; # avoid (direct) recursion on bugs
  98                 my $enc = (ref($new)) ? $new : find_encoding($new);
  99                 if ($enc)
 100                 {
 101                     $alias{$_} = $enc;
 102                     last;
 103                 }
 104             }
 105         }
 106     }
 107     return $alias{$_};
 108 }
 109
 110 sub define_alias
 111 {
 112     while (@_)
 113     {
 114         my ($alias,$name) = splice(@_,0,2);
 115         push(@alias, $alias => $name);
 116     }
 117 }
 118
 119 # Allow variants of iso-8859-1 etc.
 120 define_alias( qr/^iso[-_]?(\d+)[-_](\d+)$/i => '"iso-$1-$2"' );
 121
 122 # At least HP-UX has these.
 123 define_alias( qr/^iso8859(\d+)$/i => '"iso-8859-$1"' );
 124
 125 # More HP stuff.
 126 define_alias( qr/^(?:hp-)?(arabic|greek|hebrew|kana|roman|thai|turkish)8$/i => '"${1}8"' );
 127
 128 # The Official name of ASCII.
 129 define_alias( qr/^ANSI[-_]?X3\.4[-_]?1968$/i => '"ascii"' );
 130
 131 # This is a font issue, not an encoding issue.
 132 # (The currency symbol of the Latin 1 upper half
 133 #  has been redefined as the euro symbol.)
 134 define_alias( qr/^(.+)\@euro$/i => '"$1"' );
 135
 136 # Allow latin-1 style names as well
 137 define_alias( qr/^(?:iso[-_]?)?latin[-_]?(\d+)$/i => '"iso-8859-$latin2iso_num[$1]"' );
 138
 139 # Allow winlatin1 style names as well
 140 define_alias( qr/^win(latin[12]|cyrillic|baltic|greek|turkish|hebrew|arabic|baltic|vietnamese)$/i => '"cp$winlatin2cp{\u$1}"' );
 141
 142 # Common names for non-latin prefered MIME names
 143 define_alias( 'ascii'    => 'US-ascii',
 144               'cyrillic' => 'iso-8859-5',
 145               'arabic'   => 'iso-8859-6',
 146               'greek'    => 'iso-8859-7',
 147               'hebrew'   => 'iso-8859-8',
 148               'thai'     => 'iso-8859-11',
 149               'tis620'   => 'iso-8859-11',
 150             );
 151
 152 # At least AIX has IBM-NNN (surprisingly...) instead of cpNNN.
 153 # And Microsoft has their own naming (again, surprisingly).
 154 define_alias( qr/^(?:ibm|ms)[-_]?(\d\d\d\d?)$/i => '"cp$1"');
 155
 156 # Sometimes seen with a leading zero.
 157 define_alias( qr/^cp037$/i => '"cp37"');
 158
 159 # Ououououou.
 160 define_alias( qr/^macRomanian$/i => '"macRumanian"');
 161
 162 # Standardize on the dashed versions.
 163 define_alias( qr/^utf8$/i  => 'utf-8' );
 164 define_alias( qr/^koi8r$/i => 'koi8-r' );
 165 define_alias( qr/^koi8u$/i => 'koi8-u' );
 166
 167 # Seen in some Linuxes.
 168 define_alias( qr/^ujis$/i => 'euc-jp' );
 169
 170 # CP936 doesn't have vendor-addon for GBK, so they're identical.
 171 define_alias( qr/^gbk$/i => '"cp936"');
 172
 173 # TODO: HP-UX '8' encodings arabic8 greek8 hebrew8 kana8 thai8 turkish8
 174 # TODO: HP-UX '15' encodings japanese15 korean15 roi15
 175 # TODO: Cyrillic encoding ISO-IR-111 (useful?)
 176 # TODO: Chinese encodings HZ
 177 # TODO: Armenian encoding ARMSCII-8
 178 # TODO: Hebrew encoding ISO-8859-8-1
 179 # TODO: Thai encoding TCVN
 180 # TODO: Korean encoding Johab
 181 # TODO: Vietnamese encodings VPS
 182 # TODO: Japanese encoding JIS (not the same as SJIS)
 183 # TODO: Mac Asian+African encodings: Arabic Armenian Bengali Burmese
 184 #       ChineseSimp ChineseTrad Devanagari Ethiopic ExtArabic
 185 #       Farsi Georgian Gujarati Gurmukhi Hebrew Japanese
 186 #       Kannada Khmer Korean Laotian Malayalam Mongolian
 187 #       Oriya Sinhalese Symbol Tamil Telugu Tibetan Vietnamese
 188
 189 # Map white space and _ to '-'
 190 define_alias( qr/^(\S+)[\s_]+(.*)$/i => '"$1-$2"' );
 191
 192 sub define_encoding
 193 {
 194     my $obj  = shift;
 195     my $name = shift;
 196     $encoding{$name} = $obj;
 197     my $lc = lc($name);
 198     define_alias($lc => $obj) unless $lc eq $name;
 199     while (@_)
 200     {
 201         my $alias = shift;
 202         define_alias($alias,$obj);
 203     }
 204     return $obj;
 205 }
 206
 207 sub getEncoding
 208 {
 209     my ($class,$name) = @_;
 210     my $enc;
 211     if (ref($name) && $name->can('new_sequence'))
 212     {
 213         return $name;
 214     }
 215     my $lc = lc $name;
 216     if (exists $encoding{$name})
 217     {
 218         return $encoding{$name};
 219     }
 220     if (exists $encoding{$lc})
 221     {
 222         return $encoding{$lc};
 223     }
 224
 225     my $oc = $class->findAlias($name);
 226     return $oc if defined $oc;
 227     return $class->findAlias($lc) if $lc ne $name;
 228
 229     return;
 230 }
 231
 232 sub find_encoding
 233 {
 234     my ($name) = @_;
 235     return __PACKAGE__->getEncoding($name);
 236 }
 237
 238 sub encode
 239 {
 240     my ($name,$string,$check) = @_;
 241     my $enc = find_encoding($name);
 242     croak("Unknown encoding '$name'") unless defined $enc;
 243     my $octets = $enc->encode($string,$check);
 244     return undef if ($check && length($string));
 245     return $octets;
 246 }
 247
 248 sub decode
 249 {
 250     my ($name,$octets,$check) = @_;
 251     my $enc = find_encoding($name);
 252     croak("Unknown encoding '$name'") unless defined $enc;
 253     my $string = $enc->decode($octets,$check);
 254     $_[1] = $octets if $check;
 255     return $string;
 256 }
 257
 258 sub from_to
 259 {
 260     my ($string,$from,$to,$check) = @_;
 261     my $f = find_encoding($from);
 262     croak("Unknown encoding '$from'") unless defined $f;
 263     my $t = find_encoding($to);
 264     croak("Unknown encoding '$to'") unless defined $t;
 265     my $uni = $f->decode($string,$check);
 266     return undef if ($check && length($string));
 267     $string = $t->encode($uni,$check);
 268     return undef if ($check && length($uni));
 269     return length($_[0] = $string);
 270 }
 271
 272 sub encode_utf8
 273 {
 274     my ($str) = @_;
 275   utf8::encode($str);
 276     return $str;
 277 }
 278
 279 sub decode_utf8
 280 {
 281     my ($str) = @_;
 282     return undef unless utf8::decode($str);
 283     return $str;
 284 }
 285
 286 require Encode::Encoding;
 287 require Encode::XS;
 288 require Encode::Internal;
 289 require Encode::Unicode;
 290 require Encode::utf8;
 291 require Encode::iso10646_1;
 292 require Encode::ucs2_le;
 293
 294 1;
 295
 296 __END__
 297
 298 =head1 NAME
 299
 300 Encode - character encodings
 301
 302 =head1 SYNOPSIS
 303
 304     use Encode;
 305
 306     use Encode::TW; # for Taiwan-based Chinese encodings
 307     use Encode::CN; # for China-based Chinese encodings
 308     use Encode::JP; # for Japanese encodings
 309     use Encode::KR; # for Korean encodings
 310
 311 =head1 DESCRIPTION
 312
 313 The C<Encode> module provides the interfaces between Perl's strings
 314 and the rest of the system.  Perl strings are sequences of B<characters>.
 315
 316 The repertoire of characters that Perl can represent is at least that
 317 defined by the Unicode Consortium. On most platforms the ordinal
 318 values of the characters (as returned by C<ord(ch)>) is the "Unicode
 319 codepoint" for the character (the exceptions are those platforms where
 320 the legacy encoding is some variant of EBCDIC rather than a super-set
 321 of ASCII - see L<perlebcdic>).
 322
 323 Traditionaly computer data has been moved around in 8-bit chunks
 324 often called "bytes". These chunks are also known as "octets" in
 325 networking standards. Perl is widely used to manipulate data of
 326 many types - not only strings of characters representing human or
 327 computer languages but also "binary" data being the machines representation
 328 of numbers, pixels in an image - or just about anything.
 329
 330 When Perl is processing "binary data" the programmer wants Perl to process
 331 "sequences of bytes". This is not a problem for Perl - as a byte has 256
 332 possible values it easily fits in Perl's much larger "logical character".
 333
 334 Due to size concerns, before using B<CJK> (Chinese, Japanese & Korean)
 335 encodings, you have to C<use> the corresponding
 336 B<Encode::>(B<TW>|B<CN>|B<JP>|B<KR>) modules first.
 337
 338 =head2 TERMINOLOGY
 339
 340 =over 4
 341
 342 =item *
 343
 344 I<character>: a character in the range 0..(2**32-1) (or more).
 345 (What Perl's strings are made of.)
 346
 347 =item *
 348
 349 I<byte>: a character in the range 0..255
 350 (A special case of a Perl character.)
 351
 352 =item *
 353
 354 I<octet>: 8 bits of data, with ordinal values 0..255
 355 (Term for bytes passed to or from a non-Perl context, e.g. disk file.)
 356
 357 =back
 358
 359 The marker [INTERNAL] marks Internal Implementation Details, in
 360 general meant only for those who think they know what they are doing,
 361 and such details may change in future releases.
 362
 363 =head1 ENCODINGS
 364
 365 =head2 Characteristics of an Encoding
 366
 367 An encoding has a "repertoire" of characters that it can represent,
 368 and for each representable character there is at least one sequence of
 369 octets that represents it.
 370
 371 =head2 Types of Encodings
 372
 373 Encodings can be divided into the following types:
 374
 375 =over 4
 376
 377 =item * Fixed length 8-bit (or less) encodings.
 378
 379 Each character is a single octet so may have a repertoire of up to
 380 256 characters. ASCII and iso-8859-* are typical examples.
 381
 382 =item * Fixed length 16-bit encodings
 383
 384 Each character is two octets so may have a repertoire of up to
 385 65 536 characters.  Unicode's UCS-2 is an example.  Also used for
 386 encodings for East Asian languages.
 387
 388 =item * Fixed length 32-bit encodings.
 389
 390 Not really very "encoded" encodings. The Unicode code points
 391 are just represented as 4-octet integers. None the less because
 392 different architectures use different representations of integers
 393 (so called "endian") there at least two disctinct encodings.
 394
 395 =item * Multi-byte encodings
 396
 397 The number of octets needed to represent a character varies.
 398 UTF-8 is a particularly complex but regular case of a multi-byte
 399 encoding. Several East Asian countries use a multi-byte encoding
 400 where 1-octet is used to cover western roman characters and Asian
 401 characters get 2-octets.
 402 (UTF-16 is strictly a multi-byte encoding taking either 2 or 4 octets
 403 to represent a Unicode code point.)
 404
 405 =item * "Escape" encodings.
 406
 407 These encodings embed "escape sequences" into the octet sequence
 408 which describe how the following octets are to be interpreted.
 409 The iso-2022-* family is typical. Following the escape sequence
 410 octets are encoded by an "embedded" encoding (which will be one
 411 of the above types) until another escape sequence switches to
 412 a different "embedded" encoding.
 413
 414 These schemes are very flexible and can handle mixed languages but are
 415 very complex to process (and have state).  No escape encodings are
 416 implemented for Perl yet.
 417
 418 =back
 419
 420 =head2 Specifying Encodings
 421
 422 Encodings can be specified to the API described below in two ways:
 423
 424 =over 4
 425
 426 =item 1. By name
 427
 428 Encoding names are strings with characters taken from a restricted
 429 repertoire.  See L</"Encoding Names">.
 430
 431 =item 2. As an object
 432
 433 Encoding objects are returned by C<find_encoding($name)>.
 434
 435 =back
 436
 437 =head2 Encoding Names
 438
 439 Encoding names are case insensitive. White space in names is ignored.
 440 In addition an encoding may have aliases. Each encoding has one
 441 "canonical" name.  The "canonical" name is chosen from the names of
 442 the encoding by picking the first in the following sequence:
 443
 444 =over 4
 445
 446 =item * The MIME name as defined in IETF RFCs.
 447
 448 =item * The name in the IANA registry.
 449
 450 =item * The name used by the organization that defined it.
 451
 452 =back
 453
 454 Because of all the alias issues, and because in the general case
 455 encodings have state C<Encode> uses the encoding object internally
 456 once an operation is in progress.
 457
 458 As of Perl 5.8.0, at least the following encodings are recognized
 459 (the => marks aliases):
 460
 461   ASCII
 462
 463   US-ASCII => ASCII
 464
 465 The Unicode:
 466
 467   UTF-8
 468   UTF-16
 469   UCS-2
 470
 471   ISO 10646-1 => UCS-2
 472
 473 The ISO 8859 and KOI:
 474
 475   ISO 8859-1  ISO 8859-6   ISO 8859-11         KOI8-F
 476   ISO 8859-2  ISO 8859-7   (12 doesn't exist)  KOI8-R
 477   ISO 8859-3  ISO 8859-8   ISO 8859-13         KOI8-U
 478   ISO 8859-4  ISO 8859-9   ISO 8859-14
 479   ISO 8859-5  ISO 8859-10  ISO 8859-15
 480                            ISO 8859-16
 481
 482   Latin1  => 8859-1  Latin6  => 8859-10
 483   Latin2  => 8859-2  Latin7  => 8859-13
 484   Latin3  => 8859-3  Latin8  => 8859-14
 485   Latin4  => 8859-4  Latin9  => 8859-15
 486   Latin5  => 8859-9  Latin10 => 8859-16
 487
 488   Cyrillic => 8859-5
 489   Arabic   => 8859-6
 490   Greek    => 8859-7
 491   Hebrew   => 8859-8
 492   Thai     => 8859-11
 493   TIS620   => 8859-11
 494
 495 The CJKV: Chinese, Japanese, Korean, Vietnamese:
 496
 497   ISO 2022     ISO 2022 JP-1  JIS 0201  GB 1988   Big5       EUC-CN
 498   ISO 2022 CN  ISO 2022 JP-2  JIS 0208  GB 2312   HZ         EUC-JP
 499   ISO 2022 JP  ISO 2022 KR    JIS 0210  GB 12345  CNS 11643  EUC-JP-0212
 500   Shift-JIS                             GBK       Big5-HKSCS EUC-KR
 501   VISCII                                ISO-IR-165
 502
 503 (Due to size concerns, additional Chinese encodings including C<GB 18030>,
 504 C<EUC-TW> and C<BIG5PLUS> are distributed separately on CPAN, under the name
 505 L<Encode::HanExtra>.)
 506
 507 The PC codepages:
 508
 509   CP37   CP852  CP861  CP866  CP949   CP1251  CP1256
 510   CP424  CP855  CP862  CP869  CP950   CP1252  CP1257
 511   CP737  CP856  CP863  CP874  CP1006  CP1253  CP1258
 512   CP775  CP857  CP864  CP932  CP1047  CP1254
 513   CP850  CP860  CP865  CP936  CP1250  CP1255
 514
 515   WinLatin1     => CP1252
 516   WinLatin2     => CP1250
 517   WinCyrillic   => CP1251
 518   WinGreek      => CP1253
 519   WinTurkiskh   => CP1254
 520   WinHebrew     => CP1255
 521   WinArabic     => CP1256
 522   WinBaltic     => CP1257
 523   WinVietnamese => CP1258
 524
 525 (All the CPI<NNN...> are available also as IBMI<NNN...>.)
 526
 527 The Mac codepages:
 528
 529   MacCentralEuropean   MacJapanese
 530   MacCroatian          MacRoman
 531   MacCyrillic          MacRomanian
 532   MacDingbats          MacSami
 533   MacGreek             MacThai
 534   MacIcelandic         MacTurkish
 535                        MacUkraine
 536
 537 Miscellaneous:
 538
 539   7bit-greek  IR-197
 540   7bit-kana   NeXTstep
 541   7bit-latin1 POSIX-BC
 542   DingBats    Roman8
 543   GSM 0338    Symbol
 544
 545 =head1 PERL ENCODING API
 546
 547 =head2 Generic Encoding Interface
 548
 549 =over 4
 550
 551 =item *
 552
 553         $bytes  = encode(ENCODING, $string[, CHECK])
 554
 555 Encodes string from Perl's internal form into I<ENCODING> and returns
 556 a sequence of octets.  For CHECK see L</"Handling Malformed Data">.
 557
 558 For example to convert (internally UTF-8 encoded) Unicode data
 559 to octets:
 560
 561         $octets = encode("utf8", $unicode);
 562
 563 =item *
 564
 565         $string = decode(ENCODING, $bytes[, CHECK])
 566
 567 Decode sequence of octets assumed to be in I<ENCODING> into Perl's
 568 internal form and returns the resulting string.  For CHECK see
 569 L</"Handling Malformed Data">.
 570
 571 For example to convert ISO 8859-1 data to UTF-8:
 572
 573         $utf8 = decode("latin1", $latin1);
 574
 575 =item *
 576
 577         from_to($string, FROM_ENCODING, TO_ENCODING[, CHECK])
 578
 579 Convert B<in-place> the data between two encodings.  How did the data
 580 in $string originally get to be in FROM_ENCODING?  Either using
 581 encode() or through PerlIO: See L</"Encoding and IO">.  For CHECK
 582 see L</"Handling Malformed Data">.
 583
 584 For example to convert ISO 8859-1 data to UTF-8:
 585
 586         from_to($data, "iso-8859-1", "utf-8");
 587
 588 and to convert it back:
 589
 590         from_to($data, "utf-8", "iso-8859-1");
 591
 592 Note that because the conversion happens in place, the data to be
 593 converted cannot be a string constant, it must be a scalar variable.
 594
 595 =back
 596
 597 =head2 Handling Malformed Data
 598
 599 If CHECK is not set, C<undef> is returned.  If the data is supposed to
 600 be UTF-8, an optional lexical warning (category utf8) is given.  If
 601 CHECK is true but not a code reference, dies.
 602
 603 It would desirable to have a way to indicate that transform should use
 604 the encodings "replacement character" - no such mechanism is defined yet.
 605
 606 It is also planned to allow I<CHECK> to be a code reference.
 607
 608 This is not yet implemented as there are design issues with what its
 609 arguments should be and how it returns its results.
 610
 611 =over 4
 612
 613 =item Scheme 1
 614
 615 Passed remaining fragment of string being processed.
 616 Modifies it in place to remove bytes/characters it can understand
 617 and returns a string used to represent them.
 618 e.g.
 619
 620  sub fixup {
 621    my $ch = substr($_[0],0,1,'');
 622    return sprintf("\x{%02X}",ord($ch);
 623  }
 624
 625 This scheme is close to how underlying C code for Encode works, but gives
 626 the fixup routine very little context.
 627
 628 =item Scheme 2
 629
 630 Passed original string, and an index into it of the problem area, and
 631 output string so far.  Appends what it will to output string and
 632 returns new index into original string.  For example:
 633
 634  sub fixup {
 635    # my ($s,$i,$d) = @_;
 636    my $ch = substr($_[0],$_[1],1);
 637    $_[2] .= sprintf("\x{%02X}",ord($ch);
 638    return $_[1]+1;
 639  }
 640
 641 This scheme gives maximal control to the fixup routine but is more
 642 complicated to code, and may need internals of Encode to be tweaked to
 643 keep original string intact.
 644
 645 =item Other Schemes
 646
 647 Hybrids of above.
 648
 649 Multiple return values rather than in-place modifications.
 650
 651 Index into the string could be pos($str) allowing s/\G...//.
 652
 653 =back
 654
 655 =head2 UTF-8 / utf8
 656
 657 The Unicode consortium defines the UTF-8 standard as a way of encoding
 658 the entire Unicode repertiore as sequences of octets.  This encoding is
 659 expected to become very widespread. Perl can use this form internaly
 660 to represent strings, so conversions to and from this form are
 661 particularly efficient (as octets in memory do not have to change,
 662 just the meta-data that tells Perl how to treat them).
 663
 664 =over 4
 665
 666 =item *
 667
 668         $bytes = encode_utf8($string);
 669
 670 The characters that comprise string are encoded in Perl's superset of UTF-8
 671 and the resulting octets returned as a sequence of bytes. All possible
 672 characters have a UTF-8 representation so this function cannot fail.
 673
 674 =item *
 675
 676         $string = decode_utf8($bytes [,CHECK]);
 677
 678 The sequence of octets represented by $bytes is decoded from UTF-8
 679 into a sequence of logical characters. Not all sequences of octets
 680 form valid UTF-8 encodings, so it is possible for this call to fail.
 681 For CHECK see L</"Handling Malformed Data">.
 682
 683 =back
 684
 685 =head2 Other Encodings of Unicode
 686
 687 UTF-16 is similar to UCS-2, 16 bit or 2-byte chunks.  UCS-2 can only
 688 represent 0..0xFFFF, while UTF-16 has a I<surrogate pair> scheme which
 689 allows it to cover the whole Unicode range.
 690
 691 Surrogates are code points set aside to encode the 0x01000..0x10FFFF
 692 range of Unicode code points in pairs of 16-bit units.  The I<high
 693 surrogates> are the range 0xD800..0xDBFF, and the I<low surrogates>
 694 are the range 0xDC00..0xDFFFF.  The surrogate encoding is
 695
 696         $hi = ($uni - 0x10000) / 0x400 + 0xD800;
 697         $lo = ($uni - 0x10000) % 0x400 + 0xDC00;
 698
 699 and the decoding is
 700
 701         $uni = 0x10000 + ($hi - 0xD8000) * 0x400 + ($lo - 0xDC00);
 702
 703 Encode implements big-endian UCS-2 aliased to "iso-10646-1" as that
 704 happens to be the name used by that representation when used with X11
 705 fonts.
 706
 707 UTF-32 or UCS-4 is 32-bit or 4-byte chunks.  Perl's logical characters
 708 can be considered as being in this form without encoding. An encoding
 709 to transfer strings in this form (e.g. to write them to a file) would
 710 need to
 711
 712      pack('L*', unpack('U*', $string));  # native
 713   or
 714      pack('V*', unpack('U*', $string));  # little-endian
 715   or
 716      pack('N*', unpack('U*', $string));  # big-endian
 717
 718 depending on the endianness required.
 719
 720 No UTF-32 encodings are implemented yet.
 721
 722 Both UCS-2 and UCS-4 style encodings can have "byte order marks" by
 723 representing the code point 0xFFFE as the very first thing in a file.
 724
 725 =head2 Listing available encodings
 726
 727   use Encode qw(encodings);
 728   @list = encodings();
 729
 730 Returns a list of the canonical names of the available encodings.
 731
 732 =head2 Defining Aliases
 733
 734   use Encode qw(define_alias);
 735   define_alias( newName => ENCODING);
 736
 737 Allows newName to be used as am alias for ENCODING. ENCODING may be
 738 either the name of an encoding or and encoding object (as above).
 739
 740 Currently I<newName> can be specified in the following ways:
 741
 742 =over 4
 743
 744 =item As a simple string.
 745
 746 =item As a qr// compiled regular expression, e.g.:
 747
 748   define_alias( qr/^iso8859-(\d+)$/i => '"iso-8859-$1"' );
 749
 750 In this case if I<ENCODING> is not a reference it is C<eval>-ed to
 751 allow C<$1> etc. to be subsituted.  The example is one way to names as
 752 used in X11 font names to alias the MIME names for the iso-8859-*
 753 family.
 754
 755 =item As a code reference, e.g.:
 756
 757   define_alias( sub { return /^iso8859-(\d+)$/i ? "iso-8859-$1" : undef } , '');
 758
 759 In this case C<$_> will be set to the name that is being looked up and
 760 I<ENCODING> is passed to the sub as its first argument.  The example
 761 is another way to names as used in X11 font names to alias the MIME
 762 names for the iso-8859-* family.
 763
 764 =back
 765
 766 =head2 Defining Encodings
 767
 768     use Encode qw(define_alias);
 769     define_encoding( $object, 'canonicalName' [,alias...]);
 770
 771 Causes I<canonicalName> to be associated with I<$object>.  The object
 772 should provide the interface described in L</"IMPLEMENTATION CLASSES">
 773 below.  If more than two arguments are provided then additional
 774 arguments are taken as aliases for I<$object> as for C<define_alias>.
 775
 776 =head1 Encoding and IO
 777
 778 It is very common to want to do encoding transformations when
 779 reading or writing files, network connections, pipes etc.
 780 If Perl is configured to use the new 'perlio' IO system then
 781 C<Encode> provides a "layer" (See L<perliol>) which can transform
 782 data as it is read or written.
 783
 784 Here is how the blind poet would modernise the encoding:
 785
 786     use Encode;
 787     open(my $iliad,'<:encoding(iso-8859-7)','iliad.greek');
 788     open(my $utf8,'>:utf8','iliad.utf8');
 789     my @epic = <$iliad>;
 790     print $utf8 @epic;
 791     close($utf8);
 792     close($illiad);
 793
 794 In addition the new IO system can also be configured to read/write
 795 UTF-8 encoded characters (as noted above this is efficient):
 796
 797     open(my $fh,'>:utf8','anything');
 798     print $fh "Any \x{0021} string \N{SMILEY FACE}\n";
 799
 800 Either of the above forms of "layer" specifications can be made the default
 801 for a lexical scope with the C<use open ...> pragma. See L<open>.
 802
 803 Once a handle is open is layers can be altered using C<binmode>.
 804
 805 Without any such configuration, or if Perl itself is built using
 806 system's own IO, then write operations assume that file handle accepts
 807 only I<bytes> and will C<die> if a character larger than 255 is
 808 written to the handle. When reading, each octet from the handle
 809 becomes a byte-in-a-character. Note that this default is the same
 810 behaviour as bytes-only languages (including Perl before v5.6) would
 811 have, and is sufficient to handle native 8-bit encodings
 812 e.g. iso-8859-1, EBCDIC etc. and any legacy mechanisms for handling
 813 other encodings and binary data.
 814
 815 In other cases it is the programs responsibility to transform
 816 characters into bytes using the API above before doing writes, and to
 817 transform the bytes read from a handle into characters before doing
 818 "character operations" (e.g. C<lc>, C</\W+/>, ...).
 819
 820 You can also use PerlIO to convert larger amounts of data you don't
 821 want to bring into memory.  For example to convert between ISO 8859-1
 822 (Latin 1) and UTF-8 (or UTF-EBCDIC in EBCDIC machines):
 823
 824     open(F, "<:encoding(iso-8859-1)", "data.txt") or die $!;
 825     open(G, ">:utf8",                 "data.utf") or die $!;
 826     while (<F>) { print G }
 827
 828     # Could also do "print G <F>" but that would pull
 829     # the whole file into memory just to write it out again.
 830
 831 More examples:
 832
 833     open(my $f, "<:encoding(cp1252)")
 834     open(my $g, ">:encoding(iso-8859-2)")
 835     open(my $h, ">:encoding(latin9)")       # iso-8859-15
 836
 837 See L<PerlIO> for more information.
 838
 839 See also L<encoding> for how to change the default encoding of the
 840 data in your script.
 841
 842 =head1 Encoding How to ...
 843
 844 To do:
 845
 846 =over 4
 847
 848 =item * IO with mixed content (faking iso-2020-*)
 849
 850 =item * MIME's Content-Length:
 851
 852 =item * UTF-8 strings in binary data.
 853
 854 =item * Perl/Encode wrappers on non-Unicode XS modules.
 855
 856 =back
 857
 858 =head1 Messing with Perl's Internals
 859
 860 The following API uses parts of Perl's internals in the current
 861 implementation.  As such they are efficient, but may change.
 862
 863 =over 4
 864
 865 =item * is_utf8(STRING [, CHECK])
 866
 867 [INTERNAL] Test whether the UTF-8 flag is turned on in the STRING.
 868 If CHECK is true, also checks the data in STRING for being well-formed
 869 UTF-8.  Returns true if successful, false otherwise.
 870
 871 =item * valid_utf8(STRING)
 872
 873 [INTERNAL] Test whether STRING is in a consistent state.  Will return
 874 true if string is held as bytes, or is well-formed UTF-8 and has the
 875 UTF-8 flag on.  Main reason for this routine is to allow Perl's
 876 testsuite to check that operations have left strings in a consistent
 877 state.
 878
 879 =item *
 880
 881         _utf8_on(STRING)
 882
 883 [INTERNAL] Turn on the UTF-8 flag in STRING.  The data in STRING is
 884 B<not> checked for being well-formed UTF-8.  Do not use unless you
 885 B<know> that the STRING is well-formed UTF-8.  Returns the previous
 886 state of the UTF-8 flag (so please don't test the return value as
 887 I<not> success or failure), or C<undef> if STRING is not a string.
 888
 889 =item *
 890
 891         _utf8_off(STRING)
 892
 893 [INTERNAL] Turn off the UTF-8 flag in STRING.  Do not use frivolously.
 894 Returns the previous state of the UTF-8 flag (so please don't test the
 895 return value as I<not> success or failure), or C<undef> if STRING is
 896 not a string.
 897
 898 =back
 899
 900 =head1 IMPLEMENTATION CLASSES
 901
 902 As mentioned above encodings are (in the current implementation at least)
 903 defined by objects. The mapping of encoding name to object is via the
 904 C<%encodings> hash.
 905
 906 The values of the hash can currently be either strings or objects.
 907 The string form may go away in the future. The string form occurs
 908 when C<encodings()> has scanned C<@INC> for loadable encodings but has
 909 not actually loaded the encoding in question. This is because the
 910 current "loading" process is all Perl and a bit slow.
 911
 912 Once an encoding is loaded then value of the hash is object which
 913 implements the encoding. The object should provide the following
 914 interface:
 915
 916 =over 4
 917
 918 =item -E<gt>name
 919
 920 Should return the string representing the canonical name of the encoding.
 921
 922 =item -E<gt>new_sequence
 923
 924 This is a placeholder for encodings with state. It should return an
 925 object which implements this interface, all current implementations
 926 return the original object.
 927
 928 =item -E<gt>encode($string,$check)
 929
 930 Should return the octet sequence representing I<$string>. If I<$check>
 931 is true it should modify I<$string> in place to remove the converted
 932 part (i.e.  the whole string unless there is an error).  If an error
 933 occurs it should return the octet sequence for the fragment of string
 934 that has been converted, and modify $string in-place to remove the
 935 converted part leaving it starting with the problem fragment.
 936
 937 If check is is false then C<encode> should make a "best effort" to
 938 convert the string - for example by using a replacement character.
 939
 940 =item -E<gt>decode($octets,$check)
 941
 942 Should return the string that I<$octets> represents. If I<$check> is
 943 true it should modify I<$octets> in place to remove the converted part
 944 (i.e.  the whole sequence unless there is an error).  If an error
 945 occurs it should return the fragment of string that has been
 946 converted, and modify $octets in-place to remove the converted part
 947 leaving it starting with the problem fragment.
 948
 949 If check is is false then C<decode> should make a "best effort" to
 950 convert the string - for example by using Unicode's "\x{FFFD}" as a
 951 replacement character.
 952
 953 =back
 954
 955 It should be noted that the check behaviour is different from the
 956 outer public API. The logic is that the "unchecked" case is useful
 957 when encoding is part of a stream which may be reporting errors
 958 (e.g. STDERR).  In such cases it is desirable to get everything
 959 through somehow without causing additional errors which obscure the
 960 original one. Also the encoding is best placed to know what the
 961 correct replacement character is, so if that is the desired behaviour
 962 then letting low level code do it is the most efficient.
 963
 964 In contrast if check is true, the scheme above allows the encoding to
 965 do as much as it can and tell layer above how much that was. What is
 966 lacking at present is a mechanism to report what went wrong. The most
 967 likely interface will be an additional method call to the object, or
 968 perhaps (to avoid forcing per-stream objects on otherwise stateless
 969 encodings) and additional parameter.
 970
 971 It is also highly desirable that encoding classes inherit from
 972 C<Encode::Encoding> as a base class. This allows that class to define
 973 additional behaviour for all encoding objects. For example built in
 974 Unicode, UCS-2 and UTF-8 classes use :
 975
 976   package Encode::MyEncoding;
 977   use base qw(Encode::Encoding);
 978
 979   __PACKAGE__->Define(qw(myCanonical myAlias));
 980
 981 To create an object with bless {Name => ...},$class, and call
 982 define_encoding.  They inherit their C<name> method from
 983 C<Encode::Encoding>.
 984
 985 =head2 Compiled Encodings
 986
 987 F<Encode.xs> provides a class C<Encode::XS> which provides the
 988 interface described above. It calls a generic octet-sequence to
 989 octet-sequence "engine" that is driven by tables (defined in
 990 F<encengine.c>). The same engine is used for both encode and
 991 decode. C<Encode:XS>'s C<encode> forces Perl's characters to their
 992 UTF-8 form and then treats them as just another multibyte
 993 encoding. C<Encode:XS>'s C<decode> transforms the sequence and then
 994 turns the UTF-8-ness flag as that is the form that the tables are
 995 defined to produce. For details of the engine see the comments in
 996 F<encengine.c>.
 997
 998 The tables are produced by the Perl script F<compile> (the name needs
 999 to change so we can eventually install it somewhere). F<compile> can
1000 currently read two formats:
1001
1002 =over 4
1003
1004 =item *.enc
1005
1006 This is a coined format used by Tcl. It is documented in
1007 Encode/EncodeFormat.pod.
1008
1009 =item *.ucm
1010
1011 This is the semi-standard format used by IBM's ICU package.
1012
1013 =back
1014
1015 F<compile> can write the following forms:
1016
1017 =over 4
1018
1019 =item *.ucm
1020
1021 See above - the F<Encode/*.ucm> files provided with the distribution have
1022 been created from the original Tcl .enc files using this approach.
1023
1024 =item *.c
1025
1026 Produces tables as C data structures - this is used to build in encodings
1027 into F<Encode.so>/F<Encode.dll>.
1028
1029 =item *.xs
1030
1031 In theory this allows encodings to be stand-alone loadable Perl
1032 extensions.  The process has not yet been tested. The plan is to use
1033 this approach for large East Asian encodings.
1034
1035 =back
1036
1037 The set of encodings built-in to F<Encode.so>/F<Encode.dll> is
1038 determined by F<Makefile.PL>.  The current set is as follows:
1039
1040 =over 4
1041
1042 =item ascii and iso-8859-*
1043
1044 That is all the common 8-bit "western" encodings.
1045
1046 =item IBM-1047 and two other variants of EBCDIC.
1047
1048 These are the same variants that are supported by EBCDIC Perl as
1049 "native" encodings.  They are included to prove "reversibility" of
1050 some constructs in EBCDIC Perl.
1051
1052 =item symbol and dingbats as used by Tk on X11.
1053
1054 (The reason Encode got started was to support Perl/Tk.)
1055
1056 =back
1057
1058 That set is rather ad hoc and has been driven by the needs of the
1059 tests rather than the needs of typical applications. It is likely
1060 to be rationalized.
1061
1062 =head1 SEE ALSO
1063
1064 L<perlunicode>, L<perlebcdic>, L<perlfunc/open>, L<PerlIO>, L<encoding>
1065
1066 =cut
1067