ext/DynaLoader/DynaLoader.pm

   1 package DynaLoader;
   2
   3 #   And Gandalf said: 'Many folk like to know beforehand what is to
   4 #   be set on the table; but those who have laboured to prepare the
   5 #   feast like to keep their secret; for wonder makes the words of
   6 #   praise louder.'
   7
   8 #   (Quote from Tolkien sugested by Anno Siegel.)
   9 #
  10 # See pod text at end of file for documentation.
  11 # See also ext/DynaLoader/README in source tree for other information.
  12 #
  13 # Tim.Bunce@ig.co.uk, August 1994
  14
  15 use vars qw($VERSION @ISA) ;
  16
  17 require Carp;
  18 require Config;
  19 require AutoLoader;
  20
  21 @ISA=qw(AutoLoader);
  22
  23 $VERSION = "1.00" ;
  24
  25 sub import { }          # override import inherited from AutoLoader
  26
  27 # enable debug/trace messages from DynaLoader perl code
  28 $dl_debug = $ENV{PERL_DL_DEBUG} || 0 unless defined $dl_debug;
  29
  30 ($dl_dlext, $dlsrc)
  31         = @Config::Config{'dlext', 'dlsrc'};
  32
  33 # Some systems need special handling to expand file specifications
  34 # (VMS support by Charles Bailey <bailey@HMIVAX.HUMGEN.UPENN.EDU>)
  35 # See dl_expandspec() for more details. Should be harmless but
  36 # inefficient to define on systems that don't need it.
  37 $do_expand = $Is_VMS = $^O eq 'VMS';
  38
  39 @dl_require_symbols = ();       # names of symbols we need
  40 @dl_resolve_using   = ();       # names of files to link with
  41 @dl_library_path    = ();       # path to look for files
  42
  43 # This is a fix to support DLD's unfortunate desire to relink -lc
  44 @dl_resolve_using = dl_findfile('-lc') if $dlsrc eq "dl_dld.xs";
  45
  46 # Initialise @dl_library_path with the 'standard' library path
  47 # for this platform as determined by Configure
  48 push(@dl_library_path, split(' ',$Config::Config{'libpth'}));
  49
  50 # Add to @dl_library_path any extra directories we can gather from
  51 # environment variables. So far LD_LIBRARY_PATH is the only known
  52 # variable used for this purpose. Others may be added later.
  53 push(@dl_library_path, split(/:/, $ENV{LD_LIBRARY_PATH}))
  54     if $ENV{LD_LIBRARY_PATH};
  55
  56
  57 # No prizes for guessing why we don't say 'bootstrap DynaLoader;' here.
  58 boot_DynaLoader('DynaLoader') if defined(&boot_DynaLoader);
  59
  60
  61 if ($dl_debug) {
  62     print STDERR "DynaLoader.pm loaded (@INC, @dl_library_path)\n";
  63     print STDERR "DynaLoader not linked into this perl\n"
  64             unless defined(&boot_DynaLoader);
  65 }
  66
  67 1; # End of main code
  68
  69
  70 # The bootstrap function cannot be autoloaded (without complications)
  71 # so we define it here:
  72
  73 sub bootstrap {
  74     # use local vars to enable $module.bs script to edit values
  75     local(@args) = @_;
  76     local($module) = $args[0];
  77     local(@dirs, $file);
  78
  79     Carp::confess("Usage: DynaLoader::bootstrap(module)") unless $module;
  80
  81     # A common error on platforms which don't support dynamic loading.
  82     # Since it's fatal and potentially confusing we give a detailed message.
  83     Carp::croak("Can't load module $module, dynamic loading not available in this perl.\n".
  84         "  (You may need to build a new perl executable which either supports\n".
  85         "  dynamic loading or has the $module module statically linked into it.)\n")
  86         unless defined(&dl_load_file);
  87
  88     my @modparts = split(/::/,$module);
  89     my $modfname = $modparts[-1];
  90
  91     # Some systems have restrictions on files names for DLL's etc.
  92     # mod2fname returns appropriate file base name (typically truncated)
  93     # It may also edit @modparts if required.
  94     $modfname = &mod2fname(\@modparts) if defined &mod2fname;
  95
  96     my $modpname = join('/',@modparts);
  97
  98     print STDERR "DynaLoader::bootstrap for $module ",
  99                 "(auto/$modpname/$modfname.$dl_dlext)\n" if $dl_debug;
 100
 101     foreach (@INC) {
 102         chop($_ = VMS::Filespec::unixpath($_)) if $Is_VMS;
 103         my $dir = "$_/auto/$modpname";
 104         next unless -d $dir; # skip over uninteresting directories
 105
 106         # check for common cases to avoid autoload of dl_findfile
 107         last if ($file=_check_file("$dir/$modfname.$dl_dlext"));
 108
 109         # no luck here, save dir for possible later dl_findfile search
 110         push(@dirs, "-L$dir");
 111     }
 112     # last resort, let dl_findfile have a go in all known locations
 113     $file = dl_findfile(@dirs, map("-L$_",@INC), $modfname) unless $file;
 114
 115     Carp::croak("Can't find loadable object for module $module in \@INC (@INC)")
 116         unless $file;
 117
 118     my $bootname = "boot_$module";
 119     $bootname =~ s/\W/_/g;
 120     @dl_require_symbols = ($bootname);
 121
 122     # Execute optional '.bootstrap' perl script for this module.
 123     # The .bs file can be used to configure @dl_resolve_using etc to
 124     # match the needs of the individual module on this architecture.
 125     my $bs = $file;
 126     $bs =~ s/(\.\w+)?$/\.bs/; # look for .bs 'beside' the library
 127     if (-s $bs) { # only read file if it's not empty
 128         print STDERR "BS: $bs ($^O, $dlsrc)\n" if $dl_debug;
 129         eval { do $bs; };
 130         warn "$bs: $@\n" if $@;
 131     }
 132
 133     # Many dynamic extension loading problems will appear to come from
 134     # this section of code: XYZ failed at line 123 of DynaLoader.pm.
 135     # Often these errors are actually occurring in the initialisation
 136     # C code of the extension XS file. Perl reports the error as being
 137     # in this perl code simply because this was the last perl code
 138     # it executed.
 139
 140     my $libref = dl_load_file($file) or
 141         Carp::croak("Can't load '$file' for module $module: ".dl_error()."\n");
 142
 143     my @unresolved = dl_undef_symbols();
 144     Carp::carp("Undefined symbols present after loading $file: @unresolved\n")
 145         if @unresolved;
 146
 147     my $boot_symbol_ref = dl_find_symbol($libref, $bootname) or
 148          Carp::croak("Can't find '$bootname' symbol in $file\n");
 149
 150     my $xs = dl_install_xsub("${module}::bootstrap", $boot_symbol_ref, $file);
 151
 152     # See comment block above
 153     &$xs(@args);
 154 }
 155
 156
 157 sub _check_file {   # private utility to handle dl_expandspec vs -f tests
 158     my($file) = @_;
 159     return $file if (!$do_expand && -f $file); # the common case
 160     return $file if ( $do_expand && ($file=dl_expandspec($file)));
 161     return undef;
 162 }
 163
 164
 165 # Let autosplit and the autoloader deal with these functions:
 166 __END__
 167
 168
 169 sub dl_findfile {
 170     # Read ext/DynaLoader/DynaLoader.doc for detailed information.
 171     # This function does not automatically consider the architecture
 172     # or the perl library auto directories.
 173     my (@args) = @_;
 174     my (@dirs,  $dir);   # which directories to search
 175     my (@found);         # full paths to real files we have found
 176     my $dl_ext= $Config::Config{'dlext'}; # suffix for perl extensions
 177     my $dl_so = $Config::Config{'so'};  # suffix for shared libraries
 178
 179     print STDERR "dl_findfile(@args)\n" if $dl_debug;
 180
 181     # accumulate directories but process files as they appear
 182     arg: foreach(@args) {
 183         #  Special fast case: full filepath requires no search
 184         if ($Is_VMS && m%[:>/\]]% && -f $_) {
 185             push(@found,dl_expandspec(VMS::Filespec::vmsify($_)));
 186             last arg unless wantarray;
 187             next;
 188         }
 189         elsif (m:/: && -f $_ && !$do_expand) {
 190             push(@found,$_);
 191             last arg unless wantarray;
 192             next;
 193         }
 194
 195         # Deal with directories first:
 196         #  Using a -L prefix is the preferred option (faster and more robust)
 197         if (m:^-L:) { s/^-L//; push(@dirs, $_); next; }
 198
 199         #  Otherwise we try to try to spot directories by a heuristic
 200         #  (this is a more complicated issue than it first appears)
 201         if (m:/: && -d $_) {   push(@dirs, $_); next; }
 202
 203         # VMS: we may be using native VMS directry syntax instead of
 204         # Unix emulation, so check this as well
 205         if ($Is_VMS && /[:>\]]/ && -d $_) {   push(@dirs, $_); next; }
 206
 207         #  Only files should get this far...
 208         my(@names, $name);    # what filenames to look for
 209         if (m:-l: ) {          # convert -lname to appropriate library name
 210             s/-l//;
 211             push(@names,"lib$_.$dl_so");
 212             push(@names,"lib$_.a");
 213         } else {                # Umm, a bare name. Try various alternatives:
 214             # these should be ordered with the most likely first
 215             push(@names,"$_.$dl_ext")    unless m/\.$dl_ext$/o;
 216             push(@names,"$_.$dl_so")     unless m/\.$dl_so$/o;
 217             push(@names,"lib$_.$dl_so")  unless m:/:;
 218             push(@names,"$_.a")          if !m/\.a$/ and $dlsrc eq "dl_dld.xs";
 219             push(@names, $_);
 220         }
 221         foreach $dir (@dirs, @dl_library_path) {
 222             next unless -d $dir;
 223             chop($dir = VMS::Filespec::unixpath($dir)) if $Is_VMS;
 224             foreach $name (@names) {
 225                 my($file) = "$dir/$name";
 226                 print STDERR " checking in $dir for $name\n" if $dl_debug;
 227                 $file = _check_file($file);
 228                 if ($file) {
 229                     push(@found, $file);
 230                     next arg; # no need to look any further
 231                 }
 232             }
 233         }
 234     }
 235     if ($dl_debug) {
 236         foreach(@dirs) {
 237             print STDERR " dl_findfile ignored non-existent directory: $_\n" unless -d $_;
 238         }
 239         print STDERR "dl_findfile found: @found\n";
 240     }
 241     return $found[0] unless wantarray;
 242     @found;
 243 }
 244
 245
 246 sub dl_expandspec {
 247     my($spec) = @_;
 248     # Optional function invoked if DynaLoader.pm sets $do_expand.
 249     # Most systems do not require or use this function.
 250     # Some systems may implement it in the dl_*.xs file in which case
 251     # this autoload version will not be called but is harmless.
 252
 253     # This function is designed to deal with systems which treat some
 254     # 'filenames' in a special way. For example VMS 'Logical Names'
 255     # (something like unix environment variables - but different).
 256     # This function should recognise such names and expand them into
 257     # full file paths.
 258     # Must return undef if $spec is invalid or file does not exist.
 259
 260     my $file = $spec; # default output to input
 261
 262     if ($Is_VMS) { # dl_expandspec should be defined in dl_vms.xs
 263         Carp::croak("dl_expandspec: should be defined in XS file!\n");
 264     } else {
 265         return undef unless -f $file;
 266     }
 267     print STDERR "dl_expandspec($spec) => $file\n" if $dl_debug;
 268     $file;
 269 }
 270
 271
 272 =head1 NAME
 273
 274 DynaLoader - Dynamically load C libraries into Perl code
 275
 276 dl_error(), dl_findfile(), dl_expandspec(), dl_load_file(), dl_find_symbol(), dl_undef_symbols(), dl_install_xsub(), boostrap() - routines used by DynaLoader modules
 277
 278 =head1 SYNOPSIS
 279
 280     package YourPackage;
 281     require DynaLoader;
 282     @ISA = qw(... DynaLoader ...);
 283     bootstrap YourPackage;
 284
 285
 286 =head1 DESCRIPTION
 287
 288 This document defines a standard generic interface to the dynamic
 289 linking mechanisms available on many platforms.  Its primary purpose is
 290 to implement automatic dynamic loading of Perl modules.
 291
 292 This document serves as both a specification for anyone wishing to
 293 implement the DynaLoader for a new platform and as a guide for
 294 anyone wishing to use the DynaLoader directly in an application.
 295
 296 The DynaLoader is designed to be a very simple high-level
 297 interface that is sufficiently general to cover the requirements
 298 of SunOS, HP-UX, NeXT, Linux, VMS and other platforms.
 299
 300 It is also hoped that the interface will cover the needs of OS/2, NT
 301 etc and also allow pseudo-dynamic linking (using C<ld -A> at runtime).
 302
 303 It must be stressed that the DynaLoader, by itself, is practically
 304 useless for accessing non-Perl libraries because it provides almost no
 305 Perl-to-C 'glue'.  There is, for example, no mechanism for calling a C
 306 library function or supplying arguments.  It is anticipated that any
 307 glue that may be developed in the future will be implemented in a
 308 separate dynamically loaded module.
 309
 310 DynaLoader Interface Summary
 311
 312   @dl_library_path
 313   @dl_resolve_using
 314   @dl_require_symbols
 315   $dl_debug
 316                                                   Implemented in:
 317   bootstrap($modulename)                               Perl
 318   @filepaths = dl_findfile(@names)                     Perl
 319
 320   $libref  = dl_load_file($filename)                   C
 321   $symref  = dl_find_symbol($libref, $symbol)          C
 322   @symbols = dl_undef_symbols()                        C
 323   dl_install_xsub($name, $symref [, $filename])        C
 324   $message = dl_error                                  C
 325
 326 =over 4
 327
 328 =item @dl_library_path
 329
 330 The standard/default list of directories in which dl_findfile() will
 331 search for libraries etc.  Directories are searched in order:
 332 $dl_library_path[0], [1], ... etc
 333
 334 @dl_library_path is initialised to hold the list of 'normal' directories
 335 (F</usr/lib>, etc) determined by B<Configure> (C<$Config{'libpth'}>).  This should
 336 ensure portability across a wide range of platforms.
 337
 338 @dl_library_path should also be initialised with any other directories
 339 that can be determined from the environment at runtime (such as
 340 LD_LIBRARY_PATH for SunOS).
 341
 342 After initialisation @dl_library_path can be manipulated by an
 343 application using push and unshift before calling dl_findfile().
 344 Unshift can be used to add directories to the front of the search order
 345 either to save search time or to override libraries with the same name
 346 in the 'normal' directories.
 347
 348 The load function that dl_load_file() calls may require an absolute
 349 pathname.  The dl_findfile() function and @dl_library_path can be
 350 used to search for and return the absolute pathname for the
 351 library/object that you wish to load.
 352
 353 =item @dl_resolve_using
 354
 355 A list of additional libraries or other shared objects which can be
 356 used to resolve any undefined symbols that might be generated by a
 357 later call to load_file().
 358
 359 This is only required on some platforms which do not handle dependent
 360 libraries automatically.  For example the Socket Perl extension library
 361 (F<auto/Socket/Socket.so>) contains references to many socket functions
 362 which need to be resolved when it's loaded.  Most platforms will
 363 automatically know where to find the 'dependent' library (e.g.,
 364 F</usr/lib/libsocket.so>).  A few platforms need to to be told the location
 365 of the dependent library explicitly.  Use @dl_resolve_using for this.
 366
 367 Example usage:
 368
 369     @dl_resolve_using = dl_findfile('-lsocket');
 370
 371 =item @dl_require_symbols
 372
 373 A list of one or more symbol names that are in the library/object file
 374 to be dynamically loaded.  This is only required on some platforms.
 375
 376 =item dl_error()
 377
 378 Syntax:
 379
 380     $message = dl_error();
 381
 382 Error message text from the last failed DynaLoader function.  Note
 383 that, similar to errno in unix, a successful function call does not
 384 reset this message.
 385
 386 Implementations should detect the error as soon as it occurs in any of
 387 the other functions and save the corresponding message for later
 388 retrieval.  This will avoid problems on some platforms (such as SunOS)
 389 where the error message is very temporary (e.g., dlerror()).
 390
 391 =item $dl_debug
 392
 393 Internal debugging messages are enabled when $dl_debug is set true.
 394 Currently setting $dl_debug only affects the Perl side of the
 395 DynaLoader.  These messages should help an application developer to
 396 resolve any DynaLoader usage problems.
 397
 398 $dl_debug is set to C<$ENV{'PERL_DL_DEBUG'}> if defined.
 399
 400 For the DynaLoader developer/porter there is a similar debugging
 401 variable added to the C code (see dlutils.c) and enabled if Perl was
 402 built with the B<-DDEBUGGING> flag.  This can also be set via the
 403 PERL_DL_DEBUG environment variable.  Set to 1 for minimal information or
 404 higher for more.
 405
 406 =item dl_findfile()
 407
 408 Syntax:
 409
 410     @filepaths = dl_findfile(@names)
 411
 412 Determine the full paths (including file suffix) of one or more
 413 loadable files given their generic names and optionally one or more
 414 directories.  Searches directories in @dl_library_path by default and
 415 returns an empty list if no files were found.
 416
 417 Names can be specified in a variety of platform independent forms.  Any
 418 names in the form B<-lname> are converted into F<libname.*>, where F<.*> is
 419 an appropriate suffix for the platform.
 420
 421 If a name does not already have a suitable prefix and/or suffix then
 422 the corresponding file will be searched for by trying combinations of
 423 prefix and suffix appropriate to the platform: "$name.o", "lib$name.*"
 424 and "$name".
 425
 426 If any directories are included in @names they are searched before
 427 @dl_library_path.  Directories may be specified as B<-Ldir>.  Any other
 428 names are treated as filenames to be searched for.
 429
 430 Using arguments of the form C<-Ldir> and C<-lname> is recommended.
 431
 432 Example:
 433
 434     @dl_resolve_using = dl_findfile(qw(-L/usr/5lib -lposix));
 435
 436
 437 =item dl_expandspec()
 438
 439 Syntax:
 440
 441     $filepath = dl_expandspec($spec)
 442
 443 Some unusual systems, such as VMS, require special filename handling in
 444 order to deal with symbolic names for files (i.e., VMS's Logical Names).
 445
 446 To support these systems a dl_expandspec() function can be implemented
 447 either in the F<dl_*.xs> file or code can be added to the autoloadable
 448 dl_expandspec() function in F<DynaLoader.pm>.  See F<DynaLoader.pm> for
 449 more information.
 450
 451 =item dl_load_file()
 452
 453 Syntax:
 454
 455     $libref = dl_load_file($filename)
 456
 457 Dynamically load $filename, which must be the path to a shared object
 458 or library.  An opaque 'library reference' is returned as a handle for
 459 the loaded object.  Returns undef on error.
 460
 461 (On systems that provide a handle for the loaded object such as SunOS
 462 and HPUX, $libref will be that handle.  On other systems $libref will
 463 typically be $filename or a pointer to a buffer containing $filename.
 464 The application should not examine or alter $libref in any way.)
 465
 466 This is function that does the real work.  It should use the current
 467 values of @dl_require_symbols and @dl_resolve_using if required.
 468
 469     SunOS: dlopen($filename)
 470     HP-UX: shl_load($filename)
 471     Linux: dld_create_reference(@dl_require_symbols); dld_link($filename)
 472     NeXT:  rld_load($filename, @dl_resolve_using)
 473     VMS:   lib$find_image_symbol($filename,$dl_require_symbols[0])
 474
 475
 476 =item dl_find_symbol()
 477
 478 Syntax:
 479
 480     $symref = dl_find_symbol($libref, $symbol)
 481
 482 Return the address of the symbol $symbol or C<undef> if not found.  If the
 483 target system has separate functions to search for symbols of different
 484 types then dl_find_symbol() should search for function symbols first and
 485 then other types.
 486
 487 The exact manner in which the address is returned in $symref is not
 488 currently defined.  The only initial requirement is that $symref can
 489 be passed to, and understood by, dl_install_xsub().
 490
 491     SunOS: dlsym($libref, $symbol)
 492     HP-UX: shl_findsym($libref, $symbol)
 493     Linux: dld_get_func($symbol) and/or dld_get_symbol($symbol)
 494     NeXT:  rld_lookup("_$symbol")
 495     VMS:   lib$find_image_symbol($libref,$symbol)
 496
 497
 498 =item dl_undef_symbols()
 499
 500 Example
 501
 502     @symbols = dl_undef_symbols()
 503
 504 Return a list of symbol names which remain undefined after load_file().
 505 Returns C<()> if not known.  Don't worry if your platform does not provide
 506 a mechanism for this.  Most do not need it and hence do not provide it,
 507 they just return an empty list.
 508
 509
 510 =item dl_install_xsub()
 511
 512 Syntax:
 513
 514     dl_install_xsub($perl_name, $symref [, $filename])
 515
 516 Create a new Perl external subroutine named $perl_name using $symref as
 517 a pointer to the function which implements the routine.  This is simply
 518 a direct call to newXSUB().  Returns a reference to the installed
 519 function.
 520
 521 The $filename parameter is used by Perl to identify the source file for
 522 the function if required by die(), caller() or the debugger.  If
 523 $filename is not defined then "DynaLoader" will be used.
 524
 525
 526 =item boostrap()
 527
 528 Syntax:
 529
 530 bootstrap($module)
 531
 532 This is the normal entry point for automatic dynamic loading in Perl.
 533
 534 It performs the following actions:
 535
 536 =over 8
 537
 538 =item *
 539
 540 locates an auto/$module directory by searching @INC
 541
 542 =item *
 543
 544 uses dl_findfile() to determine the filename to load
 545
 546 =item *
 547
 548 sets @dl_require_symbols to C<("boot_$module")>
 549
 550 =item *
 551
 552 executes an F<auto/$module/$module.bs> file if it exists
 553 (typically used to add to @dl_resolve_using any files which
 554 are required to load the module on the current platform)
 555
 556 =item *
 557
 558 calls dl_load_file() to load the file
 559
 560 =item *
 561
 562 calls dl_undef_symbols() and warns if any symbols are undefined
 563
 564 =item *
 565
 566 calls dl_find_symbol() for "boot_$module"
 567
 568 =item *
 569
 570 calls dl_install_xsub() to install it as "${module}::bootstrap"
 571
 572 =item *
 573
 574 calls &{"${module}::bootstrap"} to bootstrap the module (actually
 575 it uses the function reference returned by dl_install_xsub for speed)
 576
 577 =back
 578
 579 =back
 580
 581
 582 =head1 AUTHOR
 583
 584 Tim Bunce, 11 August 1994.
 585
 586 This interface is based on the work and comments of (in no particular
 587 order): Larry Wall, Robert Sanders, Dean Roehrich, Jeff Okamoto, Anno
 588 Siegel, Thomas Neumann, Paul Marquess, Charles Bailey, myself and others.
 589
 590 Larry Wall designed the elegant inherited bootstrap mechanism and
 591 implemented the first Perl 5 dynamic loader using it.
 592
 593 =cut