ext/Devel-PPPort/Makefile.PL

   1 ################################################################################
   2 #
   3 #  Makefile.PL -- generate Makefile
   4 #
   5 ################################################################################
   6 #
   7 #  $Revision: 29 $
   8 #  $Author: mhx $
   9 #  $Date: 2009/01/18 14:10:49 +0100 $
  10 #
  11 ################################################################################
  12 #
  13 #  Version 3.x, Copyright (C) 2004-2009, Marcus Holland-Moritz.
  14 #  Version 2.x, Copyright (C) 2001, Paul Marquess.
  15 #  Version 1.x, Copyright (C) 1999, Kenneth Albanowski.
  16 #
  17 #  This program is free software; you can redistribute it and/or
  18 #  modify it under the same terms as Perl itself.
  19 #
  20 ################################################################################
  21
  22 require 5.003;
  23
  24 use strict;
  25 use ExtUtils::MakeMaker;
  26
  27 use vars '%opt';  # needs to be global, and we can't use 'our'
  28
  29 unless ($ENV{'PERL_CORE'}) {
  30   $ENV{'PERL_CORE'} = 1 if grep { $_ eq 'PERL_CORE=1' } @ARGV;
  31 }
  32
  33 @ARGV = map { /^--with-(apicheck)$/ && ++$opt{$1} ? () : $_ } @ARGV;
  34
  35 WriteMakefile(
  36   NAME          => 'Devel::PPPort',
  37   VERSION_FROM  => 'PPPort_pm.PL',
  38   PM            => { 'PPPort.pm' => '$(INST_LIBDIR)/PPPort.pm' },
  39   H             => [ qw(ppport.h) ],
  40   OBJECT        => 'RealPPPort$(OBJ_EXT) $(O_FILES)',
  41   XSPROTOARG    => '-noprototypes',
  42   CONFIGURE     => \&configure,
  43 );
  44
  45 sub configure
  46 {
  47   my @clean    = qw{ $(H_FILES) RealPPPort.xs RealPPPort.c };
  48   my %depend   = ('$(OBJECT)' => '$(H_FILES)');
  49   my @C_FILES  = qw{ module2.c module3.c },
  50   my %PL_FILES = (
  51     'ppport_h.PL'  => 'ppport.h',
  52     'PPPort_pm.PL' => 'PPPort.pm',
  53     'PPPort_xs.PL' => 'RealPPPort.xs',
  54   );
  55   my @moreopts;
  56
  57   if (eval $ExtUtils::MakeMaker::VERSION >= 6) {
  58     push @moreopts, AUTHOR => 'Marcus Holland-Moritz <mhx@cpan.org>';
  59     if (-f 'PPPort.pm') {
  60       push @moreopts, ABSTRACT_FROM => 'PPPort.pm';
  61     }
  62   }
  63
  64   if (eval $ExtUtils::MakeMaker::VERSION >= 6.30_01) {
  65     print "Setting license tag...\n";
  66     push @moreopts, LICENSE => 'perl';
  67   }
  68
  69   if ($ENV{'PERL_CORE'}) {
  70     # Pods will be built by installman.
  71     push @moreopts, MAN3PODS => {};
  72     push @clean, 'PPPort.pm';
  73   }
  74   else {
  75     # Devel::PPPort is in the core since 5.7.3
  76     push @moreopts, INSTALLDIRS => ($] >= 5.007003 ? 'perl' : 'site');
  77   }
  78
  79   if ($opt{'apicheck'}) {
  80     $PL_FILES{'apicheck_c.PL'} = 'apicheck.c';
  81     push @C_FILES, qw{ apicheck.c };
  82     push @clean,   qw{ apicheck.c apicheck.i };
  83     $depend{'apicheck.i'} = 'ppport.h';
  84   }
  85
  86   return {
  87     C        => \@C_FILES,
  88     XS       => { 'RealPPPort.xs' => 'RealPPPort.c' },
  89     PL_FILES => \%PL_FILES,
  90     depend   => \%depend,
  91     clean    => { FILES => "@clean" },
  92     @moreopts,
  93   };
  94 }
  95
  96 sub MY::postamble
  97 {
  98   package MY;
  99   my $post = shift->SUPER::postamble(@_);
 100   $post .= <<'POSTAMBLE';
 101
 102 purge_all: realclean
 103         @$(RM_F) PPPort.pm t/*.t
 104
 105 regen_pm:
 106         $(PERL) -I$(INST_ARCHLIB) -I$(INST_LIB) -I$(PERL_ARCHLIB) -I$(PERL_LIB) PPPort_pm.PL
 107
 108 regen_xs:
 109         $(PERL) -I$(INST_ARCHLIB) -I$(INST_LIB) -I$(PERL_ARCHLIB) -I$(PERL_LIB) PPPort_xs.PL
 110
 111 regen_tests:
 112         $(PERL) -I$(INST_ARCHLIB) -I$(INST_LIB) -I$(PERL_ARCHLIB) -I$(PERL_LIB) mktests.PL
 113
 114 regen_h:
 115         $(PERL) -I$(INST_ARCHLIB) -I$(INST_LIB) -I$(PERL_ARCHLIB) -I$(PERL_LIB) ppport_h.PL
 116
 117 regen: regen_pm regen_xs regen_tests regen_h
 118
 119 POSTAMBLE
 120   return $post;
 121 }
 122
 123 sub MY::c_o
 124 {
 125   package MY;
 126   my $co = shift->SUPER::c_o(@_);
 127
 128   if ($::opt{'apicheck'} && $co !~ /^\.c\.i:/m) {
 129     print "Adding custom rule for preprocessed apicheck file...\n";
 130
 131     $co .= <<'CO'
 132
 133 .SUFFIXES: .i
 134
 135 .c.i:
 136         $(CCCMD) -E -I$(PERL_INC) $(DEFINE) $*.c > $*.i
 137 CO
 138   }
 139
 140   return $co;
 141 }
 142