ext/Encode/Encode.pm

   1 package Encode;
   2 use strict;
   3 our $VERSION = '0.40';
   4
   5 require DynaLoader;
   6 require Exporter;
   7
   8 our @ISA = qw(Exporter DynaLoader);
   9
  10 # Public, encouraged API is exported by default
  11 our @EXPORT = qw (
  12   encode
  13   decode
  14   encode_utf8
  15   decode_utf8
  16   find_encoding
  17   encodings
  18 );
  19
  20 our @EXPORT_OK =
  21     qw(
  22        define_encoding
  23        define_alias
  24        from_to
  25        is_utf8
  26        is_8bit
  27        is_16bit
  28        utf8_upgrade
  29        utf8_downgrade
  30        _utf8_on
  31        _utf8_off
  32       );
  33
  34 bootstrap Encode ();
  35
  36 # Documentation moved after __END__ for speed - NI-S
  37
  38 use Carp;
  39
  40 # Make a %encoding package variable to allow a certain amount of cheating
  41 our %encoding;
  42 my @alias;  # ordered matching list
  43 my %alias;  # cached known aliases
  44
  45                      # 0  1  2  3  4  5   6   7   8   9  10
  46 our @latin2iso_num = ( 0, 1, 2, 3, 4, 9, 10, 13, 14, 15, 16 );
  47
  48 our %winlatin2cp   = (
  49                       'Latin1'     => 1252,
  50                       'Latin2'     => 1250,
  51                       'Cyrillic'   => 1251,
  52                       'Greek'      => 1253,
  53                       'Turkish'    => 1254,
  54                       'Hebrew'     => 1255,
  55                       'Arabic'     => 1256,
  56                       'Baltic'     => 1257,
  57                       'Vietnamese' => 1258,
  58                      );
  59
  60 sub encodings
  61 {
  62  my ($class) = @_;
  63  return
  64      map { $_->[0] }
  65          sort { $a->[1] cmp $b->[1] }
  66                map { [$_, lc $_] }
  67                    grep { $_ ne 'Internal' }
  68                         keys %encoding;
  69 }
  70
  71 sub findAlias
  72 {
  73     my $class = shift;
  74     local $_ = shift;
  75     # print "# findAlias $_\n";
  76     unless (exists $alias{$_})
  77     {
  78         for (my $i=0; $i < @alias; $i += 2)
  79         {
  80             my $alias = $alias[$i];
  81             my $val   = $alias[$i+1];
  82             my $new;
  83             if (ref($alias) eq 'Regexp' && $_ =~ $alias)
  84             {
  85                 $new = eval $val;
  86             }
  87             elsif (ref($alias) eq 'CODE')
  88             {
  89                 $new = &{$alias}($val)
  90                 }
  91             elsif (lc($_) eq lc($alias))
  92             {
  93                 $new = $val;
  94             }
  95             if (defined($new))
  96             {
  97                 next if $new eq $_; # avoid (direct) recursion on bugs
  98                 my $enc = (ref($new)) ? $new : find_encoding($new);
  99                 if ($enc)
 100                 {
 101                     $alias{$_} = $enc;
 102                     last;
 103                 }
 104             }
 105         }
 106     }
 107     return $alias{$_};
 108 }
 109
 110 sub define_alias
 111 {
 112     while (@_)
 113     {
 114         my ($alias,$name) = splice(@_,0,2);
 115         push(@alias, $alias => $name);
 116     }
 117 }
 118
 119 # Allow variants of iso-8859-1 etc.
 120 define_alias( qr/^iso[-_]?(\d+)[-_](\d+)$/i => '"iso-$1-$2"' );
 121
 122 # At least HP-UX has these.
 123 define_alias( qr/^iso8859(\d+)$/i => '"iso-8859-$1"' );
 124
 125 # More HP stuff.
 126 define_alias( qr/^(?:hp-)?(arabic|greek|hebrew|kana|roman|thai|turkish)8$/i => '"${1}8"' );
 127
 128 # The Official name of ASCII.
 129 define_alias( qr/^ANSI[-_]?X3\.4[-_]?1968$/i => '"ascii"' );
 130
 131 # This is a font issue, not an encoding issue.
 132 # (The currency symbol of the Latin 1 upper half
 133 #  has been redefined as the euro symbol.)
 134 define_alias( qr/^(.+)\@euro$/i => '"$1"' );
 135
 136 # Allow latin-1 style names as well
 137 define_alias( qr/^(?:iso[-_]?)?latin[-_]?(\d+)$/i => '"iso-8859-$latin2iso_num[$1]"' );
 138
 139 # Allow winlatin1 style names as well
 140 define_alias( qr/^win(latin[12]|cyrillic|baltic|greek|turkish|hebrew|arabic|baltic|vietnamese)$/i => '"cp$winlatin2cp{\u$1}"' );
 141
 142 # Common names for non-latin prefered MIME names
 143 define_alias( 'ascii'    => 'US-ascii',
 144               'cyrillic' => 'iso-8859-5',
 145               'arabic'   => 'iso-8859-6',
 146               'greek'    => 'iso-8859-7',
 147               'hebrew'   => 'iso-8859-8',
 148               'thai'     => 'iso-8859-11',
 149               'tis620'   => 'iso-8859-11',
 150             );
 151
 152 # At least AIX has IBM-NNN (surprisingly...) instead of cpNNN.
 153 # And Microsoft has their own naming (again, surprisingly).
 154 define_alias( qr/^(?:ibm|ms)[-_]?(\d\d\d\d?)$/i => '"cp$1"');
 155
 156 # Sometimes seen with a leading zero.
 157 define_alias( qr/^cp037$/i => '"cp37"');
 158
 159 # Ououououou.
 160 define_alias( qr/^macRomanian$/i => '"macRumanian"');
 161
 162 # Standardize on the dashed versions.
 163 define_alias( qr/^utf8$/i  => 'utf-8' );
 164 define_alias( qr/^koi8r$/i => 'koi8-r' );
 165 define_alias( qr/^koi8u$/i => 'koi8-u' );
 166
 167 # Seen in some Linuxes.
 168 define_alias( qr/^ujis$/i => 'euc-jp' );
 169
 170 # TODO: HP-UX '8' encodings arabic8 greek8 hebrew8 kana8 thai8 turkish8
 171 # TODO: HP-UX '15' encodings japanese15 korean15 roi15
 172 # TODO: Cyrillic encoding ISO-IR-111 (useful?)
 173 # TODO: Chinese encodings GB18030 EUC-TW HZ
 174 # TODO: Armenian encoding ARMSCII-8
 175 # TODO: Hebrew encoding ISO-8859-8-1
 176 # TODO: Thai encoding TCVN
 177 # TODO: Korean encoding Johab
 178 # TODO: Vietnamese encodings VPS
 179 # TODO: Japanese encoding JIS (not the same as SJIS)
 180 # TODO: Mac Asian+African encodings: Arabic Armenian Bengali Burmese
 181 #       ChineseSimp ChineseTrad Devanagari Ethiopic ExtArabic
 182 #       Farsi Georgian Gujarati Gurmukhi Hebrew Japanese
 183 #       Kannada Khmer Korean Laotian Malayalam Mongolian
 184 #       Oriya Sinhalese Symbol Tamil Telugu Tibetan Vietnamese
 185
 186 # Map white space and _ to '-'
 187 define_alias( qr/^(\S+)[\s_]+(.*)$/i => '"$1-$2"' );
 188
 189 sub define_encoding
 190 {
 191     my $obj  = shift;
 192     my $name = shift;
 193     $encoding{$name} = $obj;
 194     my $lc = lc($name);
 195     define_alias($lc => $obj) unless $lc eq $name;
 196     while (@_)
 197     {
 198         my $alias = shift;
 199         define_alias($alias,$obj);
 200     }
 201     return $obj;
 202 }
 203
 204 sub getEncoding
 205 {
 206     my ($class,$name) = @_;
 207     my $enc;
 208     if (ref($name) && $name->can('new_sequence'))
 209     {
 210         return $name;
 211     }
 212     my $lc = lc $name;
 213     if (exists $encoding{$name})
 214     {
 215         return $encoding{$name};
 216     }
 217     if (exists $encoding{$lc})
 218     {
 219         return $encoding{$lc};
 220     }
 221
 222     my $oc = $class->findAlias($name);
 223     return $oc if defined $oc;
 224     return $class->findAlias($lc) if $lc ne $name;
 225
 226     return;
 227 }
 228
 229 sub find_encoding
 230 {
 231     my ($name) = @_;
 232     return __PACKAGE__->getEncoding($name);
 233 }
 234
 235 sub encode
 236 {
 237     my ($name,$string,$check) = @_;
 238     my $enc = find_encoding($name);
 239     croak("Unknown encoding '$name'") unless defined $enc;
 240     my $octets = $enc->encode($string,$check);
 241     return undef if ($check && length($string));
 242     return $octets;
 243 }
 244
 245 sub decode
 246 {
 247     my ($name,$octets,$check) = @_;
 248     my $enc = find_encoding($name);
 249     croak("Unknown encoding '$name'") unless defined $enc;
 250     my $string = $enc->decode($octets,$check);
 251     $_[1] = $octets if $check;
 252     return $string;
 253 }
 254
 255 sub from_to
 256 {
 257     my ($string,$from,$to,$check) = @_;
 258     my $f = find_encoding($from);
 259     croak("Unknown encoding '$from'") unless defined $f;
 260     my $t = find_encoding($to);
 261     croak("Unknown encoding '$to'") unless defined $t;
 262     my $uni = $f->decode($string,$check);
 263     return undef if ($check && length($string));
 264     $string = $t->encode($uni,$check);
 265     return undef if ($check && length($uni));
 266     return length($_[0] = $string);
 267 }
 268
 269 sub encode_utf8
 270 {
 271     my ($str) = @_;
 272   utf8::encode($str);
 273     return $str;
 274 }
 275
 276 sub decode_utf8
 277 {
 278     my ($str) = @_;
 279     return undef unless utf8::decode($str);
 280     return $str;
 281 }
 282
 283 require Encode::Encoding;
 284 require Encode::XS;
 285 require Encode::Internal;
 286 require Encode::Unicode;
 287 require Encode::utf8;
 288 require Encode::iso10646_1;
 289 require Encode::ucs2_le;
 290
 291 1;
 292
 293 __END__
 294
 295 =head1 NAME
 296
 297 Encode - character encodings
 298
 299 =head1 SYNOPSIS
 300
 301     use Encode;
 302
 303 =head1 DESCRIPTION
 304
 305 The C<Encode> module provides the interfaces between Perl's strings
 306 and the rest of the system.  Perl strings are sequences of B<characters>.
 307
 308 The repertoire of characters that Perl can represent is at least that
 309 defined by the Unicode Consortium. On most platforms the ordinal
 310 values of the characters (as returned by C<ord(ch)>) is the "Unicode
 311 codepoint" for the character (the exceptions are those platforms where
 312 the legacy encoding is some variant of EBCDIC rather than a super-set
 313 of ASCII - see L<perlebcdic>).
 314
 315 Traditionaly computer data has been moved around in 8-bit chunks
 316 often called "bytes". These chunks are also known as "octets" in
 317 networking standards. Perl is widely used to manipulate data of
 318 many types - not only strings of characters representing human or
 319 computer languages but also "binary" data being the machines representation
 320 of numbers, pixels in an image - or just about anything.
 321
 322 When Perl is processing "binary data" the programmer wants Perl to process
 323 "sequences of bytes". This is not a problem for Perl - as a byte has 256
 324 possible values it easily fits in Perl's much larger "logical character".
 325
 326 =head2 TERMINOLOGY
 327
 328 =over 4
 329
 330 =item *
 331
 332 I<character>: a character in the range 0..(2**32-1) (or more).
 333 (What Perl's strings are made of.)
 334
 335 =item *
 336
 337 I<byte>: a character in the range 0..255
 338 (A special case of a Perl character.)
 339
 340 =item *
 341
 342 I<octet>: 8 bits of data, with ordinal values 0..255
 343 (Term for bytes passed to or from a non-Perl context, e.g. disk file.)
 344
 345 =back
 346
 347 The marker [INTERNAL] marks Internal Implementation Details, in
 348 general meant only for those who think they know what they are doing,
 349 and such details may change in future releases.
 350
 351 =head1 ENCODINGS
 352
 353 =head2 Characteristics of an Encoding
 354
 355 An encoding has a "repertoire" of characters that it can represent,
 356 and for each representable character there is at least one sequence of
 357 octets that represents it.
 358
 359 =head2 Types of Encodings
 360
 361 Encodings can be divided into the following types:
 362
 363 =over 4
 364
 365 =item * Fixed length 8-bit (or less) encodings.
 366
 367 Each character is a single octet so may have a repertoire of up to
 368 256 characters. ASCII and iso-8859-* are typical examples.
 369
 370 =item * Fixed length 16-bit encodings
 371
 372 Each character is two octets so may have a repertoire of up to
 373 65 536 characters.  Unicode's UCS-2 is an example.  Also used for
 374 encodings for East Asian languages.
 375
 376 =item * Fixed length 32-bit encodings.
 377
 378 Not really very "encoded" encodings. The Unicode code points
 379 are just represented as 4-octet integers. None the less because
 380 different architectures use different representations of integers
 381 (so called "endian") there at least two disctinct encodings.
 382
 383 =item * Multi-byte encodings
 384
 385 The number of octets needed to represent a character varies.
 386 UTF-8 is a particularly complex but regular case of a multi-byte
 387 encoding. Several East Asian countries use a multi-byte encoding
 388 where 1-octet is used to cover western roman characters and Asian
 389 characters get 2-octets.
 390 (UTF-16 is strictly a multi-byte encoding taking either 2 or 4 octets
 391 to represent a Unicode code point.)
 392
 393 =item * "Escape" encodings.
 394
 395 These encodings embed "escape sequences" into the octet sequence
 396 which describe how the following octets are to be interpreted.
 397 The iso-2022-* family is typical. Following the escape sequence
 398 octets are encoded by an "embedded" encoding (which will be one
 399 of the above types) until another escape sequence switches to
 400 a different "embedded" encoding.
 401
 402 These schemes are very flexible and can handle mixed languages but are
 403 very complex to process (and have state).  No escape encodings are
 404 implemented for Perl yet.
 405
 406 =back
 407
 408 =head2 Specifying Encodings
 409
 410 Encodings can be specified to the API described below in two ways:
 411
 412 =over 4
 413
 414 =item 1. By name
 415
 416 Encoding names are strings with characters taken from a restricted
 417 repertoire.  See L</"Encoding Names">.
 418
 419 =item 2. As an object
 420
 421 Encoding objects are returned by C<find_encoding($name)>.
 422
 423 =back
 424
 425 =head2 Encoding Names
 426
 427 Encoding names are case insensitive. White space in names is ignored.
 428 In addition an encoding may have aliases. Each encoding has one
 429 "canonical" name.  The "canonical" name is chosen from the names of
 430 the encoding by picking the first in the following sequence:
 431
 432 =over 4
 433
 434 =item * The MIME name as defined in IETF RFCs.
 435
 436 =item * The name in the IANA registry.
 437
 438 =item * The name used by the organization that defined it.
 439
 440 =back
 441
 442 Because of all the alias issues, and because in the general case
 443 encodings have state C<Encode> uses the encoding object internally
 444 once an operation is in progress.
 445
 446 As of Perl 5.8.0, at least the following encodings are recognized
 447 (the => marks aliases):
 448
 449   ASCII
 450
 451   US-ASCII => ASCII
 452
 453 The Unicode:
 454
 455   UTF-8
 456   UTF-16
 457   UCS-2
 458
 459   ISO 10646-1 => UCS-2
 460
 461 The ISO 8859 and KOI:
 462
 463   ISO 8859-1  ISO 8859-6   ISO 8859-11         KOI8-F
 464   ISO 8859-2  ISO 8859-7   (12 doesn't exist)  KOI8-R
 465   ISO 8859-3  ISO 8859-8   ISO 8859-13         KOI8-U
 466   ISO 8859-4  ISO 8859-9   ISO 8859-14
 467   ISO 8859-5  ISO 8859-10  ISO 8859-15
 468                            ISO 8859-16
 469
 470   Latin1  => 8859-1  Latin6  => 8859-10
 471   Latin2  => 8859-2  Latin7  => 8859-13
 472   Latin3  => 8859-3  Latin8  => 8859-14
 473   Latin4  => 8859-4  Latin9  => 8859-15
 474   Latin5  => 8859-9  Latin10 => 8859-16
 475
 476   Cyrillic => 8859-5
 477   Arabic   => 8859-6
 478   Greek    => 8859-7
 479   Hebrew   => 8859-8
 480   Thai     => 8859-11
 481   TIS620   => 8859-11
 482
 483 The CJKV: Chinese, Japanese, Korean, Vietnamese:
 484
 485   ISO 2022     ISO 2022 JP-1  JIS 0201  GB 1988   Big5       EUC-CN
 486   ISO 2022 CN  ISO 2022 JP-2  JIS 0208  GB 2312   HZ         EUC-JP
 487   ISO 2022 JP  ISO 2022 KR    JIS 0210  GB 12345  CNS 11643  EUC-JP-0212
 488   Shift-JIS                                                  EUC-KR
 489   VISCII
 490
 491 The PC codepages:
 492
 493   CP37   CP852  CP861  CP866  CP949   CP1251  CP1256
 494   CP424  CP855  CP862  CP869  CP950   CP1252  CP1257
 495   CP737  CP856  CP863  CP874  CP1006  CP1253  CP1258
 496   CP775  CP857  CP864  CP932  CP1047  CP1254
 497   CP850  CP860  CP865  CP936  CP1250  CP1255
 498
 499   WinLatin1     => CP1252
 500   WinLatin2     => CP1250
 501   WinCyrillic   => CP1251
 502   WinGreek      => CP1253
 503   WinTurkiskh   => CP1254
 504   WinHebrew     => CP1255
 505   WinArabic     => CP1256
 506   WinBaltic     => CP1257
 507   WinVietnamese => CP1258
 508
 509 (All the CPI<NNN...> are available also as IBMI<NNN...>.)
 510
 511 The Mac codepages:
 512
 513   MacCentralEuropean   MacJapanese
 514   MacCroatian          MacRoman
 515   MacCyrillic          MacRomanian
 516   MacDingbats          MacSami
 517   MacGreek             MacThai
 518   MacIcelandic         MacTurkish
 519                        MacUkraine
 520
 521 Miscellaneous:
 522
 523   7bit-greek  IR-197
 524   7bit-kana   NeXTstep
 525   7bit-latin1 POSIX-BC
 526   DingBats    Roman8
 527   GSM 0338    Symbol
 528
 529 =head1 PERL ENCODING API
 530
 531 =head2 Generic Encoding Interface
 532
 533 =over 4
 534
 535 =item *
 536
 537         $bytes  = encode(ENCODING, $string[, CHECK])
 538
 539 Encodes string from Perl's internal form into I<ENCODING> and returns
 540 a sequence of octets.  For CHECK see L</"Handling Malformed Data">.
 541
 542 For example to convert (internally UTF-8 encoded) Unicode data
 543 to octets:
 544
 545         $octets = encode("utf8", $unicode);
 546
 547 =item *
 548
 549         $string = decode(ENCODING, $bytes[, CHECK])
 550
 551 Decode sequence of octets assumed to be in I<ENCODING> into Perl's
 552 internal form and returns the resulting string.  For CHECK see
 553 L</"Handling Malformed Data">.
 554
 555 For example to convert ISO 8859-1 data to UTF-8:
 556
 557         $utf8 = decode("latin1", $latin1);
 558
 559 =item *
 560
 561         from_to($string, FROM_ENCODING, TO_ENCODING[, CHECK])
 562
 563 Convert B<in-place> the data between two encodings.  How did the data
 564 in $string originally get to be in FROM_ENCODING?  Either using
 565 encode() or through PerlIO: See L</"Encoding and IO">.  For CHECK
 566 see L</"Handling Malformed Data">.
 567
 568 For example to convert ISO 8859-1 data to UTF-8:
 569
 570         from_to($data, "iso-8859-1", "utf-8");
 571
 572 and to convert it back:
 573
 574         from_to($data, "utf-8", "iso-8859-1");
 575
 576 Note that because the conversion happens in place, the data to be
 577 converted cannot be a string constant, it must be a scalar variable.
 578
 579 =back
 580
 581 =head2 Handling Malformed Data
 582
 583 If CHECK is not set, C<undef> is returned.  If the data is supposed to
 584 be UTF-8, an optional lexical warning (category utf8) is given.  If
 585 CHECK is true but not a code reference, dies.
 586
 587 It would desirable to have a way to indicate that transform should use
 588 the encodings "replacement character" - no such mechanism is defined yet.
 589
 590 It is also planned to allow I<CHECK> to be a code reference.
 591
 592 This is not yet implemented as there are design issues with what its
 593 arguments should be and how it returns its results.
 594
 595 =over 4
 596
 597 =item Scheme 1
 598
 599 Passed remaining fragment of string being processed.
 600 Modifies it in place to remove bytes/characters it can understand
 601 and returns a string used to represent them.
 602 e.g.
 603
 604  sub fixup {
 605    my $ch = substr($_[0],0,1,'');
 606    return sprintf("\x{%02X}",ord($ch);
 607  }
 608
 609 This scheme is close to how underlying C code for Encode works, but gives
 610 the fixup routine very little context.
 611
 612 =item Scheme 2
 613
 614 Passed original string, and an index into it of the problem area, and
 615 output string so far.  Appends what it will to output string and
 616 returns new index into original string.  For example:
 617
 618  sub fixup {
 619    # my ($s,$i,$d) = @_;
 620    my $ch = substr($_[0],$_[1],1);
 621    $_[2] .= sprintf("\x{%02X}",ord($ch);
 622    return $_[1]+1;
 623  }
 624
 625 This scheme gives maximal control to the fixup routine but is more
 626 complicated to code, and may need internals of Encode to be tweaked to
 627 keep original string intact.
 628
 629 =item Other Schemes
 630
 631 Hybrids of above.
 632
 633 Multiple return values rather than in-place modifications.
 634
 635 Index into the string could be pos($str) allowing s/\G...//.
 636
 637 =back
 638
 639 =head2 UTF-8 / utf8
 640
 641 The Unicode consortium defines the UTF-8 standard as a way of encoding
 642 the entire Unicode repertiore as sequences of octets.  This encoding is
 643 expected to become very widespread. Perl can use this form internaly
 644 to represent strings, so conversions to and from this form are
 645 particularly efficient (as octets in memory do not have to change,
 646 just the meta-data that tells Perl how to treat them).
 647
 648 =over 4
 649
 650 =item *
 651
 652         $bytes = encode_utf8($string);
 653
 654 The characters that comprise string are encoded in Perl's superset of UTF-8
 655 and the resulting octets returned as a sequence of bytes. All possible
 656 characters have a UTF-8 representation so this function cannot fail.
 657
 658 =item *
 659
 660         $string = decode_utf8($bytes [,CHECK]);
 661
 662 The sequence of octets represented by $bytes is decoded from UTF-8
 663 into a sequence of logical characters. Not all sequences of octets
 664 form valid UTF-8 encodings, so it is possible for this call to fail.
 665 For CHECK see L</"Handling Malformed Data">.
 666
 667 =back
 668
 669 =head2 Other Encodings of Unicode
 670
 671 UTF-16 is similar to UCS-2, 16 bit or 2-byte chunks.  UCS-2 can only
 672 represent 0..0xFFFF, while UTF-16 has a I<surrogate pair> scheme which
 673 allows it to cover the whole Unicode range.
 674
 675 Surrogates are code points set aside to encode the 0x01000..0x10FFFF
 676 range of Unicode code points in pairs of 16-bit units.  The I<high
 677 surrogates> are the range 0xD800..0xDBFF, and the I<low surrogates>
 678 are the range 0xDC00..0xDFFFF.  The surrogate encoding is
 679
 680         $hi = ($uni - 0x10000) / 0x400 + 0xD800;
 681         $lo = ($uni - 0x10000) % 0x400 + 0xDC00;
 682
 683 and the decoding is
 684
 685         $uni = 0x10000 + ($hi - 0xD8000) * 0x400 + ($lo - 0xDC00);
 686
 687 Encode implements big-endian UCS-2 aliased to "iso-10646-1" as that
 688 happens to be the name used by that representation when used with X11
 689 fonts.
 690
 691 UTF-32 or UCS-4 is 32-bit or 4-byte chunks.  Perl's logical characters
 692 can be considered as being in this form without encoding. An encoding
 693 to transfer strings in this form (e.g. to write them to a file) would
 694 need to
 695
 696      pack('L*', unpack('U*', $string));  # native
 697   or
 698      pack('V*', unpack('U*', $string));  # little-endian
 699   or
 700      pack('N*', unpack('U*', $string));  # big-endian
 701
 702 depending on the endianness required.
 703
 704 No UTF-32 encodings are implemented yet.
 705
 706 Both UCS-2 and UCS-4 style encodings can have "byte order marks" by
 707 representing the code point 0xFFFE as the very first thing in a file.
 708
 709 =head2 Listing available encodings
 710
 711   use Encode qw(encodings);
 712   @list = encodings();
 713
 714 Returns a list of the canonical names of the available encodings.
 715
 716 =head2 Defining Aliases
 717
 718   use Encode qw(define_alias);
 719   define_alias( newName => ENCODING);
 720
 721 Allows newName to be used as am alias for ENCODING. ENCODING may be
 722 either the name of an encoding or and encoding object (as above).
 723
 724 Currently I<newName> can be specified in the following ways:
 725
 726 =over 4
 727
 728 =item As a simple string.
 729
 730 =item As a qr// compiled regular expression, e.g.:
 731
 732   define_alias( qr/^iso8859-(\d+)$/i => '"iso-8859-$1"' );
 733
 734 In this case if I<ENCODING> is not a reference it is C<eval>-ed to
 735 allow C<$1> etc. to be subsituted.  The example is one way to names as
 736 used in X11 font names to alias the MIME names for the iso-8859-*
 737 family.
 738
 739 =item As a code reference, e.g.:
 740
 741   define_alias( sub { return /^iso8859-(\d+)$/i ? "iso-8859-$1" : undef } , '');
 742
 743 In this case C<$_> will be set to the name that is being looked up and
 744 I<ENCODING> is passed to the sub as its first argument.  The example
 745 is another way to names as used in X11 font names to alias the MIME
 746 names for the iso-8859-* family.
 747
 748 =back
 749
 750 =head2 Defining Encodings
 751
 752     use Encode qw(define_alias);
 753     define_encoding( $object, 'canonicalName' [,alias...]);
 754
 755 Causes I<canonicalName> to be associated with I<$object>.  The object
 756 should provide the interface described in L</"IMPLEMENTATION CLASSES">
 757 below.  If more than two arguments are provided then additional
 758 arguments are taken as aliases for I<$object> as for C<define_alias>.
 759
 760 =head1 Encoding and IO
 761
 762 It is very common to want to do encoding transformations when
 763 reading or writing files, network connections, pipes etc.
 764 If Perl is configured to use the new 'perlio' IO system then
 765 C<Encode> provides a "layer" (See L<perliol>) which can transform
 766 data as it is read or written.
 767
 768 Here is how the blind poet would modernise the encoding:
 769
 770     use Encode;
 771     open(my $iliad,'<:encoding(iso-8859-7)','iliad.greek');
 772     open(my $utf8,'>:utf8','iliad.utf8');
 773     my @epic = <$iliad>;
 774     print $utf8 @epic;
 775     close($utf8);
 776     close($illiad);
 777
 778 In addition the new IO system can also be configured to read/write
 779 UTF-8 encoded characters (as noted above this is efficient):
 780
 781     open(my $fh,'>:utf8','anything');
 782     print $fh "Any \x{0021} string \N{SMILEY FACE}\n";
 783
 784 Either of the above forms of "layer" specifications can be made the default
 785 for a lexical scope with the C<use open ...> pragma. See L<open>.
 786
 787 Once a handle is open is layers can be altered using C<binmode>.
 788
 789 Without any such configuration, or if Perl itself is built using
 790 system's own IO, then write operations assume that file handle accepts
 791 only I<bytes> and will C<die> if a character larger than 255 is
 792 written to the handle. When reading, each octet from the handle
 793 becomes a byte-in-a-character. Note that this default is the same
 794 behaviour as bytes-only languages (including Perl before v5.6) would
 795 have, and is sufficient to handle native 8-bit encodings
 796 e.g. iso-8859-1, EBCDIC etc. and any legacy mechanisms for handling
 797 other encodings and binary data.
 798
 799 In other cases it is the programs responsibility to transform
 800 characters into bytes using the API above before doing writes, and to
 801 transform the bytes read from a handle into characters before doing
 802 "character operations" (e.g. C<lc>, C</\W+/>, ...).
 803
 804 You can also use PerlIO to convert larger amounts of data you don't
 805 want to bring into memory.  For example to convert between ISO 8859-1
 806 (Latin 1) and UTF-8 (or UTF-EBCDIC in EBCDIC machines):
 807
 808     open(F, "<:encoding(iso-8859-1)", "data.txt") or die $!;
 809     open(G, ">:utf8",                 "data.utf") or die $!;
 810     while (<F>) { print G }
 811
 812     # Could also do "print G <F>" but that would pull
 813     # the whole file into memory just to write it out again.
 814
 815 More examples:
 816
 817     open(my $f, "<:encoding(cp1252)")
 818     open(my $g, ">:encoding(iso-8859-2)")
 819     open(my $h, ">:encoding(latin9)")       # iso-8859-15
 820
 821 See L<PerlIO> for more information.
 822
 823 See also L<encoding> for how to change the default encoding of the
 824 data in your script.
 825
 826 =head1 Encoding How to ...
 827
 828 To do:
 829
 830 =over 4
 831
 832 =item * IO with mixed content (faking iso-2020-*)
 833
 834 =item * MIME's Content-Length:
 835
 836 =item * UTF-8 strings in binary data.
 837
 838 =item * Perl/Encode wrappers on non-Unicode XS modules.
 839
 840 =back
 841
 842 =head1 Messing with Perl's Internals
 843
 844 The following API uses parts of Perl's internals in the current
 845 implementation.  As such they are efficient, but may change.
 846
 847 =over 4
 848
 849 =item * is_utf8(STRING [, CHECK])
 850
 851 [INTERNAL] Test whether the UTF-8 flag is turned on in the STRING.
 852 If CHECK is true, also checks the data in STRING for being well-formed
 853 UTF-8.  Returns true if successful, false otherwise.
 854
 855 =item * valid_utf8(STRING)
 856
 857 [INTERNAL] Test whether STRING is in a consistent state.  Will return
 858 true if string is held as bytes, or is well-formed UTF-8 and has the
 859 UTF-8 flag on.  Main reason for this routine is to allow Perl's
 860 testsuite to check that operations have left strings in a consistent
 861 state.
 862
 863 =item *
 864
 865         _utf8_on(STRING)
 866
 867 [INTERNAL] Turn on the UTF-8 flag in STRING.  The data in STRING is
 868 B<not> checked for being well-formed UTF-8.  Do not use unless you
 869 B<know> that the STRING is well-formed UTF-8.  Returns the previous
 870 state of the UTF-8 flag (so please don't test the return value as
 871 I<not> success or failure), or C<undef> if STRING is not a string.
 872
 873 =item *
 874
 875         _utf8_off(STRING)
 876
 877 [INTERNAL] Turn off the UTF-8 flag in STRING.  Do not use frivolously.
 878 Returns the previous state of the UTF-8 flag (so please don't test the
 879 return value as I<not> success or failure), or C<undef> if STRING is
 880 not a string.
 881
 882 =back
 883
 884 =head1 IMPLEMENTATION CLASSES
 885
 886 As mentioned above encodings are (in the current implementation at least)
 887 defined by objects. The mapping of encoding name to object is via the
 888 C<%encodings> hash.
 889
 890 The values of the hash can currently be either strings or objects.
 891 The string form may go away in the future. The string form occurs
 892 when C<encodings()> has scanned C<@INC> for loadable encodings but has
 893 not actually loaded the encoding in question. This is because the
 894 current "loading" process is all Perl and a bit slow.
 895
 896 Once an encoding is loaded then value of the hash is object which
 897 implements the encoding. The object should provide the following
 898 interface:
 899
 900 =over 4
 901
 902 =item -E<gt>name
 903
 904 Should return the string representing the canonical name of the encoding.
 905
 906 =item -E<gt>new_sequence
 907
 908 This is a placeholder for encodings with state. It should return an
 909 object which implements this interface, all current implementations
 910 return the original object.
 911
 912 =item -E<gt>encode($string,$check)
 913
 914 Should return the octet sequence representing I<$string>. If I<$check>
 915 is true it should modify I<$string> in place to remove the converted
 916 part (i.e.  the whole string unless there is an error).  If an error
 917 occurs it should return the octet sequence for the fragment of string
 918 that has been converted, and modify $string in-place to remove the
 919 converted part leaving it starting with the problem fragment.
 920
 921 If check is is false then C<encode> should make a "best effort" to
 922 convert the string - for example by using a replacement character.
 923
 924 =item -E<gt>decode($octets,$check)
 925
 926 Should return the string that I<$octets> represents. If I<$check> is
 927 true it should modify I<$octets> in place to remove the converted part
 928 (i.e.  the whole sequence unless there is an error).  If an error
 929 occurs it should return the fragment of string that has been
 930 converted, and modify $octets in-place to remove the converted part
 931 leaving it starting with the problem fragment.
 932
 933 If check is is false then C<decode> should make a "best effort" to
 934 convert the string - for example by using Unicode's "\x{FFFD}" as a
 935 replacement character.
 936
 937 =back
 938
 939 It should be noted that the check behaviour is different from the
 940 outer public API. The logic is that the "unchecked" case is useful
 941 when encoding is part of a stream which may be reporting errors
 942 (e.g. STDERR).  In such cases it is desirable to get everything
 943 through somehow without causing additional errors which obscure the
 944 original one. Also the encoding is best placed to know what the
 945 correct replacement character is, so if that is the desired behaviour
 946 then letting low level code do it is the most efficient.
 947
 948 In contrast if check is true, the scheme above allows the encoding to
 949 do as much as it can and tell layer above how much that was. What is
 950 lacking at present is a mechanism to report what went wrong. The most
 951 likely interface will be an additional method call to the object, or
 952 perhaps (to avoid forcing per-stream objects on otherwise stateless
 953 encodings) and additional parameter.
 954
 955 It is also highly desirable that encoding classes inherit from
 956 C<Encode::Encoding> as a base class. This allows that class to define
 957 additional behaviour for all encoding objects. For example built in
 958 Unicode, UCS-2 and UTF-8 classes use :
 959
 960   package Encode::MyEncoding;
 961   use base qw(Encode::Encoding);
 962
 963   __PACKAGE__->Define(qw(myCanonical myAlias));
 964
 965 To create an object with bless {Name => ...},$class, and call
 966 define_encoding.  They inherit their C<name> method from
 967 C<Encode::Encoding>.
 968
 969 =head2 Compiled Encodings
 970
 971 F<Encode.xs> provides a class C<Encode::XS> which provides the
 972 interface described above. It calls a generic octet-sequence to
 973 octet-sequence "engine" that is driven by tables (defined in
 974 F<encengine.c>). The same engine is used for both encode and
 975 decode. C<Encode:XS>'s C<encode> forces Perl's characters to their
 976 UTF-8 form and then treats them as just another multibyte
 977 encoding. C<Encode:XS>'s C<decode> transforms the sequence and then
 978 turns the UTF-8-ness flag as that is the form that the tables are
 979 defined to produce. For details of the engine see the comments in
 980 F<encengine.c>.
 981
 982 The tables are produced by the Perl script F<compile> (the name needs
 983 to change so we can eventually install it somewhere). F<compile> can
 984 currently read two formats:
 985
 986 =over 4
 987
 988 =item *.enc
 989
 990 This is a coined format used by Tcl. It is documented in
 991 Encode/EncodeFormat.pod.
 992
 993 =item *.ucm
 994
 995 This is the semi-standard format used by IBM's ICU package.
 996
 997 =back
 998
 999 F<compile> can write the following forms:
1000
1001 =over 4
1002
1003 =item *.ucm
1004
1005 See above - the F<Encode/*.ucm> files provided with the distribution have
1006 been created from the original Tcl .enc files using this approach.
1007
1008 =item *.c
1009
1010 Produces tables as C data structures - this is used to build in encodings
1011 into F<Encode.so>/F<Encode.dll>.
1012
1013 =item *.xs
1014
1015 In theory this allows encodings to be stand-alone loadable Perl
1016 extensions.  The process has not yet been tested. The plan is to use
1017 this approach for large East Asian encodings.
1018
1019 =back
1020
1021 The set of encodings built-in to F<Encode.so>/F<Encode.dll> is
1022 determined by F<Makefile.PL>.  The current set is as follows:
1023
1024 =over 4
1025
1026 =item ascii and iso-8859-*
1027
1028 That is all the common 8-bit "western" encodings.
1029
1030 =item IBM-1047 and two other variants of EBCDIC.
1031
1032 These are the same variants that are supported by EBCDIC Perl as
1033 "native" encodings.  They are included to prove "reversibility" of
1034 some constructs in EBCDIC Perl.
1035
1036 =item symbol and dingbats as used by Tk on X11.
1037
1038 (The reason Encode got started was to support Perl/Tk.)
1039
1040 =back
1041
1042 That set is rather ad hoc and has been driven by the needs of the
1043 tests rather than the needs of typical applications. It is likely
1044 to be rationalized.
1045
1046 =head1 SEE ALSO
1047
1048 L<perlunicode>, L<perlebcdic>, L<perlfunc/open>, L<PerlIO>, L<encoding>
1049
1050 =cut
1051