ext/DynaLoader/DynaLoader_pm.PL

   1
   2 use Config;
   3
   4 sub to_string {
   5     my ($value) = @_;
   6     $value =~ s/\\/\\\\'/g;
   7     $value =~ s/'/\\'/g;
   8     return "'$value'";
   9 }
  10
  11 unlink "DynaLoader.pm" if -f "DynaLoader.pm";
  12 open OUT, ">DynaLoader.pm" or die $!;
  13 print OUT <<'EOT';
  14
  15 # Generated from DynaLoader.pm.PL (resolved %Config::Config values)
  16
  17 package DynaLoader;
  18
  19 #   And Gandalf said: 'Many folk like to know beforehand what is to
  20 #   be set on the table; but those who have laboured to prepare the
  21 #   feast like to keep their secret; for wonder makes the words of
  22 #   praise louder.'
  23
  24 #   (Quote from Tolkien sugested by Anno Siegel.)
  25 #
  26 # See pod text at end of file for documentation.
  27 # See also ext/DynaLoader/README in source tree for other information.
  28 #
  29 # Tim.Bunce@ig.co.uk, August 1994
  30
  31 $VERSION = $VERSION = "1.03";   # avoid typo warning
  32
  33 require AutoLoader;
  34 *AUTOLOAD = \&AutoLoader::AUTOLOAD;
  35
  36 # The following require can't be removed during maintenance
  37 # releases, sadly, because of the risk of buggy code that does
  38 # require Carp; Carp::croak "..."; without brackets dying
  39 # if Carp hasn't been loaded in earlier compile time. :-(
  40 # We'll let those bugs get found on the development track.
  41 require Carp if $] < 5.00450;
  42
  43
  44 # enable debug/trace messages from DynaLoader perl code
  45 $dl_debug = $ENV{PERL_DL_DEBUG} || 0 unless defined $dl_debug;
  46
  47 #
  48 # Flags to alter dl_load_file behaviour.  Assigned bits:
  49 #   0x01  make symbols available for linking later dl_load_file's.
  50 #         (only known to work on Solaris 2 using dlopen(RTLD_GLOBAL))
  51 #         (ignored under VMS; effect is built-in to image linking)
  52 #
  53 # This is called as a class method $module->dl_load_flags.  The
  54 # definition here will be inherited and result on "default" loading
  55 # behaviour unless a sub-class of DynaLoader defines its own version.
  56 #
  57
  58 sub dl_load_flags { 0x00 }
  59
  60 # ($dl_dlext, $dlsrc)
  61 #         = @Config::Config{'dlext', 'dlsrc'};
  62 EOT
  63
  64 print OUT "  (\$dl_dlext, \$dlsrc) = (",
  65           to_string($Config::Config{'dlext'}), ",",
  66           to_string($Config::Config{'dlsrc'}), ")\n;" ;
  67
  68 print OUT <<'EOT';
  69
  70 # Some systems need special handling to expand file specifications
  71 # (VMS support by Charles Bailey <bailey@HMIVAX.HUMGEN.UPENN.EDU>)
  72 # See dl_expandspec() for more details. Should be harmless but
  73 # inefficient to define on systems that don't need it.
  74 $do_expand = $Is_VMS = $^O eq 'VMS';
  75 $Is_MacOS  = $^O eq 'MacOS';
  76
  77 @dl_require_symbols = ();       # names of symbols we need
  78 @dl_resolve_using   = ();       # names of files to link with
  79 @dl_library_path    = ();       # path to look for files
  80 @dl_librefs         = ();       # things we have loaded
  81 @dl_modules         = ();       # Modules we have loaded
  82
  83 # This is a fix to support DLD's unfortunate desire to relink -lc
  84 @dl_resolve_using = dl_findfile('-lc') if $dlsrc eq "dl_dld.xs";
  85
  86 # Initialise @dl_library_path with the 'standard' library path
  87 # for this platform as determined by Configure
  88
  89 # push(@dl_library_path, split(' ', $Config::Config{'libpth'});
  90 EOT
  91
  92 print OUT "push(\@dl_library_path, split(' ', ",
  93           to_string($Config::Config{'libpth'}), "));\n";
  94
  95 print OUT <<'EOT';
  96
  97 # Add to @dl_library_path any extra directories we can gather
  98 # from environment variables.
  99 if ($Is_MacOS) {
 100     push(@dl_library_path, split(/,/, $ENV{LD_LIBRARY_PATH}))
 101         if exists $ENV{LD_LIBRARY_PATH};
 102 } else {
 103     push(@dl_library_path, split(/:/, $ENV{$Config::Config{ldlibpthname}}))
 104         if exists      $Config::Config{ldlibpthname}        &&
 105                        $Config::Config{ldlibpthname}  ne '' &&
 106                 exists $ENV{$Config::Config{ldlibpthname}}       ;;
 107     push(@dl_library_path, split(/:/, $ENV{$Config::Config{ldlibpthname}}))
 108         if exists      $Config::Config{ldlibpthname}        &&
 109                        $Config::Config{ldlibpthname}  ne '' &&
 110                 exists $ENV{$Config::Config{ldlibpthname}}       ;;
 111 # E.g. HP-UX supports both its native SHLIB_PATH *and* LD_LIBRARY_PATH.
 112 push(@dl_library_path, split(/:/, $ENV{LD_LIBRARY_PATH}))
 113     if exists $ENV{LD_LIBRARY_PATH};
 114 }
 115
 116 # No prizes for guessing why we don't say 'bootstrap DynaLoader;' here.
 117 boot_DynaLoader('DynaLoader') if defined(&boot_DynaLoader) &&
 118                                 !defined(&dl_load_file);
 119
 120
 121 if ($dl_debug) {
 122     print STDERR "DynaLoader.pm loaded (@INC, @dl_library_path)\n";
 123     print STDERR "DynaLoader not linked into this perl\n"
 124             unless defined(&boot_DynaLoader);
 125 }
 126
 127 1; # End of main code
 128
 129
 130 sub croak   { require Carp; Carp::croak(@_)   }
 131
 132 # The bootstrap function cannot be autoloaded (without complications)
 133 # so we define it here:
 134
 135 sub bootstrap {
 136     # use local vars to enable $module.bs script to edit values
 137     local(@args) = @_;
 138     local($module) = $args[0];
 139     local(@dirs, $file);
 140
 141     unless ($module) {
 142         require Carp;
 143         Carp::confess("Usage: DynaLoader::bootstrap(module)");
 144     }
 145
 146     # A common error on platforms which don't support dynamic loading.
 147     # Since it's fatal and potentially confusing we give a detailed message.
 148     croak("Can't load module $module, dynamic loading not available in this perl.\n".
 149         "  (You may need to build a new perl executable which either supports\n".
 150         "  dynamic loading or has the $module module statically linked into it.)\n")
 151         unless defined(&dl_load_file);
 152
 153     my @modparts = split(/::/,$module);
 154     my $modfname = $modparts[-1];
 155
 156     # Some systems have restrictions on files names for DLL's etc.
 157     # mod2fname returns appropriate file base name (typically truncated)
 158     # It may also edit @modparts if required.
 159     $modfname = &mod2fname(\@modparts) if defined &mod2fname;
 160
 161     my $modpname = join(($Is_MacOS ? ':' : '/'),@modparts);
 162
 163     print STDERR "DynaLoader::bootstrap for $module ",
 164                 ($Is_MacOS
 165                       ? "(auto/$modpname/$modfname.$dl_dlext)\n" :
 166                         "(:auto:$modpname:$modfname.$dl_dlext)\n")
 167         if $dl_debug;
 168
 169     foreach (@INC) {
 170         chop($_ = VMS::Filespec::unixpath($_)) if $Is_VMS;
 171         my $dir;
 172         if ($Is_MacOS) {
 173             chop $_  if /:$/;
 174             $dir = "$_:auto:$modpname";
 175         } else {
 176             $dir = "$_/auto/$modpname";
 177         }
 178         next unless -d $dir; # skip over uninteresting directories
 179
 180         # check for common cases to avoid autoload of dl_findfile
 181         my $try = $Is_MacOS ? "$dir:$modfname.$dl_dlext" : "$dir/$modfname.$dl_dlext";
 182         last if $file = ($do_expand) ? dl_expandspec($try) : (-f $try && $try);
 183
 184         # no luck here, save dir for possible later dl_findfile search
 185         push @dirs, $dir;
 186     }
 187     # last resort, let dl_findfile have a go in all known locations
 188     $file = dl_findfile(map("-L$_",@dirs,@INC), $modfname) unless $file;
 189
 190     croak("Can't locate loadable object for module $module in \@INC (\@INC contains: @INC)")
 191         unless $file;   # wording similar to error from 'require'
 192
 193     my $bootname = "boot_$module";
 194     $bootname =~ s/\W/_/g;
 195     @dl_require_symbols = ($bootname);
 196
 197     # Execute optional '.bootstrap' perl script for this module.
 198     # The .bs file can be used to configure @dl_resolve_using etc to
 199     # match the needs of the individual module on this architecture.
 200     my $bs = $file;
 201     $bs =~ s/(\.\w+)?(;\d*)?$/\.bs/; # look for .bs 'beside' the library
 202     if (-s $bs) { # only read file if it's not empty
 203         print STDERR "BS: $bs ($^O, $dlsrc)\n" if $dl_debug;
 204         eval { do $bs; };
 205         warn "$bs: $@\n" if $@;
 206     }
 207
 208     # Many dynamic extension loading problems will appear to come from
 209     # this section of code: XYZ failed at line 123 of DynaLoader.pm.
 210     # Often these errors are actually occurring in the initialisation
 211     # C code of the extension XS file. Perl reports the error as being
 212     # in this perl code simply because this was the last perl code
 213     # it executed.
 214
 215     my $libref = dl_load_file($file, $module->dl_load_flags) or
 216         croak("Can't load '$file' for module $module: ".dl_error());
 217
 218     push(@dl_librefs,$libref);  # record loaded object
 219
 220     my @unresolved = dl_undef_symbols();
 221     if (@unresolved) {
 222         require Carp;
 223         Carp::carp("Undefined symbols present after loading $file: @unresolved\n");
 224     }
 225
 226     my $boot_symbol_ref = dl_find_symbol($libref, $bootname) or
 227          croak("Can't find '$bootname' symbol in $file\n");
 228
 229     my $xs = dl_install_xsub("${module}::bootstrap", $boot_symbol_ref, $file);
 230
 231     push(@dl_modules, $module); # record loaded module
 232
 233     # See comment block above
 234     &$xs(@args);
 235 }
 236
 237
 238 #sub _check_file {   # private utility to handle dl_expandspec vs -f tests
 239 #    my($file) = @_;
 240 #    return $file if (!$do_expand && -f $file); # the common case
 241 #    return $file if ( $do_expand && ($file=dl_expandspec($file)));
 242 #    return undef;
 243 #}
 244
 245
 246 # Let autosplit and the autoloader deal with these functions:
 247 __END__
 248
 249
 250 sub dl_findfile {
 251     # Read ext/DynaLoader/DynaLoader.doc for detailed information.
 252     # This function does not automatically consider the architecture
 253     # or the perl library auto directories.
 254     my (@args) = @_;
 255     my (@dirs,  $dir);   # which directories to search
 256     my (@found);         # full paths to real files we have found
 257 EOT
 258
 259 print OUT '    my $dl_ext= ' . to_string($Config::Config{'dlext'}) .
 260           "; # \$Config::Config{'dlext'} suffix for perl extensions\n";
 261 print OUT '    my $dl_so = ' . to_string($Config::Config{'so'}) .
 262           "; # \$Config::Config{'so'} suffix for shared libraries\n";
 263
 264 print OUT <<'EOT';
 265
 266     print STDERR "dl_findfile(@args)\n" if $dl_debug;
 267
 268     # accumulate directories but process files as they appear
 269     arg: foreach(@args) {
 270         #  Special fast case: full filepath requires no search
 271         if ($Is_VMS && m%[:>/\]]% && -f $_) {
 272             push(@found,dl_expandspec(VMS::Filespec::vmsify($_)));
 273             last arg unless wantarray;
 274             next;
 275         }
 276         elsif ($Is_MacOS) {
 277             if (m/:/ && -f $_) {
 278                 push(@found,$_);
 279                 last arg unless wantarray;
 280             }
 281         }
 282         elsif (m:/: && -f $_ && !$do_expand) {
 283             push(@found,$_);
 284             last arg unless wantarray;
 285             next;
 286         }
 287
 288         # Deal with directories first:
 289         #  Using a -L prefix is the preferred option (faster and more robust)
 290         if (m:^-L:) { s/^-L//; push(@dirs, $_); next; }
 291
 292         if ($Is_MacOS) {
 293             #  Otherwise we try to try to spot directories by a heuristic
 294             #  (this is a more complicated issue than it first appears)
 295             if (m/:/ && -d $_) {   push(@dirs, $_); next; }
 296             #  Only files should get this far...
 297             my(@names, $name);    # what filenames to look for
 298             s/^-l//;
 299             push(@names, $_);
 300             foreach $dir (@dirs, @dl_library_path) {
 301                 next unless -d $dir;
 302                 $dir =~ s/^([^:]+)$/:$1/;
 303                 $dir =~ s/:$//;
 304                 foreach $name (@names) {
 305                     my($file) = "$dir:$name";
 306                     print STDERR " checking in $dir for $name\n" if $dl_debug;
 307                     if (-f $file) {
 308                         push(@found, $file);
 309                         next arg; # no need to look any further
 310                     }
 311                 }
 312             }
 313             next;
 314         }
 315
 316         #  Otherwise we try to try to spot directories by a heuristic
 317         #  (this is a more complicated issue than it first appears)
 318         if (m:/: && -d $_) {   push(@dirs, $_); next; }
 319
 320         # VMS: we may be using native VMS directry syntax instead of
 321         # Unix emulation, so check this as well
 322         if ($Is_VMS && /[:>\]]/ && -d $_) {   push(@dirs, $_); next; }
 323
 324         #  Only files should get this far...
 325         my(@names, $name);    # what filenames to look for
 326         if (m:-l: ) {          # convert -lname to appropriate library name
 327             s/-l//;
 328             push(@names,"lib$_.$dl_so");
 329             push(@names,"lib$_.a");
 330         } else {                # Umm, a bare name. Try various alternatives:
 331             # these should be ordered with the most likely first
 332             push(@names,"$_.$dl_ext")    unless m/\.$dl_ext$/o;
 333             push(@names,"$_.$dl_so")     unless m/\.$dl_so$/o;
 334             push(@names,"lib$_.$dl_so")  unless m:/:;
 335             push(@names,"$_.a")          if !m/\.a$/ and $dlsrc eq "dl_dld.xs";
 336             push(@names, $_);
 337         }
 338         foreach $dir (@dirs, @dl_library_path) {
 339             next unless -d $dir;
 340             chop($dir = VMS::Filespec::unixpath($dir)) if $Is_VMS;
 341             foreach $name (@names) {
 342                 my($file) = "$dir/$name";
 343                 print STDERR " checking in $dir for $name\n" if $dl_debug;
 344                 $file = ($do_expand) ? dl_expandspec($file) : (-f $file && $file);
 345                 #$file = _check_file($file);
 346                 if ($file) {
 347                     push(@found, $file);
 348                     next arg; # no need to look any further
 349                 }
 350             }
 351         }
 352     }
 353     if ($dl_debug) {
 354         foreach(@dirs) {
 355             print STDERR " dl_findfile ignored non-existent directory: $_\n" unless -d $_;
 356         }
 357         print STDERR "dl_findfile found: @found\n";
 358     }
 359     return $found[0] unless wantarray;
 360     @found;
 361 }
 362
 363
 364 sub dl_expandspec {
 365     my($spec) = @_;
 366     # Optional function invoked if DynaLoader.pm sets $do_expand.
 367     # Most systems do not require or use this function.
 368     # Some systems may implement it in the dl_*.xs file in which case
 369     # this autoload version will not be called but is harmless.
 370
 371     # This function is designed to deal with systems which treat some
 372     # 'filenames' in a special way. For example VMS 'Logical Names'
 373     # (something like unix environment variables - but different).
 374     # This function should recognise such names and expand them into
 375     # full file paths.
 376     # Must return undef if $spec is invalid or file does not exist.
 377
 378     my $file = $spec; # default output to input
 379
 380     if ($Is_VMS) { # dl_expandspec should be defined in dl_vms.xs
 381         require Carp;
 382         Carp::croak("dl_expandspec: should be defined in XS file!\n");
 383     } else {
 384         return undef unless -f $file;
 385     }
 386     print STDERR "dl_expandspec($spec) => $file\n" if $dl_debug;
 387     $file;
 388 }
 389
 390 sub dl_find_symbol_anywhere
 391 {
 392     my $sym = shift;
 393     my $libref;
 394     foreach $libref (@dl_librefs) {
 395         my $symref = dl_find_symbol($libref,$sym);
 396         return $symref if $symref;
 397     }
 398     return undef;
 399 }
 400
 401 =head1 NAME
 402
 403 DynaLoader - Dynamically load C libraries into Perl code
 404
 405 dl_error(), dl_findfile(), dl_expandspec(), dl_load_file(), dl_find_symbol(), dl_find_symbol_anywhere(), dl_undef_symbols(), dl_install_xsub(), dl_load_flags(), bootstrap() - routines used by DynaLoader modules
 406
 407 =head1 SYNOPSIS
 408
 409     package YourPackage;
 410     require DynaLoader;
 411     @ISA = qw(... DynaLoader ...);
 412     bootstrap YourPackage;
 413
 414     # optional method for 'global' loading
 415     sub dl_load_flags { 0x01 }
 416
 417
 418 =head1 DESCRIPTION
 419
 420 This document defines a standard generic interface to the dynamic
 421 linking mechanisms available on many platforms.  Its primary purpose is
 422 to implement automatic dynamic loading of Perl modules.
 423
 424 This document serves as both a specification for anyone wishing to
 425 implement the DynaLoader for a new platform and as a guide for
 426 anyone wishing to use the DynaLoader directly in an application.
 427
 428 The DynaLoader is designed to be a very simple high-level
 429 interface that is sufficiently general to cover the requirements
 430 of SunOS, HP-UX, NeXT, Linux, VMS and other platforms.
 431
 432 It is also hoped that the interface will cover the needs of OS/2, NT
 433 etc and also allow pseudo-dynamic linking (using C<ld -A> at runtime).
 434
 435 It must be stressed that the DynaLoader, by itself, is practically
 436 useless for accessing non-Perl libraries because it provides almost no
 437 Perl-to-C 'glue'.  There is, for example, no mechanism for calling a C
 438 library function or supplying arguments.  A C::DynaLib module
 439 is available from CPAN sites which performs that function for some
 440 common system types.
 441
 442 DynaLoader Interface Summary
 443
 444   @dl_library_path
 445   @dl_resolve_using
 446   @dl_require_symbols
 447   $dl_debug
 448   @dl_librefs
 449   @dl_modules
 450                                                   Implemented in:
 451   bootstrap($modulename)                               Perl
 452   @filepaths = dl_findfile(@names)                     Perl
 453   $flags = $modulename->dl_load_flags                  Perl
 454   $symref  = dl_find_symbol_anywhere($symbol)          Perl
 455
 456   $libref  = dl_load_file($filename, $flags)           C
 457   $symref  = dl_find_symbol($libref, $symbol)          C
 458   @symbols = dl_undef_symbols()                        C
 459   dl_install_xsub($name, $symref [, $filename])        C
 460   $message = dl_error                                  C
 461
 462 =over 4
 463
 464 =item @dl_library_path
 465
 466 The standard/default list of directories in which dl_findfile() will
 467 search for libraries etc.  Directories are searched in order:
 468 $dl_library_path[0], [1], ... etc
 469
 470 @dl_library_path is initialised to hold the list of 'normal' directories
 471 (F</usr/lib>, etc) determined by B<Configure> (C<$Config{'libpth'}>).  This should
 472 ensure portability across a wide range of platforms.
 473
 474 @dl_library_path should also be initialised with any other directories
 475 that can be determined from the environment at runtime (such as
 476 LD_LIBRARY_PATH for SunOS).
 477
 478 After initialisation @dl_library_path can be manipulated by an
 479 application using push and unshift before calling dl_findfile().
 480 Unshift can be used to add directories to the front of the search order
 481 either to save search time or to override libraries with the same name
 482 in the 'normal' directories.
 483
 484 The load function that dl_load_file() calls may require an absolute
 485 pathname.  The dl_findfile() function and @dl_library_path can be
 486 used to search for and return the absolute pathname for the
 487 library/object that you wish to load.
 488
 489 =item @dl_resolve_using
 490
 491 A list of additional libraries or other shared objects which can be
 492 used to resolve any undefined symbols that might be generated by a
 493 later call to load_file().
 494
 495 This is only required on some platforms which do not handle dependent
 496 libraries automatically.  For example the Socket Perl extension
 497 library (F<auto/Socket/Socket.so>) contains references to many socket
 498 functions which need to be resolved when it's loaded.  Most platforms
 499 will automatically know where to find the 'dependent' library (e.g.,
 500 F</usr/lib/libsocket.so>).  A few platforms need to be told the
 501 location of the dependent library explicitly.  Use @dl_resolve_using
 502 for this.
 503
 504 Example usage:
 505
 506     @dl_resolve_using = dl_findfile('-lsocket');
 507
 508 =item @dl_require_symbols
 509
 510 A list of one or more symbol names that are in the library/object file
 511 to be dynamically loaded.  This is only required on some platforms.
 512
 513 =item @dl_librefs
 514
 515 An array of the handles returned by successful calls to dl_load_file(),
 516 made by bootstrap, in the order in which they were loaded.
 517 Can be used with dl_find_symbol() to look for a symbol in any of
 518 the loaded files.
 519
 520 =item @dl_modules
 521
 522 An array of module (package) names that have been bootstrap'ed.
 523
 524 =item dl_error()
 525
 526 Syntax:
 527
 528     $message = dl_error();
 529
 530 Error message text from the last failed DynaLoader function.  Note
 531 that, similar to errno in unix, a successful function call does not
 532 reset this message.
 533
 534 Implementations should detect the error as soon as it occurs in any of
 535 the other functions and save the corresponding message for later
 536 retrieval.  This will avoid problems on some platforms (such as SunOS)
 537 where the error message is very temporary (e.g., dlerror()).
 538
 539 =item $dl_debug
 540
 541 Internal debugging messages are enabled when $dl_debug is set true.
 542 Currently setting $dl_debug only affects the Perl side of the
 543 DynaLoader.  These messages should help an application developer to
 544 resolve any DynaLoader usage problems.
 545
 546 $dl_debug is set to C<$ENV{'PERL_DL_DEBUG'}> if defined.
 547
 548 For the DynaLoader developer/porter there is a similar debugging
 549 variable added to the C code (see dlutils.c) and enabled if Perl was
 550 built with the B<-DDEBUGGING> flag.  This can also be set via the
 551 PERL_DL_DEBUG environment variable.  Set to 1 for minimal information or
 552 higher for more.
 553
 554 =item dl_findfile()
 555
 556 Syntax:
 557
 558     @filepaths = dl_findfile(@names)
 559
 560 Determine the full paths (including file suffix) of one or more
 561 loadable files given their generic names and optionally one or more
 562 directories.  Searches directories in @dl_library_path by default and
 563 returns an empty list if no files were found.
 564
 565 Names can be specified in a variety of platform independent forms.  Any
 566 names in the form B<-lname> are converted into F<libname.*>, where F<.*> is
 567 an appropriate suffix for the platform.
 568
 569 If a name does not already have a suitable prefix and/or suffix then
 570 the corresponding file will be searched for by trying combinations of
 571 prefix and suffix appropriate to the platform: "$name.o", "lib$name.*"
 572 and "$name".
 573
 574 If any directories are included in @names they are searched before
 575 @dl_library_path.  Directories may be specified as B<-Ldir>.  Any other
 576 names are treated as filenames to be searched for.
 577
 578 Using arguments of the form C<-Ldir> and C<-lname> is recommended.
 579
 580 Example:
 581
 582     @dl_resolve_using = dl_findfile(qw(-L/usr/5lib -lposix));
 583
 584
 585 =item dl_expandspec()
 586
 587 Syntax:
 588
 589     $filepath = dl_expandspec($spec)
 590
 591 Some unusual systems, such as VMS, require special filename handling in
 592 order to deal with symbolic names for files (i.e., VMS's Logical Names).
 593
 594 To support these systems a dl_expandspec() function can be implemented
 595 either in the F<dl_*.xs> file or code can be added to the autoloadable
 596 dl_expandspec() function in F<DynaLoader.pm>.  See F<DynaLoader.pm> for
 597 more information.
 598
 599 =item dl_load_file()
 600
 601 Syntax:
 602
 603     $libref = dl_load_file($filename, $flags)
 604
 605 Dynamically load $filename, which must be the path to a shared object
 606 or library.  An opaque 'library reference' is returned as a handle for
 607 the loaded object.  Returns undef on error.
 608
 609 The $flags argument to alters dl_load_file behaviour.
 610 Assigned bits:
 611
 612  0x01  make symbols available for linking later dl_load_file's.
 613        (only known to work on Solaris 2 using dlopen(RTLD_GLOBAL))
 614        (ignored under VMS; this is a normal part of image linking)
 615
 616 (On systems that provide a handle for the loaded object such as SunOS
 617 and HPUX, $libref will be that handle.  On other systems $libref will
 618 typically be $filename or a pointer to a buffer containing $filename.
 619 The application should not examine or alter $libref in any way.)
 620
 621 This is the function that does the real work.  It should use the
 622 current values of @dl_require_symbols and @dl_resolve_using if required.
 623
 624     SunOS: dlopen($filename)
 625     HP-UX: shl_load($filename)
 626     Linux: dld_create_reference(@dl_require_symbols); dld_link($filename)
 627     NeXT:  rld_load($filename, @dl_resolve_using)
 628     VMS:   lib$find_image_symbol($filename,$dl_require_symbols[0])
 629
 630 (The dlopen() function is also used by Solaris and some versions of
 631 Linux, and is a common choice when providing a "wrapper" on other
 632 mechanisms as is done in the OS/2 port.)
 633
 634 =item dl_loadflags()
 635
 636 Syntax:
 637
 638     $flags = dl_loadflags $modulename;
 639
 640 Designed to be a method call, and to be overridden by a derived class
 641 (i.e. a class which has DynaLoader in its @ISA).  The definition in
 642 DynaLoader itself returns 0, which produces standard behavior from
 643 dl_load_file().
 644
 645 =item dl_find_symbol()
 646
 647 Syntax:
 648
 649     $symref = dl_find_symbol($libref, $symbol)
 650
 651 Return the address of the symbol $symbol or C<undef> if not found.  If the
 652 target system has separate functions to search for symbols of different
 653 types then dl_find_symbol() should search for function symbols first and
 654 then other types.
 655
 656 The exact manner in which the address is returned in $symref is not
 657 currently defined.  The only initial requirement is that $symref can
 658 be passed to, and understood by, dl_install_xsub().
 659
 660     SunOS: dlsym($libref, $symbol)
 661     HP-UX: shl_findsym($libref, $symbol)
 662     Linux: dld_get_func($symbol) and/or dld_get_symbol($symbol)
 663     NeXT:  rld_lookup("_$symbol")
 664     VMS:   lib$find_image_symbol($libref,$symbol)
 665
 666
 667 =item dl_find_symbol_anywhere()
 668
 669 Syntax:
 670
 671     $symref = dl_find_symbol_anywhere($symbol)
 672
 673 Applies dl_find_symbol() to the members of @dl_librefs and returns
 674 the first match found.
 675
 676 =item dl_undef_symbols()
 677
 678 Example
 679
 680     @symbols = dl_undef_symbols()
 681
 682 Return a list of symbol names which remain undefined after load_file().
 683 Returns C<()> if not known.  Don't worry if your platform does not provide
 684 a mechanism for this.  Most do not need it and hence do not provide it,
 685 they just return an empty list.
 686
 687
 688 =item dl_install_xsub()
 689
 690 Syntax:
 691
 692     dl_install_xsub($perl_name, $symref [, $filename])
 693
 694 Create a new Perl external subroutine named $perl_name using $symref as
 695 a pointer to the function which implements the routine.  This is simply
 696 a direct call to newXSUB().  Returns a reference to the installed
 697 function.
 698
 699 The $filename parameter is used by Perl to identify the source file for
 700 the function if required by die(), caller() or the debugger.  If
 701 $filename is not defined then "DynaLoader" will be used.
 702
 703
 704 =item bootstrap()
 705
 706 Syntax:
 707
 708 bootstrap($module)
 709
 710 This is the normal entry point for automatic dynamic loading in Perl.
 711
 712 It performs the following actions:
 713
 714 =over 8
 715
 716 =item *
 717
 718 locates an auto/$module directory by searching @INC
 719
 720 =item *
 721
 722 uses dl_findfile() to determine the filename to load
 723
 724 =item *
 725
 726 sets @dl_require_symbols to C<("boot_$module")>
 727
 728 =item *
 729
 730 executes an F<auto/$module/$module.bs> file if it exists
 731 (typically used to add to @dl_resolve_using any files which
 732 are required to load the module on the current platform)
 733
 734 =item *
 735
 736 calls dl_load_flags() to determine how to load the file.
 737
 738 =item *
 739
 740 calls dl_load_file() to load the file
 741
 742 =item *
 743
 744 calls dl_undef_symbols() and warns if any symbols are undefined
 745
 746 =item *
 747
 748 calls dl_find_symbol() for "boot_$module"
 749
 750 =item *
 751
 752 calls dl_install_xsub() to install it as "${module}::bootstrap"
 753
 754 =item *
 755
 756 calls &{"${module}::bootstrap"} to bootstrap the module (actually
 757 it uses the function reference returned by dl_install_xsub for speed)
 758
 759 =back
 760
 761 =back
 762
 763
 764 =head1 AUTHOR
 765
 766 Tim Bunce, 11 August 1994.
 767
 768 This interface is based on the work and comments of (in no particular
 769 order): Larry Wall, Robert Sanders, Dean Roehrich, Jeff Okamoto, Anno
 770 Siegel, Thomas Neumann, Paul Marquess, Charles Bailey, myself and others.
 771
 772 Larry Wall designed the elegant inherited bootstrap mechanism and
 773 implemented the first Perl 5 dynamic loader using it.
 774
 775 Solaris global loading added by Nick Ing-Simmons with design/coding
 776 assistance from Tim Bunce, January 1996.
 777
 778 =cut
 779 EOT
 780
 781 close OUT or die $!;
 782