ext/Cwd/t/cwd.t

   1 #!./perl -w
   2
   3 BEGIN {
   4     if ($ENV{PERL_CORE}) {
   5         chdir 't';
   6         @INC = '../lib';
   7     }
   8 }
   9 use Cwd;
  10 chdir 't';
  11
  12 use strict;
  13 use Config;
  14 use File::Spec;
  15 use File::Path;
  16
  17 use lib File::Spec->catdir('t', 'lib');
  18 use Test::More;
  19 require VMS::Filespec if $^O eq 'VMS';
  20
  21 my $tests = 28;
  22 # _perl_abs_path() currently only works when the directory separator
  23 # is '/', so don't test it when it won't work.
  24 my $EXTRA_ABSPATH_TESTS = ($Config{prefix} =~ m/\//) && $^O ne 'cygwin';
  25 $tests += 4 if $EXTRA_ABSPATH_TESTS;
  26 plan tests => $tests;
  27
  28 SKIP: {
  29     skip "not suitable for core perl testing", 1 if $ENV{PERL_CORE};
  30     like $INC{'Cwd.pm'}, qr{blib}i, "Cwd should be loaded from blib/ during testing";
  31 }
  32
  33 my $IsVMS = $^O eq 'VMS';
  34 my $IsMacOS = $^O eq 'MacOS';
  35
  36 # check imports
  37 can_ok('main', qw(cwd getcwd fastcwd fastgetcwd));
  38 ok( !defined(&chdir),           'chdir() not exported by default' );
  39 ok( !defined(&abs_path),        '  nor abs_path()' );
  40 ok( !defined(&fast_abs_path),   '  nor fast_abs_path()');
  41
  42
  43 # XXX force Cwd to bootsrap its XSUBs since we have set @INC = "../lib"
  44 # XXX and subsequent chdir()s can make them impossible to find
  45 eval { fastcwd };
  46
  47 # Must find an external pwd (or equivalent) command.
  48
  49 my $pwd = $^O eq 'MSWin32' ? "cmd" : "pwd";
  50 my $pwd_cmd =
  51     ($^O eq "NetWare") ?
  52         "cd" :
  53     ($IsMacOS) ?
  54         "pwd" :
  55         (grep { -x && -f } map { "$_/$pwd$Config{exe_ext}" }
  56                            split m/$Config{path_sep}/, $ENV{PATH})[0];
  57
  58 $pwd_cmd = 'SHOW DEFAULT' if $IsVMS;
  59 if ($^O eq 'MSWin32') {
  60     $pwd_cmd =~ s,/,\\,g;
  61     $pwd_cmd = "$pwd_cmd /c cd";
  62 }
  63 $pwd_cmd =~ s=\\=/=g if ($^O eq 'dos');
  64
  65 SKIP: {
  66     skip "No native pwd command found to test against", 4 unless $pwd_cmd;
  67
  68     print "# native pwd = '$pwd_cmd'\n";
  69
  70     local @ENV{qw(PATH IFS CDPATH ENV BASH_ENV)};
  71     my ($pwd_cmd_untainted) = $pwd_cmd =~ /^(.+)$/; # Untaint.
  72     chomp(my $start = `$pwd_cmd_untainted`);
  73
  74     # Win32's cd returns native C:\ style
  75     $start =~ s,\\,/,g if ($^O eq 'MSWin32' || $^O eq "NetWare");
  76     # DCL SHOW DEFAULT has leading spaces
  77     $start =~ s/^\s+// if $IsVMS;
  78     SKIP: {
  79         skip("'$pwd_cmd' failed, nothing to test against", 4) if $?;
  80         skip("/afs seen, paths unlikely to match", 4) if $start =~ m|/afs/|;
  81
  82         # Darwin's getcwd(3) (which Cwd.xs:bsd_realpath() uses which
  83         # Cwd.pm:getcwd uses) has some magic related to the PWD
  84         # environment variable: if PWD is set to a directory that
  85         # looks about right (guess: has the same (dev,ino) as the '.'?),
  86         # the PWD is returned.  However, if that path contains
  87         # symlinks, the path will not be equal to the one returned by
  88         # /bin/pwd (which probably uses the usual walking upwards in
  89         # the path -trick).  This situation is easy to reproduce since
  90         # /tmp is a symlink to /private/tmp.  Therefore we invalidate
  91         # the PWD to force getcwd(3) to (re)compute the cwd in full.
  92         # Admittedly fixing this in the Cwd module would be better
  93         # long-term solution but deleting $ENV{PWD} should not be
  94         # done light-heartedly. --jhi
  95         delete $ENV{PWD} if $^O eq 'darwin';
  96
  97         my $cwd        = cwd;
  98         my $getcwd     = getcwd;
  99         my $fastcwd    = fastcwd;
 100         my $fastgetcwd = fastgetcwd;
 101
 102         is($cwd,        $start, 'cwd()');
 103         is($getcwd,     $start, 'getcwd()');
 104         is($fastcwd,    $start, 'fastcwd()');
 105         is($fastgetcwd, $start, 'fastgetcwd()');
 106     }
 107 }
 108
 109 my @test_dirs = qw{_ptrslt_ _path_ _to_ _a_ _dir_};
 110 my $Test_Dir     = File::Spec->catdir(@test_dirs);
 111
 112 mkpath([$Test_Dir], 0, 0777);
 113 Cwd::chdir $Test_Dir;
 114
 115 foreach my $func (qw(cwd getcwd fastcwd fastgetcwd)) {
 116   my $result = eval "$func()";
 117   is $@, '';
 118   dir_ends_with( $result, $Test_Dir, "$func()" );
 119 }
 120
 121 # Cwd::chdir should also update $ENV{PWD}
 122 dir_ends_with( $ENV{PWD}, $Test_Dir, 'Cwd::chdir() updates $ENV{PWD}' );
 123 my $updir = File::Spec->updir;
 124 Cwd::chdir $updir;
 125 print "#$ENV{PWD}\n";
 126 Cwd::chdir $updir;
 127 print "#$ENV{PWD}\n";
 128 Cwd::chdir $updir;
 129 print "#$ENV{PWD}\n";
 130 Cwd::chdir $updir;
 131 print "#$ENV{PWD}\n";
 132 Cwd::chdir $updir;
 133 print "#$ENV{PWD}\n";
 134
 135 rmtree($test_dirs[0], 0, 0);
 136
 137 {
 138   my $check = ($IsVMS   ? qr|\b((?i)t)\]$| :
 139                $IsMacOS ? qr|\bt:$| :
 140                           qr|\bt$| );
 141
 142   like($ENV{PWD}, $check);
 143 }
 144
 145 {
 146   # Make sure abs_path() doesn't trample $ENV{PWD}
 147   my $start_pwd = $ENV{PWD};
 148   mkpath([$Test_Dir], 0, 0777);
 149   Cwd::abs_path($Test_Dir);
 150   is $ENV{PWD}, $start_pwd;
 151   rmtree($test_dirs[0], 0, 0);
 152 }
 153
 154 SKIP: {
 155     skip "no symlinks on this platform", 2+$EXTRA_ABSPATH_TESTS unless $Config{d_symlink};
 156
 157     mkpath([$Test_Dir], 0, 0777);
 158     symlink $Test_Dir, "linktest";
 159
 160     my $abs_path      =  Cwd::abs_path("linktest");
 161     my $fast_abs_path =  Cwd::fast_abs_path("linktest");
 162     my $want          =  File::Spec->catdir("t", $Test_Dir);
 163
 164     like($abs_path,      qr|$want$|);
 165     like($fast_abs_path, qr|$want$|);
 166     like(Cwd::_perl_abs_path("linktest"), qr|$want$|) if $EXTRA_ABSPATH_TESTS;
 167
 168     rmtree($test_dirs[0], 0, 0);
 169     unlink "linktest";
 170 }
 171
 172 if ($ENV{PERL_CORE}) {
 173     chdir '../ext/Cwd/t';
 174     unshift @INC, '../../../lib';
 175 }
 176
 177 # Make sure we can run abs_path() on files, not just directories
 178 my $path = 'cwd.t';
 179 path_ends_with(Cwd::abs_path($path), 'cwd.t', 'abs_path() can be invoked on a file');
 180 path_ends_with(Cwd::fast_abs_path($path), 'cwd.t', 'fast_abs_path() can be invoked on a file');
 181 path_ends_with(Cwd::_perl_abs_path($path), 'cwd.t', '_perl_abs_path() can be invoked on a file')
 182   if $EXTRA_ABSPATH_TESTS;
 183
 184 $path = File::Spec->catfile(File::Spec->updir, 't', $path);
 185 path_ends_with(Cwd::abs_path($path), 'cwd.t', 'abs_path() can be invoked on a file');
 186 path_ends_with(Cwd::fast_abs_path($path), 'cwd.t', 'fast_abs_path() can be invoked on a file');
 187 path_ends_with(Cwd::_perl_abs_path($path), 'cwd.t', '_perl_abs_path() can be invoked on a file')
 188   if $EXTRA_ABSPATH_TESTS;
 189
 190
 191
 192 SKIP: {
 193   my $file;
 194   {
 195     my $root = File::Spec->rootdir;
 196     local *FH;
 197     opendir FH, $root or skip("Can't opendir($root): $!", 2+$EXTRA_ABSPATH_TESTS);
 198     ($file) = grep {-f $_ and not -l $_} map File::Spec->catfile($root, $_), readdir FH;
 199     closedir FH;
 200   }
 201   skip "No plain file in root directory to test with", 2+$EXTRA_ABSPATH_TESTS unless $file;
 202
 203   $file = VMS::Filespec::rmsexpand($file) if $^O eq 'VMS';
 204   is Cwd::abs_path($file), $file, 'abs_path() works on files in the root directory';
 205   is Cwd::fast_abs_path($file), $file, 'fast_abs_path() works on files in the root directory';
 206   is Cwd::_perl_abs_path($file), $file, '_perl_abs_path() works on files in the root directory'
 207     if $EXTRA_ABSPATH_TESTS;
 208 }
 209
 210
 211 #############################################
 212 # These routines give us sort of a poor-man's cross-platform
 213 # directory or path comparison capability.
 214
 215 sub bracketed_form_dir {
 216   return join '', map "[$_]",
 217     grep length, File::Spec->splitdir(File::Spec->canonpath( shift() ));
 218 }
 219
 220 sub dir_ends_with {
 221   my ($dir, $expect) = (shift, shift);
 222   my $bracketed_expect = quotemeta bracketed_form_dir($expect);
 223   like( bracketed_form_dir($dir), qr|$bracketed_expect$|i, (@_ ? shift : ()) );
 224 }
 225
 226 sub bracketed_form_path {
 227   return join '', map "[$_]",
 228     grep length, File::Spec->splitpath(File::Spec->canonpath( shift() ));
 229 }
 230
 231 sub path_ends_with {
 232   my ($dir, $expect) = (shift, shift);
 233   my $bracketed_expect = quotemeta bracketed_form_path($expect);
 234   like( bracketed_form_path($dir), qr|$bracketed_expect$|i, (@_ ? shift : ()) );
 235 }