ext/Encode/Encode.pm

   1 #
   2 # $Id: Encode.pm,v 2.15 2006/04/06 15:44:11 dankogai Exp dankogai $
   3 #
   4 package Encode;
   5 use strict;
   6 our $VERSION = sprintf "%d.%02d", q$Revision: 2.15 $ =~ /(\d+)/g;
   7 sub DEBUG () { 0 }
   8 use XSLoader ();
   9 XSLoader::load(__PACKAGE__, $VERSION);
  10
  11 require Exporter;
  12 use base qw/Exporter/;
  13
  14 # Public, encouraged API is exported by default
  15
  16 our @EXPORT = qw(
  17   decode  decode_utf8  encode  encode_utf8 str2bytes bytes2str
  18   encodings  find_encoding clone_encoding
  19 );
  20
  21 our @FB_FLAGS  = qw(DIE_ON_ERR WARN_ON_ERR RETURN_ON_ERR LEAVE_SRC
  22                     PERLQQ HTMLCREF XMLCREF STOP_AT_PARTIAL);
  23 our @FB_CONSTS = qw(FB_DEFAULT FB_CROAK FB_QUIET FB_WARN
  24                     FB_PERLQQ FB_HTMLCREF FB_XMLCREF);
  25
  26 our @EXPORT_OK =
  27     (
  28      qw(
  29        _utf8_off _utf8_on define_encoding from_to is_16bit is_8bit
  30        is_utf8 perlio_ok resolve_alias utf8_downgrade utf8_upgrade
  31       ),
  32      @FB_FLAGS, @FB_CONSTS,
  33     );
  34
  35 our %EXPORT_TAGS =
  36     (
  37      all          =>  [ @EXPORT, @EXPORT_OK ],
  38      fallbacks    =>  [ @FB_CONSTS ],
  39      fallback_all =>  [ @FB_CONSTS, @FB_FLAGS ],
  40     );
  41
  42 # Documentation moved after __END__ for speed - NI-S
  43
  44 our $ON_EBCDIC = (ord("A") == 193);
  45
  46 use Encode::Alias;
  47
  48 # Make a %Encoding package variable to allow a certain amount of cheating
  49 our %Encoding;
  50 our %ExtModule;
  51 require Encode::Config;
  52 eval { require Encode::ConfigLocal };
  53
  54 sub encodings
  55 {
  56     my $class = shift;
  57     my %enc;
  58     if (@_ and $_[0] eq ":all"){
  59         %enc = ( %Encoding, %ExtModule );
  60     }else{
  61         %enc = %Encoding;
  62         for my $mod (map {m/::/o ? $_ : "Encode::$_" } @_){
  63             DEBUG and warn $mod;
  64             for my $enc (keys %ExtModule){
  65                 $ExtModule{$enc} eq $mod and $enc{$enc} = $mod;
  66             }
  67         }
  68     }
  69     return
  70         sort { lc $a cmp lc $b }
  71              grep {!/^(?:Internal|Unicode|Guess)$/o} keys %enc;
  72 }
  73
  74 sub perlio_ok{
  75     my $obj = ref($_[0]) ? $_[0] : find_encoding($_[0]);
  76     $obj->can("perlio_ok") and return $obj->perlio_ok();
  77     return 0; # safety net
  78 }
  79
  80 sub define_encoding
  81 {
  82     my $obj  = shift;
  83     my $name = shift;
  84     $Encoding{$name} = $obj;
  85     my $lc = lc($name);
  86     define_alias($lc => $obj) unless $lc eq $name;
  87     while (@_){
  88         my $alias = shift;
  89         define_alias($alias, $obj);
  90     }
  91     return $obj;
  92 }
  93
  94 sub getEncoding
  95 {
  96     my ($class, $name, $skip_external) = @_;
  97
  98     ref($name) && $name->can('renew') and return $name;
  99     exists $Encoding{$name} and return $Encoding{$name};
 100     my $lc = lc $name;
 101     exists $Encoding{$lc} and return $Encoding{$lc};
 102
 103     my $oc = $class->find_alias($name);
 104     defined($oc) and return $oc;
 105     $lc ne $name and $oc = $class->find_alias($lc);
 106     defined($oc) and return $oc;
 107
 108     unless ($skip_external)
 109     {
 110         if (my $mod = $ExtModule{$name} || $ExtModule{$lc}){
 111             $mod =~ s,::,/,g ; $mod .= '.pm';
 112             eval{ require $mod; };
 113             exists $Encoding{$name} and return $Encoding{$name};
 114         }
 115     }
 116     return;
 117 }
 118
 119 sub find_encoding($;$)
 120 {
 121     my ($name, $skip_external) = @_;
 122     return __PACKAGE__->getEncoding($name,$skip_external);
 123 }
 124
 125 sub resolve_alias($){
 126     my $obj = find_encoding(shift);
 127     defined $obj and return $obj->name;
 128     return;
 129 }
 130
 131 sub clone_encoding($){
 132     my $obj = find_encoding(shift);
 133     ref $obj or return;
 134     eval { require Storable };
 135     $@ and return;
 136     return Storable::dclone($obj);
 137 }
 138
 139 sub encode($$;$)
 140 {
 141     my ($name, $string, $check) = @_;
 142     return undef unless defined $string;
 143     $string .= '' if ref $string; # stringify;
 144     $check ||=0;
 145     my $enc = find_encoding($name);
 146     unless(defined $enc){
 147         require Carp;
 148         Carp::croak("Unknown encoding '$name'");
 149     }
 150     my $octets = $enc->encode($string,$check);
 151     $_[1] = $string if $check and !($check & LEAVE_SRC());
 152     return $octets;
 153 }
 154 *str2bytes = \&encode;
 155
 156 sub decode($$;$)
 157 {
 158     my ($name,$octets,$check) = @_;
 159     return undef unless defined $octets;
 160     $octets .= '' if ref $octets;
 161     $check ||=0;
 162     my $enc = find_encoding($name);
 163     unless(defined $enc){
 164         require Carp;
 165         Carp::croak("Unknown encoding '$name'");
 166     }
 167     my $string = $enc->decode($octets,$check);
 168     $_[1] = $octets if $check and !($check & LEAVE_SRC());
 169     return $string;
 170 }
 171 *bytes2str = \&decode;
 172
 173 sub from_to($$$;$)
 174 {
 175     my ($string,$from,$to,$check) = @_;
 176     return undef unless defined $string;
 177     $check ||=0;
 178     my $f = find_encoding($from);
 179     unless (defined $f){
 180         require Carp;
 181         Carp::croak("Unknown encoding '$from'");
 182     }
 183     my $t = find_encoding($to);
 184     unless (defined $t){
 185         require Carp;
 186         Carp::croak("Unknown encoding '$to'");
 187     }
 188     my $uni = $f->decode($string);
 189     $_[0] = $string =  $t->encode($uni,$check);
 190     return undef if ($check && length($uni));
 191     return defined($_[0]) ? length($string) : undef ;
 192 }
 193
 194 sub encode_utf8($)
 195 {
 196     my ($str) = @_;
 197     utf8::encode($str);
 198     return $str;
 199 }
 200
 201 sub decode_utf8($;$)
 202 {
 203     my ($str, $check) = @_;
 204     return $str if is_utf8($str);
 205     if ($check){
 206         return decode("utf8", $str, $check);
 207     }else{
 208         return decode("utf8", $str);
 209         return $str;
 210     }
 211 }
 212
 213 predefine_encodings(1);
 214
 215 #
 216 # This is to restore %Encoding if really needed;
 217 #
 218
 219 sub predefine_encodings{
 220     use Encode::Encoding;
 221     no warnings 'redefine';
 222     my $use_xs = shift;
 223     if ($ON_EBCDIC) {
 224         # was in Encode::UTF_EBCDIC
 225         package Encode::UTF_EBCDIC;
 226         push @Encode::UTF_EBCDIC::ISA, 'Encode::Encoding';
 227         *decode = sub{
 228             my ($obj,$str,$chk) = @_;
 229             my $res = '';
 230             for (my $i = 0; $i < length($str); $i++) {
 231                 $res .=
 232                     chr(utf8::unicode_to_native(ord(substr($str,$i,1))));
 233             }
 234             $_[1] = '' if $chk;
 235             return $res;
 236         };
 237         *encode = sub{
 238             my ($obj,$str,$chk) = @_;
 239             my $res = '';
 240             for (my $i = 0; $i < length($str); $i++) {
 241                 $res .=
 242                     chr(utf8::native_to_unicode(ord(substr($str,$i,1))));
 243             }
 244             $_[1] = '' if $chk;
 245             return $res;
 246         };
 247         $Encode::Encoding{Unicode} =
 248             bless {Name => "UTF_EBCDIC"} => "Encode::UTF_EBCDIC";
 249     } else {
 250         package Encode::Internal;
 251         push @Encode::Internal::ISA, 'Encode::Encoding';
 252         *decode = sub{
 253             my ($obj,$str,$chk) = @_;
 254             utf8::upgrade($str);
 255             $_[1] = '' if $chk;
 256             return $str;
 257         };
 258         *encode = \&decode;
 259         $Encode::Encoding{Unicode} =
 260             bless {Name => "Internal"} => "Encode::Internal";
 261     }
 262
 263     {
 264         # was in Encode::utf8
 265         package Encode::utf8;
 266         push @Encode::utf8::ISA, 'Encode::Encoding';
 267         #
 268         if ($use_xs){
 269             Encode::DEBUG and warn __PACKAGE__, " XS on";
 270             *decode = \&decode_xs;
 271             *encode = \&encode_xs;
 272         }else{
 273             Encode::DEBUG and warn __PACKAGE__, " XS off";
 274             *decode = sub{
 275                 my ($obj,$octets,$chk) = @_;
 276                 my $str = Encode::decode_utf8($octets);
 277                 if (defined $str) {
 278                     $_[1] = '' if $chk;
 279                     return $str;
 280                 }
 281                 return undef;
 282             };
 283             *encode = sub {
 284                 my ($obj,$string,$chk) = @_;
 285                 my $octets = Encode::encode_utf8($string);
 286                 $_[1] = '' if $chk;
 287                 return $octets;
 288             };
 289         }
 290         *cat_decode = sub{ # ($obj, $dst, $src, $pos, $trm, $chk)
 291             my ($obj, undef, undef, $pos, $trm) = @_; # currently ignores $chk
 292             my ($rdst, $rsrc, $rpos) = \@_[1,2,3];
 293             use bytes;
 294             if ((my $npos = index($$rsrc, $trm, $pos)) >= 0) {
 295                 $$rdst .= substr($$rsrc, $pos, $npos - $pos + length($trm));
 296                 $$rpos = $npos + length($trm);
 297                 return 1;
 298             }
 299             $$rdst .= substr($$rsrc, $pos);
 300             $$rpos = length($$rsrc);
 301             return '';
 302         };
 303         $Encode::Encoding{utf8} =
 304             bless {Name => "utf8"} => "Encode::utf8";
 305         $Encode::Encoding{"utf-8-strict"} =
 306             bless {Name => "utf-8-strict", strict_utf8 => 1 } => "Encode::utf8";
 307     }
 308 }
 309
 310 1;
 311
 312 __END__
 313
 314 =head1 NAME
 315
 316 Encode - character encodings
 317
 318 =head1 SYNOPSIS
 319
 320     use Encode;
 321
 322 =head2 Table of Contents
 323
 324 Encode consists of a collection of modules whose details are too big
 325 to fit in one document.  This POD itself explains the top-level APIs
 326 and general topics at a glance.  For other topics and more details,
 327 see the PODs below:
 328
 329   Name                          Description
 330   --------------------------------------------------------
 331   Encode::Alias         Alias definitions to encodings
 332   Encode::Encoding      Encode Implementation Base Class
 333   Encode::Supported     List of Supported Encodings
 334   Encode::CN            Simplified Chinese Encodings
 335   Encode::JP            Japanese Encodings
 336   Encode::KR            Korean Encodings
 337   Encode::TW            Traditional Chinese Encodings
 338   --------------------------------------------------------
 339
 340 =head1 DESCRIPTION
 341
 342 The C<Encode> module provides the interfaces between Perl's strings
 343 and the rest of the system.  Perl strings are sequences of
 344 B<characters>.
 345
 346 The repertoire of characters that Perl can represent is at least that
 347 defined by the Unicode Consortium. On most platforms the ordinal
 348 values of the characters (as returned by C<ord(ch)>) is the "Unicode
 349 codepoint" for the character (the exceptions are those platforms where
 350 the legacy encoding is some variant of EBCDIC rather than a super-set
 351 of ASCII - see L<perlebcdic>).
 352
 353 Traditionally, computer data has been moved around in 8-bit chunks
 354 often called "bytes". These chunks are also known as "octets" in
 355 networking standards. Perl is widely used to manipulate data of many
 356 types - not only strings of characters representing human or computer
 357 languages but also "binary" data being the machine's representation of
 358 numbers, pixels in an image - or just about anything.
 359
 360 When Perl is processing "binary data", the programmer wants Perl to
 361 process "sequences of bytes". This is not a problem for Perl - as a
 362 byte has 256 possible values, it easily fits in Perl's much larger
 363 "logical character".
 364
 365 =head2 TERMINOLOGY
 366
 367 =over 2
 368
 369 =item *
 370
 371 I<character>: a character in the range 0..(2**32-1) (or more).
 372 (What Perl's strings are made of.)
 373
 374 =item *
 375
 376 I<byte>: a character in the range 0..255
 377 (A special case of a Perl character.)
 378
 379 =item *
 380
 381 I<octet>: 8 bits of data, with ordinal values 0..255
 382 (Term for bytes passed to or from a non-Perl context, e.g. a disk file.)
 383
 384 =back
 385
 386 =head1 PERL ENCODING API
 387
 388 =over 2
 389
 390 =item $octets  = encode(ENCODING, $string [, CHECK])
 391
 392 Encodes a string from Perl's internal form into I<ENCODING> and returns
 393 a sequence of octets.  ENCODING can be either a canonical name or
 394 an alias.  For encoding names and aliases, see L</"Defining Aliases">.
 395 For CHECK, see L</"Handling Malformed Data">.
 396
 397 For example, to convert a string from Perl's internal format to
 398 iso-8859-1 (also known as Latin1),
 399
 400   $octets = encode("iso-8859-1", $string);
 401
 402 B<CAVEAT>: When you run C<$octets = encode("utf8", $string)>, then $octets
 403 B<may not be equal to> $string.  Though they both contain the same data, the utf8 flag
 404 for $octets is B<always> off.  When you encode anything, utf8 flag of
 405 the result is always off, even when it contains completely valid utf8
 406 string. See L</"The UTF-8 flag"> below.
 407
 408 If the $string is C<undef> then C<undef> is returned.
 409
 410 =item $string = decode(ENCODING, $octets [, CHECK])
 411
 412 Decodes a sequence of octets assumed to be in I<ENCODING> into Perl's
 413 internal form and returns the resulting string.  As in encode(),
 414 ENCODING can be either a canonical name or an alias. For encoding names
 415 and aliases, see L</"Defining Aliases">.  For CHECK, see
 416 L</"Handling Malformed Data">.
 417
 418 For example, to convert ISO-8859-1 data to a string in Perl's internal format:
 419
 420   $string = decode("iso-8859-1", $octets);
 421
 422 B<CAVEAT>: When you run C<$string = decode("utf8", $octets)>, then $string
 423 B<may not be equal to> $octets.  Though they both contain the same data,
 424 the utf8 flag for $string is on unless $octets entirely consists of
 425 ASCII data (or EBCDIC on EBCDIC machines).  See L</"The UTF-8 flag">
 426 below.
 427
 428 If the $string is C<undef> then C<undef> is returned.
 429
 430 =item [$length =] from_to($octets, FROM_ENC, TO_ENC [, CHECK])
 431
 432 Converts B<in-place> data between two encodings. The data in $octets
 433 must be encoded as octets and not as characters in Perl's internal
 434 format. For example, to convert ISO-8859-1 data to Microsoft's CP1250
 435 encoding:
 436
 437   from_to($octets, "iso-8859-1", "cp1250");
 438
 439 and to convert it back:
 440
 441   from_to($octets, "cp1250", "iso-8859-1");
 442
 443 Note that because the conversion happens in place, the data to be
 444 converted cannot be a string constant; it must be a scalar variable.
 445
 446 from_to() returns the length of the converted string in octets on
 447 success, I<undef> on error.
 448
 449 B<CAVEAT>: The following operations look the same but are not quite so;
 450
 451   from_to($data, "iso-8859-1", "utf8"); #1
 452   $data = decode("iso-8859-1", $data);  #2
 453
 454 Both #1 and #2 make $data consist of a completely valid UTF-8 string
 455 but only #2 turns utf8 flag on.  #1 is equivalent to
 456
 457   $data = encode("utf8", decode("iso-8859-1", $data));
 458
 459 See L</"The UTF-8 flag"> below.
 460
 461 =item $octets = encode_utf8($string);
 462
 463 Equivalent to C<$octets = encode("utf8", $string);> The characters
 464 that comprise $string are encoded in Perl's internal format and the
 465 result is returned as a sequence of octets. All possible
 466 characters have a UTF-8 representation so this function cannot fail.
 467
 468
 469 =item $string = decode_utf8($octets [, CHECK]);
 470
 471 equivalent to C<$string = decode("utf8", $octets [, CHECK])>.
 472 The sequence of octets represented by
 473 $octets is decoded from UTF-8 into a sequence of logical
 474 characters. Not all sequences of octets form valid UTF-8 encodings, so
 475 it is possible for this call to fail.  For CHECK, see
 476 L</"Handling Malformed Data">.
 477
 478 =back
 479
 480 =head2 Listing available encodings
 481
 482   use Encode;
 483   @list = Encode->encodings();
 484
 485 Returns a list of the canonical names of the available encodings that
 486 are loaded.  To get a list of all available encodings including the
 487 ones that are not loaded yet, say
 488
 489   @all_encodings = Encode->encodings(":all");
 490
 491 Or you can give the name of a specific module.
 492
 493   @with_jp = Encode->encodings("Encode::JP");
 494
 495 When "::" is not in the name, "Encode::" is assumed.
 496
 497   @ebcdic = Encode->encodings("EBCDIC");
 498
 499 To find out in detail which encodings are supported by this package,
 500 see L<Encode::Supported>.
 501
 502 =head2 Defining Aliases
 503
 504 To add a new alias to a given encoding, use:
 505
 506   use Encode;
 507   use Encode::Alias;
 508   define_alias(newName => ENCODING);
 509
 510 After that, newName can be used as an alias for ENCODING.
 511 ENCODING may be either the name of an encoding or an
 512 I<encoding object>
 513
 514 But before you do so, make sure the alias is nonexistent with
 515 C<resolve_alias()>, which returns the canonical name thereof.
 516 i.e.
 517
 518   Encode::resolve_alias("latin1") eq "iso-8859-1" # true
 519   Encode::resolve_alias("iso-8859-12")   # false; nonexistent
 520   Encode::resolve_alias($name) eq $name  # true if $name is canonical
 521
 522 resolve_alias() does not need C<use Encode::Alias>; it can be
 523 exported via C<use Encode qw(resolve_alias)>.
 524
 525 See L<Encode::Alias> for details.
 526
 527 =head1 Encoding via PerlIO
 528
 529 If your perl supports I<PerlIO> (which is the default), you can use a PerlIO layer to decode
 530 and encode directly via a filehandle.  The following two examples
 531 are totally identical in their functionality.
 532
 533   # via PerlIO
 534   open my $in,  "<:encoding(shiftjis)", $infile  or die;
 535   open my $out, ">:encoding(euc-jp)",   $outfile or die;
 536   while(<$in>){ print $out $_; }
 537
 538   # via from_to
 539   open my $in,  "<", $infile  or die;
 540   open my $out, ">", $outfile or die;
 541   while(<$in>){
 542     from_to($_, "shiftjis", "euc-jp", 1);
 543     print $out $_;
 544   }
 545
 546 Unfortunately, it may be that encodings are PerlIO-savvy.  You can check
 547 if your encoding is supported by PerlIO by calling the C<perlio_ok>
 548 method.
 549
 550   Encode::perlio_ok("hz");             # False
 551   find_encoding("euc-cn")->perlio_ok;  # True where PerlIO is available
 552
 553   use Encode qw(perlio_ok);            # exported upon request
 554   perlio_ok("euc-jp")
 555
 556 Fortunately, all encodings that come with Encode core are PerlIO-savvy
 557 except for hz and ISO-2022-kr.  For gory details, see
 558 L<Encode::Encoding> and L<Encode::PerlIO>.
 559
 560 =head1 Handling Malformed Data
 561
 562 The optional I<CHECK> argument tells Encode what to do when it
 563 encounters malformed data.  Without CHECK, Encode::FB_DEFAULT ( == 0 )
 564 is assumed.
 565
 566 As of version 2.12 Encode supports coderef values for CHECK.  See below.
 567
 568 =over 2
 569
 570 =item B<NOTE:> Not all encoding support this feature
 571
 572 Some encodings ignore I<CHECK> argument.  For example,
 573 L<Encode::Unicode> ignores I<CHECK> and it always croaks on error.
 574
 575 =back
 576
 577 Now here is the list of I<CHECK> values available
 578
 579 =over 2
 580
 581 =item I<CHECK> = Encode::FB_DEFAULT ( == 0)
 582
 583 If I<CHECK> is 0, (en|de)code will put a I<substitution character> in
 584 place of a malformed character.  When you encode, E<lt>subcharE<gt>
 585 will be used.  When you decode the code point C<0xFFFD> is used.  If
 586 the data is supposed to be UTF-8, an optional lexical warning
 587 (category utf8) is given.
 588
 589 =item I<CHECK> = Encode::FB_CROAK ( == 1)
 590
 591 If I<CHECK> is 1, methods will die on error immediately with an error
 592 message.  Therefore, when I<CHECK> is set to 1,  you should trap the
 593 error with eval{} unless you really want to let it die.
 594
 595 =item I<CHECK> = Encode::FB_QUIET
 596
 597 If I<CHECK> is set to Encode::FB_QUIET, (en|de)code will immediately
 598 return the portion of the data that has been processed so far when an
 599 error occurs. The data argument will be overwritten with everything
 600 after that point (that is, the unprocessed part of data).  This is
 601 handy when you have to call decode repeatedly in the case where your
 602 source data may contain partial multi-byte character sequences,
 603 (i.e. you are reading with a fixed-width buffer). Here is a sample
 604 code that does exactly this:
 605
 606   my $buffer = ''; my $string = '';
 607   while(read $fh, $buffer, 256, length($buffer)){
 608     $string .= decode($encoding, $buffer, Encode::FB_QUIET);
 609     # $buffer now contains the unprocessed partial character
 610   }
 611
 612 =item I<CHECK> = Encode::FB_WARN
 613
 614 This is the same as above, except that it warns on error.  Handy when
 615 you are debugging the mode above.
 616
 617 =item perlqq mode (I<CHECK> = Encode::FB_PERLQQ)
 618
 619 =item HTML charref mode (I<CHECK> = Encode::FB_HTMLCREF)
 620
 621 =item XML charref mode (I<CHECK> = Encode::FB_XMLCREF)
 622
 623 For encodings that are implemented by Encode::XS, CHECK ==
 624 Encode::FB_PERLQQ turns (en|de)code into C<perlqq> fallback mode.
 625
 626 When you decode, C<\xI<HH>> will be inserted for a malformed character,
 627 where I<HH> is the hex representation of the octet  that could not be
 628 decoded to utf8.  And when you encode, C<\x{I<HHHH>}> will be inserted,
 629 where I<HHHH> is the Unicode ID of the character that cannot be found
 630 in the character repertoire of the encoding.
 631
 632 HTML/XML character reference modes are about the same, in place of
 633 C<\x{I<HHHH>}>, HTML uses C<&#I<NNN>;> where I<NNN> is a decimal number and
 634 XML uses C<&#xI<HHHH>;> where I<HHHH> is the hexadecimal number.
 635
 636 In Encode 2.10 or later, C<LEAVE_SRC> is also implied.
 637
 638 =item The bitmask
 639
 640 These modes are actually set via a bitmask.  Here is how the FB_XX
 641 constants are laid out.  You can import the FB_XX constants via
 642 C<use Encode qw(:fallbacks)>; you can import the generic bitmask
 643 constants via C<use Encode qw(:fallback_all)>.
 644
 645                      FB_DEFAULT FB_CROAK FB_QUIET FB_WARN  FB_PERLQQ
 646  DIE_ON_ERR    0x0001             X
 647  WARN_ON_ERR   0x0002                               X
 648  RETURN_ON_ERR 0x0004                      X        X
 649  LEAVE_SRC     0x0008                                        X
 650  PERLQQ        0x0100                                        X
 651  HTMLCREF      0x0200
 652  XMLCREF       0x0400
 653
 654 =back
 655
 656 =head2 coderef for CHECK
 657
 658 As of Encode 2.12 CHECK can also be a code reference which takes the
 659 ord value of unmapped caharacter as an argument and returns a string
 660 that represents the fallback character.  For instance,
 661
 662   $ascii = encode("ascii", $utf8, sub{ sprintf "<U+%04X>", shift });
 663
 664 Acts like FB_PERLQQ but E<lt>U+I<XXXX>E<gt> is used instead of
 665 \x{I<XXXX>}.
 666
 667 =head1 Defining Encodings
 668
 669 To define a new encoding, use:
 670
 671     use Encode qw(define_encoding);
 672     define_encoding($object, 'canonicalName' [, alias...]);
 673
 674 I<canonicalName> will be associated with I<$object>.  The object
 675 should provide the interface described in L<Encode::Encoding>.
 676 If more than two arguments are provided then additional
 677 arguments are taken as aliases for I<$object>.
 678
 679 See L<Encode::Encoding> for more details.
 680
 681 =head1 The UTF-8 flag
 682
 683 Before the introduction of utf8 support in perl, The C<eq> operator
 684 just compared the strings represented by two scalars. Beginning with
 685 perl 5.8, C<eq> compares two strings with simultaneous consideration
 686 of I<the utf8 flag>. To explain why we made it so, I will quote page
 687 402 of C<Programming Perl, 3rd ed.>
 688
 689 =over 2
 690
 691 =item Goal #1:
 692
 693 Old byte-oriented programs should not spontaneously break on the old
 694 byte-oriented data they used to work on.
 695
 696 =item Goal #2:
 697
 698 Old byte-oriented programs should magically start working on the new
 699 character-oriented data when appropriate.
 700
 701 =item Goal #3:
 702
 703 Programs should run just as fast in the new character-oriented mode
 704 as in the old byte-oriented mode.
 705
 706 =item Goal #4:
 707
 708 Perl should remain one language, rather than forking into a
 709 byte-oriented Perl and a character-oriented Perl.
 710
 711 =back
 712
 713 Back when C<Programming Perl, 3rd ed.> was written, not even Perl 5.6.0
 714 was born and many features documented in the book remained
 715 unimplemented for a long time.  Perl 5.8 corrected this and the introduction
 716 of the UTF-8 flag is one of them.  You can think of this perl notion as of a
 717 byte-oriented mode (utf8 flag off) and a character-oriented mode (utf8
 718 flag on).
 719
 720 Here is how Encode takes care of the utf8 flag.
 721
 722 =over 2
 723
 724 =item *
 725
 726 When you encode, the resulting utf8 flag is always off.
 727
 728 =item *
 729
 730 When you decode, the resulting utf8 flag is on unless you can
 731 unambiguously represent data.  Here is the definition of
 732 dis-ambiguity.
 733
 734 After C<$utf8 = decode('foo', $octet);>,
 735
 736   When $octet is...   The utf8 flag in $utf8 is
 737   ---------------------------------------------
 738   In ASCII only (or EBCDIC only)            OFF
 739   In ISO-8859-1                              ON
 740   In any other Encoding                      ON
 741   ---------------------------------------------
 742
 743 As you see, there is one exception, In ASCII.  That way you can assume
 744 Goal #1.  And with Encode Goal #2 is assumed but you still have to be
 745 careful in such cases mentioned in B<CAVEAT> paragraphs.
 746
 747 This utf8 flag is not visible in perl scripts, exactly for the same
 748 reason you cannot (or you I<don't have to>) see if a scalar contains a
 749 string, integer, or floating point number.   But you can still peek
 750 and poke these if you will.  See the section below.
 751
 752 =back
 753
 754 =head2 Messing with Perl's Internals
 755
 756 The following API uses parts of Perl's internals in the current
 757 implementation.  As such, they are efficient but may change.
 758
 759 =over 2
 760
 761 =item is_utf8(STRING [, CHECK])
 762
 763 [INTERNAL] Tests whether the UTF-8 flag is turned on in the STRING.
 764 If CHECK is true, also checks the data in STRING for being well-formed
 765 UTF-8.  Returns true if successful, false otherwise.
 766
 767 As of perl 5.8.1, L<utf8> also has utf8::is_utf8().
 768
 769 =item _utf8_on(STRING)
 770
 771 [INTERNAL] Turns on the UTF-8 flag in STRING.  The data in STRING is
 772 B<not> checked for being well-formed UTF-8.  Do not use unless you
 773 B<know> that the STRING is well-formed UTF-8.  Returns the previous
 774 state of the UTF-8 flag (so please don't treat the return value as
 775 indicating success or failure), or C<undef> if STRING is not a string.
 776
 777 =item _utf8_off(STRING)
 778
 779 [INTERNAL] Turns off the UTF-8 flag in STRING.  Do not use frivolously.
 780 Returns the previous state of the UTF-8 flag (so please don't treat the
 781 return value as indicating success or failure), or C<undef> if STRING is
 782 not a string.
 783
 784 =back
 785
 786 =head1 UTF-8 vs. utf8
 787
 788   ....We now view strings not as sequences of bytes, but as sequences
 789   of numbers in the range 0 .. 2**32-1 (or in the case of 64-bit
 790   computers, 0 .. 2**64-1) -- Programming Perl, 3rd ed.
 791
 792 That has been the perl's notion of UTF-8 but official UTF-8 is more
 793 strict; Its ranges is much narrower (0 .. 10FFFF), some sequences are
 794 not allowed (i.e. Those used in the surrogate pair, 0xFFFE, et al).
 795
 796 Now that is overruled by Larry Wall himself.
 797
 798   From: Larry Wall <larry@wall.org>
 799   Date: December 04, 2004 11:51:58 JST
 800   To: perl-unicode@perl.org
 801   Subject: Re: Make Encode.pm support the real UTF-8
 802   Message-Id: <20041204025158.GA28754@wall.org>
 803
 804   On Fri, Dec 03, 2004 at 10:12:12PM +0000, Tim Bunce wrote:
 805   : I've no problem with 'utf8' being perl's unrestricted uft8 encoding,
 806   : but "UTF-8" is the name of the standard and should give the
 807   : corresponding behaviour.
 808
 809   For what it's worth, that's how I've always kept them straight in my
 810   head.
 811
 812   Also for what it's worth, Perl 6 will mostly default to strict but
 813   make it easy to switch back to lax.
 814
 815   Larry
 816
 817 Do you copy?  As of Perl 5.8.7, B<UTF-8> means strict, official UTF-8
 818 while B<utf8> means liberal, lax, version thereof.  And Encode version
 819 2.10 or later thus groks the difference between C<UTF-8> and C"utf8".
 820
 821   encode("utf8",  "\x{FFFF_FFFF}", 1); # okay
 822   encode("UTF-8", "\x{FFFF_FFFF}", 1); # croaks
 823
 824 C<UTF-8> in Encode is actually a canonical name for C<utf-8-strict>.
 825 Yes, the hyphen between "UTF" and "8" is important.  Without it Encode
 826 goes "liberal"
 827
 828   find_encoding("UTF-8")->name # is 'utf-8-strict'
 829   find_encoding("utf-8")->name # ditto. names are case insensitive
 830   find_encoding("utf_8")->name  # ditto. "_" are treated as "-"
 831   find_encoding("UTF8")->name  # is 'utf8'.
 832
 833
 834 =head1 SEE ALSO
 835
 836 L<Encode::Encoding>,
 837 L<Encode::Supported>,
 838 L<Encode::PerlIO>,
 839 L<encoding>,
 840 L<perlebcdic>,
 841 L<perlfunc/open>,
 842 L<perlunicode>,
 843 L<utf8>,
 844 the Perl Unicode Mailing List E<lt>perl-unicode@perl.orgE<gt>
 845
 846 =head1 MAINTAINER
 847
 848 This project was originated by Nick Ing-Simmons and later maintained
 849 by Dan Kogai E<lt>dankogai@dan.co.jpE<gt>.  See AUTHORS for a full
 850 list of people involved.  For any questions, use
 851 E<lt>perl-unicode@perl.orgE<gt> so we can all share.
 852
 853 =cut