ext/Encode/Encode.pm

   1 package Encode;
   2 use strict;
   3
   4 our $VERSION = '0.02';
   5
   6 require DynaLoader;
   7 require Exporter;
   8
   9 our @ISA = qw(Exporter DynaLoader);
  10
  11 # Public, encouraged API is exported by default
  12 our @EXPORT = qw (
  13   encode
  14   decode
  15   encode_utf8
  16   decode_utf8
  17   find_encoding
  18   encodings
  19 );
  20
  21 our @EXPORT_OK =
  22     qw(
  23        define_encoding
  24        define_alias
  25        from_to
  26        is_utf8
  27        is_8bit
  28        is_16bit
  29        utf8_upgrade
  30        utf8_downgrade
  31        _utf8_on
  32        _utf8_off
  33       );
  34
  35 bootstrap Encode ();
  36
  37 # Documentation moved after __END__ for speed - NI-S
  38
  39 use Carp;
  40
  41 # Make a %encoding package variable to allow a certain amount of cheating
  42 our %encoding;
  43 my @alias;  # ordered matching list
  44 my %alias;  # cached known aliases
  45
  46                      # 0  1  2  3  4  5   6   7   8   9  10
  47 our @latin2iso_num = ( 0, 1, 2, 3, 4, 9, 10, 13, 14, 15, 16 );
  48
  49 our %winlatin2cp   = (
  50                       'Latin1'     => 1252,
  51                       'Latin2'     => 1250,
  52                       'Cyrillic'   => 1251,
  53                       'Greek'      => 1253,
  54                       'Turkish'    => 1254,
  55                       'Hebrew'     => 1255,
  56                       'Arabic'     => 1256,
  57                       'Baltic'     => 1257,
  58                       'Vietnamese' => 1258,
  59                      );
  60
  61 sub encodings
  62 {
  63  my ($class) = @_;
  64  return keys %encoding;
  65 }
  66
  67 sub findAlias
  68 {
  69  my $class = shift;
  70  local $_ = shift;
  71  # print "# findAlias $_\n";
  72  unless (exists $alias{$_})
  73   {
  74    for (my $i=0; $i < @alias; $i += 2)
  75     {
  76      my $alias = $alias[$i];
  77      my $val   = $alias[$i+1];
  78      my $new;
  79      if (ref($alias) eq 'Regexp' && $_ =~ $alias)
  80       {
  81        $new = eval $val;
  82       }
  83      elsif (ref($alias) eq 'CODE')
  84       {
  85        $new = &{$alias}($val)
  86       }
  87      elsif (lc($_) eq lc($alias))
  88       {
  89        $new = $val;
  90       }
  91      if (defined($new))
  92       {
  93        next if $new eq $_; # avoid (direct) recursion on bugs
  94        my $enc = (ref($new)) ? $new : find_encoding($new);
  95        if ($enc)
  96         {
  97          $alias{$_} = $enc;
  98          last;
  99         }
 100       }
 101     }
 102   }
 103  return $alias{$_};
 104 }
 105
 106 sub define_alias
 107 {
 108  while (@_)
 109   {
 110    my ($alias,$name) = splice(@_,0,2);
 111    push(@alias, $alias => $name);
 112   }
 113 }
 114
 115 # Allow variants of iso-8859-1 etc.
 116 define_alias( qr/^iso[-_]?(\d+)[-_](\d+)$/i => '"iso-$1-$2"' );
 117
 118 # At least HP-UX has these.
 119 define_alias( qr/^iso8859(\d+)$/i => '"iso-8859-$1"' );
 120
 121 # More HP stuff.
 122 define_alias( qr/^(?:hp-)?(arabic|greek|hebrew|kana|roman|thai|turkish)8$/i => '"${1}8"' );
 123
 124 # The Official name of ASCII.
 125 define_alias( qr/^ANSI[-_]?X3\.4[-_]?1968$/i => '"ascii"' );
 126
 127 # This is a font issue, not an encoding issue.
 128 # (The currency symbol of the Latin 1 upper half
 129 #  has been redefined as the euro symbol.)
 130 define_alias( qr/^(.+)\@euro$/i => '"$1"' );
 131
 132 # Allow latin-1 style names as well
 133 define_alias( qr/^(?:iso[-_]?)?latin[-_]?(\d+)$/i => '"iso-8859-$latin2iso_num[$1]"' );
 134
 135 # Allow winlatin1 style names as well
 136 define_alias( qr/^win(latin[12]|cyrillic|baltic|greek|turkish|hebrew|arabic|baltic|vietnamese)$/i => '"cp$winlatin2cp{\u$1}"' );
 137
 138 # Common names for non-latin prefered MIME names
 139 define_alias( 'ascii'    => 'US-ascii',
 140               'cyrillic' => 'iso-8859-5',
 141               'arabic'   => 'iso-8859-6',
 142               'greek'    => 'iso-8859-7',
 143               'hebrew'   => 'iso-8859-8',
 144               'thai'     => 'iso-8859-11',
 145               'tis620'   => 'iso-8859-11',
 146             );
 147
 148 # At least AIX has IBM-NNN (surprisingly...) instead of cpNNN.
 149 define_alias( qr/^ibm[-_]?(\d\d\d\d?)$/i => '"cp$1"');
 150
 151 # Standardize on the dashed versions.
 152 define_alias( qr/^utf8$/i  => 'utf-8' );
 153 define_alias( qr/^koi8r$/i => 'koi8-r' );
 154 define_alias( qr/^koi8u$/i => 'koi8-u' );
 155
 156 # TODO: HP-UX '8' encodings arabic8 greek8 hebrew8 kana8 thai8 turkish8
 157 # TODO: HP-UX '15' encodings japanese15 korean15 roi15
 158 # TODO: Cyrillic encoding ISO-IR-111 (useful?)
 159 # TODO: Chinese encodings GB18030 GBK Big5-HSKCS EUC-TW
 160 # TODO: Armenian encoding ARMSCII-8
 161 # TODO: Hebrew encoding ISO-8859-8-1
 162 # TODO: Thai encoding TCVN
 163 # TODO: Korean encoding Johab
 164 # TODO: Vietnamese encodings VPS
 165 # TODO: Japanese encoding JIS (not the same as SJIS)
 166 # TODO: Mac Asian+African encodings: Arabic Armenian Bengali Burmese
 167 #       ChineseSimp ChineseTrad Devanagari Ethiopic ExtArabic
 168 #       Farsi Georgian Gujarati Gurmukhi Hebrew Japanese
 169 #       Kannada Khmer Korean Laotian Malayalam Mongolian
 170 #       Oriya Sinhalese Symbol Tamil Telugu Tibetan Vietnamese
 171 # TODO: what is the Japanese 'UJIS' encoding seen in some Linuxes?
 172
 173 # Map white space and _ to '-'
 174 define_alias( qr/^(\S+)[\s_]+(.*)$/i => '"$1-$2"' );
 175
 176 sub define_encoding
 177 {
 178  my $obj  = shift;
 179  my $name = shift;
 180  $encoding{$name} = $obj;
 181  my $lc = lc($name);
 182  define_alias($lc => $obj) unless $lc eq $name;
 183  while (@_)
 184   {
 185    my $alias = shift;
 186    define_alias($alias,$obj);
 187   }
 188  return $obj;
 189 }
 190
 191 sub getEncoding
 192 {
 193  my ($class,$name) = @_;
 194  my $enc;
 195  if (ref($name) && $name->can('new_sequence'))
 196   {
 197    return $name;
 198   }
 199  my $lc = lc $name;
 200  if (exists $encoding{$name})
 201   {
 202    return $encoding{$name};
 203   }
 204  if (exists $encoding{$lc})
 205   {
 206    return $encoding{$lc};
 207   }
 208
 209   my $oc = $class->findAlias($name);
 210   return $oc if defined $oc;
 211   return $class->findAlias($lc) if $lc ne $name;
 212
 213   return;
 214 }
 215
 216 sub find_encoding
 217 {
 218  my ($name) = @_;
 219  return __PACKAGE__->getEncoding($name);
 220 }
 221
 222 sub encode
 223 {
 224  my ($name,$string,$check) = @_;
 225  my $enc = find_encoding($name);
 226  croak("Unknown encoding '$name'") unless defined $enc;
 227  my $octets = $enc->encode($string,$check);
 228  return undef if ($check && length($string));
 229  return $octets;
 230 }
 231
 232 sub decode
 233 {
 234  my ($name,$octets,$check) = @_;
 235  my $enc = find_encoding($name);
 236  croak("Unknown encoding '$name'") unless defined $enc;
 237  my $string = $enc->decode($octets,$check);
 238  $_[1] = $octets if $check;
 239  return $string;
 240 }
 241
 242 sub from_to
 243 {
 244  my ($string,$from,$to,$check) = @_;
 245  my $f = find_encoding($from);
 246  croak("Unknown encoding '$from'") unless defined $f;
 247  my $t = find_encoding($to);
 248  croak("Unknown encoding '$to'") unless defined $t;
 249  my $uni = $f->decode($string,$check);
 250  return undef if ($check && length($string));
 251  $string = $t->encode($uni,$check);
 252  return undef if ($check && length($uni));
 253  return length($_[0] = $string);
 254 }
 255
 256 sub encode_utf8
 257 {
 258  my ($str) = @_;
 259  utf8::encode($str);
 260  return $str;
 261 }
 262
 263 sub decode_utf8
 264 {
 265  my ($str) = @_;
 266  return undef unless utf8::decode($str);
 267  return $str;
 268 }
 269
 270 package Encode::Encoding;
 271 # Base class for classes which implement encodings
 272
 273 sub Define
 274 {
 275  my $obj = shift;
 276  my $canonical = shift;
 277  $obj = bless { Name => $canonical },$obj unless ref $obj;
 278  # warn "$canonical => $obj\n";
 279  Encode::define_encoding($obj, $canonical, @_);
 280 }
 281
 282 sub name { shift->{'Name'} }
 283
 284 # Temporary legacy methods
 285 sub toUnicode    { shift->decode(@_) }
 286 sub fromUnicode  { shift->encode(@_) }
 287
 288 sub new_sequence { return $_[0] }
 289
 290 package Encode::XS;
 291 use base 'Encode::Encoding';
 292
 293 package Encode::Internal;
 294 use base 'Encode::Encoding';
 295
 296 # Dummy package that provides the encode interface but leaves data
 297 # as UTF-X encoded. It is here so that from_to() works.
 298
 299 __PACKAGE__->Define('Internal');
 300
 301 Encode::define_alias( 'Unicode' => 'Internal' ) if ord('A') == 65;
 302
 303 sub decode
 304 {
 305  my ($obj,$str,$chk) = @_;
 306  utf8::upgrade($str);
 307  $_[1] = '' if $chk;
 308  return $str;
 309 }
 310
 311 *encode = \&decode;
 312
 313 package Encoding::Unicode;
 314 use base 'Encode::Encoding';
 315
 316 __PACKAGE__->Define('Unicode') unless ord('A') == 65;
 317
 318 sub decode
 319 {
 320  my ($obj,$str,$chk) = @_;
 321  my $res = '';
 322  for (my $i = 0; $i < length($str); $i++)
 323   {
 324    $res .= chr(utf8::unicode_to_native(ord(substr($str,$i,1))));
 325   }
 326  $_[1] = '' if $chk;
 327  return $res;
 328 }
 329
 330 sub encode
 331 {
 332  my ($obj,$str,$chk) = @_;
 333  my $res = '';
 334  for (my $i = 0; $i < length($str); $i++)
 335   {
 336    $res .= chr(utf8::native_to_unicode(ord(substr($str,$i,1))));
 337   }
 338  $_[1] = '' if $chk;
 339  return $res;
 340 }
 341
 342
 343 package Encode::utf8;
 344 use base 'Encode::Encoding';
 345 # package to allow long-hand
 346 #   $octets = encode( utf8 => $string );
 347 #
 348
 349 __PACKAGE__->Define(qw(UTF-8 utf8));
 350
 351 sub decode
 352 {
 353  my ($obj,$octets,$chk) = @_;
 354  my $str = Encode::decode_utf8($octets);
 355  if (defined $str)
 356   {
 357    $_[1] = '' if $chk;
 358    return $str;
 359   }
 360  return undef;
 361 }
 362
 363 sub encode
 364 {
 365  my ($obj,$string,$chk) = @_;
 366  my $octets = Encode::encode_utf8($string);
 367  $_[1] = '' if $chk;
 368  return $octets;
 369 }
 370
 371 package Encode::iso10646_1;
 372 use base 'Encode::Encoding';
 373 # Encoding is 16-bit network order Unicode (no surogates)
 374 # Used for X font encodings
 375
 376 __PACKAGE__->Define(qw(UCS-2 iso-10646-1));
 377
 378 sub decode
 379 {
 380  my ($obj,$str,$chk) = @_;
 381  my $uni   = '';
 382  while (length($str))
 383   {
 384    my $code = unpack('n',substr($str,0,2,'')) & 0xffff;
 385    $uni .= chr($code);
 386   }
 387  $_[1] = $str if $chk;
 388  utf8::upgrade($uni);
 389  return $uni;
 390 }
 391
 392 sub encode
 393 {
 394  my ($obj,$uni,$chk) = @_;
 395  my $str   = '';
 396  while (length($uni))
 397   {
 398    my $ch = substr($uni,0,1,'');
 399    my $x  = ord($ch);
 400    unless ($x < 32768)
 401     {
 402      last if ($chk);
 403      $x = 0;
 404     }
 405    $str .= pack('n',$x);
 406   }
 407  $_[1] = $uni if $chk;
 408  return $str;
 409 }
 410
 411 package Encode::ucs_2le;
 412 use base 'Encode::Encoding';
 413
 414 __PACKAGE__->Define(qw(UCS-2le UCS-2LE ucs-2le));
 415
 416 sub decode
 417 {
 418  my ($obj,$str,$chk) = @_;
 419  my $uni   = '';
 420  while (length($str))
 421  {
 422   my $code = unpack('v',substr($str,0,2,'')) & 0xffff;
 423   $uni .= chr($code);
 424  }
 425  $_[1] = $str if $chk;
 426  utf8::upgrade($uni);
 427  return $uni;
 428 }
 429
 430 sub encode
 431 {
 432  my ($obj,$uni,$chk) = @_;
 433  my $str   = '';
 434  while (length($uni))
 435  {
 436   my $ch = substr($uni,0,1,'');
 437   my $x  = ord($ch);
 438   unless ($x < 32768)
 439   {
 440    last if ($chk);
 441    $x = 0;
 442   }
 443   $str .= pack('v',$x);
 444  }
 445  $_[1] = $uni if $chk;
 446  return $str;
 447 }
 448
 449 # switch back to Encode package in case we ever add AutoLoader
 450 package Encode;
 451
 452 1;
 453
 454 __END__
 455
 456 =head1 NAME
 457
 458 Encode - character encodings
 459
 460 =head1 SYNOPSIS
 461
 462     use Encode;
 463
 464 =head1 DESCRIPTION
 465
 466 The C<Encode> module provides the interfaces between Perl's strings
 467 and the rest of the system.  Perl strings are sequences of B<characters>.
 468
 469 The repertoire of characters that Perl can represent is at least that
 470 defined by the Unicode Consortium. On most platforms the ordinal
 471 values of the characters (as returned by C<ord(ch)>) is the "Unicode
 472 codepoint" for the character (the exceptions are those platforms where
 473 the legacy encoding is some variant of EBCDIC rather than a super-set
 474 of ASCII - see L<perlebcdic>).
 475
 476 Traditionaly computer data has been moved around in 8-bit chunks
 477 often called "bytes". These chunks are also known as "octets" in
 478 networking standards. Perl is widely used to manipulate data of
 479 many types - not only strings of characters representing human or
 480 computer languages but also "binary" data being the machines representation
 481 of numbers, pixels in an image - or just about anything.
 482
 483 When Perl is processing "binary data" the programmer wants Perl to process
 484 "sequences of bytes". This is not a problem for Perl - as a byte has 256
 485 possible values it easily fits in Perl's much larger "logical character".
 486
 487 =head2 TERMINOLOGY
 488
 489 =over 4
 490
 491 =item *
 492
 493 I<character>: a character in the range 0..(2**32-1) (or more).
 494 (What Perl's strings are made of.)
 495
 496 =item *
 497
 498 I<byte>: a character in the range 0..255
 499 (A special case of a Perl character.)
 500
 501 =item *
 502
 503 I<octet>: 8 bits of data, with ordinal values 0..255
 504 (Term for bytes passed to or from a non-Perl context, e.g. disk file.)
 505
 506 =back
 507
 508 The marker [INTERNAL] marks Internal Implementation Details, in
 509 general meant only for those who think they know what they are doing,
 510 and such details may change in future releases.
 511
 512 =head1 ENCODINGS
 513
 514 =head2 Characteristics of an Encoding
 515
 516 An encoding has a "repertoire" of characters that it can represent,
 517 and for each representable character there is at least one sequence of
 518 octets that represents it.
 519
 520 =head2 Types of Encodings
 521
 522 Encodings can be divided into the following types:
 523
 524 =over 4
 525
 526 =item * Fixed length 8-bit (or less) encodings.
 527
 528 Each character is a single octet so may have a repertoire of up to
 529 256 characters. ASCII and iso-8859-* are typical examples.
 530
 531 =item * Fixed length 16-bit encodings
 532
 533 Each character is two octets so may have a repertoire of up to
 534 65 536 characters.  Unicode's UCS-2 is an example.  Also used for
 535 encodings for East Asian languages.
 536
 537 =item * Fixed length 32-bit encodings.
 538
 539 Not really very "encoded" encodings. The Unicode code points
 540 are just represented as 4-octet integers. None the less because
 541 different architectures use different representations of integers
 542 (so called "endian") there at least two disctinct encodings.
 543
 544 =item * Multi-byte encodings
 545
 546 The number of octets needed to represent a character varies.
 547 UTF-8 is a particularly complex but regular case of a multi-byte
 548 encoding. Several East Asian countries use a multi-byte encoding
 549 where 1-octet is used to cover western roman characters and Asian
 550 characters get 2-octets.
 551 (UTF-16 is strictly a multi-byte encoding taking either 2 or 4 octets
 552 to represent a Unicode code point.)
 553
 554 =item * "Escape" encodings.
 555
 556 These encodings embed "escape sequences" into the octet sequence
 557 which describe how the following octets are to be interpreted.
 558 The iso-2022-* family is typical. Following the escape sequence
 559 octets are encoded by an "embedded" encoding (which will be one
 560 of the above types) until another escape sequence switches to
 561 a different "embedded" encoding.
 562
 563 These schemes are very flexible and can handle mixed languages but are
 564 very complex to process (and have state).  No escape encodings are
 565 implemented for Perl yet.
 566
 567 =back
 568
 569 =head2 Specifying Encodings
 570
 571 Encodings can be specified to the API described below in two ways:
 572
 573 =over 4
 574
 575 =item 1. By name
 576
 577 Encoding names are strings with characters taken from a restricted
 578 repertoire.  See L</"Encoding Names">.
 579
 580 =item 2. As an object
 581
 582 Encoding objects are returned by C<find_encoding($name)>.
 583
 584 =back
 585
 586 =head2 Encoding Names
 587
 588 Encoding names are case insensitive. White space in names is ignored.
 589 In addition an encoding may have aliases. Each encoding has one
 590 "canonical" name.  The "canonical" name is chosen from the names of
 591 the encoding by picking the first in the following sequence:
 592
 593 =over 4
 594
 595 =item * The MIME name as defined in IETF RFC-2045.
 596
 597 =item * The name in the IANA registry.
 598
 599 =item * The name used by the organization that defined it.
 600
 601 =back
 602
 603 Because of all the alias issues, and because in the general case
 604 encodings have state C<Encode> uses the encoding object internally
 605 once an operation is in progress.
 606
 607 As of Perl 5.8.0, at least the following encodings are recognized
 608 (the => marks aliases):
 609
 610   ASCII
 611
 612   US-ASCII => ASCII
 613
 614 The Unicode:
 615
 616   UTF-8
 617   UTF-16
 618   UCS-2
 619
 620   ISO 10646-1 => UCS-2
 621
 622 The ISO 8859 and KOI:
 623
 624   ISO 8859-1  ISO 8859-6   ISO 8859-11         KOI8-F
 625   ISO 8859-2  ISO 8859-7   (12 doesn't exist)  KOI8-R
 626   ISO 8859-3  ISO 8859-8   ISO 8859-13         KOI8-U
 627   ISO 8859-4  ISO 8859-9   ISO 8859-14
 628   ISO 8859-5  ISO 8859-10  ISO 8859-15
 629                            ISO 8859-16
 630
 631   Latin1  => 8859-1  Latin6  => 8859-10
 632   Latin2  => 8859-2  Latin7  => 8859-13
 633   Latin3  => 8859-3  Latin8  => 8859-14
 634   Latin4  => 8859-4  Latin9  => 8859-15
 635   Latin5  => 8859-9  Latin10 => 8859-16
 636
 637   Cyrillic => 8859-5
 638   Arabic   => 8859-6
 639   Greek    => 8859-7
 640   Hebrew   => 8859-8
 641   Thai     => 8859-11
 642   TIS620   => 8859-11
 643
 644 The CJKV: Chinese, Japanese, Korean, Vietnamese:
 645
 646   ISO 2022     ISO 2022 JP-1  JIS 0201  GB 1988   Big5       EUC-CN
 647   ISO 2022 CN  ISO 2022 JP-2  JIS 0208  GB 2312   HZ         EUC-JP
 648   ISO 2022 JP  ISO 2022 KR    JIS 0210  GB 12345  CNS 11643  EUC-JP-0212
 649   Shift-JIS                                                  EUC-KR
 650   VISCII
 651
 652 The PC codepages:
 653
 654   CP37   CP852  CP861  CP866  CP949   CP1251  CP1256
 655   CP424  CP855  CP862  CP869  CP950   CP1252  CP1257
 656   CP737  CP856  CP863  CP874  CP1006  CP1253  CP1258
 657   CP775  CP857  CP864  CP932  CP1047  CP1254
 658   CP850  CP860  CP865  CP936  CP1250  CP1255
 659
 660   WinLatin1     => CP1252
 661   WinLatin2     => CP1250
 662   WinCyrillic   => CP1251
 663   WinGreek      => CP1253
 664   WinTurkiskh   => CP1254
 665   WinHebrew     => CP1255
 666   WinArabic     => CP1256
 667   WinBaltic     => CP1257
 668   WinVietnamese => CP1258
 669
 670 (All the CPI<NNN...> are available also as IBMI<NNN...>.)
 671
 672 The Mac codepages:
 673
 674   MacCentralEuropean   MacJapanese
 675   MacCroatian          MacRoman
 676   MacCyrillic          MacRumanian
 677   MacDingbats          MacSami
 678   MacGreek             MacThai
 679   MacIcelandic         MacTurkish
 680                        MacUkraine
 681
 682 Miscellaneous:
 683
 684   7bit-greek  IR-197
 685   7bit-kana   NeXTstep
 686   7bit-latin1 POSIX-BC
 687   DingBats    Roman8
 688   GSM 0338    Symbol
 689
 690 =head1 PERL ENCODING API
 691
 692 =head2 Generic Encoding Interface
 693
 694 =over 4
 695
 696 =item *
 697
 698         $bytes  = encode(ENCODING, $string[, CHECK])
 699
 700 Encodes string from Perl's internal form into I<ENCODING> and returns
 701 a sequence of octets.  For CHECK see L</"Handling Malformed Data">.
 702
 703 =item *
 704
 705         $string = decode(ENCODING, $bytes[, CHECK])
 706
 707 Decode sequence of octets assumed to be in I<ENCODING> into Perl's
 708 internal form and returns the resulting string.  For CHECK see
 709 L</"Handling Malformed Data">.
 710
 711 =item *
 712
 713         from_to($string, FROM_ENCODING, TO_ENCODING[, CHECK])
 714
 715 Convert B<in-place> the data between two encodings.  How did the data
 716 in $string originally get to be in FROM_ENCODING?  Either using
 717 encode() or through PerlIO: See L</"Encoding and IO">.  For CHECK
 718 see L</"Handling Malformed Data">.
 719
 720 For example to convert ISO 8859-1 data to UTF-8:
 721
 722         from_to($data, "iso-8859-1", "utf-8");
 723
 724 and to convert it back:
 725
 726         from_to($data, "utf-8", "iso-8859-1");
 727
 728 Note that because the conversion happens in place, the data to be
 729 converted cannot be a string constant, it must be a scalar variable.
 730
 731 =back
 732
 733 =head2 Handling Malformed Data
 734
 735 If CHECK is not set, C<undef> is returned.  If the data is supposed to
 736 be UTF-8, an optional lexical warning (category utf8) is given.  If
 737 CHECK is true but not a code reference, dies.
 738
 739 It would desirable to have a way to indicate that transform should use
 740 the encodings "replacement character" - no such mechanism is defined yet.
 741
 742 It is also planned to allow I<CHECK> to be a code reference.
 743
 744 This is not yet implemented as there are design issues with what its
 745 arguments should be and how it returns its results.
 746
 747 =over 4
 748
 749 =item Scheme 1
 750
 751 Passed remaining fragment of string being processed.
 752 Modifies it in place to remove bytes/characters it can understand
 753 and returns a string used to represent them.
 754 e.g.
 755
 756  sub fixup {
 757    my $ch = substr($_[0],0,1,'');
 758    return sprintf("\x{%02X}",ord($ch);
 759  }
 760
 761 This scheme is close to how underlying C code for Encode works, but gives
 762 the fixup routine very little context.
 763
 764 =item Scheme 2
 765
 766 Passed original string, and an index into it of the problem area, and
 767 output string so far.  Appends what it will to output string and
 768 returns new index into original string.  For example:
 769
 770  sub fixup {
 771    # my ($s,$i,$d) = @_;
 772    my $ch = substr($_[0],$_[1],1);
 773    $_[2] .= sprintf("\x{%02X}",ord($ch);
 774    return $_[1]+1;
 775  }
 776
 777 This scheme gives maximal control to the fixup routine but is more
 778 complicated to code, and may need internals of Encode to be tweaked to
 779 keep original string intact.
 780
 781 =item Other Schemes
 782
 783 Hybrids of above.
 784
 785 Multiple return values rather than in-place modifications.
 786
 787 Index into the string could be pos($str) allowing s/\G...//.
 788
 789 =back
 790
 791 =head2 UTF-8 / utf8
 792
 793 The Unicode consortium defines the UTF-8 standard as a way of encoding
 794 the entire Unicode repertiore as sequences of octets.  This encoding is
 795 expected to become very widespread. Perl can use this form internaly
 796 to represent strings, so conversions to and from this form are
 797 particularly efficient (as octets in memory do not have to change,
 798 just the meta-data that tells Perl how to treat them).
 799
 800 =over 4
 801
 802 =item *
 803
 804         $bytes = encode_utf8($string);
 805
 806 The characters that comprise string are encoded in Perl's superset of UTF-8
 807 and the resulting octets returned as a sequence of bytes. All possible
 808 characters have a UTF-8 representation so this function cannot fail.
 809
 810 =item *
 811
 812         $string = decode_utf8($bytes [,CHECK]);
 813
 814 The sequence of octets represented by $bytes is decoded from UTF-8
 815 into a sequence of logical characters. Not all sequences of octets
 816 form valid UTF-8 encodings, so it is possible for this call to fail.
 817 For CHECK see L</"Handling Malformed Data">.
 818
 819 =back
 820
 821 =head2 Other Encodings of Unicode
 822
 823 UTF-16 is similar to UCS-2, 16 bit or 2-byte chunks.  UCS-2 can only
 824 represent 0..0xFFFF, while UTF-16 has a I<surrogate pair> scheme which
 825 allows it to cover the whole Unicode range.
 826
 827 Surrogates are code points set aside to encode the 0x01000..0x10FFFF
 828 range of Unicode code points in pairs of 16-bit units.  The I<high
 829 surrogates> are the range 0xD800..0xDBFF, and the I<low surrogates>
 830 are the range 0xDC00..0xDFFFF.  The surrogate encoding is
 831
 832         $hi = ($uni - 0x10000) / 0x400 + 0xD800;
 833         $lo = ($uni - 0x10000) % 0x400 + 0xDC00;
 834
 835 and the decoding is
 836
 837         $uni = 0x10000 + ($hi - 0xD8000) * 0x400 + ($lo - 0xDC00);
 838
 839 Encode implements big-endian UCS-2 aliased to "iso-10646-1" as that
 840 happens to be the name used by that representation when used with X11
 841 fonts.
 842
 843 UTF-32 or UCS-4 is 32-bit or 4-byte chunks.  Perl's logical characters
 844 can be considered as being in this form without encoding. An encoding
 845 to transfer strings in this form (e.g. to write them to a file) would
 846 need to
 847
 848      pack('L*', unpack('U*', $string));  # native
 849   or
 850      pack('V*', unpack('U*', $string));  # little-endian
 851   or
 852      pack('N*', unpack('U*', $string));  # big-endian
 853
 854 depending on the endianness required.
 855
 856 No UTF-32 encodings are implemented yet.
 857
 858 Both UCS-2 and UCS-4 style encodings can have "byte order marks" by
 859 representing the code point 0xFFFE as the very first thing in a file.
 860
 861 =head2 Listing available encodings
 862
 863   use Encode qw(encodings);
 864   @list = encodings();
 865
 866 Returns a list of the canonical names of the available encodings.
 867
 868 =head2 Defining Aliases
 869
 870   use Encode qw(define_alias);
 871   define_alias( newName => ENCODING);
 872
 873 Allows newName to be used as am alias for ENCODING. ENCODING may be
 874 either the name of an encoding or and encoding object (as above).
 875
 876 Currently I<newName> can be specified in the following ways:
 877
 878 =over 4
 879
 880 =item As a simple string.
 881
 882 =item As a qr// compiled regular expression, e.g.:
 883
 884   define_alias( qr/^iso8859-(\d+)$/i => '"iso-8859-$1"' );
 885
 886 In this case if I<ENCODING> is not a reference it is C<eval>-ed to
 887 allow C<$1> etc. to be subsituted.  The example is one way to names as
 888 used in X11 font names to alias the MIME names for the iso-8859-*
 889 family.
 890
 891 =item As a code reference, e.g.:
 892
 893   define_alias( sub { return /^iso8859-(\d+)$/i ? "iso-8859-$1" : undef } , '');
 894
 895 In this case C<$_> will be set to the name that is being looked up and
 896 I<ENCODING> is passed to the sub as its first argument.  The example
 897 is another way to names as used in X11 font names to alias the MIME
 898 names for the iso-8859-* family.
 899
 900 =back
 901
 902 =head2 Defining Encodings
 903
 904     use Encode qw(define_alias);
 905     define_encoding( $object, 'canonicalName' [,alias...]);
 906
 907 Causes I<canonicalName> to be associated with I<$object>.  The object
 908 should provide the interface described in L</"IMPLEMENTATION CLASSES">
 909 below.  If more than two arguments are provided then additional
 910 arguments are taken as aliases for I<$object> as for C<define_alias>.
 911
 912 =head1 Encoding and IO
 913
 914 It is very common to want to do encoding transformations when
 915 reading or writing files, network connections, pipes etc.
 916 If Perl is configured to use the new 'perlio' IO system then
 917 C<Encode> provides a "layer" (See L<perliol>) which can transform
 918 data as it is read or written.
 919
 920 Here is how the blind poet would modernise the encoding:
 921
 922     use Encode;
 923     open(my $iliad,'<:encoding(iso-8859-7)','iliad.greek');
 924     open(my $utf8,'>:utf8','iliad.utf8');
 925     my @epic = <$iliad>;
 926     print $utf8 @epic;
 927     close($utf8);
 928     close($illiad);
 929
 930 In addition the new IO system can also be configured to read/write
 931 UTF-8 encoded characters (as noted above this is efficient):
 932
 933     open(my $fh,'>:utf8','anything');
 934     print $fh "Any \x{0021} string \N{SMILEY FACE}\n";
 935
 936 Either of the above forms of "layer" specifications can be made the default
 937 for a lexical scope with the C<use open ...> pragma. See L<open>.
 938
 939 Once a handle is open is layers can be altered using C<binmode>.
 940
 941 Without any such configuration, or if Perl itself is built using
 942 system's own IO, then write operations assume that file handle accepts
 943 only I<bytes> and will C<die> if a character larger than 255 is
 944 written to the handle. When reading, each octet from the handle
 945 becomes a byte-in-a-character. Note that this default is the same
 946 behaviour as bytes-only languages (including Perl before v5.6) would
 947 have, and is sufficient to handle native 8-bit encodings
 948 e.g. iso-8859-1, EBCDIC etc. and any legacy mechanisms for handling
 949 other encodings and binary data.
 950
 951 In other cases it is the programs responsibility to transform
 952 characters into bytes using the API above before doing writes, and to
 953 transform the bytes read from a handle into characters before doing
 954 "character operations" (e.g. C<lc>, C</\W+/>, ...).
 955
 956 You can also use PerlIO to convert larger amounts of data you don't
 957 want to bring into memory.  For example to convert between ISO 8859-1
 958 (Latin 1) and UTF-8 (or UTF-EBCDIC in EBCDIC machines):
 959
 960     open(F, "<:encoding(iso-8859-1)", "data.txt") or die $!;
 961     open(G, ">:utf8",                 "data.utf") or die $!;
 962     while (<F>) { print G }
 963
 964     # Could also do "print G <F>" but that would pull
 965     # the whole file into memory just to write it out again.
 966
 967 More examples:
 968
 969     open(my $f, "<:encoding(cp1252)")
 970     open(my $g, ">:encoding(iso-8859-2)")
 971     open(my $h, ">:encoding(latin9)")       # iso-8859-15
 972
 973 See L<PerlIO> for more information.
 974
 975 See also L<encoding> for how to change the default encoding of the
 976 data in your script.
 977
 978 =head1 Encoding How to ...
 979
 980 To do:
 981
 982 =over 4
 983
 984 =item * IO with mixed content (faking iso-2020-*)
 985
 986 =item * MIME's Content-Length:
 987
 988 =item * UTF-8 strings in binary data.
 989
 990 =item * Perl/Encode wrappers on non-Unicode XS modules.
 991
 992 =back
 993
 994 =head1 Messing with Perl's Internals
 995
 996 The following API uses parts of Perl's internals in the current
 997 implementation.  As such they are efficient, but may change.
 998
 999 =over 4
1000
1001 =item * is_utf8(STRING [, CHECK])
1002
1003 [INTERNAL] Test whether the UTF-8 flag is turned on in the STRING.
1004 If CHECK is true, also checks the data in STRING for being well-formed
1005 UTF-8.  Returns true if successful, false otherwise.
1006
1007 =item * valid_utf8(STRING)
1008
1009 [INTERNAL] Test whether STRING is in a consistent state.  Will return
1010 true if string is held as bytes, or is well-formed UTF-8 and has the
1011 UTF-8 flag on.  Main reason for this routine is to allow Perl's
1012 testsuite to check that operations have left strings in a consistent
1013 state.
1014
1015 =item *
1016
1017         _utf8_on(STRING)
1018
1019 [INTERNAL] Turn on the UTF-8 flag in STRING.  The data in STRING is
1020 B<not> checked for being well-formed UTF-8.  Do not use unless you
1021 B<know> that the STRING is well-formed UTF-8.  Returns the previous
1022 state of the UTF-8 flag (so please don't test the return value as
1023 I<not> success or failure), or C<undef> if STRING is not a string.
1024
1025 =item *
1026
1027         _utf8_off(STRING)
1028
1029 [INTERNAL] Turn off the UTF-8 flag in STRING.  Do not use frivolously.
1030 Returns the previous state of the UTF-8 flag (so please don't test the
1031 return value as I<not> success or failure), or C<undef> if STRING is
1032 not a string.
1033
1034 =back
1035
1036 =head1 IMPLEMENTATION CLASSES
1037
1038 As mentioned above encodings are (in the current implementation at least)
1039 defined by objects. The mapping of encoding name to object is via the
1040 C<%encodings> hash.
1041
1042 The values of the hash can currently be either strings or objects.
1043 The string form may go away in the future. The string form occurs
1044 when C<encodings()> has scanned C<@INC> for loadable encodings but has
1045 not actually loaded the encoding in question. This is because the
1046 current "loading" process is all Perl and a bit slow.
1047
1048 Once an encoding is loaded then value of the hash is object which
1049 implements the encoding. The object should provide the following
1050 interface:
1051
1052 =over 4
1053
1054 =item -E<gt>name
1055
1056 Should return the string representing the canonical name of the encoding.
1057
1058 =item -E<gt>new_sequence
1059
1060 This is a placeholder for encodings with state. It should return an
1061 object which implements this interface, all current implementations
1062 return the original object.
1063
1064 =item -E<gt>encode($string,$check)
1065
1066 Should return the octet sequence representing I<$string>. If I<$check>
1067 is true it should modify I<$string> in place to remove the converted
1068 part (i.e.  the whole string unless there is an error).  If an error
1069 occurs it should return the octet sequence for the fragment of string
1070 that has been converted, and modify $string in-place to remove the
1071 converted part leaving it starting with the problem fragment.
1072
1073 If check is is false then C<encode> should make a "best effort" to
1074 convert the string - for example by using a replacement character.
1075
1076 =item -E<gt>decode($octets,$check)
1077
1078 Should return the string that I<$octets> represents. If I<$check> is
1079 true it should modify I<$octets> in place to remove the converted part
1080 (i.e.  the whole sequence unless there is an error).  If an error
1081 occurs it should return the fragment of string that has been
1082 converted, and modify $octets in-place to remove the converted part
1083 leaving it starting with the problem fragment.
1084
1085 If check is is false then C<decode> should make a "best effort" to
1086 convert the string - for example by using Unicode's "\x{FFFD}" as a
1087 replacement character.
1088
1089 =back
1090
1091 It should be noted that the check behaviour is different from the
1092 outer public API. The logic is that the "unchecked" case is useful
1093 when encoding is part of a stream which may be reporting errors
1094 (e.g. STDERR).  In such cases it is desirable to get everything
1095 through somehow without causing additional errors which obscure the
1096 original one. Also the encoding is best placed to know what the
1097 correct replacement character is, so if that is the desired behaviour
1098 then letting low level code do it is the most efficient.
1099
1100 In contrast if check is true, the scheme above allows the encoding to
1101 do as much as it can and tell layer above how much that was. What is
1102 lacking at present is a mechanism to report what went wrong. The most
1103 likely interface will be an additional method call to the object, or
1104 perhaps (to avoid forcing per-stream objects on otherwise stateless
1105 encodings) and additional parameter.
1106
1107 It is also highly desirable that encoding classes inherit from
1108 C<Encode::Encoding> as a base class. This allows that class to define
1109 additional behaviour for all encoding objects. For example built in
1110 Unicode, UCS-2 and UTF-8 classes use :
1111
1112   package Encode::MyEncoding;
1113   use base qw(Encode::Encoding);
1114
1115   __PACKAGE__->Define(qw(myCanonical myAlias));
1116
1117 To create an object with bless {Name => ...},$class, and call
1118 define_encoding.  They inherit their C<name> method from
1119 C<Encode::Encoding>.
1120
1121 =head2 Compiled Encodings
1122
1123 F<Encode.xs> provides a class C<Encode::XS> which provides the
1124 interface described above. It calls a generic octet-sequence to
1125 octet-sequence "engine" that is driven by tables (defined in
1126 F<encengine.c>). The same engine is used for both encode and
1127 decode. C<Encode:XS>'s C<encode> forces Perl's characters to their
1128 UTF-8 form and then treats them as just another multibyte
1129 encoding. C<Encode:XS>'s C<decode> transforms the sequence and then
1130 turns the UTF-8-ness flag as that is the form that the tables are
1131 defined to produce. For details of the engine see the comments in
1132 F<encengine.c>.
1133
1134 The tables are produced by the Perl script F<compile> (the name needs
1135 to change so we can eventually install it somewhere). F<compile> can
1136 currently read two formats:
1137
1138 =over 4
1139
1140 =item *.enc
1141
1142 This is a coined format used by Tcl. It is documented in
1143 Encode/EncodeFormat.pod.
1144
1145 =item *.ucm
1146
1147 This is the semi-standard format used by IBM's ICU package.
1148
1149 =back
1150
1151 F<compile> can write the following forms:
1152
1153 =over 4
1154
1155 =item *.ucm
1156
1157 See above - the F<Encode/*.ucm> files provided with the distribution have
1158 been created from the original Tcl .enc files using this approach.
1159
1160 =item *.c
1161
1162 Produces tables as C data structures - this is used to build in encodings
1163 into F<Encode.so>/F<Encode.dll>.
1164
1165 =item *.xs
1166
1167 In theory this allows encodings to be stand-alone loadable Perl
1168 extensions.  The process has not yet been tested. The plan is to use
1169 this approach for large East Asian encodings.
1170
1171 =back
1172
1173 The set of encodings built-in to F<Encode.so>/F<Encode.dll> is
1174 determined by F<Makefile.PL>.  The current set is as follows:
1175
1176 =over 4
1177
1178 =item ascii and iso-8859-*
1179
1180 That is all the common 8-bit "western" encodings.
1181
1182 =item IBM-1047 and two other variants of EBCDIC.
1183
1184 These are the same variants that are supported by EBCDIC Perl as
1185 "native" encodings.  They are included to prove "reversibility" of
1186 some constructs in EBCDIC Perl.
1187
1188 =item symbol and dingbats as used by Tk on X11.
1189
1190 (The reason Encode got started was to support Perl/Tk.)
1191
1192 =back
1193
1194 That set is rather ad hoc and has been driven by the needs of the
1195 tests rather than the needs of typical applications. It is likely
1196 to be rationalized.
1197
1198 =head1 SEE ALSO
1199
1200 L<perlunicode>, L<perlebcdic>, L<perlfunc/open>, L<PerlIO>, L<encoding>
1201
1202 =cut
1203