ext/Data/Dumper/Dumper.pm

   1 #
   2 # Data/Dumper.pm
   3 #
   4 # convert perl data structures into perl syntax suitable for both printing
   5 # and eval
   6 #
   7 # Documentation at the __END__
   8 #
   9
  10 package Data::Dumper;
  11
  12 $VERSION = '2.102';
  13
  14 #$| = 1;
  15
  16 require 5.005_64;
  17 require Exporter;
  18 use XSLoader ();
  19 require overload;
  20
  21 use Carp;
  22
  23 @ISA = qw(Exporter);
  24 @EXPORT = qw(Dumper);
  25 @EXPORT_OK = qw(DumperX);
  26
  27 XSLoader::load 'Data::Dumper';
  28
  29 # module vars and their defaults
  30 $Indent = 2 unless defined $Indent;
  31 $Purity = 0 unless defined $Purity;
  32 $Pad = "" unless defined $Pad;
  33 $Varname = "VAR" unless defined $Varname;
  34 $Useqq = 0 unless defined $Useqq;
  35 $Terse = 0 unless defined $Terse;
  36 $Freezer = "" unless defined $Freezer;
  37 $Toaster = "" unless defined $Toaster;
  38 $Deepcopy = 0 unless defined $Deepcopy;
  39 $Quotekeys = 1 unless defined $Quotekeys;
  40 $Bless = "bless" unless defined $Bless;
  41 #$Expdepth = 0 unless defined $Expdepth;
  42 $Maxdepth = 0 unless defined $Maxdepth;
  43
  44 #
  45 # expects an arrayref of values to be dumped.
  46 # can optionally pass an arrayref of names for the values.
  47 # names must have leading $ sign stripped. begin the name with *
  48 # to cause output of arrays and hashes rather than refs.
  49 #
  50 sub new {
  51   my($c, $v, $n) = @_;
  52
  53   croak "Usage:  PACKAGE->new(ARRAYREF, [ARRAYREF])"
  54     unless (defined($v) && (ref($v) eq 'ARRAY'));
  55   $n = [] unless (defined($n) && (ref($v) eq 'ARRAY'));
  56
  57   my($s) = {
  58              level      => 0,           # current recursive depth
  59              indent     => $Indent,     # various styles of indenting
  60              pad        => $Pad,        # all lines prefixed by this string
  61              xpad       => "",          # padding-per-level
  62              apad       => "",          # added padding for hash keys n such
  63              sep        => "",          # list separator
  64              seen       => {},          # local (nested) refs (id => [name, val])
  65              todump     => $v,          # values to dump []
  66              names      => $n,          # optional names for values []
  67              varname    => $Varname,    # prefix to use for tagging nameless ones
  68              purity     => $Purity,     # degree to which output is evalable
  69              useqq      => $Useqq,      # use "" for strings (backslashitis ensues)
  70              terse      => $Terse,      # avoid name output (where feasible)
  71              freezer    => $Freezer,    # name of Freezer method for objects
  72              toaster    => $Toaster,    # name of method to revive objects
  73              deepcopy   => $Deepcopy,   # dont cross-ref, except to stop recursion
  74              quotekeys  => $Quotekeys,  # quote hash keys
  75              'bless'    => $Bless,      # keyword to use for "bless"
  76 #            expdepth   => $Expdepth,   # cutoff depth for explicit dumping
  77              maxdepth   => $Maxdepth,   # depth beyond which we give up
  78            };
  79
  80   if ($Indent > 0) {
  81     $s->{xpad} = "  ";
  82     $s->{sep} = "\n";
  83   }
  84   return bless($s, $c);
  85 }
  86
  87 #
  88 # add-to or query the table of already seen references
  89 #
  90 sub Seen {
  91   my($s, $g) = @_;
  92   if (defined($g) && (ref($g) eq 'HASH'))  {
  93     my($k, $v, $id);
  94     while (($k, $v) = each %$g) {
  95       if (defined $v and ref $v) {
  96         ($id) = (overload::StrVal($v) =~ /\((.*)\)$/);
  97         if ($k =~ /^[*](.*)$/) {
  98           $k = (ref $v eq 'ARRAY') ? ( "\\\@" . $1 ) :
  99                (ref $v eq 'HASH')  ? ( "\\\%" . $1 ) :
 100                (ref $v eq 'CODE')  ? ( "\\\&" . $1 ) :
 101                                      (   "\$" . $1 ) ;
 102         }
 103         elsif ($k !~ /^\$/) {
 104           $k = "\$" . $k;
 105         }
 106         $s->{seen}{$id} = [$k, $v];
 107       }
 108       else {
 109         carp "Only refs supported, ignoring non-ref item \$$k";
 110       }
 111     }
 112     return $s;
 113   }
 114   else {
 115     return map { @$_ } values %{$s->{seen}};
 116   }
 117 }
 118
 119 #
 120 # set or query the values to be dumped
 121 #
 122 sub Values {
 123   my($s, $v) = @_;
 124   if (defined($v) && (ref($v) eq 'ARRAY'))  {
 125     $s->{todump} = [@$v];        # make a copy
 126     return $s;
 127   }
 128   else {
 129     return @{$s->{todump}};
 130   }
 131 }
 132
 133 #
 134 # set or query the names of the values to be dumped
 135 #
 136 sub Names {
 137   my($s, $n) = @_;
 138   if (defined($n) && (ref($n) eq 'ARRAY'))  {
 139     $s->{names} = [@$n];         # make a copy
 140     return $s;
 141   }
 142   else {
 143     return @{$s->{names}};
 144   }
 145 }
 146
 147 sub DESTROY {}
 148
 149 sub Dump {
 150     return &Dumpxs
 151         unless $Data::Dumper::Useqq || (ref($_[0]) && $_[0]->{useqq});
 152     return &Dumpperl;
 153 }
 154
 155 #
 156 # dump the refs in the current dumper object.
 157 # expects same args as new() if called via package name.
 158 #
 159 sub Dumpperl {
 160   my($s) = shift;
 161   my(@out, $val, $name);
 162   my($i) = 0;
 163   local(@post);
 164
 165   $s = $s->new(@_) unless ref $s;
 166
 167   for $val (@{$s->{todump}}) {
 168     my $out = "";
 169     @post = ();
 170     $name = $s->{names}[$i++];
 171     if (defined $name) {
 172       if ($name =~ /^[*](.*)$/) {
 173         if (defined $val) {
 174           $name = (ref $val eq 'ARRAY') ? ( "\@" . $1 ) :
 175                   (ref $val eq 'HASH')  ? ( "\%" . $1 ) :
 176                   (ref $val eq 'CODE')  ? ( "\*" . $1 ) :
 177                                           ( "\$" . $1 ) ;
 178         }
 179         else {
 180           $name = "\$" . $1;
 181         }
 182       }
 183       elsif ($name !~ /^\$/) {
 184         $name = "\$" . $name;
 185       }
 186     }
 187     else {
 188       $name = "\$" . $s->{varname} . $i;
 189     }
 190
 191     my $valstr;
 192     {
 193       local($s->{apad}) = $s->{apad};
 194       $s->{apad} .= ' ' x (length($name) + 3) if $s->{indent} >= 2;
 195       $valstr = $s->_dump($val, $name);
 196     }
 197
 198     $valstr = "$name = " . $valstr . ';' if @post or !$s->{terse};
 199     $out .= $s->{pad} . $valstr . $s->{sep};
 200     $out .= $s->{pad} . join(';' . $s->{sep} . $s->{pad}, @post)
 201       . ';' . $s->{sep} if @post;
 202
 203     push @out, $out;
 204   }
 205   return wantarray ? @out : join('', @out);
 206 }
 207
 208 #
 209 # twist, toil and turn;
 210 # and recurse, of course.
 211 #
 212 sub _dump {
 213   my($s, $val, $name) = @_;
 214   my($sname);
 215   my($out, $realpack, $realtype, $type, $ipad, $id, $blesspad);
 216
 217   $type = ref $val;
 218   $out = "";
 219
 220   if ($type) {
 221
 222     # prep it, if it looks like an object
 223     if (my $freezer = $s->{freezer}) {
 224       $val->$freezer() if UNIVERSAL::can($val, $freezer);
 225     }
 226
 227     ($realpack, $realtype, $id) =
 228       (overload::StrVal($val) =~ /^(?:(.*)\=)?([^=]*)\(([^\(]*)\)$/);
 229
 230     # if it has a name, we need to either look it up, or keep a tab
 231     # on it so we know when we hit it later
 232     if (defined($name) and length($name)) {
 233       # keep a tab on it so that we dont fall into recursive pit
 234       if (exists $s->{seen}{$id}) {
 235 #       if ($s->{expdepth} < $s->{level}) {
 236           if ($s->{purity} and $s->{level} > 0) {
 237             $out = ($realtype eq 'HASH')  ? '{}' :
 238               ($realtype eq 'ARRAY') ? '[]' :
 239                 'do{my $o}' ;
 240             push @post, $name . " = " . $s->{seen}{$id}[0];
 241           }
 242           else {
 243             $out = $s->{seen}{$id}[0];
 244             if ($name =~ /^([\@\%])/) {
 245               my $start = $1;
 246               if ($out =~ /^\\$start/) {
 247                 $out = substr($out, 1);
 248               }
 249               else {
 250                 $out = $start . '{' . $out . '}';
 251               }
 252             }
 253           }
 254           return $out;
 255 #        }
 256       }
 257       else {
 258         # store our name
 259         $s->{seen}{$id} = [ (($name =~ /^[@%]/)     ? ('\\' . $name ) :
 260                              ($realtype eq 'CODE' and
 261                               $name =~ /^[*](.*)$/) ? ('\\&' . $1 )   :
 262                              $name          ),
 263                             $val ];
 264       }
 265     }
 266
 267     if ($realpack and $realpack eq 'Regexp') {
 268         $out = "$val";
 269         $out =~ s,/,\\/,g;
 270         return "qr/$out/";
 271     }
 272
 273     # If purity is not set and maxdepth is set, then check depth:
 274     # if we have reached maximum depth, return the string
 275     # representation of the thing we are currently examining
 276     # at this depth (i.e., 'Foo=ARRAY(0xdeadbeef)').
 277     if (!$s->{purity}
 278         and $s->{maxdepth} > 0
 279         and $s->{level} >= $s->{maxdepth})
 280     {
 281       return qq['$val'];
 282     }
 283
 284     # we have a blessed ref
 285     if ($realpack) {
 286       $out = $s->{'bless'} . '( ';
 287       $blesspad = $s->{apad};
 288       $s->{apad} .= '       ' if ($s->{indent} >= 2);
 289     }
 290
 291     $s->{level}++;
 292     $ipad = $s->{xpad} x $s->{level};
 293
 294     if ($realtype eq 'SCALAR' || $realtype eq 'REF') {
 295       if ($realpack) {
 296         $out .= 'do{\\(my $o = ' . $s->_dump($$val, "\${$name}") . ')}';
 297       }
 298       else {
 299         $out .= '\\' . $s->_dump($$val, "\${$name}");
 300       }
 301     }
 302     elsif ($realtype eq 'GLOB') {
 303         $out .= '\\' . $s->_dump($$val, "*{$name}");
 304     }
 305     elsif ($realtype eq 'ARRAY') {
 306       my($v, $pad, $mname);
 307       my($i) = 0;
 308       $out .= ($name =~ /^\@/) ? '(' : '[';
 309       $pad = $s->{sep} . $s->{pad} . $s->{apad};
 310       ($name =~ /^\@(.*)$/) ? ($mname = "\$" . $1) :
 311         # omit -> if $foo->[0]->{bar}, but not ${$foo->[0]}->{bar}
 312         ($name =~ /^\\?[\%\@\*\$][^{].*[]}]$/) ? ($mname = $name) :
 313           ($mname = $name . '->');
 314       $mname .= '->' if $mname =~ /^\*.+\{[A-Z]+\}$/;
 315       for $v (@$val) {
 316         $sname = $mname . '[' . $i . ']';
 317         $out .= $pad . $ipad . '#' . $i if $s->{indent} >= 3;
 318         $out .= $pad . $ipad . $s->_dump($v, $sname);
 319         $out .= "," if $i++ < $#$val;
 320       }
 321       $out .= $pad . ($s->{xpad} x ($s->{level} - 1)) if $i;
 322       $out .= ($name =~ /^\@/) ? ')' : ']';
 323     }
 324     elsif ($realtype eq 'HASH') {
 325       my($k, $v, $pad, $lpad, $mname);
 326       $out .= ($name =~ /^\%/) ? '(' : '{';
 327       $pad = $s->{sep} . $s->{pad} . $s->{apad};
 328       $lpad = $s->{apad};
 329       ($name =~ /^\%(.*)$/) ? ($mname = "\$" . $1) :
 330         # omit -> if $foo->[0]->{bar}, but not ${$foo->[0]}->{bar}
 331         ($name =~ /^\\?[\%\@\*\$][^{].*[]}]$/) ? ($mname = $name) :
 332           ($mname = $name . '->');
 333       $mname .= '->' if $mname =~ /^\*.+\{[A-Z]+\}$/;
 334       while (($k, $v) = each %$val) {
 335         my $nk = $s->_dump($k, "");
 336         $nk = $1 if !$s->{quotekeys} and $nk =~ /^[\"\']([A-Za-z_]\w*)[\"\']$/;
 337         $sname = $mname . '{' . $nk . '}';
 338         $out .= $pad . $ipad . $nk . " => ";
 339
 340         # temporarily alter apad
 341         $s->{apad} .= (" " x (length($nk) + 4)) if $s->{indent} >= 2;
 342         $out .= $s->_dump($val->{$k}, $sname) . ",";
 343         $s->{apad} = $lpad if $s->{indent} >= 2;
 344       }
 345       if (substr($out, -1) eq ',') {
 346         chop $out;
 347         $out .= $pad . ($s->{xpad} x ($s->{level} - 1));
 348       }
 349       $out .= ($name =~ /^\%/) ? ')' : '}';
 350     }
 351     elsif ($realtype eq 'CODE') {
 352       $out .= 'sub { "DUMMY" }';
 353       carp "Encountered CODE ref, using dummy placeholder" if $s->{purity};
 354     }
 355     else {
 356       croak "Can\'t handle $realtype type.";
 357     }
 358
 359     if ($realpack) { # we have a blessed ref
 360       $out .= ', \'' . $realpack . '\'' . ' )';
 361       $out .= '->' . $s->{toaster} . '()'  if $s->{toaster} ne '';
 362       $s->{apad} = $blesspad;
 363     }
 364     $s->{level}--;
 365
 366   }
 367   else {                                 # simple scalar
 368
 369     my $ref = \$_[1];
 370     # first, catalog the scalar
 371     if ($name ne '') {
 372       ($id) = ("$ref" =~ /\(([^\(]*)\)$/);
 373       if (exists $s->{seen}{$id}) {
 374         if ($s->{seen}{$id}[2]) {
 375           $out = $s->{seen}{$id}[0];
 376           #warn "[<$out]\n";
 377           return "\${$out}";
 378         }
 379       }
 380       else {
 381         #warn "[>\\$name]\n";
 382         $s->{seen}{$id} = ["\\$name", $ref];
 383       }
 384     }
 385     if (ref($ref) eq 'GLOB' or "$ref" =~ /=GLOB\([^()]+\)$/) {  # glob
 386       my $name = substr($val, 1);
 387       if ($name =~ /^[A-Za-z_][\w:]*$/) {
 388         $name =~ s/^main::/::/;
 389         $sname = $name;
 390       }
 391       else {
 392         $sname = $s->_dump($name, "");
 393         $sname = '{' . $sname . '}';
 394       }
 395       if ($s->{purity}) {
 396         my $k;
 397         local ($s->{level}) = 0;
 398         for $k (qw(SCALAR ARRAY HASH)) {
 399           my $gval = *$val{$k};
 400           next unless defined $gval;
 401           next if $k eq "SCALAR" && ! defined $$gval;  # always there
 402
 403           # _dump can push into @post, so we hold our place using $postlen
 404           my $postlen = scalar @post;
 405           $post[$postlen] = "\*$sname = ";
 406           local ($s->{apad}) = " " x length($post[$postlen]) if $s->{indent} >= 2;
 407           $post[$postlen] .= $s->_dump($gval, "\*$sname\{$k\}");
 408         }
 409       }
 410       $out .= '*' . $sname;
 411     }
 412     elsif (!defined($val)) {
 413       $out .= "undef";
 414     }
 415     elsif ($val =~ /^(?:0|-?[1-9]\d{0,8})$/) { # safe decimal number
 416       $out .= $val;
 417     }
 418     else {                               # string
 419       if ($s->{useqq}) {
 420         $out .= qquote($val, $s->{useqq});
 421       }
 422       else {
 423         $val =~ s/([\\\'])/\\$1/g;
 424         $out .= '\'' . $val .  '\'';
 425       }
 426     }
 427   }
 428   if ($id) {
 429     # if we made it this far, $id was added to seen list at current
 430     # level, so remove it to get deep copies
 431     if ($s->{deepcopy}) {
 432       delete($s->{seen}{$id});
 433     }
 434     elsif ($name) {
 435       $s->{seen}{$id}[2] = 1;
 436     }
 437   }
 438   return $out;
 439 }
 440
 441 #
 442 # non-OO style of earlier version
 443 #
 444 sub Dumper {
 445   return Data::Dumper->Dump([@_]);
 446 }
 447
 448 # compat stub
 449 sub DumperX {
 450   return Data::Dumper->Dumpxs([@_], []);
 451 }
 452
 453 sub Dumpf { return Data::Dumper->Dump(@_) }
 454
 455 sub Dumpp { print Data::Dumper->Dump(@_) }
 456
 457 #
 458 # reset the "seen" cache
 459 #
 460 sub Reset {
 461   my($s) = shift;
 462   $s->{seen} = {};
 463   return $s;
 464 }
 465
 466 sub Indent {
 467   my($s, $v) = @_;
 468   if (defined($v)) {
 469     if ($v == 0) {
 470       $s->{xpad} = "";
 471       $s->{sep} = "";
 472     }
 473     else {
 474       $s->{xpad} = "  ";
 475       $s->{sep} = "\n";
 476     }
 477     $s->{indent} = $v;
 478     return $s;
 479   }
 480   else {
 481     return $s->{indent};
 482   }
 483 }
 484
 485 sub Pad {
 486   my($s, $v) = @_;
 487   defined($v) ? (($s->{pad} = $v), return $s) : $s->{pad};
 488 }
 489
 490 sub Varname {
 491   my($s, $v) = @_;
 492   defined($v) ? (($s->{varname} = $v), return $s) : $s->{varname};
 493 }
 494
 495 sub Purity {
 496   my($s, $v) = @_;
 497   defined($v) ? (($s->{purity} = $v), return $s) : $s->{purity};
 498 }
 499
 500 sub Useqq {
 501   my($s, $v) = @_;
 502   defined($v) ? (($s->{useqq} = $v), return $s) : $s->{useqq};
 503 }
 504
 505 sub Terse {
 506   my($s, $v) = @_;
 507   defined($v) ? (($s->{terse} = $v), return $s) : $s->{terse};
 508 }
 509
 510 sub Freezer {
 511   my($s, $v) = @_;
 512   defined($v) ? (($s->{freezer} = $v), return $s) : $s->{freezer};
 513 }
 514
 515 sub Toaster {
 516   my($s, $v) = @_;
 517   defined($v) ? (($s->{toaster} = $v), return $s) : $s->{toaster};
 518 }
 519
 520 sub Deepcopy {
 521   my($s, $v) = @_;
 522   defined($v) ? (($s->{deepcopy} = $v), return $s) : $s->{deepcopy};
 523 }
 524
 525 sub Quotekeys {
 526   my($s, $v) = @_;
 527   defined($v) ? (($s->{quotekeys} = $v), return $s) : $s->{quotekeys};
 528 }
 529
 530 sub Bless {
 531   my($s, $v) = @_;
 532   defined($v) ? (($s->{'bless'} = $v), return $s) : $s->{'bless'};
 533 }
 534
 535 sub Maxdepth {
 536   my($s, $v) = @_;
 537   defined($v) ? (($s->{'maxdepth'} = $v), return $s) : $s->{'maxdepth'};
 538 }
 539
 540
 541 # used by qquote below
 542 my %esc = (
 543     "\a" => "\\a",
 544     "\b" => "\\b",
 545     "\t" => "\\t",
 546     "\n" => "\\n",
 547     "\f" => "\\f",
 548     "\r" => "\\r",
 549     "\e" => "\\e",
 550 );
 551
 552 # put a string value in double quotes
 553 sub qquote {
 554   local($_) = shift;
 555   s/([\\\"\@\$])/\\$1/g;
 556   return qq("$_") unless
 557     /[^ !"\#\$%&'()*+,\-.\/0-9:;<=>?\@A-Z[\\\]^_`a-z{|}~]/;  # fast exit
 558
 559   my $high = shift || "";
 560   s/([\a\b\t\n\f\r\e])/$esc{$1}/g;
 561
 562   if (ord('^')==94)  { # ascii
 563     # no need for 3 digits in escape for these
 564     s/([\0-\037])(?!\d)/'\\'.sprintf('%o',ord($1))/eg;
 565     s/([\0-\037\177])/'\\'.sprintf('%03o',ord($1))/eg;
 566     # all but last branch below not supported --BEHAVIOR SUBJECT TO CHANGE--
 567     if ($high eq "iso8859") {
 568       s/([\200-\240])/'\\'.sprintf('%o',ord($1))/eg;
 569     } elsif ($high eq "utf8") {
 570 #     use utf8;
 571 #     $str =~ s/([^\040-\176])/sprintf "\\x{%04x}", ord($1)/ge;
 572     } elsif ($high eq "8bit") {
 573         # leave it as it is
 574     } else {
 575       s/([\200-\377])/'\\'.sprintf('%03o',ord($1))/eg;
 576     }
 577   }
 578   else { # ebcdic
 579       s{([^ !"\#\$%&'()*+,\-.\/0-9:;<=>?\@A-Z[\\\]^_`a-z{|}~])(?!\d)}
 580        {my $v = ord($1); '\\'.sprintf(($v <= 037 ? '%o' : '%03o'), $v)}eg;
 581       s{([^ !"\#\$%&'()*+,\-.\/0-9:;<=>?\@A-Z[\\\]^_`a-z{|}~])}
 582        {'\\'.sprintf('%03o',ord($1))}eg;
 583   }
 584
 585   return qq("$_");
 586 }
 587
 588 1;
 589 __END__
 590
 591 =head1 NAME
 592
 593 Data::Dumper - stringified perl data structures, suitable for both printing and C<eval>
 594
 595 =head1 SYNOPSIS
 596
 597     use Data::Dumper;
 598
 599     # simple procedural interface
 600     print Dumper($foo, $bar);
 601
 602     # extended usage with names
 603     print Data::Dumper->Dump([$foo, $bar], [qw(foo *ary)]);
 604
 605     # configuration variables
 606     {
 607       local $Data::Dump::Purity = 1;
 608       eval Data::Dumper->Dump([$foo, $bar], [qw(foo *ary)]);
 609     }
 610
 611     # OO usage
 612     $d = Data::Dumper->new([$foo, $bar], [qw(foo *ary)]);
 613        ...
 614     print $d->Dump;
 615        ...
 616     $d->Purity(1)->Terse(1)->Deepcopy(1);
 617     eval $d->Dump;
 618
 619
 620 =head1 DESCRIPTION
 621
 622 Given a list of scalars or reference variables, writes out their contents in
 623 perl syntax. The references can also be objects.  The contents of each
 624 variable is output in a single Perl statement.  Handles self-referential
 625 structures correctly.
 626
 627 The return value can be C<eval>ed to get back an identical copy of the
 628 original reference structure.
 629
 630 Any references that are the same as one of those passed in will be named
 631 C<$VAR>I<n> (where I<n> is a numeric suffix), and other duplicate references
 632 to substructures within C<$VAR>I<n> will be appropriately labeled using arrow
 633 notation.  You can specify names for individual values to be dumped if you
 634 use the C<Dump()> method, or you can change the default C<$VAR> prefix to
 635 something else.  See C<$Data::Dumper::Varname> and C<$Data::Dumper::Terse>
 636 below.
 637
 638 The default output of self-referential structures can be C<eval>ed, but the
 639 nested references to C<$VAR>I<n> will be undefined, since a recursive
 640 structure cannot be constructed using one Perl statement.  You should set the
 641 C<Purity> flag to 1 to get additional statements that will correctly fill in
 642 these references.
 643
 644 In the extended usage form, the references to be dumped can be given
 645 user-specified names.  If a name begins with a C<*>, the output will
 646 describe the dereferenced type of the supplied reference for hashes and
 647 arrays, and coderefs.  Output of names will be avoided where possible if
 648 the C<Terse> flag is set.
 649
 650 In many cases, methods that are used to set the internal state of the
 651 object will return the object itself, so method calls can be conveniently
 652 chained together.
 653
 654 Several styles of output are possible, all controlled by setting
 655 the C<Indent> flag.  See L<Configuration Variables or Methods> below
 656 for details.
 657
 658
 659 =head2 Methods
 660
 661 =over 4
 662
 663 =item I<PACKAGE>->new(I<ARRAYREF [>, I<ARRAYREF]>)
 664
 665 Returns a newly created C<Data::Dumper> object.  The first argument is an
 666 anonymous array of values to be dumped.  The optional second argument is an
 667 anonymous array of names for the values.  The names need not have a leading
 668 C<$> sign, and must be comprised of alphanumeric characters.  You can begin
 669 a name with a C<*> to specify that the dereferenced type must be dumped
 670 instead of the reference itself, for ARRAY and HASH references.
 671
 672 The prefix specified by C<$Data::Dumper::Varname> will be used with a
 673 numeric suffix if the name for a value is undefined.
 674
 675 Data::Dumper will catalog all references encountered while dumping the
 676 values. Cross-references (in the form of names of substructures in perl
 677 syntax) will be inserted at all possible points, preserving any structural
 678 interdependencies in the original set of values.  Structure traversal is
 679 depth-first,  and proceeds in order from the first supplied value to
 680 the last.
 681
 682 =item I<$OBJ>->Dump  I<or>  I<PACKAGE>->Dump(I<ARRAYREF [>, I<ARRAYREF]>)
 683
 684 Returns the stringified form of the values stored in the object (preserving
 685 the order in which they were supplied to C<new>), subject to the
 686 configuration options below.  In a list context, it returns a list
 687 of strings corresponding to the supplied values.
 688
 689 The second form, for convenience, simply calls the C<new> method on its
 690 arguments before dumping the object immediately.
 691
 692 =item I<$OBJ>->Seen(I<[HASHREF]>)
 693
 694 Queries or adds to the internal table of already encountered references.
 695 You must use C<Reset> to explicitly clear the table if needed.  Such
 696 references are not dumped; instead, their names are inserted wherever they
 697 are encountered subsequently.  This is useful especially for properly
 698 dumping subroutine references.
 699
 700 Expects a anonymous hash of name => value pairs.  Same rules apply for names
 701 as in C<new>.  If no argument is supplied, will return the "seen" list of
 702 name => value pairs, in a list context.  Otherwise, returns the object
 703 itself.
 704
 705 =item I<$OBJ>->Values(I<[ARRAYREF]>)
 706
 707 Queries or replaces the internal array of values that will be dumped.
 708 When called without arguments, returns the values.  Otherwise, returns the
 709 object itself.
 710
 711 =item I<$OBJ>->Names(I<[ARRAYREF]>)
 712
 713 Queries or replaces the internal array of user supplied names for the values
 714 that will be dumped.  When called without arguments, returns the names.
 715 Otherwise, returns the object itself.
 716
 717 =item I<$OBJ>->Reset
 718
 719 Clears the internal table of "seen" references and returns the object
 720 itself.
 721
 722 =back
 723
 724 =head2 Functions
 725
 726 =over 4
 727
 728 =item Dumper(I<LIST>)
 729
 730 Returns the stringified form of the values in the list, subject to the
 731 configuration options below.  The values will be named C<$VAR>I<n> in the
 732 output, where I<n> is a numeric suffix.  Will return a list of strings
 733 in a list context.
 734
 735 =back
 736
 737 =head2 Configuration Variables or Methods
 738
 739 Several configuration variables can be used to control the kind of output
 740 generated when using the procedural interface.  These variables are usually
 741 C<local>ized in a block so that other parts of the code are not affected by
 742 the change.
 743
 744 These variables determine the default state of the object created by calling
 745 the C<new> method, but cannot be used to alter the state of the object
 746 thereafter.  The equivalent method names should be used instead to query
 747 or set the internal state of the object.
 748
 749 The method forms return the object itself when called with arguments,
 750 so that they can be chained together nicely.
 751
 752 =over 4
 753
 754 =item $Data::Dumper::Indent  I<or>  I<$OBJ>->Indent(I<[NEWVAL]>)
 755
 756 Controls the style of indentation.  It can be set to 0, 1, 2 or 3.  Style 0
 757 spews output without any newlines, indentation, or spaces between list
 758 items.  It is the most compact format possible that can still be called
 759 valid perl.  Style 1 outputs a readable form with newlines but no fancy
 760 indentation (each level in the structure is simply indented by a fixed
 761 amount of whitespace).  Style 2 (the default) outputs a very readable form
 762 which takes into account the length of hash keys (so the hash value lines
 763 up).  Style 3 is like style 2, but also annotates the elements of arrays
 764 with their index (but the comment is on its own line, so array output
 765 consumes twice the number of lines).  Style 2 is the default.
 766
 767 =item $Data::Dumper::Purity  I<or>  I<$OBJ>->Purity(I<[NEWVAL]>)
 768
 769 Controls the degree to which the output can be C<eval>ed to recreate the
 770 supplied reference structures.  Setting it to 1 will output additional perl
 771 statements that will correctly recreate nested references.  The default is
 772 0.
 773
 774 =item $Data::Dumper::Pad  I<or>  I<$OBJ>->Pad(I<[NEWVAL]>)
 775
 776 Specifies the string that will be prefixed to every line of the output.
 777 Empty string by default.
 778
 779 =item $Data::Dumper::Varname  I<or>  I<$OBJ>->Varname(I<[NEWVAL]>)
 780
 781 Contains the prefix to use for tagging variable names in the output. The
 782 default is "VAR".
 783
 784 =item $Data::Dumper::Useqq  I<or>  I<$OBJ>->Useqq(I<[NEWVAL]>)
 785
 786 When set, enables the use of double quotes for representing string values.
 787 Whitespace other than space will be represented as C<[\n\t\r]>, "unsafe"
 788 characters will be backslashed, and unprintable characters will be output as
 789 quoted octal integers.  Since setting this variable imposes a performance
 790 penalty, the default is 0.  C<Dump()> will run slower if this flag is set,
 791 since the fast XSUB implementation doesn't support it yet.
 792
 793 =item $Data::Dumper::Terse  I<or>  I<$OBJ>->Terse(I<[NEWVAL]>)
 794
 795 When set, Data::Dumper will emit single, non-self-referential values as
 796 atoms/terms rather than statements.  This means that the C<$VAR>I<n> names
 797 will be avoided where possible, but be advised that such output may not
 798 always be parseable by C<eval>.
 799
 800 =item $Data::Dumper::Freezer  I<or>  $I<OBJ>->Freezer(I<[NEWVAL]>)
 801
 802 Can be set to a method name, or to an empty string to disable the feature.
 803 Data::Dumper will invoke that method via the object before attempting to
 804 stringify it.  This method can alter the contents of the object (if, for
 805 instance, it contains data allocated from C), and even rebless it in a
 806 different package.  The client is responsible for making sure the specified
 807 method can be called via the object, and that the object ends up containing
 808 only perl data types after the method has been called.  Defaults to an empty
 809 string.
 810
 811 =item $Data::Dumper::Toaster  I<or>  $I<OBJ>->Toaster(I<[NEWVAL]>)
 812
 813 Can be set to a method name, or to an empty string to disable the feature.
 814 Data::Dumper will emit a method call for any objects that are to be dumped
 815 using the syntax C<bless(DATA, CLASS)->METHOD()>.  Note that this means that
 816 the method specified will have to perform any modifications required on the
 817 object (like creating new state within it, and/or reblessing it in a
 818 different package) and then return it.  The client is responsible for making
 819 sure the method can be called via the object, and that it returns a valid
 820 object.  Defaults to an empty string.
 821
 822 =item $Data::Dumper::Deepcopy  I<or>  $I<OBJ>->Deepcopy(I<[NEWVAL]>)
 823
 824 Can be set to a boolean value to enable deep copies of structures.
 825 Cross-referencing will then only be done when absolutely essential
 826 (i.e., to break reference cycles).  Default is 0.
 827
 828 =item $Data::Dumper::Quotekeys  I<or>  $I<OBJ>->Quotekeys(I<[NEWVAL]>)
 829
 830 Can be set to a boolean value to control whether hash keys are quoted.
 831 A false value will avoid quoting hash keys when it looks like a simple
 832 string.  Default is 1, which will always enclose hash keys in quotes.
 833
 834 =item $Data::Dumper::Bless  I<or>  $I<OBJ>->Bless(I<[NEWVAL]>)
 835
 836 Can be set to a string that specifies an alternative to the C<bless>
 837 builtin operator used to create objects.  A function with the specified
 838 name should exist, and should accept the same arguments as the builtin.
 839 Default is C<bless>.
 840
 841 =item $Data::Dumper::Maxdepth  I<or>  $I<OBJ>->Maxdepth(I<[NEWVAL]>)
 842
 843 Can be set to a positive integer that specifies the depth beyond which
 844 which we don't venture into a structure.  Has no effect when
 845 C<Data::Dumper::Purity> is set.  (Useful in debugger when we often don't
 846 want to see more than enough).  Default is 0, which means there is
 847 no maximum depth.
 848
 849 =back
 850
 851 =head2 Exports
 852
 853 =over 4
 854
 855 =item Dumper
 856
 857 =back
 858
 859 =head1 EXAMPLES
 860
 861 Run these code snippets to get a quick feel for the behavior of this
 862 module.  When you are through with these examples, you may want to
 863 add or change the various configuration variables described above,
 864 to see their behavior.  (See the testsuite in the Data::Dumper
 865 distribution for more examples.)
 866
 867
 868     use Data::Dumper;
 869
 870     package Foo;
 871     sub new {bless {'a' => 1, 'b' => sub { return "foo" }}, $_[0]};
 872
 873     package Fuz;                       # a weird REF-REF-SCALAR object
 874     sub new {bless \($_ = \ 'fu\'z'), $_[0]};
 875
 876     package main;
 877     $foo = Foo->new;
 878     $fuz = Fuz->new;
 879     $boo = [ 1, [], "abcd", \*foo,
 880              {1 => 'a', 023 => 'b', 0x45 => 'c'},
 881              \\"p\q\'r", $foo, $fuz];
 882
 883     ########
 884     # simple usage
 885     ########
 886
 887     $bar = eval(Dumper($boo));
 888     print($@) if $@;
 889     print Dumper($boo), Dumper($bar);  # pretty print (no array indices)
 890
 891     $Data::Dumper::Terse = 1;          # don't output names where feasible
 892     $Data::Dumper::Indent = 0;         # turn off all pretty print
 893     print Dumper($boo), "\n";
 894
 895     $Data::Dumper::Indent = 1;         # mild pretty print
 896     print Dumper($boo);
 897
 898     $Data::Dumper::Indent = 3;         # pretty print with array indices
 899     print Dumper($boo);
 900
 901     $Data::Dumper::Useqq = 1;          # print strings in double quotes
 902     print Dumper($boo);
 903
 904
 905     ########
 906     # recursive structures
 907     ########
 908
 909     @c = ('c');
 910     $c = \@c;
 911     $b = {};
 912     $a = [1, $b, $c];
 913     $b->{a} = $a;
 914     $b->{b} = $a->[1];
 915     $b->{c} = $a->[2];
 916     print Data::Dumper->Dump([$a,$b,$c], [qw(a b c)]);
 917
 918
 919     $Data::Dumper::Purity = 1;         # fill in the holes for eval
 920     print Data::Dumper->Dump([$a, $b], [qw(*a b)]); # print as @a
 921     print Data::Dumper->Dump([$b, $a], [qw(*b a)]); # print as %b
 922
 923
 924     $Data::Dumper::Deepcopy = 1;       # avoid cross-refs
 925     print Data::Dumper->Dump([$b, $a], [qw(*b a)]);
 926
 927
 928     $Data::Dumper::Purity = 0;         # avoid cross-refs
 929     print Data::Dumper->Dump([$b, $a], [qw(*b a)]);
 930
 931     ########
 932     # deep structures
 933     ########
 934
 935     $a = "pearl";
 936     $b = [ $a ];
 937     $c = { 'b' => $b };
 938     $d = [ $c ];
 939     $e = { 'd' => $d };
 940     $f = { 'e' => $e };
 941     print Data::Dumper->Dump([$f], [qw(f)]);
 942
 943     $Data::Dumper::Maxdepth = 3;       # no deeper than 3 refs down
 944     print Data::Dumper->Dump([$f], [qw(f)]);
 945
 946
 947     ########
 948     # object-oriented usage
 949     ########
 950
 951     $d = Data::Dumper->new([$a,$b], [qw(a b)]);
 952     $d->Seen({'*c' => $c});            # stash a ref without printing it
 953     $d->Indent(3);
 954     print $d->Dump;
 955     $d->Reset->Purity(0);              # empty the seen cache
 956     print join "----\n", $d->Dump;
 957
 958
 959     ########
 960     # persistence
 961     ########
 962
 963     package Foo;
 964     sub new { bless { state => 'awake' }, shift }
 965     sub Freeze {
 966         my $s = shift;
 967         print STDERR "preparing to sleep\n";
 968         $s->{state} = 'asleep';
 969         return bless $s, 'Foo::ZZZ';
 970     }
 971
 972     package Foo::ZZZ;
 973     sub Thaw {
 974         my $s = shift;
 975         print STDERR "waking up\n";
 976         $s->{state} = 'awake';
 977         return bless $s, 'Foo';
 978     }
 979
 980     package Foo;
 981     use Data::Dumper;
 982     $a = Foo->new;
 983     $b = Data::Dumper->new([$a], ['c']);
 984     $b->Freezer('Freeze');
 985     $b->Toaster('Thaw');
 986     $c = $b->Dump;
 987     print $c;
 988     $d = eval $c;
 989     print Data::Dumper->Dump([$d], ['d']);
 990
 991
 992     ########
 993     # symbol substitution (useful for recreating CODE refs)
 994     ########
 995
 996     sub foo { print "foo speaking\n" }
 997     *other = \&foo;
 998     $bar = [ \&other ];
 999     $d = Data::Dumper->new([\&other,$bar],['*other','bar']);
1000     $d->Seen({ '*foo' => \&foo });
1001     print $d->Dump;
1002
1003
1004 =head1 BUGS
1005
1006 Due to limitations of Perl subroutine call semantics, you cannot pass an
1007 array or hash.  Prepend it with a C<\> to pass its reference instead.  This
1008 will be remedied in time, with the arrival of prototypes in later versions
1009 of Perl.  For now, you need to use the extended usage form, and prepend the
1010 name with a C<*> to output it as a hash or array.
1011
1012 C<Data::Dumper> cheats with CODE references.  If a code reference is
1013 encountered in the structure being processed, an anonymous subroutine that
1014 contains the string '"DUMMY"' will be inserted in its place, and a warning
1015 will be printed if C<Purity> is set.  You can C<eval> the result, but bear
1016 in mind that the anonymous sub that gets created is just a placeholder.
1017 Someday, perl will have a switch to cache-on-demand the string
1018 representation of a compiled piece of code, I hope.  If you have prior
1019 knowledge of all the code refs that your data structures are likely
1020 to have, you can use the C<Seen> method to pre-seed the internal reference
1021 table and make the dumped output point to them, instead.  See L<EXAMPLES>
1022 above.
1023
1024 The C<Useqq> flag makes Dump() run slower, since the XSUB implementation
1025 does not support it.
1026
1027 SCALAR objects have the weirdest looking C<bless> workaround.
1028
1029
1030 =head1 AUTHOR
1031
1032 Gurusamy Sarathy        gsar@activestate.com
1033
1034 Copyright (c) 1996-98 Gurusamy Sarathy. All rights reserved.
1035 This program is free software; you can redistribute it and/or
1036 modify it under the same terms as Perl itself.
1037
1038
1039 =head1 VERSION
1040
1041 Version 2.11   (unreleased)
1042
1043 =head1 SEE ALSO
1044
1045 perl(1)
1046
1047 =cut