ext/DynaLoader/DynaLoader.pm

   1 package DynaLoader;
   2
   3 #
   4 #   And Gandalf said: 'Many folk like to know beforehand what is to
   5 #   be set on the table; but those who have laboured to prepare the
   6 #   feast like to keep their secret; for wonder makes the words of
   7 #   praise louder.'
   8 #
   9
  10 # Quote from Tolkien sugested by Anno Siegel.
  11 #
  12 # Read ext/DynaLoader/README and DynaLoader.doc for
  13 # detailed information.
  14 #
  15 # Tim.Bunce@ig.co.uk, August 1994
  16
  17 use Config;
  18 use Carp;
  19 use AutoLoader;
  20
  21 @ISA=(AutoLoader);
  22
  23
  24 # enable messages from DynaLoader perl code
  25 $dl_debug = 0 unless $dl_debug;
  26 $dl_debug = $ENV{'PERL_DL_DEBUG'} if $ENV{'PERL_DL_DEBUG'};
  27
  28 $dl_so = $dl_dlext = ""; # avoid typo warnings
  29 $dl_so = $Config{'so'}; # suffix for shared libraries
  30 $dl_dlext = $Config{'dlext'}; # suffix for dynamic modules
  31
  32 # Some systems need special handling to expand file specifications
  33 # (VMS support by Charles Bailey <bailey@HMIVAX.HUMGEN.UPENN.EDU>)
  34 # See dl_expandspec() for more details. Should be harmless but
  35 # inefficient to define on systems that don't need it.
  36 $do_expand = ($Config{'osname'} eq 'VMS');
  37
  38 @dl_require_symbols = ();       # names of symbols we need
  39 @dl_resolve_using   = ();       # names of files to link with
  40 @dl_library_path    = ();       # path to look for files
  41
  42 # This is a fix to support DLD's unfortunate desire to relink -lc
  43 @dl_resolve_using = dl_findfile('-lc') if $Config{'dlsrc'} eq "dl_dld.xs";
  44
  45 # Initialise @dl_library_path with the 'standard' library path
  46 # for this platform as determined by Configure
  47 push(@dl_library_path, split(' ',$Config{'libpth'}));
  48
  49 # Add to @dl_library_path any extra directories we can gather from
  50 # environment variables. So far LD_LIBRARY_PATH is the only known
  51 # variable used for this purpose. Others may be added later.
  52 push(@dl_library_path, split(/:/, $ENV{'LD_LIBRARY_PATH'}))
  53     if $ENV{'LD_LIBRARY_PATH'};
  54
  55
  56 # No prizes for guessing why we don't say 'bootstrap DynaLoader;' here.
  57 &boot_DynaLoader if defined &boot_DynaLoader;
  58
  59 print STDERR "DynaLoader.pm loaded (@dl_library_path)\n"
  60     if ($dl_debug >= 2);
  61
  62 # Temporary interface checks for recent changes (Aug 1994)
  63 if (defined(&dl_load_file)){
  64 die "dl_error not defined" unless defined (&dl_error);
  65 die "dl_undef_symbols not defined" unless defined (&dl_undef_symbols);
  66 }
  67
  68 1; # End of main code
  69
  70
  71 # The bootstrap function cannot be autoloaded (without complications)
  72 # so we define it here:
  73
  74 sub bootstrap {
  75     # use local vars to enable $module.bs script to edit values
  76     local(@args) = @_;
  77     local($module) = $args[0];
  78     local(@dirs, $file);
  79
  80     croak "Usage: DynaLoader::bootstrap(module)"
  81         unless ($module);
  82
  83     croak "Can't load module $module, DynaLoader not linked into this perl"
  84         unless defined(&dl_load_file);
  85
  86     print STDERR "DynaLoader::bootstrap($module)\n" if $dl_debug;
  87
  88     my(@modparts) = split(/::/,$module);
  89     my($modfname) = $modparts[-1];
  90     my($modpname) = join('/',@modparts);
  91     foreach (@INC) {
  92         my $dir = "$_/auto/$modpname";
  93         next unless -d $dir; # skip over uninteresting directories
  94
  95         # check for common cases to avoid autoload of dl_findfile
  96         last if ($file=_check_file("$dir/$modfname.$dl_dlext"));
  97
  98         # no luck here, save dir for possible later dl_findfile search
  99         push(@dirs, "-L$dir");
 100     }
 101     # last resort, let dl_findfile have a go in all known locations
 102     $file = dl_findfile(@dirs, map("-L$_",@INC), $modfname) unless $file;
 103
 104     croak "Can't find loadable object for module $module in \@INC"
 105         unless $file;
 106
 107     my($bootname) = "boot_$module";
 108     $bootname =~ s/\W/_/g;
 109     @dl_require_symbols = ($bootname);
 110
 111     # Execute optional '.bootstrap' perl script for this module.
 112     # The .bs file can be used to configure @dl_resolve_using etc to
 113     # match the needs of the individual module on this architecture.
 114     my $bs = $file;
 115     $bs =~ s/\.$dl_dlext$/\.bs/o; # look for .bs 'beside' the library
 116     if (-f $bs) {
 117         local($osname, $dlsrc) = @Config{'osname','dlsrc'};
 118         print STDERR "$bs ($osname, $dlsrc)\n" if $dl_debug;
 119         $@ = "";
 120         do $bs;
 121         warn "$bs: $@\n" if $@;
 122     }
 123
 124     my $libref = DynaLoader::dl_load_file($file) or
 125         croak "Can't load '$file' for module $module: ".&dl_error."\n";
 126
 127     my(@unresolved) = dl_undef_symbols();
 128     carp "Undefined symbols present after loading $file: @unresolved\n"
 129         if (@unresolved);
 130
 131     my $boot_symbol_ref = dl_find_symbol($libref, $bootname) or
 132          croak "Can't find '$bootname' symbol in $file\n";
 133
 134     dl_install_xsub("${module}::bootstrap", $boot_symbol_ref, $file);
 135     &{"${module}::bootstrap"}(@args);
 136 }
 137
 138
 139 sub _check_file{   # private utility to handle dl_expandspec vs -f tests
 140     my($file) = @_;
 141     return $file if (!$do_expand && -f $file); # the common case
 142     return $file if ( $do_expand && ($file=dl_expandspec($file)));
 143     return undef;
 144 }
 145
 146
 147 # Let autosplit and the autoloader deal with these functions:
 148 __END__
 149
 150
 151 sub dl_findfile {
 152     # Read ext/DynaLoader/DynaLoader.doc for detailed information.
 153     # This function does not automatically consider the architecture
 154     # or the perl library auto directories.
 155     my (@args) = @_;
 156     my (@dirs,  $dir);   # which directories to search
 157     my (@found);         # full paths to real files we have found
 158     my ($vms) = ($Config{'osname'} eq 'VMS');
 159
 160     print STDERR "dl_findfile(@args)\n" if $dl_debug;
 161
 162     # accumulate directories but process files as they appear
 163     arg: foreach(@args) {
 164         #  Special fast case: full filepath requires no search
 165         if (m:/: && -f $_ && !$do_expand){
 166             push(@found,$_);
 167             last arg unless wantarray;
 168             next;
 169         }
 170
 171         # Deal with directories first:
 172         #  Using a -L prefix is the preferred option (faster and more robust)
 173         if (m:^-L:){ s/^-L//; push(@dirs, $_); next; }
 174         #  Otherwise we try to try to spot directories by a heuristic
 175         #  (this is a more complicated issue than it first appears)
 176         if (m:/: && -d $_){   push(@dirs, $_); next; }
 177         # VMS: we may be using native VMS directry syntax instead of
 178         # Unix emulation, so check this as well
 179         if ($vms && /[:>\]]/ && -d $_){   push(@dirs, $_); next; }
 180
 181         #  Only files should get this far...
 182         my(@names, $name);    # what filenames to look for
 183         if (m:-l: ){          # convert -lname to appropriate library name
 184             s/-l//;
 185             push(@names,"lib$_.$dl_so");
 186             push(@names,"lib$_.a");
 187         }else{                # Umm, a bare name. Try various alternatives:
 188             # these should be ordered with the most likely first
 189             push(@names,"$_.$dl_so")     unless m/\.$dl_so$/o;
 190             push(@names,"lib$_.$dl_so")  unless m:/:;
 191             push(@names,"$_.o")          unless m/\.(o|$dl_so)$/o;
 192             push(@names,"$_.a")          unless m/\.a$/;
 193             push(@names, $_);
 194         }
 195         foreach $dir (@dirs, @dl_library_path) {
 196             next unless -d $dir;
 197             foreach $name (@names) {
 198                 my($file) = "$dir/$name";
 199                 print STDERR " checking in $dir for $name\n" if $dl_debug;
 200                 $file = _check_file($file);
 201                 if ($file){
 202                     push(@found, $file);
 203                     next arg; # no need to look any further
 204                 }
 205             }
 206         }
 207     }
 208     if ($dl_debug) {
 209         foreach(@dirs) {
 210             print STDERR " dl_findfile ignored non-existent directory: $_\n" unless -d $_;
 211         }
 212         print STDERR "dl_findfile found: @found\n";
 213     }
 214     return $found[0] unless wantarray;
 215     @found;
 216 }
 217
 218
 219 sub dl_expandspec{
 220     my($spec) = @_;
 221     # Optional function invoked if DynaLoader.pm sets $do_expand.
 222     # Most systems do not require or use this function.
 223     # Some systems may implement it in the dl_*.xs file in which case
 224     # this autoload version will not be called but is harmless.
 225
 226     # This function is designed to deal with systems which treat some
 227     # 'filenames' in a special way. For example VMS 'Logical Names'
 228     # (something like unix environment variables - but different).
 229     # This function should recognise such names and expand them into
 230     # full file paths.
 231     # Must return undef if $spec is invalid or file does not exist.
 232
 233     my($file)   = $spec; # default output to input
 234     my($osname) = $Config{'osname'};
 235
 236     if ($osname eq 'VMS'){ # dl_expandspec should be defined in dl_vms.xs
 237         croak "dl_expandspec: should be defined in XS file!\n";
 238     }else{
 239         return undef unless -f $file;
 240     }
 241     print STDERR "dl_expandspec($spec) => $file\n" if $dl_debug;
 242     $file;
 243 }