ext/Data/Dumper/Dumper.pm

   1 #
   2 # Data/Dumper.pm
   3 #
   4 # convert perl data structures into perl syntax suitable for both printing
   5 # and eval
   6 #
   7 # Documentation at the __END__
   8 #
   9
  10 package Data::Dumper;
  11
  12 $VERSION = '2.121_02';
  13
  14 #$| = 1;
  15
  16 use 5.006_001;
  17 require Exporter;
  18 use XSLoader ();
  19 require overload;
  20
  21 use Carp;
  22
  23 @ISA = qw(Exporter);
  24 @EXPORT = qw(Dumper);
  25 @EXPORT_OK = qw(DumperX);
  26
  27 XSLoader::load 'Data::Dumper';
  28
  29 # module vars and their defaults
  30 $Indent = 2 unless defined $Indent;
  31 $Purity = 0 unless defined $Purity;
  32 $Pad = "" unless defined $Pad;
  33 $Varname = "VAR" unless defined $Varname;
  34 $Useqq = 0 unless defined $Useqq;
  35 $Terse = 0 unless defined $Terse;
  36 $Freezer = "" unless defined $Freezer;
  37 $Toaster = "" unless defined $Toaster;
  38 $Deepcopy = 0 unless defined $Deepcopy;
  39 $Quotekeys = 1 unless defined $Quotekeys;
  40 $Bless = "bless" unless defined $Bless;
  41 #$Expdepth = 0 unless defined $Expdepth;
  42 $Maxdepth = 0 unless defined $Maxdepth;
  43 $Pair = ' => ' unless defined $Pair;
  44 $Useperl = 0 unless defined $Useperl;
  45 $Sortkeys = 0 unless defined $Sortkeys;
  46 $Deparse = 0 unless defined $Deparse;
  47
  48 #
  49 # expects an arrayref of values to be dumped.
  50 # can optionally pass an arrayref of names for the values.
  51 # names must have leading $ sign stripped. begin the name with *
  52 # to cause output of arrays and hashes rather than refs.
  53 #
  54 sub new {
  55   my($c, $v, $n) = @_;
  56
  57   croak "Usage:  PACKAGE->new(ARRAYREF, [ARRAYREF])"
  58     unless (defined($v) && (ref($v) eq 'ARRAY'));
  59   $n = [] unless (defined($n) && (ref($v) eq 'ARRAY'));
  60
  61   my($s) = {
  62              level      => 0,           # current recursive depth
  63              indent     => $Indent,     # various styles of indenting
  64              pad        => $Pad,        # all lines prefixed by this string
  65              xpad       => "",          # padding-per-level
  66              apad       => "",          # added padding for hash keys n such
  67              sep        => "",          # list separator
  68              pair       => $Pair,       # hash key/value separator: defaults to ' => '
  69              seen       => {},          # local (nested) refs (id => [name, val])
  70              todump     => $v,          # values to dump []
  71              names      => $n,          # optional names for values []
  72              varname    => $Varname,    # prefix to use for tagging nameless ones
  73              purity     => $Purity,     # degree to which output is evalable
  74              useqq      => $Useqq,      # use "" for strings (backslashitis ensues)
  75              terse      => $Terse,      # avoid name output (where feasible)
  76              freezer    => $Freezer,    # name of Freezer method for objects
  77              toaster    => $Toaster,    # name of method to revive objects
  78              deepcopy   => $Deepcopy,   # dont cross-ref, except to stop recursion
  79              quotekeys  => $Quotekeys,  # quote hash keys
  80              'bless'    => $Bless,      # keyword to use for "bless"
  81 #            expdepth   => $Expdepth,   # cutoff depth for explicit dumping
  82              maxdepth   => $Maxdepth,   # depth beyond which we give up
  83              useperl    => $Useperl,    # use the pure Perl implementation
  84              sortkeys   => $Sortkeys,   # flag or filter for sorting hash keys
  85              deparse    => $Deparse,    # use B::Deparse for coderefs
  86            };
  87
  88   if ($Indent > 0) {
  89     $s->{xpad} = "  ";
  90     $s->{sep} = "\n";
  91   }
  92   return bless($s, $c);
  93 }
  94
  95 #
  96 # add-to or query the table of already seen references
  97 #
  98 sub Seen {
  99   my($s, $g) = @_;
 100   if (defined($g) && (ref($g) eq 'HASH'))  {
 101     my($k, $v, $id);
 102     while (($k, $v) = each %$g) {
 103       if (defined $v and ref $v) {
 104         ($id) = (overload::StrVal($v) =~ /\((.*)\)$/);
 105         if ($k =~ /^[*](.*)$/) {
 106           $k = (ref $v eq 'ARRAY') ? ( "\\\@" . $1 ) :
 107                (ref $v eq 'HASH')  ? ( "\\\%" . $1 ) :
 108                (ref $v eq 'CODE')  ? ( "\\\&" . $1 ) :
 109                                      (   "\$" . $1 ) ;
 110         }
 111         elsif ($k !~ /^\$/) {
 112           $k = "\$" . $k;
 113         }
 114         $s->{seen}{$id} = [$k, $v];
 115       }
 116       else {
 117         carp "Only refs supported, ignoring non-ref item \$$k";
 118       }
 119     }
 120     return $s;
 121   }
 122   else {
 123     return map { @$_ } values %{$s->{seen}};
 124   }
 125 }
 126
 127 #
 128 # set or query the values to be dumped
 129 #
 130 sub Values {
 131   my($s, $v) = @_;
 132   if (defined($v) && (ref($v) eq 'ARRAY'))  {
 133     $s->{todump} = [@$v];        # make a copy
 134     return $s;
 135   }
 136   else {
 137     return @{$s->{todump}};
 138   }
 139 }
 140
 141 #
 142 # set or query the names of the values to be dumped
 143 #
 144 sub Names {
 145   my($s, $n) = @_;
 146   if (defined($n) && (ref($n) eq 'ARRAY'))  {
 147     $s->{names} = [@$n];         # make a copy
 148     return $s;
 149   }
 150   else {
 151     return @{$s->{names}};
 152   }
 153 }
 154
 155 sub DESTROY {}
 156
 157 sub Dump {
 158     return &Dumpxs
 159         unless $Data::Dumper::Useperl || (ref($_[0]) && $_[0]->{useperl}) ||
 160                $Data::Dumper::Useqq   || (ref($_[0]) && $_[0]->{useqq}) ||
 161                $Data::Dumper::Deparse || (ref($_[0]) && $_[0]->{deparse});
 162     return &Dumpperl;
 163 }
 164
 165 #
 166 # dump the refs in the current dumper object.
 167 # expects same args as new() if called via package name.
 168 #
 169 sub Dumpperl {
 170   my($s) = shift;
 171   my(@out, $val, $name);
 172   my($i) = 0;
 173   local(@post);
 174
 175   $s = $s->new(@_) unless ref $s;
 176
 177   for $val (@{$s->{todump}}) {
 178     my $out = "";
 179     @post = ();
 180     $name = $s->{names}[$i++];
 181     if (defined $name) {
 182       if ($name =~ /^[*](.*)$/) {
 183         if (defined $val) {
 184           $name = (ref $val eq 'ARRAY') ? ( "\@" . $1 ) :
 185                   (ref $val eq 'HASH')  ? ( "\%" . $1 ) :
 186                   (ref $val eq 'CODE')  ? ( "\*" . $1 ) :
 187                                           ( "\$" . $1 ) ;
 188         }
 189         else {
 190           $name = "\$" . $1;
 191         }
 192       }
 193       elsif ($name !~ /^\$/) {
 194         $name = "\$" . $name;
 195       }
 196     }
 197     else {
 198       $name = "\$" . $s->{varname} . $i;
 199     }
 200
 201     my $valstr;
 202     {
 203       local($s->{apad}) = $s->{apad};
 204       $s->{apad} .= ' ' x (length($name) + 3) if $s->{indent} >= 2;
 205       $valstr = $s->_dump($val, $name);
 206     }
 207
 208     $valstr = "$name = " . $valstr . ';' if @post or !$s->{terse};
 209     $out .= $s->{pad} . $valstr . $s->{sep};
 210     $out .= $s->{pad} . join(';' . $s->{sep} . $s->{pad}, @post)
 211       . ';' . $s->{sep} if @post;
 212
 213     push @out, $out;
 214   }
 215   return wantarray ? @out : join('', @out);
 216 }
 217
 218 #
 219 # twist, toil and turn;
 220 # and recurse, of course.
 221 # sometimes sordidly;
 222 # and curse if no recourse.
 223 #
 224 sub _dump {
 225   my($s, $val, $name) = @_;
 226   my($sname);
 227   my($out, $realpack, $realtype, $type, $ipad, $id, $blesspad);
 228
 229   $type = ref $val;
 230   $out = "";
 231
 232   if ($type) {
 233
 234     # prep it, if it looks like an object
 235     if (my $freezer = $s->{freezer}) {
 236       $val->$freezer() if UNIVERSAL::can($val, $freezer);
 237     }
 238
 239     ($realpack, $realtype, $id) =
 240       (overload::StrVal($val) =~ /^(?:(.*)\=)?([^=]*)\(([^\(]*)\)$/);
 241
 242     # if it has a name, we need to either look it up, or keep a tab
 243     # on it so we know when we hit it later
 244     if (defined($name) and length($name)) {
 245       # keep a tab on it so that we dont fall into recursive pit
 246       if (exists $s->{seen}{$id}) {
 247 #       if ($s->{expdepth} < $s->{level}) {
 248           if ($s->{purity} and $s->{level} > 0) {
 249             $out = ($realtype eq 'HASH')  ? '{}' :
 250               ($realtype eq 'ARRAY') ? '[]' :
 251                 'do{my $o}' ;
 252             push @post, $name . " = " . $s->{seen}{$id}[0];
 253           }
 254           else {
 255             $out = $s->{seen}{$id}[0];
 256             if ($name =~ /^([\@\%])/) {
 257               my $start = $1;
 258               if ($out =~ /^\\$start/) {
 259                 $out = substr($out, 1);
 260               }
 261               else {
 262                 $out = $start . '{' . $out . '}';
 263               }
 264             }
 265           }
 266           return $out;
 267 #        }
 268       }
 269       else {
 270         # store our name
 271         $s->{seen}{$id} = [ (($name =~ /^[@%]/)     ? ('\\' . $name ) :
 272                              ($realtype eq 'CODE' and
 273                               $name =~ /^[*](.*)$/) ? ('\\&' . $1 )   :
 274                              $name          ),
 275                             $val ];
 276       }
 277     }
 278
 279     if ($realpack and $realpack eq 'Regexp') {
 280         $out = "$val";
 281         $out =~ s,/,\\/,g;
 282         return "qr/$out/";
 283     }
 284
 285     # If purity is not set and maxdepth is set, then check depth:
 286     # if we have reached maximum depth, return the string
 287     # representation of the thing we are currently examining
 288     # at this depth (i.e., 'Foo=ARRAY(0xdeadbeef)').
 289     if (!$s->{purity}
 290         and $s->{maxdepth} > 0
 291         and $s->{level} >= $s->{maxdepth})
 292     {
 293       return qq['$val'];
 294     }
 295
 296     # we have a blessed ref
 297     if ($realpack) {
 298       $out = $s->{'bless'} . '( ';
 299       $blesspad = $s->{apad};
 300       $s->{apad} .= '       ' if ($s->{indent} >= 2);
 301     }
 302
 303     $s->{level}++;
 304     $ipad = $s->{xpad} x $s->{level};
 305
 306     if ($realtype eq 'SCALAR' || $realtype eq 'REF') {
 307       if ($realpack) {
 308         $out .= 'do{\\(my $o = ' . $s->_dump($$val, "\${$name}") . ')}';
 309       }
 310       else {
 311         $out .= '\\' . $s->_dump($$val, "\${$name}");
 312       }
 313     }
 314     elsif ($realtype eq 'GLOB') {
 315         $out .= '\\' . $s->_dump($$val, "*{$name}");
 316     }
 317     elsif ($realtype eq 'ARRAY') {
 318       my($v, $pad, $mname);
 319       my($i) = 0;
 320       $out .= ($name =~ /^\@/) ? '(' : '[';
 321       $pad = $s->{sep} . $s->{pad} . $s->{apad};
 322       ($name =~ /^\@(.*)$/) ? ($mname = "\$" . $1) :
 323         # omit -> if $foo->[0]->{bar}, but not ${$foo->[0]}->{bar}
 324         ($name =~ /^\\?[\%\@\*\$][^{].*[]}]$/) ? ($mname = $name) :
 325           ($mname = $name . '->');
 326       $mname .= '->' if $mname =~ /^\*.+\{[A-Z]+\}$/;
 327       for $v (@$val) {
 328         $sname = $mname . '[' . $i . ']';
 329         $out .= $pad . $ipad . '#' . $i if $s->{indent} >= 3;
 330         $out .= $pad . $ipad . $s->_dump($v, $sname);
 331         $out .= "," if $i++ < $#$val;
 332       }
 333       $out .= $pad . ($s->{xpad} x ($s->{level} - 1)) if $i;
 334       $out .= ($name =~ /^\@/) ? ')' : ']';
 335     }
 336     elsif ($realtype eq 'HASH') {
 337       my($k, $v, $pad, $lpad, $mname, $pair);
 338       $out .= ($name =~ /^\%/) ? '(' : '{';
 339       $pad = $s->{sep} . $s->{pad} . $s->{apad};
 340       $lpad = $s->{apad};
 341       $pair = $s->{pair};
 342       ($name =~ /^\%(.*)$/) ? ($mname = "\$" . $1) :
 343         # omit -> if $foo->[0]->{bar}, but not ${$foo->[0]}->{bar}
 344         ($name =~ /^\\?[\%\@\*\$][^{].*[]}]$/) ? ($mname = $name) :
 345           ($mname = $name . '->');
 346       $mname .= '->' if $mname =~ /^\*.+\{[A-Z]+\}$/;
 347       my ($sortkeys, $keys, $key) = ("$s->{sortkeys}");
 348       if ($sortkeys) {
 349         if (ref($s->{sortkeys}) eq 'CODE') {
 350           $keys = $s->{sortkeys}($val);
 351           unless (ref($keys) eq 'ARRAY') {
 352             carp "Sortkeys subroutine did not return ARRAYREF";
 353             $keys = [];
 354           }
 355         }
 356         else {
 357           $keys = [ sort keys %$val ];
 358         }
 359       }
 360       while (($k, $v) = ! $sortkeys ? (each %$val) :
 361              @$keys ? ($key = shift(@$keys), $val->{$key}) :
 362              () )
 363       {
 364         my $nk = $s->_dump($k, "");
 365         $nk = $1 if !$s->{quotekeys} and $nk =~ /^[\"\']([A-Za-z_]\w*)[\"\']$/;
 366         $sname = $mname . '{' . $nk . '}';
 367         $out .= $pad . $ipad . $nk . $pair;
 368
 369         # temporarily alter apad
 370         $s->{apad} .= (" " x (length($nk) + 4)) if $s->{indent} >= 2;
 371         $out .= $s->_dump($val->{$k}, $sname) . ",";
 372         $s->{apad} = $lpad if $s->{indent} >= 2;
 373       }
 374       if (substr($out, -1) eq ',') {
 375         chop $out;
 376         $out .= $pad . ($s->{xpad} x ($s->{level} - 1));
 377       }
 378       $out .= ($name =~ /^\%/) ? ')' : '}';
 379     }
 380     elsif ($realtype eq 'CODE') {
 381       if ($s->{deparse}) {
 382         require B::Deparse;
 383         my $sub =  'sub ' . (B::Deparse->new)->coderef2text($val);
 384         $pad    =  $s->{sep} . $s->{pad} . $s->{apad} . $s->{xpad} x ($s->{level} - 1);
 385         $sub    =~ s/\n/$pad/gse;
 386         $out   .=  $sub;
 387       } else {
 388         $out .= 'sub { "DUMMY" }';
 389         carp "Encountered CODE ref, using dummy placeholder" if $s->{purity};
 390       }
 391     }
 392     else {
 393       croak "Can\'t handle $realtype type.";
 394     }
 395
 396     if ($realpack) { # we have a blessed ref
 397       $out .= ', \'' . $realpack . '\'' . ' )';
 398       $out .= '->' . $s->{toaster} . '()'  if $s->{toaster} ne '';
 399       $s->{apad} = $blesspad;
 400     }
 401     $s->{level}--;
 402
 403   }
 404   else {                                 # simple scalar
 405
 406     my $ref = \$_[1];
 407     # first, catalog the scalar
 408     if ($name ne '') {
 409       ($id) = ("$ref" =~ /\(([^\(]*)\)$/);
 410       if (exists $s->{seen}{$id}) {
 411         if ($s->{seen}{$id}[2]) {
 412           $out = $s->{seen}{$id}[0];
 413           #warn "[<$out]\n";
 414           return "\${$out}";
 415         }
 416       }
 417       else {
 418         #warn "[>\\$name]\n";
 419         $s->{seen}{$id} = ["\\$name", $ref];
 420       }
 421     }
 422     if (ref($ref) eq 'GLOB' or "$ref" =~ /=GLOB\([^()]+\)$/) {  # glob
 423       my $name = substr($val, 1);
 424       if ($name =~ /^[A-Za-z_][\w:]*$/) {
 425         $name =~ s/^main::/::/;
 426         $sname = $name;
 427       }
 428       else {
 429         $sname = $s->_dump($name, "");
 430         $sname = '{' . $sname . '}';
 431       }
 432       if ($s->{purity}) {
 433         my $k;
 434         local ($s->{level}) = 0;
 435         for $k (qw(SCALAR ARRAY HASH)) {
 436           my $gval = *$val{$k};
 437           next unless defined $gval;
 438           next if $k eq "SCALAR" && ! defined $$gval;  # always there
 439
 440           # _dump can push into @post, so we hold our place using $postlen
 441           my $postlen = scalar @post;
 442           $post[$postlen] = "\*$sname = ";
 443           local ($s->{apad}) = " " x length($post[$postlen]) if $s->{indent} >= 2;
 444           $post[$postlen] .= $s->_dump($gval, "\*$sname\{$k\}");
 445         }
 446       }
 447       $out .= '*' . $sname;
 448     }
 449     elsif (!defined($val)) {
 450       $out .= "undef";
 451     }
 452     elsif ($val =~ /^(?:0|-?[1-9]\d{0,8})\z/) { # safe decimal number
 453       $out .= $val;
 454     }
 455     else {                               # string
 456       if ($s->{useqq} or $val =~ tr/\0-\377//c) {
 457         # Fall back to qq if there's unicode
 458         $out .= qquote($val, $s->{useqq});
 459       }
 460       else {
 461         $val =~ s/([\\\'])/\\$1/g;
 462         $out .= '\'' . $val .  '\'';
 463       }
 464     }
 465   }
 466   if ($id) {
 467     # if we made it this far, $id was added to seen list at current
 468     # level, so remove it to get deep copies
 469     if ($s->{deepcopy}) {
 470       delete($s->{seen}{$id});
 471     }
 472     elsif ($name) {
 473       $s->{seen}{$id}[2] = 1;
 474     }
 475   }
 476   return $out;
 477 }
 478
 479 #
 480 # non-OO style of earlier version
 481 #
 482 sub Dumper {
 483   return Data::Dumper->Dump([@_]);
 484 }
 485
 486 # compat stub
 487 sub DumperX {
 488   return Data::Dumper->Dumpxs([@_], []);
 489 }
 490
 491 sub Dumpf { return Data::Dumper->Dump(@_) }
 492
 493 sub Dumpp { print Data::Dumper->Dump(@_) }
 494
 495 #
 496 # reset the "seen" cache
 497 #
 498 sub Reset {
 499   my($s) = shift;
 500   $s->{seen} = {};
 501   return $s;
 502 }
 503
 504 sub Indent {
 505   my($s, $v) = @_;
 506   if (defined($v)) {
 507     if ($v == 0) {
 508       $s->{xpad} = "";
 509       $s->{sep} = "";
 510     }
 511     else {
 512       $s->{xpad} = "  ";
 513       $s->{sep} = "\n";
 514     }
 515     $s->{indent} = $v;
 516     return $s;
 517   }
 518   else {
 519     return $s->{indent};
 520   }
 521 }
 522
 523 sub Pair {
 524     my($s, $v) = @_;
 525     defined($v) ? (($s->{pair} = $v), return $s) : $s->{pair};
 526 }
 527
 528 sub Pad {
 529   my($s, $v) = @_;
 530   defined($v) ? (($s->{pad} = $v), return $s) : $s->{pad};
 531 }
 532
 533 sub Varname {
 534   my($s, $v) = @_;
 535   defined($v) ? (($s->{varname} = $v), return $s) : $s->{varname};
 536 }
 537
 538 sub Purity {
 539   my($s, $v) = @_;
 540   defined($v) ? (($s->{purity} = $v), return $s) : $s->{purity};
 541 }
 542
 543 sub Useqq {
 544   my($s, $v) = @_;
 545   defined($v) ? (($s->{useqq} = $v), return $s) : $s->{useqq};
 546 }
 547
 548 sub Terse {
 549   my($s, $v) = @_;
 550   defined($v) ? (($s->{terse} = $v), return $s) : $s->{terse};
 551 }
 552
 553 sub Freezer {
 554   my($s, $v) = @_;
 555   defined($v) ? (($s->{freezer} = $v), return $s) : $s->{freezer};
 556 }
 557
 558 sub Toaster {
 559   my($s, $v) = @_;
 560   defined($v) ? (($s->{toaster} = $v), return $s) : $s->{toaster};
 561 }
 562
 563 sub Deepcopy {
 564   my($s, $v) = @_;
 565   defined($v) ? (($s->{deepcopy} = $v), return $s) : $s->{deepcopy};
 566 }
 567
 568 sub Quotekeys {
 569   my($s, $v) = @_;
 570   defined($v) ? (($s->{quotekeys} = $v), return $s) : $s->{quotekeys};
 571 }
 572
 573 sub Bless {
 574   my($s, $v) = @_;
 575   defined($v) ? (($s->{'bless'} = $v), return $s) : $s->{'bless'};
 576 }
 577
 578 sub Maxdepth {
 579   my($s, $v) = @_;
 580   defined($v) ? (($s->{'maxdepth'} = $v), return $s) : $s->{'maxdepth'};
 581 }
 582
 583 sub Useperl {
 584   my($s, $v) = @_;
 585   defined($v) ? (($s->{'useperl'} = $v), return $s) : $s->{'useperl'};
 586 }
 587
 588 sub Sortkeys {
 589   my($s, $v) = @_;
 590   defined($v) ? (($s->{'sortkeys'} = $v), return $s) : $s->{'sortkeys'};
 591 }
 592
 593 sub Deparse {
 594   my($s, $v) = @_;
 595   defined($v) ? (($s->{'deparse'} = $v), return $s) : $s->{'deparse'};
 596 }
 597
 598 # used by qquote below
 599 my %esc = (
 600     "\a" => "\\a",
 601     "\b" => "\\b",
 602     "\t" => "\\t",
 603     "\n" => "\\n",
 604     "\f" => "\\f",
 605     "\r" => "\\r",
 606     "\e" => "\\e",
 607 );
 608
 609 # put a string value in double quotes
 610 sub qquote {
 611   local($_) = shift;
 612   s/([\\\"\@\$])/\\$1/g;
 613   my $bytes; { use bytes; $bytes = length }
 614   s/([^\x00-\x7f])/'\x{'.sprintf("%x",ord($1)).'}'/ge if $bytes > length;
 615   return qq("$_") unless
 616     /[^ !"\#\$%&'()*+,\-.\/0-9:;<=>?\@A-Z[\\\]^_`a-z{|}~]/;  # fast exit
 617
 618   my $high = shift || "";
 619   s/([\a\b\t\n\f\r\e])/$esc{$1}/g;
 620
 621   if (ord('^')==94)  { # ascii
 622     # no need for 3 digits in escape for these
 623     s/([\0-\037])(?!\d)/'\\'.sprintf('%o',ord($1))/eg;
 624     s/([\0-\037\177])/'\\'.sprintf('%03o',ord($1))/eg;
 625     # all but last branch below not supported --BEHAVIOR SUBJECT TO CHANGE--
 626     if ($high eq "iso8859") {
 627       s/([\200-\240])/'\\'.sprintf('%o',ord($1))/eg;
 628     } elsif ($high eq "utf8") {
 629 #     use utf8;
 630 #     $str =~ s/([^\040-\176])/sprintf "\\x{%04x}", ord($1)/ge;
 631     } elsif ($high eq "8bit") {
 632         # leave it as it is
 633     } else {
 634       s/([\200-\377])/'\\'.sprintf('%03o',ord($1))/eg;
 635       s/([^\040-\176])/sprintf "\\x{%04x}", ord($1)/ge;
 636     }
 637   }
 638   else { # ebcdic
 639       s{([^ !"\#\$%&'()*+,\-.\/0-9:;<=>?\@A-Z[\\\]^_`a-z{|}~])(?!\d)}
 640        {my $v = ord($1); '\\'.sprintf(($v <= 037 ? '%o' : '%03o'), $v)}eg;
 641       s{([^ !"\#\$%&'()*+,\-.\/0-9:;<=>?\@A-Z[\\\]^_`a-z{|}~])}
 642        {'\\'.sprintf('%03o',ord($1))}eg;
 643   }
 644
 645   return qq("$_");
 646 }
 647
 648 # helper sub to sort hash keys in Perl < 5.8.0 where we don't have
 649 # access to sortsv() from XS
 650 sub _sortkeys { [ sort keys %{$_[0]} ] }
 651
 652 1;
 653 __END__
 654
 655 =head1 NAME
 656
 657 Data::Dumper - stringified perl data structures, suitable for both printing and C<eval>
 658
 659 =head1 SYNOPSIS
 660
 661     use Data::Dumper;
 662
 663     # simple procedural interface
 664     print Dumper($foo, $bar);
 665
 666     # extended usage with names
 667     print Data::Dumper->Dump([$foo, $bar], [qw(foo *ary)]);
 668
 669     # configuration variables
 670     {
 671       local $Data::Dumper::Purity = 1;
 672       eval Data::Dumper->Dump([$foo, $bar], [qw(foo *ary)]);
 673     }
 674
 675     # OO usage
 676     $d = Data::Dumper->new([$foo, $bar], [qw(foo *ary)]);
 677        ...
 678     print $d->Dump;
 679        ...
 680     $d->Purity(1)->Terse(1)->Deepcopy(1);
 681     eval $d->Dump;
 682
 683
 684 =head1 DESCRIPTION
 685
 686 Given a list of scalars or reference variables, writes out their contents in
 687 perl syntax. The references can also be objects.  The contents of each
 688 variable is output in a single Perl statement.  Handles self-referential
 689 structures correctly.
 690
 691 The return value can be C<eval>ed to get back an identical copy of the
 692 original reference structure.
 693
 694 Any references that are the same as one of those passed in will be named
 695 C<$VAR>I<n> (where I<n> is a numeric suffix), and other duplicate references
 696 to substructures within C<$VAR>I<n> will be appropriately labeled using arrow
 697 notation.  You can specify names for individual values to be dumped if you
 698 use the C<Dump()> method, or you can change the default C<$VAR> prefix to
 699 something else.  See C<$Data::Dumper::Varname> and C<$Data::Dumper::Terse>
 700 below.
 701
 702 The default output of self-referential structures can be C<eval>ed, but the
 703 nested references to C<$VAR>I<n> will be undefined, since a recursive
 704 structure cannot be constructed using one Perl statement.  You should set the
 705 C<Purity> flag to 1 to get additional statements that will correctly fill in
 706 these references.  Moreover, if C<eval>ed when strictures are in effect,
 707 you need to ensure that any variables it accesses are previously declared.
 708
 709 In the extended usage form, the references to be dumped can be given
 710 user-specified names.  If a name begins with a C<*>, the output will
 711 describe the dereferenced type of the supplied reference for hashes and
 712 arrays, and coderefs.  Output of names will be avoided where possible if
 713 the C<Terse> flag is set.
 714
 715 In many cases, methods that are used to set the internal state of the
 716 object will return the object itself, so method calls can be conveniently
 717 chained together.
 718
 719 Several styles of output are possible, all controlled by setting
 720 the C<Indent> flag.  See L<Configuration Variables or Methods> below
 721 for details.
 722
 723
 724 =head2 Methods
 725
 726 =over 4
 727
 728 =item I<PACKAGE>->new(I<ARRAYREF [>, I<ARRAYREF]>)
 729
 730 Returns a newly created C<Data::Dumper> object.  The first argument is an
 731 anonymous array of values to be dumped.  The optional second argument is an
 732 anonymous array of names for the values.  The names need not have a leading
 733 C<$> sign, and must be comprised of alphanumeric characters.  You can begin
 734 a name with a C<*> to specify that the dereferenced type must be dumped
 735 instead of the reference itself, for ARRAY and HASH references.
 736
 737 The prefix specified by C<$Data::Dumper::Varname> will be used with a
 738 numeric suffix if the name for a value is undefined.
 739
 740 Data::Dumper will catalog all references encountered while dumping the
 741 values. Cross-references (in the form of names of substructures in perl
 742 syntax) will be inserted at all possible points, preserving any structural
 743 interdependencies in the original set of values.  Structure traversal is
 744 depth-first,  and proceeds in order from the first supplied value to
 745 the last.
 746
 747 =item I<$OBJ>->Dump  I<or>  I<PACKAGE>->Dump(I<ARRAYREF [>, I<ARRAYREF]>)
 748
 749 Returns the stringified form of the values stored in the object (preserving
 750 the order in which they were supplied to C<new>), subject to the
 751 configuration options below.  In a list context, it returns a list
 752 of strings corresponding to the supplied values.
 753
 754 The second form, for convenience, simply calls the C<new> method on its
 755 arguments before dumping the object immediately.
 756
 757 =item I<$OBJ>->Seen(I<[HASHREF]>)
 758
 759 Queries or adds to the internal table of already encountered references.
 760 You must use C<Reset> to explicitly clear the table if needed.  Such
 761 references are not dumped; instead, their names are inserted wherever they
 762 are encountered subsequently.  This is useful especially for properly
 763 dumping subroutine references.
 764
 765 Expects an anonymous hash of name => value pairs.  Same rules apply for names
 766 as in C<new>.  If no argument is supplied, will return the "seen" list of
 767 name => value pairs, in a list context.  Otherwise, returns the object
 768 itself.
 769
 770 =item I<$OBJ>->Values(I<[ARRAYREF]>)
 771
 772 Queries or replaces the internal array of values that will be dumped.
 773 When called without arguments, returns the values.  Otherwise, returns the
 774 object itself.
 775
 776 =item I<$OBJ>->Names(I<[ARRAYREF]>)
 777
 778 Queries or replaces the internal array of user supplied names for the values
 779 that will be dumped.  When called without arguments, returns the names.
 780 Otherwise, returns the object itself.
 781
 782 =item I<$OBJ>->Reset
 783
 784 Clears the internal table of "seen" references and returns the object
 785 itself.
 786
 787 =back
 788
 789 =head2 Functions
 790
 791 =over 4
 792
 793 =item Dumper(I<LIST>)
 794
 795 Returns the stringified form of the values in the list, subject to the
 796 configuration options below.  The values will be named C<$VAR>I<n> in the
 797 output, where I<n> is a numeric suffix.  Will return a list of strings
 798 in a list context.
 799
 800 =back
 801
 802 =head2 Configuration Variables or Methods
 803
 804 Several configuration variables can be used to control the kind of output
 805 generated when using the procedural interface.  These variables are usually
 806 C<local>ized in a block so that other parts of the code are not affected by
 807 the change.
 808
 809 These variables determine the default state of the object created by calling
 810 the C<new> method, but cannot be used to alter the state of the object
 811 thereafter.  The equivalent method names should be used instead to query
 812 or set the internal state of the object.
 813
 814 The method forms return the object itself when called with arguments,
 815 so that they can be chained together nicely.
 816
 817 =over 4
 818
 819 =item *
 820
 821 $Data::Dumper::Indent  I<or>  I<$OBJ>->Indent(I<[NEWVAL]>)
 822
 823 Controls the style of indentation.  It can be set to 0, 1, 2 or 3.  Style 0
 824 spews output without any newlines, indentation, or spaces between list
 825 items.  It is the most compact format possible that can still be called
 826 valid perl.  Style 1 outputs a readable form with newlines but no fancy
 827 indentation (each level in the structure is simply indented by a fixed
 828 amount of whitespace).  Style 2 (the default) outputs a very readable form
 829 which takes into account the length of hash keys (so the hash value lines
 830 up).  Style 3 is like style 2, but also annotates the elements of arrays
 831 with their index (but the comment is on its own line, so array output
 832 consumes twice the number of lines).  Style 2 is the default.
 833
 834 =item *
 835
 836 $Data::Dumper::Purity  I<or>  I<$OBJ>->Purity(I<[NEWVAL]>)
 837
 838 Controls the degree to which the output can be C<eval>ed to recreate the
 839 supplied reference structures.  Setting it to 1 will output additional perl
 840 statements that will correctly recreate nested references.  The default is
 841 0.
 842
 843 =item *
 844
 845 $Data::Dumper::Pad  I<or>  I<$OBJ>->Pad(I<[NEWVAL]>)
 846
 847 Specifies the string that will be prefixed to every line of the output.
 848 Empty string by default.
 849
 850 =item *
 851
 852 $Data::Dumper::Varname  I<or>  I<$OBJ>->Varname(I<[NEWVAL]>)
 853
 854 Contains the prefix to use for tagging variable names in the output. The
 855 default is "VAR".
 856
 857 =item *
 858
 859 $Data::Dumper::Useqq  I<or>  I<$OBJ>->Useqq(I<[NEWVAL]>)
 860
 861 When set, enables the use of double quotes for representing string values.
 862 Whitespace other than space will be represented as C<[\n\t\r]>, "unsafe"
 863 characters will be backslashed, and unprintable characters will be output as
 864 quoted octal integers.  Since setting this variable imposes a performance
 865 penalty, the default is 0.  C<Dump()> will run slower if this flag is set,
 866 since the fast XSUB implementation doesn't support it yet.
 867
 868 =item *
 869
 870 $Data::Dumper::Terse  I<or>  I<$OBJ>->Terse(I<[NEWVAL]>)
 871
 872 When set, Data::Dumper will emit single, non-self-referential values as
 873 atoms/terms rather than statements.  This means that the C<$VAR>I<n> names
 874 will be avoided where possible, but be advised that such output may not
 875 always be parseable by C<eval>.
 876
 877 =item *
 878
 879 $Data::Dumper::Freezer  I<or>  $I<OBJ>->Freezer(I<[NEWVAL]>)
 880
 881 Can be set to a method name, or to an empty string to disable the feature.
 882 Data::Dumper will invoke that method via the object before attempting to
 883 stringify it.  This method can alter the contents of the object (if, for
 884 instance, it contains data allocated from C), and even rebless it in a
 885 different package.  The client is responsible for making sure the specified
 886 method can be called via the object, and that the object ends up containing
 887 only perl data types after the method has been called.  Defaults to an empty
 888 string.
 889
 890 =item *
 891
 892 $Data::Dumper::Toaster  I<or>  $I<OBJ>->Toaster(I<[NEWVAL]>)
 893
 894 Can be set to a method name, or to an empty string to disable the feature.
 895 Data::Dumper will emit a method call for any objects that are to be dumped
 896 using the syntax C<bless(DATA, CLASS)-E<gt>METHOD()>.  Note that this means that
 897 the method specified will have to perform any modifications required on the
 898 object (like creating new state within it, and/or reblessing it in a
 899 different package) and then return it.  The client is responsible for making
 900 sure the method can be called via the object, and that it returns a valid
 901 object.  Defaults to an empty string.
 902
 903 =item *
 904
 905 $Data::Dumper::Deepcopy  I<or>  $I<OBJ>->Deepcopy(I<[NEWVAL]>)
 906
 907 Can be set to a boolean value to enable deep copies of structures.
 908 Cross-referencing will then only be done when absolutely essential
 909 (i.e., to break reference cycles).  Default is 0.
 910
 911 =item *
 912
 913 $Data::Dumper::Quotekeys  I<or>  $I<OBJ>->Quotekeys(I<[NEWVAL]>)
 914
 915 Can be set to a boolean value to control whether hash keys are quoted.
 916 A false value will avoid quoting hash keys when it looks like a simple
 917 string.  Default is 1, which will always enclose hash keys in quotes.
 918
 919 =item *
 920
 921 $Data::Dumper::Bless  I<or>  $I<OBJ>->Bless(I<[NEWVAL]>)
 922
 923 Can be set to a string that specifies an alternative to the C<bless>
 924 builtin operator used to create objects.  A function with the specified
 925 name should exist, and should accept the same arguments as the builtin.
 926 Default is C<bless>.
 927
 928 =item *
 929
 930 $Data::Dumper::Pair  I<or>  $I<OBJ>->Pair(I<[NEWVAL]>)
 931
 932 Can be set to a string that specifies the separator between hash keys
 933 and values. To dump nested hash, array and scalar values to JavaScript,
 934 use: C<$Data::Dumper::Pair = ' : ';>. Implementing C<bless> in JavaScript
 935 is left as an exercise for the reader.
 936 A function with the specified name exists, and accepts the same arguments
 937 as the builtin.
 938
 939 Default is: C< =E<gt> >.
 940
 941 =item *
 942
 943 $Data::Dumper::Maxdepth  I<or>  $I<OBJ>->Maxdepth(I<[NEWVAL]>)
 944
 945 Can be set to a positive integer that specifies the depth beyond which
 946 which we don't venture into a structure.  Has no effect when
 947 C<Data::Dumper::Purity> is set.  (Useful in debugger when we often don't
 948 want to see more than enough).  Default is 0, which means there is
 949 no maximum depth.
 950
 951 =item *
 952
 953 $Data::Dumper::Useperl  I<or>  $I<OBJ>->Useperl(I<[NEWVAL]>)
 954
 955 Can be set to a boolean value which controls whether the pure Perl
 956 implementation of C<Data::Dumper> is used. The C<Data::Dumper> module is
 957 a dual implementation, with almost all functionality written in both
 958 pure Perl and also in XS ('C'). Since the XS version is much faster, it
 959 will always be used if possible. This option lets you override the
 960 default behavior, usually for testing purposes only. Default is 0, which
 961 means the XS implementation will be used if possible.
 962
 963 =item *
 964
 965 $Data::Dumper::Sortkeys  I<or>  $I<OBJ>->Sortkeys(I<[NEWVAL]>)
 966
 967 Can be set to a boolean value to control whether hash keys are dumped in
 968 sorted order. A true value will cause the keys of all hashes to be
 969 dumped in Perl's default sort order. Can also be set to a subroutine
 970 reference which will be called for each hash that is dumped. In this
 971 case C<Data::Dumper> will call the subroutine once for each hash,
 972 passing it the reference of the hash. The purpose of the subroutine is
 973 to return a reference to an array of the keys that will be dumped, in
 974 the order that they should be dumped. Using this feature, you can
 975 control both the order of the keys, and which keys are actually used. In
 976 other words, this subroutine acts as a filter by which you can exclude
 977 certain keys from being dumped. Default is 0, which means that hash keys
 978 are not sorted.
 979
 980 =item *
 981
 982 $Data::Dumper::Deparse  I<or>  $I<OBJ>->Deparse(I<[NEWVAL]>)
 983
 984 Can be set to a boolean value to control whether code references are
 985 turned into perl source code. If set to a true value, C<B::Deparse>
 986 will be used to get the source of the code reference. Using this option
 987 will force using the Perl implementation of the dumper, since the fast
 988 XSUB implementation doesn't support it.
 989
 990 Caution : use this option only if you know that your coderefs will be
 991 properly reconstructed by C<B::Deparse>.
 992
 993 =back
 994
 995 =head2 Exports
 996
 997 =over 4
 998
 999 =item Dumper
1000
1001 =back
1002
1003 =head1 EXAMPLES
1004
1005 Run these code snippets to get a quick feel for the behavior of this
1006 module.  When you are through with these examples, you may want to
1007 add or change the various configuration variables described above,
1008 to see their behavior.  (See the testsuite in the Data::Dumper
1009 distribution for more examples.)
1010
1011
1012     use Data::Dumper;
1013
1014     package Foo;
1015     sub new {bless {'a' => 1, 'b' => sub { return "foo" }}, $_[0]};
1016
1017     package Fuz;                       # a weird REF-REF-SCALAR object
1018     sub new {bless \($_ = \ 'fu\'z'), $_[0]};
1019
1020     package main;
1021     $foo = Foo->new;
1022     $fuz = Fuz->new;
1023     $boo = [ 1, [], "abcd", \*foo,
1024              {1 => 'a', 023 => 'b', 0x45 => 'c'},
1025              \\"p\q\'r", $foo, $fuz];
1026
1027     ########
1028     # simple usage
1029     ########
1030
1031     $bar = eval(Dumper($boo));
1032     print($@) if $@;
1033     print Dumper($boo), Dumper($bar);  # pretty print (no array indices)
1034
1035     $Data::Dumper::Terse = 1;          # don't output names where feasible
1036     $Data::Dumper::Indent = 0;         # turn off all pretty print
1037     print Dumper($boo), "\n";
1038
1039     $Data::Dumper::Indent = 1;         # mild pretty print
1040     print Dumper($boo);
1041
1042     $Data::Dumper::Indent = 3;         # pretty print with array indices
1043     print Dumper($boo);
1044
1045     $Data::Dumper::Useqq = 1;          # print strings in double quotes
1046     print Dumper($boo);
1047
1048     $Data::Dumper::Pair = " : ";       # specify hash key/value separator
1049     print Dumper($boo);
1050
1051
1052     ########
1053     # recursive structures
1054     ########
1055
1056     @c = ('c');
1057     $c = \@c;
1058     $b = {};
1059     $a = [1, $b, $c];
1060     $b->{a} = $a;
1061     $b->{b} = $a->[1];
1062     $b->{c} = $a->[2];
1063     print Data::Dumper->Dump([$a,$b,$c], [qw(a b c)]);
1064
1065
1066     $Data::Dumper::Purity = 1;         # fill in the holes for eval
1067     print Data::Dumper->Dump([$a, $b], [qw(*a b)]); # print as @a
1068     print Data::Dumper->Dump([$b, $a], [qw(*b a)]); # print as %b
1069
1070
1071     $Data::Dumper::Deepcopy = 1;       # avoid cross-refs
1072     print Data::Dumper->Dump([$b, $a], [qw(*b a)]);
1073
1074
1075     $Data::Dumper::Purity = 0;         # avoid cross-refs
1076     print Data::Dumper->Dump([$b, $a], [qw(*b a)]);
1077
1078     ########
1079     # deep structures
1080     ########
1081
1082     $a = "pearl";
1083     $b = [ $a ];
1084     $c = { 'b' => $b };
1085     $d = [ $c ];
1086     $e = { 'd' => $d };
1087     $f = { 'e' => $e };
1088     print Data::Dumper->Dump([$f], [qw(f)]);
1089
1090     $Data::Dumper::Maxdepth = 3;       # no deeper than 3 refs down
1091     print Data::Dumper->Dump([$f], [qw(f)]);
1092
1093
1094     ########
1095     # object-oriented usage
1096     ########
1097
1098     $d = Data::Dumper->new([$a,$b], [qw(a b)]);
1099     $d->Seen({'*c' => $c});            # stash a ref without printing it
1100     $d->Indent(3);
1101     print $d->Dump;
1102     $d->Reset->Purity(0);              # empty the seen cache
1103     print join "----\n", $d->Dump;
1104
1105
1106     ########
1107     # persistence
1108     ########
1109
1110     package Foo;
1111     sub new { bless { state => 'awake' }, shift }
1112     sub Freeze {
1113         my $s = shift;
1114         print STDERR "preparing to sleep\n";
1115         $s->{state} = 'asleep';
1116         return bless $s, 'Foo::ZZZ';
1117     }
1118
1119     package Foo::ZZZ;
1120     sub Thaw {
1121         my $s = shift;
1122         print STDERR "waking up\n";
1123         $s->{state} = 'awake';
1124         return bless $s, 'Foo';
1125     }
1126
1127     package Foo;
1128     use Data::Dumper;
1129     $a = Foo->new;
1130     $b = Data::Dumper->new([$a], ['c']);
1131     $b->Freezer('Freeze');
1132     $b->Toaster('Thaw');
1133     $c = $b->Dump;
1134     print $c;
1135     $d = eval $c;
1136     print Data::Dumper->Dump([$d], ['d']);
1137
1138
1139     ########
1140     # symbol substitution (useful for recreating CODE refs)
1141     ########
1142
1143     sub foo { print "foo speaking\n" }
1144     *other = \&foo;
1145     $bar = [ \&other ];
1146     $d = Data::Dumper->new([\&other,$bar],['*other','bar']);
1147     $d->Seen({ '*foo' => \&foo });
1148     print $d->Dump;
1149
1150
1151     ########
1152     # sorting and filtering hash keys
1153     ########
1154
1155     $Data::Dumper::Sortkeys = \&my_filter;
1156     my $foo = { map { (ord, "$_$_$_") } 'I'..'Q' };
1157     my $bar = { %$foo };
1158     my $baz = { reverse %$foo };
1159     print Dumper [ $foo, $bar, $baz ];
1160
1161     sub my_filter {
1162         my ($hash) = @_;
1163         # return an array ref containing the hash keys to dump
1164         # in the order that you want them to be dumped
1165         return [
1166           # Sort the keys of %$foo in reverse numeric order
1167             $hash eq $foo ? (sort {$b <=> $a} keys %$hash) :
1168           # Only dump the odd number keys of %$bar
1169             $hash eq $bar ? (grep {$_ % 2} keys %$hash) :
1170           # Sort keys in default order for all other hashes
1171             (sort keys %$hash)
1172         ];
1173     }
1174
1175 =head1 BUGS
1176
1177 Due to limitations of Perl subroutine call semantics, you cannot pass an
1178 array or hash.  Prepend it with a C<\> to pass its reference instead.  This
1179 will be remedied in time, now that Perl has subroutine prototypes.
1180 For now, you need to use the extended usage form, and prepend the
1181 name with a C<*> to output it as a hash or array.
1182
1183 C<Data::Dumper> cheats with CODE references.  If a code reference is
1184 encountered in the structure being processed (and if you haven't set
1185 the C<Deparse> flag), an anonymous subroutine that
1186 contains the string '"DUMMY"' will be inserted in its place, and a warning
1187 will be printed if C<Purity> is set.  You can C<eval> the result, but bear
1188 in mind that the anonymous sub that gets created is just a placeholder.
1189 Someday, perl will have a switch to cache-on-demand the string
1190 representation of a compiled piece of code, I hope.  If you have prior
1191 knowledge of all the code refs that your data structures are likely
1192 to have, you can use the C<Seen> method to pre-seed the internal reference
1193 table and make the dumped output point to them, instead.  See L<EXAMPLES>
1194 above.
1195
1196 The C<Useqq> and C<Deparse> flags makes Dump() run slower, since the
1197 XSUB implementation does not support them.
1198
1199 SCALAR objects have the weirdest looking C<bless> workaround.
1200
1201 Pure Perl version of C<Data::Dumper> escapes UTF-8 strings correctly
1202 only in Perl 5.8.0 and later.
1203
1204 =head2 NOTE
1205
1206 Starting from Perl 5.8.1 different runs of Perl will have different
1207 ordering of hash keys.  The change was done for greater security,
1208 see L<perlsec/"Algorithmic Complexity Attacks">.  This means that
1209 different runs of Perl will have different Data::Dumper outputs if
1210 the data contains hashes.  If you need to have identical Data::Dumper
1211 outputs from different runs of Perl, use the environment variable
1212 PERL_HASH_SEED, see L<perlrun/PERL_HASH_SEED>.  Using this restores
1213 the old (platform-specific) ordering: an even prettier solution might
1214 be to use the C<Sortkeys> filter of Data::Dumper.
1215
1216 =head1 AUTHOR
1217
1218 Gurusamy Sarathy        gsar@activestate.com
1219
1220 Copyright (c) 1996-98 Gurusamy Sarathy. All rights reserved.
1221 This program is free software; you can redistribute it and/or
1222 modify it under the same terms as Perl itself.
1223
1224 =head1 VERSION
1225
1226 Version 2.121  (Aug 24 2003)
1227
1228 =head1 SEE ALSO
1229
1230 perl(1)
1231
1232 =cut