ext/Data/Dumper/Dumper.pm

   1 #
   2 # Data/Dumper.pm
   3 #
   4 # convert perl data structures into perl syntax suitable for both printing
   5 # and eval
   6 #
   7 # Documentation at the __END__
   8 #
   9
  10 package Data::Dumper;
  11
  12 $VERSION = '2.121_12';
  13
  14 #$| = 1;
  15
  16 use 5.006_001;
  17 require Exporter;
  18 require overload;
  19
  20 use Carp;
  21
  22 BEGIN {
  23     @ISA = qw(Exporter);
  24     @EXPORT = qw(Dumper);
  25     @EXPORT_OK = qw(DumperX);
  26
  27     # if run under miniperl, or otherwise lacking dynamic loading,
  28     # XSLoader should be attempted to load, or the pure perl flag
  29     # toggled on load failure.
  30     eval {
  31         require XSLoader;
  32     };
  33     $Useperl = 1 if $@;
  34 }
  35
  36 XSLoader::load( 'Data::Dumper' ) unless $Useperl;
  37
  38 # module vars and their defaults
  39 $Indent     = 2         unless defined $Indent;
  40 $Purity     = 0         unless defined $Purity;
  41 $Pad        = ""        unless defined $Pad;
  42 $Varname    = "VAR"     unless defined $Varname;
  43 $Useqq      = 0         unless defined $Useqq;
  44 $Terse      = 0         unless defined $Terse;
  45 $Freezer    = ""        unless defined $Freezer;
  46 $Toaster    = ""        unless defined $Toaster;
  47 $Deepcopy   = 0         unless defined $Deepcopy;
  48 $Quotekeys  = 1         unless defined $Quotekeys;
  49 $Bless      = "bless"   unless defined $Bless;
  50 #$Expdepth   = 0         unless defined $Expdepth;
  51 $Maxdepth   = 0         unless defined $Maxdepth;
  52 $Pair       = ' => '    unless defined $Pair;
  53 $Useperl    = 0         unless defined $Useperl;
  54 $Sortkeys   = 0         unless defined $Sortkeys;
  55 $Deparse    = 0         unless defined $Deparse;
  56
  57 #
  58 # expects an arrayref of values to be dumped.
  59 # can optionally pass an arrayref of names for the values.
  60 # names must have leading $ sign stripped. begin the name with *
  61 # to cause output of arrays and hashes rather than refs.
  62 #
  63 sub new {
  64   my($c, $v, $n) = @_;
  65
  66   croak "Usage:  PACKAGE->new(ARRAYREF, [ARRAYREF])"
  67     unless (defined($v) && (ref($v) eq 'ARRAY'));
  68   $n = [] unless (defined($n) && (ref($v) eq 'ARRAY'));
  69
  70   my($s) = {
  71              level      => 0,           # current recursive depth
  72              indent     => $Indent,     # various styles of indenting
  73              pad        => $Pad,        # all lines prefixed by this string
  74              xpad       => "",          # padding-per-level
  75              apad       => "",          # added padding for hash keys n such
  76              sep        => "",          # list separator
  77              pair       => $Pair,       # hash key/value separator: defaults to ' => '
  78              seen       => {},          # local (nested) refs (id => [name, val])
  79              todump     => $v,          # values to dump []
  80              names      => $n,          # optional names for values []
  81              varname    => $Varname,    # prefix to use for tagging nameless ones
  82              purity     => $Purity,     # degree to which output is evalable
  83              useqq      => $Useqq,      # use "" for strings (backslashitis ensues)
  84              terse      => $Terse,      # avoid name output (where feasible)
  85              freezer    => $Freezer,    # name of Freezer method for objects
  86              toaster    => $Toaster,    # name of method to revive objects
  87              deepcopy   => $Deepcopy,   # dont cross-ref, except to stop recursion
  88              quotekeys  => $Quotekeys,  # quote hash keys
  89              'bless'    => $Bless,      # keyword to use for "bless"
  90 #            expdepth   => $Expdepth,   # cutoff depth for explicit dumping
  91              maxdepth   => $Maxdepth,   # depth beyond which we give up
  92              useperl    => $Useperl,    # use the pure Perl implementation
  93              sortkeys   => $Sortkeys,   # flag or filter for sorting hash keys
  94              deparse    => $Deparse,    # use B::Deparse for coderefs
  95            };
  96
  97   if ($Indent > 0) {
  98     $s->{xpad} = "  ";
  99     $s->{sep} = "\n";
 100   }
 101   return bless($s, $c);
 102 }
 103
 104 if ($] >= 5.006) {
 105   # Packed numeric addresses take less memory. Plus pack is faster than sprintf
 106   *init_refaddr_format = sub {};
 107
 108   *format_refaddr  = sub {
 109     require Scalar::Util;
 110     pack "J", Scalar::Util::refaddr(shift);
 111   };
 112 } else {
 113   *init_refaddr_format = sub {
 114     require Config;
 115     my $f = $Config::Config{uvxformat};
 116     $f =~ tr/"//d;
 117     our $refaddr_format = "0x%" . $f;
 118   };
 119
 120   *format_refaddr = sub {
 121     require Scalar::Util;
 122     sprintf our $refaddr_format, Scalar::Util::refaddr(shift);
 123   }
 124 }
 125
 126 #
 127 # add-to or query the table of already seen references
 128 #
 129 sub Seen {
 130   my($s, $g) = @_;
 131   if (defined($g) && (ref($g) eq 'HASH'))  {
 132     init_refaddr_format();
 133     my($k, $v, $id);
 134     while (($k, $v) = each %$g) {
 135       if (defined $v and ref $v) {
 136         $id = format_refaddr($v);
 137         if ($k =~ /^[*](.*)$/) {
 138           $k = (ref $v eq 'ARRAY') ? ( "\\\@" . $1 ) :
 139                (ref $v eq 'HASH')  ? ( "\\\%" . $1 ) :
 140                (ref $v eq 'CODE')  ? ( "\\\&" . $1 ) :
 141                                      (   "\$" . $1 ) ;
 142         }
 143         elsif ($k !~ /^\$/) {
 144           $k = "\$" . $k;
 145         }
 146         $s->{seen}{$id} = [$k, $v];
 147       }
 148       else {
 149         carp "Only refs supported, ignoring non-ref item \$$k";
 150       }
 151     }
 152     return $s;
 153   }
 154   else {
 155     return map { @$_ } values %{$s->{seen}};
 156   }
 157 }
 158
 159 #
 160 # set or query the values to be dumped
 161 #
 162 sub Values {
 163   my($s, $v) = @_;
 164   if (defined($v) && (ref($v) eq 'ARRAY'))  {
 165     $s->{todump} = [@$v];        # make a copy
 166     return $s;
 167   }
 168   else {
 169     return @{$s->{todump}};
 170   }
 171 }
 172
 173 #
 174 # set or query the names of the values to be dumped
 175 #
 176 sub Names {
 177   my($s, $n) = @_;
 178   if (defined($n) && (ref($n) eq 'ARRAY'))  {
 179     $s->{names} = [@$n];         # make a copy
 180     return $s;
 181   }
 182   else {
 183     return @{$s->{names}};
 184   }
 185 }
 186
 187 sub DESTROY {}
 188
 189 sub Dump {
 190     return &Dumpxs
 191         unless $Data::Dumper::Useperl || (ref($_[0]) && $_[0]->{useperl}) ||
 192                $Data::Dumper::Useqq   || (ref($_[0]) && $_[0]->{useqq}) ||
 193                $Data::Dumper::Deparse || (ref($_[0]) && $_[0]->{deparse});
 194     return &Dumpperl;
 195 }
 196
 197 #
 198 # dump the refs in the current dumper object.
 199 # expects same args as new() if called via package name.
 200 #
 201 sub Dumpperl {
 202   my($s) = shift;
 203   my(@out, $val, $name);
 204   my($i) = 0;
 205   local(@post);
 206   init_refaddr_format();
 207
 208   $s = $s->new(@_) unless ref $s;
 209
 210   for $val (@{$s->{todump}}) {
 211     my $out = "";
 212     @post = ();
 213     $name = $s->{names}[$i++];
 214     if (defined $name) {
 215       if ($name =~ /^[*](.*)$/) {
 216         if (defined $val) {
 217           $name = (ref $val eq 'ARRAY') ? ( "\@" . $1 ) :
 218                   (ref $val eq 'HASH')  ? ( "\%" . $1 ) :
 219                   (ref $val eq 'CODE')  ? ( "\*" . $1 ) :
 220                                           ( "\$" . $1 ) ;
 221         }
 222         else {
 223           $name = "\$" . $1;
 224         }
 225       }
 226       elsif ($name !~ /^\$/) {
 227         $name = "\$" . $name;
 228       }
 229     }
 230     else {
 231       $name = "\$" . $s->{varname} . $i;
 232     }
 233
 234     # Ensure hash iterator is reset
 235     if (ref($val) eq 'HASH') {
 236         keys(%$val);
 237     }
 238
 239     my $valstr;
 240     {
 241       local($s->{apad}) = $s->{apad};
 242       $s->{apad} .= ' ' x (length($name) + 3) if $s->{indent} >= 2;
 243       $valstr = $s->_dump($val, $name);
 244     }
 245
 246     $valstr = "$name = " . $valstr . ';' if @post or !$s->{terse};
 247     $out .= $s->{pad} . $valstr . $s->{sep};
 248     $out .= $s->{pad} . join(';' . $s->{sep} . $s->{pad}, @post)
 249       . ';' . $s->{sep} if @post;
 250
 251     push @out, $out;
 252   }
 253   return wantarray ? @out : join('', @out);
 254 }
 255
 256 #
 257 # twist, toil and turn;
 258 # and recurse, of course.
 259 # sometimes sordidly;
 260 # and curse if no recourse.
 261 #
 262 sub _dump {
 263   my($s, $val, $name) = @_;
 264   my($sname);
 265   my($out, $realpack, $realtype, $type, $ipad, $id, $blesspad);
 266
 267   $type = ref $val;
 268   $out = "";
 269
 270   if ($type) {
 271
 272     # Call the freezer method if it's specified and the object has the
 273     # method.  Trap errors and warn() instead of die()ing, like the XS
 274     # implementation.
 275     my $freezer = $s->{freezer};
 276     if ($freezer and UNIVERSAL::can($val, $freezer)) {
 277       eval { $val->$freezer() };
 278       warn "WARNING(Freezer method call failed): $@" if $@;
 279     }
 280
 281     require Scalar::Util;
 282     $realpack = Scalar::Util::blessed($val);
 283     $realtype = $realpack ? Scalar::Util::reftype($val) : ref $val;
 284     $id = format_refaddr($val);
 285
 286     # if it has a name, we need to either look it up, or keep a tab
 287     # on it so we know when we hit it later
 288     if (defined($name) and length($name)) {
 289       # keep a tab on it so that we dont fall into recursive pit
 290       if (exists $s->{seen}{$id}) {
 291 #       if ($s->{expdepth} < $s->{level}) {
 292           if ($s->{purity} and $s->{level} > 0) {
 293             $out = ($realtype eq 'HASH')  ? '{}' :
 294               ($realtype eq 'ARRAY') ? '[]' :
 295                 'do{my $o}' ;
 296             push @post, $name . " = " . $s->{seen}{$id}[0];
 297           }
 298           else {
 299             $out = $s->{seen}{$id}[0];
 300             if ($name =~ /^([\@\%])/) {
 301               my $start = $1;
 302               if ($out =~ /^\\$start/) {
 303                 $out = substr($out, 1);
 304               }
 305               else {
 306                 $out = $start . '{' . $out . '}';
 307               }
 308             }
 309           }
 310           return $out;
 311 #        }
 312       }
 313       else {
 314         # store our name
 315         $s->{seen}{$id} = [ (($name =~ /^[@%]/)     ? ('\\' . $name ) :
 316                              ($realtype eq 'CODE' and
 317                               $name =~ /^[*](.*)$/) ? ('\\&' . $1 )   :
 318                              $name          ),
 319                             $val ];
 320       }
 321     }
 322
 323     if ($realpack and $realpack eq 'Regexp') {
 324         $out = "$val";
 325         $out =~ s,/,\\/,g;
 326         return "qr/$out/";
 327     }
 328
 329     # If purity is not set and maxdepth is set, then check depth:
 330     # if we have reached maximum depth, return the string
 331     # representation of the thing we are currently examining
 332     # at this depth (i.e., 'Foo=ARRAY(0xdeadbeef)').
 333     if (!$s->{purity}
 334         and $s->{maxdepth} > 0
 335         and $s->{level} >= $s->{maxdepth})
 336     {
 337       return qq['$val'];
 338     }
 339
 340     # we have a blessed ref
 341     if ($realpack) {
 342       $out = $s->{'bless'} . '( ';
 343       $blesspad = $s->{apad};
 344       $s->{apad} .= '       ' if ($s->{indent} >= 2);
 345     }
 346
 347     $s->{level}++;
 348     $ipad = $s->{xpad} x $s->{level};
 349
 350     if ($realtype eq 'SCALAR' || $realtype eq 'REF') {
 351       if ($realpack) {
 352         $out .= 'do{\\(my $o = ' . $s->_dump($$val, "\${$name}") . ')}';
 353       }
 354       else {
 355         $out .= '\\' . $s->_dump($$val, "\${$name}");
 356       }
 357     }
 358     elsif ($realtype eq 'GLOB') {
 359         $out .= '\\' . $s->_dump($$val, "*{$name}");
 360     }
 361     elsif ($realtype eq 'ARRAY') {
 362       my($v, $pad, $mname);
 363       my($i) = 0;
 364       $out .= ($name =~ /^\@/) ? '(' : '[';
 365       $pad = $s->{sep} . $s->{pad} . $s->{apad};
 366       ($name =~ /^\@(.*)$/) ? ($mname = "\$" . $1) :
 367         # omit -> if $foo->[0]->{bar}, but not ${$foo->[0]}->{bar}
 368         ($name =~ /^\\?[\%\@\*\$][^{].*[]}]$/) ? ($mname = $name) :
 369           ($mname = $name . '->');
 370       $mname .= '->' if $mname =~ /^\*.+\{[A-Z]+\}$/;
 371       for $v (@$val) {
 372         $sname = $mname . '[' . $i . ']';
 373         $out .= $pad . $ipad . '#' . $i if $s->{indent} >= 3;
 374         $out .= $pad . $ipad . $s->_dump($v, $sname);
 375         $out .= "," if $i++ < $#$val;
 376       }
 377       $out .= $pad . ($s->{xpad} x ($s->{level} - 1)) if $i;
 378       $out .= ($name =~ /^\@/) ? ')' : ']';
 379     }
 380     elsif ($realtype eq 'HASH') {
 381       my($k, $v, $pad, $lpad, $mname, $pair);
 382       $out .= ($name =~ /^\%/) ? '(' : '{';
 383       $pad = $s->{sep} . $s->{pad} . $s->{apad};
 384       $lpad = $s->{apad};
 385       $pair = $s->{pair};
 386       ($name =~ /^\%(.*)$/) ? ($mname = "\$" . $1) :
 387         # omit -> if $foo->[0]->{bar}, but not ${$foo->[0]}->{bar}
 388         ($name =~ /^\\?[\%\@\*\$][^{].*[]}]$/) ? ($mname = $name) :
 389           ($mname = $name . '->');
 390       $mname .= '->' if $mname =~ /^\*.+\{[A-Z]+\}$/;
 391       my ($sortkeys, $keys, $key) = ("$s->{sortkeys}");
 392       if ($sortkeys) {
 393         if (ref($s->{sortkeys}) eq 'CODE') {
 394           $keys = $s->{sortkeys}($val);
 395           unless (ref($keys) eq 'ARRAY') {
 396             carp "Sortkeys subroutine did not return ARRAYREF";
 397             $keys = [];
 398           }
 399         }
 400         else {
 401           $keys = [ sort keys %$val ];
 402         }
 403       }
 404       while (($k, $v) = ! $sortkeys ? (each %$val) :
 405              @$keys ? ($key = shift(@$keys), $val->{$key}) :
 406              () )
 407       {
 408         my $nk = $s->_dump($k, "");
 409         $nk = $1 if !$s->{quotekeys} and $nk =~ /^[\"\']([A-Za-z_]\w*)[\"\']$/;
 410         $sname = $mname . '{' . $nk . '}';
 411         $out .= $pad . $ipad . $nk . $pair;
 412
 413         # temporarily alter apad
 414         $s->{apad} .= (" " x (length($nk) + 4)) if $s->{indent} >= 2;
 415         $out .= $s->_dump($val->{$k}, $sname) . ",";
 416         $s->{apad} = $lpad if $s->{indent} >= 2;
 417       }
 418       if (substr($out, -1) eq ',') {
 419         chop $out;
 420         $out .= $pad . ($s->{xpad} x ($s->{level} - 1));
 421       }
 422       $out .= ($name =~ /^\%/) ? ')' : '}';
 423     }
 424     elsif ($realtype eq 'CODE') {
 425       if ($s->{deparse}) {
 426         require B::Deparse;
 427         my $sub =  'sub ' . (B::Deparse->new)->coderef2text($val);
 428         $pad    =  $s->{sep} . $s->{pad} . $s->{apad} . $s->{xpad} x ($s->{level} - 1);
 429         $sub    =~ s/\n/$pad/gse;
 430         $out   .=  $sub;
 431       } else {
 432         $out .= 'sub { "DUMMY" }';
 433         carp "Encountered CODE ref, using dummy placeholder" if $s->{purity};
 434       }
 435     }
 436     else {
 437       croak "Can\'t handle $realtype type.";
 438     }
 439
 440     if ($realpack) { # we have a blessed ref
 441       $out .= ', \'' . $realpack . '\'' . ' )';
 442       $out .= '->' . $s->{toaster} . '()'  if $s->{toaster} ne '';
 443       $s->{apad} = $blesspad;
 444     }
 445     $s->{level}--;
 446
 447   }
 448   else {                                 # simple scalar
 449
 450     my $ref = \$_[1];
 451     # first, catalog the scalar
 452     if ($name ne '') {
 453       $id = format_refaddr($ref);
 454       if (exists $s->{seen}{$id}) {
 455         if ($s->{seen}{$id}[2]) {
 456           $out = $s->{seen}{$id}[0];
 457           #warn "[<$out]\n";
 458           return "\${$out}";
 459         }
 460       }
 461       else {
 462         #warn "[>\\$name]\n";
 463         $s->{seen}{$id} = ["\\$name", $ref];
 464       }
 465     }
 466     if (ref($ref) eq 'GLOB' or "$ref" =~ /=GLOB\([^()]+\)$/) {  # glob
 467       my $name = substr($val, 1);
 468       if ($name =~ /^[A-Za-z_][\w:]*$/) {
 469         $name =~ s/^main::/::/;
 470         $sname = $name;
 471       }
 472       else {
 473         $sname = $s->_dump($name, "");
 474         $sname = '{' . $sname . '}';
 475       }
 476       if ($s->{purity}) {
 477         my $k;
 478         local ($s->{level}) = 0;
 479         for $k (qw(SCALAR ARRAY HASH)) {
 480           my $gval = *$val{$k};
 481           next unless defined $gval;
 482           next if $k eq "SCALAR" && ! defined $$gval;  # always there
 483
 484           # _dump can push into @post, so we hold our place using $postlen
 485           my $postlen = scalar @post;
 486           $post[$postlen] = "\*$sname = ";
 487           local ($s->{apad}) = " " x length($post[$postlen]) if $s->{indent} >= 2;
 488           $post[$postlen] .= $s->_dump($gval, "\*$sname\{$k\}");
 489         }
 490       }
 491       $out .= '*' . $sname;
 492     }
 493     elsif (!defined($val)) {
 494       $out .= "undef";
 495     }
 496     elsif ($val =~ /^(?:0|-?[1-9]\d{0,8})\z/) { # safe decimal number
 497       $out .= $val;
 498     }
 499     else {                               # string
 500       if ($s->{useqq} or $val =~ tr/\0-\377//c) {
 501         # Fall back to qq if there's unicode
 502         $out .= qquote($val, $s->{useqq});
 503       }
 504       else {
 505         $val =~ s/([\\\'])/\\$1/g;
 506         $out .= '\'' . $val .  '\'';
 507       }
 508     }
 509   }
 510   if ($id) {
 511     # if we made it this far, $id was added to seen list at current
 512     # level, so remove it to get deep copies
 513     if ($s->{deepcopy}) {
 514       delete($s->{seen}{$id});
 515     }
 516     elsif ($name) {
 517       $s->{seen}{$id}[2] = 1;
 518     }
 519   }
 520   return $out;
 521 }
 522
 523 #
 524 # non-OO style of earlier version
 525 #
 526 sub Dumper {
 527   return Data::Dumper->Dump([@_]);
 528 }
 529
 530 # compat stub
 531 sub DumperX {
 532   return Data::Dumper->Dumpxs([@_], []);
 533 }
 534
 535 sub Dumpf { return Data::Dumper->Dump(@_) }
 536
 537 sub Dumpp { print Data::Dumper->Dump(@_) }
 538
 539 #
 540 # reset the "seen" cache
 541 #
 542 sub Reset {
 543   my($s) = shift;
 544   $s->{seen} = {};
 545   return $s;
 546 }
 547
 548 sub Indent {
 549   my($s, $v) = @_;
 550   if (defined($v)) {
 551     if ($v == 0) {
 552       $s->{xpad} = "";
 553       $s->{sep} = "";
 554     }
 555     else {
 556       $s->{xpad} = "  ";
 557       $s->{sep} = "\n";
 558     }
 559     $s->{indent} = $v;
 560     return $s;
 561   }
 562   else {
 563     return $s->{indent};
 564   }
 565 }
 566
 567 sub Pair {
 568     my($s, $v) = @_;
 569     defined($v) ? (($s->{pair} = $v), return $s) : $s->{pair};
 570 }
 571
 572 sub Pad {
 573   my($s, $v) = @_;
 574   defined($v) ? (($s->{pad} = $v), return $s) : $s->{pad};
 575 }
 576
 577 sub Varname {
 578   my($s, $v) = @_;
 579   defined($v) ? (($s->{varname} = $v), return $s) : $s->{varname};
 580 }
 581
 582 sub Purity {
 583   my($s, $v) = @_;
 584   defined($v) ? (($s->{purity} = $v), return $s) : $s->{purity};
 585 }
 586
 587 sub Useqq {
 588   my($s, $v) = @_;
 589   defined($v) ? (($s->{useqq} = $v), return $s) : $s->{useqq};
 590 }
 591
 592 sub Terse {
 593   my($s, $v) = @_;
 594   defined($v) ? (($s->{terse} = $v), return $s) : $s->{terse};
 595 }
 596
 597 sub Freezer {
 598   my($s, $v) = @_;
 599   defined($v) ? (($s->{freezer} = $v), return $s) : $s->{freezer};
 600 }
 601
 602 sub Toaster {
 603   my($s, $v) = @_;
 604   defined($v) ? (($s->{toaster} = $v), return $s) : $s->{toaster};
 605 }
 606
 607 sub Deepcopy {
 608   my($s, $v) = @_;
 609   defined($v) ? (($s->{deepcopy} = $v), return $s) : $s->{deepcopy};
 610 }
 611
 612 sub Quotekeys {
 613   my($s, $v) = @_;
 614   defined($v) ? (($s->{quotekeys} = $v), return $s) : $s->{quotekeys};
 615 }
 616
 617 sub Bless {
 618   my($s, $v) = @_;
 619   defined($v) ? (($s->{'bless'} = $v), return $s) : $s->{'bless'};
 620 }
 621
 622 sub Maxdepth {
 623   my($s, $v) = @_;
 624   defined($v) ? (($s->{'maxdepth'} = $v), return $s) : $s->{'maxdepth'};
 625 }
 626
 627 sub Useperl {
 628   my($s, $v) = @_;
 629   defined($v) ? (($s->{'useperl'} = $v), return $s) : $s->{'useperl'};
 630 }
 631
 632 sub Sortkeys {
 633   my($s, $v) = @_;
 634   defined($v) ? (($s->{'sortkeys'} = $v), return $s) : $s->{'sortkeys'};
 635 }
 636
 637 sub Deparse {
 638   my($s, $v) = @_;
 639   defined($v) ? (($s->{'deparse'} = $v), return $s) : $s->{'deparse'};
 640 }
 641
 642 # used by qquote below
 643 my %esc = (
 644     "\a" => "\\a",
 645     "\b" => "\\b",
 646     "\t" => "\\t",
 647     "\n" => "\\n",
 648     "\f" => "\\f",
 649     "\r" => "\\r",
 650     "\e" => "\\e",
 651 );
 652
 653 # put a string value in double quotes
 654 sub qquote {
 655   local($_) = shift;
 656   s/([\\\"\@\$])/\\$1/g;
 657   my $bytes; { use bytes; $bytes = length }
 658   s/([^\x00-\x7f])/'\x{'.sprintf("%x",ord($1)).'}'/ge if $bytes > length;
 659   return qq("$_") unless
 660     /[^ !"\#\$%&'()*+,\-.\/0-9:;<=>?\@A-Z[\\\]^_`a-z{|}~]/;  # fast exit
 661
 662   my $high = shift || "";
 663   s/([\a\b\t\n\f\r\e])/$esc{$1}/g;
 664
 665   if (ord('^')==94)  { # ascii
 666     # no need for 3 digits in escape for these
 667     s/([\0-\037])(?!\d)/'\\'.sprintf('%o',ord($1))/eg;
 668     s/([\0-\037\177])/'\\'.sprintf('%03o',ord($1))/eg;
 669     # all but last branch below not supported --BEHAVIOR SUBJECT TO CHANGE--
 670     if ($high eq "iso8859") {
 671       s/([\200-\240])/'\\'.sprintf('%o',ord($1))/eg;
 672     } elsif ($high eq "utf8") {
 673 #     use utf8;
 674 #     $str =~ s/([^\040-\176])/sprintf "\\x{%04x}", ord($1)/ge;
 675     } elsif ($high eq "8bit") {
 676         # leave it as it is
 677     } else {
 678       s/([\200-\377])/'\\'.sprintf('%03o',ord($1))/eg;
 679       s/([^\040-\176])/sprintf "\\x{%04x}", ord($1)/ge;
 680     }
 681   }
 682   else { # ebcdic
 683       s{([^ !"\#\$%&'()*+,\-.\/0-9:;<=>?\@A-Z[\\\]^_`a-z{|}~])(?!\d)}
 684        {my $v = ord($1); '\\'.sprintf(($v <= 037 ? '%o' : '%03o'), $v)}eg;
 685       s{([^ !"\#\$%&'()*+,\-.\/0-9:;<=>?\@A-Z[\\\]^_`a-z{|}~])}
 686        {'\\'.sprintf('%03o',ord($1))}eg;
 687   }
 688
 689   return qq("$_");
 690 }
 691
 692 # helper sub to sort hash keys in Perl < 5.8.0 where we don't have
 693 # access to sortsv() from XS
 694 sub _sortkeys { [ sort keys %{$_[0]} ] }
 695
 696 1;
 697 __END__
 698
 699 =head1 NAME
 700
 701 Data::Dumper - stringified perl data structures, suitable for both printing and C<eval>
 702
 703 =head1 SYNOPSIS
 704
 705     use Data::Dumper;
 706
 707     # simple procedural interface
 708     print Dumper($foo, $bar);
 709
 710     # extended usage with names
 711     print Data::Dumper->Dump([$foo, $bar], [qw(foo *ary)]);
 712
 713     # configuration variables
 714     {
 715       local $Data::Dumper::Purity = 1;
 716       eval Data::Dumper->Dump([$foo, $bar], [qw(foo *ary)]);
 717     }
 718
 719     # OO usage
 720     $d = Data::Dumper->new([$foo, $bar], [qw(foo *ary)]);
 721        ...
 722     print $d->Dump;
 723        ...
 724     $d->Purity(1)->Terse(1)->Deepcopy(1);
 725     eval $d->Dump;
 726
 727
 728 =head1 DESCRIPTION
 729
 730 Given a list of scalars or reference variables, writes out their contents in
 731 perl syntax. The references can also be objects.  The contents of each
 732 variable is output in a single Perl statement.  Handles self-referential
 733 structures correctly.
 734
 735 The return value can be C<eval>ed to get back an identical copy of the
 736 original reference structure.
 737
 738 Any references that are the same as one of those passed in will be named
 739 C<$VAR>I<n> (where I<n> is a numeric suffix), and other duplicate references
 740 to substructures within C<$VAR>I<n> will be appropriately labeled using arrow
 741 notation.  You can specify names for individual values to be dumped if you
 742 use the C<Dump()> method, or you can change the default C<$VAR> prefix to
 743 something else.  See C<$Data::Dumper::Varname> and C<$Data::Dumper::Terse>
 744 below.
 745
 746 The default output of self-referential structures can be C<eval>ed, but the
 747 nested references to C<$VAR>I<n> will be undefined, since a recursive
 748 structure cannot be constructed using one Perl statement.  You should set the
 749 C<Purity> flag to 1 to get additional statements that will correctly fill in
 750 these references.  Moreover, if C<eval>ed when strictures are in effect,
 751 you need to ensure that any variables it accesses are previously declared.
 752
 753 In the extended usage form, the references to be dumped can be given
 754 user-specified names.  If a name begins with a C<*>, the output will
 755 describe the dereferenced type of the supplied reference for hashes and
 756 arrays, and coderefs.  Output of names will be avoided where possible if
 757 the C<Terse> flag is set.
 758
 759 In many cases, methods that are used to set the internal state of the
 760 object will return the object itself, so method calls can be conveniently
 761 chained together.
 762
 763 Several styles of output are possible, all controlled by setting
 764 the C<Indent> flag.  See L<Configuration Variables or Methods> below
 765 for details.
 766
 767
 768 =head2 Methods
 769
 770 =over 4
 771
 772 =item I<PACKAGE>->new(I<ARRAYREF [>, I<ARRAYREF]>)
 773
 774 Returns a newly created C<Data::Dumper> object.  The first argument is an
 775 anonymous array of values to be dumped.  The optional second argument is an
 776 anonymous array of names for the values.  The names need not have a leading
 777 C<$> sign, and must be comprised of alphanumeric characters.  You can begin
 778 a name with a C<*> to specify that the dereferenced type must be dumped
 779 instead of the reference itself, for ARRAY and HASH references.
 780
 781 The prefix specified by C<$Data::Dumper::Varname> will be used with a
 782 numeric suffix if the name for a value is undefined.
 783
 784 Data::Dumper will catalog all references encountered while dumping the
 785 values. Cross-references (in the form of names of substructures in perl
 786 syntax) will be inserted at all possible points, preserving any structural
 787 interdependencies in the original set of values.  Structure traversal is
 788 depth-first,  and proceeds in order from the first supplied value to
 789 the last.
 790
 791 =item I<$OBJ>->Dump  I<or>  I<PACKAGE>->Dump(I<ARRAYREF [>, I<ARRAYREF]>)
 792
 793 Returns the stringified form of the values stored in the object (preserving
 794 the order in which they were supplied to C<new>), subject to the
 795 configuration options below.  In a list context, it returns a list
 796 of strings corresponding to the supplied values.
 797
 798 The second form, for convenience, simply calls the C<new> method on its
 799 arguments before dumping the object immediately.
 800
 801 =item I<$OBJ>->Seen(I<[HASHREF]>)
 802
 803 Queries or adds to the internal table of already encountered references.
 804 You must use C<Reset> to explicitly clear the table if needed.  Such
 805 references are not dumped; instead, their names are inserted wherever they
 806 are encountered subsequently.  This is useful especially for properly
 807 dumping subroutine references.
 808
 809 Expects an anonymous hash of name => value pairs.  Same rules apply for names
 810 as in C<new>.  If no argument is supplied, will return the "seen" list of
 811 name => value pairs, in a list context.  Otherwise, returns the object
 812 itself.
 813
 814 =item I<$OBJ>->Values(I<[ARRAYREF]>)
 815
 816 Queries or replaces the internal array of values that will be dumped.
 817 When called without arguments, returns the values.  Otherwise, returns the
 818 object itself.
 819
 820 =item I<$OBJ>->Names(I<[ARRAYREF]>)
 821
 822 Queries or replaces the internal array of user supplied names for the values
 823 that will be dumped.  When called without arguments, returns the names.
 824 Otherwise, returns the object itself.
 825
 826 =item I<$OBJ>->Reset
 827
 828 Clears the internal table of "seen" references and returns the object
 829 itself.
 830
 831 =back
 832
 833 =head2 Functions
 834
 835 =over 4
 836
 837 =item Dumper(I<LIST>)
 838
 839 Returns the stringified form of the values in the list, subject to the
 840 configuration options below.  The values will be named C<$VAR>I<n> in the
 841 output, where I<n> is a numeric suffix.  Will return a list of strings
 842 in a list context.
 843
 844 =back
 845
 846 =head2 Configuration Variables or Methods
 847
 848 Several configuration variables can be used to control the kind of output
 849 generated when using the procedural interface.  These variables are usually
 850 C<local>ized in a block so that other parts of the code are not affected by
 851 the change.
 852
 853 These variables determine the default state of the object created by calling
 854 the C<new> method, but cannot be used to alter the state of the object
 855 thereafter.  The equivalent method names should be used instead to query
 856 or set the internal state of the object.
 857
 858 The method forms return the object itself when called with arguments,
 859 so that they can be chained together nicely.
 860
 861 =over 4
 862
 863 =item *
 864
 865 $Data::Dumper::Indent  I<or>  I<$OBJ>->Indent(I<[NEWVAL]>)
 866
 867 Controls the style of indentation.  It can be set to 0, 1, 2 or 3.  Style 0
 868 spews output without any newlines, indentation, or spaces between list
 869 items.  It is the most compact format possible that can still be called
 870 valid perl.  Style 1 outputs a readable form with newlines but no fancy
 871 indentation (each level in the structure is simply indented by a fixed
 872 amount of whitespace).  Style 2 (the default) outputs a very readable form
 873 which takes into account the length of hash keys (so the hash value lines
 874 up).  Style 3 is like style 2, but also annotates the elements of arrays
 875 with their index (but the comment is on its own line, so array output
 876 consumes twice the number of lines).  Style 2 is the default.
 877
 878 =item *
 879
 880 $Data::Dumper::Purity  I<or>  I<$OBJ>->Purity(I<[NEWVAL]>)
 881
 882 Controls the degree to which the output can be C<eval>ed to recreate the
 883 supplied reference structures.  Setting it to 1 will output additional perl
 884 statements that will correctly recreate nested references.  The default is
 885 0.
 886
 887 =item *
 888
 889 $Data::Dumper::Pad  I<or>  I<$OBJ>->Pad(I<[NEWVAL]>)
 890
 891 Specifies the string that will be prefixed to every line of the output.
 892 Empty string by default.
 893
 894 =item *
 895
 896 $Data::Dumper::Varname  I<or>  I<$OBJ>->Varname(I<[NEWVAL]>)
 897
 898 Contains the prefix to use for tagging variable names in the output. The
 899 default is "VAR".
 900
 901 =item *
 902
 903 $Data::Dumper::Useqq  I<or>  I<$OBJ>->Useqq(I<[NEWVAL]>)
 904
 905 When set, enables the use of double quotes for representing string values.
 906 Whitespace other than space will be represented as C<[\n\t\r]>, "unsafe"
 907 characters will be backslashed, and unprintable characters will be output as
 908 quoted octal integers.  Since setting this variable imposes a performance
 909 penalty, the default is 0.  C<Dump()> will run slower if this flag is set,
 910 since the fast XSUB implementation doesn't support it yet.
 911
 912 =item *
 913
 914 $Data::Dumper::Terse  I<or>  I<$OBJ>->Terse(I<[NEWVAL]>)
 915
 916 When set, Data::Dumper will emit single, non-self-referential values as
 917 atoms/terms rather than statements.  This means that the C<$VAR>I<n> names
 918 will be avoided where possible, but be advised that such output may not
 919 always be parseable by C<eval>.
 920
 921 =item *
 922
 923 $Data::Dumper::Freezer  I<or>  $I<OBJ>->Freezer(I<[NEWVAL]>)
 924
 925 Can be set to a method name, or to an empty string to disable the feature.
 926 Data::Dumper will invoke that method via the object before attempting to
 927 stringify it.  This method can alter the contents of the object (if, for
 928 instance, it contains data allocated from C), and even rebless it in a
 929 different package.  The client is responsible for making sure the specified
 930 method can be called via the object, and that the object ends up containing
 931 only perl data types after the method has been called.  Defaults to an empty
 932 string.
 933
 934 If an object does not support the method specified (determined using
 935 UNIVERSAL::can()) then the call will be skipped.  If the method dies a
 936 warning will be generated.
 937
 938 =item *
 939
 940 $Data::Dumper::Toaster  I<or>  $I<OBJ>->Toaster(I<[NEWVAL]>)
 941
 942 Can be set to a method name, or to an empty string to disable the feature.
 943 Data::Dumper will emit a method call for any objects that are to be dumped
 944 using the syntax C<bless(DATA, CLASS)-E<gt>METHOD()>.  Note that this means that
 945 the method specified will have to perform any modifications required on the
 946 object (like creating new state within it, and/or reblessing it in a
 947 different package) and then return it.  The client is responsible for making
 948 sure the method can be called via the object, and that it returns a valid
 949 object.  Defaults to an empty string.
 950
 951 =item *
 952
 953 $Data::Dumper::Deepcopy  I<or>  $I<OBJ>->Deepcopy(I<[NEWVAL]>)
 954
 955 Can be set to a boolean value to enable deep copies of structures.
 956 Cross-referencing will then only be done when absolutely essential
 957 (i.e., to break reference cycles).  Default is 0.
 958
 959 =item *
 960
 961 $Data::Dumper::Quotekeys  I<or>  $I<OBJ>->Quotekeys(I<[NEWVAL]>)
 962
 963 Can be set to a boolean value to control whether hash keys are quoted.
 964 A false value will avoid quoting hash keys when it looks like a simple
 965 string.  Default is 1, which will always enclose hash keys in quotes.
 966
 967 =item *
 968
 969 $Data::Dumper::Bless  I<or>  $I<OBJ>->Bless(I<[NEWVAL]>)
 970
 971 Can be set to a string that specifies an alternative to the C<bless>
 972 builtin operator used to create objects.  A function with the specified
 973 name should exist, and should accept the same arguments as the builtin.
 974 Default is C<bless>.
 975
 976 =item *
 977
 978 $Data::Dumper::Pair  I<or>  $I<OBJ>->Pair(I<[NEWVAL]>)
 979
 980 Can be set to a string that specifies the separator between hash keys
 981 and values. To dump nested hash, array and scalar values to JavaScript,
 982 use: C<$Data::Dumper::Pair = ' : ';>. Implementing C<bless> in JavaScript
 983 is left as an exercise for the reader.
 984 A function with the specified name exists, and accepts the same arguments
 985 as the builtin.
 986
 987 Default is: C< =E<gt> >.
 988
 989 =item *
 990
 991 $Data::Dumper::Maxdepth  I<or>  $I<OBJ>->Maxdepth(I<[NEWVAL]>)
 992
 993 Can be set to a positive integer that specifies the depth beyond which
 994 which we don't venture into a structure.  Has no effect when
 995 C<Data::Dumper::Purity> is set.  (Useful in debugger when we often don't
 996 want to see more than enough).  Default is 0, which means there is
 997 no maximum depth.
 998
 999 =item *
1000
1001 $Data::Dumper::Useperl  I<or>  $I<OBJ>->Useperl(I<[NEWVAL]>)
1002
1003 Can be set to a boolean value which controls whether the pure Perl
1004 implementation of C<Data::Dumper> is used. The C<Data::Dumper> module is
1005 a dual implementation, with almost all functionality written in both
1006 pure Perl and also in XS ('C'). Since the XS version is much faster, it
1007 will always be used if possible. This option lets you override the
1008 default behavior, usually for testing purposes only. Default is 0, which
1009 means the XS implementation will be used if possible.
1010
1011 =item *
1012
1013 $Data::Dumper::Sortkeys  I<or>  $I<OBJ>->Sortkeys(I<[NEWVAL]>)
1014
1015 Can be set to a boolean value to control whether hash keys are dumped in
1016 sorted order. A true value will cause the keys of all hashes to be
1017 dumped in Perl's default sort order. Can also be set to a subroutine
1018 reference which will be called for each hash that is dumped. In this
1019 case C<Data::Dumper> will call the subroutine once for each hash,
1020 passing it the reference of the hash. The purpose of the subroutine is
1021 to return a reference to an array of the keys that will be dumped, in
1022 the order that they should be dumped. Using this feature, you can
1023 control both the order of the keys, and which keys are actually used. In
1024 other words, this subroutine acts as a filter by which you can exclude
1025 certain keys from being dumped. Default is 0, which means that hash keys
1026 are not sorted.
1027
1028 =item *
1029
1030 $Data::Dumper::Deparse  I<or>  $I<OBJ>->Deparse(I<[NEWVAL]>)
1031
1032 Can be set to a boolean value to control whether code references are
1033 turned into perl source code. If set to a true value, C<B::Deparse>
1034 will be used to get the source of the code reference. Using this option
1035 will force using the Perl implementation of the dumper, since the fast
1036 XSUB implementation doesn't support it.
1037
1038 Caution : use this option only if you know that your coderefs will be
1039 properly reconstructed by C<B::Deparse>.
1040
1041 =back
1042
1043 =head2 Exports
1044
1045 =over 4
1046
1047 =item Dumper
1048
1049 =back
1050
1051 =head1 EXAMPLES
1052
1053 Run these code snippets to get a quick feel for the behavior of this
1054 module.  When you are through with these examples, you may want to
1055 add or change the various configuration variables described above,
1056 to see their behavior.  (See the testsuite in the Data::Dumper
1057 distribution for more examples.)
1058
1059
1060     use Data::Dumper;
1061
1062     package Foo;
1063     sub new {bless {'a' => 1, 'b' => sub { return "foo" }}, $_[0]};
1064
1065     package Fuz;                       # a weird REF-REF-SCALAR object
1066     sub new {bless \($_ = \ 'fu\'z'), $_[0]};
1067
1068     package main;
1069     $foo = Foo->new;
1070     $fuz = Fuz->new;
1071     $boo = [ 1, [], "abcd", \*foo,
1072              {1 => 'a', 023 => 'b', 0x45 => 'c'},
1073              \\"p\q\'r", $foo, $fuz];
1074
1075     ########
1076     # simple usage
1077     ########
1078
1079     $bar = eval(Dumper($boo));
1080     print($@) if $@;
1081     print Dumper($boo), Dumper($bar);  # pretty print (no array indices)
1082
1083     $Data::Dumper::Terse = 1;          # don't output names where feasible
1084     $Data::Dumper::Indent = 0;         # turn off all pretty print
1085     print Dumper($boo), "\n";
1086
1087     $Data::Dumper::Indent = 1;         # mild pretty print
1088     print Dumper($boo);
1089
1090     $Data::Dumper::Indent = 3;         # pretty print with array indices
1091     print Dumper($boo);
1092
1093     $Data::Dumper::Useqq = 1;          # print strings in double quotes
1094     print Dumper($boo);
1095
1096     $Data::Dumper::Pair = " : ";       # specify hash key/value separator
1097     print Dumper($boo);
1098
1099
1100     ########
1101     # recursive structures
1102     ########
1103
1104     @c = ('c');
1105     $c = \@c;
1106     $b = {};
1107     $a = [1, $b, $c];
1108     $b->{a} = $a;
1109     $b->{b} = $a->[1];
1110     $b->{c} = $a->[2];
1111     print Data::Dumper->Dump([$a,$b,$c], [qw(a b c)]);
1112
1113
1114     $Data::Dumper::Purity = 1;         # fill in the holes for eval
1115     print Data::Dumper->Dump([$a, $b], [qw(*a b)]); # print as @a
1116     print Data::Dumper->Dump([$b, $a], [qw(*b a)]); # print as %b
1117
1118
1119     $Data::Dumper::Deepcopy = 1;       # avoid cross-refs
1120     print Data::Dumper->Dump([$b, $a], [qw(*b a)]);
1121
1122
1123     $Data::Dumper::Purity = 0;         # avoid cross-refs
1124     print Data::Dumper->Dump([$b, $a], [qw(*b a)]);
1125
1126     ########
1127     # deep structures
1128     ########
1129
1130     $a = "pearl";
1131     $b = [ $a ];
1132     $c = { 'b' => $b };
1133     $d = [ $c ];
1134     $e = { 'd' => $d };
1135     $f = { 'e' => $e };
1136     print Data::Dumper->Dump([$f], [qw(f)]);
1137
1138     $Data::Dumper::Maxdepth = 3;       # no deeper than 3 refs down
1139     print Data::Dumper->Dump([$f], [qw(f)]);
1140
1141
1142     ########
1143     # object-oriented usage
1144     ########
1145
1146     $d = Data::Dumper->new([$a,$b], [qw(a b)]);
1147     $d->Seen({'*c' => $c});            # stash a ref without printing it
1148     $d->Indent(3);
1149     print $d->Dump;
1150     $d->Reset->Purity(0);              # empty the seen cache
1151     print join "----\n", $d->Dump;
1152
1153
1154     ########
1155     # persistence
1156     ########
1157
1158     package Foo;
1159     sub new { bless { state => 'awake' }, shift }
1160     sub Freeze {
1161         my $s = shift;
1162         print STDERR "preparing to sleep\n";
1163         $s->{state} = 'asleep';
1164         return bless $s, 'Foo::ZZZ';
1165     }
1166
1167     package Foo::ZZZ;
1168     sub Thaw {
1169         my $s = shift;
1170         print STDERR "waking up\n";
1171         $s->{state} = 'awake';
1172         return bless $s, 'Foo';
1173     }
1174
1175     package Foo;
1176     use Data::Dumper;
1177     $a = Foo->new;
1178     $b = Data::Dumper->new([$a], ['c']);
1179     $b->Freezer('Freeze');
1180     $b->Toaster('Thaw');
1181     $c = $b->Dump;
1182     print $c;
1183     $d = eval $c;
1184     print Data::Dumper->Dump([$d], ['d']);
1185
1186
1187     ########
1188     # symbol substitution (useful for recreating CODE refs)
1189     ########
1190
1191     sub foo { print "foo speaking\n" }
1192     *other = \&foo;
1193     $bar = [ \&other ];
1194     $d = Data::Dumper->new([\&other,$bar],['*other','bar']);
1195     $d->Seen({ '*foo' => \&foo });
1196     print $d->Dump;
1197
1198
1199     ########
1200     # sorting and filtering hash keys
1201     ########
1202
1203     $Data::Dumper::Sortkeys = \&my_filter;
1204     my $foo = { map { (ord, "$_$_$_") } 'I'..'Q' };
1205     my $bar = { %$foo };
1206     my $baz = { reverse %$foo };
1207     print Dumper [ $foo, $bar, $baz ];
1208
1209     sub my_filter {
1210         my ($hash) = @_;
1211         # return an array ref containing the hash keys to dump
1212         # in the order that you want them to be dumped
1213         return [
1214           # Sort the keys of %$foo in reverse numeric order
1215             $hash eq $foo ? (sort {$b <=> $a} keys %$hash) :
1216           # Only dump the odd number keys of %$bar
1217             $hash eq $bar ? (grep {$_ % 2} keys %$hash) :
1218           # Sort keys in default order for all other hashes
1219             (sort keys %$hash)
1220         ];
1221     }
1222
1223 =head1 BUGS
1224
1225 Due to limitations of Perl subroutine call semantics, you cannot pass an
1226 array or hash.  Prepend it with a C<\> to pass its reference instead.  This
1227 will be remedied in time, now that Perl has subroutine prototypes.
1228 For now, you need to use the extended usage form, and prepend the
1229 name with a C<*> to output it as a hash or array.
1230
1231 C<Data::Dumper> cheats with CODE references.  If a code reference is
1232 encountered in the structure being processed (and if you haven't set
1233 the C<Deparse> flag), an anonymous subroutine that
1234 contains the string '"DUMMY"' will be inserted in its place, and a warning
1235 will be printed if C<Purity> is set.  You can C<eval> the result, but bear
1236 in mind that the anonymous sub that gets created is just a placeholder.
1237 Someday, perl will have a switch to cache-on-demand the string
1238 representation of a compiled piece of code, I hope.  If you have prior
1239 knowledge of all the code refs that your data structures are likely
1240 to have, you can use the C<Seen> method to pre-seed the internal reference
1241 table and make the dumped output point to them, instead.  See L</EXAMPLES>
1242 above.
1243
1244 The C<Useqq> and C<Deparse> flags makes Dump() run slower, since the
1245 XSUB implementation does not support them.
1246
1247 SCALAR objects have the weirdest looking C<bless> workaround.
1248
1249 Pure Perl version of C<Data::Dumper> escapes UTF-8 strings correctly
1250 only in Perl 5.8.0 and later.
1251
1252 =head2 NOTE
1253
1254 Starting from Perl 5.8.1 different runs of Perl will have different
1255 ordering of hash keys.  The change was done for greater security,
1256 see L<perlsec/"Algorithmic Complexity Attacks">.  This means that
1257 different runs of Perl will have different Data::Dumper outputs if
1258 the data contains hashes.  If you need to have identical Data::Dumper
1259 outputs from different runs of Perl, use the environment variable
1260 PERL_HASH_SEED, see L<perlrun/PERL_HASH_SEED>.  Using this restores
1261 the old (platform-specific) ordering: an even prettier solution might
1262 be to use the C<Sortkeys> filter of Data::Dumper.
1263
1264 =head1 AUTHOR
1265
1266 Gurusamy Sarathy        gsar@activestate.com
1267
1268 Copyright (c) 1996-98 Gurusamy Sarathy. All rights reserved.
1269 This program is free software; you can redistribute it and/or
1270 modify it under the same terms as Perl itself.
1271
1272 =head1 VERSION
1273
1274 Version 2.121  (Aug 24 2003)
1275
1276 =head1 SEE ALSO
1277
1278 perl(1)
1279
1280 =cut