ext/B/O.pm

   1 package O;
   2
   3 our $VERSION = '1.00';
   4
   5 use B qw(minus_c save_BEGINs);
   6 use Carp;
   7
   8 sub import {
   9     my ($class, @options) = @_;
  10     my ($quiet, $veryquiet) = (0, 0);
  11     if ($options[0] eq '-q' || $options[0] eq '-qq') {
  12         $quiet = 1;
  13         open (SAVEOUT, ">&STDOUT");
  14         close STDOUT;
  15         open (STDOUT, ">", \$O::BEGIN_output);
  16         if ($options[0] eq '-qq') {
  17             $veryquiet = 1;
  18         }
  19         shift @options;
  20     }
  21     my $backend = shift (@options);
  22     eval q[
  23         BEGIN {
  24             minus_c;
  25             save_BEGINs;
  26         }
  27
  28         CHECK {
  29             if ($quiet) {
  30                 close STDOUT;
  31                 open (STDOUT, ">&SAVEOUT");
  32                 close SAVEOUT;
  33             }
  34             use B::].$backend.q[ ();
  35             if ($@) {
  36                 croak "use of backend $backend failed: $@";
  37             }
  38
  39
  40             my $compilesub = &{"B::${backend}::compile"}(@options);
  41             if (ref($compilesub) ne "CODE") {
  42                 die $compilesub;
  43             }
  44
  45            local ($\,$",$,) = (undef,' ','');
  46             &$compilesub();
  47
  48             close STDERR if $veryquiet;
  49         }
  50     ];
  51     die $@ if $@;
  52 }
  53
  54 1;
  55
  56 __END__
  57
  58 =head1 NAME
  59
  60 O - Generic interface to Perl Compiler backends
  61
  62 =head1 SYNOPSIS
  63
  64         perl -MO=[-q,]Backend[,OPTIONS] foo.pl
  65
  66 =head1 DESCRIPTION
  67
  68 This is the module that is used as a frontend to the Perl Compiler.
  69
  70 If you pass the C<-q> option to the module, then the STDOUT
  71 filehandle will be redirected into the variable C<$O::BEGIN_output>
  72 during compilation.  This has the effect that any output printed
  73 to STDOUT by BEGIN blocks or use'd modules will be stored in this
  74 variable rather than printed. It's useful with those backends which
  75 produce output themselves (C<Deparse>, C<Concise> etc), so that
  76 their output is not confused with that generated by the code
  77 being compiled.
  78
  79 The C<-qq> option behaves like C<-q>, except that it also closes
  80 STDERR after deparsing has finished. This suppresses the "Syntax OK"
  81 message normally produced by perl.
  82
  83 =head1 CONVENTIONS
  84
  85 Most compiler backends use the following conventions: OPTIONS
  86 consists of a comma-separated list of words (no white-space).
  87 The C<-v> option usually puts the backend into verbose mode.
  88 The C<-ofile> option generates output to B<file> instead of
  89 stdout. The C<-D> option followed by various letters turns on
  90 various internal debugging flags. See the documentation for the
  91 desired backend (named C<B::Backend> for the example above) to
  92 find out about that backend.
  93
  94 =head1 IMPLEMENTATION
  95
  96 This section is only necessary for those who want to write a
  97 compiler backend module that can be used via this module.
  98
  99 The command-line mentioned in the SYNOPSIS section corresponds to
 100 the Perl code
 101
 102     use O ("Backend", OPTIONS);
 103
 104 The C<import> function which that calls loads in the appropriate
 105 C<B::Backend> module and calls the C<compile> function in that
 106 package, passing it OPTIONS. That function is expected to return
 107 a sub reference which we'll call CALLBACK. Next, the "compile-only"
 108 flag is switched on (equivalent to the command-line option C<-c>)
 109 and a CHECK block is registered which calls CALLBACK. Thus the main
 110 Perl program mentioned on the command-line is read in, parsed and
 111 compiled into internal syntax tree form. Since the C<-c> flag is
 112 set, the program does not start running (excepting BEGIN blocks of
 113 course) but the CALLBACK function registered by the compiler
 114 backend is called.
 115
 116 In summary, a compiler backend module should be called "B::Foo"
 117 for some foo and live in the appropriate directory for that name.
 118 It should define a function called C<compile>. When the user types
 119
 120     perl -MO=Foo,OPTIONS foo.pl
 121
 122 that function is called and is passed those OPTIONS (split on
 123 commas). It should return a sub ref to the main compilation function.
 124 After the user's program is loaded and parsed, that returned sub ref
 125 is invoked which can then go ahead and do the compilation, usually by
 126 making use of the C<B> module's functionality.
 127
 128 =head1 AUTHOR
 129
 130 Malcolm Beattie, C<mbeattie@sable.ox.ac.uk>
 131
 132 =cut