ext/DynaLoader/DynaLoader_pm.PL

   1 use Config;
   2
   3 sub to_string {
   4     my ($value) = @_;
   5     $value =~ s/\\/\\\\/g;
   6     $value =~ s/'/\\'/g;
   7     return "'$value'";
   8 }
   9
  10 unlink "DynaLoader.pm" if -f "DynaLoader.pm";
  11 open OUT, ">DynaLoader.pm" or die $!;
  12 print OUT <<'EOT';
  13
  14 # Generated from DynaLoader.pm.PL
  15
  16 package DynaLoader;
  17
  18 #   And Gandalf said: 'Many folk like to know beforehand what is to
  19 #   be set on the table; but those who have laboured to prepare the
  20 #   feast like to keep their secret; for wonder makes the words of
  21 #   praise louder.'
  22
  23 #   (Quote from Tolkien suggested by Anno Siegel.)
  24 #
  25 # See pod text at end of file for documentation.
  26 # See also ext/DynaLoader/README in source tree for other information.
  27 #
  28 # Tim.Bunce@ig.co.uk, August 1994
  29
  30 use vars qw($VERSION *AUTOLOAD);
  31
  32 $VERSION = 1.04;        # avoid typo warning
  33
  34 require AutoLoader;
  35 *AUTOLOAD = \&AutoLoader::AUTOLOAD;
  36
  37 use Config;
  38
  39 # The following require can't be removed during maintenance
  40 # releases, sadly, because of the risk of buggy code that does
  41 # require Carp; Carp::croak "..."; without brackets dying
  42 # if Carp hasn't been loaded in earlier compile time. :-(
  43 # We'll let those bugs get found on the development track.
  44 require Carp if $] < 5.00450;
  45
  46 # enable debug/trace messages from DynaLoader perl code
  47 $dl_debug = $ENV{PERL_DL_DEBUG} || 0 unless defined $dl_debug;
  48
  49 #
  50 # Flags to alter dl_load_file behaviour.  Assigned bits:
  51 #   0x01  make symbols available for linking later dl_load_file's.
  52 #         (only known to work on Solaris 2 using dlopen(RTLD_GLOBAL))
  53 #         (ignored under VMS; effect is built-in to image linking)
  54 #
  55 # This is called as a class method $module->dl_load_flags.  The
  56 # definition here will be inherited and result on "default" loading
  57 # behaviour unless a sub-class of DynaLoader defines its own version.
  58 #
  59
  60 sub dl_load_flags { 0x00 }
  61
  62 # ($dl_dlext, $dlsrc)
  63 #         = @Config::Config{'dlext', 'dlsrc'};
  64 EOT
  65
  66 print OUT "  (\$dl_dlext, \$dlsrc) = (",
  67           to_string($Config::Config{'dlext'}), ",",
  68           to_string($Config::Config{'dlsrc'}), ")\n;" ;
  69
  70 print OUT <<'EOT';
  71
  72 # Some systems need special handling to expand file specifications
  73 # (VMS support by Charles Bailey <bailey@HMIVAX.HUMGEN.UPENN.EDU>)
  74 # See dl_expandspec() for more details. Should be harmless but
  75 # inefficient to define on systems that don't need it.
  76 $Is_VMS    = $^O eq 'VMS';
  77 $do_expand = $Is_VMS;
  78 $Is_MacOS  = $^O eq 'MacOS';
  79
  80 @dl_require_symbols = ();       # names of symbols we need
  81 @dl_resolve_using   = ();       # names of files to link with
  82 @dl_library_path    = ();       # path to look for files
  83 @dl_librefs         = ();       # things we have loaded
  84 @dl_modules         = ();       # Modules we have loaded
  85
  86 # This is a fix to support DLD's unfortunate desire to relink -lc
  87 @dl_resolve_using = dl_findfile('-lc') if $dlsrc eq "dl_dld.xs";
  88
  89 EOT
  90
  91 my $cfg_dl_library_path = <<'EOT';
  92 push(@dl_library_path, split(' ', $Config::Config{libpth}));
  93 EOT
  94
  95 sub dquoted_comma_list {
  96     join(", ", map {qq("$_")} @_);
  97 }
  98
  99 if ($ENV{PERL_BUILD_EXPAND_CONFIG_VARS}) {
 100     eval $cfg_dl_library_path;
 101     if (!$ENV{PERL_BUILD_EXPAND_ENV_VARS}) {
 102         my $dl_library_path = dquoted_comma_list(@dl_library_path);
 103         print OUT <<EOT;
 104 # The below \@dl_library_path has been expanded (%Config) in Perl build time.
 105
 106 \@dl_library_path = ($dl_library_path);
 107
 108 EOT
 109     }
 110 }
 111 else {
 112     print OUT <<EOT;
 113 # Initialise \@dl_library_path with the 'standard' library path
 114 # for this platform as determined by Configure.
 115
 116 $cfg_dl_library_path
 117
 118 EOT
 119 }
 120
 121 my $ldlibpthname;
 122 my $ldlibpthname_defined;
 123 my $pthsep;
 124
 125 if ($ENV{PERL_BUILD_EXPAND_CONFIG_VARS}) {
 126     $ldlibpthname         = $Config::Config{ldlibpthname};
 127     $ldlibpthname_defined = defined $Config::Config{ldlibpthname} ? 1 : 0;
 128     $pthsep               = $Config::Config{path_sep};
 129 }
 130 else {
 131     $ldlibpthname         = q($Config::Config{ldlibpthname});
 132     $ldlibpthname_defined = q(defined $Config::Config{ldlibpthname});
 133     $pthsep               = q($Config::Config{path_sep});
 134     print OUT <<EOT;
 135 my \$ldlibpthname         = $ldlibpthname;
 136 my \$ldlibpthname_defined = $ldlibpthname_defined;
 137 my \$pthsep               = $pthsep;
 138
 139 EOT
 140 }
 141
 142 my $env_dl_library_path = <<'EOT';
 143 if ($ldlibpthname_defined &&
 144     exists $ENV{$ldlibpthname}) {
 145     push(@dl_library_path, split(/$pthsep/, $ENV{$ldlibpthname}));
 146 }
 147
 148 # E.g. HP-UX supports both its native SHLIB_PATH *and* LD_LIBRARY_PATH.
 149
 150 if ($ldlibpthname_defined &&
 151     $ldlibpthname ne 'LD_LIBRARY_PATH' &&
 152     exists $ENV{LD_LIBRARY_PATH}) {
 153     push(@dl_library_path, split(/$pthsep/, $ENV{LD_LIBRARY_PATH}));
 154 }
 155 EOT
 156
 157 if ($ENV{PERL_BUILD_EXPAND_CONFIG_VARS} && $ENV{PERL_BUILD_EXPAND_ENV_VARS}) {
 158     eval $env_dl_library_path;
 159 }
 160 else {
 161     print OUT <<EOT;
 162 # Add to \@dl_library_path any extra directories we can gather from environment
 163 # during runtime.
 164
 165 $env_dl_library_path
 166
 167 EOT
 168 }
 169
 170 if ($ENV{PERL_BUILD_EXPAND_CONFIG_VARS} && $ENV{PERL_BUILD_EXPAND_ENV_VARS}) {
 171     my $dl_library_path = dquoted_comma_list(@dl_library_path);
 172     print OUT <<EOT;
 173 # The below \@dl_library_path has been expanded (%Config, %ENV)
 174 # in Perl build time.
 175
 176 \@dl_library_path = ($dl_library_path);
 177
 178 EOT
 179 }
 180
 181 print OUT <<'EOT';
 182 # No prizes for guessing why we don't say 'bootstrap DynaLoader;' here.
 183 # NOTE: All dl_*.xs (including dl_none.xs) define a dl_error() XSUB
 184 boot_DynaLoader('DynaLoader') if defined(&boot_DynaLoader) &&
 185                                 !defined(&dl_error);
 186
 187 if ($dl_debug) {
 188     print STDERR "DynaLoader.pm loaded (@INC, @dl_library_path)\n";
 189     print STDERR "DynaLoader not linked into this perl\n"
 190             unless defined(&boot_DynaLoader);
 191 }
 192
 193 1; # End of main code
 194
 195
 196 sub croak   { require Carp; Carp::croak(@_)   }
 197
 198 sub bootstrap_inherit {
 199     my $module = $_[0];
 200     local *isa = *{"$module\::ISA"};
 201     local @isa = (@isa, 'DynaLoader');
 202     # Cannot goto due to delocalization.  Will report errors on a wrong line?
 203     bootstrap(@_);
 204 }
 205
 206 # The bootstrap function cannot be autoloaded (without complications)
 207 # so we define it here:
 208
 209 sub bootstrap {
 210     # use local vars to enable $module.bs script to edit values
 211     local(@args) = @_;
 212     local($module) = $args[0];
 213     local(@dirs, $file);
 214
 215     unless ($module) {
 216         require Carp;
 217         Carp::confess("Usage: DynaLoader::bootstrap(module)");
 218     }
 219
 220     # A common error on platforms which don't support dynamic loading.
 221     # Since it's fatal and potentially confusing we give a detailed message.
 222     croak("Can't load module $module, dynamic loading not available in this perl.\n".
 223         "  (You may need to build a new perl executable which either supports\n".
 224         "  dynamic loading or has the $module module statically linked into it.)\n")
 225         unless defined(&dl_load_file);
 226
 227     my @modparts = split(/::/,$module);
 228     my $modfname = $modparts[-1];
 229
 230     # Some systems have restrictions on files names for DLL's etc.
 231     # mod2fname returns appropriate file base name (typically truncated)
 232     # It may also edit @modparts if required.
 233     $modfname = &mod2fname(\@modparts) if defined &mod2fname;
 234
 235     my $modpname = join(($Is_MacOS ? ':' : '/'),@modparts);
 236
 237     print STDERR "DynaLoader::bootstrap for $module ",
 238                 ($Is_MacOS
 239                        ? "(:auto:$modpname:$modfname.$dl_dlext)\n" :
 240                        "(auto/$modpname/$modfname.$dl_dlext)\n")
 241         if $dl_debug;
 242
 243     foreach (@INC) {
 244         chop($_ = VMS::Filespec::unixpath($_)) if $Is_VMS;
 245         my $dir;
 246         if ($Is_MacOS) {
 247             chop $_  if /:$/;
 248             $dir = "$_:auto:$modpname";
 249         } else {
 250             $dir = "$_/auto/$modpname";
 251         }
 252         next unless -d $dir; # skip over uninteresting directories
 253
 254         # check for common cases to avoid autoload of dl_findfile
 255         my $try = $Is_MacOS ? "$dir:$modfname.$dl_dlext" : "$dir/$modfname.$dl_dlext";
 256         last if $file = ($do_expand) ? dl_expandspec($try) : (-f $try && $try);
 257
 258         # no luck here, save dir for possible later dl_findfile search
 259         push @dirs, $dir;
 260     }
 261     # last resort, let dl_findfile have a go in all known locations
 262     $file = dl_findfile(map("-L$_",@dirs,@INC), $modfname) unless $file;
 263
 264     croak("Can't locate loadable object for module $module in \@INC (\@INC contains: @INC)")
 265         unless $file;   # wording similar to error from 'require'
 266
 267     $file = uc($file) if $Is_VMS && $Config::Config{d_vms_case_sensitive_symbols};
 268     my $bootname = "boot_$module";
 269     $bootname =~ s/\W/_/g;
 270     @dl_require_symbols = ($bootname);
 271
 272     # Execute optional '.bootstrap' perl script for this module.
 273     # The .bs file can be used to configure @dl_resolve_using etc to
 274     # match the needs of the individual module on this architecture.
 275     my $bs = $file;
 276     $bs =~ s/(\.\w+)?(;\d*)?$/\.bs/; # look for .bs 'beside' the library
 277     if (-s $bs) { # only read file if it's not empty
 278         print STDERR "BS: $bs ($^O, $dlsrc)\n" if $dl_debug;
 279         eval { do $bs; };
 280         warn "$bs: $@\n" if $@;
 281     }
 282
 283     # Many dynamic extension loading problems will appear to come from
 284     # this section of code: XYZ failed at line 123 of DynaLoader.pm.
 285     # Often these errors are actually occurring in the initialisation
 286     # C code of the extension XS file. Perl reports the error as being
 287     # in this perl code simply because this was the last perl code
 288     # it executed.
 289
 290     my $libref = dl_load_file($file, $module->dl_load_flags) or
 291         croak("Can't load '$file' for module $module: ".dl_error());
 292
 293     push(@dl_librefs,$libref);  # record loaded object
 294
 295     my @unresolved = dl_undef_symbols();
 296     if (@unresolved) {
 297         require Carp;
 298         Carp::carp("Undefined symbols present after loading $file: @unresolved\n");
 299     }
 300
 301     my $boot_symbol_ref = dl_find_symbol($libref, $bootname) or
 302          croak("Can't find '$bootname' symbol in $file\n");
 303
 304     my $xs = dl_install_xsub("${module}::bootstrap", $boot_symbol_ref, $file);
 305
 306     push(@dl_modules, $module); # record loaded module
 307
 308     # See comment block above
 309     &$xs(@args);
 310 }
 311
 312
 313 #sub _check_file {   # private utility to handle dl_expandspec vs -f tests
 314 #    my($file) = @_;
 315 #    return $file if (!$do_expand && -f $file); # the common case
 316 #    return $file if ( $do_expand && ($file=dl_expandspec($file)));
 317 #    return undef;
 318 #}
 319
 320
 321 # Let autosplit and the autoloader deal with these functions:
 322 __END__
 323
 324
 325 sub dl_findfile {
 326     # Read ext/DynaLoader/DynaLoader.doc for detailed information.
 327     # This function does not automatically consider the architecture
 328     # or the perl library auto directories.
 329     my (@args) = @_;
 330     my (@dirs,  $dir);   # which directories to search
 331     my (@found);         # full paths to real files we have found
 332 EOT
 333
 334 print OUT '    my $dl_ext= ' . to_string($Config::Config{'dlext'}) .
 335           "; # \$Config::Config{'dlext'} suffix for perl extensions\n";
 336 print OUT '    my $dl_so = ' . to_string($Config::Config{'so'}) .
 337           "; # \$Config::Config{'so'} suffix for shared libraries\n";
 338
 339 print OUT <<'EOT';
 340
 341     print STDERR "dl_findfile(@args)\n" if $dl_debug;
 342
 343     # accumulate directories but process files as they appear
 344     arg: foreach(@args) {
 345         #  Special fast case: full filepath requires no search
 346         if ($Is_VMS && m%[:>/\]]% && -f $_) {
 347             push(@found,dl_expandspec(VMS::Filespec::vmsify($_)));
 348             last arg unless wantarray;
 349             next;
 350         }
 351         elsif ($Is_MacOS) {
 352             if (m/:/ && -f $_) {
 353                 push(@found,$_);
 354                 last arg unless wantarray;
 355             }
 356         }
 357         elsif (m:/: && -f $_ && !$do_expand) {
 358             push(@found,$_);
 359             last arg unless wantarray;
 360             next;
 361         }
 362
 363         # Deal with directories first:
 364         #  Using a -L prefix is the preferred option (faster and more robust)
 365         if (m:^-L:) { s/^-L//; push(@dirs, $_); next; }
 366
 367         if ($Is_MacOS) {
 368             #  Otherwise we try to try to spot directories by a heuristic
 369             #  (this is a more complicated issue than it first appears)
 370             if (m/:/ && -d $_) {   push(@dirs, $_); next; }
 371             #  Only files should get this far...
 372             my(@names, $name);    # what filenames to look for
 373             s/^-l//;
 374             push(@names, $_);
 375             foreach $dir (@dirs, @dl_library_path) {
 376                 next unless -d $dir;
 377                 $dir =~ s/^([^:]+)$/:$1/;
 378                 $dir =~ s/:$//;
 379                 foreach $name (@names) {
 380                     my($file) = "$dir:$name";
 381                     print STDERR " checking in $dir for $name\n" if $dl_debug;
 382                     if (-f $file) {
 383                         push(@found, $file);
 384                         next arg; # no need to look any further
 385                     }
 386                 }
 387             }
 388             next;
 389         }
 390
 391         #  Otherwise we try to try to spot directories by a heuristic
 392         #  (this is a more complicated issue than it first appears)
 393         if (m:/: && -d $_) {   push(@dirs, $_); next; }
 394
 395         # VMS: we may be using native VMS directory syntax instead of
 396         # Unix emulation, so check this as well
 397         if ($Is_VMS && /[:>\]]/ && -d $_) {   push(@dirs, $_); next; }
 398
 399         #  Only files should get this far...
 400         my(@names, $name);    # what filenames to look for
 401         if (m:-l: ) {          # convert -lname to appropriate library name
 402             s/-l//;
 403             push(@names,"lib$_.$dl_so");
 404             push(@names,"lib$_.a");
 405         } else {                # Umm, a bare name. Try various alternatives:
 406             # these should be ordered with the most likely first
 407             push(@names,"$_.$dl_ext")    unless m/\.$dl_ext$/o;
 408             push(@names,"$_.$dl_so")     unless m/\.$dl_so$/o;
 409             push(@names,"lib$_.$dl_so")  unless m:/:;
 410             push(@names,"$_.a")          if !m/\.a$/ and $dlsrc eq "dl_dld.xs";
 411             push(@names, $_);
 412         }
 413         foreach $dir (@dirs, @dl_library_path) {
 414             next unless -d $dir;
 415             chop($dir = VMS::Filespec::unixpath($dir)) if $Is_VMS;
 416             foreach $name (@names) {
 417                 my($file) = "$dir/$name";
 418                 print STDERR " checking in $dir for $name\n" if $dl_debug;
 419                 $file = ($do_expand) ? dl_expandspec($file) : (-f $file && $file);
 420                 #$file = _check_file($file);
 421                 if ($file) {
 422                     push(@found, $file);
 423                     next arg; # no need to look any further
 424                 }
 425             }
 426         }
 427     }
 428     if ($dl_debug) {
 429         foreach(@dirs) {
 430             print STDERR " dl_findfile ignored non-existent directory: $_\n" unless -d $_;
 431         }
 432         print STDERR "dl_findfile found: @found\n";
 433     }
 434     return $found[0] unless wantarray;
 435     @found;
 436 }
 437
 438
 439 sub dl_expandspec {
 440     my($spec) = @_;
 441     # Optional function invoked if DynaLoader.pm sets $do_expand.
 442     # Most systems do not require or use this function.
 443     # Some systems may implement it in the dl_*.xs file in which case
 444     # this autoload version will not be called but is harmless.
 445
 446     # This function is designed to deal with systems which treat some
 447     # 'filenames' in a special way. For example VMS 'Logical Names'
 448     # (something like unix environment variables - but different).
 449     # This function should recognise such names and expand them into
 450     # full file paths.
 451     # Must return undef if $spec is invalid or file does not exist.
 452
 453     my $file = $spec; # default output to input
 454
 455     if ($Is_VMS) { # dl_expandspec should be defined in dl_vms.xs
 456         require Carp;
 457         Carp::croak("dl_expandspec: should be defined in XS file!\n");
 458     } else {
 459         return undef unless -f $file;
 460     }
 461     print STDERR "dl_expandspec($spec) => $file\n" if $dl_debug;
 462     $file;
 463 }
 464
 465 sub dl_find_symbol_anywhere
 466 {
 467     my $sym = shift;
 468     my $libref;
 469     foreach $libref (@dl_librefs) {
 470         my $symref = dl_find_symbol($libref,$sym);
 471         return $symref if $symref;
 472     }
 473     return undef;
 474 }
 475
 476 =head1 NAME
 477
 478 DynaLoader - Dynamically load C libraries into Perl code
 479
 480 dl_error(), dl_findfile(), dl_expandspec(), dl_load_file(), dl_unload_file(), dl_find_symbol(), dl_find_symbol_anywhere(), dl_undef_symbols(), dl_install_xsub(), dl_load_flags(), bootstrap() - routines used by DynaLoader modules
 481
 482 =head1 SYNOPSIS
 483
 484     package YourPackage;
 485     require DynaLoader;
 486     @ISA = qw(... DynaLoader ...);
 487     bootstrap YourPackage;
 488
 489     # optional method for 'global' loading
 490     sub dl_load_flags { 0x01 }
 491
 492
 493 =head1 DESCRIPTION
 494
 495 This document defines a standard generic interface to the dynamic
 496 linking mechanisms available on many platforms.  Its primary purpose is
 497 to implement automatic dynamic loading of Perl modules.
 498
 499 This document serves as both a specification for anyone wishing to
 500 implement the DynaLoader for a new platform and as a guide for
 501 anyone wishing to use the DynaLoader directly in an application.
 502
 503 The DynaLoader is designed to be a very simple high-level
 504 interface that is sufficiently general to cover the requirements
 505 of SunOS, HP-UX, NeXT, Linux, VMS and other platforms.
 506
 507 It is also hoped that the interface will cover the needs of OS/2, NT
 508 etc and also allow pseudo-dynamic linking (using C<ld -A> at runtime).
 509
 510 It must be stressed that the DynaLoader, by itself, is practically
 511 useless for accessing non-Perl libraries because it provides almost no
 512 Perl-to-C 'glue'.  There is, for example, no mechanism for calling a C
 513 library function or supplying arguments.  A C::DynaLib module
 514 is available from CPAN sites which performs that function for some
 515 common system types.
 516
 517 DynaLoader Interface Summary
 518
 519   @dl_library_path
 520   @dl_resolve_using
 521   @dl_require_symbols
 522   $dl_debug
 523   @dl_librefs
 524   @dl_modules
 525                                                   Implemented in:
 526   bootstrap($modulename)                               Perl
 527   @filepaths = dl_findfile(@names)                     Perl
 528   $flags = $modulename->dl_load_flags                  Perl
 529   $symref  = dl_find_symbol_anywhere($symbol)          Perl
 530
 531   $libref  = dl_load_file($filename, $flags)           C
 532   $status  = dl_unload_file($libref)                   C
 533   $symref  = dl_find_symbol($libref, $symbol)          C
 534   @symbols = dl_undef_symbols()                        C
 535   dl_install_xsub($name, $symref [, $filename])        C
 536   $message = dl_error                                  C
 537
 538 =over 4
 539
 540 =item @dl_library_path
 541
 542 The standard/default list of directories in which dl_findfile() will
 543 search for libraries etc.  Directories are searched in order:
 544 $dl_library_path[0], [1], ... etc
 545
 546 @dl_library_path is initialised to hold the list of 'normal' directories
 547 (F</usr/lib>, etc) determined by B<Configure> (C<$Config{'libpth'}>).  This should
 548 ensure portability across a wide range of platforms.
 549
 550 @dl_library_path should also be initialised with any other directories
 551 that can be determined from the environment at runtime (such as
 552 LD_LIBRARY_PATH for SunOS).
 553
 554 After initialisation @dl_library_path can be manipulated by an
 555 application using push and unshift before calling dl_findfile().
 556 Unshift can be used to add directories to the front of the search order
 557 either to save search time or to override libraries with the same name
 558 in the 'normal' directories.
 559
 560 The load function that dl_load_file() calls may require an absolute
 561 pathname.  The dl_findfile() function and @dl_library_path can be
 562 used to search for and return the absolute pathname for the
 563 library/object that you wish to load.
 564
 565 =item @dl_resolve_using
 566
 567 A list of additional libraries or other shared objects which can be
 568 used to resolve any undefined symbols that might be generated by a
 569 later call to load_file().
 570
 571 This is only required on some platforms which do not handle dependent
 572 libraries automatically.  For example the Socket Perl extension
 573 library (F<auto/Socket/Socket.so>) contains references to many socket
 574 functions which need to be resolved when it's loaded.  Most platforms
 575 will automatically know where to find the 'dependent' library (e.g.,
 576 F</usr/lib/libsocket.so>).  A few platforms need to be told the
 577 location of the dependent library explicitly.  Use @dl_resolve_using
 578 for this.
 579
 580 Example usage:
 581
 582     @dl_resolve_using = dl_findfile('-lsocket');
 583
 584 =item @dl_require_symbols
 585
 586 A list of one or more symbol names that are in the library/object file
 587 to be dynamically loaded.  This is only required on some platforms.
 588
 589 =item @dl_librefs
 590
 591 An array of the handles returned by successful calls to dl_load_file(),
 592 made by bootstrap, in the order in which they were loaded.
 593 Can be used with dl_find_symbol() to look for a symbol in any of
 594 the loaded files.
 595
 596 =item @dl_modules
 597
 598 An array of module (package) names that have been bootstrap'ed.
 599
 600 =item dl_error()
 601
 602 Syntax:
 603
 604     $message = dl_error();
 605
 606 Error message text from the last failed DynaLoader function.  Note
 607 that, similar to errno in unix, a successful function call does not
 608 reset this message.
 609
 610 Implementations should detect the error as soon as it occurs in any of
 611 the other functions and save the corresponding message for later
 612 retrieval.  This will avoid problems on some platforms (such as SunOS)
 613 where the error message is very temporary (e.g., dlerror()).
 614
 615 =item $dl_debug
 616
 617 Internal debugging messages are enabled when $dl_debug is set true.
 618 Currently setting $dl_debug only affects the Perl side of the
 619 DynaLoader.  These messages should help an application developer to
 620 resolve any DynaLoader usage problems.
 621
 622 $dl_debug is set to C<$ENV{'PERL_DL_DEBUG'}> if defined.
 623
 624 For the DynaLoader developer/porter there is a similar debugging
 625 variable added to the C code (see dlutils.c) and enabled if Perl was
 626 built with the B<-DDEBUGGING> flag.  This can also be set via the
 627 PERL_DL_DEBUG environment variable.  Set to 1 for minimal information or
 628 higher for more.
 629
 630 =item dl_findfile()
 631
 632 Syntax:
 633
 634     @filepaths = dl_findfile(@names)
 635
 636 Determine the full paths (including file suffix) of one or more
 637 loadable files given their generic names and optionally one or more
 638 directories.  Searches directories in @dl_library_path by default and
 639 returns an empty list if no files were found.
 640
 641 Names can be specified in a variety of platform independent forms.  Any
 642 names in the form B<-lname> are converted into F<libname.*>, where F<.*> is
 643 an appropriate suffix for the platform.
 644
 645 If a name does not already have a suitable prefix and/or suffix then
 646 the corresponding file will be searched for by trying combinations of
 647 prefix and suffix appropriate to the platform: "$name.o", "lib$name.*"
 648 and "$name".
 649
 650 If any directories are included in @names they are searched before
 651 @dl_library_path.  Directories may be specified as B<-Ldir>.  Any other
 652 names are treated as filenames to be searched for.
 653
 654 Using arguments of the form C<-Ldir> and C<-lname> is recommended.
 655
 656 Example:
 657
 658     @dl_resolve_using = dl_findfile(qw(-L/usr/5lib -lposix));
 659
 660
 661 =item dl_expandspec()
 662
 663 Syntax:
 664
 665     $filepath = dl_expandspec($spec)
 666
 667 Some unusual systems, such as VMS, require special filename handling in
 668 order to deal with symbolic names for files (i.e., VMS's Logical Names).
 669
 670 To support these systems a dl_expandspec() function can be implemented
 671 either in the F<dl_*.xs> file or code can be added to the autoloadable
 672 dl_expandspec() function in F<DynaLoader.pm>.  See F<DynaLoader.pm> for
 673 more information.
 674
 675 =item dl_load_file()
 676
 677 Syntax:
 678
 679     $libref = dl_load_file($filename, $flags)
 680
 681 Dynamically load $filename, which must be the path to a shared object
 682 or library.  An opaque 'library reference' is returned as a handle for
 683 the loaded object.  Returns undef on error.
 684
 685 The $flags argument to alters dl_load_file behaviour.
 686 Assigned bits:
 687
 688  0x01  make symbols available for linking later dl_load_file's.
 689        (only known to work on Solaris 2 using dlopen(RTLD_GLOBAL))
 690        (ignored under VMS; this is a normal part of image linking)
 691
 692 (On systems that provide a handle for the loaded object such as SunOS
 693 and HPUX, $libref will be that handle.  On other systems $libref will
 694 typically be $filename or a pointer to a buffer containing $filename.
 695 The application should not examine or alter $libref in any way.)
 696
 697 This is the function that does the real work.  It should use the
 698 current values of @dl_require_symbols and @dl_resolve_using if required.
 699
 700     SunOS: dlopen($filename)
 701     HP-UX: shl_load($filename)
 702     Linux: dld_create_reference(@dl_require_symbols); dld_link($filename)
 703     NeXT:  rld_load($filename, @dl_resolve_using)
 704     VMS:   lib$find_image_symbol($filename,$dl_require_symbols[0])
 705
 706 (The dlopen() function is also used by Solaris and some versions of
 707 Linux, and is a common choice when providing a "wrapper" on other
 708 mechanisms as is done in the OS/2 port.)
 709
 710 =item dl_unload_file()
 711
 712 Syntax:
 713
 714     $status = dl_unload_file($libref)
 715
 716 Dynamically unload $libref, which must be an opaque 'library reference' as
 717 returned from dl_load_file.  Returns one on success and zero on failure.
 718
 719 This function is optional and may not necessarily be provided on all platforms.
 720 If it is defined, it is called automatically when the interpreter exits for
 721 every shared object or library loaded by DynaLoader::bootstrap.  All such
 722 library references are stored in @dl_librefs by DynaLoader::Bootstrap as it
 723 loads the libraries.  The files are unloaded in last-in, first-out order.
 724
 725 This unloading is usually necessary when embedding a shared-object perl (e.g.
 726 one configured with -Duseshrplib) within a larger application, and the perl
 727 interpreter is created and destroyed several times within the lifetime of the
 728 application.  In this case it is possible that the system dynamic linker will
 729 unload and then subsequently reload the shared libperl without relocating any
 730 references to it from any files DynaLoaded by the previous incarnation of the
 731 interpreter.  As a result, any shared objects opened by DynaLoader may point to
 732 a now invalid 'ghost' of the libperl shared object, causing apparently random
 733 memory corruption and crashes.  This behaviour is most commonly seen when using
 734 Apache and mod_perl built with the APXS mechanism.
 735
 736     SunOS: dlclose($libref)
 737     HP-UX: ???
 738     Linux: ???
 739     NeXT:  ???
 740     VMS:   ???
 741
 742 (The dlclose() function is also used by Solaris and some versions of
 743 Linux, and is a common choice when providing a "wrapper" on other
 744 mechanisms as is done in the OS/2 port.)
 745
 746 =item dl_loadflags()
 747
 748 Syntax:
 749
 750     $flags = dl_loadflags $modulename;
 751
 752 Designed to be a method call, and to be overridden by a derived class
 753 (i.e. a class which has DynaLoader in its @ISA).  The definition in
 754 DynaLoader itself returns 0, which produces standard behavior from
 755 dl_load_file().
 756
 757 =item dl_find_symbol()
 758
 759 Syntax:
 760
 761     $symref = dl_find_symbol($libref, $symbol)
 762
 763 Return the address of the symbol $symbol or C<undef> if not found.  If the
 764 target system has separate functions to search for symbols of different
 765 types then dl_find_symbol() should search for function symbols first and
 766 then other types.
 767
 768 The exact manner in which the address is returned in $symref is not
 769 currently defined.  The only initial requirement is that $symref can
 770 be passed to, and understood by, dl_install_xsub().
 771
 772     SunOS: dlsym($libref, $symbol)
 773     HP-UX: shl_findsym($libref, $symbol)
 774     Linux: dld_get_func($symbol) and/or dld_get_symbol($symbol)
 775     NeXT:  rld_lookup("_$symbol")
 776     VMS:   lib$find_image_symbol($libref,$symbol)
 777
 778
 779 =item dl_find_symbol_anywhere()
 780
 781 Syntax:
 782
 783     $symref = dl_find_symbol_anywhere($symbol)
 784
 785 Applies dl_find_symbol() to the members of @dl_librefs and returns
 786 the first match found.
 787
 788 =item dl_undef_symbols()
 789
 790 Example
 791
 792     @symbols = dl_undef_symbols()
 793
 794 Return a list of symbol names which remain undefined after load_file().
 795 Returns C<()> if not known.  Don't worry if your platform does not provide
 796 a mechanism for this.  Most do not need it and hence do not provide it,
 797 they just return an empty list.
 798
 799
 800 =item dl_install_xsub()
 801
 802 Syntax:
 803
 804     dl_install_xsub($perl_name, $symref [, $filename])
 805
 806 Create a new Perl external subroutine named $perl_name using $symref as
 807 a pointer to the function which implements the routine.  This is simply
 808 a direct call to newXSUB().  Returns a reference to the installed
 809 function.
 810
 811 The $filename parameter is used by Perl to identify the source file for
 812 the function if required by die(), caller() or the debugger.  If
 813 $filename is not defined then "DynaLoader" will be used.
 814
 815
 816 =item bootstrap()
 817
 818 Syntax:
 819
 820 bootstrap($module)
 821
 822 This is the normal entry point for automatic dynamic loading in Perl.
 823
 824 It performs the following actions:
 825
 826 =over 8
 827
 828 =item *
 829
 830 locates an auto/$module directory by searching @INC
 831
 832 =item *
 833
 834 uses dl_findfile() to determine the filename to load
 835
 836 =item *
 837
 838 sets @dl_require_symbols to C<("boot_$module")>
 839
 840 =item *
 841
 842 executes an F<auto/$module/$module.bs> file if it exists
 843 (typically used to add to @dl_resolve_using any files which
 844 are required to load the module on the current platform)
 845
 846 =item *
 847
 848 calls dl_load_flags() to determine how to load the file.
 849
 850 =item *
 851
 852 calls dl_load_file() to load the file
 853
 854 =item *
 855
 856 calls dl_undef_symbols() and warns if any symbols are undefined
 857
 858 =item *
 859
 860 calls dl_find_symbol() for "boot_$module"
 861
 862 =item *
 863
 864 calls dl_install_xsub() to install it as "${module}::bootstrap"
 865
 866 =item *
 867
 868 calls &{"${module}::bootstrap"} to bootstrap the module (actually
 869 it uses the function reference returned by dl_install_xsub for speed)
 870
 871 =back
 872
 873 =back
 874
 875
 876 =head1 AUTHOR
 877
 878 Tim Bunce, 11 August 1994.
 879
 880 This interface is based on the work and comments of (in no particular
 881 order): Larry Wall, Robert Sanders, Dean Roehrich, Jeff Okamoto, Anno
 882 Siegel, Thomas Neumann, Paul Marquess, Charles Bailey, myself and others.
 883
 884 Larry Wall designed the elegant inherited bootstrap mechanism and
 885 implemented the first Perl 5 dynamic loader using it.
 886
 887 Solaris global loading added by Nick Ing-Simmons with design/coding
 888 assistance from Tim Bunce, January 1996.
 889
 890 =cut
 891 EOT
 892
 893 close OUT or die $!;
 894