ext/Encode/Encode.pm

   1 #
   2 # $Id: Encode.pm,v 2.29 2009/02/01 13:10:07 dankogai Exp $
   3 #
   4 package Encode;
   5 use strict;
   6 use warnings;
   7 our $VERSION = sprintf "%d.%02d", q$Revision: 2.29 $ =~ /(\d+)/g;
   8 sub DEBUG () { 0 }
   9 use XSLoader ();
  10 XSLoader::load( __PACKAGE__, $VERSION );
  11
  12 require Exporter;
  13 use base qw/Exporter/;
  14
  15 # Public, encouraged API is exported by default
  16
  17 our @EXPORT = qw(
  18   decode  decode_utf8  encode  encode_utf8 str2bytes bytes2str
  19   encodings  find_encoding clone_encoding
  20 );
  21 our @FB_FLAGS = qw(
  22   DIE_ON_ERR WARN_ON_ERR RETURN_ON_ERR LEAVE_SRC
  23   PERLQQ HTMLCREF XMLCREF STOP_AT_PARTIAL
  24 );
  25 our @FB_CONSTS = qw(
  26   FB_DEFAULT FB_CROAK FB_QUIET FB_WARN
  27   FB_PERLQQ FB_HTMLCREF FB_XMLCREF
  28 );
  29 our @EXPORT_OK = (
  30     qw(
  31       _utf8_off _utf8_on define_encoding from_to is_16bit is_8bit
  32       is_utf8 perlio_ok resolve_alias utf8_downgrade utf8_upgrade
  33       ),
  34     @FB_FLAGS, @FB_CONSTS,
  35 );
  36
  37 our %EXPORT_TAGS = (
  38     all          => [ @EXPORT,    @EXPORT_OK ],
  39     default      => [ @EXPORT ],
  40     fallbacks    => [ @FB_CONSTS ],
  41     fallback_all => [ @FB_CONSTS, @FB_FLAGS ],
  42 );
  43
  44 # Documentation moved after __END__ for speed - NI-S
  45
  46 our $ON_EBCDIC = ( ord("A") == 193 );
  47
  48 use Encode::Alias;
  49
  50 # Make a %Encoding package variable to allow a certain amount of cheating
  51 our %Encoding;
  52 our %ExtModule;
  53 require Encode::Config;
  54 #  See
  55 #  https://bugzilla.redhat.com/show_bug.cgi?id=435505#c2
  56 #  to find why sig handers inside eval{} are disabled.
  57 eval {
  58     local $SIG{__DIE__};
  59     local $SIG{__WARN__};
  60     require Encode::ConfigLocal;
  61 };
  62
  63 sub encodings {
  64     my $class = shift;
  65     my %enc;
  66     if ( @_ and $_[0] eq ":all" ) {
  67         %enc = ( %Encoding, %ExtModule );
  68     }
  69     else {
  70         %enc = %Encoding;
  71         for my $mod ( map { m/::/o ? $_ : "Encode::$_" } @_ ) {
  72             DEBUG and warn $mod;
  73             for my $enc ( keys %ExtModule ) {
  74                 $ExtModule{$enc} eq $mod and $enc{$enc} = $mod;
  75             }
  76         }
  77     }
  78     return sort { lc $a cmp lc $b }
  79       grep      { !/^(?:Internal|Unicode|Guess)$/o } keys %enc;
  80 }
  81
  82 sub perlio_ok {
  83     my $obj = ref( $_[0] ) ? $_[0] : find_encoding( $_[0] );
  84     $obj->can("perlio_ok") and return $obj->perlio_ok();
  85     return 0;    # safety net
  86 }
  87
  88 sub define_encoding {
  89     my $obj  = shift;
  90     my $name = shift;
  91     $Encoding{$name} = $obj;
  92     my $lc = lc($name);
  93     define_alias( $lc => $obj ) unless $lc eq $name;
  94     while (@_) {
  95         my $alias = shift;
  96         define_alias( $alias, $obj );
  97     }
  98     return $obj;
  99 }
 100
 101 sub getEncoding {
 102     my ( $class, $name, $skip_external ) = @_;
 103
 104     ref($name) && $name->can('renew') and return $name;
 105     exists $Encoding{$name} and return $Encoding{$name};
 106     my $lc = lc $name;
 107     exists $Encoding{$lc} and return $Encoding{$lc};
 108
 109     my $oc = $class->find_alias($name);
 110     defined($oc) and return $oc;
 111     $lc ne $name and $oc = $class->find_alias($lc);
 112     defined($oc) and return $oc;
 113
 114     unless ($skip_external) {
 115         if ( my $mod = $ExtModule{$name} || $ExtModule{$lc} ) {
 116             $mod =~ s,::,/,g;
 117             $mod .= '.pm';
 118             eval { require $mod; };
 119             exists $Encoding{$name} and return $Encoding{$name};
 120         }
 121     }
 122     return;
 123 }
 124
 125 sub find_encoding($;$) {
 126     my ( $name, $skip_external ) = @_;
 127     return __PACKAGE__->getEncoding( $name, $skip_external );
 128 }
 129
 130 sub resolve_alias($) {
 131     my $obj = find_encoding(shift);
 132     defined $obj and return $obj->name;
 133     return;
 134 }
 135
 136 sub clone_encoding($) {
 137     my $obj = find_encoding(shift);
 138     ref $obj or return;
 139     eval { require Storable };
 140     $@ and return;
 141     return Storable::dclone($obj);
 142 }
 143
 144 sub encode($$;$) {
 145     my ( $name, $string, $check ) = @_;
 146     return undef unless defined $string;
 147     $string .= '' if ref $string;    # stringify;
 148     $check ||= 0;
 149     my $enc = find_encoding($name);
 150     unless ( defined $enc ) {
 151         require Carp;
 152         Carp::croak("Unknown encoding '$name'");
 153     }
 154     my $octets = $enc->encode( $string, $check );
 155     $_[1] = $string if $check and !ref $check and !( $check & LEAVE_SRC() );
 156     return $octets;
 157 }
 158 *str2bytes = \&encode;
 159
 160 sub decode($$;$) {
 161     my ( $name, $octets, $check ) = @_;
 162     return undef unless defined $octets;
 163     $octets .= '' if ref $octets;
 164     $check ||= 0;
 165     my $enc = find_encoding($name);
 166     unless ( defined $enc ) {
 167         require Carp;
 168         Carp::croak("Unknown encoding '$name'");
 169     }
 170     my $string = $enc->decode( $octets, $check );
 171     $_[1] = $octets if $check and !ref $check and !( $check & LEAVE_SRC() );
 172     return $string;
 173 }
 174 *bytes2str = \&decode;
 175
 176 sub from_to($$$;$) {
 177     my ( $string, $from, $to, $check ) = @_;
 178     return undef unless defined $string;
 179     $check ||= 0;
 180     my $f = find_encoding($from);
 181     unless ( defined $f ) {
 182         require Carp;
 183         Carp::croak("Unknown encoding '$from'");
 184     }
 185     my $t = find_encoding($to);
 186     unless ( defined $t ) {
 187         require Carp;
 188         Carp::croak("Unknown encoding '$to'");
 189     }
 190     my $uni = $f->decode($string);
 191     $_[0] = $string = $t->encode( $uni, $check );
 192     return undef if ( $check && length($uni) );
 193     return defined( $_[0] ) ? length($string) : undef;
 194 }
 195
 196 sub encode_utf8($) {
 197     my ($str) = @_;
 198     utf8::encode($str);
 199     return $str;
 200 }
 201
 202 sub decode_utf8($;$) {
 203     my ( $str, $check ) = @_;
 204     return $str if is_utf8($str);
 205     if ($check) {
 206         return decode( "utf8", $str, $check );
 207     }
 208     else {
 209         return decode( "utf8", $str );
 210         return $str;
 211     }
 212 }
 213
 214 predefine_encodings(1);
 215
 216 #
 217 # This is to restore %Encoding if really needed;
 218 #
 219
 220 sub predefine_encodings {
 221     require Encode::Encoding;
 222     no warnings 'redefine';
 223     my $use_xs = shift;
 224     if ($ON_EBCDIC) {
 225
 226         # was in Encode::UTF_EBCDIC
 227         package Encode::UTF_EBCDIC;
 228         push @Encode::UTF_EBCDIC::ISA, 'Encode::Encoding';
 229         *decode = sub {
 230             my ( $obj, $str, $chk ) = @_;
 231             my $res = '';
 232             for ( my $i = 0 ; $i < length($str) ; $i++ ) {
 233                 $res .=
 234                   chr(
 235                     utf8::unicode_to_native( ord( substr( $str, $i, 1 ) ) )
 236                   );
 237             }
 238             $_[1] = '' if $chk;
 239             return $res;
 240         };
 241         *encode = sub {
 242             my ( $obj, $str, $chk ) = @_;
 243             my $res = '';
 244             for ( my $i = 0 ; $i < length($str) ; $i++ ) {
 245                 $res .=
 246                   chr(
 247                     utf8::native_to_unicode( ord( substr( $str, $i, 1 ) ) )
 248                   );
 249             }
 250             $_[1] = '' if $chk;
 251             return $res;
 252         };
 253         $Encode::Encoding{Unicode} =
 254           bless { Name => "UTF_EBCDIC" } => "Encode::UTF_EBCDIC";
 255     }
 256     else {
 257
 258         package Encode::Internal;
 259         push @Encode::Internal::ISA, 'Encode::Encoding';
 260         *decode = sub {
 261             my ( $obj, $str, $chk ) = @_;
 262             utf8::upgrade($str);
 263             $_[1] = '' if $chk;
 264             return $str;
 265         };
 266         *encode = \&decode;
 267         $Encode::Encoding{Unicode} =
 268           bless { Name => "Internal" } => "Encode::Internal";
 269     }
 270
 271     {
 272
 273         # was in Encode::utf8
 274         package Encode::utf8;
 275         push @Encode::utf8::ISA, 'Encode::Encoding';
 276
 277         #
 278         if ($use_xs) {
 279             Encode::DEBUG and warn __PACKAGE__, " XS on";
 280             *decode = \&decode_xs;
 281             *encode = \&encode_xs;
 282         }
 283         else {
 284             Encode::DEBUG and warn __PACKAGE__, " XS off";
 285             *decode = sub {
 286                 my ( $obj, $octets, $chk ) = @_;
 287                 my $str = Encode::decode_utf8($octets);
 288                 if ( defined $str ) {
 289                     $_[1] = '' if $chk;
 290                     return $str;
 291                 }
 292                 return undef;
 293             };
 294             *encode = sub {
 295                 my ( $obj, $string, $chk ) = @_;
 296                 my $octets = Encode::encode_utf8($string);
 297                 $_[1] = '' if $chk;
 298                 return $octets;
 299             };
 300         }
 301         *cat_decode = sub {    # ($obj, $dst, $src, $pos, $trm, $chk)
 302                                # currently ignores $chk
 303             my ( $obj, undef, undef, $pos, $trm ) = @_;
 304             my ( $rdst, $rsrc, $rpos ) = \@_[ 1, 2, 3 ];
 305             use bytes;
 306             if ( ( my $npos = index( $$rsrc, $trm, $pos ) ) >= 0 ) {
 307                 $$rdst .=
 308                   substr( $$rsrc, $pos, $npos - $pos + length($trm) );
 309                 $$rpos = $npos + length($trm);
 310                 return 1;
 311             }
 312             $$rdst .= substr( $$rsrc, $pos );
 313             $$rpos = length($$rsrc);
 314             return '';
 315         };
 316         $Encode::Encoding{utf8} =
 317           bless { Name => "utf8" } => "Encode::utf8";
 318         $Encode::Encoding{"utf-8-strict"} =
 319           bless { Name => "utf-8-strict", strict_utf8 => 1 } =>
 320           "Encode::utf8";
 321     }
 322 }
 323
 324 1;
 325
 326 __END__
 327
 328 =head1 NAME
 329
 330 Encode - character encodings
 331
 332 =head1 SYNOPSIS
 333
 334     use Encode;
 335
 336 =head2 Table of Contents
 337
 338 Encode consists of a collection of modules whose details are too big
 339 to fit in one document.  This POD itself explains the top-level APIs
 340 and general topics at a glance.  For other topics and more details,
 341 see the PODs below:
 342
 343   Name                          Description
 344   --------------------------------------------------------
 345   Encode::Alias         Alias definitions to encodings
 346   Encode::Encoding      Encode Implementation Base Class
 347   Encode::Supported     List of Supported Encodings
 348   Encode::CN            Simplified Chinese Encodings
 349   Encode::JP            Japanese Encodings
 350   Encode::KR            Korean Encodings
 351   Encode::TW            Traditional Chinese Encodings
 352   --------------------------------------------------------
 353
 354 =head1 DESCRIPTION
 355
 356 The C<Encode> module provides the interfaces between Perl's strings
 357 and the rest of the system.  Perl strings are sequences of
 358 B<characters>.
 359
 360 The repertoire of characters that Perl can represent is at least that
 361 defined by the Unicode Consortium. On most platforms the ordinal
 362 values of the characters (as returned by C<ord(ch)>) is the "Unicode
 363 codepoint" for the character (the exceptions are those platforms where
 364 the legacy encoding is some variant of EBCDIC rather than a super-set
 365 of ASCII - see L<perlebcdic>).
 366
 367 Traditionally, computer data has been moved around in 8-bit chunks
 368 often called "bytes". These chunks are also known as "octets" in
 369 networking standards. Perl is widely used to manipulate data of many
 370 types - not only strings of characters representing human or computer
 371 languages but also "binary" data being the machine's representation of
 372 numbers, pixels in an image - or just about anything.
 373
 374 When Perl is processing "binary data", the programmer wants Perl to
 375 process "sequences of bytes". This is not a problem for Perl - as a
 376 byte has 256 possible values, it easily fits in Perl's much larger
 377 "logical character".
 378
 379 =head2 TERMINOLOGY
 380
 381 =over 2
 382
 383 =item *
 384
 385 I<character>: a character in the range 0..(2**32-1) (or more).
 386 (What Perl's strings are made of.)
 387
 388 =item *
 389
 390 I<byte>: a character in the range 0..255
 391 (A special case of a Perl character.)
 392
 393 =item *
 394
 395 I<octet>: 8 bits of data, with ordinal values 0..255
 396 (Term for bytes passed to or from a non-Perl context, e.g. a disk file.)
 397
 398 =back
 399
 400 =head1 PERL ENCODING API
 401
 402 =over 2
 403
 404 =item $octets  = encode(ENCODING, $string [, CHECK])
 405
 406 Encodes a string from Perl's internal form into I<ENCODING> and returns
 407 a sequence of octets.  ENCODING can be either a canonical name or
 408 an alias.  For encoding names and aliases, see L</"Defining Aliases">.
 409 For CHECK, see L</"Handling Malformed Data">.
 410
 411 For example, to convert a string from Perl's internal format to
 412 iso-8859-1 (also known as Latin1),
 413
 414   $octets = encode("iso-8859-1", $string);
 415
 416 B<CAVEAT>: When you run C<$octets = encode("utf8", $string)>, then
 417 $octets B<may not be equal to> $string.  Though they both contain the
 418 same data, the UTF8 flag for $octets is B<always> off.  When you
 419 encode anything, UTF8 flag of the result is always off, even when it
 420 contains completely valid utf8 string. See L</"The UTF8 flag"> below.
 421
 422 If the $string is C<undef> then C<undef> is returned.
 423
 424 =item $string = decode(ENCODING, $octets [, CHECK])
 425
 426 Decodes a sequence of octets assumed to be in I<ENCODING> into Perl's
 427 internal form and returns the resulting string.  As in encode(),
 428 ENCODING can be either a canonical name or an alias. For encoding names
 429 and aliases, see L</"Defining Aliases">.  For CHECK, see
 430 L</"Handling Malformed Data">.
 431
 432 For example, to convert ISO-8859-1 data to a string in Perl's internal format:
 433
 434   $string = decode("iso-8859-1", $octets);
 435
 436 B<CAVEAT>: When you run C<$string = decode("utf8", $octets)>, then $string
 437 B<may not be equal to> $octets.  Though they both contain the same data,
 438 the UTF8 flag for $string is on unless $octets entirely consists of
 439 ASCII data (or EBCDIC on EBCDIC machines).  See L</"The UTF8 flag">
 440 below.
 441
 442 If the $string is C<undef> then C<undef> is returned.
 443
 444 =item [$obj =] find_encoding(ENCODING)
 445
 446 Returns the I<encoding object> corresponding to ENCODING.  Returns
 447 undef if no matching ENCODING is find.
 448
 449 This object is what actually does the actual (en|de)coding.
 450
 451   $utf8 = decode($name, $bytes);
 452
 453 is in fact
 454
 455   $utf8 = do{
 456     $obj = find_encoding($name);
 457     croak qq(encoding "$name" not found) unless ref $obj;
 458     $obj->decode($bytes)
 459   };
 460
 461 with more error checking.
 462
 463 Therefore you can save time by reusing this object as follows;
 464
 465   my $enc = find_encoding("iso-8859-1");
 466   while(<>){
 467      my $utf8 = $enc->decode($_);
 468      # and do someting with $utf8;
 469   }
 470
 471 Besides C<< ->decode >> and C<< ->encode >>, other methods are
 472 available as well.  For instance, C<< -> name >> returns the canonical
 473 name of the encoding object.
 474
 475   find_encoding("latin1")->name; # iso-8859-1
 476
 477 See L<Encode::Encoding> for details.
 478
 479 =item [$length =] from_to($octets, FROM_ENC, TO_ENC [, CHECK])
 480
 481 Converts B<in-place> data between two encodings. The data in $octets
 482 must be encoded as octets and not as characters in Perl's internal
 483 format. For example, to convert ISO-8859-1 data to Microsoft's CP1250
 484 encoding:
 485
 486   from_to($octets, "iso-8859-1", "cp1250");
 487
 488 and to convert it back:
 489
 490   from_to($octets, "cp1250", "iso-8859-1");
 491
 492 Note that because the conversion happens in place, the data to be
 493 converted cannot be a string constant; it must be a scalar variable.
 494
 495 from_to() returns the length of the converted string in octets on
 496 success, I<undef> on error.
 497
 498 B<CAVEAT>: The following operations look the same but are not quite so;
 499
 500   from_to($data, "iso-8859-1", "utf8"); #1
 501   $data = decode("iso-8859-1", $data);  #2
 502
 503 Both #1 and #2 make $data consist of a completely valid UTF-8 string
 504 but only #2 turns UTF8 flag on.  #1 is equivalent to
 505
 506   $data = encode("utf8", decode("iso-8859-1", $data));
 507
 508 See L</"The UTF8 flag"> below.
 509
 510 Also note that
 511
 512   from_to($octets, $from, $to, $check);
 513
 514 is equivalent to
 515
 516   $octets = encode($to, decode($from, $octets), $check);
 517
 518 Yes, it does not respect the $check during decoding.  It is
 519 deliberately done that way.  If you need minute control, C<decode>
 520 then C<encode> as follows;
 521
 522   $octets = encode($to, decode($from, $octets, $check_from), $check_to);
 523
 524 =item $octets = encode_utf8($string);
 525
 526 Equivalent to C<$octets = encode("utf8", $string);> The characters
 527 that comprise $string are encoded in Perl's internal format and the
 528 result is returned as a sequence of octets. All possible
 529 characters have a UTF-8 representation so this function cannot fail.
 530
 531
 532 =item $string = decode_utf8($octets [, CHECK]);
 533
 534 equivalent to C<$string = decode("utf8", $octets [, CHECK])>.
 535 The sequence of octets represented by
 536 $octets is decoded from UTF-8 into a sequence of logical
 537 characters. Not all sequences of octets form valid UTF-8 encodings, so
 538 it is possible for this call to fail.  For CHECK, see
 539 L</"Handling Malformed Data">.
 540
 541 =back
 542
 543 =head2 Listing available encodings
 544
 545   use Encode;
 546   @list = Encode->encodings();
 547
 548 Returns a list of the canonical names of the available encodings that
 549 are loaded.  To get a list of all available encodings including the
 550 ones that are not loaded yet, say
 551
 552   @all_encodings = Encode->encodings(":all");
 553
 554 Or you can give the name of a specific module.
 555
 556   @with_jp = Encode->encodings("Encode::JP");
 557
 558 When "::" is not in the name, "Encode::" is assumed.
 559
 560   @ebcdic = Encode->encodings("EBCDIC");
 561
 562 To find out in detail which encodings are supported by this package,
 563 see L<Encode::Supported>.
 564
 565 =head2 Defining Aliases
 566
 567 To add a new alias to a given encoding, use:
 568
 569   use Encode;
 570   use Encode::Alias;
 571   define_alias(newName => ENCODING);
 572
 573 After that, newName can be used as an alias for ENCODING.
 574 ENCODING may be either the name of an encoding or an
 575 I<encoding object>
 576
 577 But before you do so, make sure the alias is nonexistent with
 578 C<resolve_alias()>, which returns the canonical name thereof.
 579 i.e.
 580
 581   Encode::resolve_alias("latin1") eq "iso-8859-1" # true
 582   Encode::resolve_alias("iso-8859-12")   # false; nonexistent
 583   Encode::resolve_alias($name) eq $name  # true if $name is canonical
 584
 585 resolve_alias() does not need C<use Encode::Alias>; it can be
 586 exported via C<use Encode qw(resolve_alias)>.
 587
 588 See L<Encode::Alias> for details.
 589
 590 =head2 Finding IANA Character Set Registry names
 591
 592 The canonical name of a given encoding does not necessarily agree with
 593 IANA IANA Character Set Registry, commonly seen as C<< Content-Type:
 594 text/plain; charset=I<whatever> >>.  For most cases canonical names
 595 work but sometimes it does not (notably 'utf-8-strict').
 596
 597 Therefore as of Encode version 2.21, a new method C<mime_name()> is added.
 598
 599   use Encode;
 600   my $enc = find_encoding('UTF-8');
 601   warn $enc->name;      # utf-8-strict
 602   warn $enc->mime_name; # UTF-8
 603
 604 See also:  L<Encode::Encoding>
 605
 606 =head1 Encoding via PerlIO
 607
 608 If your perl supports I<PerlIO> (which is the default), you can use a
 609 PerlIO layer to decode and encode directly via a filehandle.  The
 610 following two examples are totally identical in their functionality.
 611
 612   # via PerlIO
 613   open my $in,  "<:encoding(shiftjis)", $infile  or die;
 614   open my $out, ">:encoding(euc-jp)",   $outfile or die;
 615   while(<$in>){ print $out $_; }
 616
 617   # via from_to
 618   open my $in,  "<", $infile  or die;
 619   open my $out, ">", $outfile or die;
 620   while(<$in>){
 621     from_to($_, "shiftjis", "euc-jp", 1);
 622     print $out $_;
 623   }
 624
 625 Unfortunately, it may be that encodings are PerlIO-savvy.  You can check
 626 if your encoding is supported by PerlIO by calling the C<perlio_ok>
 627 method.
 628
 629   Encode::perlio_ok("hz");             # False
 630   find_encoding("euc-cn")->perlio_ok;  # True where PerlIO is available
 631
 632   use Encode qw(perlio_ok);            # exported upon request
 633   perlio_ok("euc-jp")
 634
 635 Fortunately, all encodings that come with Encode core are PerlIO-savvy
 636 except for hz and ISO-2022-kr.  For gory details, see
 637 L<Encode::Encoding> and L<Encode::PerlIO>.
 638
 639 =head1 Handling Malformed Data
 640
 641 The optional I<CHECK> argument tells Encode what to do when it
 642 encounters malformed data.  Without CHECK, Encode::FB_DEFAULT ( == 0 )
 643 is assumed.
 644
 645 As of version 2.12 Encode supports coderef values for CHECK.  See below.
 646
 647 =over 2
 648
 649 =item B<NOTE:> Not all encoding support this feature
 650
 651 Some encodings ignore I<CHECK> argument.  For example,
 652 L<Encode::Unicode> ignores I<CHECK> and it always croaks on error.
 653
 654 =back
 655
 656 Now here is the list of I<CHECK> values available
 657
 658 =over 2
 659
 660 =item I<CHECK> = Encode::FB_DEFAULT ( == 0)
 661
 662 If I<CHECK> is 0, (en|de)code will put a I<substitution character> in
 663 place of a malformed character.  When you encode, E<lt>subcharE<gt>
 664 will be used.  When you decode the code point C<0xFFFD> is used.  If
 665 the data is supposed to be UTF-8, an optional lexical warning
 666 (category utf8) is given.
 667
 668 =item I<CHECK> = Encode::FB_CROAK ( == 1)
 669
 670 If I<CHECK> is 1, methods will die on error immediately with an error
 671 message.  Therefore, when I<CHECK> is set to 1,  you should trap the
 672 error with eval{} unless you really want to let it die.
 673
 674 =item I<CHECK> = Encode::FB_QUIET
 675
 676 If I<CHECK> is set to Encode::FB_QUIET, (en|de)code will immediately
 677 return the portion of the data that has been processed so far when an
 678 error occurs. The data argument will be overwritten with everything
 679 after that point (that is, the unprocessed part of data).  This is
 680 handy when you have to call decode repeatedly in the case where your
 681 source data may contain partial multi-byte character sequences,
 682 (i.e. you are reading with a fixed-width buffer). Here is a sample
 683 code that does exactly this:
 684
 685   my $buffer = ''; my $string = '';
 686   while(read $fh, $buffer, 256, length($buffer)){
 687     $string .= decode($encoding, $buffer, Encode::FB_QUIET);
 688     # $buffer now contains the unprocessed partial character
 689   }
 690
 691 =item I<CHECK> = Encode::FB_WARN
 692
 693 This is the same as above, except that it warns on error.  Handy when
 694 you are debugging the mode above.
 695
 696 =item perlqq mode (I<CHECK> = Encode::FB_PERLQQ)
 697
 698 =item HTML charref mode (I<CHECK> = Encode::FB_HTMLCREF)
 699
 700 =item XML charref mode (I<CHECK> = Encode::FB_XMLCREF)
 701
 702 For encodings that are implemented by Encode::XS, CHECK ==
 703 Encode::FB_PERLQQ turns (en|de)code into C<perlqq> fallback mode.
 704
 705 When you decode, C<\xI<HH>> will be inserted for a malformed character,
 706 where I<HH> is the hex representation of the octet  that could not be
 707 decoded to utf8.  And when you encode, C<\x{I<HHHH>}> will be inserted,
 708 where I<HHHH> is the Unicode ID of the character that cannot be found
 709 in the character repertoire of the encoding.
 710
 711 HTML/XML character reference modes are about the same, in place of
 712 C<\x{I<HHHH>}>, HTML uses C<&#I<NNN>;> where I<NNN> is a decimal number and
 713 XML uses C<&#xI<HHHH>;> where I<HHHH> is the hexadecimal number.
 714
 715 In Encode 2.10 or later, C<LEAVE_SRC> is also implied.
 716
 717 =item The bitmask
 718
 719 These modes are actually set via a bitmask.  Here is how the FB_XX
 720 constants are laid out.  You can import the FB_XX constants via
 721 C<use Encode qw(:fallbacks)>; you can import the generic bitmask
 722 constants via C<use Encode qw(:fallback_all)>.
 723
 724                      FB_DEFAULT FB_CROAK FB_QUIET FB_WARN  FB_PERLQQ
 725  DIE_ON_ERR    0x0001             X
 726  WARN_ON_ERR   0x0002                               X
 727  RETURN_ON_ERR 0x0004                      X        X
 728  LEAVE_SRC     0x0008                                        X
 729  PERLQQ        0x0100                                        X
 730  HTMLCREF      0x0200
 731  XMLCREF       0x0400
 732
 733 =back
 734
 735 =over 2
 736
 737 =item Encode::LEAVE_SRC
 738
 739 If the C<Encode::LEAVE_SRC> bit is not set, but I<CHECK> is, then the second
 740 argument to C<encode()> or C<decode()> may be assigned to by the functions. If
 741 you're not interested in this, then bitwise-or the bitmask with it.
 742
 743 =back
 744
 745 =head2 coderef for CHECK
 746
 747 As of Encode 2.12 CHECK can also be a code reference which takes the
 748 ord value of unmapped caharacter as an argument and returns a string
 749 that represents the fallback character.  For instance,
 750
 751   $ascii = encode("ascii", $utf8, sub{ sprintf "<U+%04X>", shift });
 752
 753 Acts like FB_PERLQQ but E<lt>U+I<XXXX>E<gt> is used instead of
 754 \x{I<XXXX>}.
 755
 756 =head1 Defining Encodings
 757
 758 To define a new encoding, use:
 759
 760     use Encode qw(define_encoding);
 761     define_encoding($object, 'canonicalName' [, alias...]);
 762
 763 I<canonicalName> will be associated with I<$object>.  The object
 764 should provide the interface described in L<Encode::Encoding>.
 765 If more than two arguments are provided then additional
 766 arguments are taken as aliases for I<$object>.
 767
 768 See L<Encode::Encoding> for more details.
 769
 770 =head1 The UTF8 flag
 771
 772 Before the introduction of Unicode support in perl, The C<eq> operator
 773 just compared the strings represented by two scalars. Beginning with
 774 perl 5.8, C<eq> compares two strings with simultaneous consideration of
 775 I<the UTF8 flag>. To explain why we made it so, I will quote page 402 of
 776 C<Programming Perl, 3rd ed.>
 777
 778 =over 2
 779
 780 =item Goal #1:
 781
 782 Old byte-oriented programs should not spontaneously break on the old
 783 byte-oriented data they used to work on.
 784
 785 =item Goal #2:
 786
 787 Old byte-oriented programs should magically start working on the new
 788 character-oriented data when appropriate.
 789
 790 =item Goal #3:
 791
 792 Programs should run just as fast in the new character-oriented mode
 793 as in the old byte-oriented mode.
 794
 795 =item Goal #4:
 796
 797 Perl should remain one language, rather than forking into a
 798 byte-oriented Perl and a character-oriented Perl.
 799
 800 =back
 801
 802 Back when C<Programming Perl, 3rd ed.> was written, not even Perl 5.6.0
 803 was born and many features documented in the book remained
 804 unimplemented for a long time.  Perl 5.8 corrected this and the introduction
 805 of the UTF8 flag is one of them.  You can think of this perl notion as of a
 806 byte-oriented mode (UTF8 flag off) and a character-oriented mode (UTF8
 807 flag on).
 808
 809 Here is how Encode takes care of the UTF8 flag.
 810
 811 =over 2
 812
 813 =item *
 814
 815 When you encode, the resulting UTF8 flag is always off.
 816
 817 =item *
 818
 819 When you decode, the resulting UTF8 flag is on unless you can
 820 unambiguously represent data.  Here is the definition of
 821 dis-ambiguity.
 822
 823 After C<$utf8 = decode('foo', $octet);>,
 824
 825   When $octet is...   The UTF8 flag in $utf8 is
 826   ---------------------------------------------
 827   In ASCII only (or EBCDIC only)            OFF
 828   In ISO-8859-1                              ON
 829   In any other Encoding                      ON
 830   ---------------------------------------------
 831
 832 As you see, there is one exception, In ASCII.  That way you can assume
 833 Goal #1.  And with Encode Goal #2 is assumed but you still have to be
 834 careful in such cases mentioned in B<CAVEAT> paragraphs.
 835
 836 This UTF8 flag is not visible in perl scripts, exactly for the same
 837 reason you cannot (or you I<don't have to>) see if a scalar contains a
 838 string, integer, or floating point number.   But you can still peek
 839 and poke these if you will.  See the section below.
 840
 841 =back
 842
 843 =head2 Messing with Perl's Internals
 844
 845 The following API uses parts of Perl's internals in the current
 846 implementation.  As such, they are efficient but may change.
 847
 848 =over 2
 849
 850 =item is_utf8(STRING [, CHECK])
 851
 852 [INTERNAL] Tests whether the UTF8 flag is turned on in the STRING.
 853 If CHECK is true, also checks the data in STRING for being well-formed
 854 UTF-8.  Returns true if successful, false otherwise.
 855
 856 As of perl 5.8.1, L<utf8> also has utf8::is_utf8().
 857
 858 =item _utf8_on(STRING)
 859
 860 [INTERNAL] Turns on the UTF8 flag in STRING.  The data in STRING is
 861 B<not> checked for being well-formed UTF-8.  Do not use unless you
 862 B<know> that the STRING is well-formed UTF-8.  Returns the previous
 863 state of the UTF8 flag (so please don't treat the return value as
 864 indicating success or failure), or C<undef> if STRING is not a string.
 865
 866 This function does not work on tainted values.
 867
 868 =item _utf8_off(STRING)
 869
 870 [INTERNAL] Turns off the UTF8 flag in STRING.  Do not use frivolously.
 871 Returns the previous state of the UTF8 flag (so please don't treat the
 872 return value as indicating success or failure), or C<undef> if STRING is
 873 not a string.
 874
 875 This function does not work on tainted values.
 876
 877 =back
 878
 879 =head1 UTF-8 vs. utf8 vs. UTF8
 880
 881   ....We now view strings not as sequences of bytes, but as sequences
 882   of numbers in the range 0 .. 2**32-1 (or in the case of 64-bit
 883   computers, 0 .. 2**64-1) -- Programming Perl, 3rd ed.
 884
 885 That has been the perl's notion of UTF-8 but official UTF-8 is more
 886 strict; Its ranges is much narrower (0 .. 10FFFF), some sequences are
 887 not allowed (i.e. Those used in the surrogate pair, 0xFFFE, et al).
 888
 889 Now that is overruled by Larry Wall himself.
 890
 891   From: Larry Wall <larry@wall.org>
 892   Date: December 04, 2004 11:51:58 JST
 893   To: perl-unicode@perl.org
 894   Subject: Re: Make Encode.pm support the real UTF-8
 895   Message-Id: <20041204025158.GA28754@wall.org>
 896
 897   On Fri, Dec 03, 2004 at 10:12:12PM +0000, Tim Bunce wrote:
 898   : I've no problem with 'utf8' being perl's unrestricted uft8 encoding,
 899   : but "UTF-8" is the name of the standard and should give the
 900   : corresponding behaviour.
 901
 902   For what it's worth, that's how I've always kept them straight in my
 903   head.
 904
 905   Also for what it's worth, Perl 6 will mostly default to strict but
 906   make it easy to switch back to lax.
 907
 908   Larry
 909
 910 Do you copy?  As of Perl 5.8.7, B<UTF-8> means strict, official UTF-8
 911 while B<utf8> means liberal, lax, version thereof.  And Encode version
 912 2.10 or later thus groks the difference between C<UTF-8> and C"utf8".
 913
 914   encode("utf8",  "\x{FFFF_FFFF}", 1); # okay
 915   encode("UTF-8", "\x{FFFF_FFFF}", 1); # croaks
 916
 917 C<UTF-8> in Encode is actually a canonical name for C<utf-8-strict>.
 918 Yes, the hyphen between "UTF" and "8" is important.  Without it Encode
 919 goes "liberal"
 920
 921   find_encoding("UTF-8")->name # is 'utf-8-strict'
 922   find_encoding("utf-8")->name # ditto. names are case insensitive
 923   find_encoding("utf_8")->name  # ditto. "_" are treated as "-"
 924   find_encoding("UTF8")->name  # is 'utf8'.
 925
 926 The UTF8 flag is internally called UTF8, without a hyphen. It indicates
 927 whether a string is internally encoded as utf8, also without a hypen.
 928
 929 =head1 SEE ALSO
 930
 931 L<Encode::Encoding>,
 932 L<Encode::Supported>,
 933 L<Encode::PerlIO>,
 934 L<encoding>,
 935 L<perlebcdic>,
 936 L<perlfunc/open>,
 937 L<perlunicode>, L<perluniintro>, L<perlunifaq>, L<perlunitut>
 938 L<utf8>,
 939 the Perl Unicode Mailing List E<lt>perl-unicode@perl.orgE<gt>
 940
 941 =head1 MAINTAINER
 942
 943 This project was originated by Nick Ing-Simmons and later maintained
 944 by Dan Kogai E<lt>dankogai@dan.co.jpE<gt>.  See AUTHORS for a full
 945 list of people involved.  For any questions, use
 946 E<lt>perl-unicode@perl.orgE<gt> so we can all share.
 947
 948 While Dan Kogai retains the copyright as a maintainer, the credit
 949 should go to all those involoved.  See AUTHORS for those submitted
 950 codes.
 951
 952 =head1 COPYRIGHT
 953
 954 Copyright 2002-2006 Dan Kogai E<lt>dankogai@dan.co.jpE<gt>
 955
 956 This library is free software; you can redistribute it and/or modify
 957 it under the same terms as Perl itself.
 958
 959 =cut