ext/DynaLoader/t/XSLoader.t

   1 #!/usr/bin/perl -T
   2
   3 BEGIN {
   4     if( $ENV{PERL_CORE} ) {
   5         chdir 't';
   6         @INC = '../lib';
   7     }
   8 }
   9
  10 use strict;
  11 use Config;
  12
  13 my $db_file;
  14 BEGIN {
  15     eval "use Test::More";
  16     if ($@) {
  17         print "1..0 # Skip: Test::More not available\n";
  18         die "Test::More not available\n";
  19     }
  20
  21     use Config;
  22     foreach (qw/SDBM_File GDBM_File ODBM_File NDBM_File DB_File/) {
  23         if ($Config{extensions} =~ /\b$_\b/) {
  24             $db_file = $_;
  25             last;
  26         }
  27     }
  28 }
  29
  30
  31 my %modules = (
  32     # ModuleName  => q|code to check that it was loaded|,
  33     'Cwd'        => q| ::can_ok( 'Cwd' => 'fastcwd'         ) |,  # 5.7 ?
  34     'File::Glob' => q| ::can_ok( 'File::Glob' => 'doglob'   ) |,  # 5.6
  35     $db_file     => q| ::can_ok( $db_file => 'TIEHASH'      ) |,  # 5.0
  36     'Socket'     => q| ::can_ok( 'Socket' => 'inet_aton'    ) |,  # 5.0
  37     'Time::HiRes'=> q| ::can_ok( 'Time::HiRes' => 'usleep'  ) |,  # 5.7.3
  38 );
  39
  40 plan tests => keys(%modules) * 3 + 5;
  41
  42 # Try to load the module
  43 use_ok( 'XSLoader' );
  44
  45 # Check functions
  46 can_ok( 'XSLoader' => 'load' );
  47 can_ok( 'XSLoader' => 'bootstrap_inherit' );
  48
  49 # Check error messages
  50 eval { XSLoader::load() };
  51 like( $@, '/^XSLoader::load\(\'Your::Module\', \$Your::Module::VERSION\)/',
  52         "calling XSLoader::load() with no argument" );
  53
  54 eval q{ package Thwack; XSLoader::load('Thwack'); };
  55 like( $@, q{/^Can't locate loadable object for module Thwack in @INC/},
  56         "calling XSLoader::load() under a package with no XS part" );
  57
  58 # Now try to load well known XS modules
  59 my $extensions = $Config{'extensions'};
  60 $extensions =~ s|/|::|g;
  61
  62 for my $module (sort keys %modules) {
  63     SKIP: {
  64         skip "$module not available", 3 if $extensions !~ /\b$module\b/;
  65
  66         eval qq{ package $module; XSLoader::load('$module', "qunckkk"); };
  67         like( $@, "/^$module object version \\S+ does not match bootstrap parameter (?:qunckkk|0)/",
  68                 "calling XSLoader::load() with a XS module and an incorrect version" );
  69
  70         eval qq{ package $module; XSLoader::load('$module'); };
  71         is( $@, '',  "XSLoader::load($module)");
  72
  73         eval qq{ package $module; $modules{$module}; };
  74     }
  75 }
  76