ext/Encode/Encode.pm

   1 package Encode;
   2 use strict;
   3 our $VERSION = do { my @r = (q$Revision: 1.61 $ =~ /\d+/g); sprintf "%d."."%02d" x $#r, @r };
   4 our $DEBUG = 0;
   5 use XSLoader ();
   6 XSLoader::load 'Encode';
   7
   8 require Exporter;
   9 use base qw/Exporter/;
  10
  11 # Public, encouraged API is exported by default
  12
  13 our @EXPORT = qw(
  14   decode  decode_utf8  encode  encode_utf8
  15   encodings  find_encoding
  16 );
  17
  18 our @FB_FLAGS  = qw(DIE_ON_ERR WARN_ON_ERR RETURN_ON_ERR LEAVE_SRC
  19                     PERLQQ HTMLCREF XMLCREF);
  20 our @FB_CONSTS = qw(FB_DEFAULT FB_CROAK FB_QUIET FB_WARN
  21                     FB_PERLQQ FB_HTMLCREF FB_XMLCREF);
  22
  23 our @EXPORT_OK =
  24     (
  25      qw(
  26        _utf8_off _utf8_on define_encoding from_to is_16bit is_8bit
  27        is_utf8 perlio_ok resolve_alias utf8_downgrade utf8_upgrade
  28       ),
  29      @FB_FLAGS, @FB_CONSTS,
  30     );
  31
  32 our %EXPORT_TAGS =
  33     (
  34      all          =>  [ @EXPORT, @EXPORT_OK ],
  35      fallbacks    =>  [ @FB_CONSTS ],
  36      fallback_all =>  [ @FB_CONSTS, @FB_FLAGS ],
  37     );
  38
  39 # Documentation moved after __END__ for speed - NI-S
  40
  41 use Carp;
  42
  43 our $ON_EBCDIC = (ord("A") == 193);
  44
  45 use Encode::Alias;
  46
  47 # Make a %Encoding package variable to allow a certain amount of cheating
  48 our %Encoding;
  49 our %ExtModule;
  50 require Encode::Config;
  51 eval { require Encode::ConfigLocal };
  52
  53 sub encodings
  54 {
  55     my $class = shift;
  56     my @modules = (@_ and $_[0] eq ":all") ? values %ExtModule : @_;
  57     for my $mod (@modules){
  58         $mod =~ s,::,/,g or $mod = "Encode/$mod";
  59         $mod .= '.pm';
  60         $DEBUG and warn "about to require $mod;";
  61         eval { require $mod; };
  62     }
  63     my %modules = map {$_ => 1} @modules;
  64     return
  65         sort { lc $a cmp lc $b }
  66              grep {!/^(?:Internal|Unicode)$/o} keys %Encoding;
  67 }
  68
  69 sub perlio_ok{
  70     my $obj = ref($_[0]) ? $_[0] : find_encoding($_[0]);
  71     $obj->can("perlio_ok") and return $obj->perlio_ok();
  72     return 0; # safety net
  73 }
  74
  75 sub define_encoding
  76 {
  77     my $obj  = shift;
  78     my $name = shift;
  79     $Encoding{$name} = $obj;
  80     my $lc = lc($name);
  81     define_alias($lc => $obj) unless $lc eq $name;
  82     while (@_)
  83     {
  84         my $alias = shift;
  85         define_alias($alias,$obj);
  86     }
  87     return $obj;
  88 }
  89
  90 sub getEncoding
  91 {
  92     my ($class,$name,$skip_external) = @_;
  93     my $enc;
  94     if (ref($name) && $name->can('new_sequence'))
  95     {
  96         return $name;
  97     }
  98     my $lc = lc $name;
  99     if (exists $Encoding{$name})
 100     {
 101         return $Encoding{$name};
 102     }
 103     if (exists $Encoding{$lc})
 104     {
 105         return $Encoding{$lc};
 106     }
 107
 108     my $oc = $class->find_alias($name);
 109     return $oc if defined $oc;
 110
 111     $oc = $class->find_alias($lc) if $lc ne $name;
 112     return $oc if defined $oc;
 113
 114     unless ($skip_external)
 115     {
 116         if (my $mod = $ExtModule{$name} || $ExtModule{$lc}){
 117             $mod =~ s,::,/,g ; $mod .= '.pm';
 118             eval{ require $mod; };
 119             return $Encoding{$name} if exists $Encoding{$name};
 120         }
 121     }
 122     return;
 123 }
 124
 125 sub find_encoding
 126 {
 127     my ($name,$skip_external) = @_;
 128     return __PACKAGE__->getEncoding($name,$skip_external);
 129 }
 130
 131 sub resolve_alias {
 132     my $obj = find_encoding(shift);
 133     defined $obj and return $obj->name;
 134     return;
 135 }
 136
 137 sub encode($$;$)
 138 {
 139     my ($name,$string,$check) = @_;
 140     $check ||=0;
 141     my $enc = find_encoding($name);
 142     croak("Unknown encoding '$name'") unless defined $enc;
 143     my $octets = $enc->encode($string,$check);
 144     return undef if ($check && length($string));
 145     return $octets;
 146 }
 147
 148 sub decode($$;$)
 149 {
 150     my ($name,$octets,$check) = @_;
 151     $check ||=0;
 152     my $enc = find_encoding($name);
 153     croak("Unknown encoding '$name'") unless defined $enc;
 154     my $string = $enc->decode($octets,$check);
 155     $_[1] = $octets if $check;
 156     return $string;
 157 }
 158
 159 sub from_to($$$;$)
 160 {
 161     my ($string,$from,$to,$check) = @_;
 162     $check ||=0;
 163     my $f = find_encoding($from);
 164     croak("Unknown encoding '$from'") unless defined $f;
 165     my $t = find_encoding($to);
 166     croak("Unknown encoding '$to'") unless defined $t;
 167     my $uni = $f->decode($string,$check);
 168     return undef if ($check && length($string));
 169     $string =  $t->encode($uni,$check);
 170     return undef if ($check && length($uni));
 171     return defined($_[0] = $string) ? length($string) : undef ;
 172 }
 173
 174 sub encode_utf8($)
 175 {
 176     my ($str) = @_;
 177     utf8::encode($str);
 178     return $str;
 179 }
 180
 181 sub decode_utf8($)
 182 {
 183     my ($str) = @_;
 184     return undef unless utf8::decode($str);
 185     return $str;
 186 }
 187
 188 predefine_encodings();
 189
 190 #
 191 # This is to restore %Encoding if really needed;
 192 #
 193 sub predefine_encodings{
 194     if ($ON_EBCDIC) {
 195         # was in Encode::UTF_EBCDIC
 196         package Encode::UTF_EBCDIC;
 197         *name         = sub{ shift->{'Name'} };
 198         *new_sequence = sub{ return $_[0] };
 199         *needs_lines = sub{ 0 };
 200         *perlio_ok = sub {
 201             eval{ require PerlIO::encoding };
 202             return $@ ? 0 : 1;
 203         };
 204         *decode = sub{
 205             my ($obj,$str,$chk) = @_;
 206             my $res = '';
 207             for (my $i = 0; $i < length($str); $i++) {
 208                 $res .=
 209                     chr(utf8::unicode_to_native(ord(substr($str,$i,1))));
 210             }
 211             $_[1] = '' if $chk;
 212             return $res;
 213         };
 214         *encode = sub{
 215             my ($obj,$str,$chk) = @_;
 216             my $res = '';
 217             for (my $i = 0; $i < length($str); $i++) {
 218                 $res .=
 219                     chr(utf8::native_to_unicode(ord(substr($str,$i,1))));
 220             }
 221             $_[1] = '' if $chk;
 222             return $res;
 223         };
 224         $Encode::Encoding{Unicode} =
 225             bless {Name => "UTF_EBCDIC"} => "Encode::UTF_EBCDIC";
 226     } else {
 227         # was in Encode::UTF_EBCDIC
 228         package Encode::Internal;
 229         *name         = sub{ shift->{'Name'} };
 230         *new_sequence = sub{ return $_[0] };
 231         *needs_lines = sub{ 0 };
 232         *perlio_ok = sub {
 233             eval{ require PerlIO::encoding };
 234             return $@ ? 0 : 1;
 235         };
 236         *decode = sub{
 237             my ($obj,$str,$chk) = @_;
 238             utf8::upgrade($str);
 239             $_[1] = '' if $chk;
 240             return $str;
 241         };
 242         *encode = \&decode;
 243         $Encode::Encoding{Unicode} =
 244             bless {Name => "Internal"} => "Encode::Internal";
 245     }
 246
 247     {
 248         # was in Encode::utf8
 249         package Encode::utf8;
 250         *name         = sub{ shift->{'Name'} };
 251         *new_sequence = sub{ return $_[0] };
 252         *needs_lines = sub{ 0 };
 253         *perlio_ok = sub {
 254             eval{ require PerlIO::encoding };
 255             return $@ ? 0 : 1;
 256         };
 257         *decode = sub{
 258             my ($obj,$octets,$chk) = @_;
 259             my $str = Encode::decode_utf8($octets);
 260             if (defined $str) {
 261                 $_[1] = '' if $chk;
 262                 return $str;
 263             }
 264             return undef;
 265         };
 266         *encode = sub {
 267             my ($obj,$string,$chk) = @_;
 268             my $octets = Encode::encode_utf8($string);
 269             $_[1] = '' if $chk;
 270             return $octets;
 271         };
 272         $Encode::Encoding{utf8} =
 273             bless {Name => "utf8"} => "Encode::utf8";
 274     }
 275 }
 276
 277 1;
 278
 279 __END__
 280
 281 =head1 NAME
 282
 283 Encode - character encodings
 284
 285 =head1 SYNOPSIS
 286
 287     use Encode;
 288
 289 =head2 Table of Contents
 290
 291 Encode consists of a collection of modules whose details are too big
 292 to fit in one document.  This POD itself explains the top-level APIs
 293 and general topics at a glance.  For other topics and more details,
 294 see the PODs below:
 295
 296   Name                          Description
 297   --------------------------------------------------------
 298   Encode::Alias         Alias definitions to encodings
 299   Encode::Encoding      Encode Implementation Base Class
 300   Encode::Supported     List of Supported Encodings
 301   Encode::CN            Simplified Chinese Encodings
 302   Encode::JP            Japanese Encodings
 303   Encode::KR            Korean Encodings
 304   Encode::TW            Traditional Chinese Encodings
 305   --------------------------------------------------------
 306
 307 =head1 DESCRIPTION
 308
 309 The C<Encode> module provides the interfaces between Perl's strings
 310 and the rest of the system.  Perl strings are sequences of
 311 B<characters>.
 312
 313 The repertoire of characters that Perl can represent is at least that
 314 defined by the Unicode Consortium. On most platforms the ordinal
 315 values of the characters (as returned by C<ord(ch)>) is the "Unicode
 316 codepoint" for the character (the exceptions are those platforms where
 317 the legacy encoding is some variant of EBCDIC rather than a super-set
 318 of ASCII - see L<perlebcdic>).
 319
 320 Traditionally, computer data has been moved around in 8-bit chunks
 321 often called "bytes". These chunks are also known as "octets" in
 322 networking standards. Perl is widely used to manipulate data of many
 323 types - not only strings of characters representing human or computer
 324 languages but also "binary" data being the machine's representation of
 325 numbers, pixels in an image - or just about anything.
 326
 327 When Perl is processing "binary data", the programmer wants Perl to
 328 process "sequences of bytes". This is not a problem for Perl - as a
 329 byte has 256 possible values, it easily fits in Perl's much larger
 330 "logical character".
 331
 332 =head2 TERMINOLOGY
 333
 334 =over 2
 335
 336 =item *
 337
 338 I<character>: a character in the range 0..(2**32-1) (or more).
 339 (What Perl's strings are made of.)
 340
 341 =item *
 342
 343 I<byte>: a character in the range 0..255
 344 (A special case of a Perl character.)
 345
 346 =item *
 347
 348 I<octet>: 8 bits of data, with ordinal values 0..255
 349 (Term for bytes passed to or from a non-Perl context, e.g. a disk file.)
 350
 351 =back
 352
 353 The marker [INTERNAL] marks Internal Implementation Details, in
 354 general meant only for those who think they know what they are doing,
 355 and such details may change in future releases.
 356
 357 =head1 PERL ENCODING API
 358
 359 =over 2
 360
 361 =item $octets  = encode(ENCODING, $string[, CHECK])
 362
 363 Encodes a string from Perl's internal form into I<ENCODING> and returns
 364 a sequence of octets.  ENCODING can be either a canonical name or
 365 an alias.  For encoding names and aliases, see L</"Defining Aliases">.
 366 For CHECK, see L</"Handling Malformed Data">.
 367
 368 For example, to convert (internally UTF-8 encoded) Unicode string to
 369 iso-8859-1 (also known as Latin1),
 370
 371   $octets = encode("iso-8859-1", $utf8);
 372
 373 B<CAVEAT>: When you C<$octets = encode("utf8", $utf8)>, then $octets
 374 B<ne> $utf8.  Though they both contain the same data, the utf8 flag
 375 for $octets is B<always> off.  When you encode anything, utf8 flag of
 376 the result is always off, even when it contains completely valid utf8
 377 string. See L</"The UTF-8 flag"> below.
 378
 379 =item $string = decode(ENCODING, $octets[, CHECK])
 380
 381 Decodes a sequence of octets assumed to be in I<ENCODING> into Perl's
 382 internal form and returns the resulting string.  As in encode(),
 383 ENCODING can be either a canonical name or an alias. For encoding names
 384 and aliases, see L</"Defining Aliases">.  For CHECK, see
 385 L</"Handling Malformed Data">.
 386
 387 For example, to convert ISO-8859-1 data to UTF-8:
 388
 389   $utf8 = decode("iso-8859-1", $latin1);
 390
 391 B<CAVEAT>: When you C<$utf8 = encode("utf8", $octets)>, then $utf8
 392 B<may not be equal to> $utf8.  Though they both contain the same data,
 393 the utf8 flag for $utf8 is on unless $octets entirely conststs of
 394 ASCII data (or EBCDIC on EBCDIC machines).  See L</"The UTF-8 flag">
 395 below.
 396
 397 =item [$length =] from_to($string, FROM_ENC, TO_ENC [, CHECK])
 398
 399 Converts B<in-place> data between two encodings. For example, to
 400 convert ISO-8859-1 data to UTF-8:
 401
 402   from_to($data, "iso-8859-1", "utf8");
 403
 404 and to convert it back:
 405
 406   from_to($data, "utf8", "iso-8859-1");
 407
 408 Note that because the conversion happens in place, the data to be
 409 converted cannot be a string constant; it must be a scalar variable.
 410
 411 from_to() returns the length of the converted string on success, undef
 412 otherwise.
 413
 414 B<CAVEAT>: The following operations look the same but not quite so;
 415
 416   from_to($data, "iso-8859-1", "utf8"); #1
 417   $data = decode("iso-8859-1", $data);  #2
 418
 419 Both #1 and #2 makes $data consists of completely valid UTF-8 string
 420 but only #2 turns utf8 flag on.  #1 is equivalent to
 421
 422   $data = encode("utf8", decode("iso-8859-1", $data));
 423
 424 See L</"The UTF-8 flag"> below.
 425
 426 =item $octets = encode_utf8($string);
 427
 428 Equivalent to C<$octets = encode("utf8", $string);> The characters
 429 that comprise $string are encoded in Perl's superset of UTF-8 and the
 430 resulting octets are returned as a sequence of bytes. All possible
 431 characters have a UTF-8 representation so this function cannot fail.
 432
 433
 434 =item $string = decode_utf8($octets [, CHECK]);
 435
 436 equivalent to C<$string = decode("utf8", $octets [, CHECK])>.
 437 decode_utf8($octets [, CHECK]); The sequence of octets represented by
 438 $octets is decoded from UTF-8 into a sequence of logical
 439 characters. Not all sequences of octets form valid UTF-8 encodings, so
 440 it is possible for this call to fail.  For CHECK, see
 441 L</"Handling Malformed Data">.
 442
 443 =back
 444
 445 =head2 Listing available encodings
 446
 447   use Encode;
 448   @list = Encode->encodings();
 449
 450 Returns a list of the canonical names of the available encodings that
 451 are loaded.  To get a list of all available encodings including the
 452 ones that are not loaded yet, say
 453
 454   @all_encodings = Encode->encodings(":all");
 455
 456 Or you can give the name of a specific module.
 457
 458   @with_jp = Encode->encodings("Encode::JP");
 459
 460 When "::" is not in the name, "Encode::" is assumed.
 461
 462   @ebcdic = Encode->encodings("EBCDIC");
 463
 464 To find out in detail which encodings are supported by this package,
 465 see L<Encode::Supported>.
 466
 467 =head2 Defining Aliases
 468
 469 To add a new alias to a given encoding, use:
 470
 471   use Encode;
 472   use Encode::Alias;
 473   define_alias(newName => ENCODING);
 474
 475 After that, newName can be used as an alias for ENCODING.
 476 ENCODING may be either the name of an encoding or an
 477 I<encoding object>
 478
 479 But before you do so, make sure the alias is nonexistent with
 480 C<resolve_alias()>, which returns the canonical name thereof.
 481 i.e.
 482
 483   Encode::resolve_alias("latin1") eq "iso-8859-1" # true
 484   Encode::resolve_alias("iso-8859-12")   # false; nonexistent
 485   Encode::resolve_alias($name) eq $name  # true if $name is canonical
 486
 487 resolve_alias() does not need C<use Encode::Alias>; it can be
 488 exported via C<use Encode qw(resolve_alias)>.
 489
 490 See L<Encode::Alias> for details.
 491
 492 =head1 Encoding via PerlIO
 493
 494 If your perl supports I<PerlIO>, you can use a PerlIO layer to decode
 495 and encode directly via a filehandle.  The following two examples
 496 are totally identical in their functionality.
 497
 498   # via PerlIO
 499   open my $in,  "<:encoding(shiftjis)", $infile  or die;
 500   open my $out, ">:encoding(euc-jp)",   $outfile or die;
 501   while(<>){ print; }
 502
 503   # via from_to
 504   open my $in,  "<", $infile  or die;
 505   open my $out, ">", $outfile or die;
 506   while(<>){
 507     from_to($_, "shiftjis", "euc-jp", 1);
 508   }
 509
 510 Unfortunately, there may be encodings are PerlIO-savvy.  You can check
 511 if your encoding is supported by PerlIO by calling the C<perlio_ok>
 512 method.
 513
 514   Encode::perlio_ok("hz");             # False
 515   find_encoding("euc-cn")->perlio_ok;  # True where PerlIO is available
 516
 517   use Encode qw(perlio_ok);            # exported upon request
 518   perlio_ok("euc-jp")
 519
 520 Fortunately, all encodings that come with Encode core are PerlIO-savvy
 521 except for hz and ISO-2022-kr.  See L<Encode::Encoding> for details.
 522
 523 For gory details, see L<Encode::PerlIO>.
 524
 525 =head1 Handling Malformed Data
 526
 527 =over 2
 528
 529 The I<CHECK> argument is used as follows.  When you omit it,
 530 the behaviour is the same as if you had passed a value of 0 for
 531 I<CHECK>.
 532
 533 =item I<CHECK> = Encode::FB_DEFAULT ( == 0)
 534
 535 If I<CHECK> is 0, (en|de)code will put a I<substitution character>
 536 in place of a malformed character.  For UCM-based encodings,
 537 E<lt>subcharE<gt> will be used.  For Unicode, "\x{FFFD}" is used.
 538 If the data is supposed to be UTF-8, an optional lexical warning
 539 (category utf8) is given.
 540
 541 =item I<CHECK> = Encode::FB_CROAK ( == 1)
 542
 543 If I<CHECK> is 1, methods will die immediately with an error
 544 message.  Therefore, when I<CHECK> is set to 1,  you should trap the
 545 fatal error with eval{} unless you really want to let it die on error.
 546
 547 =item I<CHECK> = Encode::FB_QUIET
 548
 549 If I<CHECK> is set to Encode::FB_QUIET, (en|de)code will immediately
 550 return the portion of the data that has been processed so far when
 551 an error occurs. The data argument will be overwritten with
 552 everything after that point (that is, the unprocessed part of data).
 553 This is handy when you have to call decode repeatedly in the case
 554 where your source data may contain partial multi-byte character
 555 sequences, for example because you are reading with a fixed-width
 556 buffer. Here is some sample code that does exactly this:
 557
 558   my $data = '';
 559   while(defined(read $fh, $buffer, 256)){
 560     # buffer may end in a partial character so we append
 561     $data .= $buffer;
 562     $utf8 .= decode($encoding, $data, ENCODE::FB_QUIET);
 563     # $data now contains the unprocessed partial character
 564   }
 565
 566 =item I<CHECK> = Encode::FB_WARN
 567
 568 This is the same as above, except that it warns on error.  Handy when
 569 you are debugging the mode above.
 570
 571 =item perlqq mode (I<CHECK> = Encode::FB_PERLQQ)
 572
 573 =item HTML charref mode (I<CHECK> = Encode::FB_HTMLCREF)
 574
 575 =item XML charref mode (I<CHECK> = Encode::FB_XMLCREF)
 576
 577 For encodings that are implemented by Encode::XS, CHECK ==
 578 Encode::FB_PERLQQ turns (en|de)code into C<perlqq> fallback mode.
 579
 580 When you decode, '\xI<XX>' will be inserted for a malformed character,
 581 where I<XX> is the hex representation of the octet  that could not be
 582 decoded to utf8.  And when you encode, '\x{I<xxxx>}' will be inserted,
 583 where I<xxxx> is the Unicode ID of the character that cannot be found
 584 in the character repertoire of the encoding.
 585
 586 HTML/XML character reference modes are about the same, in place of
 587 \x{I<xxxx>}, HTML uses &#I<1234>; where I<1234> is a decimal digit and
 588 XML uses &#xI<abcd>; where I<abcd> is the hexadecimal digit.
 589
 590 =item The bitmask
 591
 592 These modes are actually set via a bitmask.  Here is how the FB_XX
 593 constants are laid out.  You can import the FB_XX constants via
 594 C<use Encode qw(:fallbacks)>; you can import the generic bitmask
 595 constants via C<use Encode qw(:fallback_all)>.
 596
 597                      FB_DEFAULT FB_CROAK FB_QUIET FB_WARN  FB_PERLQQ
 598  DIE_ON_ERR    0x0001             X
 599  WARN_ON_ER    0x0002                               X
 600  RETURN_ON_ERR 0x0004                      X        X
 601  LEAVE_SRC     0x0008
 602  PERLQQ        0x0100                                        X
 603  HTMLCREF      0x0200
 604  XMLCREF       0x0400
 605
 606 =head2 Unimplemented fallback schemes
 607
 608 In the future, you will be able to use a code reference to a callback
 609 function for the value of I<CHECK> but its API is still undecided.
 610
 611 =head1 Defining Encodings
 612
 613 To define a new encoding, use:
 614
 615     use Encode qw(define_alias);
 616     define_encoding($object, 'canonicalName' [, alias...]);
 617
 618 I<canonicalName> will be associated with I<$object>.  The object
 619 should provide the interface described in L<Encode::Encoding>.
 620 If more than two arguments are provided then additional
 621 arguments are taken as aliases for I<$object>, as for C<define_alias>.
 622
 623 See L<Encode::Encoding> for more details.
 624
 625 =head1 The UTF-8 flag
 626
 627 Before the introduction of utf8 support in perl, The C<eq> operator
 628 just compares internal data of the scalars.  Now C<eq> means internal
 629 data equality AND I<the utf8 flag>.  To explain why we made it so, I
 630 will quote page 402 of C<Programming Perl, 3rd ed.>
 631
 632 =over 2
 633
 634 =item Goal #1:
 635
 636 Old byte-oriented programs should not spontaneously break on the old
 637 byte-oriented data they used to work on.
 638
 639 =item Goal #2:
 640
 641 Old byte-oriented programs should magically start working on the new
 642 character-oriented data when appropriate.
 643
 644 =item Goal #3:
 645
 646 Programs should run just as fast in the new character-oriented mode
 647 as in the old byte-oriented mode.
 648
 649 =item Goal #4:
 650
 651 Perl should remain one language, rather than forking into a
 652 byte-oriented Perl and a character-oriented Perl.
 653
 654 =back
 655
 656 Back when C<Programming Perl, 3rd ed.> was written, not even Perl 5.6.0
 657 was born and many features documented in the book remained
 658 unimplemented.  Perl 5.8 hopefully correct this and the introduction
 659 of UTF-8 flag is one of them.  You can think this perl notion of
 660 byte-oriented mode (utf8 flag off) and character-oriented mode (utf8
 661 flag on).
 662
 663 Here is how Encode takes care of the utf8 flag.
 664
 665 =over2
 666
 667 =item *
 668
 669 When you encode, the resulting utf8 flag is always off.
 670
 671 =item
 672
 673 When you decode, the resuting utf8 flag is on unless you can
 674 unambiguously represent data.  Here is the definition of
 675 dis-ambiguity.
 676
 677   After C<$utf8 = decode('foo', $octet);>,
 678
 679   When $octet is...   The utf8 flag in $utf8 is
 680   ---------------------------------------------
 681   In ASCII only (or EBCDIC only)            OFF
 682   In ISO-8859-1                              ON
 683   In any other Encoding                      ON
 684   ---------------------------------------------
 685
 686 As you see, there is one exception, In ASCII.  That way you can assue
 687 Goal #1.  And with Encode Goal #2 is assumed but you still have to be
 688 careful in such cases mentioned in B<CAVEAT> paragraphs.
 689
 690 This utf8 flag is not visible in perl scripts, exactly for the same
 691 reason you cannot (or you I<don't have to>) see if a scalar contains a
 692 string, integer, or floating point number.   But you can still peek
 693 and poke these if you will.  See the section below.
 694
 695 =back
 696
 697 =head2 Messing with Perl's Internals
 698
 699 The following API uses parts of Perl's internals in the current
 700 implementation.  As such, they are efficient but may change.
 701
 702 =over 2
 703
 704 =item is_utf8(STRING [, CHECK])
 705
 706 [INTERNAL] Tests whether the UTF-8 flag is turned on in the STRING.
 707 If CHECK is true, also checks the data in STRING for being well-formed
 708 UTF-8.  Returns true if successful, false otherwise.
 709
 710 =item _utf8_on(STRING)
 711
 712 [INTERNAL] Turns on the UTF-8 flag in STRING.  The data in STRING is
 713 B<not> checked for being well-formed UTF-8.  Do not use unless you
 714 B<know> that the STRING is well-formed UTF-8.  Returns the previous
 715 state of the UTF-8 flag (so please don't treat the return value as
 716 indicating success or failure), or C<undef> if STRING is not a string.
 717
 718 =item _utf8_off(STRING)
 719
 720 [INTERNAL] Turns off the UTF-8 flag in STRING.  Do not use frivolously.
 721 Returns the previous state of the UTF-8 flag (so please don't treat the
 722 return value as indicating success or failure), or C<undef> if STRING is
 723 not a string.
 724
 725 =back
 726
 727 =head1 SEE ALSO
 728
 729 L<Encode::Encoding>,
 730 L<Encode::Supported>,
 731 L<Encode::PerlIO>,
 732 L<encoding>,
 733 L<perlebcdic>,
 734 L<perlfunc/open>,
 735 L<perlunicode>,
 736 L<utf8>,
 737 the Perl Unicode Mailing List E<lt>perl-unicode@perl.orgE<gt>
 738
 739 =head1 MAINTAINER
 740
 741 This project was originated by Nick Ing-Simmons and later maintained
 742 by Dan Kogai E<lt>dankogai@dan.co.jpE<gt>.  See AUTHORS for a full
 743 list of people involved.  For any questions, use
 744 E<lt>perl-unicode@perl.orgE<gt> so we can all share share.
 745
 746 =cut