ext/Data/Dumper/Dumper.pm

   1 #
   2 # Data/Dumper.pm
   3 #
   4 # convert perl data structures into perl syntax suitable for both printing
   5 # and eval
   6 #
   7 # Documentation at the __END__
   8 #
   9
  10 package Data::Dumper;
  11
  12 $VERSION = '2.121_03';
  13
  14 #$| = 1;
  15
  16 use 5.006_001;
  17 require Exporter;
  18 use XSLoader ();
  19 require overload;
  20
  21 use Carp;
  22
  23 @ISA = qw(Exporter);
  24 @EXPORT = qw(Dumper);
  25 @EXPORT_OK = qw(DumperX);
  26
  27 XSLoader::load 'Data::Dumper';
  28
  29 # module vars and their defaults
  30 $Indent = 2 unless defined $Indent;
  31 $Purity = 0 unless defined $Purity;
  32 $Pad = "" unless defined $Pad;
  33 $Varname = "VAR" unless defined $Varname;
  34 $Useqq = 0 unless defined $Useqq;
  35 $Terse = 0 unless defined $Terse;
  36 $Freezer = "" unless defined $Freezer;
  37 $Toaster = "" unless defined $Toaster;
  38 $Deepcopy = 0 unless defined $Deepcopy;
  39 $Quotekeys = 1 unless defined $Quotekeys;
  40 $Bless = "bless" unless defined $Bless;
  41 #$Expdepth = 0 unless defined $Expdepth;
  42 $Maxdepth = 0 unless defined $Maxdepth;
  43 $Pair = ' => ' unless defined $Pair;
  44 $Useperl = 0 unless defined $Useperl;
  45 $Sortkeys = 0 unless defined $Sortkeys;
  46 $Deparse = 0 unless defined $Deparse;
  47
  48 #
  49 # expects an arrayref of values to be dumped.
  50 # can optionally pass an arrayref of names for the values.
  51 # names must have leading $ sign stripped. begin the name with *
  52 # to cause output of arrays and hashes rather than refs.
  53 #
  54 sub new {
  55   my($c, $v, $n) = @_;
  56
  57   croak "Usage:  PACKAGE->new(ARRAYREF, [ARRAYREF])"
  58     unless (defined($v) && (ref($v) eq 'ARRAY'));
  59   $n = [] unless (defined($n) && (ref($v) eq 'ARRAY'));
  60
  61   my($s) = {
  62              level      => 0,           # current recursive depth
  63              indent     => $Indent,     # various styles of indenting
  64              pad        => $Pad,        # all lines prefixed by this string
  65              xpad       => "",          # padding-per-level
  66              apad       => "",          # added padding for hash keys n such
  67              sep        => "",          # list separator
  68              pair       => $Pair,       # hash key/value separator: defaults to ' => '
  69              seen       => {},          # local (nested) refs (id => [name, val])
  70              todump     => $v,          # values to dump []
  71              names      => $n,          # optional names for values []
  72              varname    => $Varname,    # prefix to use for tagging nameless ones
  73              purity     => $Purity,     # degree to which output is evalable
  74              useqq      => $Useqq,      # use "" for strings (backslashitis ensues)
  75              terse      => $Terse,      # avoid name output (where feasible)
  76              freezer    => $Freezer,    # name of Freezer method for objects
  77              toaster    => $Toaster,    # name of method to revive objects
  78              deepcopy   => $Deepcopy,   # dont cross-ref, except to stop recursion
  79              quotekeys  => $Quotekeys,  # quote hash keys
  80              'bless'    => $Bless,      # keyword to use for "bless"
  81 #            expdepth   => $Expdepth,   # cutoff depth for explicit dumping
  82              maxdepth   => $Maxdepth,   # depth beyond which we give up
  83              useperl    => $Useperl,    # use the pure Perl implementation
  84              sortkeys   => $Sortkeys,   # flag or filter for sorting hash keys
  85              deparse    => $Deparse,    # use B::Deparse for coderefs
  86            };
  87
  88   if ($Indent > 0) {
  89     $s->{xpad} = "  ";
  90     $s->{sep} = "\n";
  91   }
  92   return bless($s, $c);
  93 }
  94
  95 #
  96 # add-to or query the table of already seen references
  97 #
  98 sub Seen {
  99   my($s, $g) = @_;
 100   if (defined($g) && (ref($g) eq 'HASH'))  {
 101     my($k, $v, $id);
 102     while (($k, $v) = each %$g) {
 103       if (defined $v and ref $v) {
 104         ($id) = (overload::StrVal($v) =~ /\((.*)\)$/);
 105         if ($k =~ /^[*](.*)$/) {
 106           $k = (ref $v eq 'ARRAY') ? ( "\\\@" . $1 ) :
 107                (ref $v eq 'HASH')  ? ( "\\\%" . $1 ) :
 108                (ref $v eq 'CODE')  ? ( "\\\&" . $1 ) :
 109                                      (   "\$" . $1 ) ;
 110         }
 111         elsif ($k !~ /^\$/) {
 112           $k = "\$" . $k;
 113         }
 114         $s->{seen}{$id} = [$k, $v];
 115       }
 116       else {
 117         carp "Only refs supported, ignoring non-ref item \$$k";
 118       }
 119     }
 120     return $s;
 121   }
 122   else {
 123     return map { @$_ } values %{$s->{seen}};
 124   }
 125 }
 126
 127 #
 128 # set or query the values to be dumped
 129 #
 130 sub Values {
 131   my($s, $v) = @_;
 132   if (defined($v) && (ref($v) eq 'ARRAY'))  {
 133     $s->{todump} = [@$v];        # make a copy
 134     return $s;
 135   }
 136   else {
 137     return @{$s->{todump}};
 138   }
 139 }
 140
 141 #
 142 # set or query the names of the values to be dumped
 143 #
 144 sub Names {
 145   my($s, $n) = @_;
 146   if (defined($n) && (ref($n) eq 'ARRAY'))  {
 147     $s->{names} = [@$n];         # make a copy
 148     return $s;
 149   }
 150   else {
 151     return @{$s->{names}};
 152   }
 153 }
 154
 155 sub DESTROY {}
 156
 157 sub Dump {
 158     return &Dumpxs
 159         unless $Data::Dumper::Useperl || (ref($_[0]) && $_[0]->{useperl}) ||
 160                $Data::Dumper::Useqq   || (ref($_[0]) && $_[0]->{useqq}) ||
 161                $Data::Dumper::Deparse || (ref($_[0]) && $_[0]->{deparse});
 162     return &Dumpperl;
 163 }
 164
 165 #
 166 # dump the refs in the current dumper object.
 167 # expects same args as new() if called via package name.
 168 #
 169 sub Dumpperl {
 170   my($s) = shift;
 171   my(@out, $val, $name);
 172   my($i) = 0;
 173   local(@post);
 174
 175   $s = $s->new(@_) unless ref $s;
 176
 177   for $val (@{$s->{todump}}) {
 178     my $out = "";
 179     @post = ();
 180     $name = $s->{names}[$i++];
 181     if (defined $name) {
 182       if ($name =~ /^[*](.*)$/) {
 183         if (defined $val) {
 184           $name = (ref $val eq 'ARRAY') ? ( "\@" . $1 ) :
 185                   (ref $val eq 'HASH')  ? ( "\%" . $1 ) :
 186                   (ref $val eq 'CODE')  ? ( "\*" . $1 ) :
 187                                           ( "\$" . $1 ) ;
 188         }
 189         else {
 190           $name = "\$" . $1;
 191         }
 192       }
 193       elsif ($name !~ /^\$/) {
 194         $name = "\$" . $name;
 195       }
 196     }
 197     else {
 198       $name = "\$" . $s->{varname} . $i;
 199     }
 200
 201     my $valstr;
 202     {
 203       local($s->{apad}) = $s->{apad};
 204       $s->{apad} .= ' ' x (length($name) + 3) if $s->{indent} >= 2;
 205       $valstr = $s->_dump($val, $name);
 206     }
 207
 208     $valstr = "$name = " . $valstr . ';' if @post or !$s->{terse};
 209     $out .= $s->{pad} . $valstr . $s->{sep};
 210     $out .= $s->{pad} . join(';' . $s->{sep} . $s->{pad}, @post)
 211       . ';' . $s->{sep} if @post;
 212
 213     push @out, $out;
 214   }
 215   return wantarray ? @out : join('', @out);
 216 }
 217
 218 #
 219 # twist, toil and turn;
 220 # and recurse, of course.
 221 # sometimes sordidly;
 222 # and curse if no recourse.
 223 #
 224 sub _dump {
 225   my($s, $val, $name) = @_;
 226   my($sname);
 227   my($out, $realpack, $realtype, $type, $ipad, $id, $blesspad);
 228
 229   $type = ref $val;
 230   $out = "";
 231
 232   if ($type) {
 233
 234     # Call the freezer method if it's specified and the object has the
 235     # method.  Trap errors and warn() instead of die()ing, like the XS
 236     # implementation.
 237     my $freezer = $s->{freezer};
 238     if ($freezer and UNIVERSAL::can($val, $freezer)) {
 239       eval { $val->$freezer() };
 240       warn "WARNING(Freezer method call failed): $@" if $@;
 241     }
 242
 243     ($realpack, $realtype, $id) =
 244       (overload::StrVal($val) =~ /^(?:(.*)\=)?([^=]*)\(([^\(]*)\)$/);
 245
 246     # if it has a name, we need to either look it up, or keep a tab
 247     # on it so we know when we hit it later
 248     if (defined($name) and length($name)) {
 249       # keep a tab on it so that we dont fall into recursive pit
 250       if (exists $s->{seen}{$id}) {
 251 #       if ($s->{expdepth} < $s->{level}) {
 252           if ($s->{purity} and $s->{level} > 0) {
 253             $out = ($realtype eq 'HASH')  ? '{}' :
 254               ($realtype eq 'ARRAY') ? '[]' :
 255                 'do{my $o}' ;
 256             push @post, $name . " = " . $s->{seen}{$id}[0];
 257           }
 258           else {
 259             $out = $s->{seen}{$id}[0];
 260             if ($name =~ /^([\@\%])/) {
 261               my $start = $1;
 262               if ($out =~ /^\\$start/) {
 263                 $out = substr($out, 1);
 264               }
 265               else {
 266                 $out = $start . '{' . $out . '}';
 267               }
 268             }
 269           }
 270           return $out;
 271 #        }
 272       }
 273       else {
 274         # store our name
 275         $s->{seen}{$id} = [ (($name =~ /^[@%]/)     ? ('\\' . $name ) :
 276                              ($realtype eq 'CODE' and
 277                               $name =~ /^[*](.*)$/) ? ('\\&' . $1 )   :
 278                              $name          ),
 279                             $val ];
 280       }
 281     }
 282
 283     if ($realpack and $realpack eq 'Regexp') {
 284         $out = "$val";
 285         $out =~ s,/,\\/,g;
 286         return "qr/$out/";
 287     }
 288
 289     # If purity is not set and maxdepth is set, then check depth:
 290     # if we have reached maximum depth, return the string
 291     # representation of the thing we are currently examining
 292     # at this depth (i.e., 'Foo=ARRAY(0xdeadbeef)').
 293     if (!$s->{purity}
 294         and $s->{maxdepth} > 0
 295         and $s->{level} >= $s->{maxdepth})
 296     {
 297       return qq['$val'];
 298     }
 299
 300     # we have a blessed ref
 301     if ($realpack) {
 302       $out = $s->{'bless'} . '( ';
 303       $blesspad = $s->{apad};
 304       $s->{apad} .= '       ' if ($s->{indent} >= 2);
 305     }
 306
 307     $s->{level}++;
 308     $ipad = $s->{xpad} x $s->{level};
 309
 310     if ($realtype eq 'SCALAR' || $realtype eq 'REF') {
 311       if ($realpack) {
 312         $out .= 'do{\\(my $o = ' . $s->_dump($$val, "\${$name}") . ')}';
 313       }
 314       else {
 315         $out .= '\\' . $s->_dump($$val, "\${$name}");
 316       }
 317     }
 318     elsif ($realtype eq 'GLOB') {
 319         $out .= '\\' . $s->_dump($$val, "*{$name}");
 320     }
 321     elsif ($realtype eq 'ARRAY') {
 322       my($v, $pad, $mname);
 323       my($i) = 0;
 324       $out .= ($name =~ /^\@/) ? '(' : '[';
 325       $pad = $s->{sep} . $s->{pad} . $s->{apad};
 326       ($name =~ /^\@(.*)$/) ? ($mname = "\$" . $1) :
 327         # omit -> if $foo->[0]->{bar}, but not ${$foo->[0]}->{bar}
 328         ($name =~ /^\\?[\%\@\*\$][^{].*[]}]$/) ? ($mname = $name) :
 329           ($mname = $name . '->');
 330       $mname .= '->' if $mname =~ /^\*.+\{[A-Z]+\}$/;
 331       for $v (@$val) {
 332         $sname = $mname . '[' . $i . ']';
 333         $out .= $pad . $ipad . '#' . $i if $s->{indent} >= 3;
 334         $out .= $pad . $ipad . $s->_dump($v, $sname);
 335         $out .= "," if $i++ < $#$val;
 336       }
 337       $out .= $pad . ($s->{xpad} x ($s->{level} - 1)) if $i;
 338       $out .= ($name =~ /^\@/) ? ')' : ']';
 339     }
 340     elsif ($realtype eq 'HASH') {
 341       my($k, $v, $pad, $lpad, $mname, $pair);
 342       $out .= ($name =~ /^\%/) ? '(' : '{';
 343       $pad = $s->{sep} . $s->{pad} . $s->{apad};
 344       $lpad = $s->{apad};
 345       $pair = $s->{pair};
 346       ($name =~ /^\%(.*)$/) ? ($mname = "\$" . $1) :
 347         # omit -> if $foo->[0]->{bar}, but not ${$foo->[0]}->{bar}
 348         ($name =~ /^\\?[\%\@\*\$][^{].*[]}]$/) ? ($mname = $name) :
 349           ($mname = $name . '->');
 350       $mname .= '->' if $mname =~ /^\*.+\{[A-Z]+\}$/;
 351       my ($sortkeys, $keys, $key) = ("$s->{sortkeys}");
 352       if ($sortkeys) {
 353         if (ref($s->{sortkeys}) eq 'CODE') {
 354           $keys = $s->{sortkeys}($val);
 355           unless (ref($keys) eq 'ARRAY') {
 356             carp "Sortkeys subroutine did not return ARRAYREF";
 357             $keys = [];
 358           }
 359         }
 360         else {
 361           $keys = [ sort keys %$val ];
 362         }
 363       }
 364       while (($k, $v) = ! $sortkeys ? (each %$val) :
 365              @$keys ? ($key = shift(@$keys), $val->{$key}) :
 366              () )
 367       {
 368         my $nk = $s->_dump($k, "");
 369         $nk = $1 if !$s->{quotekeys} and $nk =~ /^[\"\']([A-Za-z_]\w*)[\"\']$/;
 370         $sname = $mname . '{' . $nk . '}';
 371         $out .= $pad . $ipad . $nk . $pair;
 372
 373         # temporarily alter apad
 374         $s->{apad} .= (" " x (length($nk) + 4)) if $s->{indent} >= 2;
 375         $out .= $s->_dump($val->{$k}, $sname) . ",";
 376         $s->{apad} = $lpad if $s->{indent} >= 2;
 377       }
 378       if (substr($out, -1) eq ',') {
 379         chop $out;
 380         $out .= $pad . ($s->{xpad} x ($s->{level} - 1));
 381       }
 382       $out .= ($name =~ /^\%/) ? ')' : '}';
 383     }
 384     elsif ($realtype eq 'CODE') {
 385       if ($s->{deparse}) {
 386         require B::Deparse;
 387         my $sub =  'sub ' . (B::Deparse->new)->coderef2text($val);
 388         $pad    =  $s->{sep} . $s->{pad} . $s->{apad} . $s->{xpad} x ($s->{level} - 1);
 389         $sub    =~ s/\n/$pad/gse;
 390         $out   .=  $sub;
 391       } else {
 392         $out .= 'sub { "DUMMY" }';
 393         carp "Encountered CODE ref, using dummy placeholder" if $s->{purity};
 394       }
 395     }
 396     else {
 397       croak "Can\'t handle $realtype type.";
 398     }
 399
 400     if ($realpack) { # we have a blessed ref
 401       $out .= ', \'' . $realpack . '\'' . ' )';
 402       $out .= '->' . $s->{toaster} . '()'  if $s->{toaster} ne '';
 403       $s->{apad} = $blesspad;
 404     }
 405     $s->{level}--;
 406
 407   }
 408   else {                                 # simple scalar
 409
 410     my $ref = \$_[1];
 411     # first, catalog the scalar
 412     if ($name ne '') {
 413       ($id) = ("$ref" =~ /\(([^\(]*)\)$/);
 414       if (exists $s->{seen}{$id}) {
 415         if ($s->{seen}{$id}[2]) {
 416           $out = $s->{seen}{$id}[0];
 417           #warn "[<$out]\n";
 418           return "\${$out}";
 419         }
 420       }
 421       else {
 422         #warn "[>\\$name]\n";
 423         $s->{seen}{$id} = ["\\$name", $ref];
 424       }
 425     }
 426     if (ref($ref) eq 'GLOB' or "$ref" =~ /=GLOB\([^()]+\)$/) {  # glob
 427       my $name = substr($val, 1);
 428       if ($name =~ /^[A-Za-z_][\w:]*$/) {
 429         $name =~ s/^main::/::/;
 430         $sname = $name;
 431       }
 432       else {
 433         $sname = $s->_dump($name, "");
 434         $sname = '{' . $sname . '}';
 435       }
 436       if ($s->{purity}) {
 437         my $k;
 438         local ($s->{level}) = 0;
 439         for $k (qw(SCALAR ARRAY HASH)) {
 440           my $gval = *$val{$k};
 441           next unless defined $gval;
 442           next if $k eq "SCALAR" && ! defined $$gval;  # always there
 443
 444           # _dump can push into @post, so we hold our place using $postlen
 445           my $postlen = scalar @post;
 446           $post[$postlen] = "\*$sname = ";
 447           local ($s->{apad}) = " " x length($post[$postlen]) if $s->{indent} >= 2;
 448           $post[$postlen] .= $s->_dump($gval, "\*$sname\{$k\}");
 449         }
 450       }
 451       $out .= '*' . $sname;
 452     }
 453     elsif (!defined($val)) {
 454       $out .= "undef";
 455     }
 456     elsif ($val =~ /^(?:0|-?[1-9]\d{0,8})\z/) { # safe decimal number
 457       $out .= $val;
 458     }
 459     else {                               # string
 460       if ($s->{useqq} or $val =~ tr/\0-\377//c) {
 461         # Fall back to qq if there's unicode
 462         $out .= qquote($val, $s->{useqq});
 463       }
 464       else {
 465         $val =~ s/([\\\'])/\\$1/g;
 466         $out .= '\'' . $val .  '\'';
 467       }
 468     }
 469   }
 470   if ($id) {
 471     # if we made it this far, $id was added to seen list at current
 472     # level, so remove it to get deep copies
 473     if ($s->{deepcopy}) {
 474       delete($s->{seen}{$id});
 475     }
 476     elsif ($name) {
 477       $s->{seen}{$id}[2] = 1;
 478     }
 479   }
 480   return $out;
 481 }
 482
 483 #
 484 # non-OO style of earlier version
 485 #
 486 sub Dumper {
 487   return Data::Dumper->Dump([@_]);
 488 }
 489
 490 # compat stub
 491 sub DumperX {
 492   return Data::Dumper->Dumpxs([@_], []);
 493 }
 494
 495 sub Dumpf { return Data::Dumper->Dump(@_) }
 496
 497 sub Dumpp { print Data::Dumper->Dump(@_) }
 498
 499 #
 500 # reset the "seen" cache
 501 #
 502 sub Reset {
 503   my($s) = shift;
 504   $s->{seen} = {};
 505   return $s;
 506 }
 507
 508 sub Indent {
 509   my($s, $v) = @_;
 510   if (defined($v)) {
 511     if ($v == 0) {
 512       $s->{xpad} = "";
 513       $s->{sep} = "";
 514     }
 515     else {
 516       $s->{xpad} = "  ";
 517       $s->{sep} = "\n";
 518     }
 519     $s->{indent} = $v;
 520     return $s;
 521   }
 522   else {
 523     return $s->{indent};
 524   }
 525 }
 526
 527 sub Pair {
 528     my($s, $v) = @_;
 529     defined($v) ? (($s->{pair} = $v), return $s) : $s->{pair};
 530 }
 531
 532 sub Pad {
 533   my($s, $v) = @_;
 534   defined($v) ? (($s->{pad} = $v), return $s) : $s->{pad};
 535 }
 536
 537 sub Varname {
 538   my($s, $v) = @_;
 539   defined($v) ? (($s->{varname} = $v), return $s) : $s->{varname};
 540 }
 541
 542 sub Purity {
 543   my($s, $v) = @_;
 544   defined($v) ? (($s->{purity} = $v), return $s) : $s->{purity};
 545 }
 546
 547 sub Useqq {
 548   my($s, $v) = @_;
 549   defined($v) ? (($s->{useqq} = $v), return $s) : $s->{useqq};
 550 }
 551
 552 sub Terse {
 553   my($s, $v) = @_;
 554   defined($v) ? (($s->{terse} = $v), return $s) : $s->{terse};
 555 }
 556
 557 sub Freezer {
 558   my($s, $v) = @_;
 559   defined($v) ? (($s->{freezer} = $v), return $s) : $s->{freezer};
 560 }
 561
 562 sub Toaster {
 563   my($s, $v) = @_;
 564   defined($v) ? (($s->{toaster} = $v), return $s) : $s->{toaster};
 565 }
 566
 567 sub Deepcopy {
 568   my($s, $v) = @_;
 569   defined($v) ? (($s->{deepcopy} = $v), return $s) : $s->{deepcopy};
 570 }
 571
 572 sub Quotekeys {
 573   my($s, $v) = @_;
 574   defined($v) ? (($s->{quotekeys} = $v), return $s) : $s->{quotekeys};
 575 }
 576
 577 sub Bless {
 578   my($s, $v) = @_;
 579   defined($v) ? (($s->{'bless'} = $v), return $s) : $s->{'bless'};
 580 }
 581
 582 sub Maxdepth {
 583   my($s, $v) = @_;
 584   defined($v) ? (($s->{'maxdepth'} = $v), return $s) : $s->{'maxdepth'};
 585 }
 586
 587 sub Useperl {
 588   my($s, $v) = @_;
 589   defined($v) ? (($s->{'useperl'} = $v), return $s) : $s->{'useperl'};
 590 }
 591
 592 sub Sortkeys {
 593   my($s, $v) = @_;
 594   defined($v) ? (($s->{'sortkeys'} = $v), return $s) : $s->{'sortkeys'};
 595 }
 596
 597 sub Deparse {
 598   my($s, $v) = @_;
 599   defined($v) ? (($s->{'deparse'} = $v), return $s) : $s->{'deparse'};
 600 }
 601
 602 # used by qquote below
 603 my %esc = (
 604     "\a" => "\\a",
 605     "\b" => "\\b",
 606     "\t" => "\\t",
 607     "\n" => "\\n",
 608     "\f" => "\\f",
 609     "\r" => "\\r",
 610     "\e" => "\\e",
 611 );
 612
 613 # put a string value in double quotes
 614 sub qquote {
 615   local($_) = shift;
 616   s/([\\\"\@\$])/\\$1/g;
 617   my $bytes; { use bytes; $bytes = length }
 618   s/([^\x00-\x7f])/'\x{'.sprintf("%x",ord($1)).'}'/ge if $bytes > length;
 619   return qq("$_") unless
 620     /[^ !"\#\$%&'()*+,\-.\/0-9:;<=>?\@A-Z[\\\]^_`a-z{|}~]/;  # fast exit
 621
 622   my $high = shift || "";
 623   s/([\a\b\t\n\f\r\e])/$esc{$1}/g;
 624
 625   if (ord('^')==94)  { # ascii
 626     # no need for 3 digits in escape for these
 627     s/([\0-\037])(?!\d)/'\\'.sprintf('%o',ord($1))/eg;
 628     s/([\0-\037\177])/'\\'.sprintf('%03o',ord($1))/eg;
 629     # all but last branch below not supported --BEHAVIOR SUBJECT TO CHANGE--
 630     if ($high eq "iso8859") {
 631       s/([\200-\240])/'\\'.sprintf('%o',ord($1))/eg;
 632     } elsif ($high eq "utf8") {
 633 #     use utf8;
 634 #     $str =~ s/([^\040-\176])/sprintf "\\x{%04x}", ord($1)/ge;
 635     } elsif ($high eq "8bit") {
 636         # leave it as it is
 637     } else {
 638       s/([\200-\377])/'\\'.sprintf('%03o',ord($1))/eg;
 639       s/([^\040-\176])/sprintf "\\x{%04x}", ord($1)/ge;
 640     }
 641   }
 642   else { # ebcdic
 643       s{([^ !"\#\$%&'()*+,\-.\/0-9:;<=>?\@A-Z[\\\]^_`a-z{|}~])(?!\d)}
 644        {my $v = ord($1); '\\'.sprintf(($v <= 037 ? '%o' : '%03o'), $v)}eg;
 645       s{([^ !"\#\$%&'()*+,\-.\/0-9:;<=>?\@A-Z[\\\]^_`a-z{|}~])}
 646        {'\\'.sprintf('%03o',ord($1))}eg;
 647   }
 648
 649   return qq("$_");
 650 }
 651
 652 # helper sub to sort hash keys in Perl < 5.8.0 where we don't have
 653 # access to sortsv() from XS
 654 sub _sortkeys { [ sort keys %{$_[0]} ] }
 655
 656 1;
 657 __END__
 658
 659 =head1 NAME
 660
 661 Data::Dumper - stringified perl data structures, suitable for both printing and C<eval>
 662
 663 =head1 SYNOPSIS
 664
 665     use Data::Dumper;
 666
 667     # simple procedural interface
 668     print Dumper($foo, $bar);
 669
 670     # extended usage with names
 671     print Data::Dumper->Dump([$foo, $bar], [qw(foo *ary)]);
 672
 673     # configuration variables
 674     {
 675       local $Data::Dumper::Purity = 1;
 676       eval Data::Dumper->Dump([$foo, $bar], [qw(foo *ary)]);
 677     }
 678
 679     # OO usage
 680     $d = Data::Dumper->new([$foo, $bar], [qw(foo *ary)]);
 681        ...
 682     print $d->Dump;
 683        ...
 684     $d->Purity(1)->Terse(1)->Deepcopy(1);
 685     eval $d->Dump;
 686
 687
 688 =head1 DESCRIPTION
 689
 690 Given a list of scalars or reference variables, writes out their contents in
 691 perl syntax. The references can also be objects.  The contents of each
 692 variable is output in a single Perl statement.  Handles self-referential
 693 structures correctly.
 694
 695 The return value can be C<eval>ed to get back an identical copy of the
 696 original reference structure.
 697
 698 Any references that are the same as one of those passed in will be named
 699 C<$VAR>I<n> (where I<n> is a numeric suffix), and other duplicate references
 700 to substructures within C<$VAR>I<n> will be appropriately labeled using arrow
 701 notation.  You can specify names for individual values to be dumped if you
 702 use the C<Dump()> method, or you can change the default C<$VAR> prefix to
 703 something else.  See C<$Data::Dumper::Varname> and C<$Data::Dumper::Terse>
 704 below.
 705
 706 The default output of self-referential structures can be C<eval>ed, but the
 707 nested references to C<$VAR>I<n> will be undefined, since a recursive
 708 structure cannot be constructed using one Perl statement.  You should set the
 709 C<Purity> flag to 1 to get additional statements that will correctly fill in
 710 these references.  Moreover, if C<eval>ed when strictures are in effect,
 711 you need to ensure that any variables it accesses are previously declared.
 712
 713 In the extended usage form, the references to be dumped can be given
 714 user-specified names.  If a name begins with a C<*>, the output will
 715 describe the dereferenced type of the supplied reference for hashes and
 716 arrays, and coderefs.  Output of names will be avoided where possible if
 717 the C<Terse> flag is set.
 718
 719 In many cases, methods that are used to set the internal state of the
 720 object will return the object itself, so method calls can be conveniently
 721 chained together.
 722
 723 Several styles of output are possible, all controlled by setting
 724 the C<Indent> flag.  See L<Configuration Variables or Methods> below
 725 for details.
 726
 727
 728 =head2 Methods
 729
 730 =over 4
 731
 732 =item I<PACKAGE>->new(I<ARRAYREF [>, I<ARRAYREF]>)
 733
 734 Returns a newly created C<Data::Dumper> object.  The first argument is an
 735 anonymous array of values to be dumped.  The optional second argument is an
 736 anonymous array of names for the values.  The names need not have a leading
 737 C<$> sign, and must be comprised of alphanumeric characters.  You can begin
 738 a name with a C<*> to specify that the dereferenced type must be dumped
 739 instead of the reference itself, for ARRAY and HASH references.
 740
 741 The prefix specified by C<$Data::Dumper::Varname> will be used with a
 742 numeric suffix if the name for a value is undefined.
 743
 744 Data::Dumper will catalog all references encountered while dumping the
 745 values. Cross-references (in the form of names of substructures in perl
 746 syntax) will be inserted at all possible points, preserving any structural
 747 interdependencies in the original set of values.  Structure traversal is
 748 depth-first,  and proceeds in order from the first supplied value to
 749 the last.
 750
 751 =item I<$OBJ>->Dump  I<or>  I<PACKAGE>->Dump(I<ARRAYREF [>, I<ARRAYREF]>)
 752
 753 Returns the stringified form of the values stored in the object (preserving
 754 the order in which they were supplied to C<new>), subject to the
 755 configuration options below.  In a list context, it returns a list
 756 of strings corresponding to the supplied values.
 757
 758 The second form, for convenience, simply calls the C<new> method on its
 759 arguments before dumping the object immediately.
 760
 761 =item I<$OBJ>->Seen(I<[HASHREF]>)
 762
 763 Queries or adds to the internal table of already encountered references.
 764 You must use C<Reset> to explicitly clear the table if needed.  Such
 765 references are not dumped; instead, their names are inserted wherever they
 766 are encountered subsequently.  This is useful especially for properly
 767 dumping subroutine references.
 768
 769 Expects an anonymous hash of name => value pairs.  Same rules apply for names
 770 as in C<new>.  If no argument is supplied, will return the "seen" list of
 771 name => value pairs, in a list context.  Otherwise, returns the object
 772 itself.
 773
 774 =item I<$OBJ>->Values(I<[ARRAYREF]>)
 775
 776 Queries or replaces the internal array of values that will be dumped.
 777 When called without arguments, returns the values.  Otherwise, returns the
 778 object itself.
 779
 780 =item I<$OBJ>->Names(I<[ARRAYREF]>)
 781
 782 Queries or replaces the internal array of user supplied names for the values
 783 that will be dumped.  When called without arguments, returns the names.
 784 Otherwise, returns the object itself.
 785
 786 =item I<$OBJ>->Reset
 787
 788 Clears the internal table of "seen" references and returns the object
 789 itself.
 790
 791 =back
 792
 793 =head2 Functions
 794
 795 =over 4
 796
 797 =item Dumper(I<LIST>)
 798
 799 Returns the stringified form of the values in the list, subject to the
 800 configuration options below.  The values will be named C<$VAR>I<n> in the
 801 output, where I<n> is a numeric suffix.  Will return a list of strings
 802 in a list context.
 803
 804 =back
 805
 806 =head2 Configuration Variables or Methods
 807
 808 Several configuration variables can be used to control the kind of output
 809 generated when using the procedural interface.  These variables are usually
 810 C<local>ized in a block so that other parts of the code are not affected by
 811 the change.
 812
 813 These variables determine the default state of the object created by calling
 814 the C<new> method, but cannot be used to alter the state of the object
 815 thereafter.  The equivalent method names should be used instead to query
 816 or set the internal state of the object.
 817
 818 The method forms return the object itself when called with arguments,
 819 so that they can be chained together nicely.
 820
 821 =over 4
 822
 823 =item *
 824
 825 $Data::Dumper::Indent  I<or>  I<$OBJ>->Indent(I<[NEWVAL]>)
 826
 827 Controls the style of indentation.  It can be set to 0, 1, 2 or 3.  Style 0
 828 spews output without any newlines, indentation, or spaces between list
 829 items.  It is the most compact format possible that can still be called
 830 valid perl.  Style 1 outputs a readable form with newlines but no fancy
 831 indentation (each level in the structure is simply indented by a fixed
 832 amount of whitespace).  Style 2 (the default) outputs a very readable form
 833 which takes into account the length of hash keys (so the hash value lines
 834 up).  Style 3 is like style 2, but also annotates the elements of arrays
 835 with their index (but the comment is on its own line, so array output
 836 consumes twice the number of lines).  Style 2 is the default.
 837
 838 =item *
 839
 840 $Data::Dumper::Purity  I<or>  I<$OBJ>->Purity(I<[NEWVAL]>)
 841
 842 Controls the degree to which the output can be C<eval>ed to recreate the
 843 supplied reference structures.  Setting it to 1 will output additional perl
 844 statements that will correctly recreate nested references.  The default is
 845 0.
 846
 847 =item *
 848
 849 $Data::Dumper::Pad  I<or>  I<$OBJ>->Pad(I<[NEWVAL]>)
 850
 851 Specifies the string that will be prefixed to every line of the output.
 852 Empty string by default.
 853
 854 =item *
 855
 856 $Data::Dumper::Varname  I<or>  I<$OBJ>->Varname(I<[NEWVAL]>)
 857
 858 Contains the prefix to use for tagging variable names in the output. The
 859 default is "VAR".
 860
 861 =item *
 862
 863 $Data::Dumper::Useqq  I<or>  I<$OBJ>->Useqq(I<[NEWVAL]>)
 864
 865 When set, enables the use of double quotes for representing string values.
 866 Whitespace other than space will be represented as C<[\n\t\r]>, "unsafe"
 867 characters will be backslashed, and unprintable characters will be output as
 868 quoted octal integers.  Since setting this variable imposes a performance
 869 penalty, the default is 0.  C<Dump()> will run slower if this flag is set,
 870 since the fast XSUB implementation doesn't support it yet.
 871
 872 =item *
 873
 874 $Data::Dumper::Terse  I<or>  I<$OBJ>->Terse(I<[NEWVAL]>)
 875
 876 When set, Data::Dumper will emit single, non-self-referential values as
 877 atoms/terms rather than statements.  This means that the C<$VAR>I<n> names
 878 will be avoided where possible, but be advised that such output may not
 879 always be parseable by C<eval>.
 880
 881 =item *
 882
 883 $Data::Dumper::Freezer  I<or>  $I<OBJ>->Freezer(I<[NEWVAL]>)
 884
 885 Can be set to a method name, or to an empty string to disable the feature.
 886 Data::Dumper will invoke that method via the object before attempting to
 887 stringify it.  This method can alter the contents of the object (if, for
 888 instance, it contains data allocated from C), and even rebless it in a
 889 different package.  The client is responsible for making sure the specified
 890 method can be called via the object, and that the object ends up containing
 891 only perl data types after the method has been called.  Defaults to an empty
 892 string.
 893
 894 If an object does not support the method specified (determined using
 895 UNIVERSAL::can()) then the call will be skipped.  If the method dies a
 896 warning will be generated.
 897
 898 =item *
 899
 900 $Data::Dumper::Toaster  I<or>  $I<OBJ>->Toaster(I<[NEWVAL]>)
 901
 902 Can be set to a method name, or to an empty string to disable the feature.
 903 Data::Dumper will emit a method call for any objects that are to be dumped
 904 using the syntax C<bless(DATA, CLASS)-E<gt>METHOD()>.  Note that this means that
 905 the method specified will have to perform any modifications required on the
 906 object (like creating new state within it, and/or reblessing it in a
 907 different package) and then return it.  The client is responsible for making
 908 sure the method can be called via the object, and that it returns a valid
 909 object.  Defaults to an empty string.
 910
 911 =item *
 912
 913 $Data::Dumper::Deepcopy  I<or>  $I<OBJ>->Deepcopy(I<[NEWVAL]>)
 914
 915 Can be set to a boolean value to enable deep copies of structures.
 916 Cross-referencing will then only be done when absolutely essential
 917 (i.e., to break reference cycles).  Default is 0.
 918
 919 =item *
 920
 921 $Data::Dumper::Quotekeys  I<or>  $I<OBJ>->Quotekeys(I<[NEWVAL]>)
 922
 923 Can be set to a boolean value to control whether hash keys are quoted.
 924 A false value will avoid quoting hash keys when it looks like a simple
 925 string.  Default is 1, which will always enclose hash keys in quotes.
 926
 927 =item *
 928
 929 $Data::Dumper::Bless  I<or>  $I<OBJ>->Bless(I<[NEWVAL]>)
 930
 931 Can be set to a string that specifies an alternative to the C<bless>
 932 builtin operator used to create objects.  A function with the specified
 933 name should exist, and should accept the same arguments as the builtin.
 934 Default is C<bless>.
 935
 936 =item *
 937
 938 $Data::Dumper::Pair  I<or>  $I<OBJ>->Pair(I<[NEWVAL]>)
 939
 940 Can be set to a string that specifies the separator between hash keys
 941 and values. To dump nested hash, array and scalar values to JavaScript,
 942 use: C<$Data::Dumper::Pair = ' : ';>. Implementing C<bless> in JavaScript
 943 is left as an exercise for the reader.
 944 A function with the specified name exists, and accepts the same arguments
 945 as the builtin.
 946
 947 Default is: C< =E<gt> >.
 948
 949 =item *
 950
 951 $Data::Dumper::Maxdepth  I<or>  $I<OBJ>->Maxdepth(I<[NEWVAL]>)
 952
 953 Can be set to a positive integer that specifies the depth beyond which
 954 which we don't venture into a structure.  Has no effect when
 955 C<Data::Dumper::Purity> is set.  (Useful in debugger when we often don't
 956 want to see more than enough).  Default is 0, which means there is
 957 no maximum depth.
 958
 959 =item *
 960
 961 $Data::Dumper::Useperl  I<or>  $I<OBJ>->Useperl(I<[NEWVAL]>)
 962
 963 Can be set to a boolean value which controls whether the pure Perl
 964 implementation of C<Data::Dumper> is used. The C<Data::Dumper> module is
 965 a dual implementation, with almost all functionality written in both
 966 pure Perl and also in XS ('C'). Since the XS version is much faster, it
 967 will always be used if possible. This option lets you override the
 968 default behavior, usually for testing purposes only. Default is 0, which
 969 means the XS implementation will be used if possible.
 970
 971 =item *
 972
 973 $Data::Dumper::Sortkeys  I<or>  $I<OBJ>->Sortkeys(I<[NEWVAL]>)
 974
 975 Can be set to a boolean value to control whether hash keys are dumped in
 976 sorted order. A true value will cause the keys of all hashes to be
 977 dumped in Perl's default sort order. Can also be set to a subroutine
 978 reference which will be called for each hash that is dumped. In this
 979 case C<Data::Dumper> will call the subroutine once for each hash,
 980 passing it the reference of the hash. The purpose of the subroutine is
 981 to return a reference to an array of the keys that will be dumped, in
 982 the order that they should be dumped. Using this feature, you can
 983 control both the order of the keys, and which keys are actually used. In
 984 other words, this subroutine acts as a filter by which you can exclude
 985 certain keys from being dumped. Default is 0, which means that hash keys
 986 are not sorted.
 987
 988 =item *
 989
 990 $Data::Dumper::Deparse  I<or>  $I<OBJ>->Deparse(I<[NEWVAL]>)
 991
 992 Can be set to a boolean value to control whether code references are
 993 turned into perl source code. If set to a true value, C<B::Deparse>
 994 will be used to get the source of the code reference. Using this option
 995 will force using the Perl implementation of the dumper, since the fast
 996 XSUB implementation doesn't support it.
 997
 998 Caution : use this option only if you know that your coderefs will be
 999 properly reconstructed by C<B::Deparse>.
1000
1001 =back
1002
1003 =head2 Exports
1004
1005 =over 4
1006
1007 =item Dumper
1008
1009 =back
1010
1011 =head1 EXAMPLES
1012
1013 Run these code snippets to get a quick feel for the behavior of this
1014 module.  When you are through with these examples, you may want to
1015 add or change the various configuration variables described above,
1016 to see their behavior.  (See the testsuite in the Data::Dumper
1017 distribution for more examples.)
1018
1019
1020     use Data::Dumper;
1021
1022     package Foo;
1023     sub new {bless {'a' => 1, 'b' => sub { return "foo" }}, $_[0]};
1024
1025     package Fuz;                       # a weird REF-REF-SCALAR object
1026     sub new {bless \($_ = \ 'fu\'z'), $_[0]};
1027
1028     package main;
1029     $foo = Foo->new;
1030     $fuz = Fuz->new;
1031     $boo = [ 1, [], "abcd", \*foo,
1032              {1 => 'a', 023 => 'b', 0x45 => 'c'},
1033              \\"p\q\'r", $foo, $fuz];
1034
1035     ########
1036     # simple usage
1037     ########
1038
1039     $bar = eval(Dumper($boo));
1040     print($@) if $@;
1041     print Dumper($boo), Dumper($bar);  # pretty print (no array indices)
1042
1043     $Data::Dumper::Terse = 1;          # don't output names where feasible
1044     $Data::Dumper::Indent = 0;         # turn off all pretty print
1045     print Dumper($boo), "\n";
1046
1047     $Data::Dumper::Indent = 1;         # mild pretty print
1048     print Dumper($boo);
1049
1050     $Data::Dumper::Indent = 3;         # pretty print with array indices
1051     print Dumper($boo);
1052
1053     $Data::Dumper::Useqq = 1;          # print strings in double quotes
1054     print Dumper($boo);
1055
1056     $Data::Dumper::Pair = " : ";       # specify hash key/value separator
1057     print Dumper($boo);
1058
1059
1060     ########
1061     # recursive structures
1062     ########
1063
1064     @c = ('c');
1065     $c = \@c;
1066     $b = {};
1067     $a = [1, $b, $c];
1068     $b->{a} = $a;
1069     $b->{b} = $a->[1];
1070     $b->{c} = $a->[2];
1071     print Data::Dumper->Dump([$a,$b,$c], [qw(a b c)]);
1072
1073
1074     $Data::Dumper::Purity = 1;         # fill in the holes for eval
1075     print Data::Dumper->Dump([$a, $b], [qw(*a b)]); # print as @a
1076     print Data::Dumper->Dump([$b, $a], [qw(*b a)]); # print as %b
1077
1078
1079     $Data::Dumper::Deepcopy = 1;       # avoid cross-refs
1080     print Data::Dumper->Dump([$b, $a], [qw(*b a)]);
1081
1082
1083     $Data::Dumper::Purity = 0;         # avoid cross-refs
1084     print Data::Dumper->Dump([$b, $a], [qw(*b a)]);
1085
1086     ########
1087     # deep structures
1088     ########
1089
1090     $a = "pearl";
1091     $b = [ $a ];
1092     $c = { 'b' => $b };
1093     $d = [ $c ];
1094     $e = { 'd' => $d };
1095     $f = { 'e' => $e };
1096     print Data::Dumper->Dump([$f], [qw(f)]);
1097
1098     $Data::Dumper::Maxdepth = 3;       # no deeper than 3 refs down
1099     print Data::Dumper->Dump([$f], [qw(f)]);
1100
1101
1102     ########
1103     # object-oriented usage
1104     ########
1105
1106     $d = Data::Dumper->new([$a,$b], [qw(a b)]);
1107     $d->Seen({'*c' => $c});            # stash a ref without printing it
1108     $d->Indent(3);
1109     print $d->Dump;
1110     $d->Reset->Purity(0);              # empty the seen cache
1111     print join "----\n", $d->Dump;
1112
1113
1114     ########
1115     # persistence
1116     ########
1117
1118     package Foo;
1119     sub new { bless { state => 'awake' }, shift }
1120     sub Freeze {
1121         my $s = shift;
1122         print STDERR "preparing to sleep\n";
1123         $s->{state} = 'asleep';
1124         return bless $s, 'Foo::ZZZ';
1125     }
1126
1127     package Foo::ZZZ;
1128     sub Thaw {
1129         my $s = shift;
1130         print STDERR "waking up\n";
1131         $s->{state} = 'awake';
1132         return bless $s, 'Foo';
1133     }
1134
1135     package Foo;
1136     use Data::Dumper;
1137     $a = Foo->new;
1138     $b = Data::Dumper->new([$a], ['c']);
1139     $b->Freezer('Freeze');
1140     $b->Toaster('Thaw');
1141     $c = $b->Dump;
1142     print $c;
1143     $d = eval $c;
1144     print Data::Dumper->Dump([$d], ['d']);
1145
1146
1147     ########
1148     # symbol substitution (useful for recreating CODE refs)
1149     ########
1150
1151     sub foo { print "foo speaking\n" }
1152     *other = \&foo;
1153     $bar = [ \&other ];
1154     $d = Data::Dumper->new([\&other,$bar],['*other','bar']);
1155     $d->Seen({ '*foo' => \&foo });
1156     print $d->Dump;
1157
1158
1159     ########
1160     # sorting and filtering hash keys
1161     ########
1162
1163     $Data::Dumper::Sortkeys = \&my_filter;
1164     my $foo = { map { (ord, "$_$_$_") } 'I'..'Q' };
1165     my $bar = { %$foo };
1166     my $baz = { reverse %$foo };
1167     print Dumper [ $foo, $bar, $baz ];
1168
1169     sub my_filter {
1170         my ($hash) = @_;
1171         # return an array ref containing the hash keys to dump
1172         # in the order that you want them to be dumped
1173         return [
1174           # Sort the keys of %$foo in reverse numeric order
1175             $hash eq $foo ? (sort {$b <=> $a} keys %$hash) :
1176           # Only dump the odd number keys of %$bar
1177             $hash eq $bar ? (grep {$_ % 2} keys %$hash) :
1178           # Sort keys in default order for all other hashes
1179             (sort keys %$hash)
1180         ];
1181     }
1182
1183 =head1 BUGS
1184
1185 Due to limitations of Perl subroutine call semantics, you cannot pass an
1186 array or hash.  Prepend it with a C<\> to pass its reference instead.  This
1187 will be remedied in time, now that Perl has subroutine prototypes.
1188 For now, you need to use the extended usage form, and prepend the
1189 name with a C<*> to output it as a hash or array.
1190
1191 C<Data::Dumper> cheats with CODE references.  If a code reference is
1192 encountered in the structure being processed (and if you haven't set
1193 the C<Deparse> flag), an anonymous subroutine that
1194 contains the string '"DUMMY"' will be inserted in its place, and a warning
1195 will be printed if C<Purity> is set.  You can C<eval> the result, but bear
1196 in mind that the anonymous sub that gets created is just a placeholder.
1197 Someday, perl will have a switch to cache-on-demand the string
1198 representation of a compiled piece of code, I hope.  If you have prior
1199 knowledge of all the code refs that your data structures are likely
1200 to have, you can use the C<Seen> method to pre-seed the internal reference
1201 table and make the dumped output point to them, instead.  See L<EXAMPLES>
1202 above.
1203
1204 The C<Useqq> and C<Deparse> flags makes Dump() run slower, since the
1205 XSUB implementation does not support them.
1206
1207 SCALAR objects have the weirdest looking C<bless> workaround.
1208
1209 Pure Perl version of C<Data::Dumper> escapes UTF-8 strings correctly
1210 only in Perl 5.8.0 and later.
1211
1212 =head2 NOTE
1213
1214 Starting from Perl 5.8.1 different runs of Perl will have different
1215 ordering of hash keys.  The change was done for greater security,
1216 see L<perlsec/"Algorithmic Complexity Attacks">.  This means that
1217 different runs of Perl will have different Data::Dumper outputs if
1218 the data contains hashes.  If you need to have identical Data::Dumper
1219 outputs from different runs of Perl, use the environment variable
1220 PERL_HASH_SEED, see L<perlrun/PERL_HASH_SEED>.  Using this restores
1221 the old (platform-specific) ordering: an even prettier solution might
1222 be to use the C<Sortkeys> filter of Data::Dumper.
1223
1224 =head1 AUTHOR
1225
1226 Gurusamy Sarathy        gsar@activestate.com
1227
1228 Copyright (c) 1996-98 Gurusamy Sarathy. All rights reserved.
1229 This program is free software; you can redistribute it and/or
1230 modify it under the same terms as Perl itself.
1231
1232 =head1 VERSION
1233
1234 Version 2.121  (Aug 24 2003)
1235
1236 =head1 SEE ALSO
1237
1238 perl(1)
1239
1240 =cut