ext/DynaLoader/XSLoader_pm.PL

   1 use strict;
   2 use Config;
   3
   4 sub to_string {
   5     my ($value) = @_;
   6     $value =~ s/\\/\\\\/g;
   7     $value =~ s/'/\\'/g;
   8     return "'$value'";
   9 }
  10
  11 1 while unlink "XSLoader.pm";
  12 open OUT, ">XSLoader.pm" or die $!;
  13 print OUT <<'EOT';
  14 # Generated from XSLoader.pm.PL (resolved %Config::Config value)
  15
  16 package XSLoader;
  17
  18 $VERSION = "0.07";
  19
  20 #use strict;
  21
  22 # enable debug/trace messages from DynaLoader perl code
  23 # $dl_debug = $ENV{PERL_DL_DEBUG} || 0 unless defined $dl_debug;
  24
  25 EOT
  26
  27 print OUT '  my $dl_dlext = ', to_string($Config::Config{'dlext'}), ";\n" ;
  28
  29 print OUT <<'EOT';
  30
  31 package DynaLoader;
  32
  33 # No prizes for guessing why we don't say 'bootstrap DynaLoader;' here.
  34 # NOTE: All dl_*.xs (including dl_none.xs) define a dl_error() XSUB
  35 boot_DynaLoader('DynaLoader') if defined(&boot_DynaLoader) &&
  36                                 !defined(&dl_error);
  37 package XSLoader;
  38
  39 sub load {
  40     package DynaLoader;
  41
  42     die q{XSLoader::load('Your::Module', $Your::Module::VERSION)} unless @_;
  43
  44     my($module) = $_[0];
  45
  46     # work with static linking too
  47     my $b = "$module\::bootstrap";
  48     goto &$b if defined &$b;
  49
  50     goto retry unless $module and defined &dl_load_file;
  51
  52     my @modparts = split(/::/,$module);
  53     my $modfname = $modparts[-1];
  54
  55 EOT
  56
  57 print OUT <<'EOT' if defined &DynaLoader::mod2fname;
  58     # Some systems have restrictions on files names for DLL's etc.
  59     # mod2fname returns appropriate file base name (typically truncated)
  60     # It may also edit @modparts if required.
  61     $modfname = &mod2fname(\@modparts) if defined &mod2fname;
  62
  63 EOT
  64
  65 print OUT <<'EOT';
  66     my $modpname = join('/',@modparts);
  67     my $modlibname = (caller())[1];
  68     my $c = @modparts;
  69     $modlibname =~ s,[\\/][^\\/]+$,, while $c--;        # Q&D basename
  70     my $file = "$modlibname/auto/$modpname/$modfname.$dl_dlext";
  71
  72 #   print STDERR "XSLoader::load for $module ($file)\n" if $dl_debug;
  73
  74     my $bs = $file;
  75     $bs =~ s/(\.\w+)?(;\d*)?$/\.bs/; # look for .bs 'beside' the library
  76
  77     goto retry if not -f $file or -s $bs;
  78
  79     my $bootname = "boot_$module";
  80     $bootname =~ s/\W/_/g;
  81     @DynaLoader::dl_require_symbols = ($bootname);
  82
  83     my $boot_symbol_ref;
  84
  85 EOT
  86
  87     if ($^O eq 'darwin') {
  88 print OUT <<'EOT';
  89         if ($boot_symbol_ref = dl_find_symbol(0, $bootname)) {
  90             goto boot; #extension library has already been loaded, e.g. darwin
  91         }
  92 EOT
  93     }
  94
  95 print OUT <<'EOT';
  96     # Many dynamic extension loading problems will appear to come from
  97     # this section of code: XYZ failed at line 123 of DynaLoader.pm.
  98     # Often these errors are actually occurring in the initialisation
  99     # C code of the extension XS file. Perl reports the error as being
 100     # in this perl code simply because this was the last perl code
 101     # it executed.
 102
 103     my $libref = dl_load_file($file, 0) or do {
 104         require Carp;
 105         Carp::croak("Can't load '$file' for module $module: " . dl_error());
 106     };
 107     push(@DynaLoader::dl_librefs,$libref);  # record loaded object
 108
 109     my @unresolved = dl_undef_symbols();
 110     if (@unresolved) {
 111         require Carp;
 112         Carp::carp("Undefined symbols present after loading $file: @unresolved\n");
 113     }
 114
 115     $boot_symbol_ref = dl_find_symbol($libref, $bootname) or do {
 116         require Carp;
 117         Carp::croak("Can't find '$bootname' symbol in $file\n");
 118     };
 119
 120     push(@DynaLoader::dl_modules, $module); # record loaded module
 121
 122   boot:
 123     my $xs = dl_install_xsub("${module}::bootstrap", $boot_symbol_ref, $file);
 124
 125     # See comment block above
 126     push(@DynaLoader::dl_shared_objects, $file); # record files loaded
 127     return &$xs(@_);
 128
 129   retry:
 130     my $bootstrap_inherit = DynaLoader->can('bootstrap_inherit') ||
 131                             XSLoader->can('bootstrap_inherit');
 132     goto &$bootstrap_inherit;
 133 }
 134
 135 # Versions of DynaLoader prior to 5.6.0 don't have this function.
 136 sub bootstrap_inherit {
 137     package DynaLoader;
 138
 139     my $module = $_[0];
 140     local *DynaLoader::isa = *{"$module\::ISA"};
 141     local @DynaLoader::isa = (@DynaLoader::isa, 'DynaLoader');
 142     # Cannot goto due to delocalization.  Will report errors on a wrong line?
 143     require DynaLoader;
 144     DynaLoader::bootstrap(@_);
 145 }
 146
 147 1;
 148
 149
 150 __END__
 151
 152 =head1 NAME
 153
 154 XSLoader - Dynamically load C libraries into Perl code
 155
 156 =head1 VERSION
 157
 158 Version 0.07
 159
 160 =head1 SYNOPSIS
 161
 162     package YourPackage;
 163     use XSLoader;
 164
 165     XSLoader::load 'YourPackage', $YourPackage::VERSION;
 166
 167 =head1 DESCRIPTION
 168
 169 This module defines a standard I<simplified> interface to the dynamic
 170 linking mechanisms available on many platforms.  Its primary purpose is
 171 to implement cheap automatic dynamic loading of Perl modules.
 172
 173 For a more complicated interface, see L<DynaLoader>.  Many (most)
 174 features of C<DynaLoader> are not implemented in C<XSLoader>, like for
 175 example the C<dl_load_flags>, not honored by C<XSLoader>.
 176
 177 =head2 Migration from C<DynaLoader>
 178
 179 A typical module using L<DynaLoader|DynaLoader> starts like this:
 180
 181     package YourPackage;
 182     require DynaLoader;
 183
 184     our @ISA = qw( OnePackage OtherPackage DynaLoader );
 185     our $VERSION = '0.01';
 186     bootstrap YourPackage $VERSION;
 187
 188 Change this to
 189
 190     package YourPackage;
 191     use XSLoader;
 192
 193     our @ISA = qw( OnePackage OtherPackage );
 194     our $VERSION = '0.01';
 195     XSLoader::load 'YourPackage', $VERSION;
 196
 197 In other words: replace C<require DynaLoader> by C<use XSLoader>, remove
 198 C<DynaLoader> from C<@ISA>, change C<bootstrap> by C<XSLoader::load>.  Do not
 199 forget to quote the name of your package on the C<XSLoader::load> line,
 200 and add comma (C<,>) before the arguments (C<$VERSION> above).
 201
 202 Of course, if C<@ISA> contained only C<DynaLoader>, there is no need to have
 203 the C<@ISA> assignment at all; moreover, if instead of C<our> one uses the
 204 more backward-compatible
 205
 206     use vars qw($VERSION @ISA);
 207
 208 one can remove this reference to C<@ISA> together with the C<@ISA> assignment.
 209
 210 If no C<$VERSION> was specified on the C<bootstrap> line, the last line becomes
 211
 212     XSLoader::load 'YourPackage';
 213
 214 =head2 Backward compatible boilerplate
 215
 216 If you want to have your cake and eat it too, you need a more complicated
 217 boilerplate.
 218
 219     package YourPackage;
 220     use vars qw($VERSION @ISA);
 221
 222     @ISA = qw( OnePackage OtherPackage );
 223     $VERSION = '0.01';
 224     eval {
 225        require XSLoader;
 226        XSLoader::load('YourPackage', $VERSION);
 227        1;
 228     } or do {
 229        require DynaLoader;
 230        push @ISA, 'DynaLoader';
 231        bootstrap YourPackage $VERSION;
 232     };
 233
 234 The parentheses about C<XSLoader::load()> arguments are needed since we replaced
 235 C<use XSLoader> by C<require>, so the compiler does not know that a function
 236 C<XSLoader::load()> is present.
 237
 238 This boilerplate uses the low-overhead C<XSLoader> if present; if used with
 239 an antic Perl which has no C<XSLoader>, it falls back to using C<DynaLoader>.
 240
 241 =head1 Order of initialization: early load()
 242
 243 I<Skip this section if the XSUB functions are supposed to be called from other
 244 modules only; read it only if you call your XSUBs from the code in your module,
 245 or have a C<BOOT:> section in your XS file (see L<perlxs/"The BOOT: Keyword">).
 246 What is described here is equally applicable to the L<DynaLoader|DynaLoader>
 247 interface.>
 248
 249 A sufficiently complicated module using XS would have both Perl code (defined
 250 in F<YourPackage.pm>) and XS code (defined in F<YourPackage.xs>).  If this
 251 Perl code makes calls into this XS code, and/or this XS code makes calls to
 252 the Perl code, one should be careful with the order of initialization.
 253
 254 The call to C<XSLoader::load()> (or C<bootstrap()>) has three side effects:
 255
 256 =over
 257
 258 =item *
 259
 260 if C<$VERSION> was specified, a sanity check is done to ensure that the
 261 versions of the F<.pm> and the (compiled) F<.xs> parts are compatible;
 262
 263 =item *
 264
 265 the XSUBs are made accessible from Perl;
 266
 267 =item *
 268
 269 if a C<BOOT:> section was present in the F<.xs> file, the code there is called.
 270
 271 =back
 272
 273 Consequently, if the code in the F<.pm> file makes calls to these XSUBs, it is
 274 convenient to have XSUBs installed before the Perl code is defined; for
 275 example, this makes prototypes for XSUBs visible to this Perl code.
 276 Alternatively, if the C<BOOT:> section makes calls to Perl functions (or
 277 uses Perl variables) defined in the F<.pm> file, they must be defined prior to
 278 the call to C<XSLoader::load()> (or C<bootstrap()>).
 279
 280 The first situation being much more frequent, it makes sense to rewrite the
 281 boilerplate as
 282
 283     package YourPackage;
 284     use XSLoader;
 285     use vars qw($VERSION @ISA);
 286
 287     BEGIN {
 288        @ISA = qw( OnePackage OtherPackage );
 289        $VERSION = '0.01';
 290
 291        # Put Perl code used in the BOOT: section here
 292
 293        XSLoader::load 'YourPackage', $VERSION;
 294     }
 295
 296     # Put Perl code making calls into XSUBs here
 297
 298 =head2 The most hairy case
 299
 300 If the interdependence of your C<BOOT:> section and Perl code is
 301 more complicated than this (e.g., the C<BOOT:> section makes calls to Perl
 302 functions which make calls to XSUBs with prototypes), get rid of the C<BOOT:>
 303 section altogether.  Replace it with a function C<onBOOT()>, and call it like
 304 this:
 305
 306     package YourPackage;
 307     use XSLoader;
 308     use vars qw($VERSION @ISA);
 309
 310     BEGIN {
 311        @ISA = qw( OnePackage OtherPackage );
 312        $VERSION = '0.01';
 313        XSLoader::load 'YourPackage', $VERSION;
 314     }
 315
 316     # Put Perl code used in onBOOT() function here; calls to XSUBs are
 317     # prototype-checked.
 318
 319     onBOOT;
 320
 321     # Put Perl initialization code assuming that XS is initialized here
 322
 323
 324 =head1 DIAGNOSTICS
 325
 326 =over
 327
 328 =item C<Can't find '%s' symbol in %s>
 329
 330 B<(F)> The bootstrap symbol could not be found in the extension module.
 331
 332 =item C<Can't load '%s' for module %s: %s>
 333
 334 B<(F)> The loading or initialisation of the extension module failed.
 335 The detailed error follows.
 336
 337 =item C<Undefined symbols present after loading %s: %s>
 338
 339 B<(W)> As the message says, some symbols stay undefined although the
 340 extension module was correctly loaded and initialised. The list of undefined
 341 symbols follows.
 342
 343 =item C<XSLoader::load('Your::Module', $Your::Module::VERSION)>
 344
 345 B<(F)> You tried to invoke C<load()> without any argument. You must supply
 346 a module name, and optionally its version.
 347
 348 =back
 349
 350
 351 =head1 LIMITATIONS
 352
 353 To reduce the overhead as much as possible, only one possible location
 354 is checked to find the extension DLL (this location is where C<make install>
 355 would put the DLL).  If not found, the search for the DLL is transparently
 356 delegated to C<DynaLoader>, which looks for the DLL along the C<@INC> list.
 357
 358 In particular, this is applicable to the structure of C<@INC> used for testing
 359 not-yet-installed extensions.  This means that running uninstalled extensions
 360 may have much more overhead than running the same extensions after
 361 C<make install>.
 362
 363
 364 =head1 BUGS
 365
 366 Please report any bugs or feature requests via the perlbug(1) utility.
 367
 368
 369 =head1 SEE ALSO
 370
 371 L<DynaLoader>
 372
 373
 374 =head1 AUTHORS
 375
 376 Ilya Zakharevich originally extracted C<XSLoader> from C<DynaLoader>.
 377
 378 CPAN version is currently maintained by SE<eacute>bastien Aperghis-Tramoni
 379 E<lt>sebastien@aperghis.netE<gt>.
 380
 381 Previous maintainer was Michael G Schwern <schwern@pobox.com>.
 382
 383
 384 =head1 COPYRIGHT
 385
 386 This program is free software; you can redistribute it and/or modify
 387 it under the same terms as Perl itself.
 388
 389 =cut
 390 EOT
 391
 392 close OUT or die $!;