ext/DynaLoader/DynaLoader_pm.PL

   1
   2 use Config;
   3
   4 sub to_string {
   5     my ($value) = @_;
   6     $value =~ s/\\/\\\\/g;
   7     $value =~ s/'/\\'/g;
   8     return "'$value'";
   9 }
  10
  11 unlink "DynaLoader.pm" if -f "DynaLoader.pm";
  12 open OUT, ">DynaLoader.pm" or die $!;
  13 print OUT <<'EOT';
  14
  15 # Generated from DynaLoader.pm.PL (resolved %Config::Config values)
  16
  17 package DynaLoader;
  18
  19 #   And Gandalf said: 'Many folk like to know beforehand what is to
  20 #   be set on the table; but those who have laboured to prepare the
  21 #   feast like to keep their secret; for wonder makes the words of
  22 #   praise louder.'
  23
  24 #   (Quote from Tolkien suggested by Anno Siegel.)
  25 #
  26 # See pod text at end of file for documentation.
  27 # See also ext/DynaLoader/README in source tree for other information.
  28 #
  29 # Tim.Bunce@ig.co.uk, August 1994
  30
  31 $VERSION = "1.04";      # avoid typo warning
  32
  33 require AutoLoader;
  34 *AUTOLOAD = \&AutoLoader::AUTOLOAD;
  35
  36 # The following require can't be removed during maintenance
  37 # releases, sadly, because of the risk of buggy code that does
  38 # require Carp; Carp::croak "..."; without brackets dying
  39 # if Carp hasn't been loaded in earlier compile time. :-(
  40 # We'll let those bugs get found on the development track.
  41 require Carp if $] < 5.00450;
  42
  43
  44 # enable debug/trace messages from DynaLoader perl code
  45 $dl_debug = $ENV{PERL_DL_DEBUG} || 0 unless defined $dl_debug;
  46
  47 #
  48 # Flags to alter dl_load_file behaviour.  Assigned bits:
  49 #   0x01  make symbols available for linking later dl_load_file's.
  50 #         (only known to work on Solaris 2 using dlopen(RTLD_GLOBAL))
  51 #         (ignored under VMS; effect is built-in to image linking)
  52 #
  53 # This is called as a class method $module->dl_load_flags.  The
  54 # definition here will be inherited and result on "default" loading
  55 # behaviour unless a sub-class of DynaLoader defines its own version.
  56 #
  57
  58 sub dl_load_flags { 0x00 }
  59
  60 # ($dl_dlext, $dlsrc)
  61 #         = @Config::Config{'dlext', 'dlsrc'};
  62 EOT
  63
  64 print OUT "  (\$dl_dlext, \$dlsrc) = (",
  65           to_string($Config::Config{'dlext'}), ",",
  66           to_string($Config::Config{'dlsrc'}), ")\n;" ;
  67
  68 print OUT <<'EOT';
  69
  70 # Some systems need special handling to expand file specifications
  71 # (VMS support by Charles Bailey <bailey@HMIVAX.HUMGEN.UPENN.EDU>)
  72 # See dl_expandspec() for more details. Should be harmless but
  73 # inefficient to define on systems that don't need it.
  74 $do_expand = $Is_VMS = $^O eq 'VMS';
  75 $Is_MacOS  = $^O eq 'MacOS';
  76
  77 @dl_require_symbols = ();       # names of symbols we need
  78 @dl_resolve_using   = ();       # names of files to link with
  79 @dl_library_path    = ();       # path to look for files
  80 #@dl_librefs         = ();       # things we have loaded
  81 #@dl_modules         = ();       # Modules we have loaded
  82
  83 # This is a fix to support DLD's unfortunate desire to relink -lc
  84 @dl_resolve_using = dl_findfile('-lc') if $dlsrc eq "dl_dld.xs";
  85
  86 # Initialise @dl_library_path with the 'standard' library path
  87 # for this platform as determined by Configure
  88
  89 # push(@dl_library_path, split(' ', $Config::Config{'libpth'});
  90 EOT
  91
  92 print OUT "push(\@dl_library_path, split(' ', ",
  93           to_string($Config::Config{'libpth'}), "));\n";
  94
  95 print OUT <<'EOT';
  96
  97 # Add to @dl_library_path any extra directories we can gather
  98 # from environment variables.
  99 if ($Is_MacOS) {
 100     push(@dl_library_path, split(/,/, $ENV{LD_LIBRARY_PATH}))
 101         if exists $ENV{LD_LIBRARY_PATH};
 102 } else {
 103 #     push(@dl_library_path, split(/:/, $ENV{$Config::Config{ldlibpthname}}))
 104 #       if exists      $Config::Config{ldlibpthname}        &&
 105 #                        $Config::Config{ldlibpthname}  ne '' &&
 106 #                 exists $ENV{$Config::Config{ldlibpthname}}       ;;
 107 #     push(@dl_library_path, split(/:/, $ENV{$Config::Config{ldlibpthname}}))
 108 #       if exists      $Config::Config{ldlibpthname}        &&
 109 #                        $Config::Config{ldlibpthname}  ne '' &&
 110 #                 exists $ENV{$Config::Config{ldlibpthname}}       ;;
 111 # E.g. HP-UX supports both its native SHLIB_PATH *and* LD_LIBRARY_PATH.
 112 # push(@dl_library_path, split(/:/, $ENV{LD_LIBRARY_PATH}))
 113 #     if exists $ENV{LD_LIBRARY_PATH};
 114 EOT
 115
 116 # Make a list of paths to print.
 117 # HP-UX supports both its native SHLIB_PATH *and* LD_LIBRARY_PATH,
 118 # but for other OSes no point pushing 'LD_LIBRARY_PATH' twice.
 119 my @ldlibpthname = 'LD_LIBRARY_PATH';
 120 if (exists $Config::Config{ldlibpthname}
 121     and length $Config::Config{ldlibpthname}
 122     and $Config::Config{ldlibpthname} ne 'LD_LIBRARY_PATH') {
 123     unshift @ldlibpthname, $Config::Config{ldlibpthname};
 124 }
 125
 126 foreach (@ldlibpthname) {
 127     print OUT "    push(\@dl_library_path, split(/:/, \$ENV{", to_string($_),
 128                   "}))\n\tif exists \$ENV{", to_string($_), "};\n";
 129 }
 130
 131 print OUT <<'EOT';
 132 }
 133
 134 # No prizes for guessing why we don't say 'bootstrap DynaLoader;' here.
 135 # NOTE: All dl_*.xs (including dl_none.xs) define a dl_error() XSUB
 136 boot_DynaLoader('DynaLoader') if defined(&boot_DynaLoader) &&
 137                                 !defined(&dl_error);
 138
 139 if ($dl_debug) {
 140     print STDERR "DynaLoader.pm loaded (@INC, @dl_library_path)\n";
 141     print STDERR "DynaLoader not linked into this perl\n"
 142             unless defined(&boot_DynaLoader);
 143 }
 144
 145 1; # End of main code
 146
 147
 148 sub croak   { require Carp; Carp::croak(@_)   }
 149
 150 sub bootstrap_inherit {
 151     my $module = $_[0];
 152     local *isa = *{"$module\::ISA"};
 153     local @isa = (@isa, 'DynaLoader');
 154     # Cannot goto due to delocalization.  Will report errors on a wrong line?
 155     bootstrap(@_);
 156 }
 157
 158 # The bootstrap function cannot be autoloaded (without complications)
 159 # so we define it here:
 160
 161 sub bootstrap {
 162     # use local vars to enable $module.bs script to edit values
 163     local(@args) = @_;
 164     local($module) = $args[0];
 165     local(@dirs, $file);
 166
 167     unless ($module) {
 168         require Carp;
 169         Carp::confess("Usage: DynaLoader::bootstrap(module)");
 170     }
 171
 172     # A common error on platforms which don't support dynamic loading.
 173     # Since it's fatal and potentially confusing we give a detailed message.
 174     croak("Can't load module $module, dynamic loading not available in this perl.\n".
 175         "  (You may need to build a new perl executable which either supports\n".
 176         "  dynamic loading or has the $module module statically linked into it.)\n")
 177         unless defined(&dl_load_file);
 178
 179     my @modparts = split(/::/,$module);
 180     my $modfname = $modparts[-1];
 181
 182     # Some systems have restrictions on files names for DLL's etc.
 183     # mod2fname returns appropriate file base name (typically truncated)
 184     # It may also edit @modparts if required.
 185     $modfname = &mod2fname(\@modparts) if defined &mod2fname;
 186
 187     my $modpname = join(($Is_MacOS ? ':' : '/'),@modparts);
 188
 189     print STDERR "DynaLoader::bootstrap for $module ",
 190                 ($Is_MacOS
 191                        ? "(:auto:$modpname:$modfname.$dl_dlext)\n" :
 192                        "(auto/$modpname/$modfname.$dl_dlext)\n")
 193         if $dl_debug;
 194
 195     foreach (@INC) {
 196         chop($_ = VMS::Filespec::unixpath($_)) if $Is_VMS;
 197         my $dir;
 198         if ($Is_MacOS) {
 199             chop $_  if /:$/;
 200             $dir = "$_:auto:$modpname";
 201         } else {
 202             $dir = "$_/auto/$modpname";
 203         }
 204         next unless -d $dir; # skip over uninteresting directories
 205
 206         # check for common cases to avoid autoload of dl_findfile
 207         my $try = $Is_MacOS ? "$dir:$modfname.$dl_dlext" : "$dir/$modfname.$dl_dlext";
 208         last if $file = ($do_expand) ? dl_expandspec($try) : (-f $try && $try);
 209
 210         # no luck here, save dir for possible later dl_findfile search
 211         push @dirs, $dir;
 212     }
 213     # last resort, let dl_findfile have a go in all known locations
 214     $file = dl_findfile(map("-L$_",@dirs,@INC), $modfname) unless $file;
 215
 216     croak("Can't locate loadable object for module $module in \@INC (\@INC contains: @INC)")
 217         unless $file;   # wording similar to error from 'require'
 218
 219     $file = uc($file) if $Is_VMS && $Config{d_vms_case_sensitive_symbols};
 220     my $bootname = "boot_$module";
 221     $bootname =~ s/\W/_/g;
 222     @dl_require_symbols = ($bootname);
 223
 224     # Execute optional '.bootstrap' perl script for this module.
 225     # The .bs file can be used to configure @dl_resolve_using etc to
 226     # match the needs of the individual module on this architecture.
 227     my $bs = $file;
 228     $bs =~ s/(\.\w+)?(;\d*)?$/\.bs/; # look for .bs 'beside' the library
 229     if (-s $bs) { # only read file if it's not empty
 230         print STDERR "BS: $bs ($^O, $dlsrc)\n" if $dl_debug;
 231         eval { do $bs; };
 232         warn "$bs: $@\n" if $@;
 233     }
 234
 235     # Many dynamic extension loading problems will appear to come from
 236     # this section of code: XYZ failed at line 123 of DynaLoader.pm.
 237     # Often these errors are actually occurring in the initialisation
 238     # C code of the extension XS file. Perl reports the error as being
 239     # in this perl code simply because this was the last perl code
 240     # it executed.
 241
 242     my $libref = dl_load_file($file, $module->dl_load_flags) or
 243         croak("Can't load '$file' for module $module: ".dl_error());
 244
 245     push(@dl_librefs,$libref);  # record loaded object
 246
 247     my @unresolved = dl_undef_symbols();
 248     if (@unresolved) {
 249         require Carp;
 250         Carp::carp("Undefined symbols present after loading $file: @unresolved\n");
 251     }
 252
 253     my $boot_symbol_ref = dl_find_symbol($libref, $bootname) or
 254          croak("Can't find '$bootname' symbol in $file\n");
 255
 256     my $xs = dl_install_xsub("${module}::bootstrap", $boot_symbol_ref, $file);
 257
 258     push(@dl_modules, $module); # record loaded module
 259
 260     # See comment block above
 261     &$xs(@args);
 262 }
 263
 264
 265 #sub _check_file {   # private utility to handle dl_expandspec vs -f tests
 266 #    my($file) = @_;
 267 #    return $file if (!$do_expand && -f $file); # the common case
 268 #    return $file if ( $do_expand && ($file=dl_expandspec($file)));
 269 #    return undef;
 270 #}
 271
 272
 273 # Let autosplit and the autoloader deal with these functions:
 274 __END__
 275
 276
 277 sub dl_findfile {
 278     # Read ext/DynaLoader/DynaLoader.doc for detailed information.
 279     # This function does not automatically consider the architecture
 280     # or the perl library auto directories.
 281     my (@args) = @_;
 282     my (@dirs,  $dir);   # which directories to search
 283     my (@found);         # full paths to real files we have found
 284 EOT
 285
 286 print OUT '    my $dl_ext= ' . to_string($Config::Config{'dlext'}) .
 287           "; # \$Config::Config{'dlext'} suffix for perl extensions\n";
 288 print OUT '    my $dl_so = ' . to_string($Config::Config{'so'}) .
 289           "; # \$Config::Config{'so'} suffix for shared libraries\n";
 290
 291 print OUT <<'EOT';
 292
 293     print STDERR "dl_findfile(@args)\n" if $dl_debug;
 294
 295     # accumulate directories but process files as they appear
 296     arg: foreach(@args) {
 297         #  Special fast case: full filepath requires no search
 298         if ($Is_VMS && m%[:>/\]]% && -f $_) {
 299             push(@found,dl_expandspec(VMS::Filespec::vmsify($_)));
 300             last arg unless wantarray;
 301             next;
 302         }
 303         elsif ($Is_MacOS) {
 304             if (m/:/ && -f $_) {
 305                 push(@found,$_);
 306                 last arg unless wantarray;
 307             }
 308         }
 309         elsif (m:/: && -f $_ && !$do_expand) {
 310             push(@found,$_);
 311             last arg unless wantarray;
 312             next;
 313         }
 314
 315         # Deal with directories first:
 316         #  Using a -L prefix is the preferred option (faster and more robust)
 317         if (m:^-L:) { s/^-L//; push(@dirs, $_); next; }
 318
 319         if ($Is_MacOS) {
 320             #  Otherwise we try to try to spot directories by a heuristic
 321             #  (this is a more complicated issue than it first appears)
 322             if (m/:/ && -d $_) {   push(@dirs, $_); next; }
 323             #  Only files should get this far...
 324             my(@names, $name);    # what filenames to look for
 325             s/^-l//;
 326             push(@names, $_);
 327             foreach $dir (@dirs, @dl_library_path) {
 328                 next unless -d $dir;
 329                 $dir =~ s/^([^:]+)$/:$1/;
 330                 $dir =~ s/:$//;
 331                 foreach $name (@names) {
 332                     my($file) = "$dir:$name";
 333                     print STDERR " checking in $dir for $name\n" if $dl_debug;
 334                     if (-f $file) {
 335                         push(@found, $file);
 336                         next arg; # no need to look any further
 337                     }
 338                 }
 339             }
 340             next;
 341         }
 342
 343         #  Otherwise we try to try to spot directories by a heuristic
 344         #  (this is a more complicated issue than it first appears)
 345         if (m:/: && -d $_) {   push(@dirs, $_); next; }
 346
 347         # VMS: we may be using native VMS directry syntax instead of
 348         # Unix emulation, so check this as well
 349         if ($Is_VMS && /[:>\]]/ && -d $_) {   push(@dirs, $_); next; }
 350
 351         #  Only files should get this far...
 352         my(@names, $name);    # what filenames to look for
 353         if (m:-l: ) {          # convert -lname to appropriate library name
 354             s/-l//;
 355             push(@names,"lib$_.$dl_so");
 356             push(@names,"lib$_.a");
 357         } else {                # Umm, a bare name. Try various alternatives:
 358             # these should be ordered with the most likely first
 359             push(@names,"$_.$dl_ext")    unless m/\.$dl_ext$/o;
 360             push(@names,"$_.$dl_so")     unless m/\.$dl_so$/o;
 361             push(@names,"lib$_.$dl_so")  unless m:/:;
 362             push(@names,"$_.a")          if !m/\.a$/ and $dlsrc eq "dl_dld.xs";
 363             push(@names, $_);
 364         }
 365         foreach $dir (@dirs, @dl_library_path) {
 366             next unless -d $dir;
 367             chop($dir = VMS::Filespec::unixpath($dir)) if $Is_VMS;
 368             foreach $name (@names) {
 369                 my($file) = "$dir/$name";
 370                 print STDERR " checking in $dir for $name\n" if $dl_debug;
 371                 $file = ($do_expand) ? dl_expandspec($file) : (-f $file && $file);
 372                 #$file = _check_file($file);
 373                 if ($file) {
 374                     push(@found, $file);
 375                     next arg; # no need to look any further
 376                 }
 377             }
 378         }
 379     }
 380     if ($dl_debug) {
 381         foreach(@dirs) {
 382             print STDERR " dl_findfile ignored non-existent directory: $_\n" unless -d $_;
 383         }
 384         print STDERR "dl_findfile found: @found\n";
 385     }
 386     return $found[0] unless wantarray;
 387     @found;
 388 }
 389
 390
 391 sub dl_expandspec {
 392     my($spec) = @_;
 393     # Optional function invoked if DynaLoader.pm sets $do_expand.
 394     # Most systems do not require or use this function.
 395     # Some systems may implement it in the dl_*.xs file in which case
 396     # this autoload version will not be called but is harmless.
 397
 398     # This function is designed to deal with systems which treat some
 399     # 'filenames' in a special way. For example VMS 'Logical Names'
 400     # (something like unix environment variables - but different).
 401     # This function should recognise such names and expand them into
 402     # full file paths.
 403     # Must return undef if $spec is invalid or file does not exist.
 404
 405     my $file = $spec; # default output to input
 406
 407     if ($Is_VMS) { # dl_expandspec should be defined in dl_vms.xs
 408         require Carp;
 409         Carp::croak("dl_expandspec: should be defined in XS file!\n");
 410     } else {
 411         return undef unless -f $file;
 412     }
 413     print STDERR "dl_expandspec($spec) => $file\n" if $dl_debug;
 414     $file;
 415 }
 416
 417 sub dl_find_symbol_anywhere
 418 {
 419     my $sym = shift;
 420     my $libref;
 421     foreach $libref (@dl_librefs) {
 422         my $symref = dl_find_symbol($libref,$sym);
 423         return $symref if $symref;
 424     }
 425     return undef;
 426 }
 427
 428 =head1 NAME
 429
 430 DynaLoader - Dynamically load C libraries into Perl code
 431
 432 dl_error(), dl_findfile(), dl_expandspec(), dl_load_file(), dl_unload_file(), dl_find_symbol(), dl_find_symbol_anywhere(), dl_undef_symbols(), dl_install_xsub(), dl_load_flags(), bootstrap() - routines used by DynaLoader modules
 433
 434 =head1 SYNOPSIS
 435
 436     package YourPackage;
 437     require DynaLoader;
 438     @ISA = qw(... DynaLoader ...);
 439     bootstrap YourPackage;
 440
 441     # optional method for 'global' loading
 442     sub dl_load_flags { 0x01 }
 443
 444
 445 =head1 DESCRIPTION
 446
 447 This document defines a standard generic interface to the dynamic
 448 linking mechanisms available on many platforms.  Its primary purpose is
 449 to implement automatic dynamic loading of Perl modules.
 450
 451 This document serves as both a specification for anyone wishing to
 452 implement the DynaLoader for a new platform and as a guide for
 453 anyone wishing to use the DynaLoader directly in an application.
 454
 455 The DynaLoader is designed to be a very simple high-level
 456 interface that is sufficiently general to cover the requirements
 457 of SunOS, HP-UX, NeXT, Linux, VMS and other platforms.
 458
 459 It is also hoped that the interface will cover the needs of OS/2, NT
 460 etc and also allow pseudo-dynamic linking (using C<ld -A> at runtime).
 461
 462 It must be stressed that the DynaLoader, by itself, is practically
 463 useless for accessing non-Perl libraries because it provides almost no
 464 Perl-to-C 'glue'.  There is, for example, no mechanism for calling a C
 465 library function or supplying arguments.  A C::DynaLib module
 466 is available from CPAN sites which performs that function for some
 467 common system types.
 468
 469 DynaLoader Interface Summary
 470
 471   @dl_library_path
 472   @dl_resolve_using
 473   @dl_require_symbols
 474   $dl_debug
 475   @dl_librefs
 476   @dl_modules
 477                                                   Implemented in:
 478   bootstrap($modulename)                               Perl
 479   @filepaths = dl_findfile(@names)                     Perl
 480   $flags = $modulename->dl_load_flags                  Perl
 481   $symref  = dl_find_symbol_anywhere($symbol)          Perl
 482
 483   $libref  = dl_load_file($filename, $flags)           C
 484   $status  = dl_unload_file($libref)                   C
 485   $symref  = dl_find_symbol($libref, $symbol)          C
 486   @symbols = dl_undef_symbols()                        C
 487   dl_install_xsub($name, $symref [, $filename])        C
 488   $message = dl_error                                  C
 489
 490 =over 4
 491
 492 =item @dl_library_path
 493
 494 The standard/default list of directories in which dl_findfile() will
 495 search for libraries etc.  Directories are searched in order:
 496 $dl_library_path[0], [1], ... etc
 497
 498 @dl_library_path is initialised to hold the list of 'normal' directories
 499 (F</usr/lib>, etc) determined by B<Configure> (C<$Config{'libpth'}>).  This should
 500 ensure portability across a wide range of platforms.
 501
 502 @dl_library_path should also be initialised with any other directories
 503 that can be determined from the environment at runtime (such as
 504 LD_LIBRARY_PATH for SunOS).
 505
 506 After initialisation @dl_library_path can be manipulated by an
 507 application using push and unshift before calling dl_findfile().
 508 Unshift can be used to add directories to the front of the search order
 509 either to save search time or to override libraries with the same name
 510 in the 'normal' directories.
 511
 512 The load function that dl_load_file() calls may require an absolute
 513 pathname.  The dl_findfile() function and @dl_library_path can be
 514 used to search for and return the absolute pathname for the
 515 library/object that you wish to load.
 516
 517 =item @dl_resolve_using
 518
 519 A list of additional libraries or other shared objects which can be
 520 used to resolve any undefined symbols that might be generated by a
 521 later call to load_file().
 522
 523 This is only required on some platforms which do not handle dependent
 524 libraries automatically.  For example the Socket Perl extension
 525 library (F<auto/Socket/Socket.so>) contains references to many socket
 526 functions which need to be resolved when it's loaded.  Most platforms
 527 will automatically know where to find the 'dependent' library (e.g.,
 528 F</usr/lib/libsocket.so>).  A few platforms need to be told the
 529 location of the dependent library explicitly.  Use @dl_resolve_using
 530 for this.
 531
 532 Example usage:
 533
 534     @dl_resolve_using = dl_findfile('-lsocket');
 535
 536 =item @dl_require_symbols
 537
 538 A list of one or more symbol names that are in the library/object file
 539 to be dynamically loaded.  This is only required on some platforms.
 540
 541 =item @dl_librefs
 542
 543 An array of the handles returned by successful calls to dl_load_file(),
 544 made by bootstrap, in the order in which they were loaded.
 545 Can be used with dl_find_symbol() to look for a symbol in any of
 546 the loaded files.
 547
 548 =item @dl_modules
 549
 550 An array of module (package) names that have been bootstrap'ed.
 551
 552 =item dl_error()
 553
 554 Syntax:
 555
 556     $message = dl_error();
 557
 558 Error message text from the last failed DynaLoader function.  Note
 559 that, similar to errno in unix, a successful function call does not
 560 reset this message.
 561
 562 Implementations should detect the error as soon as it occurs in any of
 563 the other functions and save the corresponding message for later
 564 retrieval.  This will avoid problems on some platforms (such as SunOS)
 565 where the error message is very temporary (e.g., dlerror()).
 566
 567 =item $dl_debug
 568
 569 Internal debugging messages are enabled when $dl_debug is set true.
 570 Currently setting $dl_debug only affects the Perl side of the
 571 DynaLoader.  These messages should help an application developer to
 572 resolve any DynaLoader usage problems.
 573
 574 $dl_debug is set to C<$ENV{'PERL_DL_DEBUG'}> if defined.
 575
 576 For the DynaLoader developer/porter there is a similar debugging
 577 variable added to the C code (see dlutils.c) and enabled if Perl was
 578 built with the B<-DDEBUGGING> flag.  This can also be set via the
 579 PERL_DL_DEBUG environment variable.  Set to 1 for minimal information or
 580 higher for more.
 581
 582 =item dl_findfile()
 583
 584 Syntax:
 585
 586     @filepaths = dl_findfile(@names)
 587
 588 Determine the full paths (including file suffix) of one or more
 589 loadable files given their generic names and optionally one or more
 590 directories.  Searches directories in @dl_library_path by default and
 591 returns an empty list if no files were found.
 592
 593 Names can be specified in a variety of platform independent forms.  Any
 594 names in the form B<-lname> are converted into F<libname.*>, where F<.*> is
 595 an appropriate suffix for the platform.
 596
 597 If a name does not already have a suitable prefix and/or suffix then
 598 the corresponding file will be searched for by trying combinations of
 599 prefix and suffix appropriate to the platform: "$name.o", "lib$name.*"
 600 and "$name".
 601
 602 If any directories are included in @names they are searched before
 603 @dl_library_path.  Directories may be specified as B<-Ldir>.  Any other
 604 names are treated as filenames to be searched for.
 605
 606 Using arguments of the form C<-Ldir> and C<-lname> is recommended.
 607
 608 Example:
 609
 610     @dl_resolve_using = dl_findfile(qw(-L/usr/5lib -lposix));
 611
 612
 613 =item dl_expandspec()
 614
 615 Syntax:
 616
 617     $filepath = dl_expandspec($spec)
 618
 619 Some unusual systems, such as VMS, require special filename handling in
 620 order to deal with symbolic names for files (i.e., VMS's Logical Names).
 621
 622 To support these systems a dl_expandspec() function can be implemented
 623 either in the F<dl_*.xs> file or code can be added to the autoloadable
 624 dl_expandspec() function in F<DynaLoader.pm>.  See F<DynaLoader.pm> for
 625 more information.
 626
 627 =item dl_load_file()
 628
 629 Syntax:
 630
 631     $libref = dl_load_file($filename, $flags)
 632
 633 Dynamically load $filename, which must be the path to a shared object
 634 or library.  An opaque 'library reference' is returned as a handle for
 635 the loaded object.  Returns undef on error.
 636
 637 The $flags argument to alters dl_load_file behaviour.
 638 Assigned bits:
 639
 640  0x01  make symbols available for linking later dl_load_file's.
 641        (only known to work on Solaris 2 using dlopen(RTLD_GLOBAL))
 642        (ignored under VMS; this is a normal part of image linking)
 643
 644 (On systems that provide a handle for the loaded object such as SunOS
 645 and HPUX, $libref will be that handle.  On other systems $libref will
 646 typically be $filename or a pointer to a buffer containing $filename.
 647 The application should not examine or alter $libref in any way.)
 648
 649 This is the function that does the real work.  It should use the
 650 current values of @dl_require_symbols and @dl_resolve_using if required.
 651
 652     SunOS: dlopen($filename)
 653     HP-UX: shl_load($filename)
 654     Linux: dld_create_reference(@dl_require_symbols); dld_link($filename)
 655     NeXT:  rld_load($filename, @dl_resolve_using)
 656     VMS:   lib$find_image_symbol($filename,$dl_require_symbols[0])
 657
 658 (The dlopen() function is also used by Solaris and some versions of
 659 Linux, and is a common choice when providing a "wrapper" on other
 660 mechanisms as is done in the OS/2 port.)
 661
 662 =item dl_unload_file()
 663
 664 Syntax:
 665
 666     $status = dl_unload_file($libref)
 667
 668 Dynamically unload $libref, which must be an opaque 'library reference' as
 669 returned from dl_load_file.  Returns one on success and zero on failure.
 670
 671 This function is optional and may not necessarily be provided on all platforms.
 672 If it is defined, it is called automatically when the interpreter exits for
 673 every shared object or library loaded by DynaLoader::bootstrap.  All such
 674 library references are stored in @dl_librefs by DynaLoader::Bootstrap as it
 675 loads the libraries.  The files are unloaded in last-in, first-out order.
 676
 677 This unloading is usually necessary when embedding a shared-object perl (e.g.
 678 one configured with -Duseshrplib) within a larger application, and the perl
 679 interpreter is created and destroyed several times within the lifetime of the
 680 application.  In this case it is possible that the system dynamic linker will
 681 unload and then subsequently reload the shared libperl without relocating any
 682 references to it from any files DynaLoaded by the previous incarnation of the
 683 interpreter.  As a result, any shared objects opened by DynaLoader may point to
 684 a now invalid 'ghost' of the libperl shared object, causing apparently random
 685 memory corruption and crashes.  This behaviour is most commonly seen when using
 686 Apache and mod_perl built with the APXS mechanism.
 687
 688     SunOS: dlclose($libref)
 689     HP-UX: ???
 690     Linux: ???
 691     NeXT:  ???
 692     VMS:   ???
 693
 694 (The dlclose() function is also used by Solaris and some versions of
 695 Linux, and is a common choice when providing a "wrapper" on other
 696 mechanisms as is done in the OS/2 port.)
 697
 698 =item dl_loadflags()
 699
 700 Syntax:
 701
 702     $flags = dl_loadflags $modulename;
 703
 704 Designed to be a method call, and to be overridden by a derived class
 705 (i.e. a class which has DynaLoader in its @ISA).  The definition in
 706 DynaLoader itself returns 0, which produces standard behavior from
 707 dl_load_file().
 708
 709 =item dl_find_symbol()
 710
 711 Syntax:
 712
 713     $symref = dl_find_symbol($libref, $symbol)
 714
 715 Return the address of the symbol $symbol or C<undef> if not found.  If the
 716 target system has separate functions to search for symbols of different
 717 types then dl_find_symbol() should search for function symbols first and
 718 then other types.
 719
 720 The exact manner in which the address is returned in $symref is not
 721 currently defined.  The only initial requirement is that $symref can
 722 be passed to, and understood by, dl_install_xsub().
 723
 724     SunOS: dlsym($libref, $symbol)
 725     HP-UX: shl_findsym($libref, $symbol)
 726     Linux: dld_get_func($symbol) and/or dld_get_symbol($symbol)
 727     NeXT:  rld_lookup("_$symbol")
 728     VMS:   lib$find_image_symbol($libref,$symbol)
 729
 730
 731 =item dl_find_symbol_anywhere()
 732
 733 Syntax:
 734
 735     $symref = dl_find_symbol_anywhere($symbol)
 736
 737 Applies dl_find_symbol() to the members of @dl_librefs and returns
 738 the first match found.
 739
 740 =item dl_undef_symbols()
 741
 742 Example
 743
 744     @symbols = dl_undef_symbols()
 745
 746 Return a list of symbol names which remain undefined after load_file().
 747 Returns C<()> if not known.  Don't worry if your platform does not provide
 748 a mechanism for this.  Most do not need it and hence do not provide it,
 749 they just return an empty list.
 750
 751
 752 =item dl_install_xsub()
 753
 754 Syntax:
 755
 756     dl_install_xsub($perl_name, $symref [, $filename])
 757
 758 Create a new Perl external subroutine named $perl_name using $symref as
 759 a pointer to the function which implements the routine.  This is simply
 760 a direct call to newXSUB().  Returns a reference to the installed
 761 function.
 762
 763 The $filename parameter is used by Perl to identify the source file for
 764 the function if required by die(), caller() or the debugger.  If
 765 $filename is not defined then "DynaLoader" will be used.
 766
 767
 768 =item bootstrap()
 769
 770 Syntax:
 771
 772 bootstrap($module)
 773
 774 This is the normal entry point for automatic dynamic loading in Perl.
 775
 776 It performs the following actions:
 777
 778 =over 8
 779
 780 =item *
 781
 782 locates an auto/$module directory by searching @INC
 783
 784 =item *
 785
 786 uses dl_findfile() to determine the filename to load
 787
 788 =item *
 789
 790 sets @dl_require_symbols to C<("boot_$module")>
 791
 792 =item *
 793
 794 executes an F<auto/$module/$module.bs> file if it exists
 795 (typically used to add to @dl_resolve_using any files which
 796 are required to load the module on the current platform)
 797
 798 =item *
 799
 800 calls dl_load_flags() to determine how to load the file.
 801
 802 =item *
 803
 804 calls dl_load_file() to load the file
 805
 806 =item *
 807
 808 calls dl_undef_symbols() and warns if any symbols are undefined
 809
 810 =item *
 811
 812 calls dl_find_symbol() for "boot_$module"
 813
 814 =item *
 815
 816 calls dl_install_xsub() to install it as "${module}::bootstrap"
 817
 818 =item *
 819
 820 calls &{"${module}::bootstrap"} to bootstrap the module (actually
 821 it uses the function reference returned by dl_install_xsub for speed)
 822
 823 =back
 824
 825 =back
 826
 827
 828 =head1 AUTHOR
 829
 830 Tim Bunce, 11 August 1994.
 831
 832 This interface is based on the work and comments of (in no particular
 833 order): Larry Wall, Robert Sanders, Dean Roehrich, Jeff Okamoto, Anno
 834 Siegel, Thomas Neumann, Paul Marquess, Charles Bailey, myself and others.
 835
 836 Larry Wall designed the elegant inherited bootstrap mechanism and
 837 implemented the first Perl 5 dynamic loader using it.
 838
 839 Solaris global loading added by Nick Ing-Simmons with design/coding
 840 assistance from Tim Bunce, January 1996.
 841
 842 =cut
 843 EOT
 844
 845 close OUT or die $!;
 846