ext/Data/Dumper/Dumper.pm

   1 #
   2 # Data/Dumper.pm
   3 #
   4 # convert perl data structures into perl syntax suitable for both printing
   5 # and eval
   6 #
   7 # Documentation at the __END__
   8 #
   9
  10 package Data::Dumper;
  11
  12 $VERSION = '2.12';
  13
  14 #$| = 1;
  15
  16 use 5.006_001;
  17 require Exporter;
  18 use XSLoader ();
  19 require overload;
  20
  21 use Carp;
  22
  23 @ISA = qw(Exporter);
  24 @EXPORT = qw(Dumper);
  25 @EXPORT_OK = qw(DumperX);
  26
  27 XSLoader::load 'Data::Dumper';
  28
  29 # module vars and their defaults
  30 $Indent = 2 unless defined $Indent;
  31 $Purity = 0 unless defined $Purity;
  32 $Pad = "" unless defined $Pad;
  33 $Varname = "VAR" unless defined $Varname;
  34 $Useqq = 0 unless defined $Useqq;
  35 $Terse = 0 unless defined $Terse;
  36 $Freezer = "" unless defined $Freezer;
  37 $Toaster = "" unless defined $Toaster;
  38 $Deepcopy = 0 unless defined $Deepcopy;
  39 $Quotekeys = 1 unless defined $Quotekeys;
  40 $Bless = "bless" unless defined $Bless;
  41 #$Expdepth = 0 unless defined $Expdepth;
  42 $Maxdepth = 0 unless defined $Maxdepth;
  43 $Pair = ' => ' unless defined $Pair;
  44 $Useperl = 0 unless defined $Useperl;
  45 $Sortkeys = 0 unless defined $Sortkeys;
  46 $Deparse = 0 unless defined $Deparse;
  47
  48 #
  49 # expects an arrayref of values to be dumped.
  50 # can optionally pass an arrayref of names for the values.
  51 # names must have leading $ sign stripped. begin the name with *
  52 # to cause output of arrays and hashes rather than refs.
  53 #
  54 sub new {
  55   my($c, $v, $n) = @_;
  56
  57   croak "Usage:  PACKAGE->new(ARRAYREF, [ARRAYREF])"
  58     unless (defined($v) && (ref($v) eq 'ARRAY'));
  59   $n = [] unless (defined($n) && (ref($v) eq 'ARRAY'));
  60
  61   my($s) = {
  62              level      => 0,           # current recursive depth
  63              indent     => $Indent,     # various styles of indenting
  64              pad        => $Pad,        # all lines prefixed by this string
  65              xpad       => "",          # padding-per-level
  66              apad       => "",          # added padding for hash keys n such
  67              sep        => "",          # list separator
  68              pair       => $Pair,       # hash key/value separator: defaults to ' => '
  69              seen       => {},          # local (nested) refs (id => [name, val])
  70              todump     => $v,          # values to dump []
  71              names      => $n,          # optional names for values []
  72              varname    => $Varname,    # prefix to use for tagging nameless ones
  73              purity     => $Purity,     # degree to which output is evalable
  74              useqq      => $Useqq,      # use "" for strings (backslashitis ensues)
  75              terse      => $Terse,      # avoid name output (where feasible)
  76              freezer    => $Freezer,    # name of Freezer method for objects
  77              toaster    => $Toaster,    # name of method to revive objects
  78              deepcopy   => $Deepcopy,   # dont cross-ref, except to stop recursion
  79              quotekeys  => $Quotekeys,  # quote hash keys
  80              'bless'    => $Bless,      # keyword to use for "bless"
  81 #            expdepth   => $Expdepth,   # cutoff depth for explicit dumping
  82              maxdepth   => $Maxdepth,   # depth beyond which we give up
  83              useperl    => $Useperl,    # use the pure Perl implementation
  84              sortkeys   => $Sortkeys,   # flag or filter for sorting hash keys
  85              deparse    => $Deparse,    # use B::Deparse for coderefs
  86            };
  87
  88   if ($Indent > 0) {
  89     $s->{xpad} = "  ";
  90     $s->{sep} = "\n";
  91   }
  92   return bless($s, $c);
  93 }
  94
  95 #
  96 # add-to or query the table of already seen references
  97 #
  98 sub Seen {
  99   my($s, $g) = @_;
 100   if (defined($g) && (ref($g) eq 'HASH'))  {
 101     my($k, $v, $id);
 102     while (($k, $v) = each %$g) {
 103       if (defined $v and ref $v) {
 104         ($id) = (overload::StrVal($v) =~ /\((.*)\)$/);
 105         if ($k =~ /^[*](.*)$/) {
 106           $k = (ref $v eq 'ARRAY') ? ( "\\\@" . $1 ) :
 107                (ref $v eq 'HASH')  ? ( "\\\%" . $1 ) :
 108                (ref $v eq 'CODE')  ? ( "\\\&" . $1 ) :
 109                                      (   "\$" . $1 ) ;
 110         }
 111         elsif ($k !~ /^\$/) {
 112           $k = "\$" . $k;
 113         }
 114         $s->{seen}{$id} = [$k, $v];
 115       }
 116       else {
 117         carp "Only refs supported, ignoring non-ref item \$$k";
 118       }
 119     }
 120     return $s;
 121   }
 122   else {
 123     return map { @$_ } values %{$s->{seen}};
 124   }
 125 }
 126
 127 #
 128 # set or query the values to be dumped
 129 #
 130 sub Values {
 131   my($s, $v) = @_;
 132   if (defined($v) && (ref($v) eq 'ARRAY'))  {
 133     $s->{todump} = [@$v];        # make a copy
 134     return $s;
 135   }
 136   else {
 137     return @{$s->{todump}};
 138   }
 139 }
 140
 141 #
 142 # set or query the names of the values to be dumped
 143 #
 144 sub Names {
 145   my($s, $n) = @_;
 146   if (defined($n) && (ref($n) eq 'ARRAY'))  {
 147     $s->{names} = [@$n];         # make a copy
 148     return $s;
 149   }
 150   else {
 151     return @{$s->{names}};
 152   }
 153 }
 154
 155 sub DESTROY {}
 156
 157 sub Dump {
 158     return &Dumpxs
 159         unless $Data::Dumper::Useperl || (ref($_[0]) && $_[0]->{useperl}) ||
 160                $Data::Dumper::Useqq   || (ref($_[0]) && $_[0]->{useqq}) ||
 161                $Data::Dumper::Deparse || (ref($_[0]) && $_[0]->{deparse});
 162     return &Dumpperl;
 163 }
 164
 165 #
 166 # dump the refs in the current dumper object.
 167 # expects same args as new() if called via package name.
 168 #
 169 sub Dumpperl {
 170   my($s) = shift;
 171   my(@out, $val, $name);
 172   my($i) = 0;
 173   local(@post);
 174
 175   $s = $s->new(@_) unless ref $s;
 176
 177   for $val (@{$s->{todump}}) {
 178     my $out = "";
 179     @post = ();
 180     $name = $s->{names}[$i++];
 181     if (defined $name) {
 182       if ($name =~ /^[*](.*)$/) {
 183         if (defined $val) {
 184           $name = (ref $val eq 'ARRAY') ? ( "\@" . $1 ) :
 185                   (ref $val eq 'HASH')  ? ( "\%" . $1 ) :
 186                   (ref $val eq 'CODE')  ? ( "\*" . $1 ) :
 187                                           ( "\$" . $1 ) ;
 188         }
 189         else {
 190           $name = "\$" . $1;
 191         }
 192       }
 193       elsif ($name !~ /^\$/) {
 194         $name = "\$" . $name;
 195       }
 196     }
 197     else {
 198       $name = "\$" . $s->{varname} . $i;
 199     }
 200
 201     my $valstr;
 202     {
 203       local($s->{apad}) = $s->{apad};
 204       $s->{apad} .= ' ' x (length($name) + 3) if $s->{indent} >= 2;
 205       $valstr = $s->_dump($val, $name);
 206     }
 207
 208     $valstr = "$name = " . $valstr . ';' if @post or !$s->{terse};
 209     $out .= $s->{pad} . $valstr . $s->{sep};
 210     $out .= $s->{pad} . join(';' . $s->{sep} . $s->{pad}, @post)
 211       . ';' . $s->{sep} if @post;
 212
 213     push @out, $out;
 214   }
 215   return wantarray ? @out : join('', @out);
 216 }
 217
 218 #
 219 # twist, toil and turn;
 220 # and recurse, of course.
 221 # sometimes sordidly;
 222 # and curse if no recourse.
 223 #
 224 sub _dump {
 225   my($s, $val, $name) = @_;
 226   my($sname);
 227   my($out, $realpack, $realtype, $type, $ipad, $id, $blesspad);
 228
 229   $type = ref $val;
 230   $out = "";
 231
 232   if ($type) {
 233
 234     # prep it, if it looks like an object
 235     if (my $freezer = $s->{freezer}) {
 236       $val->$freezer() if UNIVERSAL::can($val, $freezer);
 237     }
 238
 239     ($realpack, $realtype, $id) =
 240       (overload::StrVal($val) =~ /^(?:(.*)\=)?([^=]*)\(([^\(]*)\)$/);
 241
 242     # if it has a name, we need to either look it up, or keep a tab
 243     # on it so we know when we hit it later
 244     if (defined($name) and length($name)) {
 245       # keep a tab on it so that we dont fall into recursive pit
 246       if (exists $s->{seen}{$id}) {
 247 #       if ($s->{expdepth} < $s->{level}) {
 248           if ($s->{purity} and $s->{level} > 0) {
 249             $out = ($realtype eq 'HASH')  ? '{}' :
 250               ($realtype eq 'ARRAY') ? '[]' :
 251                 'do{my $o}' ;
 252             push @post, $name . " = " . $s->{seen}{$id}[0];
 253           }
 254           else {
 255             $out = $s->{seen}{$id}[0];
 256             if ($name =~ /^([\@\%])/) {
 257               my $start = $1;
 258               if ($out =~ /^\\$start/) {
 259                 $out = substr($out, 1);
 260               }
 261               else {
 262                 $out = $start . '{' . $out . '}';
 263               }
 264             }
 265           }
 266           return $out;
 267 #        }
 268       }
 269       else {
 270         # store our name
 271         $s->{seen}{$id} = [ (($name =~ /^[@%]/)     ? ('\\' . $name ) :
 272                              ($realtype eq 'CODE' and
 273                               $name =~ /^[*](.*)$/) ? ('\\&' . $1 )   :
 274                              $name          ),
 275                             $val ];
 276       }
 277     }
 278
 279     if ($realpack and $realpack eq 'Regexp') {
 280         $out = "$val";
 281         $out =~ s,/,\\/,g;
 282         return "qr/$out/";
 283     }
 284
 285     # If purity is not set and maxdepth is set, then check depth:
 286     # if we have reached maximum depth, return the string
 287     # representation of the thing we are currently examining
 288     # at this depth (i.e., 'Foo=ARRAY(0xdeadbeef)').
 289     if (!$s->{purity}
 290         and $s->{maxdepth} > 0
 291         and $s->{level} >= $s->{maxdepth})
 292     {
 293       return qq['$val'];
 294     }
 295
 296     # we have a blessed ref
 297     if ($realpack) {
 298       $out = $s->{'bless'} . '( ';
 299       $blesspad = $s->{apad};
 300       $s->{apad} .= '       ' if ($s->{indent} >= 2);
 301     }
 302
 303     $s->{level}++;
 304     $ipad = $s->{xpad} x $s->{level};
 305
 306     if ($realtype eq 'SCALAR' || $realtype eq 'REF') {
 307       if ($realpack) {
 308         $out .= 'do{\\(my $o = ' . $s->_dump($$val, "\${$name}") . ')}';
 309       }
 310       else {
 311         $out .= '\\' . $s->_dump($$val, "\${$name}");
 312       }
 313     }
 314     elsif ($realtype eq 'GLOB') {
 315         $out .= '\\' . $s->_dump($$val, "*{$name}");
 316     }
 317     elsif ($realtype eq 'ARRAY') {
 318       my($v, $pad, $mname);
 319       my($i) = 0;
 320       $out .= ($name =~ /^\@/) ? '(' : '[';
 321       $pad = $s->{sep} . $s->{pad} . $s->{apad};
 322       ($name =~ /^\@(.*)$/) ? ($mname = "\$" . $1) :
 323         # omit -> if $foo->[0]->{bar}, but not ${$foo->[0]}->{bar}
 324         ($name =~ /^\\?[\%\@\*\$][^{].*[]}]$/) ? ($mname = $name) :
 325           ($mname = $name . '->');
 326       $mname .= '->' if $mname =~ /^\*.+\{[A-Z]+\}$/;
 327       for $v (@$val) {
 328         $sname = $mname . '[' . $i . ']';
 329         $out .= $pad . $ipad . '#' . $i if $s->{indent} >= 3;
 330         $out .= $pad . $ipad . $s->_dump($v, $sname);
 331         $out .= "," if $i++ < $#$val;
 332       }
 333       $out .= $pad . ($s->{xpad} x ($s->{level} - 1)) if $i;
 334       $out .= ($name =~ /^\@/) ? ')' : ']';
 335     }
 336     elsif ($realtype eq 'HASH') {
 337       my($k, $v, $pad, $lpad, $mname, $pair);
 338       $out .= ($name =~ /^\%/) ? '(' : '{';
 339       $pad = $s->{sep} . $s->{pad} . $s->{apad};
 340       $lpad = $s->{apad};
 341       $pair = $s->{pair};
 342       ($name =~ /^\%(.*)$/) ? ($mname = "\$" . $1) :
 343         # omit -> if $foo->[0]->{bar}, but not ${$foo->[0]}->{bar}
 344         ($name =~ /^\\?[\%\@\*\$][^{].*[]}]$/) ? ($mname = $name) :
 345           ($mname = $name . '->');
 346       $mname .= '->' if $mname =~ /^\*.+\{[A-Z]+\}$/;
 347       my ($sortkeys, $keys, $key) = ("$s->{sortkeys}");
 348       if ($sortkeys) {
 349         if (ref($s->{sortkeys}) eq 'CODE') {
 350           $keys = $s->{sortkeys}($val);
 351           unless (ref($keys) eq 'ARRAY') {
 352             carp "Sortkeys subroutine did not return ARRAYREF";
 353             $keys = [];
 354           }
 355         }
 356         else {
 357           $keys = [ sort keys %$val ];
 358         }
 359       }
 360       while (($k, $v) = ! $sortkeys ? (each %$val) :
 361              @$keys ? ($key = shift(@$keys), $val->{$key}) :
 362              () )
 363       {
 364         my $nk = $s->_dump($k, "");
 365         $nk = $1 if !$s->{quotekeys} and $nk =~ /^[\"\']([A-Za-z_]\w*)[\"\']$/;
 366         $sname = $mname . '{' . $nk . '}';
 367         $out .= $pad . $ipad . $nk . $pair;
 368
 369         # temporarily alter apad
 370         $s->{apad} .= (" " x (length($nk) + 4)) if $s->{indent} >= 2;
 371         $out .= $s->_dump($val->{$k}, $sname) . ",";
 372         $s->{apad} = $lpad if $s->{indent} >= 2;
 373       }
 374       if (substr($out, -1) eq ',') {
 375         chop $out;
 376         $out .= $pad . ($s->{xpad} x ($s->{level} - 1));
 377       }
 378       $out .= ($name =~ /^\%/) ? ')' : '}';
 379     }
 380     elsif ($realtype eq 'CODE') {
 381       if ($s->{deparse}) {
 382         require B::Deparse;
 383         my $sub =  'sub ' . (B::Deparse->new)->coderef2text($val);
 384         $pad    =  $s->{sep} . $s->{pad} . $s->{xpad} . $s->{apad} . '    ';
 385         $sub    =~ s/\n/$pad/gse;
 386         $out   .=  $sub;
 387       } else {
 388         $out .= 'sub { "DUMMY" }';
 389         carp "Encountered CODE ref, using dummy placeholder" if $s->{purity};
 390       }
 391     }
 392     else {
 393       croak "Can\'t handle $realtype type.";
 394     }
 395
 396     if ($realpack) { # we have a blessed ref
 397       $out .= ', \'' . $realpack . '\'' . ' )';
 398       $out .= '->' . $s->{toaster} . '()'  if $s->{toaster} ne '';
 399       $s->{apad} = $blesspad;
 400     }
 401     $s->{level}--;
 402
 403   }
 404   else {                                 # simple scalar
 405
 406     my $ref = \$_[1];
 407     # first, catalog the scalar
 408     if ($name ne '') {
 409       ($id) = ("$ref" =~ /\(([^\(]*)\)$/);
 410       if (exists $s->{seen}{$id}) {
 411         if ($s->{seen}{$id}[2]) {
 412           $out = $s->{seen}{$id}[0];
 413           #warn "[<$out]\n";
 414           return "\${$out}";
 415         }
 416       }
 417       else {
 418         #warn "[>\\$name]\n";
 419         $s->{seen}{$id} = ["\\$name", $ref];
 420       }
 421     }
 422     if (ref($ref) eq 'GLOB' or "$ref" =~ /=GLOB\([^()]+\)$/) {  # glob
 423       my $name = substr($val, 1);
 424       if ($name =~ /^[A-Za-z_][\w:]*$/) {
 425         $name =~ s/^main::/::/;
 426         $sname = $name;
 427       }
 428       else {
 429         $sname = $s->_dump($name, "");
 430         $sname = '{' . $sname . '}';
 431       }
 432       if ($s->{purity}) {
 433         my $k;
 434         local ($s->{level}) = 0;
 435         for $k (qw(SCALAR ARRAY HASH)) {
 436           my $gval = *$val{$k};
 437           next unless defined $gval;
 438           next if $k eq "SCALAR" && ! defined $$gval;  # always there
 439
 440           # _dump can push into @post, so we hold our place using $postlen
 441           my $postlen = scalar @post;
 442           $post[$postlen] = "\*$sname = ";
 443           local ($s->{apad}) = " " x length($post[$postlen]) if $s->{indent} >= 2;
 444           $post[$postlen] .= $s->_dump($gval, "\*$sname\{$k\}");
 445         }
 446       }
 447       $out .= '*' . $sname;
 448     }
 449     elsif (!defined($val)) {
 450       $out .= "undef";
 451     }
 452     elsif ($val =~ /^(?:0|-?[1-9]\d{0,8})\z/) { # safe decimal number
 453       $out .= $val;
 454     }
 455     else {                               # string
 456       if ($s->{useqq} or $val =~ tr/\0-\377//c) {
 457         # Fall back to qq if there's unicode
 458         $out .= qquote($val, $s->{useqq});
 459       }
 460       else {
 461         $val =~ s/([\\\'])/\\$1/g;
 462         $out .= '\'' . $val .  '\'';
 463       }
 464     }
 465   }
 466   if ($id) {
 467     # if we made it this far, $id was added to seen list at current
 468     # level, so remove it to get deep copies
 469     if ($s->{deepcopy}) {
 470       delete($s->{seen}{$id});
 471     }
 472     elsif ($name) {
 473       $s->{seen}{$id}[2] = 1;
 474     }
 475   }
 476   return $out;
 477 }
 478
 479 #
 480 # non-OO style of earlier version
 481 #
 482 sub Dumper {
 483   return Data::Dumper->Dump([@_]);
 484 }
 485
 486 # compat stub
 487 sub DumperX {
 488   return Data::Dumper->Dumpxs([@_], []);
 489 }
 490
 491 sub Dumpf { return Data::Dumper->Dump(@_) }
 492
 493 sub Dumpp { print Data::Dumper->Dump(@_) }
 494
 495 #
 496 # reset the "seen" cache
 497 #
 498 sub Reset {
 499   my($s) = shift;
 500   $s->{seen} = {};
 501   return $s;
 502 }
 503
 504 sub Indent {
 505   my($s, $v) = @_;
 506   if (defined($v)) {
 507     if ($v == 0) {
 508       $s->{xpad} = "";
 509       $s->{sep} = "";
 510     }
 511     else {
 512       $s->{xpad} = "  ";
 513       $s->{sep} = "\n";
 514     }
 515     $s->{indent} = $v;
 516     return $s;
 517   }
 518   else {
 519     return $s->{indent};
 520   }
 521 }
 522
 523 sub Pair {
 524     my($s, $v) = @_;
 525     defined($v) ? (($s->{pair} = $v), return $s) : $s->{pair};
 526 }
 527
 528 sub Pad {
 529   my($s, $v) = @_;
 530   defined($v) ? (($s->{pad} = $v), return $s) : $s->{pad};
 531 }
 532
 533 sub Varname {
 534   my($s, $v) = @_;
 535   defined($v) ? (($s->{varname} = $v), return $s) : $s->{varname};
 536 }
 537
 538 sub Purity {
 539   my($s, $v) = @_;
 540   defined($v) ? (($s->{purity} = $v), return $s) : $s->{purity};
 541 }
 542
 543 sub Useqq {
 544   my($s, $v) = @_;
 545   defined($v) ? (($s->{useqq} = $v), return $s) : $s->{useqq};
 546 }
 547
 548 sub Terse {
 549   my($s, $v) = @_;
 550   defined($v) ? (($s->{terse} = $v), return $s) : $s->{terse};
 551 }
 552
 553 sub Freezer {
 554   my($s, $v) = @_;
 555   defined($v) ? (($s->{freezer} = $v), return $s) : $s->{freezer};
 556 }
 557
 558 sub Toaster {
 559   my($s, $v) = @_;
 560   defined($v) ? (($s->{toaster} = $v), return $s) : $s->{toaster};
 561 }
 562
 563 sub Deepcopy {
 564   my($s, $v) = @_;
 565   defined($v) ? (($s->{deepcopy} = $v), return $s) : $s->{deepcopy};
 566 }
 567
 568 sub Quotekeys {
 569   my($s, $v) = @_;
 570   defined($v) ? (($s->{quotekeys} = $v), return $s) : $s->{quotekeys};
 571 }
 572
 573 sub Bless {
 574   my($s, $v) = @_;
 575   defined($v) ? (($s->{'bless'} = $v), return $s) : $s->{'bless'};
 576 }
 577
 578 sub Maxdepth {
 579   my($s, $v) = @_;
 580   defined($v) ? (($s->{'maxdepth'} = $v), return $s) : $s->{'maxdepth'};
 581 }
 582
 583 sub Useperl {
 584   my($s, $v) = @_;
 585   defined($v) ? (($s->{'useperl'} = $v), return $s) : $s->{'useperl'};
 586 }
 587
 588 sub Sortkeys {
 589   my($s, $v) = @_;
 590   defined($v) ? (($s->{'sortkeys'} = $v), return $s) : $s->{'sortkeys'};
 591 }
 592
 593 sub Deparse {
 594   my($s, $v) = @_;
 595   defined($v) ? (($s->{'deparse'} = $v), return $s) : $s->{'deparse'};
 596 }
 597
 598 # used by qquote below
 599 my %esc = (
 600     "\a" => "\\a",
 601     "\b" => "\\b",
 602     "\t" => "\\t",
 603     "\n" => "\\n",
 604     "\f" => "\\f",
 605     "\r" => "\\r",
 606     "\e" => "\\e",
 607 );
 608
 609 # put a string value in double quotes
 610 sub qquote {
 611   local($_) = shift;
 612   s/([\\\"\@\$])/\\$1/g;
 613   my $bytes; { use bytes; $bytes = length }
 614   s/([^\x00-\x7f])/'\x{'.sprintf("%x",ord($1)).'}'/ge if $bytes > length;
 615   return qq("$_") unless
 616     /[^ !"\#\$%&'()*+,\-.\/0-9:;<=>?\@A-Z[\\\]^_`a-z{|}~]/;  # fast exit
 617
 618   my $high = shift || "";
 619   s/([\a\b\t\n\f\r\e])/$esc{$1}/g;
 620
 621   if (ord('^')==94)  { # ascii
 622     # no need for 3 digits in escape for these
 623     s/([\0-\037])(?!\d)/'\\'.sprintf('%o',ord($1))/eg;
 624     s/([\0-\037\177])/'\\'.sprintf('%03o',ord($1))/eg;
 625     # all but last branch below not supported --BEHAVIOR SUBJECT TO CHANGE--
 626     if ($high eq "iso8859") {
 627       s/([\200-\240])/'\\'.sprintf('%o',ord($1))/eg;
 628     } elsif ($high eq "utf8") {
 629 #     use utf8;
 630 #     $str =~ s/([^\040-\176])/sprintf "\\x{%04x}", ord($1)/ge;
 631     } elsif ($high eq "8bit") {
 632         # leave it as it is
 633     } else {
 634       s/([\200-\377])/'\\'.sprintf('%03o',ord($1))/eg;
 635       s/([^\040-\176])/sprintf "\\x{%04x}", ord($1)/ge;
 636     }
 637   }
 638   else { # ebcdic
 639       s{([^ !"\#\$%&'()*+,\-.\/0-9:;<=>?\@A-Z[\\\]^_`a-z{|}~])(?!\d)}
 640        {my $v = ord($1); '\\'.sprintf(($v <= 037 ? '%o' : '%03o'), $v)}eg;
 641       s{([^ !"\#\$%&'()*+,\-.\/0-9:;<=>?\@A-Z[\\\]^_`a-z{|}~])}
 642        {'\\'.sprintf('%03o',ord($1))}eg;
 643   }
 644
 645   return qq("$_");
 646 }
 647
 648 1;
 649 __END__
 650
 651 =head1 NAME
 652
 653 Data::Dumper - stringified perl data structures, suitable for both printing and C<eval>
 654
 655 =head1 SYNOPSIS
 656
 657     use Data::Dumper;
 658
 659     # simple procedural interface
 660     print Dumper($foo, $bar);
 661
 662     # extended usage with names
 663     print Data::Dumper->Dump([$foo, $bar], [qw(foo *ary)]);
 664
 665     # configuration variables
 666     {
 667       local $Data::Dumper::Purity = 1;
 668       eval Data::Dumper->Dump([$foo, $bar], [qw(foo *ary)]);
 669     }
 670
 671     # OO usage
 672     $d = Data::Dumper->new([$foo, $bar], [qw(foo *ary)]);
 673        ...
 674     print $d->Dump;
 675        ...
 676     $d->Purity(1)->Terse(1)->Deepcopy(1);
 677     eval $d->Dump;
 678
 679
 680 =head1 DESCRIPTION
 681
 682 Given a list of scalars or reference variables, writes out their contents in
 683 perl syntax. The references can also be objects.  The contents of each
 684 variable is output in a single Perl statement.  Handles self-referential
 685 structures correctly.
 686
 687 The return value can be C<eval>ed to get back an identical copy of the
 688 original reference structure.
 689
 690 Any references that are the same as one of those passed in will be named
 691 C<$VAR>I<n> (where I<n> is a numeric suffix), and other duplicate references
 692 to substructures within C<$VAR>I<n> will be appropriately labeled using arrow
 693 notation.  You can specify names for individual values to be dumped if you
 694 use the C<Dump()> method, or you can change the default C<$VAR> prefix to
 695 something else.  See C<$Data::Dumper::Varname> and C<$Data::Dumper::Terse>
 696 below.
 697
 698 The default output of self-referential structures can be C<eval>ed, but the
 699 nested references to C<$VAR>I<n> will be undefined, since a recursive
 700 structure cannot be constructed using one Perl statement.  You should set the
 701 C<Purity> flag to 1 to get additional statements that will correctly fill in
 702 these references.
 703
 704 In the extended usage form, the references to be dumped can be given
 705 user-specified names.  If a name begins with a C<*>, the output will
 706 describe the dereferenced type of the supplied reference for hashes and
 707 arrays, and coderefs.  Output of names will be avoided where possible if
 708 the C<Terse> flag is set.
 709
 710 In many cases, methods that are used to set the internal state of the
 711 object will return the object itself, so method calls can be conveniently
 712 chained together.
 713
 714 Several styles of output are possible, all controlled by setting
 715 the C<Indent> flag.  See L<Configuration Variables or Methods> below
 716 for details.
 717
 718
 719 =head2 Methods
 720
 721 =over 4
 722
 723 =item I<PACKAGE>->new(I<ARRAYREF [>, I<ARRAYREF]>)
 724
 725 Returns a newly created C<Data::Dumper> object.  The first argument is an
 726 anonymous array of values to be dumped.  The optional second argument is an
 727 anonymous array of names for the values.  The names need not have a leading
 728 C<$> sign, and must be comprised of alphanumeric characters.  You can begin
 729 a name with a C<*> to specify that the dereferenced type must be dumped
 730 instead of the reference itself, for ARRAY and HASH references.
 731
 732 The prefix specified by C<$Data::Dumper::Varname> will be used with a
 733 numeric suffix if the name for a value is undefined.
 734
 735 Data::Dumper will catalog all references encountered while dumping the
 736 values. Cross-references (in the form of names of substructures in perl
 737 syntax) will be inserted at all possible points, preserving any structural
 738 interdependencies in the original set of values.  Structure traversal is
 739 depth-first,  and proceeds in order from the first supplied value to
 740 the last.
 741
 742 =item I<$OBJ>->Dump  I<or>  I<PACKAGE>->Dump(I<ARRAYREF [>, I<ARRAYREF]>)
 743
 744 Returns the stringified form of the values stored in the object (preserving
 745 the order in which they were supplied to C<new>), subject to the
 746 configuration options below.  In a list context, it returns a list
 747 of strings corresponding to the supplied values.
 748
 749 The second form, for convenience, simply calls the C<new> method on its
 750 arguments before dumping the object immediately.
 751
 752 =item I<$OBJ>->Seen(I<[HASHREF]>)
 753
 754 Queries or adds to the internal table of already encountered references.
 755 You must use C<Reset> to explicitly clear the table if needed.  Such
 756 references are not dumped; instead, their names are inserted wherever they
 757 are encountered subsequently.  This is useful especially for properly
 758 dumping subroutine references.
 759
 760 Expects an anonymous hash of name => value pairs.  Same rules apply for names
 761 as in C<new>.  If no argument is supplied, will return the "seen" list of
 762 name => value pairs, in a list context.  Otherwise, returns the object
 763 itself.
 764
 765 =item I<$OBJ>->Values(I<[ARRAYREF]>)
 766
 767 Queries or replaces the internal array of values that will be dumped.
 768 When called without arguments, returns the values.  Otherwise, returns the
 769 object itself.
 770
 771 =item I<$OBJ>->Names(I<[ARRAYREF]>)
 772
 773 Queries or replaces the internal array of user supplied names for the values
 774 that will be dumped.  When called without arguments, returns the names.
 775 Otherwise, returns the object itself.
 776
 777 =item I<$OBJ>->Reset
 778
 779 Clears the internal table of "seen" references and returns the object
 780 itself.
 781
 782 =back
 783
 784 =head2 Functions
 785
 786 =over 4
 787
 788 =item Dumper(I<LIST>)
 789
 790 Returns the stringified form of the values in the list, subject to the
 791 configuration options below.  The values will be named C<$VAR>I<n> in the
 792 output, where I<n> is a numeric suffix.  Will return a list of strings
 793 in a list context.
 794
 795 =back
 796
 797 =head2 Configuration Variables or Methods
 798
 799 Several configuration variables can be used to control the kind of output
 800 generated when using the procedural interface.  These variables are usually
 801 C<local>ized in a block so that other parts of the code are not affected by
 802 the change.
 803
 804 These variables determine the default state of the object created by calling
 805 the C<new> method, but cannot be used to alter the state of the object
 806 thereafter.  The equivalent method names should be used instead to query
 807 or set the internal state of the object.
 808
 809 The method forms return the object itself when called with arguments,
 810 so that they can be chained together nicely.
 811
 812 =over 4
 813
 814 =item *
 815
 816 $Data::Dumper::Indent  I<or>  I<$OBJ>->Indent(I<[NEWVAL]>)
 817
 818 Controls the style of indentation.  It can be set to 0, 1, 2 or 3.  Style 0
 819 spews output without any newlines, indentation, or spaces between list
 820 items.  It is the most compact format possible that can still be called
 821 valid perl.  Style 1 outputs a readable form with newlines but no fancy
 822 indentation (each level in the structure is simply indented by a fixed
 823 amount of whitespace).  Style 2 (the default) outputs a very readable form
 824 which takes into account the length of hash keys (so the hash value lines
 825 up).  Style 3 is like style 2, but also annotates the elements of arrays
 826 with their index (but the comment is on its own line, so array output
 827 consumes twice the number of lines).  Style 2 is the default.
 828
 829 =item *
 830
 831 $Data::Dumper::Purity  I<or>  I<$OBJ>->Purity(I<[NEWVAL]>)
 832
 833 Controls the degree to which the output can be C<eval>ed to recreate the
 834 supplied reference structures.  Setting it to 1 will output additional perl
 835 statements that will correctly recreate nested references.  The default is
 836 0.
 837
 838 =item *
 839
 840 $Data::Dumper::Pad  I<or>  I<$OBJ>->Pad(I<[NEWVAL]>)
 841
 842 Specifies the string that will be prefixed to every line of the output.
 843 Empty string by default.
 844
 845 =item *
 846
 847 $Data::Dumper::Varname  I<or>  I<$OBJ>->Varname(I<[NEWVAL]>)
 848
 849 Contains the prefix to use for tagging variable names in the output. The
 850 default is "VAR".
 851
 852 =item *
 853
 854 $Data::Dumper::Useqq  I<or>  I<$OBJ>->Useqq(I<[NEWVAL]>)
 855
 856 When set, enables the use of double quotes for representing string values.
 857 Whitespace other than space will be represented as C<[\n\t\r]>, "unsafe"
 858 characters will be backslashed, and unprintable characters will be output as
 859 quoted octal integers.  Since setting this variable imposes a performance
 860 penalty, the default is 0.  C<Dump()> will run slower if this flag is set,
 861 since the fast XSUB implementation doesn't support it yet.
 862
 863 =item *
 864
 865 $Data::Dumper::Terse  I<or>  I<$OBJ>->Terse(I<[NEWVAL]>)
 866
 867 When set, Data::Dumper will emit single, non-self-referential values as
 868 atoms/terms rather than statements.  This means that the C<$VAR>I<n> names
 869 will be avoided where possible, but be advised that such output may not
 870 always be parseable by C<eval>.
 871
 872 =item *
 873
 874 $Data::Dumper::Freezer  I<or>  $I<OBJ>->Freezer(I<[NEWVAL]>)
 875
 876 Can be set to a method name, or to an empty string to disable the feature.
 877 Data::Dumper will invoke that method via the object before attempting to
 878 stringify it.  This method can alter the contents of the object (if, for
 879 instance, it contains data allocated from C), and even rebless it in a
 880 different package.  The client is responsible for making sure the specified
 881 method can be called via the object, and that the object ends up containing
 882 only perl data types after the method has been called.  Defaults to an empty
 883 string.
 884
 885 =item *
 886
 887 $Data::Dumper::Toaster  I<or>  $I<OBJ>->Toaster(I<[NEWVAL]>)
 888
 889 Can be set to a method name, or to an empty string to disable the feature.
 890 Data::Dumper will emit a method call for any objects that are to be dumped
 891 using the syntax C<bless(DATA, CLASS)-E<gt>METHOD()>.  Note that this means that
 892 the method specified will have to perform any modifications required on the
 893 object (like creating new state within it, and/or reblessing it in a
 894 different package) and then return it.  The client is responsible for making
 895 sure the method can be called via the object, and that it returns a valid
 896 object.  Defaults to an empty string.
 897
 898 =item *
 899
 900 $Data::Dumper::Deepcopy  I<or>  $I<OBJ>->Deepcopy(I<[NEWVAL]>)
 901
 902 Can be set to a boolean value to enable deep copies of structures.
 903 Cross-referencing will then only be done when absolutely essential
 904 (i.e., to break reference cycles).  Default is 0.
 905
 906 =item *
 907
 908 $Data::Dumper::Quotekeys  I<or>  $I<OBJ>->Quotekeys(I<[NEWVAL]>)
 909
 910 Can be set to a boolean value to control whether hash keys are quoted.
 911 A false value will avoid quoting hash keys when it looks like a simple
 912 string.  Default is 1, which will always enclose hash keys in quotes.
 913
 914 =item *
 915
 916 $Data::Dumper::Bless  I<or>  $I<OBJ>->Bless(I<[NEWVAL]>)
 917
 918 Can be set to a string that specifies an alternative to the C<bless>
 919 builtin operator used to create objects.  A function with the specified
 920 name should exist, and should accept the same arguments as the builtin.
 921 Default is C<bless>.
 922
 923 =item *
 924
 925 $Data::Dumper::Pair  I<or>  $I<OBJ>->Pair(I<[NEWVAL]>)
 926
 927 Can be set to a string that specifies the separator between hash keys
 928 and values. To dump nested hash, array and scalar values to JavaScript,
 929 use: C<$Data::Dumper::Pair = ' : ';>. Implementing C<bless> in JavaScript
 930 is left as an exercise for the reader.
 931 A function with the specified name exists, and accepts the same arguments
 932 as the builtin.
 933
 934 Default is: C< =E<gt> >.
 935
 936 =item *
 937
 938 $Data::Dumper::Maxdepth  I<or>  $I<OBJ>->Maxdepth(I<[NEWVAL]>)
 939
 940 Can be set to a positive integer that specifies the depth beyond which
 941 which we don't venture into a structure.  Has no effect when
 942 C<Data::Dumper::Purity> is set.  (Useful in debugger when we often don't
 943 want to see more than enough).  Default is 0, which means there is
 944 no maximum depth.
 945
 946 =item *
 947
 948 $Data::Dumper::Useperl  I<or>  $I<OBJ>->Useperl(I<[NEWVAL]>)
 949
 950 Can be set to a boolean value which controls whether the pure Perl
 951 implementation of C<Data::Dumper> is used. The C<Data::Dumper> module is
 952 a dual implementation, with almost all functionality written in both
 953 pure Perl and also in XS ('C'). Since the XS version is much faster, it
 954 will always be used if possible. This option lets you override the
 955 default behavior, usually for testing purposes only. Default is 0, which
 956 means the XS implementation will be used if possible.
 957
 958 =item *
 959
 960 $Data::Dumper::Sortkeys  I<or>  $I<OBJ>->Sortkeys(I<[NEWVAL]>)
 961
 962 Can be set to a boolean value to control whether hash keys are dumped in
 963 sorted order. A true value will cause the keys of all hashes to be
 964 dumped in Perl's default sort order. Can also be set to a subroutine
 965 reference which will be called for each hash that is dumped. In this
 966 case C<Data::Dumper> will call the subroutine once for each hash,
 967 passing it the reference of the hash. The purpose of the subroutine is
 968 to return a reference to an array of the keys that will be dumped, in
 969 the order that they should be dumped. Using this feature, you can
 970 control both the order of the keys, and which keys are actually used. In
 971 other words, this subroutine acts as a filter by which you can exclude
 972 certain keys from being dumped. Default is 0, which means that hash keys
 973 are not sorted.
 974
 975 =item *
 976
 977 $Data::Dumper::Deparse  I<or>  $I<OBJ>->Deparse(I<[NEWVAL]>)
 978
 979 Can be set to a boolean value to control whether code references are
 980 turned into perl source code. If set to a true value, C<B::Deparse>
 981 will be used to get the source of the code reference. Using this option
 982 will force using the Perl implementation of the dumper, since the fast
 983 XSUB implementation doesn't support it.
 984
 985 Caution : use this option only if you know that your coderefs will be
 986 properly reconstructed by C<B::Deparse>.
 987
 988 =back
 989
 990 =head2 Exports
 991
 992 =over 4
 993
 994 =item Dumper
 995
 996 =back
 997
 998 =head1 EXAMPLES
 999
1000 Run these code snippets to get a quick feel for the behavior of this
1001 module.  When you are through with these examples, you may want to
1002 add or change the various configuration variables described above,
1003 to see their behavior.  (See the testsuite in the Data::Dumper
1004 distribution for more examples.)
1005
1006
1007     use Data::Dumper;
1008
1009     package Foo;
1010     sub new {bless {'a' => 1, 'b' => sub { return "foo" }}, $_[0]};
1011
1012     package Fuz;                       # a weird REF-REF-SCALAR object
1013     sub new {bless \($_ = \ 'fu\'z'), $_[0]};
1014
1015     package main;
1016     $foo = Foo->new;
1017     $fuz = Fuz->new;
1018     $boo = [ 1, [], "abcd", \*foo,
1019              {1 => 'a', 023 => 'b', 0x45 => 'c'},
1020              \\"p\q\'r", $foo, $fuz];
1021
1022     ########
1023     # simple usage
1024     ########
1025
1026     $bar = eval(Dumper($boo));
1027     print($@) if $@;
1028     print Dumper($boo), Dumper($bar);  # pretty print (no array indices)
1029
1030     $Data::Dumper::Terse = 1;          # don't output names where feasible
1031     $Data::Dumper::Indent = 0;         # turn off all pretty print
1032     print Dumper($boo), "\n";
1033
1034     $Data::Dumper::Indent = 1;         # mild pretty print
1035     print Dumper($boo);
1036
1037     $Data::Dumper::Indent = 3;         # pretty print with array indices
1038     print Dumper($boo);
1039
1040     $Data::Dumper::Useqq = 1;          # print strings in double quotes
1041     print Dumper($boo);
1042
1043     $Data::Dumper::Pair = " : ";       # specify hash key/value separator
1044     print Dumper($boo);
1045
1046
1047     ########
1048     # recursive structures
1049     ########
1050
1051     @c = ('c');
1052     $c = \@c;
1053     $b = {};
1054     $a = [1, $b, $c];
1055     $b->{a} = $a;
1056     $b->{b} = $a->[1];
1057     $b->{c} = $a->[2];
1058     print Data::Dumper->Dump([$a,$b,$c], [qw(a b c)]);
1059
1060
1061     $Data::Dumper::Purity = 1;         # fill in the holes for eval
1062     print Data::Dumper->Dump([$a, $b], [qw(*a b)]); # print as @a
1063     print Data::Dumper->Dump([$b, $a], [qw(*b a)]); # print as %b
1064
1065
1066     $Data::Dumper::Deepcopy = 1;       # avoid cross-refs
1067     print Data::Dumper->Dump([$b, $a], [qw(*b a)]);
1068
1069
1070     $Data::Dumper::Purity = 0;         # avoid cross-refs
1071     print Data::Dumper->Dump([$b, $a], [qw(*b a)]);
1072
1073     ########
1074     # deep structures
1075     ########
1076
1077     $a = "pearl";
1078     $b = [ $a ];
1079     $c = { 'b' => $b };
1080     $d = [ $c ];
1081     $e = { 'd' => $d };
1082     $f = { 'e' => $e };
1083     print Data::Dumper->Dump([$f], [qw(f)]);
1084
1085     $Data::Dumper::Maxdepth = 3;       # no deeper than 3 refs down
1086     print Data::Dumper->Dump([$f], [qw(f)]);
1087
1088
1089     ########
1090     # object-oriented usage
1091     ########
1092
1093     $d = Data::Dumper->new([$a,$b], [qw(a b)]);
1094     $d->Seen({'*c' => $c});            # stash a ref without printing it
1095     $d->Indent(3);
1096     print $d->Dump;
1097     $d->Reset->Purity(0);              # empty the seen cache
1098     print join "----\n", $d->Dump;
1099
1100
1101     ########
1102     # persistence
1103     ########
1104
1105     package Foo;
1106     sub new { bless { state => 'awake' }, shift }
1107     sub Freeze {
1108         my $s = shift;
1109         print STDERR "preparing to sleep\n";
1110         $s->{state} = 'asleep';
1111         return bless $s, 'Foo::ZZZ';
1112     }
1113
1114     package Foo::ZZZ;
1115     sub Thaw {
1116         my $s = shift;
1117         print STDERR "waking up\n";
1118         $s->{state} = 'awake';
1119         return bless $s, 'Foo';
1120     }
1121
1122     package Foo;
1123     use Data::Dumper;
1124     $a = Foo->new;
1125     $b = Data::Dumper->new([$a], ['c']);
1126     $b->Freezer('Freeze');
1127     $b->Toaster('Thaw');
1128     $c = $b->Dump;
1129     print $c;
1130     $d = eval $c;
1131     print Data::Dumper->Dump([$d], ['d']);
1132
1133
1134     ########
1135     # symbol substitution (useful for recreating CODE refs)
1136     ########
1137
1138     sub foo { print "foo speaking\n" }
1139     *other = \&foo;
1140     $bar = [ \&other ];
1141     $d = Data::Dumper->new([\&other,$bar],['*other','bar']);
1142     $d->Seen({ '*foo' => \&foo });
1143     print $d->Dump;
1144
1145
1146     ########
1147     # sorting and filtering hash keys
1148     ########
1149
1150     $Data::Dumper::Sortkeys = \&my_filter;
1151     my $foo = { map { (ord, "$_$_$_") } 'I'..'Q' };
1152     my $bar = { %$foo };
1153     my $baz = { reverse %$foo };
1154     print Dumper [ $foo, $bar, $baz ];
1155
1156     sub my_filter {
1157         my ($hash) = @_;
1158         # return an array ref containing the hash keys to dump
1159         # in the order that you want them to be dumped
1160         return [
1161           # Sort the keys of %$foo in reverse numeric order
1162             $hash eq $foo ? (sort {$b <=> $a} keys %$hash) :
1163           # Only dump the odd number keys of %$bar
1164             $hash eq $bar ? (grep {$_ % 2} keys %$hash) :
1165           # Sort keys in default order for all other hashes
1166             (sort keys %$hash)
1167         ];
1168     }
1169
1170 =head1 BUGS
1171
1172 Due to limitations of Perl subroutine call semantics, you cannot pass an
1173 array or hash.  Prepend it with a C<\> to pass its reference instead.  This
1174 will be remedied in time, now that Perl has subroutine prototypes.
1175 For now, you need to use the extended usage form, and prepend the
1176 name with a C<*> to output it as a hash or array.
1177
1178 C<Data::Dumper> cheats with CODE references.  If a code reference is
1179 encountered in the structure being processed (and if you haven't set
1180 the C<Deparse> flag), an anonymous subroutine that
1181 contains the string '"DUMMY"' will be inserted in its place, and a warning
1182 will be printed if C<Purity> is set.  You can C<eval> the result, but bear
1183 in mind that the anonymous sub that gets created is just a placeholder.
1184 Someday, perl will have a switch to cache-on-demand the string
1185 representation of a compiled piece of code, I hope.  If you have prior
1186 knowledge of all the code refs that your data structures are likely
1187 to have, you can use the C<Seen> method to pre-seed the internal reference
1188 table and make the dumped output point to them, instead.  See L<EXAMPLES>
1189 above.
1190
1191 The C<Useqq> and C<Deparse> flags makes Dump() run slower, since the
1192 XSUB implementation does not support them.
1193
1194 SCALAR objects have the weirdest looking C<bless> workaround.
1195
1196 =head2 NOTE
1197
1198 Starting from Perl 5.8.1 different runs of Perl will have different
1199 ordering of hash keys.  The change was done for greater security,
1200 see L<perlsec/"Algorithmic Complexity Attacks">.  This means that
1201 different runs of Perl will have different Data::Dumper outputs if
1202 the data contains hashes.  If you need to have identical Data::Dumper
1203 outputs from different runs of Perl, use the environment variable
1204 PERL_HASH_SEED, see L<perlrun/PERL_HASH_SEED>.  Using this restores
1205 the old (platform-specific) ordering: an even prettier solution might
1206 be to use the C<Sortkeys> filter of Data::Dumper.
1207
1208 =head1 AUTHOR
1209
1210 Gurusamy Sarathy        gsar@activestate.com
1211
1212 Copyright (c) 1996-98 Gurusamy Sarathy. All rights reserved.
1213 This program is free software; you can redistribute it and/or
1214 modify it under the same terms as Perl itself.
1215
1216 =head1 VERSION
1217
1218 Version 2.12   (unreleased)
1219
1220 =head1 SEE ALSO
1221
1222 perl(1)
1223
1224 =cut