ext/Encode/Encode.pm

   1 #
   2 # $Id: Encode.pm,v 2.17 2006/05/09 17:10:42 dankogai Exp dankogai $
   3 #
   4 package Encode;
   5 use strict;
   6 our $VERSION = sprintf "%d.%02d", q$Revision: 2.17 $ =~ /(\d+)/g;
   7 sub DEBUG () { 0 }
   8 use XSLoader ();
   9 XSLoader::load( __PACKAGE__, $VERSION );
  10
  11 require Exporter;
  12 use base qw/Exporter/;
  13
  14 # Public, encouraged API is exported by default
  15
  16 our @EXPORT = qw(
  17   decode  decode_utf8  encode  encode_utf8 str2bytes bytes2str
  18   encodings  find_encoding clone_encoding
  19 );
  20 our @FB_FLAGS = qw(
  21   DIE_ON_ERR WARN_ON_ERR RETURN_ON_ERR LEAVE_SRC
  22   PERLQQ HTMLCREF XMLCREF STOP_AT_PARTIAL
  23 );
  24 our @FB_CONSTS = qw(
  25   FB_DEFAULT FB_CROAK FB_QUIET FB_WARN
  26   FB_PERLQQ FB_HTMLCREF FB_XMLCREF
  27 );
  28 our @EXPORT_OK = (
  29     qw(
  30       _utf8_off _utf8_on define_encoding from_to is_16bit is_8bit
  31       is_utf8 perlio_ok resolve_alias utf8_downgrade utf8_upgrade
  32       ),
  33     @FB_FLAGS, @FB_CONSTS,
  34 );
  35
  36 our %EXPORT_TAGS = (
  37     all          => [ @EXPORT,    @EXPORT_OK ],
  38     fallbacks    => [@FB_CONSTS],
  39     fallback_all => [ @FB_CONSTS, @FB_FLAGS ],
  40 );
  41
  42 # Documentation moved after __END__ for speed - NI-S
  43
  44 our $ON_EBCDIC = ( ord("A") == 193 );
  45
  46 use Encode::Alias;
  47
  48 # Make a %Encoding package variable to allow a certain amount of cheating
  49 our %Encoding;
  50 our %ExtModule;
  51 require Encode::Config;
  52 eval { require Encode::ConfigLocal };
  53
  54 sub encodings {
  55     my $class = shift;
  56     my %enc;
  57     if ( @_ and $_[0] eq ":all" ) {
  58         %enc = ( %Encoding, %ExtModule );
  59     }
  60     else {
  61         %enc = %Encoding;
  62         for my $mod ( map { m/::/o ? $_ : "Encode::$_" } @_ ) {
  63             DEBUG and warn $mod;
  64             for my $enc ( keys %ExtModule ) {
  65                 $ExtModule{$enc} eq $mod and $enc{$enc} = $mod;
  66             }
  67         }
  68     }
  69     return sort { lc $a cmp lc $b }
  70       grep      { !/^(?:Internal|Unicode|Guess)$/o } keys %enc;
  71 }
  72
  73 sub perlio_ok {
  74     my $obj = ref( $_[0] ) ? $_[0] : find_encoding( $_[0] );
  75     $obj->can("perlio_ok") and return $obj->perlio_ok();
  76     return 0;    # safety net
  77 }
  78
  79 sub define_encoding {
  80     my $obj  = shift;
  81     my $name = shift;
  82     $Encoding{$name} = $obj;
  83     my $lc = lc($name);
  84     define_alias( $lc => $obj ) unless $lc eq $name;
  85     while (@_) {
  86         my $alias = shift;
  87         define_alias( $alias, $obj );
  88     }
  89     return $obj;
  90 }
  91
  92 sub getEncoding {
  93     my ( $class, $name, $skip_external ) = @_;
  94
  95     ref($name) && $name->can('renew') and return $name;
  96     exists $Encoding{$name} and return $Encoding{$name};
  97     my $lc = lc $name;
  98     exists $Encoding{$lc} and return $Encoding{$lc};
  99
 100     my $oc = $class->find_alias($name);
 101     defined($oc) and return $oc;
 102     $lc ne $name and $oc = $class->find_alias($lc);
 103     defined($oc) and return $oc;
 104
 105     unless ($skip_external) {
 106         if ( my $mod = $ExtModule{$name} || $ExtModule{$lc} ) {
 107             $mod =~ s,::,/,g;
 108             $mod .= '.pm';
 109             eval { require $mod; };
 110             exists $Encoding{$name} and return $Encoding{$name};
 111         }
 112     }
 113     return;
 114 }
 115
 116 sub find_encoding($;$) {
 117     my ( $name, $skip_external ) = @_;
 118     return __PACKAGE__->getEncoding( $name, $skip_external );
 119 }
 120
 121 sub resolve_alias($) {
 122     my $obj = find_encoding(shift);
 123     defined $obj and return $obj->name;
 124     return;
 125 }
 126
 127 sub clone_encoding($) {
 128     my $obj = find_encoding(shift);
 129     ref $obj or return;
 130     eval { require Storable };
 131     $@ and return;
 132     return Storable::dclone($obj);
 133 }
 134
 135 sub encode($$;$) {
 136     my ( $name, $string, $check ) = @_;
 137     return undef unless defined $string;
 138     $string .= '' if ref $string;    # stringify;
 139     $check ||= 0;
 140     my $enc = find_encoding($name);
 141     unless ( defined $enc ) {
 142         require Carp;
 143         Carp::croak("Unknown encoding '$name'");
 144     }
 145     my $octets = $enc->encode( $string, $check );
 146     $_[1] = $string if $check and !( $check & LEAVE_SRC() );
 147     return $octets;
 148 }
 149 *str2bytes = \&encode;
 150
 151 sub decode($$;$) {
 152     my ( $name, $octets, $check ) = @_;
 153     return undef unless defined $octets;
 154     $octets .= '' if ref $octets;
 155     $check ||= 0;
 156     my $enc = find_encoding($name);
 157     unless ( defined $enc ) {
 158         require Carp;
 159         Carp::croak("Unknown encoding '$name'");
 160     }
 161     my $string = $enc->decode( $octets, $check );
 162     $_[1] = $octets if $check and !( $check & LEAVE_SRC() );
 163     return $string;
 164 }
 165 *bytes2str = \&decode;
 166
 167 sub from_to($$$;$) {
 168     my ( $string, $from, $to, $check ) = @_;
 169     return undef unless defined $string;
 170     $check ||= 0;
 171     my $f = find_encoding($from);
 172     unless ( defined $f ) {
 173         require Carp;
 174         Carp::croak("Unknown encoding '$from'");
 175     }
 176     my $t = find_encoding($to);
 177     unless ( defined $t ) {
 178         require Carp;
 179         Carp::croak("Unknown encoding '$to'");
 180     }
 181     my $uni = $f->decode($string);
 182     $_[0] = $string = $t->encode( $uni, $check );
 183     return undef if ( $check && length($uni) );
 184     return defined( $_[0] ) ? length($string) : undef;
 185 }
 186
 187 sub encode_utf8($) {
 188     my ($str) = @_;
 189     utf8::encode($str);
 190     return $str;
 191 }
 192
 193 sub decode_utf8($;$) {
 194     my ( $str, $check ) = @_;
 195     return $str if is_utf8($str);
 196     if ($check) {
 197         return decode( "utf8", $str, $check );
 198     }
 199     else {
 200         return decode( "utf8", $str );
 201         return $str;
 202     }
 203 }
 204
 205 predefine_encodings(1);
 206
 207 #
 208 # This is to restore %Encoding if really needed;
 209 #
 210
 211 sub predefine_encodings {
 212     use Encode::Encoding;
 213     no warnings 'redefine';
 214     my $use_xs = shift;
 215     if ($ON_EBCDIC) {
 216
 217         # was in Encode::UTF_EBCDIC
 218         package Encode::UTF_EBCDIC;
 219         push @Encode::UTF_EBCDIC::ISA, 'Encode::Encoding';
 220         *decode = sub {
 221             my ( $obj, $str, $chk ) = @_;
 222             my $res = '';
 223             for ( my $i = 0 ; $i < length($str) ; $i++ ) {
 224                 $res .=
 225                   chr(
 226                     utf8::unicode_to_native( ord( substr( $str, $i, 1 ) ) )
 227                   );
 228             }
 229             $_[1] = '' if $chk;
 230             return $res;
 231         };
 232         *encode = sub {
 233             my ( $obj, $str, $chk ) = @_;
 234             my $res = '';
 235             for ( my $i = 0 ; $i < length($str) ; $i++ ) {
 236                 $res .=
 237                   chr(
 238                     utf8::native_to_unicode( ord( substr( $str, $i, 1 ) ) )
 239                   );
 240             }
 241             $_[1] = '' if $chk;
 242             return $res;
 243         };
 244         $Encode::Encoding{Unicode} =
 245           bless { Name => "UTF_EBCDIC" } => "Encode::UTF_EBCDIC";
 246     }
 247     else {
 248
 249         package Encode::Internal;
 250         push @Encode::Internal::ISA, 'Encode::Encoding';
 251         *decode = sub {
 252             my ( $obj, $str, $chk ) = @_;
 253             utf8::upgrade($str);
 254             $_[1] = '' if $chk;
 255             return $str;
 256         };
 257         *encode = \&decode;
 258         $Encode::Encoding{Unicode} =
 259           bless { Name => "Internal" } => "Encode::Internal";
 260     }
 261
 262     {
 263
 264         # was in Encode::utf8
 265         package Encode::utf8;
 266         push @Encode::utf8::ISA, 'Encode::Encoding';
 267
 268         #
 269         if ($use_xs) {
 270             Encode::DEBUG and warn __PACKAGE__, " XS on";
 271             *decode = \&decode_xs;
 272             *encode = \&encode_xs;
 273         }
 274         else {
 275             Encode::DEBUG and warn __PACKAGE__, " XS off";
 276             *decode = sub {
 277                 my ( $obj, $octets, $chk ) = @_;
 278                 my $str = Encode::decode_utf8($octets);
 279                 if ( defined $str ) {
 280                     $_[1] = '' if $chk;
 281                     return $str;
 282                 }
 283                 return undef;
 284             };
 285             *encode = sub {
 286                 my ( $obj, $string, $chk ) = @_;
 287                 my $octets = Encode::encode_utf8($string);
 288                 $_[1] = '' if $chk;
 289                 return $octets;
 290             };
 291         }
 292         *cat_decode = sub {    # ($obj, $dst, $src, $pos, $trm, $chk)
 293                                # currently ignores $chk
 294             my ( $obj, undef, undef, $pos, $trm ) = @_;
 295             my ( $rdst, $rsrc, $rpos ) = \@_[ 1, 2, 3 ];
 296             use bytes;
 297             if ( ( my $npos = index( $$rsrc, $trm, $pos ) ) >= 0 ) {
 298                 $$rdst .=
 299                   substr( $$rsrc, $pos, $npos - $pos + length($trm) );
 300                 $$rpos = $npos + length($trm);
 301                 return 1;
 302             }
 303             $$rdst .= substr( $$rsrc, $pos );
 304             $$rpos = length($$rsrc);
 305             return '';
 306         };
 307         $Encode::Encoding{utf8} =
 308           bless { Name => "utf8" } => "Encode::utf8";
 309         $Encode::Encoding{"utf-8-strict"} =
 310           bless { Name => "utf-8-strict", strict_utf8 => 1 } =>
 311           "Encode::utf8";
 312     }
 313 }
 314
 315 1;
 316
 317 __END__
 318
 319 =head1 NAME
 320
 321 Encode - character encodings
 322
 323 =head1 SYNOPSIS
 324
 325     use Encode;
 326
 327 =head2 Table of Contents
 328
 329 Encode consists of a collection of modules whose details are too big
 330 to fit in one document.  This POD itself explains the top-level APIs
 331 and general topics at a glance.  For other topics and more details,
 332 see the PODs below:
 333
 334   Name                          Description
 335   --------------------------------------------------------
 336   Encode::Alias         Alias definitions to encodings
 337   Encode::Encoding      Encode Implementation Base Class
 338   Encode::Supported     List of Supported Encodings
 339   Encode::CN            Simplified Chinese Encodings
 340   Encode::JP            Japanese Encodings
 341   Encode::KR            Korean Encodings
 342   Encode::TW            Traditional Chinese Encodings
 343   --------------------------------------------------------
 344
 345 =head1 DESCRIPTION
 346
 347 The C<Encode> module provides the interfaces between Perl's strings
 348 and the rest of the system.  Perl strings are sequences of
 349 B<characters>.
 350
 351 The repertoire of characters that Perl can represent is at least that
 352 defined by the Unicode Consortium. On most platforms the ordinal
 353 values of the characters (as returned by C<ord(ch)>) is the "Unicode
 354 codepoint" for the character (the exceptions are those platforms where
 355 the legacy encoding is some variant of EBCDIC rather than a super-set
 356 of ASCII - see L<perlebcdic>).
 357
 358 Traditionally, computer data has been moved around in 8-bit chunks
 359 often called "bytes". These chunks are also known as "octets" in
 360 networking standards. Perl is widely used to manipulate data of many
 361 types - not only strings of characters representing human or computer
 362 languages but also "binary" data being the machine's representation of
 363 numbers, pixels in an image - or just about anything.
 364
 365 When Perl is processing "binary data", the programmer wants Perl to
 366 process "sequences of bytes". This is not a problem for Perl - as a
 367 byte has 256 possible values, it easily fits in Perl's much larger
 368 "logical character".
 369
 370 =head2 TERMINOLOGY
 371
 372 =over 2
 373
 374 =item *
 375
 376 I<character>: a character in the range 0..(2**32-1) (or more).
 377 (What Perl's strings are made of.)
 378
 379 =item *
 380
 381 I<byte>: a character in the range 0..255
 382 (A special case of a Perl character.)
 383
 384 =item *
 385
 386 I<octet>: 8 bits of data, with ordinal values 0..255
 387 (Term for bytes passed to or from a non-Perl context, e.g. a disk file.)
 388
 389 =back
 390
 391 =head1 PERL ENCODING API
 392
 393 =over 2
 394
 395 =item $octets  = encode(ENCODING, $string [, CHECK])
 396
 397 Encodes a string from Perl's internal form into I<ENCODING> and returns
 398 a sequence of octets.  ENCODING can be either a canonical name or
 399 an alias.  For encoding names and aliases, see L</"Defining Aliases">.
 400 For CHECK, see L</"Handling Malformed Data">.
 401
 402 For example, to convert a string from Perl's internal format to
 403 iso-8859-1 (also known as Latin1),
 404
 405   $octets = encode("iso-8859-1", $string);
 406
 407 B<CAVEAT>: When you run C<$octets = encode("utf8", $string)>, then $octets
 408 B<may not be equal to> $string.  Though they both contain the same data, the utf8 flag
 409 for $octets is B<always> off.  When you encode anything, utf8 flag of
 410 the result is always off, even when it contains completely valid utf8
 411 string. See L</"The UTF-8 flag"> below.
 412
 413 If the $string is C<undef> then C<undef> is returned.
 414
 415 =item $string = decode(ENCODING, $octets [, CHECK])
 416
 417 Decodes a sequence of octets assumed to be in I<ENCODING> into Perl's
 418 internal form and returns the resulting string.  As in encode(),
 419 ENCODING can be either a canonical name or an alias. For encoding names
 420 and aliases, see L</"Defining Aliases">.  For CHECK, see
 421 L</"Handling Malformed Data">.
 422
 423 For example, to convert ISO-8859-1 data to a string in Perl's internal format:
 424
 425   $string = decode("iso-8859-1", $octets);
 426
 427 B<CAVEAT>: When you run C<$string = decode("utf8", $octets)>, then $string
 428 B<may not be equal to> $octets.  Though they both contain the same data,
 429 the utf8 flag for $string is on unless $octets entirely consists of
 430 ASCII data (or EBCDIC on EBCDIC machines).  See L</"The UTF-8 flag">
 431 below.
 432
 433 If the $string is C<undef> then C<undef> is returned.
 434
 435 =item [$length =] from_to($octets, FROM_ENC, TO_ENC [, CHECK])
 436
 437 Converts B<in-place> data between two encodings. The data in $octets
 438 must be encoded as octets and not as characters in Perl's internal
 439 format. For example, to convert ISO-8859-1 data to Microsoft's CP1250
 440 encoding:
 441
 442   from_to($octets, "iso-8859-1", "cp1250");
 443
 444 and to convert it back:
 445
 446   from_to($octets, "cp1250", "iso-8859-1");
 447
 448 Note that because the conversion happens in place, the data to be
 449 converted cannot be a string constant; it must be a scalar variable.
 450
 451 from_to() returns the length of the converted string in octets on
 452 success, I<undef> on error.
 453
 454 B<CAVEAT>: The following operations look the same but are not quite so;
 455
 456   from_to($data, "iso-8859-1", "utf8"); #1
 457   $data = decode("iso-8859-1", $data);  #2
 458
 459 Both #1 and #2 make $data consist of a completely valid UTF-8 string
 460 but only #2 turns utf8 flag on.  #1 is equivalent to
 461
 462   $data = encode("utf8", decode("iso-8859-1", $data));
 463
 464 See L</"The UTF-8 flag"> below.
 465
 466 =item $octets = encode_utf8($string);
 467
 468 Equivalent to C<$octets = encode("utf8", $string);> The characters
 469 that comprise $string are encoded in Perl's internal format and the
 470 result is returned as a sequence of octets. All possible
 471 characters have a UTF-8 representation so this function cannot fail.
 472
 473
 474 =item $string = decode_utf8($octets [, CHECK]);
 475
 476 equivalent to C<$string = decode("utf8", $octets [, CHECK])>.
 477 The sequence of octets represented by
 478 $octets is decoded from UTF-8 into a sequence of logical
 479 characters. Not all sequences of octets form valid UTF-8 encodings, so
 480 it is possible for this call to fail.  For CHECK, see
 481 L</"Handling Malformed Data">.
 482
 483 =back
 484
 485 =head2 Listing available encodings
 486
 487   use Encode;
 488   @list = Encode->encodings();
 489
 490 Returns a list of the canonical names of the available encodings that
 491 are loaded.  To get a list of all available encodings including the
 492 ones that are not loaded yet, say
 493
 494   @all_encodings = Encode->encodings(":all");
 495
 496 Or you can give the name of a specific module.
 497
 498   @with_jp = Encode->encodings("Encode::JP");
 499
 500 When "::" is not in the name, "Encode::" is assumed.
 501
 502   @ebcdic = Encode->encodings("EBCDIC");
 503
 504 To find out in detail which encodings are supported by this package,
 505 see L<Encode::Supported>.
 506
 507 =head2 Defining Aliases
 508
 509 To add a new alias to a given encoding, use:
 510
 511   use Encode;
 512   use Encode::Alias;
 513   define_alias(newName => ENCODING);
 514
 515 After that, newName can be used as an alias for ENCODING.
 516 ENCODING may be either the name of an encoding or an
 517 I<encoding object>
 518
 519 But before you do so, make sure the alias is nonexistent with
 520 C<resolve_alias()>, which returns the canonical name thereof.
 521 i.e.
 522
 523   Encode::resolve_alias("latin1") eq "iso-8859-1" # true
 524   Encode::resolve_alias("iso-8859-12")   # false; nonexistent
 525   Encode::resolve_alias($name) eq $name  # true if $name is canonical
 526
 527 resolve_alias() does not need C<use Encode::Alias>; it can be
 528 exported via C<use Encode qw(resolve_alias)>.
 529
 530 See L<Encode::Alias> for details.
 531
 532 =head1 Encoding via PerlIO
 533
 534 If your perl supports I<PerlIO> (which is the default), you can use a PerlIO layer to decode
 535 and encode directly via a filehandle.  The following two examples
 536 are totally identical in their functionality.
 537
 538   # via PerlIO
 539   open my $in,  "<:encoding(shiftjis)", $infile  or die;
 540   open my $out, ">:encoding(euc-jp)",   $outfile or die;
 541   while(<$in>){ print $out $_; }
 542
 543   # via from_to
 544   open my $in,  "<", $infile  or die;
 545   open my $out, ">", $outfile or die;
 546   while(<$in>){
 547     from_to($_, "shiftjis", "euc-jp", 1);
 548     print $out $_;
 549   }
 550
 551 Unfortunately, it may be that encodings are PerlIO-savvy.  You can check
 552 if your encoding is supported by PerlIO by calling the C<perlio_ok>
 553 method.
 554
 555   Encode::perlio_ok("hz");             # False
 556   find_encoding("euc-cn")->perlio_ok;  # True where PerlIO is available
 557
 558   use Encode qw(perlio_ok);            # exported upon request
 559   perlio_ok("euc-jp")
 560
 561 Fortunately, all encodings that come with Encode core are PerlIO-savvy
 562 except for hz and ISO-2022-kr.  For gory details, see
 563 L<Encode::Encoding> and L<Encode::PerlIO>.
 564
 565 =head1 Handling Malformed Data
 566
 567 The optional I<CHECK> argument tells Encode what to do when it
 568 encounters malformed data.  Without CHECK, Encode::FB_DEFAULT ( == 0 )
 569 is assumed.
 570
 571 As of version 2.12 Encode supports coderef values for CHECK.  See below.
 572
 573 =over 2
 574
 575 =item B<NOTE:> Not all encoding support this feature
 576
 577 Some encodings ignore I<CHECK> argument.  For example,
 578 L<Encode::Unicode> ignores I<CHECK> and it always croaks on error.
 579
 580 =back
 581
 582 Now here is the list of I<CHECK> values available
 583
 584 =over 2
 585
 586 =item I<CHECK> = Encode::FB_DEFAULT ( == 0)
 587
 588 If I<CHECK> is 0, (en|de)code will put a I<substitution character> in
 589 place of a malformed character.  When you encode, E<lt>subcharE<gt>
 590 will be used.  When you decode the code point C<0xFFFD> is used.  If
 591 the data is supposed to be UTF-8, an optional lexical warning
 592 (category utf8) is given.
 593
 594 =item I<CHECK> = Encode::FB_CROAK ( == 1)
 595
 596 If I<CHECK> is 1, methods will die on error immediately with an error
 597 message.  Therefore, when I<CHECK> is set to 1,  you should trap the
 598 error with eval{} unless you really want to let it die.
 599
 600 =item I<CHECK> = Encode::FB_QUIET
 601
 602 If I<CHECK> is set to Encode::FB_QUIET, (en|de)code will immediately
 603 return the portion of the data that has been processed so far when an
 604 error occurs. The data argument will be overwritten with everything
 605 after that point (that is, the unprocessed part of data).  This is
 606 handy when you have to call decode repeatedly in the case where your
 607 source data may contain partial multi-byte character sequences,
 608 (i.e. you are reading with a fixed-width buffer). Here is a sample
 609 code that does exactly this:
 610
 611   my $buffer = ''; my $string = '';
 612   while(read $fh, $buffer, 256, length($buffer)){
 613     $string .= decode($encoding, $buffer, Encode::FB_QUIET);
 614     # $buffer now contains the unprocessed partial character
 615   }
 616
 617 =item I<CHECK> = Encode::FB_WARN
 618
 619 This is the same as above, except that it warns on error.  Handy when
 620 you are debugging the mode above.
 621
 622 =item perlqq mode (I<CHECK> = Encode::FB_PERLQQ)
 623
 624 =item HTML charref mode (I<CHECK> = Encode::FB_HTMLCREF)
 625
 626 =item XML charref mode (I<CHECK> = Encode::FB_XMLCREF)
 627
 628 For encodings that are implemented by Encode::XS, CHECK ==
 629 Encode::FB_PERLQQ turns (en|de)code into C<perlqq> fallback mode.
 630
 631 When you decode, C<\xI<HH>> will be inserted for a malformed character,
 632 where I<HH> is the hex representation of the octet  that could not be
 633 decoded to utf8.  And when you encode, C<\x{I<HHHH>}> will be inserted,
 634 where I<HHHH> is the Unicode ID of the character that cannot be found
 635 in the character repertoire of the encoding.
 636
 637 HTML/XML character reference modes are about the same, in place of
 638 C<\x{I<HHHH>}>, HTML uses C<&#I<NNN>;> where I<NNN> is a decimal number and
 639 XML uses C<&#xI<HHHH>;> where I<HHHH> is the hexadecimal number.
 640
 641 In Encode 2.10 or later, C<LEAVE_SRC> is also implied.
 642
 643 =item The bitmask
 644
 645 These modes are actually set via a bitmask.  Here is how the FB_XX
 646 constants are laid out.  You can import the FB_XX constants via
 647 C<use Encode qw(:fallbacks)>; you can import the generic bitmask
 648 constants via C<use Encode qw(:fallback_all)>.
 649
 650                      FB_DEFAULT FB_CROAK FB_QUIET FB_WARN  FB_PERLQQ
 651  DIE_ON_ERR    0x0001             X
 652  WARN_ON_ERR   0x0002                               X
 653  RETURN_ON_ERR 0x0004                      X        X
 654  LEAVE_SRC     0x0008                                        X
 655  PERLQQ        0x0100                                        X
 656  HTMLCREF      0x0200
 657  XMLCREF       0x0400
 658
 659 =back
 660
 661 =head2 coderef for CHECK
 662
 663 As of Encode 2.12 CHECK can also be a code reference which takes the
 664 ord value of unmapped caharacter as an argument and returns a string
 665 that represents the fallback character.  For instance,
 666
 667   $ascii = encode("ascii", $utf8, sub{ sprintf "<U+%04X>", shift });
 668
 669 Acts like FB_PERLQQ but E<lt>U+I<XXXX>E<gt> is used instead of
 670 \x{I<XXXX>}.
 671
 672 =head1 Defining Encodings
 673
 674 To define a new encoding, use:
 675
 676     use Encode qw(define_encoding);
 677     define_encoding($object, 'canonicalName' [, alias...]);
 678
 679 I<canonicalName> will be associated with I<$object>.  The object
 680 should provide the interface described in L<Encode::Encoding>.
 681 If more than two arguments are provided then additional
 682 arguments are taken as aliases for I<$object>.
 683
 684 See L<Encode::Encoding> for more details.
 685
 686 =head1 The UTF-8 flag
 687
 688 Before the introduction of utf8 support in perl, The C<eq> operator
 689 just compared the strings represented by two scalars. Beginning with
 690 perl 5.8, C<eq> compares two strings with simultaneous consideration
 691 of I<the utf8 flag>. To explain why we made it so, I will quote page
 692 402 of C<Programming Perl, 3rd ed.>
 693
 694 =over 2
 695
 696 =item Goal #1:
 697
 698 Old byte-oriented programs should not spontaneously break on the old
 699 byte-oriented data they used to work on.
 700
 701 =item Goal #2:
 702
 703 Old byte-oriented programs should magically start working on the new
 704 character-oriented data when appropriate.
 705
 706 =item Goal #3:
 707
 708 Programs should run just as fast in the new character-oriented mode
 709 as in the old byte-oriented mode.
 710
 711 =item Goal #4:
 712
 713 Perl should remain one language, rather than forking into a
 714 byte-oriented Perl and a character-oriented Perl.
 715
 716 =back
 717
 718 Back when C<Programming Perl, 3rd ed.> was written, not even Perl 5.6.0
 719 was born and many features documented in the book remained
 720 unimplemented for a long time.  Perl 5.8 corrected this and the introduction
 721 of the UTF-8 flag is one of them.  You can think of this perl notion as of a
 722 byte-oriented mode (utf8 flag off) and a character-oriented mode (utf8
 723 flag on).
 724
 725 Here is how Encode takes care of the utf8 flag.
 726
 727 =over 2
 728
 729 =item *
 730
 731 When you encode, the resulting utf8 flag is always off.
 732
 733 =item *
 734
 735 When you decode, the resulting utf8 flag is on unless you can
 736 unambiguously represent data.  Here is the definition of
 737 dis-ambiguity.
 738
 739 After C<$utf8 = decode('foo', $octet);>,
 740
 741   When $octet is...   The utf8 flag in $utf8 is
 742   ---------------------------------------------
 743   In ASCII only (or EBCDIC only)            OFF
 744   In ISO-8859-1                              ON
 745   In any other Encoding                      ON
 746   ---------------------------------------------
 747
 748 As you see, there is one exception, In ASCII.  That way you can assume
 749 Goal #1.  And with Encode Goal #2 is assumed but you still have to be
 750 careful in such cases mentioned in B<CAVEAT> paragraphs.
 751
 752 This utf8 flag is not visible in perl scripts, exactly for the same
 753 reason you cannot (or you I<don't have to>) see if a scalar contains a
 754 string, integer, or floating point number.   But you can still peek
 755 and poke these if you will.  See the section below.
 756
 757 =back
 758
 759 =head2 Messing with Perl's Internals
 760
 761 The following API uses parts of Perl's internals in the current
 762 implementation.  As such, they are efficient but may change.
 763
 764 =over 2
 765
 766 =item is_utf8(STRING [, CHECK])
 767
 768 [INTERNAL] Tests whether the UTF-8 flag is turned on in the STRING.
 769 If CHECK is true, also checks the data in STRING for being well-formed
 770 UTF-8.  Returns true if successful, false otherwise.
 771
 772 As of perl 5.8.1, L<utf8> also has utf8::is_utf8().
 773
 774 =item _utf8_on(STRING)
 775
 776 [INTERNAL] Turns on the UTF-8 flag in STRING.  The data in STRING is
 777 B<not> checked for being well-formed UTF-8.  Do not use unless you
 778 B<know> that the STRING is well-formed UTF-8.  Returns the previous
 779 state of the UTF-8 flag (so please don't treat the return value as
 780 indicating success or failure), or C<undef> if STRING is not a string.
 781
 782 =item _utf8_off(STRING)
 783
 784 [INTERNAL] Turns off the UTF-8 flag in STRING.  Do not use frivolously.
 785 Returns the previous state of the UTF-8 flag (so please don't treat the
 786 return value as indicating success or failure), or C<undef> if STRING is
 787 not a string.
 788
 789 =back
 790
 791 =head1 UTF-8 vs. utf8
 792
 793   ....We now view strings not as sequences of bytes, but as sequences
 794   of numbers in the range 0 .. 2**32-1 (or in the case of 64-bit
 795   computers, 0 .. 2**64-1) -- Programming Perl, 3rd ed.
 796
 797 That has been the perl's notion of UTF-8 but official UTF-8 is more
 798 strict; Its ranges is much narrower (0 .. 10FFFF), some sequences are
 799 not allowed (i.e. Those used in the surrogate pair, 0xFFFE, et al).
 800
 801 Now that is overruled by Larry Wall himself.
 802
 803   From: Larry Wall <larry@wall.org>
 804   Date: December 04, 2004 11:51:58 JST
 805   To: perl-unicode@perl.org
 806   Subject: Re: Make Encode.pm support the real UTF-8
 807   Message-Id: <20041204025158.GA28754@wall.org>
 808
 809   On Fri, Dec 03, 2004 at 10:12:12PM +0000, Tim Bunce wrote:
 810   : I've no problem with 'utf8' being perl's unrestricted uft8 encoding,
 811   : but "UTF-8" is the name of the standard and should give the
 812   : corresponding behaviour.
 813
 814   For what it's worth, that's how I've always kept them straight in my
 815   head.
 816
 817   Also for what it's worth, Perl 6 will mostly default to strict but
 818   make it easy to switch back to lax.
 819
 820   Larry
 821
 822 Do you copy?  As of Perl 5.8.7, B<UTF-8> means strict, official UTF-8
 823 while B<utf8> means liberal, lax, version thereof.  And Encode version
 824 2.10 or later thus groks the difference between C<UTF-8> and C"utf8".
 825
 826   encode("utf8",  "\x{FFFF_FFFF}", 1); # okay
 827   encode("UTF-8", "\x{FFFF_FFFF}", 1); # croaks
 828
 829 C<UTF-8> in Encode is actually a canonical name for C<utf-8-strict>.
 830 Yes, the hyphen between "UTF" and "8" is important.  Without it Encode
 831 goes "liberal"
 832
 833   find_encoding("UTF-8")->name # is 'utf-8-strict'
 834   find_encoding("utf-8")->name # ditto. names are case insensitive
 835   find_encoding("utf_8")->name  # ditto. "_" are treated as "-"
 836   find_encoding("UTF8")->name  # is 'utf8'.
 837
 838
 839 =head1 SEE ALSO
 840
 841 L<Encode::Encoding>,
 842 L<Encode::Supported>,
 843 L<Encode::PerlIO>,
 844 L<encoding>,
 845 L<perlebcdic>,
 846 L<perlfunc/open>,
 847 L<perlunicode>,
 848 L<utf8>,
 849 the Perl Unicode Mailing List E<lt>perl-unicode@perl.orgE<gt>
 850
 851 =head1 MAINTAINER
 852
 853 This project was originated by Nick Ing-Simmons and later maintained
 854 by Dan Kogai E<lt>dankogai@dan.co.jpE<gt>.  See AUTHORS for a full
 855 list of people involved.  For any questions, use
 856 E<lt>perl-unicode@perl.orgE<gt> so we can all share.
 857
 858 While Dan Kogai retains the copyright as a maintainer, the credit
 859 should go to all those involoved.  See AUTHORS for those submitted
 860 codes.
 861
 862 =head1 COPYRIGHT
 863
 864 Copyright 2002-2006 Dan Kogai E<lt>dankogai@dan.co.jpE<gt>
 865
 866 This library is free software; you can redistribute it and/or modify
 867 it under the same terms as Perl itself.
 868
 869 =cut