ext/Cwd/t/cwd.t

   1 #!./perl
   2
   3 BEGIN {
   4     chdir 't' if -d 't';
   5     @INC = '../lib';
   6 }
   7
   8 use Config;
   9 use Cwd;
  10 use strict;
  11 use warnings;
  12 use File::Path;
  13
  14 use Test::More tests => 16;
  15
  16 my $IsVMS = $^O eq 'VMS';
  17
  18 # check imports
  19 can_ok('main', qw(cwd getcwd fastcwd fastgetcwd));
  20 ok( !defined(&chdir),           'chdir() not exported by default' );
  21 ok( !defined(&abs_path),        '  nor abs_path()' );
  22 ok( !defined(&fast_abs_path),   '  nor fast_abs_path()');
  23
  24
  25 # XXX force Cwd to bootsrap its XSUBs since we have set @INC = "../lib"
  26 # XXX and subsequent chdir()s can make them impossible to find
  27 eval { fastcwd };
  28
  29 # Must find an external pwd (or equivalent) command.
  30
  31 my $pwd = $^O eq 'MSWin32' ? "cmd" : "pwd";
  32 my $pwd_cmd =
  33     ($^O eq "NetWare") ?
  34         "cd" :
  35         (grep { -x && -f } map { "$_/$pwd$Config{exe_ext}" }
  36                            split m/$Config{path_sep}/, $ENV{PATH})[0];
  37
  38 $pwd_cmd = 'SHOW DEFAULT' if $IsVMS;
  39 if ($^O eq 'MSWin32') {
  40     $pwd_cmd =~ s,/,\\,g;
  41     $pwd_cmd = "$pwd_cmd /c cd";
  42 }
  43 $pwd_cmd =~ s=\\=/=g if ($^O eq 'dos');
  44
  45 print "# native pwd = '$pwd_cmd'\n";
  46
  47 SKIP: {
  48     skip "No native pwd command found to test against", 4 unless $pwd_cmd;
  49
  50     local @ENV{qw(PATH IFS CDPATH ENV BASH_ENV)};
  51     my ($pwd_cmd_untainted) = $pwd_cmd =~ /^(.+)$/; # Untaint.
  52     chomp(my $start = `$pwd_cmd_untainted`);
  53
  54     # Win32's cd returns native C:\ style
  55     $start =~ s,\\,/,g if ($^O eq 'MSWin32' || $^O eq "NetWare");
  56     # DCL SHOW DEFAULT has leading spaces
  57     $start =~ s/^\s+// if $IsVMS;
  58     SKIP: {
  59         skip "'$pwd_cmd' failed, nothing to test against", 4 if $?;
  60
  61         my $cwd        = cwd;
  62         my $getcwd     = getcwd;
  63         my $fastcwd    = fastcwd;
  64         my $fastgetcwd = fastgetcwd;
  65         is(cwd(),       $start, 'cwd()');
  66         is(getcwd(),    $start, 'getcwd()');
  67         is(fastcwd(),   $start, 'fastcwd()');
  68         is(fastgetcwd(),$start, 'fastgetcwd()');
  69     }
  70 }
  71
  72 my $Top_Test_Dir = '_ptrslt_';
  73 my $Test_Dir     = "$Top_Test_Dir/_path_/_to_/_a_/_dir_";
  74 my $want = "t/$Test_Dir";
  75 if( $IsVMS ) {
  76     # translate the unixy path to VMSish
  77     $want =~ s|/|\.|g;
  78     $want .= '\]';
  79     $want = '((?i)' . $want . ')';  # might be ODS-2 or ODS-5
  80 }
  81
  82 mkpath(["$Test_Dir"], 0, 0777);
  83 Cwd::chdir "$Test_Dir";
  84
  85 like(cwd(),        qr|$want$|, 'chdir() + cwd()');
  86 like(getcwd(),     qr|$want$|, '        + getcwd()');
  87 like(fastcwd(),    qr|$want$|, '        + fastcwd()');
  88 like(fastgetcwd(), qr|$want$|, '        + fastgetcwd()');
  89
  90 # Cwd::chdir should also update $ENV{PWD}
  91 like($ENV{PWD}, qr|$want$|,      'Cwd::chdir() updates $ENV{PWD}');
  92 Cwd::chdir "..";
  93 print "#$ENV{PWD}\n";
  94 Cwd::chdir "..";
  95 print "#$ENV{PWD}\n";
  96 Cwd::chdir "..";
  97 print "#$ENV{PWD}\n";
  98 Cwd::chdir "..";
  99 print "#$ENV{PWD}\n";
 100 Cwd::chdir "..";
 101 print "#$ENV{PWD}\n";
 102
 103 rmtree([$Top_Test_Dir], 0, 0);
 104
 105 if ($IsVMS) {
 106     like($ENV{PWD}, qr|\b((?i)t)\]$|);
 107 }
 108 else {
 109     like($ENV{PWD}, qr|\bt$|);
 110 }
 111
 112 SKIP: {
 113     skip "no symlinks on this platform", 2 unless $Config{d_symlink};
 114
 115     mkpath([$Test_Dir], 0, 0777);
 116     symlink $Test_Dir => "linktest";
 117
 118     my $abs_path      =  Cwd::abs_path("linktest");
 119     my $fast_abs_path =  Cwd::fast_abs_path("linktest");
 120     my $want          = "t/$Test_Dir";
 121
 122     like($abs_path,      qr|$want$|);
 123     like($fast_abs_path, qr|$want$|);
 124
 125     rmtree([$Top_Test_Dir], 0, 0);
 126     unlink "linktest";
 127 }