ext/Data/Dumper/Dumper.pm

   1 #
   2 # Data/Dumper.pm
   3 #
   4 # convert perl data structures into perl syntax suitable for both printing
   5 # and eval
   6 #
   7 # Documentation at the __END__
   8 #
   9
  10 package Data::Dumper;
  11
  12 $VERSION = '2.101';
  13
  14 #$| = 1;
  15
  16 require 5.005_64;
  17 require Exporter;
  18 use XSLoader ();
  19 require overload;
  20
  21 use Carp;
  22
  23 @ISA = qw(Exporter);
  24 @EXPORT = qw(Dumper);
  25 @EXPORT_OK = qw(DumperX);
  26
  27 XSLoader::load 'Data::Dumper';
  28
  29 # module vars and their defaults
  30 $Indent = 2 unless defined $Indent;
  31 $Purity = 0 unless defined $Purity;
  32 $Pad = "" unless defined $Pad;
  33 $Varname = "VAR" unless defined $Varname;
  34 $Useqq = 0 unless defined $Useqq;
  35 $Terse = 0 unless defined $Terse;
  36 $Freezer = "" unless defined $Freezer;
  37 $Toaster = "" unless defined $Toaster;
  38 $Deepcopy = 0 unless defined $Deepcopy;
  39 $Quotekeys = 1 unless defined $Quotekeys;
  40 $Bless = "bless" unless defined $Bless;
  41 #$Expdepth = 0 unless defined $Expdepth;
  42 $Maxdepth = 0 unless defined $Maxdepth;
  43
  44 #
  45 # expects an arrayref of values to be dumped.
  46 # can optionally pass an arrayref of names for the values.
  47 # names must have leading $ sign stripped. begin the name with *
  48 # to cause output of arrays and hashes rather than refs.
  49 #
  50 sub new {
  51   my($c, $v, $n) = @_;
  52
  53   croak "Usage:  PACKAGE->new(ARRAYREF, [ARRAYREF])"
  54     unless (defined($v) && (ref($v) eq 'ARRAY'));
  55   $n = [] unless (defined($n) && (ref($v) eq 'ARRAY'));
  56
  57   my($s) = {
  58              level      => 0,           # current recursive depth
  59              indent     => $Indent,     # various styles of indenting
  60              pad        => $Pad,        # all lines prefixed by this string
  61              xpad       => "",          # padding-per-level
  62              apad       => "",          # added padding for hash keys n such
  63              sep        => "",          # list separator
  64              seen       => {},          # local (nested) refs (id => [name, val])
  65              todump     => $v,          # values to dump []
  66              names      => $n,          # optional names for values []
  67              varname    => $Varname,    # prefix to use for tagging nameless ones
  68              purity     => $Purity,     # degree to which output is evalable
  69              useqq      => $Useqq,      # use "" for strings (backslashitis ensues)
  70              terse      => $Terse,      # avoid name output (where feasible)
  71              freezer    => $Freezer,    # name of Freezer method for objects
  72              toaster    => $Toaster,    # name of method to revive objects
  73              deepcopy   => $Deepcopy,   # dont cross-ref, except to stop recursion
  74              quotekeys  => $Quotekeys,  # quote hash keys
  75              'bless'    => $Bless,      # keyword to use for "bless"
  76 #            expdepth   => $Expdepth,   # cutoff depth for explicit dumping
  77              maxdepth   => $Maxdepth,   # depth beyond which we give up
  78            };
  79
  80   if ($Indent > 0) {
  81     $s->{xpad} = "  ";
  82     $s->{sep} = "\n";
  83   }
  84   return bless($s, $c);
  85 }
  86
  87 #
  88 # add-to or query the table of already seen references
  89 #
  90 sub Seen {
  91   my($s, $g) = @_;
  92   if (defined($g) && (ref($g) eq 'HASH'))  {
  93     my($k, $v, $id);
  94     while (($k, $v) = each %$g) {
  95       if (defined $v and ref $v) {
  96         ($id) = (overload::StrVal($v) =~ /\((.*)\)$/);
  97         if ($k =~ /^[*](.*)$/) {
  98           $k = (ref $v eq 'ARRAY') ? ( "\\\@" . $1 ) :
  99                (ref $v eq 'HASH')  ? ( "\\\%" . $1 ) :
 100                (ref $v eq 'CODE')  ? ( "\\\&" . $1 ) :
 101                                      (   "\$" . $1 ) ;
 102         }
 103         elsif ($k !~ /^\$/) {
 104           $k = "\$" . $k;
 105         }
 106         $s->{seen}{$id} = [$k, $v];
 107       }
 108       else {
 109         carp "Only refs supported, ignoring non-ref item \$$k";
 110       }
 111     }
 112     return $s;
 113   }
 114   else {
 115     return map { @$_ } values %{$s->{seen}};
 116   }
 117 }
 118
 119 #
 120 # set or query the values to be dumped
 121 #
 122 sub Values {
 123   my($s, $v) = @_;
 124   if (defined($v) && (ref($v) eq 'ARRAY'))  {
 125     $s->{todump} = [@$v];        # make a copy
 126     return $s;
 127   }
 128   else {
 129     return @{$s->{todump}};
 130   }
 131 }
 132
 133 #
 134 # set or query the names of the values to be dumped
 135 #
 136 sub Names {
 137   my($s, $n) = @_;
 138   if (defined($n) && (ref($n) eq 'ARRAY'))  {
 139     $s->{names} = [@$n];         # make a copy
 140     return $s;
 141   }
 142   else {
 143     return @{$s->{names}};
 144   }
 145 }
 146
 147 sub DESTROY {}
 148
 149 sub Dump {
 150     return &Dumpxs
 151         unless $Data::Dumper::Useqq || (ref($_[0]) && $_[0]->{useqq});
 152     return &Dumpperl;
 153 }
 154
 155 #
 156 # dump the refs in the current dumper object.
 157 # expects same args as new() if called via package name.
 158 #
 159 sub Dumpperl {
 160   my($s) = shift;
 161   my(@out, $val, $name);
 162   my($i) = 0;
 163   local(@post);
 164
 165   $s = $s->new(@_) unless ref $s;
 166
 167   for $val (@{$s->{todump}}) {
 168     my $out = "";
 169     @post = ();
 170     $name = $s->{names}[$i++];
 171     if (defined $name) {
 172       if ($name =~ /^[*](.*)$/) {
 173         if (defined $val) {
 174           $name = (ref $val eq 'ARRAY') ? ( "\@" . $1 ) :
 175                   (ref $val eq 'HASH')  ? ( "\%" . $1 ) :
 176                   (ref $val eq 'CODE')  ? ( "\*" . $1 ) :
 177                                           ( "\$" . $1 ) ;
 178         }
 179         else {
 180           $name = "\$" . $1;
 181         }
 182       }
 183       elsif ($name !~ /^\$/) {
 184         $name = "\$" . $name;
 185       }
 186     }
 187     else {
 188       $name = "\$" . $s->{varname} . $i;
 189     }
 190
 191     my $valstr;
 192     {
 193       local($s->{apad}) = $s->{apad};
 194       $s->{apad} .= ' ' x (length($name) + 3) if $s->{indent} >= 2;
 195       $valstr = $s->_dump($val, $name);
 196     }
 197
 198     $valstr = "$name = " . $valstr . ';' if @post or !$s->{terse};
 199     $out .= $s->{pad} . $valstr . $s->{sep};
 200     $out .= $s->{pad} . join(';' . $s->{sep} . $s->{pad}, @post)
 201       . ';' . $s->{sep} if @post;
 202
 203     push @out, $out;
 204   }
 205   return wantarray ? @out : join('', @out);
 206 }
 207
 208 #
 209 # twist, toil and turn;
 210 # and recurse, of course.
 211 #
 212 sub _dump {
 213   my($s, $val, $name) = @_;
 214   my($sname);
 215   my($out, $realpack, $realtype, $type, $ipad, $id, $blesspad);
 216
 217   $type = ref $val;
 218   $out = "";
 219
 220   if ($type) {
 221
 222     # prep it, if it looks like an object
 223     if (my $freezer = $s->{freezer}) {
 224       $val->$freezer() if UNIVERSAL::can($val, $freezer);
 225     }
 226
 227     ($realpack, $realtype, $id) =
 228       (overload::StrVal($val) =~ /^(?:(.*)\=)?([^=]*)\(([^\(]*)\)$/);
 229
 230     # if it has a name, we need to either look it up, or keep a tab
 231     # on it so we know when we hit it later
 232     if (defined($name) and length($name)) {
 233       # keep a tab on it so that we dont fall into recursive pit
 234       if (exists $s->{seen}{$id}) {
 235 #       if ($s->{expdepth} < $s->{level}) {
 236           if ($s->{purity} and $s->{level} > 0) {
 237             $out = ($realtype eq 'HASH')  ? '{}' :
 238               ($realtype eq 'ARRAY') ? '[]' :
 239                 'do{my $o}' ;
 240             push @post, $name . " = " . $s->{seen}{$id}[0];
 241           }
 242           else {
 243             $out = $s->{seen}{$id}[0];
 244             if ($name =~ /^([\@\%])/) {
 245               my $start = $1;
 246               if ($out =~ /^\\$start/) {
 247                 $out = substr($out, 1);
 248               }
 249               else {
 250                 $out = $start . '{' . $out . '}';
 251               }
 252             }
 253           }
 254           return $out;
 255 #        }
 256       }
 257       else {
 258         # store our name
 259         $s->{seen}{$id} = [ (($name =~ /^[@%]/)     ? ('\\' . $name ) :
 260                              ($realtype eq 'CODE' and
 261                               $name =~ /^[*](.*)$/) ? ('\\&' . $1 )   :
 262                              $name          ),
 263                             $val ];
 264       }
 265     }
 266
 267     if ($realpack and $realpack eq 'Regexp') {
 268         $out = "$val";
 269         $out =~ s,/,\\/,g;
 270         return "qr/$out/";
 271     }
 272
 273     # If purity is not set and maxdepth is set, then check depth:
 274     # if we have reached maximum depth, return the string
 275     # representation of the thing we are currently examining
 276     # at this depth (i.e., 'Foo=ARRAY(0xdeadbeef)').
 277     if (!$s->{purity}
 278         and $s->{maxdepth} > 0
 279         and $s->{level} >= $s->{maxdepth})
 280     {
 281       return qq['$val'];
 282     }
 283
 284     # we have a blessed ref
 285     if ($realpack) {
 286       $out = $s->{'bless'} . '( ';
 287       $blesspad = $s->{apad};
 288       $s->{apad} .= '       ' if ($s->{indent} >= 2);
 289     }
 290
 291     $s->{level}++;
 292     $ipad = $s->{xpad} x $s->{level};
 293
 294
 295     if ($realtype eq 'SCALAR') {
 296       if ($realpack) {
 297         $out .= 'do{\\(my $o = ' . $s->_dump($$val, "\${$name}") . ')}';
 298       }
 299       else {
 300         $out .= '\\' . $s->_dump($$val, "\${$name}");
 301       }
 302     }
 303     elsif ($realtype eq 'GLOB') {
 304         $out .= '\\' . $s->_dump($$val, "*{$name}");
 305     }
 306     elsif ($realtype eq 'ARRAY') {
 307       my($v, $pad, $mname);
 308       my($i) = 0;
 309       $out .= ($name =~ /^\@/) ? '(' : '[';
 310       $pad = $s->{sep} . $s->{pad} . $s->{apad};
 311       ($name =~ /^\@(.*)$/) ? ($mname = "\$" . $1) :
 312         # omit -> if $foo->[0]->{bar}, but not ${$foo->[0]}->{bar}
 313         ($name =~ /^\\?[\%\@\*\$][^{].*[]}]$/) ? ($mname = $name) :
 314           ($mname = $name . '->');
 315       $mname .= '->' if $mname =~ /^\*.+\{[A-Z]+\}$/;
 316       for $v (@$val) {
 317         $sname = $mname . '[' . $i . ']';
 318         $out .= $pad . $ipad . '#' . $i if $s->{indent} >= 3;
 319         $out .= $pad . $ipad . $s->_dump($v, $sname);
 320         $out .= "," if $i++ < $#$val;
 321       }
 322       $out .= $pad . ($s->{xpad} x ($s->{level} - 1)) if $i;
 323       $out .= ($name =~ /^\@/) ? ')' : ']';
 324     }
 325     elsif ($realtype eq 'HASH') {
 326       my($k, $v, $pad, $lpad, $mname);
 327       $out .= ($name =~ /^\%/) ? '(' : '{';
 328       $pad = $s->{sep} . $s->{pad} . $s->{apad};
 329       $lpad = $s->{apad};
 330       ($name =~ /^\%(.*)$/) ? ($mname = "\$" . $1) :
 331         # omit -> if $foo->[0]->{bar}, but not ${$foo->[0]}->{bar}
 332         ($name =~ /^\\?[\%\@\*\$][^{].*[]}]$/) ? ($mname = $name) :
 333           ($mname = $name . '->');
 334       $mname .= '->' if $mname =~ /^\*.+\{[A-Z]+\}$/;
 335       while (($k, $v) = each %$val) {
 336         my $nk = $s->_dump($k, "");
 337         $nk = $1 if !$s->{quotekeys} and $nk =~ /^[\"\']([A-Za-z_]\w*)[\"\']$/;
 338         $sname = $mname . '{' . $nk . '}';
 339         $out .= $pad . $ipad . $nk . " => ";
 340
 341         # temporarily alter apad
 342         $s->{apad} .= (" " x (length($nk) + 4)) if $s->{indent} >= 2;
 343         $out .= $s->_dump($val->{$k}, $sname) . ",";
 344         $s->{apad} = $lpad if $s->{indent} >= 2;
 345       }
 346       if (substr($out, -1) eq ',') {
 347         chop $out;
 348         $out .= $pad . ($s->{xpad} x ($s->{level} - 1));
 349       }
 350       $out .= ($name =~ /^\%/) ? ')' : '}';
 351     }
 352     elsif ($realtype eq 'CODE') {
 353       $out .= 'sub { "DUMMY" }';
 354       carp "Encountered CODE ref, using dummy placeholder" if $s->{purity};
 355     }
 356     else {
 357       croak "Can\'t handle $realtype type.";
 358     }
 359
 360     if ($realpack) { # we have a blessed ref
 361       $out .= ', \'' . $realpack . '\'' . ' )';
 362       $out .= '->' . $s->{toaster} . '()'  if $s->{toaster} ne '';
 363       $s->{apad} = $blesspad;
 364     }
 365     $s->{level}--;
 366
 367   }
 368   else {                                 # simple scalar
 369
 370     my $ref = \$_[1];
 371     # first, catalog the scalar
 372     if ($name ne '') {
 373       ($id) = ("$ref" =~ /\(([^\(]*)\)$/);
 374       if (exists $s->{seen}{$id}) {
 375         if ($s->{seen}{$id}[2]) {
 376           $out = $s->{seen}{$id}[0];
 377           #warn "[<$out]\n";
 378           return "\${$out}";
 379         }
 380       }
 381       else {
 382         #warn "[>\\$name]\n";
 383         $s->{seen}{$id} = ["\\$name", $ref];
 384       }
 385     }
 386     if (ref($ref) eq 'GLOB' or "$ref" =~ /=GLOB\([^()]+\)$/) {  # glob
 387       my $name = substr($val, 1);
 388       if ($name =~ /^[A-Za-z_][\w:]*$/) {
 389         $name =~ s/^main::/::/;
 390         $sname = $name;
 391       }
 392       else {
 393         $sname = $s->_dump($name, "");
 394         $sname = '{' . $sname . '}';
 395       }
 396       if ($s->{purity}) {
 397         my $k;
 398         local ($s->{level}) = 0;
 399         for $k (qw(SCALAR ARRAY HASH)) {
 400           my $gval = *$val{$k};
 401           next unless defined $gval;
 402           next if $k eq "SCALAR" && ! defined $$gval;  # always there
 403
 404           # _dump can push into @post, so we hold our place using $postlen
 405           my $postlen = scalar @post;
 406           $post[$postlen] = "\*$sname = ";
 407           local ($s->{apad}) = " " x length($post[$postlen]) if $s->{indent} >= 2;
 408           $post[$postlen] .= $s->_dump($gval, "\*$sname\{$k\}");
 409         }
 410       }
 411       $out .= '*' . $sname;
 412     }
 413     elsif (!defined($val)) {
 414       $out .= "undef";
 415     }
 416     elsif ($val =~ /^(?:0|-?[1-9]\d{0,8})$/) { # safe decimal number
 417       $out .= $val;
 418     }
 419     else {                               # string
 420       if ($s->{useqq}) {
 421         $out .= qquote($val, $s->{useqq});
 422       }
 423       else {
 424         $val =~ s/([\\\'])/\\$1/g;
 425         $out .= '\'' . $val .  '\'';
 426       }
 427     }
 428   }
 429   if ($id) {
 430     # if we made it this far, $id was added to seen list at current
 431     # level, so remove it to get deep copies
 432     if ($s->{deepcopy}) {
 433       delete($s->{seen}{$id});
 434     }
 435     elsif ($name) {
 436       $s->{seen}{$id}[2] = 1;
 437     }
 438   }
 439   return $out;
 440 }
 441
 442 #
 443 # non-OO style of earlier version
 444 #
 445 sub Dumper {
 446   return Data::Dumper->Dump([@_]);
 447 }
 448
 449 # compat stub
 450 sub DumperX {
 451   return Data::Dumper->Dumpxs([@_], []);
 452 }
 453
 454 sub Dumpf { return Data::Dumper->Dump(@_) }
 455
 456 sub Dumpp { print Data::Dumper->Dump(@_) }
 457
 458 #
 459 # reset the "seen" cache
 460 #
 461 sub Reset {
 462   my($s) = shift;
 463   $s->{seen} = {};
 464   return $s;
 465 }
 466
 467 sub Indent {
 468   my($s, $v) = @_;
 469   if (defined($v)) {
 470     if ($v == 0) {
 471       $s->{xpad} = "";
 472       $s->{sep} = "";
 473     }
 474     else {
 475       $s->{xpad} = "  ";
 476       $s->{sep} = "\n";
 477     }
 478     $s->{indent} = $v;
 479     return $s;
 480   }
 481   else {
 482     return $s->{indent};
 483   }
 484 }
 485
 486 sub Pad {
 487   my($s, $v) = @_;
 488   defined($v) ? (($s->{pad} = $v), return $s) : $s->{pad};
 489 }
 490
 491 sub Varname {
 492   my($s, $v) = @_;
 493   defined($v) ? (($s->{varname} = $v), return $s) : $s->{varname};
 494 }
 495
 496 sub Purity {
 497   my($s, $v) = @_;
 498   defined($v) ? (($s->{purity} = $v), return $s) : $s->{purity};
 499 }
 500
 501 sub Useqq {
 502   my($s, $v) = @_;
 503   defined($v) ? (($s->{useqq} = $v), return $s) : $s->{useqq};
 504 }
 505
 506 sub Terse {
 507   my($s, $v) = @_;
 508   defined($v) ? (($s->{terse} = $v), return $s) : $s->{terse};
 509 }
 510
 511 sub Freezer {
 512   my($s, $v) = @_;
 513   defined($v) ? (($s->{freezer} = $v), return $s) : $s->{freezer};
 514 }
 515
 516 sub Toaster {
 517   my($s, $v) = @_;
 518   defined($v) ? (($s->{toaster} = $v), return $s) : $s->{toaster};
 519 }
 520
 521 sub Deepcopy {
 522   my($s, $v) = @_;
 523   defined($v) ? (($s->{deepcopy} = $v), return $s) : $s->{deepcopy};
 524 }
 525
 526 sub Quotekeys {
 527   my($s, $v) = @_;
 528   defined($v) ? (($s->{quotekeys} = $v), return $s) : $s->{quotekeys};
 529 }
 530
 531 sub Bless {
 532   my($s, $v) = @_;
 533   defined($v) ? (($s->{'bless'} = $v), return $s) : $s->{'bless'};
 534 }
 535
 536 sub Maxdepth {
 537   my($s, $v) = @_;
 538   defined($v) ? (($s->{'maxdepth'} = $v), return $s) : $s->{'maxdepth'};
 539 }
 540
 541
 542 # used by qquote below
 543 my %esc = (
 544     "\a" => "\\a",
 545     "\b" => "\\b",
 546     "\t" => "\\t",
 547     "\n" => "\\n",
 548     "\f" => "\\f",
 549     "\r" => "\\r",
 550     "\e" => "\\e",
 551 );
 552
 553 # put a string value in double quotes
 554 sub qquote {
 555   local($_) = shift;
 556   s/([\\\"\@\$])/\\$1/g;
 557   return qq("$_") unless
 558     /[^ !"\#\$%&'()*+,\-.\/0-9:;<=>?\@A-Z[\\\]^_`a-z{|}~]/;  # fast exit
 559
 560   my $high = shift || "";
 561   s/([\a\b\t\n\f\r\e])/$esc{$1}/g;
 562
 563   if (ord('^')==94)  { # ascii
 564     # no need for 3 digits in escape for these
 565     s/([\0-\037])(?!\d)/'\\'.sprintf('%o',ord($1))/eg;
 566     s/([\0-\037\177])/'\\'.sprintf('%03o',ord($1))/eg;
 567     # all but last branch below not supported --BEHAVIOR SUBJECT TO CHANGE--
 568     if ($high eq "iso8859") {
 569       s/([\200-\240])/'\\'.sprintf('%o',ord($1))/eg;
 570     } elsif ($high eq "utf8") {
 571 #     use utf8;
 572 #     $str =~ s/([^\040-\176])/sprintf "\\x{%04x}", ord($1)/ge;
 573     } elsif ($high eq "8bit") {
 574         # leave it as it is
 575     } else {
 576       s/([\200-\377])/'\\'.sprintf('%03o',ord($1))/eg;
 577     }
 578   }
 579   else { # ebcdic
 580       s{([^ !"\#\$%&'()*+,\-.\/0-9:;<=>?\@A-Z[\\\]^_`a-z{|}~])(?!\d)}
 581        {my $v = ord($1); '\\'.sprintf(($v <= 037 ? '%o' : '%03o'), $v)}eg;
 582       s{([^ !"\#\$%&'()*+,\-.\/0-9:;<=>?\@A-Z[\\\]^_`a-z{|}~])}
 583        {'\\'.sprintf('%03o',ord($1))}eg;
 584   }
 585
 586   return qq("$_");
 587 }
 588
 589 1;
 590 __END__
 591
 592 =head1 NAME
 593
 594 Data::Dumper - stringified perl data structures, suitable for both printing and C<eval>
 595
 596
 597 =head1 SYNOPSIS
 598
 599     use Data::Dumper;
 600
 601     # simple procedural interface
 602     print Dumper($foo, $bar);
 603
 604     # extended usage with names
 605     print Data::Dumper->Dump([$foo, $bar], [qw(foo *ary)]);
 606
 607     # configuration variables
 608     {
 609       local $Data::Dump::Purity = 1;
 610       eval Data::Dumper->Dump([$foo, $bar], [qw(foo *ary)]);
 611     }
 612
 613     # OO usage
 614     $d = Data::Dumper->new([$foo, $bar], [qw(foo *ary)]);
 615        ...
 616     print $d->Dump;
 617        ...
 618     $d->Purity(1)->Terse(1)->Deepcopy(1);
 619     eval $d->Dump;
 620
 621
 622 =head1 DESCRIPTION
 623
 624 Given a list of scalars or reference variables, writes out their contents in
 625 perl syntax. The references can also be objects.  The contents of each
 626 variable is output in a single Perl statement.  Handles self-referential
 627 structures correctly.
 628
 629 The return value can be C<eval>ed to get back an identical copy of the
 630 original reference structure.
 631
 632 Any references that are the same as one of those passed in will be named
 633 C<$VAR>I<n> (where I<n> is a numeric suffix), and other duplicate references
 634 to substructures within C<$VAR>I<n> will be appropriately labeled using arrow
 635 notation.  You can specify names for individual values to be dumped if you
 636 use the C<Dump()> method, or you can change the default C<$VAR> prefix to
 637 something else.  See C<$Data::Dumper::Varname> and C<$Data::Dumper::Terse>
 638 below.
 639
 640 The default output of self-referential structures can be C<eval>ed, but the
 641 nested references to C<$VAR>I<n> will be undefined, since a recursive
 642 structure cannot be constructed using one Perl statement.  You should set the
 643 C<Purity> flag to 1 to get additional statements that will correctly fill in
 644 these references.
 645
 646 In the extended usage form, the references to be dumped can be given
 647 user-specified names.  If a name begins with a C<*>, the output will
 648 describe the dereferenced type of the supplied reference for hashes and
 649 arrays, and coderefs.  Output of names will be avoided where possible if
 650 the C<Terse> flag is set.
 651
 652 In many cases, methods that are used to set the internal state of the
 653 object will return the object itself, so method calls can be conveniently
 654 chained together.
 655
 656 Several styles of output are possible, all controlled by setting
 657 the C<Indent> flag.  See L<Configuration Variables or Methods> below
 658 for details.
 659
 660
 661 =head2 Methods
 662
 663 =over 4
 664
 665 =item I<PACKAGE>->new(I<ARRAYREF [>, I<ARRAYREF]>)
 666
 667 Returns a newly created C<Data::Dumper> object.  The first argument is an
 668 anonymous array of values to be dumped.  The optional second argument is an
 669 anonymous array of names for the values.  The names need not have a leading
 670 C<$> sign, and must be comprised of alphanumeric characters.  You can begin
 671 a name with a C<*> to specify that the dereferenced type must be dumped
 672 instead of the reference itself, for ARRAY and HASH references.
 673
 674 The prefix specified by C<$Data::Dumper::Varname> will be used with a
 675 numeric suffix if the name for a value is undefined.
 676
 677 Data::Dumper will catalog all references encountered while dumping the
 678 values. Cross-references (in the form of names of substructures in perl
 679 syntax) will be inserted at all possible points, preserving any structural
 680 interdependencies in the original set of values.  Structure traversal is
 681 depth-first,  and proceeds in order from the first supplied value to
 682 the last.
 683
 684 =item I<$OBJ>->Dump  I<or>  I<PACKAGE>->Dump(I<ARRAYREF [>, I<ARRAYREF]>)
 685
 686 Returns the stringified form of the values stored in the object (preserving
 687 the order in which they were supplied to C<new>), subject to the
 688 configuration options below.  In a list context, it returns a list
 689 of strings corresponding to the supplied values.
 690
 691 The second form, for convenience, simply calls the C<new> method on its
 692 arguments before dumping the object immediately.
 693
 694 =item I<$OBJ>->Seen(I<[HASHREF]>)
 695
 696 Queries or adds to the internal table of already encountered references.
 697 You must use C<Reset> to explicitly clear the table if needed.  Such
 698 references are not dumped; instead, their names are inserted wherever they
 699 are encountered subsequently.  This is useful especially for properly
 700 dumping subroutine references.
 701
 702 Expects a anonymous hash of name => value pairs.  Same rules apply for names
 703 as in C<new>.  If no argument is supplied, will return the "seen" list of
 704 name => value pairs, in a list context.  Otherwise, returns the object
 705 itself.
 706
 707 =item I<$OBJ>->Values(I<[ARRAYREF]>)
 708
 709 Queries or replaces the internal array of values that will be dumped.
 710 When called without arguments, returns the values.  Otherwise, returns the
 711 object itself.
 712
 713 =item I<$OBJ>->Names(I<[ARRAYREF]>)
 714
 715 Queries or replaces the internal array of user supplied names for the values
 716 that will be dumped.  When called without arguments, returns the names.
 717 Otherwise, returns the object itself.
 718
 719 =item I<$OBJ>->Reset
 720
 721 Clears the internal table of "seen" references and returns the object
 722 itself.
 723
 724 =back
 725
 726 =head2 Functions
 727
 728 =over 4
 729
 730 =item Dumper(I<LIST>)
 731
 732 Returns the stringified form of the values in the list, subject to the
 733 configuration options below.  The values will be named C<$VAR>I<n> in the
 734 output, where I<n> is a numeric suffix.  Will return a list of strings
 735 in a list context.
 736
 737 =back
 738
 739 =head2 Configuration Variables or Methods
 740
 741 Several configuration variables can be used to control the kind of output
 742 generated when using the procedural interface.  These variables are usually
 743 C<local>ized in a block so that other parts of the code are not affected by
 744 the change.
 745
 746 These variables determine the default state of the object created by calling
 747 the C<new> method, but cannot be used to alter the state of the object
 748 thereafter.  The equivalent method names should be used instead to query
 749 or set the internal state of the object.
 750
 751 The method forms return the object itself when called with arguments,
 752 so that they can be chained together nicely.
 753
 754 =over 4
 755
 756 =item $Data::Dumper::Indent  I<or>  I<$OBJ>->Indent(I<[NEWVAL]>)
 757
 758 Controls the style of indentation.  It can be set to 0, 1, 2 or 3.  Style 0
 759 spews output without any newlines, indentation, or spaces between list
 760 items.  It is the most compact format possible that can still be called
 761 valid perl.  Style 1 outputs a readable form with newlines but no fancy
 762 indentation (each level in the structure is simply indented by a fixed
 763 amount of whitespace).  Style 2 (the default) outputs a very readable form
 764 which takes into account the length of hash keys (so the hash value lines
 765 up).  Style 3 is like style 2, but also annotates the elements of arrays
 766 with their index (but the comment is on its own line, so array output
 767 consumes twice the number of lines).  Style 2 is the default.
 768
 769 =item $Data::Dumper::Purity  I<or>  I<$OBJ>->Purity(I<[NEWVAL]>)
 770
 771 Controls the degree to which the output can be C<eval>ed to recreate the
 772 supplied reference structures.  Setting it to 1 will output additional perl
 773 statements that will correctly recreate nested references.  The default is
 774 0.
 775
 776 =item $Data::Dumper::Pad  I<or>  I<$OBJ>->Pad(I<[NEWVAL]>)
 777
 778 Specifies the string that will be prefixed to every line of the output.
 779 Empty string by default.
 780
 781 =item $Data::Dumper::Varname  I<or>  I<$OBJ>->Varname(I<[NEWVAL]>)
 782
 783 Contains the prefix to use for tagging variable names in the output. The
 784 default is "VAR".
 785
 786 =item $Data::Dumper::Useqq  I<or>  I<$OBJ>->Useqq(I<[NEWVAL]>)
 787
 788 When set, enables the use of double quotes for representing string values.
 789 Whitespace other than space will be represented as C<[\n\t\r]>, "unsafe"
 790 characters will be backslashed, and unprintable characters will be output as
 791 quoted octal integers.  Since setting this variable imposes a performance
 792 penalty, the default is 0.  C<Dump()> will run slower if this flag is set,
 793 since the fast XSUB implementation doesn't support it yet.
 794
 795 =item $Data::Dumper::Terse  I<or>  I<$OBJ>->Terse(I<[NEWVAL]>)
 796
 797 When set, Data::Dumper will emit single, non-self-referential values as
 798 atoms/terms rather than statements.  This means that the C<$VAR>I<n> names
 799 will be avoided where possible, but be advised that such output may not
 800 always be parseable by C<eval>.
 801
 802 =item $Data::Dumper::Freezer  I<or>  $I<OBJ>->Freezer(I<[NEWVAL]>)
 803
 804 Can be set to a method name, or to an empty string to disable the feature.
 805 Data::Dumper will invoke that method via the object before attempting to
 806 stringify it.  This method can alter the contents of the object (if, for
 807 instance, it contains data allocated from C), and even rebless it in a
 808 different package.  The client is responsible for making sure the specified
 809 method can be called via the object, and that the object ends up containing
 810 only perl data types after the method has been called.  Defaults to an empty
 811 string.
 812
 813 =item $Data::Dumper::Toaster  I<or>  $I<OBJ>->Toaster(I<[NEWVAL]>)
 814
 815 Can be set to a method name, or to an empty string to disable the feature.
 816 Data::Dumper will emit a method call for any objects that are to be dumped
 817 using the syntax C<bless(DATA, CLASS)->METHOD()>.  Note that this means that
 818 the method specified will have to perform any modifications required on the
 819 object (like creating new state within it, and/or reblessing it in a
 820 different package) and then return it.  The client is responsible for making
 821 sure the method can be called via the object, and that it returns a valid
 822 object.  Defaults to an empty string.
 823
 824 =item $Data::Dumper::Deepcopy  I<or>  $I<OBJ>->Deepcopy(I<[NEWVAL]>)
 825
 826 Can be set to a boolean value to enable deep copies of structures.
 827 Cross-referencing will then only be done when absolutely essential
 828 (i.e., to break reference cycles).  Default is 0.
 829
 830 =item $Data::Dumper::Quotekeys  I<or>  $I<OBJ>->Quotekeys(I<[NEWVAL]>)
 831
 832 Can be set to a boolean value to control whether hash keys are quoted.
 833 A false value will avoid quoting hash keys when it looks like a simple
 834 string.  Default is 1, which will always enclose hash keys in quotes.
 835
 836 =item $Data::Dumper::Bless  I<or>  $I<OBJ>->Bless(I<[NEWVAL]>)
 837
 838 Can be set to a string that specifies an alternative to the C<bless>
 839 builtin operator used to create objects.  A function with the specified
 840 name should exist, and should accept the same arguments as the builtin.
 841 Default is C<bless>.
 842
 843 =item $Data::Dumper::Maxdepth  I<or>  $I<OBJ>->Maxdepth(I<[NEWVAL]>)
 844
 845 Can be set to a positive integer that specifies the depth beyond which
 846 which we don't venture into a structure.  Has no effect when
 847 C<Data::Dumper::Purity> is set.  (Useful in debugger when we often don't
 848 want to see more than enough).  Default is 0, which means there is
 849 no maximum depth.
 850
 851 =back
 852
 853 =head2 Exports
 854
 855 =over 4
 856
 857 =item Dumper
 858
 859 =back
 860
 861 =head1 EXAMPLES
 862
 863 Run these code snippets to get a quick feel for the behavior of this
 864 module.  When you are through with these examples, you may want to
 865 add or change the various configuration variables described above,
 866 to see their behavior.  (See the testsuite in the Data::Dumper
 867 distribution for more examples.)
 868
 869
 870     use Data::Dumper;
 871
 872     package Foo;
 873     sub new {bless {'a' => 1, 'b' => sub { return "foo" }}, $_[0]};
 874
 875     package Fuz;                       # a weird REF-REF-SCALAR object
 876     sub new {bless \($_ = \ 'fu\'z'), $_[0]};
 877
 878     package main;
 879     $foo = Foo->new;
 880     $fuz = Fuz->new;
 881     $boo = [ 1, [], "abcd", \*foo,
 882              {1 => 'a', 023 => 'b', 0x45 => 'c'},
 883              \\"p\q\'r", $foo, $fuz];
 884
 885     ########
 886     # simple usage
 887     ########
 888
 889     $bar = eval(Dumper($boo));
 890     print($@) if $@;
 891     print Dumper($boo), Dumper($bar);  # pretty print (no array indices)
 892
 893     $Data::Dumper::Terse = 1;          # don't output names where feasible
 894     $Data::Dumper::Indent = 0;         # turn off all pretty print
 895     print Dumper($boo), "\n";
 896
 897     $Data::Dumper::Indent = 1;         # mild pretty print
 898     print Dumper($boo);
 899
 900     $Data::Dumper::Indent = 3;         # pretty print with array indices
 901     print Dumper($boo);
 902
 903     $Data::Dumper::Useqq = 1;          # print strings in double quotes
 904     print Dumper($boo);
 905
 906
 907     ########
 908     # recursive structures
 909     ########
 910
 911     @c = ('c');
 912     $c = \@c;
 913     $b = {};
 914     $a = [1, $b, $c];
 915     $b->{a} = $a;
 916     $b->{b} = $a->[1];
 917     $b->{c} = $a->[2];
 918     print Data::Dumper->Dump([$a,$b,$c], [qw(a b c)]);
 919
 920
 921     $Data::Dumper::Purity = 1;         # fill in the holes for eval
 922     print Data::Dumper->Dump([$a, $b], [qw(*a b)]); # print as @a
 923     print Data::Dumper->Dump([$b, $a], [qw(*b a)]); # print as %b
 924
 925
 926     $Data::Dumper::Deepcopy = 1;       # avoid cross-refs
 927     print Data::Dumper->Dump([$b, $a], [qw(*b a)]);
 928
 929
 930     $Data::Dumper::Purity = 0;         # avoid cross-refs
 931     print Data::Dumper->Dump([$b, $a], [qw(*b a)]);
 932
 933     ########
 934     # deep structures
 935     ########
 936
 937     $a = "pearl";
 938     $b = [ $a ];
 939     $c = { 'b' => $b };
 940     $d = [ $c ];
 941     $e = { 'd' => $d };
 942     $f = { 'e' => $e };
 943     print Data::Dumper->Dump([$f], [qw(f)]);
 944
 945     $Data::Dumper::Maxdepth = 3;       # no deeper than 3 refs down
 946     print Data::Dumper->Dump([$f], [qw(f)]);
 947
 948
 949     ########
 950     # object-oriented usage
 951     ########
 952
 953     $d = Data::Dumper->new([$a,$b], [qw(a b)]);
 954     $d->Seen({'*c' => $c});            # stash a ref without printing it
 955     $d->Indent(3);
 956     print $d->Dump;
 957     $d->Reset->Purity(0);              # empty the seen cache
 958     print join "----\n", $d->Dump;
 959
 960
 961     ########
 962     # persistence
 963     ########
 964
 965     package Foo;
 966     sub new { bless { state => 'awake' }, shift }
 967     sub Freeze {
 968         my $s = shift;
 969         print STDERR "preparing to sleep\n";
 970         $s->{state} = 'asleep';
 971         return bless $s, 'Foo::ZZZ';
 972     }
 973
 974     package Foo::ZZZ;
 975     sub Thaw {
 976         my $s = shift;
 977         print STDERR "waking up\n";
 978         $s->{state} = 'awake';
 979         return bless $s, 'Foo';
 980     }
 981
 982     package Foo;
 983     use Data::Dumper;
 984     $a = Foo->new;
 985     $b = Data::Dumper->new([$a], ['c']);
 986     $b->Freezer('Freeze');
 987     $b->Toaster('Thaw');
 988     $c = $b->Dump;
 989     print $c;
 990     $d = eval $c;
 991     print Data::Dumper->Dump([$d], ['d']);
 992
 993
 994     ########
 995     # symbol substitution (useful for recreating CODE refs)
 996     ########
 997
 998     sub foo { print "foo speaking\n" }
 999     *other = \&foo;
1000     $bar = [ \&other ];
1001     $d = Data::Dumper->new([\&other,$bar],['*other','bar']);
1002     $d->Seen({ '*foo' => \&foo });
1003     print $d->Dump;
1004
1005
1006 =head1 BUGS
1007
1008 Due to limitations of Perl subroutine call semantics, you cannot pass an
1009 array or hash.  Prepend it with a C<\> to pass its reference instead.  This
1010 will be remedied in time, with the arrival of prototypes in later versions
1011 of Perl.  For now, you need to use the extended usage form, and prepend the
1012 name with a C<*> to output it as a hash or array.
1013
1014 C<Data::Dumper> cheats with CODE references.  If a code reference is
1015 encountered in the structure being processed, an anonymous subroutine that
1016 contains the string '"DUMMY"' will be inserted in its place, and a warning
1017 will be printed if C<Purity> is set.  You can C<eval> the result, but bear
1018 in mind that the anonymous sub that gets created is just a placeholder.
1019 Someday, perl will have a switch to cache-on-demand the string
1020 representation of a compiled piece of code, I hope.  If you have prior
1021 knowledge of all the code refs that your data structures are likely
1022 to have, you can use the C<Seen> method to pre-seed the internal reference
1023 table and make the dumped output point to them, instead.  See L<EXAMPLES>
1024 above.
1025
1026 The C<Useqq> flag makes Dump() run slower, since the XSUB implementation
1027 does not support it.
1028
1029 SCALAR objects have the weirdest looking C<bless> workaround.
1030
1031
1032 =head1 AUTHOR
1033
1034 Gurusamy Sarathy        gsar@activestate.com
1035
1036 Copyright (c) 1996-98 Gurusamy Sarathy. All rights reserved.
1037 This program is free software; you can redistribute it and/or
1038 modify it under the same terms as Perl itself.
1039
1040
1041 =head1 VERSION
1042
1043 Version 2.11   (unreleased)
1044
1045 =head1 SEE ALSO
1046
1047 perl(1)
1048
1049 =cut