ext/Encode/Encode.pm

   1 #
   2 # $Id: Encode.pm,v 1.84 2003/01/10 12:00:16 dankogai Exp dankogai $
   3 #
   4 package Encode;
   5 use strict;
   6 our $VERSION = do { my @r = (q$Revision: 1.84 $ =~ /\d+/g); sprintf "%d."."%02d" x $#r, @r };
   7 our $DEBUG = 0;
   8 use XSLoader ();
   9 XSLoader::load(__PACKAGE__, $VERSION);
  10
  11 require Exporter;
  12 use base qw/Exporter/;
  13
  14 # Public, encouraged API is exported by default
  15
  16 our @EXPORT = qw(
  17   decode  decode_utf8  encode  encode_utf8
  18   encodings  find_encoding
  19 );
  20
  21 our @FB_FLAGS  = qw(DIE_ON_ERR WARN_ON_ERR RETURN_ON_ERR LEAVE_SRC
  22                     PERLQQ HTMLCREF XMLCREF);
  23 our @FB_CONSTS = qw(FB_DEFAULT FB_CROAK FB_QUIET FB_WARN
  24                     FB_PERLQQ FB_HTMLCREF FB_XMLCREF);
  25
  26 our @EXPORT_OK =
  27     (
  28      qw(
  29        _utf8_off _utf8_on define_encoding from_to is_16bit is_8bit
  30        is_utf8 perlio_ok resolve_alias utf8_downgrade utf8_upgrade
  31       ),
  32      @FB_FLAGS, @FB_CONSTS,
  33     );
  34
  35 our %EXPORT_TAGS =
  36     (
  37      all          =>  [ @EXPORT, @EXPORT_OK ],
  38      fallbacks    =>  [ @FB_CONSTS ],
  39      fallback_all =>  [ @FB_CONSTS, @FB_FLAGS ],
  40     );
  41
  42 # Documentation moved after __END__ for speed - NI-S
  43
  44 our $ON_EBCDIC = (ord("A") == 193);
  45
  46 use Encode::Alias;
  47
  48 # Make a %Encoding package variable to allow a certain amount of cheating
  49 our %Encoding;
  50 our %ExtModule;
  51 require Encode::Config;
  52 eval { require Encode::ConfigLocal };
  53
  54 sub encodings
  55 {
  56     my $class = shift;
  57     my %enc;
  58     if (@_ and $_[0] eq ":all"){
  59         %enc = ( %Encoding, %ExtModule );
  60     }else{
  61         %enc = %Encoding;
  62         for my $mod (map {m/::/o ? $_ : "Encode::$_" } @_){
  63             $DEBUG and warn $mod;
  64             for my $enc (keys %ExtModule){
  65                 $ExtModule{$enc} eq $mod and $enc{$enc} = $mod;
  66             }
  67         }
  68     }
  69     return
  70         sort { lc $a cmp lc $b }
  71              grep {!/^(?:Internal|Unicode|Guess)$/o} keys %enc;
  72 }
  73
  74 sub perlio_ok{
  75     my $obj = ref($_[0]) ? $_[0] : find_encoding($_[0]);
  76     $obj->can("perlio_ok") and return $obj->perlio_ok();
  77     return 0; # safety net
  78 }
  79
  80 sub define_encoding
  81 {
  82     my $obj  = shift;
  83     my $name = shift;
  84     $Encoding{$name} = $obj;
  85     my $lc = lc($name);
  86     define_alias($lc => $obj) unless $lc eq $name;
  87     while (@_){
  88         my $alias = shift;
  89         define_alias($alias, $obj);
  90     }
  91     return $obj;
  92 }
  93
  94 sub getEncoding
  95 {
  96     my ($class, $name, $skip_external) = @_;
  97
  98     ref($name) && $name->can('new_sequence') and return $name;
  99     exists $Encoding{$name} and return $Encoding{$name};
 100     my $lc = lc $name;
 101     exists $Encoding{$lc} and return $Encoding{$lc};
 102
 103     my $oc = $class->find_alias($name);
 104     defined($oc) and return $oc;
 105     $lc ne $name and $oc = $class->find_alias($lc);
 106     defined($oc) and return $oc;
 107
 108     unless ($skip_external)
 109     {
 110         if (my $mod = $ExtModule{$name} || $ExtModule{$lc}){
 111             $mod =~ s,::,/,g ; $mod .= '.pm';
 112             eval{ require $mod; };
 113             exists $Encoding{$name} and return $Encoding{$name};
 114         }
 115     }
 116     return;
 117 }
 118
 119 sub find_encoding
 120 {
 121     my ($name, $skip_external) = @_;
 122     return __PACKAGE__->getEncoding($name,$skip_external);
 123 }
 124
 125 sub resolve_alias {
 126     my $obj = find_encoding(shift);
 127     defined $obj and return $obj->name;
 128     return;
 129 }
 130
 131 sub encode($$;$)
 132 {
 133     my ($name, $string, $check) = @_;
 134     return undef unless defined $string;
 135     $check ||=0;
 136     my $enc = find_encoding($name);
 137     unless(defined $enc){
 138         require Carp;
 139         Carp::croak("Unknown encoding '$name'");
 140     }
 141     my $octets = $enc->encode($string,$check);
 142     return undef if ($check && length($string));
 143     return $octets;
 144 }
 145
 146 sub decode($$;$)
 147 {
 148     my ($name,$octets,$check) = @_;
 149     return undef unless defined $octets;
 150     $check ||=0;
 151     my $enc = find_encoding($name);
 152     unless(defined $enc){
 153         require Carp;
 154         Carp::croak("Unknown encoding '$name'");
 155     }
 156     my $string = $enc->decode($octets,$check);
 157     $_[1] = $octets if $check;
 158     return $string;
 159 }
 160
 161 sub from_to($$$;$)
 162 {
 163     my ($string,$from,$to,$check) = @_;
 164     return undef unless defined $string;
 165     $check ||=0;
 166     my $f = find_encoding($from);
 167     unless (defined $f){
 168         require Carp;
 169         Carp::croak("Unknown encoding '$from'");
 170     }
 171     my $t = find_encoding($to);
 172     unless (defined $t){
 173         require Carp;
 174         Carp::croak("Unknown encoding '$to'");
 175     }
 176     my $uni = $f->decode($string,$check);
 177     return undef if ($check && length($string));
 178     $string =  $t->encode($uni,$check);
 179     return undef if ($check && length($uni));
 180     return defined($_[0] = $string) ? length($string) : undef ;
 181 }
 182
 183 sub encode_utf8($)
 184 {
 185     my ($str) = @_;
 186     utf8::encode($str);
 187     return $str;
 188 }
 189
 190 sub decode_utf8($)
 191 {
 192     my ($str) = @_;
 193     return undef unless utf8::decode($str);
 194     return $str;
 195 }
 196
 197 predefine_encodings(1);
 198
 199 #
 200 # This is to restore %Encoding if really needed;
 201 #
 202
 203 sub predefine_encodings{
 204     use Encode::Encoding;
 205     no warnings 'redefine';
 206     my $use_xs = shift;
 207     if ($ON_EBCDIC) {
 208         # was in Encode::UTF_EBCDIC
 209         package Encode::UTF_EBCDIC;
 210         push @Encode::UTF_EBCDIC::ISA, 'Encode::Encoding';
 211         *decode = sub{
 212             my ($obj,$str,$chk) = @_;
 213             my $res = '';
 214             for (my $i = 0; $i < length($str); $i++) {
 215                 $res .=
 216                     chr(utf8::unicode_to_native(ord(substr($str,$i,1))));
 217             }
 218             $_[1] = '' if $chk;
 219             return $res;
 220         };
 221         *encode = sub{
 222             my ($obj,$str,$chk) = @_;
 223             my $res = '';
 224             for (my $i = 0; $i < length($str); $i++) {
 225                 $res .=
 226                     chr(utf8::native_to_unicode(ord(substr($str,$i,1))));
 227             }
 228             $_[1] = '' if $chk;
 229             return $res;
 230         };
 231         $Encode::Encoding{Unicode} =
 232             bless {Name => "UTF_EBCDIC"} => "Encode::UTF_EBCDIC";
 233     } else {
 234         package Encode::Internal;
 235         push @Encode::Internal::ISA, 'Encode::Encoding';
 236         *decode = sub{
 237             my ($obj,$str,$chk) = @_;
 238             utf8::upgrade($str);
 239             $_[1] = '' if $chk;
 240             return $str;
 241         };
 242         *encode = \&decode;
 243         $Encode::Encoding{Unicode} =
 244             bless {Name => "Internal"} => "Encode::Internal";
 245     }
 246
 247     {
 248         # was in Encode::utf8
 249         package Encode::utf8;
 250         push @Encode::utf8::ISA, 'Encode::Encoding';
 251         #
 252         if ($use_xs){
 253             $DEBUG and warn __PACKAGE__, " XS on";
 254             *decode = \&decode_xs;
 255             *encode = \&encode_xs;
 256         }else{
 257             $DEBUG and warn __PACKAGE__, " XS off";
 258             *decode = sub{
 259                 my ($obj,$octets,$chk) = @_;
 260                 my $str = Encode::decode_utf8($octets);
 261                 if (defined $str) {
 262                     $_[1] = '' if $chk;
 263                     return $str;
 264                 }
 265                 return undef;
 266             };
 267             *encode = sub {
 268                 my ($obj,$string,$chk) = @_;
 269                 my $octets = Encode::encode_utf8($string);
 270                 $_[1] = '' if $chk;
 271                 return $octets;
 272             };
 273         }
 274         $Encode::Encoding{utf8} =
 275             bless {Name => "utf8"} => "Encode::utf8";
 276     }
 277 }
 278
 279 1;
 280
 281 __END__
 282
 283 =head1 NAME
 284
 285 Encode - character encodings
 286
 287 =head1 SYNOPSIS
 288
 289     use Encode;
 290
 291 =head2 Table of Contents
 292
 293 Encode consists of a collection of modules whose details are too big
 294 to fit in one document.  This POD itself explains the top-level APIs
 295 and general topics at a glance.  For other topics and more details,
 296 see the PODs below:
 297
 298   Name                          Description
 299   --------------------------------------------------------
 300   Encode::Alias         Alias definitions to encodings
 301   Encode::Encoding      Encode Implementation Base Class
 302   Encode::Supported     List of Supported Encodings
 303   Encode::CN            Simplified Chinese Encodings
 304   Encode::JP            Japanese Encodings
 305   Encode::KR            Korean Encodings
 306   Encode::TW            Traditional Chinese Encodings
 307   --------------------------------------------------------
 308
 309 =head1 DESCRIPTION
 310
 311 The C<Encode> module provides the interfaces between Perl's strings
 312 and the rest of the system.  Perl strings are sequences of
 313 B<characters>.
 314
 315 The repertoire of characters that Perl can represent is at least that
 316 defined by the Unicode Consortium. On most platforms the ordinal
 317 values of the characters (as returned by C<ord(ch)>) is the "Unicode
 318 codepoint" for the character (the exceptions are those platforms where
 319 the legacy encoding is some variant of EBCDIC rather than a super-set
 320 of ASCII - see L<perlebcdic>).
 321
 322 Traditionally, computer data has been moved around in 8-bit chunks
 323 often called "bytes". These chunks are also known as "octets" in
 324 networking standards. Perl is widely used to manipulate data of many
 325 types - not only strings of characters representing human or computer
 326 languages but also "binary" data being the machine's representation of
 327 numbers, pixels in an image - or just about anything.
 328
 329 When Perl is processing "binary data", the programmer wants Perl to
 330 process "sequences of bytes". This is not a problem for Perl - as a
 331 byte has 256 possible values, it easily fits in Perl's much larger
 332 "logical character".
 333
 334 =head2 TERMINOLOGY
 335
 336 =over 2
 337
 338 =item *
 339
 340 I<character>: a character in the range 0..(2**32-1) (or more).
 341 (What Perl's strings are made of.)
 342
 343 =item *
 344
 345 I<byte>: a character in the range 0..255
 346 (A special case of a Perl character.)
 347
 348 =item *
 349
 350 I<octet>: 8 bits of data, with ordinal values 0..255
 351 (Term for bytes passed to or from a non-Perl context, e.g. a disk file.)
 352
 353 =back
 354
 355 =head1 PERL ENCODING API
 356
 357 =over 2
 358
 359 =item $octets  = encode(ENCODING, $string [, CHECK])
 360
 361 Encodes a string from Perl's internal form into I<ENCODING> and returns
 362 a sequence of octets.  ENCODING can be either a canonical name or
 363 an alias.  For encoding names and aliases, see L</"Defining Aliases">.
 364 For CHECK, see L</"Handling Malformed Data">.
 365
 366 For example, to convert a string from Perl's internal format to
 367 iso-8859-1 (also known as Latin1),
 368
 369   $octets = encode("iso-8859-1", $string);
 370
 371 B<CAVEAT>: When you run C<$octets = encode("utf8", $string)>, then $octets
 372 B<may not be equal to> $string.  Though they both contain the same data, the utf8 flag
 373 for $octets is B<always> off.  When you encode anything, utf8 flag of
 374 the result is always off, even when it contains completely valid utf8
 375 string. See L</"The UTF-8 flag"> below.
 376
 377 encode($valid_encoding, undef) is harmless but warns you for
 378 C<Use of uninitialized value in subroutine entry>.
 379 encode($valid_encoding, '') is harmless and warnless.
 380
 381 =item $string = decode(ENCODING, $octets [, CHECK])
 382
 383 Decodes a sequence of octets assumed to be in I<ENCODING> into Perl's
 384 internal form and returns the resulting string.  As in encode(),
 385 ENCODING can be either a canonical name or an alias. For encoding names
 386 and aliases, see L</"Defining Aliases">.  For CHECK, see
 387 L</"Handling Malformed Data">.
 388
 389 For example, to convert ISO-8859-1 data to a string in Perl's internal format:
 390
 391   $string = decode("iso-8859-1", $octets);
 392
 393 B<CAVEAT>: When you run C<$string = decode("utf8", $octets)>, then $string
 394 B<may not be equal to> $octets.  Though they both contain the same data,
 395 the utf8 flag for $string is on unless $octets entirely consists of
 396 ASCII data (or EBCDIC on EBCDIC machines).  See L</"The UTF-8 flag">
 397 below.
 398
 399 decode($valid_encoding, undef) is harmless but warns you for
 400 C<Use of uninitialized value in subroutine entry>.
 401 decode($valid_encoding, '') is harmless and warnless.
 402
 403 =item [$length =] from_to($octets, FROM_ENC, TO_ENC [, CHECK])
 404
 405 Converts B<in-place> data between two encodings. The data in $octets
 406 must be encoded as octets and not as characters in Perl's internal
 407 format. For example, to convert ISO-8859-1 data to Microsoft's CP1250 encoding:
 408
 409   from_to($octets, "iso-8859-1", "cp1250");
 410
 411 and to convert it back:
 412
 413   from_to($octets, "cp1250", "iso-8859-1");
 414
 415 Note that because the conversion happens in place, the data to be
 416 converted cannot be a string constant; it must be a scalar variable.
 417
 418 from_to() returns the length of the converted string in octets on success, undef
 419 otherwise.
 420
 421 B<CAVEAT>: The following operations look the same but are not quite so;
 422
 423   from_to($data, "iso-8859-1", "utf8"); #1
 424   $data = decode("iso-8859-1", $data);  #2
 425
 426 Both #1 and #2 make $data consist of a completely valid UTF-8 string
 427 but only #2 turns utf8 flag on.  #1 is equivalent to
 428
 429   $data = encode("utf8", decode("iso-8859-1", $data));
 430
 431 See L</"The UTF-8 flag"> below.
 432
 433 =item $octets = encode_utf8($string);
 434
 435 Equivalent to C<$octets = encode("utf8", $string);> The characters
 436 that comprise $string are encoded in Perl's internal format and the
 437 result is returned as a sequence of octets. All possible
 438 characters have a UTF-8 representation so this function cannot fail.
 439
 440
 441 =item $string = decode_utf8($octets [, CHECK]);
 442
 443 equivalent to C<$string = decode("utf8", $octets [, CHECK])>.
 444 The sequence of octets represented by
 445 $octets is decoded from UTF-8 into a sequence of logical
 446 characters. Not all sequences of octets form valid UTF-8 encodings, so
 447 it is possible for this call to fail.  For CHECK, see
 448 L</"Handling Malformed Data">.
 449
 450 =back
 451
 452 =head2 Listing available encodings
 453
 454   use Encode;
 455   @list = Encode->encodings();
 456
 457 Returns a list of the canonical names of the available encodings that
 458 are loaded.  To get a list of all available encodings including the
 459 ones that are not loaded yet, say
 460
 461   @all_encodings = Encode->encodings(":all");
 462
 463 Or you can give the name of a specific module.
 464
 465   @with_jp = Encode->encodings("Encode::JP");
 466
 467 When "::" is not in the name, "Encode::" is assumed.
 468
 469   @ebcdic = Encode->encodings("EBCDIC");
 470
 471 To find out in detail which encodings are supported by this package,
 472 see L<Encode::Supported>.
 473
 474 =head2 Defining Aliases
 475
 476 To add a new alias to a given encoding, use:
 477
 478   use Encode;
 479   use Encode::Alias;
 480   define_alias(newName => ENCODING);
 481
 482 After that, newName can be used as an alias for ENCODING.
 483 ENCODING may be either the name of an encoding or an
 484 I<encoding object>
 485
 486 But before you do so, make sure the alias is nonexistent with
 487 C<resolve_alias()>, which returns the canonical name thereof.
 488 i.e.
 489
 490   Encode::resolve_alias("latin1") eq "iso-8859-1" # true
 491   Encode::resolve_alias("iso-8859-12")   # false; nonexistent
 492   Encode::resolve_alias($name) eq $name  # true if $name is canonical
 493
 494 resolve_alias() does not need C<use Encode::Alias>; it can be
 495 exported via C<use Encode qw(resolve_alias)>.
 496
 497 See L<Encode::Alias> for details.
 498
 499 =head1 Encoding via PerlIO
 500
 501 If your perl supports I<PerlIO> (which is the default), you can use a PerlIO layer to decode
 502 and encode directly via a filehandle.  The following two examples
 503 are totally identical in their functionality.
 504
 505   # via PerlIO
 506   open my $in,  "<:encoding(shiftjis)", $infile  or die;
 507   open my $out, ">:encoding(euc-jp)",   $outfile or die;
 508   while(<$in>){ print $out $_; }
 509
 510   # via from_to
 511   open my $in,  "<", $infile  or die;
 512   open my $out, ">", $outfile or die;
 513   while(<$in>){
 514     from_to($_, "shiftjis", "euc-jp", 1);
 515     print $out $_;
 516   }
 517
 518 Unfortunately, it may be that encodings are PerlIO-savvy.  You can check
 519 if your encoding is supported by PerlIO by calling the C<perlio_ok>
 520 method.
 521
 522   Encode::perlio_ok("hz");             # False
 523   find_encoding("euc-cn")->perlio_ok;  # True where PerlIO is available
 524
 525   use Encode qw(perlio_ok);            # exported upon request
 526   perlio_ok("euc-jp")
 527
 528 Fortunately, all encodings that come with Encode core are PerlIO-savvy
 529 except for hz and ISO-2022-kr.  For gory details, see L<Encode::Encoding> and L<Encode::PerlIO>.
 530
 531 =head1 Handling Malformed Data
 532
 533 =over 2
 534
 535 The I<CHECK> argument is used as follows.  When you omit it,
 536 the behaviour is the same as if you had passed a value of 0 for
 537 I<CHECK>.
 538
 539 =item I<CHECK> = Encode::FB_DEFAULT ( == 0)
 540
 541 If I<CHECK> is 0, (en|de)code will put a I<substitution character>
 542 in place of a malformed character.  For UCM-based encodings,
 543 E<lt>subcharE<gt> will be used.  For Unicode, the code point C<0xFFFD> is used.
 544 If the data is supposed to be UTF-8, an optional lexical warning
 545 (category utf8) is given.
 546
 547 =item I<CHECK> = Encode::FB_CROAK ( == 1)
 548
 549 If I<CHECK> is 1, methods will die on error immediately with an error
 550 message.  Therefore, when I<CHECK> is set to 1,  you should trap the
 551 fatal error with eval{} unless you really want to let it die on error.
 552
 553 =item I<CHECK> = Encode::FB_QUIET
 554
 555 If I<CHECK> is set to Encode::FB_QUIET, (en|de)code will immediately
 556 return the portion of the data that has been processed so far when
 557 an error occurs. The data argument will be overwritten with
 558 everything after that point (that is, the unprocessed part of data).
 559 This is handy when you have to call decode repeatedly in the case
 560 where your source data may contain partial multi-byte character
 561 sequences, for example because you are reading with a fixed-width
 562 buffer. Here is some sample code that does exactly this:
 563
 564   my $data = ''; my $utf8 = '';
 565   while(defined(read $fh, $buffer, 256)){
 566     # buffer may end in a partial character so we append
 567     $data .= $buffer;
 568     $utf8 .= decode($encoding, $data, Encode::FB_QUIET);
 569     # $data now contains the unprocessed partial character
 570   }
 571
 572 =item I<CHECK> = Encode::FB_WARN
 573
 574 This is the same as above, except that it warns on error.  Handy when
 575 you are debugging the mode above.
 576
 577 =item perlqq mode (I<CHECK> = Encode::FB_PERLQQ)
 578
 579 =item HTML charref mode (I<CHECK> = Encode::FB_HTMLCREF)
 580
 581 =item XML charref mode (I<CHECK> = Encode::FB_XMLCREF)
 582
 583 For encodings that are implemented by Encode::XS, CHECK ==
 584 Encode::FB_PERLQQ turns (en|de)code into C<perlqq> fallback mode.
 585
 586 When you decode, C<\xI<HH>> will be inserted for a malformed character,
 587 where I<HH> is the hex representation of the octet  that could not be
 588 decoded to utf8.  And when you encode, C<\x{I<HHHH>}> will be inserted,
 589 where I<HHHH> is the Unicode ID of the character that cannot be found
 590 in the character repertoire of the encoding.
 591
 592 HTML/XML character reference modes are about the same, in place of
 593 C<\x{I<HHHH>}>, HTML uses C<&#I<NNNN>>; where I<NNNN> is a decimal digit and
 594 XML uses C<&#xI<HHHH>>; where I<HHHH> is the hexadecimal digit.
 595
 596 =item The bitmask
 597
 598 These modes are actually set via a bitmask.  Here is how the FB_XX
 599 constants are laid out.  You can import the FB_XX constants via
 600 C<use Encode qw(:fallbacks)>; you can import the generic bitmask
 601 constants via C<use Encode qw(:fallback_all)>.
 602
 603                      FB_DEFAULT FB_CROAK FB_QUIET FB_WARN  FB_PERLQQ
 604  DIE_ON_ERR    0x0001             X
 605  WARN_ON_ERR   0x0002                               X
 606  RETURN_ON_ERR 0x0004                      X        X
 607  LEAVE_SRC     0x0008
 608  PERLQQ        0x0100                                        X
 609  HTMLCREF      0x0200
 610  XMLCREF       0x0400
 611
 612 =head2 Unimplemented fallback schemes
 613
 614 In the future, you will be able to use a code reference to a callback
 615 function for the value of I<CHECK> but its API is still undecided.
 616
 617 The fallback scheme does not work on EBCDIC platforms.
 618
 619 =head1 Defining Encodings
 620
 621 To define a new encoding, use:
 622
 623     use Encode qw(define_encoding);
 624     define_encoding($object, 'canonicalName' [, alias...]);
 625
 626 I<canonicalName> will be associated with I<$object>.  The object
 627 should provide the interface described in L<Encode::Encoding>.
 628 If more than two arguments are provided then additional
 629 arguments are taken as aliases for I<$object>.
 630
 631 See L<Encode::Encoding> for more details.
 632
 633 =head1 The UTF-8 flag
 634
 635 Before the introduction of utf8 support in perl, The C<eq> operator
 636 just compared the strings represented by two scalars. Beginning with
 637 perl 5.8, C<eq> compares two strings with simultaneous consideration
 638 of I<the utf8 flag>. To explain why we made it so, I will quote page
 639 402 of C<Programming Perl, 3rd ed.>
 640
 641 =over 2
 642
 643 =item Goal #1:
 644
 645 Old byte-oriented programs should not spontaneously break on the old
 646 byte-oriented data they used to work on.
 647
 648 =item Goal #2:
 649
 650 Old byte-oriented programs should magically start working on the new
 651 character-oriented data when appropriate.
 652
 653 =item Goal #3:
 654
 655 Programs should run just as fast in the new character-oriented mode
 656 as in the old byte-oriented mode.
 657
 658 =item Goal #4:
 659
 660 Perl should remain one language, rather than forking into a
 661 byte-oriented Perl and a character-oriented Perl.
 662
 663 =back
 664
 665 Back when C<Programming Perl, 3rd ed.> was written, not even Perl 5.6.0
 666 was born and many features documented in the book remained
 667 unimplemented for a long time.  Perl 5.8 corrected this and the introduction
 668 of the UTF-8 flag is one of them.  You can think of this perl notion as of a
 669 byte-oriented mode (utf8 flag off) and a character-oriented mode (utf8
 670 flag on).
 671
 672 Here is how Encode takes care of the utf8 flag.
 673
 674 =over 2
 675
 676 =item *
 677
 678 When you encode, the resulting utf8 flag is always off.
 679
 680 =item
 681
 682 When you decode, the resulting utf8 flag is on unless you can
 683 unambiguously represent data.  Here is the definition of
 684 dis-ambiguity.
 685
 686 After C<$utf8 = decode('foo', $octet);>,
 687
 688   When $octet is...   The utf8 flag in $utf8 is
 689   ---------------------------------------------
 690   In ASCII only (or EBCDIC only)            OFF
 691   In ISO-8859-1                              ON
 692   In any other Encoding                      ON
 693   ---------------------------------------------
 694
 695 As you see, there is one exception, In ASCII.  That way you can assue
 696 Goal #1.  And with Encode Goal #2 is assumed but you still have to be
 697 careful in such cases mentioned in B<CAVEAT> paragraphs.
 698
 699 This utf8 flag is not visible in perl scripts, exactly for the same
 700 reason you cannot (or you I<don't have to>) see if a scalar contains a
 701 string, integer, or floating point number.   But you can still peek
 702 and poke these if you will.  See the section below.
 703
 704 =back
 705
 706 =head2 Messing with Perl's Internals
 707
 708 The following API uses parts of Perl's internals in the current
 709 implementation.  As such, they are efficient but may change.
 710
 711 =over 2
 712
 713 =item is_utf8(STRING [, CHECK])
 714
 715 [INTERNAL] Tests whether the UTF-8 flag is turned on in the STRING.
 716 If CHECK is true, also checks the data in STRING for being well-formed
 717 UTF-8.  Returns true if successful, false otherwise.
 718
 719 =item _utf8_on(STRING)
 720
 721 [INTERNAL] Turns on the UTF-8 flag in STRING.  The data in STRING is
 722 B<not> checked for being well-formed UTF-8.  Do not use unless you
 723 B<know> that the STRING is well-formed UTF-8.  Returns the previous
 724 state of the UTF-8 flag (so please don't treat the return value as
 725 indicating success or failure), or C<undef> if STRING is not a string.
 726
 727 =item _utf8_off(STRING)
 728
 729 [INTERNAL] Turns off the UTF-8 flag in STRING.  Do not use frivolously.
 730 Returns the previous state of the UTF-8 flag (so please don't treat the
 731 return value as indicating success or failure), or C<undef> if STRING is
 732 not a string.
 733
 734 =back
 735
 736 =head1 SEE ALSO
 737
 738 L<Encode::Encoding>,
 739 L<Encode::Supported>,
 740 L<Encode::PerlIO>,
 741 L<encoding>,
 742 L<perlebcdic>,
 743 L<perlfunc/open>,
 744 L<perlunicode>,
 745 L<utf8>,
 746 the Perl Unicode Mailing List E<lt>perl-unicode@perl.orgE<gt>
 747
 748 =head1 MAINTAINER
 749
 750 This project was originated by Nick Ing-Simmons and later maintained
 751 by Dan Kogai E<lt>dankogai@dan.co.jpE<gt>.  See AUTHORS for a full
 752 list of people involved.  For any questions, use
 753 E<lt>perl-unicode@perl.orgE<gt> so we can all share.
 754
 755 =cut