ext/Encode/Encode.pm

   1 #
   2 # $Id: Encode.pm,v 1.65 2002/04/30 16:13:37 dankogai Exp dankogai $
   3 #
   4 package Encode;
   5 use strict;
   6 our $VERSION = do { my @r = (q$Revision: 1.65 $ =~ /\d+/g); sprintf "%d."."%02d" x $#r, @r };
   7 our $DEBUG = 0;
   8 use XSLoader ();
   9 XSLoader::load(__PACKAGE__, $VERSION);
  10
  11 require Exporter;
  12 use base qw/Exporter/;
  13
  14 # Public, encouraged API is exported by default
  15
  16 our @EXPORT = qw(
  17   decode  decode_utf8  encode  encode_utf8
  18   encodings  find_encoding
  19 );
  20
  21 our @FB_FLAGS  = qw(DIE_ON_ERR WARN_ON_ERR RETURN_ON_ERR LEAVE_SRC
  22                     PERLQQ HTMLCREF XMLCREF);
  23 our @FB_CONSTS = qw(FB_DEFAULT FB_CROAK FB_QUIET FB_WARN
  24                     FB_PERLQQ FB_HTMLCREF FB_XMLCREF);
  25
  26 our @EXPORT_OK =
  27     (
  28      qw(
  29        _utf8_off _utf8_on define_encoding from_to is_16bit is_8bit
  30        is_utf8 perlio_ok resolve_alias utf8_downgrade utf8_upgrade
  31       ),
  32      @FB_FLAGS, @FB_CONSTS,
  33     );
  34
  35 our %EXPORT_TAGS =
  36     (
  37      all          =>  [ @EXPORT, @EXPORT_OK ],
  38      fallbacks    =>  [ @FB_CONSTS ],
  39      fallback_all =>  [ @FB_CONSTS, @FB_FLAGS ],
  40     );
  41
  42 # Documentation moved after __END__ for speed - NI-S
  43
  44 our $ON_EBCDIC = (ord("A") == 193);
  45
  46 use Encode::Alias;
  47
  48 # Make a %Encoding package variable to allow a certain amount of cheating
  49 our %Encoding;
  50 our %ExtModule;
  51 require Encode::Config;
  52 eval { require Encode::ConfigLocal };
  53
  54 sub encodings
  55 {
  56     my $class = shift;
  57     my %enc;
  58     if (@_ and $_[0] eq ":all"){
  59         %enc = ( %Encoding, %ExtModule );
  60     }else{
  61         %enc = %Encoding;
  62         for my $mod (map {m/::/o ? $_ : "Encode::$_" } @_){
  63             $DEBUG and warn $mod;
  64             for my $enc (keys %ExtModule){
  65                 $ExtModule{$enc} eq $mod and $enc{$enc} = $mod;
  66             }
  67         }
  68     }
  69     return
  70         sort { lc $a cmp lc $b }
  71              grep {!/^(?:Internal|Unicode|Guess)$/o} keys %enc;
  72 }
  73
  74 sub perlio_ok{
  75     my $obj = ref($_[0]) ? $_[0] : find_encoding($_[0]);
  76     $obj->can("perlio_ok") and return $obj->perlio_ok();
  77     return 0; # safety net
  78 }
  79
  80 sub define_encoding
  81 {
  82     my $obj  = shift;
  83     my $name = shift;
  84     $Encoding{$name} = $obj;
  85     my $lc = lc($name);
  86     define_alias($lc => $obj) unless $lc eq $name;
  87     while (@_){
  88         my $alias = shift;
  89         define_alias($alias, $obj);
  90     }
  91     return $obj;
  92 }
  93
  94 sub getEncoding
  95 {
  96     my ($class, $name, $skip_external) = @_;
  97
  98     ref($name) && $name->can('new_sequence') and return $name;
  99     exists $Encoding{$name} and return $Encoding{$name};
 100     my $lc = lc $name;
 101     exists $Encoding{$lc} and return $Encoding{$lc};
 102
 103     my $oc = $class->find_alias($name);
 104     defined($oc) and return $oc;
 105     $lc ne $name and $oc = $class->find_alias($lc);
 106     defined($oc) and return $oc;
 107
 108     unless ($skip_external)
 109     {
 110         if (my $mod = $ExtModule{$name} || $ExtModule{$lc}){
 111             $mod =~ s,::,/,g ; $mod .= '.pm';
 112             eval{ require $mod; };
 113             exists $Encoding{$name} and return $Encoding{$name};
 114         }
 115     }
 116     return;
 117 }
 118
 119 sub find_encoding
 120 {
 121     my ($name, $skip_external) = @_;
 122     return __PACKAGE__->getEncoding($name,$skip_external);
 123 }
 124
 125 sub resolve_alias {
 126     my $obj = find_encoding(shift);
 127     defined $obj and return $obj->name;
 128     return;
 129 }
 130
 131 sub encode($$;$)
 132 {
 133     my ($name, $string, $check) = @_;
 134     defined $string or return;
 135     $check ||=0;
 136     my $enc = find_encoding($name);
 137     unless(defined $enc){
 138         require Carp;
 139         Carp::croak("Unknown encoding '$name'");
 140     }
 141     my $octets = $enc->encode($string,$check);
 142     return undef if ($check && length($string));
 143     return $octets;
 144 }
 145
 146 sub decode($$;$)
 147 {
 148     my ($name,$octets,$check) = @_;
 149     defined $octets or return;
 150     $check ||=0;
 151     my $enc = find_encoding($name);
 152     unless(defined $enc){
 153         require Carp;
 154         Carp::croak("Unknown encoding '$name'");
 155     }
 156     my $string = $enc->decode($octets,$check);
 157     $_[1] = $octets if $check;
 158     return $string;
 159 }
 160
 161 sub from_to($$$;$)
 162 {
 163     my ($string,$from,$to,$check) = @_;
 164     defined $string or return;
 165     $check ||=0;
 166     my $f = find_encoding($from);
 167     unless (defined $f){
 168         require Carp;
 169         Carp::croak("Unknown encoding '$from'");
 170     }
 171     my $t = find_encoding($to);
 172     unless (defined $t){
 173         require Carp;
 174         Carp::croak("Unknown encoding '$to'");
 175     }
 176     my $uni = $f->decode($string,$check);
 177     return undef if ($check && length($string));
 178     $string =  $t->encode($uni,$check);
 179     return undef if ($check && length($uni));
 180     return defined($_[0] = $string) ? length($string) : undef ;
 181 }
 182
 183 sub encode_utf8($)
 184 {
 185     my ($str) = @_;
 186     defined $str or return;
 187     utf8::encode($str);
 188     return $str;
 189 }
 190
 191 sub decode_utf8($)
 192 {
 193     my ($str) = @_;
 194     defined $str or return;
 195     return undef unless utf8::decode($str);
 196     return $str;
 197 }
 198
 199 predefine_encodings();
 200
 201 #
 202 # This is to restore %Encoding if really needed;
 203 #
 204
 205 sub predefine_encodings{
 206     use Encode::Encoding;
 207     if ($ON_EBCDIC) {
 208         # was in Encode::UTF_EBCDIC
 209         package Encode::UTF_EBCDIC;
 210         push @Encode::UTF_EBCDIC::ISA, 'Encode::Encoding';
 211         *decode = sub{
 212             my ($obj,$str,$chk) = @_;
 213             my $res = '';
 214             for (my $i = 0; $i < length($str); $i++) {
 215                 $res .=
 216                     chr(utf8::unicode_to_native(ord(substr($str,$i,1))));
 217             }
 218             $_[1] = '' if $chk;
 219             return $res;
 220         };
 221         *encode = sub{
 222             my ($obj,$str,$chk) = @_;
 223             my $res = '';
 224             for (my $i = 0; $i < length($str); $i++) {
 225                 $res .=
 226                     chr(utf8::native_to_unicode(ord(substr($str,$i,1))));
 227             }
 228             $_[1] = '' if $chk;
 229             return $res;
 230         };
 231         $Encode::Encoding{Unicode} =
 232             bless {Name => "UTF_EBCDIC"} => "Encode::UTF_EBCDIC";
 233     } else {
 234         package Encode::Internal;
 235         push @Encode::Internal::ISA, 'Encode::Encoding';
 236         *decode = sub{
 237             my ($obj,$str,$chk) = @_;
 238             utf8::upgrade($str);
 239             $_[1] = '' if $chk;
 240             return $str;
 241         };
 242         *encode = \&decode;
 243         $Encode::Encoding{Unicode} =
 244             bless {Name => "Internal"} => "Encode::Internal";
 245     }
 246
 247     {
 248         # was in Encode::utf8
 249         package Encode::utf8;
 250         push @Encode::utf8::ISA, 'Encode::Encoding';
 251         *decode = sub{
 252             my ($obj,$octets,$chk) = @_;
 253             my $str = Encode::decode_utf8($octets);
 254             if (defined $str) {
 255                 $_[1] = '' if $chk;
 256                 return $str;
 257             }
 258             return undef;
 259         };
 260         *encode = sub {
 261             my ($obj,$string,$chk) = @_;
 262             my $octets = Encode::encode_utf8($string);
 263             $_[1] = '' if $chk;
 264             return $octets;
 265         };
 266         $Encode::Encoding{utf8} =
 267             bless {Name => "utf8"} => "Encode::utf8";
 268     }
 269 }
 270
 271 1;
 272
 273 __END__
 274
 275 =head1 NAME
 276
 277 Encode - character encodings
 278
 279 =head1 SYNOPSIS
 280
 281     use Encode;
 282
 283 =head2 Table of Contents
 284
 285 Encode consists of a collection of modules whose details are too big
 286 to fit in one document.  This POD itself explains the top-level APIs
 287 and general topics at a glance.  For other topics and more details,
 288 see the PODs below:
 289
 290   Name                          Description
 291   --------------------------------------------------------
 292   Encode::Alias         Alias definitions to encodings
 293   Encode::Encoding      Encode Implementation Base Class
 294   Encode::Supported     List of Supported Encodings
 295   Encode::CN            Simplified Chinese Encodings
 296   Encode::JP            Japanese Encodings
 297   Encode::KR            Korean Encodings
 298   Encode::TW            Traditional Chinese Encodings
 299   --------------------------------------------------------
 300
 301 =head1 DESCRIPTION
 302
 303 The C<Encode> module provides the interfaces between Perl's strings
 304 and the rest of the system.  Perl strings are sequences of
 305 B<characters>.
 306
 307 The repertoire of characters that Perl can represent is at least that
 308 defined by the Unicode Consortium. On most platforms the ordinal
 309 values of the characters (as returned by C<ord(ch)>) is the "Unicode
 310 codepoint" for the character (the exceptions are those platforms where
 311 the legacy encoding is some variant of EBCDIC rather than a super-set
 312 of ASCII - see L<perlebcdic>).
 313
 314 Traditionally, computer data has been moved around in 8-bit chunks
 315 often called "bytes". These chunks are also known as "octets" in
 316 networking standards. Perl is widely used to manipulate data of many
 317 types - not only strings of characters representing human or computer
 318 languages but also "binary" data being the machine's representation of
 319 numbers, pixels in an image - or just about anything.
 320
 321 When Perl is processing "binary data", the programmer wants Perl to
 322 process "sequences of bytes". This is not a problem for Perl - as a
 323 byte has 256 possible values, it easily fits in Perl's much larger
 324 "logical character".
 325
 326 =head2 TERMINOLOGY
 327
 328 =over 2
 329
 330 =item *
 331
 332 I<character>: a character in the range 0..(2**32-1) (or more).
 333 (What Perl's strings are made of.)
 334
 335 =item *
 336
 337 I<byte>: a character in the range 0..255
 338 (A special case of a Perl character.)
 339
 340 =item *
 341
 342 I<octet>: 8 bits of data, with ordinal values 0..255
 343 (Term for bytes passed to or from a non-Perl context, e.g. a disk file.)
 344
 345 =back
 346
 347 =head1 PERL ENCODING API
 348
 349 =over 2
 350
 351 =item $octets  = encode(ENCODING, $string [, CHECK])
 352
 353 Encodes a string from Perl's internal form into I<ENCODING> and returns
 354 a sequence of octets.  ENCODING can be either a canonical name or
 355 an alias.  For encoding names and aliases, see L</"Defining Aliases">.
 356 For CHECK, see L</"Handling Malformed Data">.
 357
 358 For example, to convert a string from Perl's internal format to
 359 iso-8859-1 (also known as Latin1),
 360
 361   $octets = encode("iso-8859-1", $string);
 362
 363 B<CAVEAT>: When you run C<$octets = encode("utf8", $string)>, then $octets
 364 B<may not be equal to> $string.  Though they both contain the same data, the utf8 flag
 365 for $octets is B<always> off.  When you encode anything, utf8 flag of
 366 the result is always off, even when it contains completely valid utf8
 367 string. See L</"The UTF-8 flag"> below.
 368
 369 =item $string = decode(ENCODING, $octets [, CHECK])
 370
 371 Decodes a sequence of octets assumed to be in I<ENCODING> into Perl's
 372 internal form and returns the resulting string.  As in encode(),
 373 ENCODING can be either a canonical name or an alias. For encoding names
 374 and aliases, see L</"Defining Aliases">.  For CHECK, see
 375 L</"Handling Malformed Data">.
 376
 377 For example, to convert ISO-8859-1 data to a string in Perl's internal format:
 378
 379   $string = decode("iso-8859-1", $octets);
 380
 381 B<CAVEAT>: When you run C<$string = decode("utf8", $octets)>, then $string
 382 B<may not be equal to> $octets.  Though they both contain the same data,
 383 the utf8 flag for $string is on unless $octets entirely consists of
 384 ASCII data (or EBCDIC on EBCDIC machines).  See L</"The UTF-8 flag">
 385 below.
 386
 387 =item [$length =] from_to($octets, FROM_ENC, TO_ENC [, CHECK])
 388
 389 Converts B<in-place> data between two encodings. The data in $octets
 390 must be encoded as octets and not as characters in Perl's internal
 391 format. For example, to convert ISO-8859-1 data to Microsoft's CP1250 encoding:
 392
 393   from_to($octets, "iso-8859-1", "cp1250");
 394
 395 and to convert it back:
 396
 397   from_to($octets, "cp1250", "iso-8859-1");
 398
 399 Note that because the conversion happens in place, the data to be
 400 converted cannot be a string constant; it must be a scalar variable.
 401
 402 from_to() returns the length of the converted string in octets on success, undef
 403 otherwise.
 404
 405 B<CAVEAT>: The following operations look the same but are not quite so;
 406
 407   from_to($data, "iso-8859-1", "utf8"); #1
 408   $data = decode("iso-8859-1", $data);  #2
 409
 410 Both #1 and #2 make $data consist of a completely valid UTF-8 string
 411 but only #2 turns utf8 flag on.  #1 is equivalent to
 412
 413   $data = encode("utf8", decode("iso-8859-1", $data));
 414
 415 See L</"The UTF-8 flag"> below.
 416
 417 =item $octets = encode_utf8($string);
 418
 419 Equivalent to C<$octets = encode("utf8", $string);> The characters
 420 that comprise $string are encoded in Perl's internal format and the
 421 result is returned as a sequence of octets. All possible
 422 characters have a UTF-8 representation so this function cannot fail.
 423
 424
 425 =item $string = decode_utf8($octets [, CHECK]);
 426
 427 equivalent to C<$string = decode("utf8", $octets [, CHECK])>.
 428 The sequence of octets represented by
 429 $octets is decoded from UTF-8 into a sequence of logical
 430 characters. Not all sequences of octets form valid UTF-8 encodings, so
 431 it is possible for this call to fail.  For CHECK, see
 432 L</"Handling Malformed Data">.
 433
 434 =back
 435
 436 =head2 Listing available encodings
 437
 438   use Encode;
 439   @list = Encode->encodings();
 440
 441 Returns a list of the canonical names of the available encodings that
 442 are loaded.  To get a list of all available encodings including the
 443 ones that are not loaded yet, say
 444
 445   @all_encodings = Encode->encodings(":all");
 446
 447 Or you can give the name of a specific module.
 448
 449   @with_jp = Encode->encodings("Encode::JP");
 450
 451 When "::" is not in the name, "Encode::" is assumed.
 452
 453   @ebcdic = Encode->encodings("EBCDIC");
 454
 455 To find out in detail which encodings are supported by this package,
 456 see L<Encode::Supported>.
 457
 458 =head2 Defining Aliases
 459
 460 To add a new alias to a given encoding, use:
 461
 462   use Encode;
 463   use Encode::Alias;
 464   define_alias(newName => ENCODING);
 465
 466 After that, newName can be used as an alias for ENCODING.
 467 ENCODING may be either the name of an encoding or an
 468 I<encoding object>
 469
 470 But before you do so, make sure the alias is nonexistent with
 471 C<resolve_alias()>, which returns the canonical name thereof.
 472 i.e.
 473
 474   Encode::resolve_alias("latin1") eq "iso-8859-1" # true
 475   Encode::resolve_alias("iso-8859-12")   # false; nonexistent
 476   Encode::resolve_alias($name) eq $name  # true if $name is canonical
 477
 478 resolve_alias() does not need C<use Encode::Alias>; it can be
 479 exported via C<use Encode qw(resolve_alias)>.
 480
 481 See L<Encode::Alias> for details.
 482
 483 =head1 Encoding via PerlIO
 484
 485 If your perl supports I<PerlIO> (which is the default), you can use a PerlIO layer to decode
 486 and encode directly via a filehandle.  The following two examples
 487 are totally identical in their functionality.
 488
 489   # via PerlIO
 490   open my $in,  "<:encoding(shiftjis)", $infile  or die;
 491   open my $out, ">:encoding(euc-jp)",   $outfile or die;
 492   while(<$in>){ print $out $_; }
 493
 494   # via from_to
 495   open my $in,  "<", $infile  or die;
 496   open my $out, ">", $outfile or die;
 497   while(<$in>){
 498     from_to($_, "shiftjis", "euc-jp", 1);
 499     print $out $_;
 500   }
 501
 502 Unfortunately, it may be that encodings are PerlIO-savvy.  You can check
 503 if your encoding is supported by PerlIO by calling the C<perlio_ok>
 504 method.
 505
 506   Encode::perlio_ok("hz");             # False
 507   find_encoding("euc-cn")->perlio_ok;  # True where PerlIO is available
 508
 509   use Encode qw(perlio_ok);            # exported upon request
 510   perlio_ok("euc-jp")
 511
 512 Fortunately, all encodings that come with Encode core are PerlIO-savvy
 513 except for hz and ISO-2022-kr.  For gory details, see L<Encode::Encoding> and L<Encode::PerlIO>.
 514
 515 =head1 Handling Malformed Data
 516
 517 =over 2
 518
 519 The I<CHECK> argument is used as follows.  When you omit it,
 520 the behaviour is the same as if you had passed a value of 0 for
 521 I<CHECK>.
 522
 523 =item I<CHECK> = Encode::FB_DEFAULT ( == 0)
 524
 525 If I<CHECK> is 0, (en|de)code will put a I<substitution character>
 526 in place of a malformed character.  For UCM-based encodings,
 527 E<lt>subcharE<gt> will be used.  For Unicode, the code point C<0xFFFD> is used.
 528 If the data is supposed to be UTF-8, an optional lexical warning
 529 (category utf8) is given.
 530
 531 =item I<CHECK> = Encode::FB_CROAK ( == 1)
 532
 533 If I<CHECK> is 1, methods will die on error immediately with an error
 534 message.  Therefore, when I<CHECK> is set to 1,  you should trap the
 535 fatal error with eval{} unless you really want to let it die on error.
 536
 537 =item I<CHECK> = Encode::FB_QUIET
 538
 539 If I<CHECK> is set to Encode::FB_QUIET, (en|de)code will immediately
 540 return the portion of the data that has been processed so far when
 541 an error occurs. The data argument will be overwritten with
 542 everything after that point (that is, the unprocessed part of data).
 543 This is handy when you have to call decode repeatedly in the case
 544 where your source data may contain partial multi-byte character
 545 sequences, for example because you are reading with a fixed-width
 546 buffer. Here is some sample code that does exactly this:
 547
 548   my $data = ''; my $utf8 = '';
 549   while(defined(read $fh, $buffer, 256)){
 550     # buffer may end in a partial character so we append
 551     $data .= $buffer;
 552     $utf8 .= decode($encoding, $data, ENCODE::FB_QUIET);
 553     # $data now contains the unprocessed partial character
 554   }
 555
 556 =item I<CHECK> = Encode::FB_WARN
 557
 558 This is the same as above, except that it warns on error.  Handy when
 559 you are debugging the mode above.
 560
 561 =item perlqq mode (I<CHECK> = Encode::FB_PERLQQ)
 562
 563 =item HTML charref mode (I<CHECK> = Encode::FB_HTMLCREF)
 564
 565 =item XML charref mode (I<CHECK> = Encode::FB_XMLCREF)
 566
 567 For encodings that are implemented by Encode::XS, CHECK ==
 568 Encode::FB_PERLQQ turns (en|de)code into C<perlqq> fallback mode.
 569
 570 When you decode, C<\xI<HH>> will be inserted for a malformed character,
 571 where I<HH> is the hex representation of the octet  that could not be
 572 decoded to utf8.  And when you encode, C<\x{I<HHHH>}> will be inserted,
 573 where I<HHHH> is the Unicode ID of the character that cannot be found
 574 in the character repertoire of the encoding.
 575
 576 HTML/XML character reference modes are about the same, in place of
 577 C<\x{I<HHHH>}>, HTML uses C<&#I<NNNN>>; where I<NNNN> is a decimal digit and
 578 XML uses C<&#xI<HHHH>>; where I<HHHH> is the hexadecimal digit.
 579
 580 =item The bitmask
 581
 582 These modes are actually set via a bitmask.  Here is how the FB_XX
 583 constants are laid out.  You can import the FB_XX constants via
 584 C<use Encode qw(:fallbacks)>; you can import the generic bitmask
 585 constants via C<use Encode qw(:fallback_all)>.
 586
 587                      FB_DEFAULT FB_CROAK FB_QUIET FB_WARN  FB_PERLQQ
 588  DIE_ON_ERR    0x0001             X
 589  WARN_ON_ER    0x0002                               X
 590  RETURN_ON_ERR 0x0004                      X        X
 591  LEAVE_SRC     0x0008
 592  PERLQQ        0x0100                                        X
 593  HTMLCREF      0x0200
 594  XMLCREF       0x0400
 595
 596 =head2 Unimplemented fallback schemes
 597
 598 In the future, you will be able to use a code reference to a callback
 599 function for the value of I<CHECK> but its API is still undecided.
 600
 601 =head1 Defining Encodings
 602
 603 To define a new encoding, use:
 604
 605     use Encode qw(define_encoding);
 606     define_encoding($object, 'canonicalName' [, alias...]);
 607
 608 I<canonicalName> will be associated with I<$object>.  The object
 609 should provide the interface described in L<Encode::Encoding>.
 610 If more than two arguments are provided then additional
 611 arguments are taken as aliases for I<$object>.
 612
 613 See L<Encode::Encoding> for more details.
 614
 615 =head1 The UTF-8 flag
 616
 617 Before the introduction of utf8 support in perl, The C<eq> operator
 618 just compared the strings represented by two scalars. Beginning with
 619 perl 5.8, C<eq> compares two strings with simultaneous consideration
 620 of I<the utf8 flag>. To explain why we made it so, I will quote page
 621 402 of C<Programming Perl, 3rd ed.>
 622
 623 =over 2
 624
 625 =item Goal #1:
 626
 627 Old byte-oriented programs should not spontaneously break on the old
 628 byte-oriented data they used to work on.
 629
 630 =item Goal #2:
 631
 632 Old byte-oriented programs should magically start working on the new
 633 character-oriented data when appropriate.
 634
 635 =item Goal #3:
 636
 637 Programs should run just as fast in the new character-oriented mode
 638 as in the old byte-oriented mode.
 639
 640 =item Goal #4:
 641
 642 Perl should remain one language, rather than forking into a
 643 byte-oriented Perl and a character-oriented Perl.
 644
 645 =back
 646
 647 Back when C<Programming Perl, 3rd ed.> was written, not even Perl 5.6.0
 648 was born and many features documented in the book remained
 649 unimplemented for a long time.  Perl 5.8 corrected this and the introduction
 650 of the UTF-8 flag is one of them.  You can think of this perl notion as of a
 651 byte-oriented mode (utf8 flag off) and a character-oriented mode (utf8
 652 flag on).
 653
 654 Here is how Encode takes care of the utf8 flag.
 655
 656 =over 2
 657
 658 =item *
 659
 660 When you encode, the resulting utf8 flag is always off.
 661
 662 =item
 663
 664 When you decode, the resulting utf8 flag is on unless you can
 665 unambiguously represent data.  Here is the definition of
 666 dis-ambiguity.
 667
 668 After C<$utf8 = decode('foo', $octet);>,
 669
 670   When $octet is...   The utf8 flag in $utf8 is
 671   ---------------------------------------------
 672   In ASCII only (or EBCDIC only)            OFF
 673   In ISO-8859-1                              ON
 674   In any other Encoding                      ON
 675   ---------------------------------------------
 676
 677 As you see, there is one exception, In ASCII.  That way you can assue
 678 Goal #1.  And with Encode Goal #2 is assumed but you still have to be
 679 careful in such cases mentioned in B<CAVEAT> paragraphs.
 680
 681 This utf8 flag is not visible in perl scripts, exactly for the same
 682 reason you cannot (or you I<don't have to>) see if a scalar contains a
 683 string, integer, or floating point number.   But you can still peek
 684 and poke these if you will.  See the section below.
 685
 686 =back
 687
 688 =head2 Messing with Perl's Internals
 689
 690 The following API uses parts of Perl's internals in the current
 691 implementation.  As such, they are efficient but may change.
 692
 693 =over 2
 694
 695 =item is_utf8(STRING [, CHECK])
 696
 697 [INTERNAL] Tests whether the UTF-8 flag is turned on in the STRING.
 698 If CHECK is true, also checks the data in STRING for being well-formed
 699 UTF-8.  Returns true if successful, false otherwise.
 700
 701 =item _utf8_on(STRING)
 702
 703 [INTERNAL] Turns on the UTF-8 flag in STRING.  The data in STRING is
 704 B<not> checked for being well-formed UTF-8.  Do not use unless you
 705 B<know> that the STRING is well-formed UTF-8.  Returns the previous
 706 state of the UTF-8 flag (so please don't treat the return value as
 707 indicating success or failure), or C<undef> if STRING is not a string.
 708
 709 =item _utf8_off(STRING)
 710
 711 [INTERNAL] Turns off the UTF-8 flag in STRING.  Do not use frivolously.
 712 Returns the previous state of the UTF-8 flag (so please don't treat the
 713 return value as indicating success or failure), or C<undef> if STRING is
 714 not a string.
 715
 716 =back
 717
 718 =head1 SEE ALSO
 719
 720 L<Encode::Encoding>,
 721 L<Encode::Supported>,
 722 L<Encode::PerlIO>,
 723 L<encoding>,
 724 L<perlebcdic>,
 725 L<perlfunc/open>,
 726 L<perlunicode>,
 727 L<utf8>,
 728 the Perl Unicode Mailing List E<lt>perl-unicode@perl.orgE<gt>
 729
 730 =head1 MAINTAINER
 731
 732 This project was originated by Nick Ing-Simmons and later maintained
 733 by Dan Kogai E<lt>dankogai@dan.co.jpE<gt>.  See AUTHORS for a full
 734 list of people involved.  For any questions, use
 735 E<lt>perl-unicode@perl.orgE<gt> so we can all share.
 736
 737 =cut