ext/B/B/Deparse.pm

   1 # B::Deparse.pm
   2 # Copyright (c) 1998-2000, 2002, 2003, 2004, 2005, 2006 Stephen McCamant.
   3 # All rights reserved.
   4 # This module is free software; you can redistribute and/or modify
   5 # it under the same terms as Perl itself.
   6
   7 # This is based on the module of the same name by Malcolm Beattie,
   8 # but essentially none of his code remains.
   9
  10 package B::Deparse;
  11 use Carp;
  12 use B qw(class main_root main_start main_cv svref_2object opnumber perlstring
  13          OPf_WANT OPf_WANT_VOID OPf_WANT_SCALAR OPf_WANT_LIST
  14          OPf_KIDS OPf_REF OPf_STACKED OPf_SPECIAL OPf_MOD
  15          OPpLVAL_INTRO OPpOUR_INTRO OPpENTERSUB_AMPER OPpSLICE OPpCONST_BARE
  16          OPpTRANS_SQUASH OPpTRANS_DELETE OPpTRANS_COMPLEMENT OPpTARGET_MY
  17          OPpCONST_ARYBASE OPpEXISTS_SUB OPpSORT_NUMERIC OPpSORT_INTEGER
  18          OPpSORT_REVERSE OPpSORT_INPLACE OPpSORT_DESCEND OPpITER_REVERSED
  19          SVf_IOK SVf_NOK SVf_ROK SVf_POK SVpad_OUR SVf_FAKE SVs_RMG SVs_SMG
  20          CVf_METHOD CVf_LOCKED CVf_LVALUE CVf_ASSERTION
  21          PMf_KEEP PMf_GLOBAL PMf_CONTINUE PMf_EVAL PMf_ONCE PMf_SKIPWHITE
  22          PMf_MULTILINE PMf_SINGLELINE PMf_FOLD PMf_EXTENDED);
  23 $VERSION = 0.74;
  24 use strict;
  25 use vars qw/$AUTOLOAD/;
  26 use warnings ();
  27
  28 # Changes between 0.50 and 0.51:
  29 # - fixed nulled leave with live enter in sort { }
  30 # - fixed reference constants (\"str")
  31 # - handle empty programs gracefully
  32 # - handle infinte loops (for (;;) {}, while (1) {})
  33 # - differentiate between `for my $x ...' and `my $x; for $x ...'
  34 # - various minor cleanups
  35 # - moved globals into an object
  36 # - added `-u', like B::C
  37 # - package declarations using cop_stash
  38 # - subs, formats and code sorted by cop_seq
  39 # Changes between 0.51 and 0.52:
  40 # - added pp_threadsv (special variables under USE_5005THREADS)
  41 # - added documentation
  42 # Changes between 0.52 and 0.53:
  43 # - many changes adding precedence contexts and associativity
  44 # - added `-p' and `-s' output style options
  45 # - various other minor fixes
  46 # Changes between 0.53 and 0.54:
  47 # - added support for new `for (1..100)' optimization,
  48 #   thanks to Gisle Aas
  49 # Changes between 0.54 and 0.55:
  50 # - added support for new qr// construct
  51 # - added support for new pp_regcreset OP
  52 # Changes between 0.55 and 0.56:
  53 # - tested on base/*.t, cmd/*.t, comp/*.t, io/*.t
  54 # - fixed $# on non-lexicals broken in last big rewrite
  55 # - added temporary fix for change in opcode of OP_STRINGIFY
  56 # - fixed problem in 0.54's for() patch in `for (@ary)'
  57 # - fixed precedence in conditional of ?:
  58 # - tweaked list paren elimination in `my($x) = @_'
  59 # - made continue-block detection trickier wrt. null ops
  60 # - fixed various prototype problems in pp_entersub
  61 # - added support for sub prototypes that never get GVs
  62 # - added unquoting for special filehandle first arg in truncate
  63 # - print doubled rv2gv (a bug) as `*{*GV}' instead of illegal `**GV'
  64 # - added semicolons at the ends of blocks
  65 # - added -l `#line' declaration option -- fixes cmd/subval.t 27,28
  66 # Changes between 0.56 and 0.561:
  67 # - fixed multiply-declared my var in pp_truncate (thanks to Sarathy)
  68 # - used new B.pm symbolic constants (done by Nick Ing-Simmons)
  69 # Changes between 0.561 and 0.57:
  70 # - stylistic changes to symbolic constant stuff
  71 # - handled scope in s///e replacement code
  72 # - added unquote option for expanding "" into concats, etc.
  73 # - split method and proto parts of pp_entersub into separate functions
  74 # - various minor cleanups
  75 # Changes after 0.57:
  76 # - added parens in \&foo (patch by Albert Dvornik)
  77 # Changes between 0.57 and 0.58:
  78 # - fixed `0' statements that weren't being printed
  79 # - added methods for use from other programs
  80 #   (based on patches from James Duncan and Hugo van der Sanden)
  81 # - added -si and -sT to control indenting (also based on a patch from Hugo)
  82 # - added -sv to print something else instead of '???'
  83 # - preliminary version of utf8 tr/// handling
  84 # Changes after 0.58:
  85 # - uses of $op->ppaddr changed to new $op->name (done by Sarathy)
  86 # - added support for Hugo's new OP_SETSTATE (like nextstate)
  87 # Changes between 0.58 and 0.59
  88 # - added support for Chip's OP_METHOD_NAMED
  89 # - added support for Ilya's OPpTARGET_MY optimization
  90 # - elided arrows before `()' subscripts when possible
  91 # Changes between 0.59 and 0.60
  92 # - support for method attribues was added
  93 # - some warnings fixed
  94 # - separate recognition of constant subs
  95 # - rewrote continue block handling, now recoginizing for loops
  96 # - added more control of expanding control structures
  97 # Changes between 0.60 and 0.61 (mostly by Robin Houston)
  98 # - many bug-fixes
  99 # - support for pragmas and 'use'
 100 # - support for the little-used $[ variable
 101 # - support for __DATA__ sections
 102 # - UTF8 support
 103 # - BEGIN, CHECK, INIT and END blocks
 104 # - scoping of subroutine declarations fixed
 105 # - compile-time output from the input program can be suppressed, so that the
 106 #   output is just the deparsed code. (a change to O.pm in fact)
 107 # - our() declarations
 108 # - *all* the known bugs are now listed in the BUGS section
 109 # - comprehensive test mechanism (TEST -deparse)
 110 # Changes between 0.62 and 0.63 (mostly by Rafael Garcia-Suarez)
 111 # - bug-fixes
 112 # - new switch -P
 113 # - support for command-line switches (-l, -0, etc.)
 114 # Changes between 0.63 and 0.64
 115 # - support for //, CHECK blocks, and assertions
 116 # - improved handling of foreach loops and lexicals
 117 # - option to use Data::Dumper for constants
 118 # - more bug fixes
 119 # - discovered lots more bugs not yet fixed
 120 #
 121 # ...
 122 #
 123 # Changes between 0.72 and 0.73
 124 # - support new switch constructs
 125
 126 # Todo:
 127 #  (See also BUGS section at the end of this file)
 128 #
 129 # - finish tr/// changes
 130 # - add option for even more parens (generalize \&foo change)
 131 # - left/right context
 132 # - copy comments (look at real text with $^P?)
 133 # - avoid semis in one-statement blocks
 134 # - associativity of &&=, ||=, ?:
 135 # - ',' => '=>' (auto-unquote?)
 136 # - break long lines ("\r" as discretionary break?)
 137 # - configurable syntax highlighting: ANSI color, HTML, TeX, etc.
 138 # - more style options: brace style, hex vs. octal, quotes, ...
 139 # - print big ints as hex/octal instead of decimal (heuristic?)
 140 # - handle `my $x if 0'?
 141 # - version using op_next instead of op_first/sibling?
 142 # - avoid string copies (pass arrays, one big join?)
 143 # - here-docs?
 144
 145 # Current test.deparse failures
 146 # comp/assertions 38 - disabled assertions should be like "my($x) if 0"
 147 #    'sub f : assertion {}; no assertions; my $x=1; {f(my $x=2); print "$x\n"}'
 148 # comp/hints 6 - location of BEGIN blocks wrt. block openings
 149 # run/switchI 1 - missing -I switches entirely
 150 #    perl -Ifoo -e 'print @INC'
 151 # op/caller 2 - warning mask propagates backwards before warnings::register
 152 #    'use warnings; BEGIN {${^WARNING_BITS} eq "U"x12;} use warnings::register'
 153 # op/getpid 2 - can't assign to shared my() declaration (threads only)
 154 #    'my $x : shared = 5'
 155 # op/override 7 - parens on overriden require change v-string interpretation
 156 #    'BEGIN{*CORE::GLOBAL::require=sub {}} require v5.6'
 157 #    c.f. 'BEGIN { *f = sub {0} }; f 2'
 158 # op/pat 774 - losing Unicode-ness of Latin1-only strings
 159 #    'use charnames ":short"; $x="\N{latin:a with acute}"'
 160 # op/recurse 12 - missing parens on recursive call makes it look like method
 161 #    'sub f { f($x) }'
 162 # op/subst 90 - inconsistent handling of utf8 under "use utf8"
 163 # op/taint 29 - "use re 'taint'" deparsed in the wrong place wrt. block open
 164 # op/tiehandle compile - "use strict" deparsed in the wrong place
 165 # uni/tr_ several
 166 # ext/B/t/xref 11 - line numbers when we add newlines to one-line subs
 167 # ext/Data/Dumper/t/dumper compile
 168 # ext/DB_file/several
 169 # ext/Encode/several
 170 # ext/Ernno/Errno warnings
 171 # ext/IO/lib/IO/t/io_sel 23
 172 # ext/PerlIO/t/encoding compile
 173 # ext/POSIX/t/posix 6
 174 # ext/Socket/Socket 8
 175 # ext/Storable/t/croak compile
 176 # lib/Attribute/Handlers/t/multi compile
 177 # lib/bignum/ several
 178 # lib/charnames 35
 179 # lib/constant 32
 180 # lib/English 40
 181 # lib/ExtUtils/t/bytes 4
 182 # lib/File/DosGlob compile
 183 # lib/Filter/Simple/t/data 1
 184 # lib/Math/BigInt/t/constant 1
 185 # lib/Net/t/config Deparse-warning
 186 # lib/overload compile
 187 # lib/Switch/ several
 188 # lib/Symbol 4
 189 # lib/Test/Simple several
 190 # lib/Term/Complete
 191 # lib/Tie/File/t/29_downcopy 5
 192 # lib/vars 22
 193
 194 # Object fields (were globals):
 195 #
 196 # avoid_local:
 197 # (local($a), local($b)) and local($a, $b) have the same internal
 198 # representation but the short form looks better. We notice we can
 199 # use a large-scale local when checking the list, but need to prevent
 200 # individual locals too. This hash holds the addresses of OPs that
 201 # have already had their local-ness accounted for. The same thing
 202 # is done with my().
 203 #
 204 # curcv:
 205 # CV for current sub (or main program) being deparsed
 206 #
 207 # curcvlex:
 208 # Cached hash of lexical variables for curcv: keys are names,
 209 # each value is an array of pairs, indicating the cop_seq of scopes
 210 # in which a var of that name is valid.
 211 #
 212 # curcop:
 213 # COP for statement being deparsed
 214 #
 215 # curstash:
 216 # name of the current package for deparsed code
 217 #
 218 # subs_todo:
 219 # array of [cop_seq, CV, is_format?] for subs and formats we still
 220 # want to deparse
 221 #
 222 # protos_todo:
 223 # as above, but [name, prototype] for subs that never got a GV
 224 #
 225 # subs_done, forms_done:
 226 # keys are addresses of GVs for subs and formats we've already
 227 # deparsed (or at least put into subs_todo)
 228 #
 229 # subs_declared
 230 # keys are names of subs for which we've printed declarations.
 231 # That means we can omit parentheses from the arguments.
 232 #
 233 # subs_deparsed
 234 # Keeps track of fully qualified names of all deparsed subs.
 235 #
 236 # parens: -p
 237 # linenums: -l
 238 # unquote: -q
 239 # cuddle: ` ' or `\n', depending on -sC
 240 # indent_size: -si
 241 # use_tabs: -sT
 242 # ex_const: -sv
 243
 244 # A little explanation of how precedence contexts and associativity
 245 # work:
 246 #
 247 # deparse() calls each per-op subroutine with an argument $cx (short
 248 # for context, but not the same as the cx* in the perl core), which is
 249 # a number describing the op's parents in terms of precedence, whether
 250 # they're inside an expression or at statement level, etc.  (see
 251 # chart below). When ops with children call deparse on them, they pass
 252 # along their precedence. Fractional values are used to implement
 253 # associativity (`($x + $y) + $z' => `$x + $y + $y') and related
 254 # parentheses hacks. The major disadvantage of this scheme is that
 255 # it doesn't know about right sides and left sides, so say if you
 256 # assign a listop to a variable, it can't tell it's allowed to leave
 257 # the parens off the listop.
 258
 259 # Precedences:
 260 # 26             [TODO] inside interpolation context ("")
 261 # 25 left        terms and list operators (leftward)
 262 # 24 left        ->
 263 # 23 nonassoc    ++ --
 264 # 22 right       **
 265 # 21 right       ! ~ \ and unary + and -
 266 # 20 left        =~ !~
 267 # 19 left        * / % x
 268 # 18 left        + - .
 269 # 17 left        << >>
 270 # 16 nonassoc    named unary operators
 271 # 15 nonassoc    < > <= >= lt gt le ge
 272 # 14 nonassoc    == != <=> eq ne cmp
 273 # 13 left        &
 274 # 12 left        | ^
 275 # 11 left        &&
 276 # 10 left        ||
 277 #  9 nonassoc    ..  ...
 278 #  8 right       ?:
 279 #  7 right       = += -= *= etc.
 280 #  6 left        , =>
 281 #  5 nonassoc    list operators (rightward)
 282 #  4 right       not
 283 #  3 left        and
 284 #  2 left        or xor
 285 #  1             statement modifiers
 286 #  0.5           statements, but still print scopes as do { ... }
 287 #  0             statement level
 288
 289 # Nonprinting characters with special meaning:
 290 # \cS - steal parens (see maybe_parens_unop)
 291 # \n - newline and indent
 292 # \t - increase indent
 293 # \b - decrease indent (`outdent')
 294 # \f - flush left (no indent)
 295 # \cK - kill following semicolon, if any
 296
 297 sub null {
 298     my $op = shift;
 299     return class($op) eq "NULL";
 300 }
 301
 302 sub todo {
 303     my $self = shift;
 304     my($cv, $is_form) = @_;
 305     return unless ($cv->FILE eq $0 || exists $self->{files}{$cv->FILE});
 306     my $seq;
 307     if ($cv->OUTSIDE_SEQ) {
 308         $seq = $cv->OUTSIDE_SEQ;
 309     } elsif (!null($cv->START) and is_state($cv->START)) {
 310         $seq = $cv->START->cop_seq;
 311     } else {
 312         $seq = 0;
 313     }
 314     push @{$self->{'subs_todo'}}, [$seq, $cv, $is_form];
 315     unless ($is_form || class($cv->STASH) eq 'SPECIAL') {
 316         $self->{'subs_deparsed'}{$cv->STASH->NAME."::".$cv->GV->NAME} = 1;
 317     }
 318 }
 319
 320 sub next_todo {
 321     my $self = shift;
 322     my $ent = shift @{$self->{'subs_todo'}};
 323     my $cv = $ent->[1];
 324     my $gv = $cv->GV;
 325     my $name = $self->gv_name($gv);
 326     if ($ent->[2]) {
 327         return "format $name =\n"
 328             . $self->deparse_format($ent->[1]). "\n";
 329     } else {
 330         $self->{'subs_declared'}{$name} = 1;
 331         if ($name eq "BEGIN") {
 332             my $use_dec = $self->begin_is_use($cv);
 333             if (defined ($use_dec) and $self->{'expand'} < 5) {
 334                 return () if 0 == length($use_dec);
 335                 return $use_dec;
 336             }
 337         }
 338         my $l = '';
 339         if ($self->{'linenums'}) {
 340             my $line = $gv->LINE;
 341             my $file = $gv->FILE;
 342             $l = "\n\f#line $line \"$file\"\n";
 343         }
 344         my $p = '';
 345         if (class($cv->STASH) ne "SPECIAL") {
 346             my $stash = $cv->STASH->NAME;
 347             if ($stash ne $self->{'curstash'}) {
 348                 $p = "package $stash;\n";
 349                 $name = "$self->{'curstash'}::$name" unless $name =~ /::/;
 350                 $self->{'curstash'} = $stash;
 351             }
 352             $name =~ s/^\Q$stash\E:://;
 353         }
 354         return "${p}${l}sub $name " . $self->deparse_sub($cv);
 355     }
 356 }
 357
 358 # Return a "use" declaration for this BEGIN block, if appropriate
 359 sub begin_is_use {
 360     my ($self, $cv) = @_;
 361     my $root = $cv->ROOT;
 362     local @$self{qw'curcv curcvlex'} = ($cv);
 363 #require B::Debug;
 364 #B::walkoptree($cv->ROOT, "debug");
 365     my $lineseq = $root->first;
 366     return if $lineseq->name ne "lineseq";
 367
 368     my $req_op = $lineseq->first->sibling;
 369     return if $req_op->name ne "require";
 370
 371     my $module;
 372     if ($req_op->first->private & OPpCONST_BARE) {
 373         # Actually it should always be a bareword
 374         $module = $self->const_sv($req_op->first)->PV;
 375         $module =~ s[/][::]g;
 376         $module =~ s/.pm$//;
 377     }
 378     else {
 379         $module = $self->const($self->const_sv($req_op->first), 6);
 380     }
 381
 382     my $version;
 383     my $version_op = $req_op->sibling;
 384     return if class($version_op) eq "NULL";
 385     if ($version_op->name eq "lineseq") {
 386         # We have a version parameter; skip nextstate & pushmark
 387         my $constop = $version_op->first->next->next;
 388
 389         return unless $self->const_sv($constop)->PV eq $module;
 390         $constop = $constop->sibling;
 391         $version = $self->const_sv($constop);
 392         if (class($version) eq "IV") {
 393             $version = $version->int_value;
 394         } elsif (class($version) eq "NV") {
 395             $version = $version->NV;
 396         } elsif (class($version) ne "PVMG") {
 397             # Includes PVIV and PVNV
 398             $version = $version->PV;
 399         } else {
 400             # version specified as a v-string
 401             $version = 'v'.join '.', map ord, split //, $version->PV;
 402         }
 403         $constop = $constop->sibling;
 404         return if $constop->name ne "method_named";
 405         return if $self->const_sv($constop)->PV ne "VERSION";
 406     }
 407
 408     $lineseq = $version_op->sibling;
 409     return if $lineseq->name ne "lineseq";
 410     my $entersub = $lineseq->first->sibling;
 411     if ($entersub->name eq "stub") {
 412         return "use $module $version ();\n" if defined $version;
 413         return "use $module ();\n";
 414     }
 415     return if $entersub->name ne "entersub";
 416
 417     # See if there are import arguments
 418     my $args = '';
 419
 420     my $svop = $entersub->first->sibling; # Skip over pushmark
 421     return unless $self->const_sv($svop)->PV eq $module;
 422
 423     # Pull out the arguments
 424     for ($svop=$svop->sibling; $svop->name ne "method_named";
 425                 $svop = $svop->sibling) {
 426         $args .= ", " if length($args);
 427         $args .= $self->deparse($svop, 6);
 428     }
 429
 430     my $use = 'use';
 431     my $method_named = $svop;
 432     return if $method_named->name ne "method_named";
 433     my $method_name = $self->const_sv($method_named)->PV;
 434
 435     if ($method_name eq "unimport") {
 436         $use = 'no';
 437     }
 438
 439     # Certain pragmas are dealt with using hint bits,
 440     # so we ignore them here
 441     if ($module eq 'strict' || $module eq 'integer'
 442         || $module eq 'bytes' || $module eq 'warnings') {
 443         return "";
 444     }
 445
 446     if (defined $version && length $args) {
 447         return "$use $module $version ($args);\n";
 448     } elsif (defined $version) {
 449         return "$use $module $version;\n";
 450     } elsif (length $args) {
 451         return "$use $module ($args);\n";
 452     } else {
 453         return "$use $module;\n";
 454     }
 455 }
 456
 457 sub stash_subs {
 458     my ($self, $pack) = @_;
 459     my (@ret, $stash);
 460     if (!defined $pack) {
 461         $pack = '';
 462         $stash = \%::;
 463     }
 464     else {
 465         $pack =~ s/(::)?$/::/;
 466         no strict 'refs';
 467         $stash = \%$pack;
 468     }
 469     my %stash = svref_2object($stash)->ARRAY;
 470     while (my ($key, $val) = each %stash) {
 471         next if $key eq 'main::';       # avoid infinite recursion
 472         my $class = class($val);
 473         if ($class eq "PV") {
 474             # Just a prototype. As an ugly but fairly effective way
 475             # to find out if it belongs here is to see if the AUTOLOAD
 476             # (if any) for the stash was defined in one of our files.
 477             my $A = $stash{"AUTOLOAD"};
 478             if (defined ($A) && class($A) eq "GV" && defined($A->CV)
 479                 && class($A->CV) eq "CV") {
 480                 my $AF = $A->FILE;
 481                 next unless $AF eq $0 || exists $self->{'files'}{$AF};
 482             }
 483             push @{$self->{'protos_todo'}}, [$pack . $key, $val->PV];
 484         } elsif ($class eq "IV") {
 485             # Just a name. As above.
 486             my $A = $stash{"AUTOLOAD"};
 487             if (defined ($A) && class($A) eq "GV" && defined($A->CV)
 488                 && class($A->CV) eq "CV") {
 489                 my $AF = $A->FILE;
 490                 next unless $AF eq $0 || exists $self->{'files'}{$AF};
 491             }
 492             push @{$self->{'protos_todo'}}, [$pack . $key, undef];
 493         } elsif ($class eq "GV") {
 494             if (class(my $cv = $val->CV) ne "SPECIAL") {
 495                 next if $self->{'subs_done'}{$$val}++;
 496                 next if $$val != ${$cv->GV};   # Ignore imposters
 497                 $self->todo($cv, 0);
 498             }
 499             if (class(my $cv = $val->FORM) ne "SPECIAL") {
 500                 next if $self->{'forms_done'}{$$val}++;
 501                 next if $$val != ${$cv->GV};   # Ignore imposters
 502                 $self->todo($cv, 1);
 503             }
 504             if (class($val->HV) ne "SPECIAL" && $key =~ /::$/) {
 505                 $self->stash_subs($pack . $key);
 506             }
 507         }
 508     }
 509 }
 510
 511 sub print_protos {
 512     my $self = shift;
 513     my $ar;
 514     my @ret;
 515     foreach $ar (@{$self->{'protos_todo'}}) {
 516         my $proto = (defined $ar->[1] ? " (". $ar->[1] . ")" : "");
 517         push @ret, "sub " . $ar->[0] .  "$proto;\n";
 518     }
 519     delete $self->{'protos_todo'};
 520     return @ret;
 521 }
 522
 523 sub style_opts {
 524     my $self = shift;
 525     my $opts = shift;
 526     my $opt;
 527     while (length($opt = substr($opts, 0, 1))) {
 528         if ($opt eq "C") {
 529             $self->{'cuddle'} = " ";
 530             $opts = substr($opts, 1);
 531         } elsif ($opt eq "i") {
 532             $opts =~ s/^i(\d+)//;
 533             $self->{'indent_size'} = $1;
 534         } elsif ($opt eq "T") {
 535             $self->{'use_tabs'} = 1;
 536             $opts = substr($opts, 1);
 537         } elsif ($opt eq "v") {
 538             $opts =~ s/^v([^.]*)(.|$)//;
 539             $self->{'ex_const'} = $1;
 540         }
 541     }
 542 }
 543
 544 sub new {
 545     my $class = shift;
 546     my $self = bless {}, $class;
 547     $self->{'cuddle'} = "\n";
 548     $self->{'curcop'} = undef;
 549     $self->{'curstash'} = "main";
 550     $self->{'ex_const'} = "'???'";
 551     $self->{'expand'} = 0;
 552     $self->{'files'} = {};
 553     $self->{'indent_size'} = 4;
 554     $self->{'linenums'} = 0;
 555     $self->{'parens'} = 0;
 556     $self->{'subs_todo'} = [];
 557     $self->{'unquote'} = 0;
 558     $self->{'use_dumper'} = 0;
 559     $self->{'use_tabs'} = 0;
 560
 561     $self->{'ambient_arybase'} = 0;
 562     $self->{'ambient_warnings'} = undef; # Assume no lexical warnings
 563     $self->{'ambient_hints'} = 0;
 564     $self->init();
 565
 566     while (my $arg = shift @_) {
 567         if ($arg eq "-d") {
 568             $self->{'use_dumper'} = 1;
 569             require Data::Dumper;
 570         } elsif ($arg =~ /^-f(.*)/) {
 571             $self->{'files'}{$1} = 1;
 572         } elsif ($arg eq "-l") {
 573             $self->{'linenums'} = 1;
 574         } elsif ($arg eq "-p") {
 575             $self->{'parens'} = 1;
 576         } elsif ($arg eq "-P") {
 577             $self->{'noproto'} = 1;
 578         } elsif ($arg eq "-q") {
 579             $self->{'unquote'} = 1;
 580         } elsif (substr($arg, 0, 2) eq "-s") {
 581             $self->style_opts(substr $arg, 2);
 582         } elsif ($arg =~ /^-x(\d)$/) {
 583             $self->{'expand'} = $1;
 584         }
 585     }
 586     return $self;
 587 }
 588
 589 {
 590     # Mask out the bits that L<warnings::register> uses
 591     my $WARN_MASK;
 592     BEGIN {
 593         $WARN_MASK = $warnings::Bits{all} | $warnings::DeadBits{all};
 594     }
 595     sub WARN_MASK () {
 596         return $WARN_MASK;
 597     }
 598 }
 599
 600 # Initialise the contextual information, either from
 601 # defaults provided with the ambient_pragmas method,
 602 # or from perl's own defaults otherwise.
 603 sub init {
 604     my $self = shift;
 605
 606     $self->{'arybase'}  = $self->{'ambient_arybase'};
 607     $self->{'warnings'} = defined ($self->{'ambient_warnings'})
 608                                 ? $self->{'ambient_warnings'} & WARN_MASK
 609                                 : undef;
 610     $self->{'hints'}    = $self->{'ambient_hints'} & 0xFF;
 611
 612     # also a convenient place to clear out subs_declared
 613     delete $self->{'subs_declared'};
 614 }
 615
 616 sub compile {
 617     my(@args) = @_;
 618     return sub {
 619         my $self = B::Deparse->new(@args);
 620         # First deparse command-line args
 621         if (defined $^I) { # deparse -i
 622             print q(BEGIN { $^I = ).perlstring($^I).qq(; }\n);
 623         }
 624         if ($^W) { # deparse -w
 625             print qq(BEGIN { \$^W = $^W; }\n);
 626         }
 627         if ($/ ne "\n" or defined $O::savebackslash) { # deparse -l and -0
 628             my $fs = perlstring($/) || 'undef';
 629             my $bs = perlstring($O::savebackslash) || 'undef';
 630             print qq(BEGIN { \$/ = $fs; \$\\ = $bs; }\n);
 631         }
 632         my @BEGINs  = B::begin_av->isa("B::AV") ? B::begin_av->ARRAY : ();
 633         my @CHECKs  = B::check_av->isa("B::AV") ? B::check_av->ARRAY : ();
 634         my @INITs   = B::init_av->isa("B::AV") ? B::init_av->ARRAY : ();
 635         my @ENDs    = B::end_av->isa("B::AV") ? B::end_av->ARRAY : ();
 636         for my $block (@BEGINs, @CHECKs, @INITs, @ENDs) {
 637             $self->todo($block, 0);
 638         }
 639         $self->stash_subs();
 640         local($SIG{"__DIE__"}) =
 641           sub {
 642               if ($self->{'curcop'}) {
 643                   my $cop = $self->{'curcop'};
 644                   my($line, $file) = ($cop->line, $cop->file);
 645                   print STDERR "While deparsing $file near line $line,\n";
 646               }
 647             };
 648         $self->{'curcv'} = main_cv;
 649         $self->{'curcvlex'} = undef;
 650         print $self->print_protos;
 651         @{$self->{'subs_todo'}} =
 652           sort {$a->[0] <=> $b->[0]} @{$self->{'subs_todo'}};
 653         print $self->indent($self->deparse_root(main_root)), "\n"
 654           unless null main_root;
 655         my @text;
 656         while (scalar(@{$self->{'subs_todo'}})) {
 657             push @text, $self->next_todo;
 658         }
 659         print $self->indent(join("", @text)), "\n" if @text;
 660
 661         # Print __DATA__ section, if necessary
 662         no strict 'refs';
 663         my $laststash = defined $self->{'curcop'}
 664             ? $self->{'curcop'}->stash->NAME : $self->{'curstash'};
 665         if (defined *{$laststash."::DATA"}{IO}) {
 666             print "package $laststash;\n"
 667                 unless $laststash eq $self->{'curstash'};
 668             print "__DATA__\n";
 669             print readline(*{$laststash."::DATA"});
 670         }
 671     }
 672 }
 673
 674 sub coderef2text {
 675     my $self = shift;
 676     my $sub = shift;
 677     croak "Usage: ->coderef2text(CODEREF)" unless UNIVERSAL::isa($sub, "CODE");
 678
 679     $self->init();
 680     return $self->indent($self->deparse_sub(svref_2object($sub)));
 681 }
 682
 683 sub ambient_pragmas {
 684     my $self = shift;
 685     my ($arybase, $hint_bits, $warning_bits) = (0, 0);
 686
 687     while (@_ > 1) {
 688         my $name = shift();
 689         my $val  = shift();
 690
 691         if ($name eq 'strict') {
 692             require strict;
 693
 694             if ($val eq 'none') {
 695                 $hint_bits &= ~strict::bits(qw/refs subs vars/);
 696                 next();
 697             }
 698
 699             my @names;
 700             if ($val eq "all") {
 701                 @names = qw/refs subs vars/;
 702             }
 703             elsif (ref $val) {
 704                 @names = @$val;
 705             }
 706             else {
 707                 @names = split' ', $val;
 708             }
 709             $hint_bits |= strict::bits(@names);
 710         }
 711
 712         elsif ($name eq '$[') {
 713             $arybase = $val;
 714         }
 715
 716         elsif ($name eq 'integer'
 717             || $name eq 'bytes'
 718             || $name eq 'utf8') {
 719             require "$name.pm";
 720             if ($val) {
 721                 $hint_bits |= ${$::{"${name}::"}{"hint_bits"}};
 722             }
 723             else {
 724                 $hint_bits &= ~${$::{"${name}::"}{"hint_bits"}};
 725             }
 726         }
 727
 728         elsif ($name eq 're') {
 729             require re;
 730             if ($val eq 'none') {
 731                 $hint_bits &= ~re::bits(qw/taint eval/);
 732                 next();
 733             }
 734
 735             my @names;
 736             if ($val eq 'all') {
 737                 @names = qw/taint eval/;
 738             }
 739             elsif (ref $val) {
 740                 @names = @$val;
 741             }
 742             else {
 743                 @names = split' ',$val;
 744             }
 745             $hint_bits |= re::bits(@names);
 746         }
 747
 748         elsif ($name eq 'warnings') {
 749             if ($val eq 'none') {
 750                 $warning_bits = $warnings::NONE;
 751                 next();
 752             }
 753
 754             my @names;
 755             if (ref $val) {
 756                 @names = @$val;
 757             }
 758             else {
 759                 @names = split/\s+/, $val;
 760             }
 761
 762             $warning_bits = $warnings::NONE if !defined ($warning_bits);
 763             $warning_bits |= warnings::bits(@names);
 764         }
 765
 766         elsif ($name eq 'warning_bits') {
 767             $warning_bits = $val;
 768         }
 769
 770         elsif ($name eq 'hint_bits') {
 771             $hint_bits = $val;
 772         }
 773
 774         else {
 775             croak "Unknown pragma type: $name";
 776         }
 777     }
 778     if (@_) {
 779         croak "The ambient_pragmas method expects an even number of args";
 780     }
 781
 782     $self->{'ambient_arybase'} = $arybase;
 783     $self->{'ambient_warnings'} = $warning_bits;
 784     $self->{'ambient_hints'} = $hint_bits;
 785 }
 786
 787 # This method is the inner loop, so try to keep it simple
 788 sub deparse {
 789     my $self = shift;
 790     my($op, $cx) = @_;
 791
 792     Carp::confess("Null op in deparse") if !defined($op)
 793                                         || class($op) eq "NULL";
 794     my $meth = "pp_" . $op->name;
 795     return $self->$meth($op, $cx);
 796 }
 797
 798 sub indent {
 799     my $self = shift;
 800     my $txt = shift;
 801     my @lines = split(/\n/, $txt);
 802     my $leader = "";
 803     my $level = 0;
 804     my $line;
 805     for $line (@lines) {
 806         my $cmd = substr($line, 0, 1);
 807         if ($cmd eq "\t" or $cmd eq "\b") {
 808             $level += ($cmd eq "\t" ? 1 : -1) * $self->{'indent_size'};
 809             if ($self->{'use_tabs'}) {
 810                 $leader = "\t" x ($level / 8) . " " x ($level % 8);
 811             } else {
 812                 $leader = " " x $level;
 813             }
 814             $line = substr($line, 1);
 815         }
 816         if (substr($line, 0, 1) eq "\f") {
 817             $line = substr($line, 1); # no indent
 818         } else {
 819             $line = $leader . $line;
 820         }
 821         $line =~ s/\cK;?//g;
 822     }
 823     return join("\n", @lines);
 824 }
 825
 826 sub deparse_sub {
 827     my $self = shift;
 828     my $cv = shift;
 829     my $proto = "";
 830 Carp::confess("NULL in deparse_sub") if !defined($cv) || $cv->isa("B::NULL");
 831 Carp::confess("SPECIAL in deparse_sub") if $cv->isa("B::SPECIAL");
 832     local $self->{'curcop'} = $self->{'curcop'};
 833     if ($cv->FLAGS & SVf_POK) {
 834         $proto = "(". $cv->PV . ") ";
 835     }
 836     if ($cv->CvFLAGS & (CVf_METHOD|CVf_LOCKED|CVf_LVALUE|CVf_ASSERTION)) {
 837         $proto .= ": ";
 838         $proto .= "lvalue " if $cv->CvFLAGS & CVf_LVALUE;
 839         $proto .= "locked " if $cv->CvFLAGS & CVf_LOCKED;
 840         $proto .= "method " if $cv->CvFLAGS & CVf_METHOD;
 841         $proto .= "assertion " if $cv->CvFLAGS & CVf_ASSERTION;
 842     }
 843
 844     local($self->{'curcv'}) = $cv;
 845     local($self->{'curcvlex'});
 846     local(@$self{qw'curstash warnings hints'})
 847                 = @$self{qw'curstash warnings hints'};
 848     my $body;
 849     if (not null $cv->ROOT) {
 850         my $lineseq = $cv->ROOT->first;
 851         if ($lineseq->name eq "lineseq") {
 852             my @ops;
 853             for(my$o=$lineseq->first; $$o; $o=$o->sibling) {
 854                 push @ops, $o;
 855             }
 856             $body = $self->lineseq(undef, @ops).";";
 857             my $scope_en = $self->find_scope_en($lineseq);
 858             if (defined $scope_en) {
 859                 my $subs = join"", $self->seq_subs($scope_en);
 860                 $body .= ";\n$subs" if length($subs);
 861             }
 862         }
 863         else {
 864             $body = $self->deparse($cv->ROOT->first, 0);
 865         }
 866     }
 867     else {
 868         my $sv = $cv->const_sv;
 869         if ($$sv) {
 870             # uh-oh. inlinable sub... format it differently
 871             return $proto . "{ " . $self->const($sv, 0) . " }\n";
 872         } else { # XSUB? (or just a declaration)
 873             return "$proto;\n";
 874         }
 875     }
 876     return $proto ."{\n\t$body\n\b}" ."\n";
 877 }
 878
 879 sub deparse_format {
 880     my $self = shift;
 881     my $form = shift;
 882     my @text;
 883     local($self->{'curcv'}) = $form;
 884     local($self->{'curcvlex'});
 885     local($self->{'in_format'}) = 1;
 886     local(@$self{qw'curstash warnings hints'})
 887                 = @$self{qw'curstash warnings hints'};
 888     my $op = $form->ROOT;
 889     my $kid;
 890     return "\f." if $op->first->name eq 'stub'
 891                 || $op->first->name eq 'nextstate';
 892     $op = $op->first->first; # skip leavewrite, lineseq
 893     while (not null $op) {
 894         $op = $op->sibling; # skip nextstate
 895         my @exprs;
 896         $kid = $op->first->sibling; # skip pushmark
 897         push @text, "\f".$self->const_sv($kid)->PV;
 898         $kid = $kid->sibling;
 899         for (; not null $kid; $kid = $kid->sibling) {
 900             push @exprs, $self->deparse($kid, 0);
 901         }
 902         push @text, "\f".join(", ", @exprs)."\n" if @exprs;
 903         $op = $op->sibling;
 904     }
 905     return join("", @text) . "\f.";
 906 }
 907
 908 sub is_scope {
 909     my $op = shift;
 910     return $op->name eq "leave" || $op->name eq "scope"
 911       || $op->name eq "lineseq"
 912         || ($op->name eq "null" && class($op) eq "UNOP"
 913             && (is_scope($op->first) || $op->first->name eq "enter"));
 914 }
 915
 916 sub is_state {
 917     my $name = $_[0]->name;
 918     return $name eq "nextstate" || $name eq "dbstate" || $name eq "setstate";
 919 }
 920
 921 sub is_miniwhile { # check for one-line loop (`foo() while $y--')
 922     my $op = shift;
 923     return (!null($op) and null($op->sibling)
 924             and $op->name eq "null" and class($op) eq "UNOP"
 925             and (($op->first->name =~ /^(and|or)$/
 926                   and $op->first->first->sibling->name eq "lineseq")
 927                  or ($op->first->name eq "lineseq"
 928                      and not null $op->first->first->sibling
 929                      and $op->first->first->sibling->name eq "unstack")
 930                  ));
 931 }
 932
 933 # Check if the op and its sibling are the initialization and the rest of a
 934 # for (..;..;..) { ... } loop
 935 sub is_for_loop {
 936     my $op = shift;
 937     # This OP might be almost anything, though it won't be a
 938     # nextstate. (It's the initialization, so in the canonical case it
 939     # will be an sassign.) The sibling is a lineseq whose first child
 940     # is a nextstate and whose second is a leaveloop.
 941     my $lseq = $op->sibling;
 942     if (!is_state $op and !null($lseq) and $lseq->name eq "lineseq") {
 943         if ($lseq->first && !null($lseq->first) && is_state($lseq->first)
 944             && (my $sib = $lseq->first->sibling)) {
 945             return (!null($sib) && $sib->name eq "leaveloop");
 946         }
 947     }
 948     return 0;
 949 }
 950
 951 sub is_scalar {
 952     my $op = shift;
 953     return ($op->name eq "rv2sv" or
 954             $op->name eq "padsv" or
 955             $op->name eq "gv" or # only in array/hash constructs
 956             $op->flags & OPf_KIDS && !null($op->first)
 957               && $op->first->name eq "gvsv");
 958 }
 959
 960 sub maybe_parens {
 961     my $self = shift;
 962     my($text, $cx, $prec) = @_;
 963     if ($prec < $cx              # unary ops nest just fine
 964         or $prec == $cx and $cx != 4 and $cx != 16 and $cx != 21
 965         or $self->{'parens'})
 966     {
 967         $text = "($text)";
 968         # In a unop, let parent reuse our parens; see maybe_parens_unop
 969         $text = "\cS" . $text if $cx == 16;
 970         return $text;
 971     } else {
 972         return $text;
 973     }
 974 }
 975
 976 # same as above, but get around the `if it looks like a function' rule
 977 sub maybe_parens_unop {
 978     my $self = shift;
 979     my($name, $kid, $cx) = @_;
 980     if ($cx > 16 or $self->{'parens'}) {
 981         $kid =  $self->deparse($kid, 1);
 982         if ($name eq "umask" && $kid =~ /^\d+$/) {
 983             $kid = sprintf("%#o", $kid);
 984         }
 985         return "$name($kid)";
 986     } else {
 987         $kid = $self->deparse($kid, 16);
 988         if ($name eq "umask" && $kid =~ /^\d+$/) {
 989             $kid = sprintf("%#o", $kid);
 990         }
 991         if (substr($kid, 0, 1) eq "\cS") {
 992             # use kid's parens
 993             return $name . substr($kid, 1);
 994         } elsif (substr($kid, 0, 1) eq "(") {
 995             # avoid looks-like-a-function trap with extra parens
 996             # (`+' can lead to ambiguities)
 997             return "$name(" . $kid  . ")";
 998         } else {
 999             return "$name $kid";
1000         }
1001     }
1002 }
1003
1004 sub maybe_parens_func {
1005     my $self = shift;
1006     my($func, $text, $cx, $prec) = @_;
1007     if ($prec <= $cx or substr($text, 0, 1) eq "(" or $self->{'parens'}) {
1008         return "$func($text)";
1009     } else {
1010         return "$func $text";
1011     }
1012 }
1013
1014 sub maybe_local {
1015     my $self = shift;
1016     my($op, $cx, $text) = @_;
1017     my $our_intro = ($op->name =~ /^(gv|rv2)[ash]v$/) ? OPpOUR_INTRO : 0;
1018     if ($op->private & (OPpLVAL_INTRO|$our_intro)
1019         and not $self->{'avoid_local'}{$$op}) {
1020         my $our_local = ($op->private & OPpLVAL_INTRO) ? "local" : "our";
1021         if( $our_local eq 'our' ) {
1022             # XXX This assertion fails code with non-ASCII identifiers,
1023             # like ./ext/Encode/t/jperl.t
1024             die "Unexpected our($text)\n" unless $text =~ /^\W(\w+::)*\w+\z/;
1025             $text =~ s/(\w+::)+//;
1026         }
1027         if (want_scalar($op)) {
1028             return "$our_local $text";
1029         } else {
1030             return $self->maybe_parens_func("$our_local", $text, $cx, 16);
1031         }
1032     } else {
1033         return $text;
1034     }
1035 }
1036
1037 sub maybe_targmy {
1038     my $self = shift;
1039     my($op, $cx, $func, @args) = @_;
1040     if ($op->private & OPpTARGET_MY) {
1041         my $var = $self->padname($op->targ);
1042         my $val = $func->($self, $op, 7, @args);
1043         return $self->maybe_parens("$var = $val", $cx, 7);
1044     } else {
1045         return $func->($self, $op, $cx, @args);
1046     }
1047 }
1048
1049 sub padname_sv {
1050     my $self = shift;
1051     my $targ = shift;
1052     return $self->{'curcv'}->PADLIST->ARRAYelt(0)->ARRAYelt($targ);
1053 }
1054
1055 sub maybe_my {
1056     my $self = shift;
1057     my($op, $cx, $text) = @_;
1058     if ($op->private & OPpLVAL_INTRO and not $self->{'avoid_local'}{$$op}) {
1059         if (want_scalar($op)) {
1060             return "my $text";
1061         } else {
1062             return $self->maybe_parens_func("my", $text, $cx, 16);
1063         }
1064     } else {
1065         return $text;
1066     }
1067 }
1068
1069 # The following OPs don't have functions:
1070
1071 # pp_padany -- does not exist after parsing
1072
1073 sub AUTOLOAD {
1074     if ($AUTOLOAD =~ s/^.*::pp_//) {
1075         warn "unexpected OP_".uc $AUTOLOAD;
1076         return "XXX";
1077     } else {
1078         die "Undefined subroutine $AUTOLOAD called";
1079     }
1080 }
1081
1082 sub DESTROY {}  #       Do not AUTOLOAD
1083
1084 # $root should be the op which represents the root of whatever
1085 # we're sequencing here. If it's undefined, then we don't append
1086 # any subroutine declarations to the deparsed ops, otherwise we
1087 # append appropriate declarations.
1088 sub lineseq {
1089     my($self, $root, @ops) = @_;
1090     my($expr, @exprs);
1091
1092     my $out_cop = $self->{'curcop'};
1093     my $out_seq = defined($out_cop) ? $out_cop->cop_seq : undef;
1094     my $limit_seq;
1095     if (defined $root) {
1096         $limit_seq = $out_seq;
1097         my $nseq;
1098         $nseq = $self->find_scope_st($root->sibling) if ${$root->sibling};
1099         $limit_seq = $nseq if !defined($limit_seq)
1100                            or defined($nseq) && $nseq < $limit_seq;
1101     }
1102     $limit_seq = $self->{'limit_seq'}
1103         if defined($self->{'limit_seq'})
1104         && (!defined($limit_seq) || $self->{'limit_seq'} < $limit_seq);
1105     local $self->{'limit_seq'} = $limit_seq;
1106     for (my $i = 0; $i < @ops; $i++) {
1107         $expr = "";
1108         if (is_state $ops[$i]) {
1109             $expr = $self->deparse($ops[$i], 0);
1110             $i++;
1111             if ($i > $#ops) {
1112                 push @exprs, $expr;
1113                 last;
1114             }
1115         }
1116         if (!is_state $ops[$i] and (my $ls = $ops[$i+1]) and
1117             !null($ops[$i+1]) and $ops[$i+1]->name eq "lineseq")
1118         {
1119             if ($ls->first && !null($ls->first) && is_state($ls->first)
1120                 && (my $sib = $ls->first->sibling)) {
1121                 if (!null($sib) && $sib->name eq "leaveloop") {
1122                     push @exprs, $expr . $self->for_loop($ops[$i], 0);
1123                     $i++;
1124                     next;
1125                 }
1126             }
1127         }
1128         $expr .= $self->deparse($ops[$i], (@ops != 1)/2);
1129         $expr =~ s/;\n?\z//;
1130         push @exprs, $expr;
1131     }
1132     my $body = join(";\n", grep {length} @exprs);
1133     my $subs = "";
1134     if (defined $root && defined $limit_seq && !$self->{'in_format'}) {
1135         $subs = join "\n", $self->seq_subs($limit_seq);
1136     }
1137     return join(";\n", grep {length} $body, $subs);
1138 }
1139
1140 sub scopeop {
1141     my($real_block, $self, $op, $cx) = @_;
1142     my $kid;
1143     my @kids;
1144
1145     local(@$self{qw'curstash warnings hints'})
1146                 = @$self{qw'curstash warnings hints'} if $real_block;
1147     if ($real_block) {
1148         $kid = $op->first->sibling; # skip enter
1149         if (is_miniwhile($kid)) {
1150             my $top = $kid->first;
1151             my $name = $top->name;
1152             if ($name eq "and") {
1153                 $name = "while";
1154             } elsif ($name eq "or") {
1155                 $name = "until";
1156             } else { # no conditional -> while 1 or until 0
1157                 return $self->deparse($top->first, 1) . " while 1";
1158             }
1159             my $cond = $top->first;
1160             my $body = $cond->sibling->first; # skip lineseq
1161             $cond = $self->deparse($cond, 1);
1162             $body = $self->deparse($body, 1);
1163             return "$body $name $cond";
1164         }
1165     } else {
1166         $kid = $op->first;
1167     }
1168     for (; !null($kid); $kid = $kid->sibling) {
1169         push @kids, $kid;
1170     }
1171     if ($cx > 0) { # inside an expression, (a do {} while for lineseq)
1172         return "do {\n\t" . $self->lineseq($op, @kids) . "\n\b}";
1173     } else {
1174         my $lineseq = $self->lineseq($op, @kids);
1175         return (length ($lineseq) ? "$lineseq;" : "");
1176     }
1177 }
1178
1179 sub pp_scope { scopeop(0, @_); }
1180 sub pp_lineseq { scopeop(0, @_); }
1181 sub pp_leave { scopeop(1, @_); }
1182
1183 # This is a special case of scopeop and lineseq, for the case of the
1184 # main_root. The difference is that we print the output statements as
1185 # soon as we get them, for the sake of impatient users.
1186 sub deparse_root {
1187     my $self = shift;
1188     my($op) = @_;
1189     local(@$self{qw'curstash warnings hints'})
1190       = @$self{qw'curstash warnings hints'};
1191     my @kids;
1192     return if null $op->first; # Can happen, e.g., for Bytecode without -k
1193     for (my $kid = $op->first->sibling; !null($kid); $kid = $kid->sibling) {
1194         push @kids, $kid;
1195     }
1196     for (my $i = 0; $i < @kids; $i++) {
1197         my $expr = "";
1198         if (is_state $kids[$i]) {
1199             $expr = $self->deparse($kids[$i], 0);
1200             $i++;
1201             if ($i > $#kids) {
1202                 print $self->indent($expr);
1203                 last;
1204             }
1205         }
1206         if (is_for_loop($kids[$i])) {
1207             $expr .= $self->for_loop($kids[$i], 0);
1208             $expr .= ";\n" unless $i == $#kids;
1209             print $self->indent($expr);
1210             $i++;
1211             next;
1212         }
1213         $expr .= $self->deparse($kids[$i], (@kids != 1)/2);
1214         $expr =~ s/;\n?\z//;
1215         $expr .= ";";
1216         print $self->indent($expr);
1217         print "\n" unless $i == $#kids;
1218     }
1219 }
1220
1221 # The BEGIN {} is used here because otherwise this code isn't executed
1222 # when you run B::Deparse on itself.
1223 my %globalnames;
1224 BEGIN { map($globalnames{$_}++, "SIG", "STDIN", "STDOUT", "STDERR", "INC",
1225             "ENV", "ARGV", "ARGVOUT", "_"); }
1226
1227 sub gv_name {
1228     my $self = shift;
1229     my $gv = shift;
1230 Carp::confess() unless ref($gv) eq "B::GV";
1231     my $stash = $gv->STASH->NAME;
1232     my $name = $gv->SAFENAME;
1233     if (($stash eq 'main' && $globalnames{$name})
1234         or ($stash eq $self->{'curstash'} && !$globalnames{$name})
1235         or $name =~ /^[^A-Za-z_:]/)
1236     {
1237         $stash = "";
1238     } else {
1239         $stash = $stash . "::";
1240     }
1241     if ($name =~ /^(\^..|{)/) {
1242         $name = "{$name}";       # ${^WARNING_BITS}, etc and ${
1243     }
1244     return $stash . $name;
1245 }
1246
1247 # Return the name to use for a stash variable.
1248 # If a lexical with the same name is in scope, it may need to be
1249 # fully-qualified.
1250 sub stash_variable {
1251     my ($self, $prefix, $name) = @_;
1252
1253     return "$prefix$name" if $name =~ /::/;
1254
1255     unless ($prefix eq '$' || $prefix eq '@' || #'
1256             $prefix eq '%' || $prefix eq '$#') {
1257         return "$prefix$name";
1258     }
1259
1260     my $v = ($prefix eq '$#' ? '@' : $prefix) . $name;
1261     return $prefix .$self->{'curstash'}.'::'. $name if $self->lex_in_scope($v);
1262     return "$prefix$name";
1263 }
1264
1265 sub lex_in_scope {
1266     my ($self, $name) = @_;
1267     $self->populate_curcvlex() if !defined $self->{'curcvlex'};
1268
1269     return 0 if !defined($self->{'curcop'});
1270     my $seq = $self->{'curcop'}->cop_seq;
1271     return 0 if !exists $self->{'curcvlex'}{$name};
1272     for my $a (@{$self->{'curcvlex'}{$name}}) {
1273         my ($st, $en) = @$a;
1274         return 1 if $seq > $st && $seq <= $en;
1275     }
1276     return 0;
1277 }
1278
1279 sub populate_curcvlex {
1280     my $self = shift;
1281     for (my $cv = $self->{'curcv'}; class($cv) eq "CV"; $cv = $cv->OUTSIDE) {
1282         my $padlist = $cv->PADLIST;
1283         # an undef CV still in lexical chain
1284         next if class($padlist) eq "SPECIAL";
1285         my @padlist = $padlist->ARRAY;
1286         my @ns = $padlist[0]->ARRAY;
1287
1288         for (my $i=0; $i<@ns; ++$i) {
1289             next if class($ns[$i]) eq "SPECIAL";
1290             next if $ns[$i]->FLAGS & SVpad_OUR;  # Skip "our" vars
1291             if (class($ns[$i]) eq "PV") {
1292                 # Probably that pesky lexical @_
1293                 next;
1294             }
1295             my $name = $ns[$i]->PVX;
1296             my ($seq_st, $seq_en) =
1297                 ($ns[$i]->FLAGS & SVf_FAKE)
1298                     ? (0, 999999)
1299                     : ($ns[$i]->NVX, $ns[$i]->IVX);
1300
1301             push @{$self->{'curcvlex'}{$name}}, [$seq_st, $seq_en];
1302         }
1303     }
1304 }
1305
1306 sub find_scope_st { ((find_scope(@_))[0]); }
1307 sub find_scope_en { ((find_scope(@_))[1]); }
1308
1309 # Recurses down the tree, looking for pad variable introductions and COPs
1310 sub find_scope {
1311     my ($self, $op, $scope_st, $scope_en) = @_;
1312     carp("Undefined op in find_scope") if !defined $op;
1313     return ($scope_st, $scope_en) unless $op->flags & OPf_KIDS;
1314
1315     for (my $o=$op->first; $$o; $o=$o->sibling) {
1316         if ($o->name =~ /^pad.v$/ && $o->private & OPpLVAL_INTRO) {
1317             my $s = int($self->padname_sv($o->targ)->NVX);
1318             my $e = $self->padname_sv($o->targ)->IVX;
1319             $scope_st = $s if !defined($scope_st) || $s < $scope_st;
1320             $scope_en = $e if !defined($scope_en) || $e > $scope_en;
1321         }
1322         elsif (is_state($o)) {
1323             my $c = $o->cop_seq;
1324             $scope_st = $c if !defined($scope_st) || $c < $scope_st;
1325             $scope_en = $c if !defined($scope_en) || $c > $scope_en;
1326         }
1327         elsif ($o->flags & OPf_KIDS) {
1328             ($scope_st, $scope_en) =
1329                 $self->find_scope($o, $scope_st, $scope_en)
1330         }
1331     }
1332
1333     return ($scope_st, $scope_en);
1334 }
1335
1336 # Returns a list of subs which should be inserted before the COP
1337 sub cop_subs {
1338     my ($self, $op, $out_seq) = @_;
1339     my $seq = $op->cop_seq;
1340     # If we have nephews, then our sequence number indicates
1341     # the cop_seq of the end of some sort of scope.
1342     if (class($op->sibling) ne "NULL" && $op->sibling->flags & OPf_KIDS
1343         and my $nseq = $self->find_scope_st($op->sibling) ) {
1344         $seq = $nseq;
1345     }
1346     $seq = $out_seq if defined($out_seq) && $out_seq < $seq;
1347     return $self->seq_subs($seq);
1348 }
1349
1350 sub seq_subs {
1351     my ($self, $seq) = @_;
1352     my @text;
1353 #push @text, "# ($seq)\n";
1354
1355     return "" if !defined $seq;
1356     while (scalar(@{$self->{'subs_todo'}})
1357            and $seq > $self->{'subs_todo'}[0][0]) {
1358         push @text, $self->next_todo;
1359     }
1360     return @text;
1361 }
1362
1363 # Notice how subs and formats are inserted between statements here;
1364 # also $[ assignments and pragmas.
1365 sub pp_nextstate {
1366     my $self = shift;
1367     my($op, $cx) = @_;
1368     $self->{'curcop'} = $op;
1369     my @text;
1370     push @text, $self->cop_subs($op);
1371     push @text, $op->label . ": " if $op->label;
1372     my $stash = $op->stashpv;
1373     if ($stash ne $self->{'curstash'}) {
1374         push @text, "package $stash;\n";
1375         $self->{'curstash'} = $stash;
1376     }
1377
1378     if ($self->{'arybase'} != $op->arybase) {
1379         push @text, '$[ = '. $op->arybase .";\n";
1380         $self->{'arybase'} = $op->arybase;
1381     }
1382
1383     my $warnings = $op->warnings;
1384     my $warning_bits;
1385     if ($warnings->isa("B::SPECIAL") && $$warnings == 4) {
1386         $warning_bits = $warnings::Bits{"all"} & WARN_MASK;
1387     }
1388     elsif ($warnings->isa("B::SPECIAL") && $$warnings == 5) {
1389         $warning_bits = $warnings::NONE;
1390     }
1391     elsif ($warnings->isa("B::SPECIAL")) {
1392         $warning_bits = undef;
1393     }
1394     else {
1395         $warning_bits = $warnings->PV & WARN_MASK;
1396     }
1397
1398     if (defined ($warning_bits) and
1399        !defined($self->{warnings}) || $self->{'warnings'} ne $warning_bits) {
1400         push @text, declare_warnings($self->{'warnings'}, $warning_bits);
1401         $self->{'warnings'} = $warning_bits;
1402     }
1403
1404     if ($self->{'hints'} != $op->private) {
1405         push @text, declare_hints($self->{'hints'}, $op->private);
1406         $self->{'hints'} = $op->private;
1407     }
1408
1409     # This should go after of any branches that add statements, to
1410     # increase the chances that it refers to the same line it did in
1411     # the original program.
1412     if ($self->{'linenums'}) {
1413         push @text, "\f#line " . $op->line .
1414           ' "' . $op->file, qq'"\n';
1415     }
1416
1417     return join("", @text);
1418 }
1419
1420 sub declare_warnings {
1421     my ($from, $to) = @_;
1422     if (($to & WARN_MASK) eq (warnings::bits("all") & WARN_MASK)) {
1423         return "use warnings;\n";
1424     }
1425     elsif (($to & WARN_MASK) eq ("\0"x length($to) & WARN_MASK)) {
1426         return "no warnings;\n";
1427     }
1428     return "BEGIN {\${^WARNING_BITS} = ".perlstring($to)."}\n";
1429 }
1430
1431 sub declare_hints {
1432     my ($from, $to) = @_;
1433     my $use = $to   & ~$from;
1434     my $no  = $from & ~$to;
1435     my $decls = "";
1436     for my $pragma (hint_pragmas($use)) {
1437         $decls .= "use $pragma;\n";
1438     }
1439     for my $pragma (hint_pragmas($no)) {
1440         $decls .= "no $pragma;\n";
1441     }
1442     return $decls;
1443 }
1444
1445 sub hint_pragmas {
1446     my ($bits) = @_;
1447     my @pragmas;
1448     push @pragmas, "integer" if $bits & 0x1;
1449     push @pragmas, "strict 'refs'" if $bits & 0x2;
1450     push @pragmas, "bytes" if $bits & 0x8;
1451     return @pragmas;
1452 }
1453
1454 sub pp_dbstate { pp_nextstate(@_) }
1455 sub pp_setstate { pp_nextstate(@_) }
1456
1457 sub pp_unstack { return "" } # see also leaveloop
1458
1459 sub baseop {
1460     my $self = shift;
1461     my($op, $cx, $name) = @_;
1462     return $name;
1463 }
1464
1465 sub pp_stub {
1466     my $self = shift;
1467     my($op, $cx, $name) = @_;
1468     if ($cx >= 1) {
1469         return "()";
1470     }
1471     else {
1472         return "();";
1473     }
1474 }
1475 sub pp_wantarray { baseop(@_, "wantarray") }
1476 sub pp_fork { baseop(@_, "fork") }
1477 sub pp_wait { maybe_targmy(@_, \&baseop, "wait") }
1478 sub pp_getppid { maybe_targmy(@_, \&baseop, "getppid") }
1479 sub pp_time { maybe_targmy(@_, \&baseop, "time") }
1480 sub pp_tms { baseop(@_, "times") }
1481 sub pp_ghostent { baseop(@_, "gethostent") }
1482 sub pp_gnetent { baseop(@_, "getnetent") }
1483 sub pp_gprotoent { baseop(@_, "getprotoent") }
1484 sub pp_gservent { baseop(@_, "getservent") }
1485 sub pp_ehostent { baseop(@_, "endhostent") }
1486 sub pp_enetent { baseop(@_, "endnetent") }
1487 sub pp_eprotoent { baseop(@_, "endprotoent") }
1488 sub pp_eservent { baseop(@_, "endservent") }
1489 sub pp_gpwent { baseop(@_, "getpwent") }
1490 sub pp_spwent { baseop(@_, "setpwent") }
1491 sub pp_epwent { baseop(@_, "endpwent") }
1492 sub pp_ggrent { baseop(@_, "getgrent") }
1493 sub pp_sgrent { baseop(@_, "setgrent") }
1494 sub pp_egrent { baseop(@_, "endgrent") }
1495 sub pp_getlogin { baseop(@_, "getlogin") }
1496
1497 sub POSTFIX () { 1 }
1498
1499 # I couldn't think of a good short name, but this is the category of
1500 # symbolic unary operators with interesting precedence
1501
1502 sub pfixop {
1503     my $self = shift;
1504     my($op, $cx, $name, $prec, $flags) = (@_, 0);
1505     my $kid = $op->first;
1506     $kid = $self->deparse($kid, $prec);
1507     return $self->maybe_parens(($flags & POSTFIX) ? "$kid$name" : "$name$kid",
1508                                $cx, $prec);
1509 }
1510
1511 sub pp_preinc { pfixop(@_, "++", 23) }
1512 sub pp_predec { pfixop(@_, "--", 23) }
1513 sub pp_postinc { maybe_targmy(@_, \&pfixop, "++", 23, POSTFIX) }
1514 sub pp_postdec { maybe_targmy(@_, \&pfixop, "--", 23, POSTFIX) }
1515 sub pp_i_preinc { pfixop(@_, "++", 23) }
1516 sub pp_i_predec { pfixop(@_, "--", 23) }
1517 sub pp_i_postinc { maybe_targmy(@_, \&pfixop, "++", 23, POSTFIX) }
1518 sub pp_i_postdec { maybe_targmy(@_, \&pfixop, "--", 23, POSTFIX) }
1519 sub pp_complement { maybe_targmy(@_, \&pfixop, "~", 21) }
1520
1521 sub pp_negate { maybe_targmy(@_, \&real_negate) }
1522 sub real_negate {
1523     my $self = shift;
1524     my($op, $cx) = @_;
1525     if ($op->first->name =~ /^(i_)?negate$/) {
1526         # avoid --$x
1527         $self->pfixop($op, $cx, "-", 21.5);
1528     } else {
1529         $self->pfixop($op, $cx, "-", 21);
1530     }
1531 }
1532 sub pp_i_negate { pp_negate(@_) }
1533
1534 sub pp_not {
1535     my $self = shift;
1536     my($op, $cx) = @_;
1537     if ($cx <= 4) {
1538         $self->pfixop($op, $cx, "not ", 4);
1539     } else {
1540         $self->pfixop($op, $cx, "!", 21);
1541     }
1542 }
1543
1544 sub unop {
1545     my $self = shift;
1546     my($op, $cx, $name) = @_;
1547     my $kid;
1548     if ($op->flags & OPf_KIDS) {
1549         $kid = $op->first;
1550         if (defined prototype("CORE::$name")
1551            && prototype("CORE::$name") =~ /^;?\*/
1552            && $kid->name eq "rv2gv") {
1553             $kid = $kid->first;
1554         }
1555
1556         return $self->maybe_parens_unop($name, $kid, $cx);
1557     } else {
1558         return $name .  ($op->flags & OPf_SPECIAL ? "()" : "");
1559     }
1560 }
1561
1562 sub pp_chop { maybe_targmy(@_, \&unop, "chop") }
1563 sub pp_chomp { maybe_targmy(@_, \&unop, "chomp") }
1564 sub pp_schop { maybe_targmy(@_, \&unop, "chop") }
1565 sub pp_schomp { maybe_targmy(@_, \&unop, "chomp") }
1566 sub pp_defined { unop(@_, "defined") }
1567 sub pp_undef { unop(@_, "undef") }
1568 sub pp_study { unop(@_, "study") }
1569 sub pp_ref { unop(@_, "ref") }
1570 sub pp_pos { maybe_local(@_, unop(@_, "pos")) }
1571
1572 sub pp_sin { maybe_targmy(@_, \&unop, "sin") }
1573 sub pp_cos { maybe_targmy(@_, \&unop, "cos") }
1574 sub pp_rand { maybe_targmy(@_, \&unop, "rand") }
1575 sub pp_srand { unop(@_, "srand") }
1576 sub pp_exp { maybe_targmy(@_, \&unop, "exp") }
1577 sub pp_log { maybe_targmy(@_, \&unop, "log") }
1578 sub pp_sqrt { maybe_targmy(@_, \&unop, "sqrt") }
1579 sub pp_int { maybe_targmy(@_, \&unop, "int") }
1580 sub pp_hex { maybe_targmy(@_, \&unop, "hex") }
1581 sub pp_oct { maybe_targmy(@_, \&unop, "oct") }
1582 sub pp_abs { maybe_targmy(@_, \&unop, "abs") }
1583
1584 sub pp_length { maybe_targmy(@_, \&unop, "length") }
1585 sub pp_ord { maybe_targmy(@_, \&unop, "ord") }
1586 sub pp_chr { maybe_targmy(@_, \&unop, "chr") }
1587
1588 sub pp_each { unop(@_, "each") }
1589 sub pp_values { unop(@_, "values") }
1590 sub pp_keys { unop(@_, "keys") }
1591 sub pp_pop { unop(@_, "pop") }
1592 sub pp_shift { unop(@_, "shift") }
1593
1594 sub pp_caller { unop(@_, "caller") }
1595 sub pp_reset { unop(@_, "reset") }
1596 sub pp_exit { unop(@_, "exit") }
1597 sub pp_prototype { unop(@_, "prototype") }
1598
1599 sub pp_close { unop(@_, "close") }
1600 sub pp_fileno { unop(@_, "fileno") }
1601 sub pp_umask { unop(@_, "umask") }
1602 sub pp_untie { unop(@_, "untie") }
1603 sub pp_tied { unop(@_, "tied") }
1604 sub pp_dbmclose { unop(@_, "dbmclose") }
1605 sub pp_getc { unop(@_, "getc") }
1606 sub pp_eof { unop(@_, "eof") }
1607 sub pp_tell { unop(@_, "tell") }
1608 sub pp_getsockname { unop(@_, "getsockname") }
1609 sub pp_getpeername { unop(@_, "getpeername") }
1610
1611 sub pp_chdir { maybe_targmy(@_, \&unop, "chdir") }
1612 sub pp_chroot { maybe_targmy(@_, \&unop, "chroot") }
1613 sub pp_readlink { unop(@_, "readlink") }
1614 sub pp_rmdir { maybe_targmy(@_, \&unop, "rmdir") }
1615 sub pp_readdir { unop(@_, "readdir") }
1616 sub pp_telldir { unop(@_, "telldir") }
1617 sub pp_rewinddir { unop(@_, "rewinddir") }
1618 sub pp_closedir { unop(@_, "closedir") }
1619 sub pp_getpgrp { maybe_targmy(@_, \&unop, "getpgrp") }
1620 sub pp_localtime { unop(@_, "localtime") }
1621 sub pp_gmtime { unop(@_, "gmtime") }
1622 sub pp_alarm { unop(@_, "alarm") }
1623 sub pp_sleep { maybe_targmy(@_, \&unop, "sleep") }
1624
1625 sub pp_dofile { unop(@_, "do") }
1626 sub pp_entereval { unop(@_, "eval") }
1627
1628 sub pp_ghbyname { unop(@_, "gethostbyname") }
1629 sub pp_gnbyname { unop(@_, "getnetbyname") }
1630 sub pp_gpbyname { unop(@_, "getprotobyname") }
1631 sub pp_shostent { unop(@_, "sethostent") }
1632 sub pp_snetent { unop(@_, "setnetent") }
1633 sub pp_sprotoent { unop(@_, "setprotoent") }
1634 sub pp_sservent { unop(@_, "setservent") }
1635 sub pp_gpwnam { unop(@_, "getpwnam") }
1636 sub pp_gpwuid { unop(@_, "getpwuid") }
1637 sub pp_ggrnam { unop(@_, "getgrnam") }
1638 sub pp_ggrgid { unop(@_, "getgrgid") }
1639
1640 sub pp_lock { unop(@_, "lock") }
1641
1642 sub pp_continue { unop(@_, "continue"); }
1643 sub pp_break {
1644     my ($self, $op) = @_;
1645     return "" if $op->flags & OPf_SPECIAL;
1646     unop(@_, "break");
1647 }
1648
1649 sub givwhen {
1650     my $self = shift;
1651     my($op, $cx, $givwhen) = @_;
1652
1653     my $enterop = $op->first;
1654     my ($head, $block);
1655     if ($enterop->flags & OPf_SPECIAL) {
1656         $head = "default";
1657         $block = $self->deparse($enterop->first, 0);
1658     }
1659     else {
1660         my $cond = $enterop->first;
1661         my $cond_str = $self->deparse($cond, 1);
1662         $head = "$givwhen ($cond_str)";
1663         $block = $self->deparse($cond->sibling, 0);
1664     }
1665
1666     return "$head {\n".
1667         "\t$block\n".
1668         "\b}\cK";
1669 }
1670
1671 sub pp_leavegiven { givwhen(@_, "given"); }
1672 sub pp_leavewhen  { givwhen(@_, "when"); }
1673
1674 sub pp_exists {
1675     my $self = shift;
1676     my($op, $cx) = @_;
1677     my $arg;
1678     if ($op->private & OPpEXISTS_SUB) {
1679         # Checking for the existence of a subroutine
1680         return $self->maybe_parens_func("exists",
1681                                 $self->pp_rv2cv($op->first, 16), $cx, 16);
1682     }
1683     if ($op->flags & OPf_SPECIAL) {
1684         # Array element, not hash element
1685         return $self->maybe_parens_func("exists",
1686                                 $self->pp_aelem($op->first, 16), $cx, 16);
1687     }
1688     return $self->maybe_parens_func("exists", $self->pp_helem($op->first, 16),
1689                                     $cx, 16);
1690 }
1691
1692 sub pp_delete {
1693     my $self = shift;
1694     my($op, $cx) = @_;
1695     my $arg;
1696     if ($op->private & OPpSLICE) {
1697         if ($op->flags & OPf_SPECIAL) {
1698             # Deleting from an array, not a hash
1699             return $self->maybe_parens_func("delete",
1700                                         $self->pp_aslice($op->first, 16),
1701                                         $cx, 16);
1702         }
1703         return $self->maybe_parens_func("delete",
1704                                         $self->pp_hslice($op->first, 16),
1705                                         $cx, 16);
1706     } else {
1707         if ($op->flags & OPf_SPECIAL) {
1708             # Deleting from an array, not a hash
1709             return $self->maybe_parens_func("delete",
1710                                         $self->pp_aelem($op->first, 16),
1711                                         $cx, 16);
1712         }
1713         return $self->maybe_parens_func("delete",
1714                                         $self->pp_helem($op->first, 16),
1715                                         $cx, 16);
1716     }
1717 }
1718
1719 sub pp_require {
1720     my $self = shift;
1721     my($op, $cx) = @_;
1722     my $opname = $op->flags & OPf_SPECIAL ? 'CORE::require' : 'require';
1723     if (class($op) eq "UNOP" and $op->first->name eq "const"
1724         and $op->first->private & OPpCONST_BARE)
1725     {
1726         my $name = $self->const_sv($op->first)->PV;
1727         $name =~ s[/][::]g;
1728         $name =~ s/\.pm//g;
1729         return "$opname $name";
1730     } else {
1731         $self->unop($op, $cx, $opname);
1732     }
1733 }
1734
1735 sub pp_scalar {
1736     my $self = shift;
1737     my($op, $cv) = @_;
1738     my $kid = $op->first;
1739     if (not null $kid->sibling) {
1740         # XXX Was a here-doc
1741         return $self->dquote($op);
1742     }
1743     $self->unop(@_, "scalar");
1744 }
1745
1746
1747 sub padval {
1748     my $self = shift;
1749     my $targ = shift;
1750     return $self->{'curcv'}->PADLIST->ARRAYelt(1)->ARRAYelt($targ);
1751 }
1752
1753 sub pp_refgen {
1754     my $self = shift;
1755     my($op, $cx) = @_;
1756     my $kid = $op->first;
1757     if ($kid->name eq "null") {
1758         $kid = $kid->first;
1759         if ($kid->name eq "anonlist" || $kid->name eq "anonhash") {
1760             my($pre, $post) = @{{"anonlist" => ["[","]"],
1761                                  "anonhash" => ["{","}"]}->{$kid->name}};
1762             my($expr, @exprs);
1763             $kid = $kid->first->sibling; # skip pushmark
1764             for (; !null($kid); $kid = $kid->sibling) {
1765                 $expr = $self->deparse($kid, 6);
1766                 push @exprs, $expr;
1767             }
1768             return $pre . join(", ", @exprs) . $post;
1769         } elsif (!null($kid->sibling) and
1770                  $kid->sibling->name eq "anoncode") {
1771             return "sub " .
1772                 $self->deparse_sub($self->padval($kid->sibling->targ));
1773         } elsif ($kid->name eq "pushmark") {
1774             my $sib_name = $kid->sibling->name;
1775             if ($sib_name =~ /^(pad|rv2)[ah]v$/
1776                 and not $kid->sibling->flags & OPf_REF)
1777             {
1778                 # The @a in \(@a) isn't in ref context, but only when the
1779                 # parens are there.
1780                 return "\\(" . $self->pp_list($op->first) . ")";
1781             } elsif ($sib_name eq 'entersub') {
1782                 my $text = $self->deparse($kid->sibling, 1);
1783                 # Always show parens for \(&func()), but only with -p otherwise
1784                 $text = "($text)" if $self->{'parens'}
1785                                  or $kid->sibling->private & OPpENTERSUB_AMPER;
1786                 return "\\$text";
1787             }
1788         }
1789     }
1790     $self->pfixop($op, $cx, "\\", 20);
1791 }
1792
1793 sub pp_srefgen { pp_refgen(@_) }
1794
1795 sub pp_readline {
1796     my $self = shift;
1797     my($op, $cx) = @_;
1798     my $kid = $op->first;
1799     $kid = $kid->first if $kid->name eq "rv2gv"; # <$fh>
1800     return "<" . $self->deparse($kid, 1) . ">" if is_scalar($kid);
1801     return $self->unop($op, $cx, "readline");
1802 }
1803
1804 sub pp_rcatline {
1805     my $self = shift;
1806     my($op) = @_;
1807     return "<" . $self->gv_name($self->gv_or_padgv($op)) . ">";
1808 }
1809
1810 # Unary operators that can occur as pseudo-listops inside double quotes
1811 sub dq_unop {
1812     my $self = shift;
1813     my($op, $cx, $name, $prec, $flags) = (@_, 0, 0);
1814     my $kid;
1815     if ($op->flags & OPf_KIDS) {
1816        $kid = $op->first;
1817        # If there's more than one kid, the first is an ex-pushmark.
1818        $kid = $kid->sibling if not null $kid->sibling;
1819        return $self->maybe_parens_unop($name, $kid, $cx);
1820     } else {
1821        return $name .  ($op->flags & OPf_SPECIAL ? "()" : "");
1822     }
1823 }
1824
1825 sub pp_ucfirst { dq_unop(@_, "ucfirst") }
1826 sub pp_lcfirst { dq_unop(@_, "lcfirst") }
1827 sub pp_uc { dq_unop(@_, "uc") }
1828 sub pp_lc { dq_unop(@_, "lc") }
1829 sub pp_quotemeta { maybe_targmy(@_, \&dq_unop, "quotemeta") }
1830
1831 sub loopex {
1832     my $self = shift;
1833     my ($op, $cx, $name) = @_;
1834     if (class($op) eq "PVOP") {
1835         return "$name " . $op->pv;
1836     } elsif (class($op) eq "OP") {
1837         return $name;
1838     } elsif (class($op) eq "UNOP") {
1839         # Note -- loop exits are actually exempt from the
1840         # looks-like-a-func rule, but a few extra parens won't hurt
1841         return $self->maybe_parens_unop($name, $op->first, $cx);
1842     }
1843 }
1844
1845 sub pp_last { loopex(@_, "last") }
1846 sub pp_next { loopex(@_, "next") }
1847 sub pp_redo { loopex(@_, "redo") }
1848 sub pp_goto { loopex(@_, "goto") }
1849 sub pp_dump { loopex(@_, "dump") }
1850
1851 sub ftst {
1852     my $self = shift;
1853     my($op, $cx, $name) = @_;
1854     if (class($op) eq "UNOP") {
1855         # Genuine `-X' filetests are exempt from the LLAFR, but not
1856         # l?stat(); for the sake of clarity, give'em all parens
1857         return $self->maybe_parens_unop($name, $op->first, $cx);
1858     } elsif (class($op) =~ /^(SV|PAD)OP$/) {
1859         return $self->maybe_parens_func($name, $self->pp_gv($op, 1), $cx, 16);
1860     } else { # I don't think baseop filetests ever survive ck_ftst, but...
1861         return $name;
1862     }
1863 }
1864
1865 sub pp_lstat    { ftst(@_, "lstat") }
1866 sub pp_stat     { ftst(@_, "stat") }
1867 sub pp_ftrread  { ftst(@_, "-R") }
1868 sub pp_ftrwrite { ftst(@_, "-W") }
1869 sub pp_ftrexec  { ftst(@_, "-X") }
1870 sub pp_fteread  { ftst(@_, "-r") }
1871 sub pp_ftewrite { ftst(@_, "-w") }
1872 sub pp_fteexec  { ftst(@_, "-x") }
1873 sub pp_ftis     { ftst(@_, "-e") }
1874 sub pp_fteowned { ftst(@_, "-O") }
1875 sub pp_ftrowned { ftst(@_, "-o") }
1876 sub pp_ftzero   { ftst(@_, "-z") }
1877 sub pp_ftsize   { ftst(@_, "-s") }
1878 sub pp_ftmtime  { ftst(@_, "-M") }
1879 sub pp_ftatime  { ftst(@_, "-A") }
1880 sub pp_ftctime  { ftst(@_, "-C") }
1881 sub pp_ftsock   { ftst(@_, "-S") }
1882 sub pp_ftchr    { ftst(@_, "-c") }
1883 sub pp_ftblk    { ftst(@_, "-b") }
1884 sub pp_ftfile   { ftst(@_, "-f") }
1885 sub pp_ftdir    { ftst(@_, "-d") }
1886 sub pp_ftpipe   { ftst(@_, "-p") }
1887 sub pp_ftlink   { ftst(@_, "-l") }
1888 sub pp_ftsuid   { ftst(@_, "-u") }
1889 sub pp_ftsgid   { ftst(@_, "-g") }
1890 sub pp_ftsvtx   { ftst(@_, "-k") }
1891 sub pp_fttty    { ftst(@_, "-t") }
1892 sub pp_fttext   { ftst(@_, "-T") }
1893 sub pp_ftbinary { ftst(@_, "-B") }
1894
1895 sub SWAP_CHILDREN () { 1 }
1896 sub ASSIGN () { 2 } # has OP= variant
1897 sub LIST_CONTEXT () { 4 } # Assignment is in list context
1898
1899 my(%left, %right);
1900
1901 sub assoc_class {
1902     my $op = shift;
1903     my $name = $op->name;
1904     if ($name eq "concat" and $op->first->name eq "concat") {
1905         # avoid spurious `=' -- see comment in pp_concat
1906         return "concat";
1907     }
1908     if ($name eq "null" and class($op) eq "UNOP"
1909         and $op->first->name =~ /^(and|x?or)$/
1910         and null $op->first->sibling)
1911     {
1912         # Like all conditional constructs, OP_ANDs and OP_ORs are topped
1913         # with a null that's used as the common end point of the two
1914         # flows of control. For precedence purposes, ignore it.
1915         # (COND_EXPRs have these too, but we don't bother with
1916         # their associativity).
1917         return assoc_class($op->first);
1918     }
1919     return $name . ($op->flags & OPf_STACKED ? "=" : "");
1920 }
1921
1922 # Left associative operators, like `+', for which
1923 # $a + $b + $c is equivalent to ($a + $b) + $c
1924
1925 BEGIN {
1926     %left = ('multiply' => 19, 'i_multiply' => 19,
1927              'divide' => 19, 'i_divide' => 19,
1928              'modulo' => 19, 'i_modulo' => 19,
1929              'repeat' => 19,
1930              'add' => 18, 'i_add' => 18,
1931              'subtract' => 18, 'i_subtract' => 18,
1932              'concat' => 18,
1933              'left_shift' => 17, 'right_shift' => 17,
1934              'bit_and' => 13,
1935              'bit_or' => 12, 'bit_xor' => 12,
1936              'and' => 3,
1937              'or' => 2, 'xor' => 2,
1938             );
1939 }
1940
1941 sub deparse_binop_left {
1942     my $self = shift;
1943     my($op, $left, $prec) = @_;
1944     if ($left{assoc_class($op)} && $left{assoc_class($left)}
1945         and $left{assoc_class($op)} == $left{assoc_class($left)})
1946     {
1947         return $self->deparse($left, $prec - .00001);
1948     } else {
1949         return $self->deparse($left, $prec);
1950     }
1951 }
1952
1953 # Right associative operators, like `=', for which
1954 # $a = $b = $c is equivalent to $a = ($b = $c)
1955
1956 BEGIN {
1957     %right = ('pow' => 22,
1958               'sassign=' => 7, 'aassign=' => 7,
1959               'multiply=' => 7, 'i_multiply=' => 7,
1960               'divide=' => 7, 'i_divide=' => 7,
1961               'modulo=' => 7, 'i_modulo=' => 7,
1962               'repeat=' => 7,
1963               'add=' => 7, 'i_add=' => 7,
1964               'subtract=' => 7, 'i_subtract=' => 7,
1965               'concat=' => 7,
1966               'left_shift=' => 7, 'right_shift=' => 7,
1967               'bit_and=' => 7,
1968               'bit_or=' => 7, 'bit_xor=' => 7,
1969               'andassign' => 7,
1970               'orassign' => 7,
1971              );
1972 }
1973
1974 sub deparse_binop_right {
1975     my $self = shift;
1976     my($op, $right, $prec) = @_;
1977     if ($right{assoc_class($op)} && $right{assoc_class($right)}
1978         and $right{assoc_class($op)} == $right{assoc_class($right)})
1979     {
1980         return $self->deparse($right, $prec - .00001);
1981     } else {
1982         return $self->deparse($right, $prec);
1983     }
1984 }
1985
1986 sub binop {
1987     my $self = shift;
1988     my ($op, $cx, $opname, $prec, $flags) = (@_, 0);
1989     my $left = $op->first;
1990     my $right = $op->last;
1991     my $eq = "";
1992     if ($op->flags & OPf_STACKED && $flags & ASSIGN) {
1993         $eq = "=";
1994         $prec = 7;
1995     }
1996     if ($flags & SWAP_CHILDREN) {
1997         ($left, $right) = ($right, $left);
1998     }
1999     $left = $self->deparse_binop_left($op, $left, $prec);
2000     $left = "($left)" if $flags & LIST_CONTEXT
2001                 && $left !~ /^(my|our|local|)[\@\(]/;
2002     $right = $self->deparse_binop_right($op, $right, $prec);
2003     return $self->maybe_parens("$left $opname$eq $right", $cx, $prec);
2004 }
2005
2006 sub pp_add { maybe_targmy(@_, \&binop, "+", 18, ASSIGN) }
2007 sub pp_multiply { maybe_targmy(@_, \&binop, "*", 19, ASSIGN) }
2008 sub pp_subtract { maybe_targmy(@_, \&binop, "-",18,  ASSIGN) }
2009 sub pp_divide { maybe_targmy(@_, \&binop, "/", 19, ASSIGN) }
2010 sub pp_modulo { maybe_targmy(@_, \&binop, "%", 19, ASSIGN) }
2011 sub pp_i_add { maybe_targmy(@_, \&binop, "+", 18, ASSIGN) }
2012 sub pp_i_multiply { maybe_targmy(@_, \&binop, "*", 19, ASSIGN) }
2013 sub pp_i_subtract { maybe_targmy(@_, \&binop, "-", 18, ASSIGN) }
2014 sub pp_i_divide { maybe_targmy(@_, \&binop, "/", 19, ASSIGN) }
2015 sub pp_i_modulo { maybe_targmy(@_, \&binop, "%", 19, ASSIGN) }
2016 sub pp_pow { maybe_targmy(@_, \&binop, "**", 22, ASSIGN) }
2017
2018 sub pp_left_shift { maybe_targmy(@_, \&binop, "<<", 17, ASSIGN) }
2019 sub pp_right_shift { maybe_targmy(@_, \&binop, ">>", 17, ASSIGN) }
2020 sub pp_bit_and { maybe_targmy(@_, \&binop, "&", 13, ASSIGN) }
2021 sub pp_bit_or { maybe_targmy(@_, \&binop, "|", 12, ASSIGN) }
2022 sub pp_bit_xor { maybe_targmy(@_, \&binop, "^", 12, ASSIGN) }
2023
2024 sub pp_eq { binop(@_, "==", 14) }
2025 sub pp_ne { binop(@_, "!=", 14) }
2026 sub pp_lt { binop(@_, "<", 15) }
2027 sub pp_gt { binop(@_, ">", 15) }
2028 sub pp_ge { binop(@_, ">=", 15) }
2029 sub pp_le { binop(@_, "<=", 15) }
2030 sub pp_ncmp { binop(@_, "<=>", 14) }
2031 sub pp_i_eq { binop(@_, "==", 14) }
2032 sub pp_i_ne { binop(@_, "!=", 14) }
2033 sub pp_i_lt { binop(@_, "<", 15) }
2034 sub pp_i_gt { binop(@_, ">", 15) }
2035 sub pp_i_ge { binop(@_, ">=", 15) }
2036 sub pp_i_le { binop(@_, "<=", 15) }
2037 sub pp_i_ncmp { binop(@_, "<=>", 14) }
2038
2039 sub pp_seq { binop(@_, "eq", 14) }
2040 sub pp_sne { binop(@_, "ne", 14) }
2041 sub pp_slt { binop(@_, "lt", 15) }
2042 sub pp_sgt { binop(@_, "gt", 15) }
2043 sub pp_sge { binop(@_, "ge", 15) }
2044 sub pp_sle { binop(@_, "le", 15) }
2045 sub pp_scmp { binop(@_, "cmp", 14) }
2046
2047 sub pp_sassign { binop(@_, "=", 7, SWAP_CHILDREN) }
2048 sub pp_aassign { binop(@_, "=", 7, SWAP_CHILDREN | LIST_CONTEXT) }
2049
2050 sub pp_smartmatch {
2051     my ($self, $op, $cx) = @_;
2052     if ($op->flags & OPf_SPECIAL) {
2053         return $self->deparse($op->first, $cx);
2054     }
2055     else {
2056         binop(@_, "~~", 14);
2057     }
2058 }
2059
2060 # `.' is special because concats-of-concats are optimized to save copying
2061 # by making all but the first concat stacked. The effect is as if the
2062 # programmer had written `($a . $b) .= $c', except legal.
2063 sub pp_concat { maybe_targmy(@_, \&real_concat) }
2064 sub real_concat {
2065     my $self = shift;
2066     my($op, $cx) = @_;
2067     my $left = $op->first;
2068     my $right = $op->last;
2069     my $eq = "";
2070     my $prec = 18;
2071     if ($op->flags & OPf_STACKED and $op->first->name ne "concat") {
2072         $eq = "=";
2073         $prec = 7;
2074     }
2075     $left = $self->deparse_binop_left($op, $left, $prec);
2076     $right = $self->deparse_binop_right($op, $right, $prec);
2077     return $self->maybe_parens("$left .$eq $right", $cx, $prec);
2078 }
2079
2080 # `x' is weird when the left arg is a list
2081 sub pp_repeat {
2082     my $self = shift;
2083     my($op, $cx) = @_;
2084     my $left = $op->first;
2085     my $right = $op->last;
2086     my $eq = "";
2087     my $prec = 19;
2088     if ($op->flags & OPf_STACKED) {
2089         $eq = "=";
2090         $prec = 7;
2091     }
2092     if (null($right)) { # list repeat; count is inside left-side ex-list
2093         my $kid = $left->first->sibling; # skip pushmark
2094         my @exprs;
2095         for (; !null($kid->sibling); $kid = $kid->sibling) {
2096             push @exprs, $self->deparse($kid, 6);
2097         }
2098         $right = $kid;
2099         $left = "(" . join(", ", @exprs). ")";
2100     } else {
2101         $left = $self->deparse_binop_left($op, $left, $prec);
2102     }
2103     $right = $self->deparse_binop_right($op, $right, $prec);
2104     return $self->maybe_parens("$left x$eq $right", $cx, $prec);
2105 }
2106
2107 sub range {
2108     my $self = shift;
2109     my ($op, $cx, $type) = @_;
2110     my $left = $op->first;
2111     my $right = $left->sibling;
2112     $left = $self->deparse($left, 9);
2113     $right = $self->deparse($right, 9);
2114     return $self->maybe_parens("$left $type $right", $cx, 9);
2115 }
2116
2117 sub pp_flop {
2118     my $self = shift;
2119     my($op, $cx) = @_;
2120     my $flip = $op->first;
2121     my $type = ($flip->flags & OPf_SPECIAL) ? "..." : "..";
2122     return $self->range($flip->first, $cx, $type);
2123 }
2124
2125 # one-line while/until is handled in pp_leave
2126
2127 sub logop {
2128     my $self = shift;
2129     my ($op, $cx, $lowop, $lowprec, $highop, $highprec, $blockname) = @_;
2130     my $left = $op->first;
2131     my $right = $op->first->sibling;
2132     if ($cx < 1 and is_scope($right) and $blockname
2133         and $self->{'expand'} < 7)
2134     { # if ($a) {$b}
2135         $left = $self->deparse($left, 1);
2136         $right = $self->deparse($right, 0);
2137         return "$blockname ($left) {\n\t$right\n\b}\cK";
2138     } elsif ($cx < 1 and $blockname and not $self->{'parens'}
2139              and $self->{'expand'} < 7) { # $b if $a
2140         $right = $self->deparse($right, 1);
2141         $left = $self->deparse($left, 1);
2142         return "$right $blockname $left";
2143     } elsif ($cx > $lowprec and $highop) { # $a && $b
2144         $left = $self->deparse_binop_left($op, $left, $highprec);
2145         $right = $self->deparse_binop_right($op, $right, $highprec);
2146         return $self->maybe_parens("$left $highop $right", $cx, $highprec);
2147     } else { # $a and $b
2148         $left = $self->deparse_binop_left($op, $left, $lowprec);
2149         $right = $self->deparse_binop_right($op, $right, $lowprec);
2150         return $self->maybe_parens("$left $lowop $right", $cx, $lowprec);
2151     }
2152 }
2153
2154 sub pp_and { logop(@_, "and", 3, "&&", 11, "if") }
2155 sub pp_or  { logop(@_, "or",  2, "||", 10, "unless") }
2156 sub pp_dor { logop(@_, "err", 2, "//", 10, "") }
2157
2158 # xor is syntactically a logop, but it's really a binop (contrary to
2159 # old versions of opcode.pl). Syntax is what matters here.
2160 sub pp_xor { logop(@_, "xor", 2, "",   0,  "") }
2161
2162 sub logassignop {
2163     my $self = shift;
2164     my ($op, $cx, $opname) = @_;
2165     my $left = $op->first;
2166     my $right = $op->first->sibling->first; # skip sassign
2167     $left = $self->deparse($left, 7);
2168     $right = $self->deparse($right, 7);
2169     return $self->maybe_parens("$left $opname $right", $cx, 7);
2170 }
2171
2172 sub pp_andassign { logassignop(@_, "&&=") }
2173 sub pp_orassign  { logassignop(@_, "||=") }
2174 sub pp_dorassign { logassignop(@_, "//=") }
2175
2176 sub listop {
2177     my $self = shift;
2178     my($op, $cx, $name) = @_;
2179     my(@exprs);
2180     my $parens = ($cx >= 5) || $self->{'parens'};
2181     my $kid = $op->first->sibling;
2182     return $name if null $kid;
2183     my $first;
2184     $name = "socketpair" if $name eq "sockpair";
2185     my $proto = prototype("CORE::$name");
2186     if (defined $proto
2187         && $proto =~ /^;?\*/
2188         && $kid->name eq "rv2gv") {
2189         $first = $self->deparse($kid->first, 6);
2190     }
2191     else {
2192         $first = $self->deparse($kid, 6);
2193     }
2194     if ($name eq "chmod" && $first =~ /^\d+$/) {
2195         $first = sprintf("%#o", $first);
2196     }
2197     $first = "+$first" if not $parens and substr($first, 0, 1) eq "(";
2198     push @exprs, $first;
2199     $kid = $kid->sibling;
2200     if (defined $proto && $proto =~ /^\*\*/ && $kid->name eq "rv2gv") {
2201         push @exprs, $self->deparse($kid->first, 6);
2202         $kid = $kid->sibling;
2203     }
2204     for (; !null($kid); $kid = $kid->sibling) {
2205         push @exprs, $self->deparse($kid, 6);
2206     }
2207     if ($parens) {
2208         return "$name(" . join(", ", @exprs) . ")";
2209     } else {
2210         return "$name " . join(", ", @exprs);
2211     }
2212 }
2213
2214 sub pp_bless { listop(@_, "bless") }
2215 sub pp_atan2 { maybe_targmy(@_, \&listop, "atan2") }
2216 sub pp_substr { maybe_local(@_, listop(@_, "substr")) }
2217 sub pp_vec { maybe_local(@_, listop(@_, "vec")) }
2218 sub pp_index { maybe_targmy(@_, \&listop, "index") }
2219 sub pp_rindex { maybe_targmy(@_, \&listop, "rindex") }
2220 sub pp_sprintf { maybe_targmy(@_, \&listop, "sprintf") }
2221 sub pp_formline { listop(@_, "formline") } # see also deparse_format
2222 sub pp_crypt { maybe_targmy(@_, \&listop, "crypt") }
2223 sub pp_unpack { listop(@_, "unpack") }
2224 sub pp_pack { listop(@_, "pack") }
2225 sub pp_join { maybe_targmy(@_, \&listop, "join") }
2226 sub pp_splice { listop(@_, "splice") }
2227 sub pp_push { maybe_targmy(@_, \&listop, "push") }
2228 sub pp_unshift { maybe_targmy(@_, \&listop, "unshift") }
2229 sub pp_reverse { listop(@_, "reverse") }
2230 sub pp_warn { listop(@_, "warn") }
2231 sub pp_die { listop(@_, "die") }
2232 # Actually, return is exempt from the LLAFR (see examples in this very
2233 # module!), but for consistency's sake, ignore that fact
2234 sub pp_return { listop(@_, "return") }
2235 sub pp_open { listop(@_, "open") }
2236 sub pp_pipe_op { listop(@_, "pipe") }
2237 sub pp_tie { listop(@_, "tie") }
2238 sub pp_binmode { listop(@_, "binmode") }
2239 sub pp_dbmopen { listop(@_, "dbmopen") }
2240 sub pp_sselect { listop(@_, "select") }
2241 sub pp_select { listop(@_, "select") }
2242 sub pp_read { listop(@_, "read") }
2243 sub pp_sysopen { listop(@_, "sysopen") }
2244 sub pp_sysseek { listop(@_, "sysseek") }
2245 sub pp_sysread { listop(@_, "sysread") }
2246 sub pp_syswrite { listop(@_, "syswrite") }
2247 sub pp_send { listop(@_, "send") }
2248 sub pp_recv { listop(@_, "recv") }
2249 sub pp_seek { listop(@_, "seek") }
2250 sub pp_fcntl { listop(@_, "fcntl") }
2251 sub pp_ioctl { listop(@_, "ioctl") }
2252 sub pp_flock { maybe_targmy(@_, \&listop, "flock") }
2253 sub pp_socket { listop(@_, "socket") }
2254 sub pp_sockpair { listop(@_, "sockpair") }
2255 sub pp_bind { listop(@_, "bind") }
2256 sub pp_connect { listop(@_, "connect") }
2257 sub pp_listen { listop(@_, "listen") }
2258 sub pp_accept { listop(@_, "accept") }
2259 sub pp_shutdown { listop(@_, "shutdown") }
2260 sub pp_gsockopt { listop(@_, "getsockopt") }
2261 sub pp_ssockopt { listop(@_, "setsockopt") }
2262 sub pp_chown { maybe_targmy(@_, \&listop, "chown") }
2263 sub pp_unlink { maybe_targmy(@_, \&listop, "unlink") }
2264 sub pp_chmod { maybe_targmy(@_, \&listop, "chmod") }
2265 sub pp_utime { maybe_targmy(@_, \&listop, "utime") }
2266 sub pp_rename { maybe_targmy(@_, \&listop, "rename") }
2267 sub pp_link { maybe_targmy(@_, \&listop, "link") }
2268 sub pp_symlink { maybe_targmy(@_, \&listop, "symlink") }
2269 sub pp_mkdir { maybe_targmy(@_, \&listop, "mkdir") }
2270 sub pp_open_dir { listop(@_, "opendir") }
2271 sub pp_seekdir { listop(@_, "seekdir") }
2272 sub pp_waitpid { maybe_targmy(@_, \&listop, "waitpid") }
2273 sub pp_system { maybe_targmy(@_, \&listop, "system") }
2274 sub pp_exec { maybe_targmy(@_, \&listop, "exec") }
2275 sub pp_kill { maybe_targmy(@_, \&listop, "kill") }
2276 sub pp_setpgrp { maybe_targmy(@_, \&listop, "setpgrp") }
2277 sub pp_getpriority { maybe_targmy(@_, \&listop, "getpriority") }
2278 sub pp_setpriority { maybe_targmy(@_, \&listop, "setpriority") }
2279 sub pp_shmget { listop(@_, "shmget") }
2280 sub pp_shmctl { listop(@_, "shmctl") }
2281 sub pp_shmread { listop(@_, "shmread") }
2282 sub pp_shmwrite { listop(@_, "shmwrite") }
2283 sub pp_msgget { listop(@_, "msgget") }
2284 sub pp_msgctl { listop(@_, "msgctl") }
2285 sub pp_msgsnd { listop(@_, "msgsnd") }
2286 sub pp_msgrcv { listop(@_, "msgrcv") }
2287 sub pp_semget { listop(@_, "semget") }
2288 sub pp_semctl { listop(@_, "semctl") }
2289 sub pp_semop { listop(@_, "semop") }
2290 sub pp_ghbyaddr { listop(@_, "gethostbyaddr") }
2291 sub pp_gnbyaddr { listop(@_, "getnetbyaddr") }
2292 sub pp_gpbynumber { listop(@_, "getprotobynumber") }
2293 sub pp_gsbyname { listop(@_, "getservbyname") }
2294 sub pp_gsbyport { listop(@_, "getservbyport") }
2295 sub pp_syscall { listop(@_, "syscall") }
2296
2297 sub pp_glob {
2298     my $self = shift;
2299     my($op, $cx) = @_;
2300     my $text = $self->dq($op->first->sibling);  # skip pushmark
2301     if ($text =~ /^\$?(\w|::|\`)+$/ # could look like a readline
2302         or $text =~ /[<>]/) {
2303         return 'glob(' . single_delim('qq', '"', $text) . ')';
2304     } else {
2305         return '<' . $text . '>';
2306     }
2307 }
2308
2309 # Truncate is special because OPf_SPECIAL makes a bareword first arg
2310 # be a filehandle. This could probably be better fixed in the core
2311 # by moving the GV lookup into ck_truc.
2312
2313 sub pp_truncate {
2314     my $self = shift;
2315     my($op, $cx) = @_;
2316     my(@exprs);
2317     my $parens = ($cx >= 5) || $self->{'parens'};
2318     my $kid = $op->first->sibling;
2319     my $fh;
2320     if ($op->flags & OPf_SPECIAL) {
2321         # $kid is an OP_CONST
2322         $fh = $self->const_sv($kid)->PV;
2323     } else {
2324         $fh = $self->deparse($kid, 6);
2325         $fh = "+$fh" if not $parens and substr($fh, 0, 1) eq "(";
2326     }
2327     my $len = $self->deparse($kid->sibling, 6);
2328     if ($parens) {
2329         return "truncate($fh, $len)";
2330     } else {
2331         return "truncate $fh, $len";
2332     }
2333 }
2334
2335 sub indirop {
2336     my $self = shift;
2337     my($op, $cx, $name) = @_;
2338     my($expr, @exprs);
2339     my $kid = $op->first->sibling;
2340     my $indir = "";
2341     if ($op->flags & OPf_STACKED) {
2342         $indir = $kid;
2343         $indir = $indir->first; # skip rv2gv
2344         if (is_scope($indir)) {
2345             $indir = "{" . $self->deparse($indir, 0) . "}";
2346             $indir = "{;}" if $indir eq "{}";
2347         } elsif ($indir->name eq "const" && $indir->private & OPpCONST_BARE) {
2348             $indir = $self->const_sv($indir)->PV;
2349         } else {
2350             $indir = $self->deparse($indir, 24);
2351         }
2352         $indir = $indir . " ";
2353         $kid = $kid->sibling;
2354     }
2355     if ($name eq "sort" && $op->private & (OPpSORT_NUMERIC | OPpSORT_INTEGER)) {
2356         $indir = ($op->private & OPpSORT_DESCEND) ? '{$b <=> $a} '
2357                                                   : '{$a <=> $b} ';
2358     }
2359     elsif ($name eq "sort" && $op->private & OPpSORT_DESCEND) {
2360         $indir = '{$b cmp $a} ';
2361     }
2362     for (; !null($kid); $kid = $kid->sibling) {
2363         $expr = $self->deparse($kid, 6);
2364         push @exprs, $expr;
2365     }
2366     my $name2 = $name;
2367     if ($name eq "sort" && $op->private & OPpSORT_REVERSE) {
2368         $name2 = 'reverse sort';
2369     }
2370     if ($name eq "sort" && ($op->private & OPpSORT_INPLACE)) {
2371         return "$exprs[0] = $name2 $indir $exprs[0]";
2372     }
2373
2374     my $args = $indir . join(", ", @exprs);
2375     if ($indir ne "" and $name eq "sort") {
2376         # We don't want to say "sort(f 1, 2, 3)", since perl -w will
2377         # give bareword warnings in that case. Therefore if context
2378         # requires, we'll put parens around the outside "(sort f 1, 2,
2379         # 3)". Unfortunately, we'll currently think the parens are
2380         # necessary more often that they really are, because we don't
2381         # distinguish which side of an assignment we're on.
2382         if ($cx >= 5) {
2383             return "($name2 $args)";
2384         } else {
2385             return "$name2 $args";
2386         }
2387     } else {
2388         return $self->maybe_parens_func($name2, $args, $cx, 5);
2389     }
2390
2391 }
2392
2393 sub pp_prtf { indirop(@_, "printf") }
2394 sub pp_print { indirop(@_, "print") }
2395 sub pp_sort { indirop(@_, "sort") }
2396
2397 sub mapop {
2398     my $self = shift;
2399     my($op, $cx, $name) = @_;
2400     my($expr, @exprs);
2401     my $kid = $op->first; # this is the (map|grep)start
2402     $kid = $kid->first->sibling; # skip a pushmark
2403     my $code = $kid->first; # skip a null
2404     if (is_scope $code) {
2405         $code = "{" . $self->deparse($code, 0) . "} ";
2406     } else {
2407         $code = $self->deparse($code, 24) . ", ";
2408     }
2409     $kid = $kid->sibling;
2410     for (; !null($kid); $kid = $kid->sibling) {
2411         $expr = $self->deparse($kid, 6);
2412         push @exprs, $expr if defined $expr;
2413     }
2414     return $self->maybe_parens_func($name, $code . join(", ", @exprs), $cx, 5);
2415 }
2416
2417 sub pp_mapwhile { mapop(@_, "map") }
2418 sub pp_grepwhile { mapop(@_, "grep") }
2419 sub pp_mapstart { baseop(@_, "map") }
2420 sub pp_grepstart { baseop(@_, "grep") }
2421
2422 sub pp_list {
2423     my $self = shift;
2424     my($op, $cx) = @_;
2425     my($expr, @exprs);
2426     my $kid = $op->first->sibling; # skip pushmark
2427     my $lop;
2428     my $local = "either"; # could be local(...), my(...) or our(...)
2429     for ($lop = $kid; !null($lop); $lop = $lop->sibling) {
2430         # This assumes that no other private flags equal 128, and that
2431         # OPs that store things other than flags in their op_private,
2432         # like OP_AELEMFAST, won't be immediate children of a list.
2433         #
2434         # OP_ENTERSUB can break this logic, so check for it.
2435         # I suspect that open and exit can too.
2436
2437         if (!($lop->private & (OPpLVAL_INTRO|OPpOUR_INTRO)
2438                 or $lop->name eq "undef")
2439             or $lop->name eq "entersub"
2440             or $lop->name eq "exit"
2441             or $lop->name eq "open")
2442         {
2443             $local = ""; # or not
2444             last;
2445         }
2446         if ($lop->name =~ /^pad[ash]v$/) { # my()
2447             ($local = "", last) if $local eq "local" || $local eq "our";
2448             $local = "my";
2449         } elsif ($lop->name =~ /^(gv|rv2)[ash]v$/
2450                         && $lop->private & OPpOUR_INTRO
2451                 or $lop->name eq "null" && $lop->first->name eq "gvsv"
2452                         && $lop->first->private & OPpOUR_INTRO) { # our()
2453             ($local = "", last) if $local eq "my" || $local eq "local";
2454             $local = "our";
2455         } elsif ($lop->name ne "undef"
2456                 # specifically avoid the "reverse sort" optimisation,
2457                 # where "reverse" is nullified
2458                 && !($lop->name eq 'sort' && ($lop->flags & OPpSORT_REVERSE)))
2459         {
2460             # local()
2461             ($local = "", last) if $local eq "my" || $local eq "our";
2462             $local = "local";
2463         }
2464     }
2465     $local = "" if $local eq "either"; # no point if it's all undefs
2466     return $self->deparse($kid, $cx) if null $kid->sibling and not $local;
2467     for (; !null($kid); $kid = $kid->sibling) {
2468         if ($local) {
2469             if (class($kid) eq "UNOP" and $kid->first->name eq "gvsv") {
2470                 $lop = $kid->first;
2471             } else {
2472                 $lop = $kid;
2473             }
2474             $self->{'avoid_local'}{$$lop}++;
2475             $expr = $self->deparse($kid, 6);
2476             delete $self->{'avoid_local'}{$$lop};
2477         } else {
2478             $expr = $self->deparse($kid, 6);
2479         }
2480         push @exprs, $expr;
2481     }
2482     if ($local) {
2483         return "$local(" . join(", ", @exprs) . ")";
2484     } else {
2485         return $self->maybe_parens( join(", ", @exprs), $cx, 6);
2486     }
2487 }
2488
2489 sub is_ifelse_cont {
2490     my $op = shift;
2491     return ($op->name eq "null" and class($op) eq "UNOP"
2492             and $op->first->name =~ /^(and|cond_expr)$/
2493             and is_scope($op->first->first->sibling));
2494 }
2495
2496 sub pp_cond_expr {
2497     my $self = shift;
2498     my($op, $cx) = @_;
2499     my $cond = $op->first;
2500     my $true = $cond->sibling;
2501     my $false = $true->sibling;
2502     my $cuddle = $self->{'cuddle'};
2503     unless ($cx < 1 and (is_scope($true) and $true->name ne "null") and
2504             (is_scope($false) || is_ifelse_cont($false))
2505             and $self->{'expand'} < 7) {
2506         $cond = $self->deparse($cond, 8);
2507         $true = $self->deparse($true, 6);
2508         $false = $self->deparse($false, 8);
2509         return $self->maybe_parens("$cond ? $true : $false", $cx, 8);
2510     }
2511
2512     $cond = $self->deparse($cond, 1);
2513     $true = $self->deparse($true, 0);
2514     my $head = "if ($cond) {\n\t$true\n\b}";
2515     my @elsifs;
2516     while (!null($false) and is_ifelse_cont($false)) {
2517         my $newop = $false->first;
2518         my $newcond = $newop->first;
2519         my $newtrue = $newcond->sibling;
2520         $false = $newtrue->sibling; # last in chain is OP_AND => no else
2521         $newcond = $self->deparse($newcond, 1);
2522         $newtrue = $self->deparse($newtrue, 0);
2523         push @elsifs, "elsif ($newcond) {\n\t$newtrue\n\b}";
2524     }
2525     if (!null($false)) {
2526         $false = $cuddle . "else {\n\t" .
2527           $self->deparse($false, 0) . "\n\b}\cK";
2528     } else {
2529         $false = "\cK";
2530     }
2531     return $head . join($cuddle, "", @elsifs) . $false;
2532 }
2533
2534 sub loop_common {
2535     my $self = shift;
2536     my($op, $cx, $init) = @_;
2537     my $enter = $op->first;
2538     my $kid = $enter->sibling;
2539     local(@$self{qw'curstash warnings hints'})
2540                 = @$self{qw'curstash warnings hints'};
2541     my $head = "";
2542     my $bare = 0;
2543     my $body;
2544     my $cond = undef;
2545     if ($kid->name eq "lineseq") { # bare or infinite loop
2546         if ($kid->last->name eq "unstack") { # infinite
2547             $head = "while (1) "; # Can't use for(;;) if there's a continue
2548             $cond = "";
2549         } else {
2550             $bare = 1;
2551         }
2552         $body = $kid;
2553     } elsif ($enter->name eq "enteriter") { # foreach
2554         my $ary = $enter->first->sibling; # first was pushmark
2555         my $var = $ary->sibling;
2556         if ($ary->name eq 'null' and $enter->private & OPpITER_REVERSED) {
2557             # "reverse" was optimised away
2558             $ary = listop($self, $ary->first->sibling, 1, 'reverse');
2559         } elsif ($enter->flags & OPf_STACKED
2560             and not null $ary->first->sibling->sibling)
2561         {
2562             $ary = $self->deparse($ary->first->sibling, 9) . " .. " .
2563               $self->deparse($ary->first->sibling->sibling, 9);
2564         } else {
2565             $ary = $self->deparse($ary, 1);
2566         }
2567         if (null $var) {
2568             if ($enter->flags & OPf_SPECIAL) { # thread special var
2569                 $var = $self->pp_threadsv($enter, 1);
2570             } else { # regular my() variable
2571                 $var = $self->pp_padsv($enter, 1);
2572             }
2573         } elsif ($var->name eq "rv2gv") {
2574             $var = $self->pp_rv2sv($var, 1);
2575             if ($enter->private & OPpOUR_INTRO) {
2576                 # our declarations don't have package names
2577                 $var =~ s/^(.).*::/$1/;
2578                 $var = "our $var";
2579             }
2580         } elsif ($var->name eq "gv") {
2581             $var = "\$" . $self->deparse($var, 1);
2582         }
2583         $body = $kid->first->first->sibling; # skip OP_AND and OP_ITER
2584         if (!is_state $body->first and $body->first->name ne "stub") {
2585             confess unless $var eq '$_';
2586             $body = $body->first;
2587             return $self->deparse($body, 2) . " foreach ($ary)";
2588         }
2589         $head = "foreach $var ($ary) ";
2590     } elsif ($kid->name eq "null") { # while/until
2591         $kid = $kid->first;
2592         my $name = {"and" => "while", "or" => "until"}->{$kid->name};
2593         $cond = $self->deparse($kid->first, 1);
2594         $head = "$name ($cond) ";
2595         $body = $kid->first->sibling;
2596     } elsif ($kid->name eq "stub") { # bare and empty
2597         return "{;}"; # {} could be a hashref
2598     }
2599     # If there isn't a continue block, then the next pointer for the loop
2600     # will point to the unstack, which is kid's last child, except
2601     # in a bare loop, when it will point to the leaveloop. When neither of
2602     # these conditions hold, then the second-to-last child is the continue
2603     # block (or the last in a bare loop).
2604     my $cont_start = $enter->nextop;
2605     my $cont;
2606     if ($$cont_start != $$op && ${$cont_start} != ${$body->last}) {
2607         if ($bare) {
2608             $cont = $body->last;
2609         } else {
2610             $cont = $body->first;
2611             while (!null($cont->sibling->sibling)) {
2612                 $cont = $cont->sibling;
2613             }
2614         }
2615         my $state = $body->first;
2616         my $cuddle = $self->{'cuddle'};
2617         my @states;
2618         for (; $$state != $$cont; $state = $state->sibling) {
2619             push @states, $state;
2620         }
2621         $body = $self->lineseq(undef, @states);
2622         if (defined $cond and not is_scope $cont and $self->{'expand'} < 3) {
2623             $head = "for ($init; $cond; " . $self->deparse($cont, 1) .") ";
2624             $cont = "\cK";
2625         } else {
2626             $cont = $cuddle . "continue {\n\t" .
2627               $self->deparse($cont, 0) . "\n\b}\cK";
2628         }
2629     } else {
2630         return "" if !defined $body;
2631         if (length $init) {
2632             $head = "for ($init; $cond;) ";
2633         }
2634         $cont = "\cK";
2635         $body = $self->deparse($body, 0);
2636     }
2637     $body =~ s/;?$/;\n/;
2638
2639     return $head . "{\n\t" . $body . "\b}" . $cont;
2640 }
2641
2642 sub pp_leaveloop { loop_common(@_, "") }
2643
2644 sub for_loop {
2645     my $self = shift;
2646     my($op, $cx) = @_;
2647     my $init = $self->deparse($op, 1);
2648     return $self->loop_common($op->sibling->first->sibling, $cx, $init);
2649 }
2650
2651 sub pp_leavetry {
2652     my $self = shift;
2653     return "eval {\n\t" . $self->pp_leave(@_) . "\n\b}";
2654 }
2655
2656 BEGIN { eval "sub OP_CONST () {" . opnumber("const") . "}" }
2657 BEGIN { eval "sub OP_STRINGIFY () {" . opnumber("stringify") . "}" }
2658 BEGIN { eval "sub OP_RV2SV () {" . opnumber("rv2sv") . "}" }
2659 BEGIN { eval "sub OP_LIST () {" . opnumber("list") . "}" }
2660
2661 sub pp_null {
2662     my $self = shift;
2663     my($op, $cx) = @_;
2664     if (class($op) eq "OP") {
2665         # old value is lost
2666         return $self->{'ex_const'} if $op->targ == OP_CONST;
2667     } elsif ($op->first->name eq "pushmark") {
2668         return $self->pp_list($op, $cx);
2669     } elsif ($op->first->name eq "enter") {
2670         return $self->pp_leave($op, $cx);
2671     } elsif ($op->targ == OP_STRINGIFY) {
2672         return $self->dquote($op, $cx);
2673     } elsif (!null($op->first->sibling) and
2674              $op->first->sibling->name eq "readline" and
2675              $op->first->sibling->flags & OPf_STACKED) {
2676         return $self->maybe_parens($self->deparse($op->first, 7) . " = "
2677                                    . $self->deparse($op->first->sibling, 7),
2678                                    $cx, 7);
2679     } elsif (!null($op->first->sibling) and
2680              $op->first->sibling->name eq "trans" and
2681              $op->first->sibling->flags & OPf_STACKED) {
2682         return $self->maybe_parens($self->deparse($op->first, 20) . " =~ "
2683                                    . $self->deparse($op->first->sibling, 20),
2684                                    $cx, 20);
2685     } elsif ($op->flags & OPf_SPECIAL && $cx < 1 && !$op->targ) {
2686         return "do {\n\t". $self->deparse($op->first, $cx) ."\n\b};";
2687     } elsif (!null($op->first->sibling) and
2688              $op->first->sibling->name eq "null" and
2689              class($op->first->sibling) eq "UNOP" and
2690              $op->first->sibling->first->flags & OPf_STACKED and
2691              $op->first->sibling->first->name eq "rcatline") {
2692         return $self->maybe_parens($self->deparse($op->first, 18) . " .= "
2693                                    . $self->deparse($op->first->sibling, 18),
2694                                    $cx, 18);
2695     } else {
2696         return $self->deparse($op->first, $cx);
2697     }
2698 }
2699
2700 sub padname {
2701     my $self = shift;
2702     my $targ = shift;
2703     return $self->padname_sv($targ)->PVX;
2704 }
2705
2706 sub padany {
2707     my $self = shift;
2708     my $op = shift;
2709     return substr($self->padname($op->targ), 1); # skip $/@/%
2710 }
2711
2712 sub pp_padsv {
2713     my $self = shift;
2714     my($op, $cx) = @_;
2715     return $self->maybe_my($op, $cx, $self->padname($op->targ));
2716 }
2717
2718 sub pp_padav { pp_padsv(@_) }
2719 sub pp_padhv { pp_padsv(@_) }
2720
2721 my @threadsv_names;
2722
2723 BEGIN {
2724     @threadsv_names = ("_", "1", "2", "3", "4", "5", "6", "7", "8", "9",
2725                        "&", "`", "'", "+", "/", ".", ",", "\\", '"', ";",
2726                        "^", "-", "%", "=", "|", "~", ":", "^A", "^E",
2727                        "!", "@");
2728 }
2729
2730 sub pp_threadsv {
2731     my $self = shift;
2732     my($op, $cx) = @_;
2733     return $self->maybe_local($op, $cx, "\$" .  $threadsv_names[$op->targ]);
2734 }
2735
2736 sub gv_or_padgv {
2737     my $self = shift;
2738     my $op = shift;
2739     if (class($op) eq "PADOP") {
2740         return $self->padval($op->padix);
2741     } else { # class($op) eq "SVOP"
2742         return $op->gv;
2743     }
2744 }
2745
2746 sub pp_gvsv {
2747     my $self = shift;
2748     my($op, $cx) = @_;
2749     my $gv = $self->gv_or_padgv($op);
2750     return $self->maybe_local($op, $cx, $self->stash_variable("\$",
2751                                  $self->gv_name($gv)));
2752 }
2753
2754 sub pp_gv {
2755     my $self = shift;
2756     my($op, $cx) = @_;
2757     my $gv = $self->gv_or_padgv($op);
2758     return $self->gv_name($gv);
2759 }
2760
2761 sub pp_aelemfast {
2762     my $self = shift;
2763     my($op, $cx) = @_;
2764     my $name;
2765     if ($op->flags & OPf_SPECIAL) { # optimised PADAV
2766         $name = $self->padname($op->targ);
2767         $name =~ s/^@/\$/;
2768     }
2769     else {
2770         my $gv = $self->gv_or_padgv($op);
2771         $name = $self->gv_name($gv);
2772         $name = $self->{'curstash'}."::$name"
2773             if $name !~ /::/ && $self->lex_in_scope('@'.$name);
2774         $name = '$' . $name;
2775     }
2776
2777     return $name . "[" .  ($op->private + $self->{'arybase'}) . "]";
2778 }
2779
2780 sub rv2x {
2781     my $self = shift;
2782     my($op, $cx, $type) = @_;
2783
2784     if (class($op) eq 'NULL' || !$op->can("first")) {
2785         carp("Unexpected op in pp_rv2x");
2786         return 'XXX';
2787     }
2788     my $kid = $op->first;
2789     if ($kid->name eq "gv") {
2790         return $self->stash_variable($type, $self->deparse($kid, 0));
2791     } elsif (is_scalar $kid) {
2792         my $str = $self->deparse($kid, 0);
2793         if ($str =~ /^\$([^\w\d])\z/) {
2794             # "$$+" isn't a legal way to write the scalar dereference
2795             # of $+, since the lexer can't tell you aren't trying to
2796             # do something like "$$ + 1" to get one more than your
2797             # PID. Either "${$+}" or "$${+}" are workable
2798             # disambiguations, but if the programmer did the former,
2799             # they'd be in the "else" clause below rather than here.
2800             # It's not clear if this should somehow be unified with
2801             # the code in dq and re_dq that also adds lexer
2802             # disambiguation braces.
2803             $str = '$' . "{$1}"; #'
2804         }
2805         return $type . $str;
2806     } else {
2807         return $type . "{" . $self->deparse($kid, 0) . "}";
2808     }
2809 }
2810
2811 sub pp_rv2sv { maybe_local(@_, rv2x(@_, "\$")) }
2812 sub pp_rv2hv { maybe_local(@_, rv2x(@_, "%")) }
2813 sub pp_rv2gv { maybe_local(@_, rv2x(@_, "*")) }
2814
2815 # skip rv2av
2816 sub pp_av2arylen {
2817     my $self = shift;
2818     my($op, $cx) = @_;
2819     if ($op->first->name eq "padav") {
2820         return $self->maybe_local($op, $cx, '$#' . $self->padany($op->first));
2821     } else {
2822         return $self->maybe_local($op, $cx,
2823                                   $self->rv2x($op->first, $cx, '$#'));
2824     }
2825 }
2826
2827 # skip down to the old, ex-rv2cv
2828 sub pp_rv2cv {
2829     my ($self, $op, $cx) = @_;
2830     if (!null($op->first) && $op->first->name eq 'null' &&
2831         $op->first->targ eq OP_LIST)
2832     {
2833         return $self->rv2x($op->first->first->sibling, $cx, "&")
2834     }
2835     else {
2836         return $self->rv2x($op, $cx, "")
2837     }
2838 }
2839
2840 sub list_const {
2841     my $self = shift;
2842     my($cx, @list) = @_;
2843     my @a = map $self->const($_, 6), @list;
2844     if (@a == 0) {
2845         return "()";
2846     } elsif (@a == 1) {
2847         return $a[0];
2848     } elsif ( @a > 2 and !grep(!/^-?\d+$/, @a)) {
2849         # collapse (-1,0,1,2) into (-1..2)
2850         my ($s, $e) = @a[0,-1];
2851         my $i = $s;
2852         return $self->maybe_parens("$s..$e", $cx, 9)
2853           unless grep $i++ != $_, @a;
2854     }
2855     return $self->maybe_parens(join(", ", @a), $cx, 6);
2856 }
2857
2858 sub pp_rv2av {
2859     my $self = shift;
2860     my($op, $cx) = @_;
2861     my $kid = $op->first;
2862     if ($kid->name eq "const") { # constant list
2863         my $av = $self->const_sv($kid);
2864         return $self->list_const($cx, $av->ARRAY);
2865     } else {
2866         return $self->maybe_local($op, $cx, $self->rv2x($op, $cx, "\@"));
2867     }
2868  }
2869
2870 sub is_subscriptable {
2871     my $op = shift;
2872     if ($op->name =~ /^[ahg]elem/) {
2873         return 1;
2874     } elsif ($op->name eq "entersub") {
2875         my $kid = $op->first;
2876         return 0 unless null $kid->sibling;
2877         $kid = $kid->first;
2878         $kid = $kid->sibling until null $kid->sibling;
2879         return 0 if is_scope($kid);
2880         $kid = $kid->first;
2881         return 0 if $kid->name eq "gv";
2882         return 0 if is_scalar($kid);
2883         return is_subscriptable($kid);
2884     } else {
2885         return 0;
2886     }
2887 }
2888
2889 sub elem {
2890     my $self = shift;
2891     my ($op, $cx, $left, $right, $padname) = @_;
2892     my($array, $idx) = ($op->first, $op->first->sibling);
2893     unless ($array->name eq $padname) { # Maybe this has been fixed
2894         $array = $array->first; # skip rv2av (or ex-rv2av in _53+)
2895     }
2896     if ($array->name eq $padname) {
2897         $array = $self->padany($array);
2898     } elsif (is_scope($array)) { # ${expr}[0]
2899         $array = "{" . $self->deparse($array, 0) . "}";
2900     } elsif ($array->name eq "gv") {
2901         $array = $self->gv_name($self->gv_or_padgv($array));
2902         if ($array !~ /::/) {
2903             my $prefix = ($left eq '[' ? '@' : '%');
2904             $array = $self->{curstash}.'::'.$array
2905                 if $self->lex_in_scope($prefix . $array);
2906         }
2907     } elsif (is_scalar $array) { # $x[0], $$x[0], ...
2908         $array = $self->deparse($array, 24);
2909     } else {
2910         # $x[20][3]{hi} or expr->[20]
2911         my $arrow = is_subscriptable($array) ? "" : "->";
2912         return $self->deparse($array, 24) . $arrow .
2913             $left . $self->deparse($idx, 1) . $right;
2914     }
2915     $idx = $self->deparse($idx, 1);
2916
2917     # Outer parens in an array index will confuse perl
2918     # if we're interpolating in a regular expression, i.e.
2919     # /$x$foo[(-1)]/ is *not* the same as /$x$foo[-1]/
2920     #
2921     # If $self->{parens}, then an initial '(' will
2922     # definitely be paired with a final ')'. If
2923     # !$self->{parens}, the misleading parens won't
2924     # have been added in the first place.
2925     #
2926     # [You might think that we could get "(...)...(...)"
2927     # where the initial and final parens do not match
2928     # each other. But we can't, because the above would
2929     # only happen if there's an infix binop between the
2930     # two pairs of parens, and *that* means that the whole
2931     # expression would be parenthesized as well.]
2932     #
2933     $idx =~ s/^\((.*)\)$/$1/ if $self->{'parens'};
2934
2935     # Hash-element braces will autoquote a bareword inside themselves.
2936     # We need to make sure that C<$hash{warn()}> doesn't come out as
2937     # C<$hash{warn}>, which has a quite different meaning. Currently
2938     # B::Deparse will always quote strings, even if the string was a
2939     # bareword in the original (i.e. the OPpCONST_BARE flag is ignored
2940     # for constant strings.) So we can cheat slightly here - if we see
2941     # a bareword, we know that it is supposed to be a function call.
2942     #
2943     $idx =~ s/^([A-Za-z_]\w*)$/$1()/;
2944
2945     return "\$" . $array . $left . $idx . $right;
2946 }
2947
2948 sub pp_aelem { maybe_local(@_, elem(@_, "[", "]", "padav")) }
2949 sub pp_helem { maybe_local(@_, elem(@_, "{", "}", "padhv")) }
2950
2951 sub pp_gelem {
2952     my $self = shift;
2953     my($op, $cx) = @_;
2954     my($glob, $part) = ($op->first, $op->last);
2955     $glob = $glob->first; # skip rv2gv
2956     $glob = $glob->first if $glob->name eq "rv2gv"; # this one's a bug
2957     my $scope = is_scope($glob);
2958     $glob = $self->deparse($glob, 0);
2959     $part = $self->deparse($part, 1);
2960     return "*" . ($scope ? "{$glob}" : $glob) . "{$part}";
2961 }
2962
2963 sub slice {
2964     my $self = shift;
2965     my ($op, $cx, $left, $right, $regname, $padname) = @_;
2966     my $last;
2967     my(@elems, $kid, $array, $list);
2968     if (class($op) eq "LISTOP") {
2969         $last = $op->last;
2970     } else { # ex-hslice inside delete()
2971         for ($kid = $op->first; !null $kid->sibling; $kid = $kid->sibling) {}
2972         $last = $kid;
2973     }
2974     $array = $last;
2975     $array = $array->first
2976         if $array->name eq $regname or $array->name eq "null";
2977     if (is_scope($array)) {
2978         $array = "{" . $self->deparse($array, 0) . "}";
2979     } elsif ($array->name eq $padname) {
2980         $array = $self->padany($array);
2981     } else {
2982         $array = $self->deparse($array, 24);
2983     }
2984     $kid = $op->first->sibling; # skip pushmark
2985     if ($kid->name eq "list") {
2986         $kid = $kid->first->sibling; # skip list, pushmark
2987         for (; !null $kid; $kid = $kid->sibling) {
2988             push @elems, $self->deparse($kid, 6);
2989         }
2990         $list = join(", ", @elems);
2991     } else {
2992         $list = $self->deparse($kid, 1);
2993     }
2994     return "\@" . $array . $left . $list . $right;
2995 }
2996
2997 sub pp_aslice { maybe_local(@_, slice(@_, "[", "]", "rv2av", "padav")) }
2998 sub pp_hslice { maybe_local(@_, slice(@_, "{", "}", "rv2hv", "padhv")) }
2999
3000 sub pp_lslice {
3001     my $self = shift;
3002     my($op, $cx) = @_;
3003     my $idx = $op->first;
3004     my $list = $op->last;
3005     my(@elems, $kid);
3006     $list = $self->deparse($list, 1);
3007     $idx = $self->deparse($idx, 1);
3008     return "($list)" . "[$idx]";
3009 }
3010
3011 sub want_scalar {
3012     my $op = shift;
3013     return ($op->flags & OPf_WANT) == OPf_WANT_SCALAR;
3014 }
3015
3016 sub want_list {
3017     my $op = shift;
3018     return ($op->flags & OPf_WANT) == OPf_WANT_LIST;
3019 }
3020
3021 sub method {
3022     my $self = shift;
3023     my($op, $cx) = @_;
3024     my $kid = $op->first->sibling; # skip pushmark
3025     my($meth, $obj, @exprs);
3026     if ($kid->name eq "list" and want_list $kid) {
3027         # When an indirect object isn't a bareword but the args are in
3028         # parens, the parens aren't part of the method syntax (the LLAFR
3029         # doesn't apply), but they make a list with OPf_PARENS set that
3030         # doesn't get flattened by the append_elem that adds the method,
3031         # making a (object, arg1, arg2, ...) list where the object
3032         # usually is. This can be distinguished from
3033         # `($obj, $arg1, $arg2)->meth()' (which is legal if $arg2 is an
3034         # object) because in the later the list is in scalar context
3035         # as the left side of -> always is, while in the former
3036         # the list is in list context as method arguments always are.
3037         # (Good thing there aren't method prototypes!)
3038         $meth = $kid->sibling;
3039         $kid = $kid->first->sibling; # skip pushmark
3040         $obj = $kid;
3041         $kid = $kid->sibling;
3042         for (; not null $kid; $kid = $kid->sibling) {
3043             push @exprs, $self->deparse($kid, 6);
3044         }
3045     } else {
3046         $obj = $kid;
3047         $kid = $kid->sibling;
3048         for (; !null ($kid->sibling) && $kid->name ne "method_named";
3049               $kid = $kid->sibling) {
3050             push @exprs, $self->deparse($kid, 6);
3051         }
3052         $meth = $kid;
3053     }
3054     $obj = $self->deparse($obj, 24);
3055     if ($meth->name eq "method_named") {
3056         $meth = $self->const_sv($meth)->PV;
3057     } else {
3058         $meth = $meth->first;
3059         if ($meth->name eq "const") {
3060             # As of 5.005_58, this case is probably obsoleted by the
3061             # method_named case above
3062             $meth = $self->const_sv($meth)->PV; # needs to be bare
3063         } else {
3064             $meth = $self->deparse($meth, 1);
3065         }
3066     }
3067     my $args = join(", ", @exprs);
3068     $kid = $obj . "->" . $meth;
3069     if (length $args) {
3070         return $kid . "(" . $args . ")"; # parens mandatory
3071     } else {
3072         return $kid;
3073     }
3074 }
3075
3076 # returns "&" if the prototype doesn't match the args,
3077 # or ("", $args_after_prototype_demunging) if it does.
3078 sub check_proto {
3079     my $self = shift;
3080     return "&" if $self->{'noproto'};
3081     my($proto, @args) = @_;
3082     my($arg, $real);
3083     my $doneok = 0;
3084     my @reals;
3085     # An unbackslashed @ or % gobbles up the rest of the args
3086     1 while $proto =~ s/(?<!\\)([@%])[^\]]+$/$1/;
3087     while ($proto) {
3088         $proto =~ s/^(\\?[\$\@&%*]|\\\[[\$\@&%*]+\]|;)//;
3089         my $chr = $1;
3090         if ($chr eq "") {
3091             return "&" if @args;
3092         } elsif ($chr eq ";") {
3093             $doneok = 1;
3094         } elsif ($chr eq "@" or $chr eq "%") {
3095             push @reals, map($self->deparse($_, 6), @args);
3096             @args = ();
3097         } else {
3098             $arg = shift @args;
3099             last unless $arg;
3100             if ($chr eq "\$") {
3101                 if (want_scalar $arg) {
3102                     push @reals, $self->deparse($arg, 6);
3103                 } else {
3104                     return "&";
3105                 }
3106             } elsif ($chr eq "&") {
3107                 if ($arg->name =~ /^(s?refgen|undef)$/) {
3108                     push @reals, $self->deparse($arg, 6);
3109                 } else {
3110                     return "&";
3111                 }
3112             } elsif ($chr eq "*") {
3113                 if ($arg->name =~ /^s?refgen$/
3114                     and $arg->first->first->name eq "rv2gv")
3115                   {
3116                       $real = $arg->first->first; # skip refgen, null
3117                       if ($real->first->name eq "gv") {
3118                           push @reals, $self->deparse($real, 6);
3119                       } else {
3120                           push @reals, $self->deparse($real->first, 6);
3121                       }
3122                   } else {
3123                       return "&";
3124                   }
3125             } elsif (substr($chr, 0, 1) eq "\\") {
3126                 $chr =~ tr/\\[]//d;
3127                 if ($arg->name =~ /^s?refgen$/ and
3128                     !null($real = $arg->first) and
3129                     ($chr =~ /\$/ && is_scalar($real->first)
3130                      or ($chr =~ /@/
3131                          && class($real->first->sibling) ne 'NULL'
3132                          && $real->first->sibling->name
3133                          =~ /^(rv2|pad)av$/)
3134                      or ($chr =~ /%/
3135                          && class($real->first->sibling) ne 'NULL'
3136                          && $real->first->sibling->name
3137                          =~ /^(rv2|pad)hv$/)
3138                      #or ($chr =~ /&/ # This doesn't work
3139                      #   && $real->first->name eq "rv2cv")
3140                      or ($chr =~ /\*/
3141                          && $real->first->name eq "rv2gv")))
3142                   {
3143                       push @reals, $self->deparse($real, 6);
3144                   } else {
3145                       return "&";
3146                   }
3147             }
3148        }
3149     }
3150     return "&" if $proto and !$doneok; # too few args and no `;'
3151     return "&" if @args;               # too many args
3152     return ("", join ", ", @reals);
3153 }
3154
3155 sub pp_entersub {
3156     my $self = shift;
3157     my($op, $cx) = @_;
3158     return $self->method($op, $cx) unless null $op->first->sibling;
3159     my $prefix = "";
3160     my $amper = "";
3161     my($kid, @exprs);
3162     if ($op->flags & OPf_SPECIAL && !($op->flags & OPf_MOD)) {
3163         $prefix = "do ";
3164     } elsif ($op->private & OPpENTERSUB_AMPER) {
3165         $amper = "&";
3166     }
3167     $kid = $op->first;
3168     $kid = $kid->first->sibling; # skip ex-list, pushmark
3169     for (; not null $kid->sibling; $kid = $kid->sibling) {
3170         push @exprs, $kid;
3171     }
3172     my $simple = 0;
3173     my $proto = undef;
3174     if (is_scope($kid)) {
3175         $amper = "&";
3176         $kid = "{" . $self->deparse($kid, 0) . "}";
3177     } elsif ($kid->first->name eq "gv") {
3178         my $gv = $self->gv_or_padgv($kid->first);
3179         if (class($gv->CV) ne "SPECIAL") {
3180             $proto = $gv->CV->PV if $gv->CV->FLAGS & SVf_POK;
3181         }
3182         $simple = 1; # only calls of named functions can be prototyped
3183         $kid = $self->deparse($kid, 24);
3184     } elsif (is_scalar ($kid->first) && $kid->first->name ne 'rv2cv') {
3185         $amper = "&";
3186         $kid = $self->deparse($kid, 24);
3187     } else {
3188         $prefix = "";
3189         my $arrow = is_subscriptable($kid->first) ? "" : "->";
3190         $kid = $self->deparse($kid, 24) . $arrow;
3191     }
3192
3193     # Doesn't matter how many prototypes there are, if
3194     # they haven't happened yet!
3195     my $declared;
3196     {
3197         no strict 'refs';
3198         no warnings 'uninitialized';
3199         $declared = exists $self->{'subs_declared'}{$kid}
3200             || (
3201                  defined &{ ${$self->{'curstash'}."::"}{$kid} }
3202                  && !exists
3203                      $self->{'subs_deparsed'}{$self->{'curstash'}."::".$kid}
3204                  && defined prototype $self->{'curstash'}."::".$kid
3205                );
3206         if (!$declared && defined($proto)) {
3207             # Avoid "too early to check prototype" warning
3208             ($amper, $proto) = ('&');
3209         }
3210     }
3211
3212     my $args;
3213     if ($declared and defined $proto and not $amper) {
3214         ($amper, $args) = $self->check_proto($proto, @exprs);
3215         if ($amper eq "&") {
3216             $args = join(", ", map($self->deparse($_, 6), @exprs));
3217         }
3218     } else {
3219         $args = join(", ", map($self->deparse($_, 6), @exprs));
3220     }
3221     if ($prefix or $amper) {
3222         if ($op->flags & OPf_STACKED) {
3223             return $prefix . $amper . $kid . "(" . $args . ")";
3224         } else {
3225             return $prefix . $amper. $kid;
3226         }
3227     } else {
3228         # glob() invocations can be translated into calls of
3229         # CORE::GLOBAL::glob with a second parameter, a number.
3230         # Reverse this.
3231         if ($kid eq "CORE::GLOBAL::glob") {
3232             $kid = "glob";
3233             $args =~ s/\s*,[^,]+$//;
3234         }
3235
3236         # It's a syntax error to call CORE::GLOBAL::foo without a prefix,
3237         # so it must have been translated from a keyword call. Translate
3238         # it back.
3239         $kid =~ s/^CORE::GLOBAL:://;
3240
3241         my $dproto = defined($proto) ? $proto : "undefined";
3242         if (!$declared) {
3243             return "$kid(" . $args . ")";
3244         } elsif ($dproto eq "") {
3245             return $kid;
3246         } elsif ($dproto eq "\$" and is_scalar($exprs[0])) {
3247             # is_scalar is an excessively conservative test here:
3248             # really, we should be comparing to the precedence of the
3249             # top operator of $exprs[0] (ala unop()), but that would
3250             # take some major code restructuring to do right.
3251             return $self->maybe_parens_func($kid, $args, $cx, 16);
3252         } elsif ($dproto ne '$' and defined($proto) || $simple) { #'
3253             return $self->maybe_parens_func($kid, $args, $cx, 5);
3254         } else {
3255             return "$kid(" . $args . ")";
3256         }
3257     }
3258 }
3259
3260 sub pp_enterwrite { unop(@_, "write") }
3261
3262 # escape things that cause interpolation in double quotes,
3263 # but not character escapes
3264 sub uninterp {
3265     my($str) = @_;
3266     $str =~ s/(^|\G|[^\\])((?:\\\\)*)([\$\@]|\\[uUlLQE])/$1$2\\$3/g;
3267     return $str;
3268 }
3269
3270 {
3271 my $bal;
3272 BEGIN {
3273     use re "eval";
3274     # Matches any string which is balanced with respect to {braces}
3275     $bal = qr(
3276       (?:
3277         [^\\{}]
3278       | \\\\
3279       | \\[{}]
3280       | \{(??{$bal})\}
3281       )*
3282     )x;
3283 }
3284
3285 # the same, but treat $|, $), $( and $ at the end of the string differently
3286 sub re_uninterp {
3287     my($str) = @_;
3288
3289     $str =~ s/
3290           ( ^|\G                  # $1
3291           | [^\\]
3292           )
3293
3294           (                       # $2
3295             (?:\\\\)*
3296           )
3297
3298           (                       # $3
3299             (\(\?\??\{$bal\}\))   # $4
3300           | [\$\@]
3301             (?!\||\)|\(|$)
3302           | \\[uUlLQE]
3303           )
3304
3305         /defined($4) && length($4) ? "$1$2$4" : "$1$2\\$3"/xeg;
3306
3307     return $str;
3308 }
3309
3310 # This is for regular expressions with the /x modifier
3311 # We have to leave comments unmangled.
3312 sub re_uninterp_extended {
3313     my($str) = @_;
3314
3315     $str =~ s/
3316           ( ^|\G                  # $1
3317           | [^\\]
3318           )
3319
3320           (                       # $2
3321             (?:\\\\)*
3322           )
3323
3324           (                       # $3
3325             ( \(\?\??\{$bal\}\)   # $4  (skip over (?{}) and (??{}) blocks)
3326             | \#[^\n]*            #     (skip over comments)
3327             )
3328           | [\$\@]
3329             (?!\||\)|\(|$|\s)
3330           | \\[uUlLQE]
3331           )
3332
3333         /defined($4) && length($4) ? "$1$2$4" : "$1$2\\$3"/xeg;
3334
3335     return $str;
3336 }
3337 }
3338
3339 my %unctrl = # portable to to EBCDIC
3340     (
3341      "\c@" => '\c@',    # unused
3342      "\cA" => '\cA',
3343      "\cB" => '\cB',
3344      "\cC" => '\cC',
3345      "\cD" => '\cD',
3346      "\cE" => '\cE',
3347      "\cF" => '\cF',
3348      "\cG" => '\cG',
3349      "\cH" => '\cH',
3350      "\cI" => '\cI',
3351      "\cJ" => '\cJ',
3352      "\cK" => '\cK',
3353      "\cL" => '\cL',
3354      "\cM" => '\cM',
3355      "\cN" => '\cN',
3356      "\cO" => '\cO',
3357      "\cP" => '\cP',
3358      "\cQ" => '\cQ',
3359      "\cR" => '\cR',
3360      "\cS" => '\cS',
3361      "\cT" => '\cT',
3362      "\cU" => '\cU',
3363      "\cV" => '\cV',
3364      "\cW" => '\cW',
3365      "\cX" => '\cX',
3366      "\cY" => '\cY',
3367      "\cZ" => '\cZ',
3368      "\c[" => '\c[',    # unused
3369      "\c\\" => '\c\\',  # unused
3370      "\c]" => '\c]',    # unused
3371      "\c_" => '\c_',    # unused
3372     );
3373
3374 # character escapes, but not delimiters that might need to be escaped
3375 sub escape_str { # ASCII, UTF8
3376     my($str) = @_;
3377     $str =~ s/(.)/ord($1) > 255 ? sprintf("\\x{%x}", ord($1)) : $1/eg;
3378     $str =~ s/\a/\\a/g;
3379 #    $str =~ s/\cH/\\b/g; # \b means something different in a regex
3380     $str =~ s/\t/\\t/g;
3381     $str =~ s/\n/\\n/g;
3382     $str =~ s/\e/\\e/g;
3383     $str =~ s/\f/\\f/g;
3384     $str =~ s/\r/\\r/g;
3385     $str =~ s/([\cA-\cZ])/$unctrl{$1}/ge;
3386     $str =~ s/([[:^print:]])/sprintf("\\%03o", ord($1))/ge;
3387     return $str;
3388 }
3389
3390 # For regexes with the /x modifier.
3391 # Leave whitespace unmangled.
3392 sub escape_extended_re {
3393     my($str) = @_;
3394     $str =~ s/(.)/ord($1) > 255 ? sprintf("\\x{%x}", ord($1)) : $1/eg;
3395     $str =~ s/([[:^print:]])/
3396         ($1 =~ y! \t\n!!) ? $1 : sprintf("\\%03o", ord($1))/ge;
3397     $str =~ s/\n/\n\f/g;
3398     return $str;
3399 }
3400
3401 # Don't do this for regexen
3402 sub unback {
3403     my($str) = @_;
3404     $str =~ s/\\/\\\\/g;
3405     return $str;
3406 }
3407
3408 # Remove backslashes which precede literal control characters,
3409 # to avoid creating ambiguity when we escape the latter.
3410 sub re_unback {
3411     my($str) = @_;
3412
3413     # the insane complexity here is due to the behaviour of "\c\"
3414     $str =~ s/(^|[^\\]|\\c\\)(?<!\\c)\\(\\\\)*(?=[[:^print:]])/$1$2/g;
3415     return $str;
3416 }
3417
3418 sub balanced_delim {
3419     my($str) = @_;
3420     my @str = split //, $str;
3421     my($ar, $open, $close, $fail, $c, $cnt, $last_bs);
3422     for $ar (['[',']'], ['(',')'], ['<','>'], ['{','}']) {
3423         ($open, $close) = @$ar;
3424         $fail = 0; $cnt = 0; $last_bs = 0;
3425         for $c (@str) {
3426             if ($c eq $open) {
3427                 $fail = 1 if $last_bs;
3428                 $cnt++;
3429             } elsif ($c eq $close) {
3430                 $fail = 1 if $last_bs;
3431                 $cnt--;
3432                 if ($cnt < 0) {
3433                     # qq()() isn't ")("
3434                     $fail = 1;
3435                     last;
3436                 }
3437             }
3438             $last_bs = $c eq '\\';
3439         }
3440         $fail = 1 if $cnt != 0;
3441         return ($open, "$open$str$close") if not $fail;
3442     }
3443     return ("", $str);
3444 }
3445
3446 sub single_delim {
3447     my($q, $default, $str) = @_;
3448     return "$default$str$default" if $default and index($str, $default) == -1;
3449     if ($q ne 'qr') {
3450         (my $succeed, $str) = balanced_delim($str);
3451         return "$q$str" if $succeed;
3452     }
3453     for my $delim ('/', '"', '#') {
3454         return "$q$delim" . $str . $delim if index($str, $delim) == -1;
3455     }
3456     if ($default) {
3457         $str =~ s/$default/\\$default/g;
3458         return "$default$str$default";
3459     } else {
3460         $str =~ s[/][\\/]g;
3461         return "$q/$str/";
3462     }
3463 }
3464
3465 my $max_prec;
3466 BEGIN { $max_prec = int(0.999 + 8*length(pack("F", 42))*log(2)/log(10)); }
3467
3468 # Split a floating point number into an integer mantissa and a binary
3469 # exponent. Assumes you've already made sure the number isn't zero or
3470 # some weird infinity or NaN.
3471 sub split_float {
3472     my($f) = @_;
3473     my $exponent = 0;
3474     if ($f == int($f)) {
3475         while ($f % 2 == 0) {
3476             $f /= 2;
3477             $exponent++;
3478         }
3479     } else {
3480         while ($f != int($f)) {
3481             $f *= 2;
3482             $exponent--;
3483         }
3484     }
3485     my $mantissa = sprintf("%.0f", $f);
3486     return ($mantissa, $exponent);
3487 }
3488
3489 sub const {
3490     my $self = shift;
3491     my($sv, $cx) = @_;
3492     if ($self->{'use_dumper'}) {
3493         return $self->const_dumper($sv, $cx);
3494     }
3495     if (class($sv) eq "SPECIAL") {
3496         # sv_undef, sv_yes, sv_no
3497         return ('undef', '1', $self->maybe_parens("!1", $cx, 21))[$$sv-1];
3498     } elsif (class($sv) eq "NULL") {
3499        return 'undef';
3500     }
3501     # convert a version object into the "v1.2.3" string in its V magic
3502     if ($sv->FLAGS & SVs_RMG) {
3503         for (my $mg = $sv->MAGIC; $mg; $mg = $mg->MOREMAGIC) {
3504             return $mg->PTR if $mg->TYPE eq 'V';
3505         }
3506     }
3507
3508     if ($sv->FLAGS & SVf_IOK) {
3509         my $str = $sv->int_value;
3510         $str = $self->maybe_parens($str, $cx, 21) if $str < 0;
3511         return $str;
3512     } elsif ($sv->FLAGS & SVf_NOK) {
3513         my $nv = $sv->NV;
3514         if ($nv == 0) {
3515             if (pack("F", $nv) eq pack("F", 0)) {
3516                 # positive zero
3517                 return "0";
3518             } else {
3519                 # negative zero
3520                 return $self->maybe_parens("-.0", $cx, 21);
3521             }
3522         } elsif (1/$nv == 0) {
3523             if ($nv > 0) {
3524                 # positive infinity
3525                 return $self->maybe_parens("9**9**9", $cx, 22);
3526             } else {
3527                 # negative infinity
3528                 return $self->maybe_parens("-9**9**9", $cx, 21);
3529             }
3530         } elsif ($nv != $nv) {
3531             # NaN
3532             if (pack("F", $nv) eq pack("F", sin(9**9**9))) {
3533                 # the normal kind
3534                 return "sin(9**9**9)";
3535             } elsif (pack("F", $nv) eq pack("F", -sin(9**9**9))) {
3536                 # the inverted kind
3537                 return $self->maybe_parens("-sin(9**9**9)", $cx, 21);
3538             } else {
3539                 # some other kind
3540                 my $hex = unpack("h*", pack("F", $nv));
3541                 return qq'unpack("F", pack("h*", "$hex"))';
3542             }
3543         }
3544         # first, try the default stringification
3545         my $str = "$nv";
3546         if ($str != $nv) {
3547             # failing that, try using more precision
3548             $str = sprintf("%.${max_prec}g", $nv);
3549 #           if (pack("F", $str) ne pack("F", $nv)) {
3550             if ($str != $nv) {
3551                 # not representable in decimal with whatever sprintf()
3552                 # and atof() Perl is using here.
3553                 my($mant, $exp) = split_float($nv);
3554                 return $self->maybe_parens("$mant * 2**$exp", $cx, 19);
3555             }
3556         }
3557         $str = $self->maybe_parens($str, $cx, 21) if $nv < 0;
3558         return $str;
3559     } elsif ($sv->FLAGS & SVf_ROK && $sv->can("RV")) {
3560         my $ref = $sv->RV;
3561         if (class($ref) eq "AV") {
3562             return "[" . $self->list_const(2, $ref->ARRAY) . "]";
3563         } elsif (class($ref) eq "HV") {
3564             my %hash = $ref->ARRAY;
3565             my @elts;
3566             for my $k (sort keys %hash) {
3567                 push @elts, "$k => " . $self->const($hash{$k}, 6);
3568             }
3569             return "{" . join(", ", @elts) . "}";
3570         } elsif (class($ref) eq "CV") {
3571             return "sub " . $self->deparse_sub($ref);
3572         }
3573         if ($ref->FLAGS & SVs_SMG) {
3574             for (my $mg = $ref->MAGIC; $mg; $mg = $mg->MOREMAGIC) {
3575                 if ($mg->TYPE eq 'r') {
3576                     my $re = re_uninterp(escape_str(re_unback($mg->precomp)));
3577                     return single_delim("qr", "", $re);
3578                 }
3579             }
3580         }
3581
3582         return $self->maybe_parens("\\" . $self->const($ref, 20), $cx, 20);
3583     } elsif ($sv->FLAGS & SVf_POK) {
3584         my $str = $sv->PV;
3585         if ($str =~ /[^ -~]/) { # ASCII for non-printing
3586             return single_delim("qq", '"', uninterp escape_str unback $str);
3587         } else {
3588             return single_delim("q", "'", unback $str);
3589         }
3590     } else {
3591         return "undef";
3592     }
3593 }
3594
3595 sub const_dumper {
3596     my $self = shift;
3597     my($sv, $cx) = @_;
3598     my $ref = $sv->object_2svref();
3599     my $dumper = Data::Dumper->new([$$ref], ['$v']);
3600     $dumper->Purity(1)->Terse(1)->Deparse(1)->Indent(0)->Useqq(1)->Sortkeys(1);
3601     my $str = $dumper->Dump();
3602     if ($str =~ /^\$v/) {
3603         return '${my ' . $str . ' \$v}';
3604     } else {
3605         return $str;
3606     }
3607 }
3608
3609 sub const_sv {
3610     my $self = shift;
3611     my $op = shift;
3612     my $sv = $op->sv;
3613     # the constant could be in the pad (under useithreads)
3614     $sv = $self->padval($op->targ) unless $$sv;
3615     return $sv;
3616 }
3617
3618 sub pp_const {
3619     my $self = shift;
3620     my($op, $cx) = @_;
3621     if ($op->private & OPpCONST_ARYBASE) {
3622         return '$[';
3623     }
3624 #    if ($op->private & OPpCONST_BARE) { # trouble with `=>' autoquoting
3625 #       return $self->const_sv($op)->PV;
3626 #    }
3627     my $sv = $self->const_sv($op);
3628     return $self->const($sv, $cx);
3629 }
3630
3631 sub dq {
3632     my $self = shift;
3633     my $op = shift;
3634     my $type = $op->name;
3635     if ($type eq "const") {
3636         return '$[' if $op->private & OPpCONST_ARYBASE;
3637         return uninterp(escape_str(unback($self->const_sv($op)->as_string)));
3638     } elsif ($type eq "concat") {
3639         my $first = $self->dq($op->first);
3640         my $last  = $self->dq($op->last);
3641
3642         # Disambiguate "${foo}bar", "${foo}{bar}", "${foo}[1]", "$foo\::bar"
3643         ($last =~ /^[A-Z\\\^\[\]_?]/ &&
3644             $first =~ s/([\$@])\^$/${1}{^}/)  # "${^}W" etc
3645             || ($last =~ /^[:'{\[\w_]/ && #'
3646                 $first =~ s/([\$@])([A-Za-z_]\w*)$/${1}{$2}/);
3647
3648         return $first . $last;
3649     } elsif ($type eq "uc") {
3650         return '\U' . $self->dq($op->first->sibling) . '\E';
3651     } elsif ($type eq "lc") {
3652         return '\L' . $self->dq($op->first->sibling) . '\E';
3653     } elsif ($type eq "ucfirst") {
3654         return '\u' . $self->dq($op->first->sibling);
3655     } elsif ($type eq "lcfirst") {
3656         return '\l' . $self->dq($op->first->sibling);
3657     } elsif ($type eq "quotemeta") {
3658         return '\Q' . $self->dq($op->first->sibling) . '\E';
3659     } elsif ($type eq "join") {
3660         return $self->deparse($op->last, 26); # was join($", @ary)
3661     } else {
3662         return $self->deparse($op, 26);
3663     }
3664 }
3665
3666 sub pp_backtick {
3667     my $self = shift;
3668     my($op, $cx) = @_;
3669     # skip pushmark
3670     return single_delim("qx", '`', $self->dq($op->first->sibling));
3671 }
3672
3673 sub dquote {
3674     my $self = shift;
3675     my($op, $cx) = @_;
3676     my $kid = $op->first->sibling; # skip ex-stringify, pushmark
3677     return $self->deparse($kid, $cx) if $self->{'unquote'};
3678     $self->maybe_targmy($kid, $cx,
3679                         sub {single_delim("qq", '"', $self->dq($_[1]))});
3680 }
3681
3682 # OP_STRINGIFY is a listop, but it only ever has one arg
3683 sub pp_stringify { maybe_targmy(@_, \&dquote) }
3684
3685 # tr/// and s/// (and tr[][], tr[]//, tr###, etc)
3686 # note that tr(from)/to/ is OK, but not tr/from/(to)
3687 sub double_delim {
3688     my($from, $to) = @_;
3689     my($succeed, $delim);
3690     if ($from !~ m[/] and $to !~ m[/]) {
3691         return "/$from/$to/";
3692     } elsif (($succeed, $from) = balanced_delim($from) and $succeed) {
3693         if (($succeed, $to) = balanced_delim($to) and $succeed) {
3694             return "$from$to";
3695         } else {
3696             for $delim ('/', '"', '#') { # note no `'' -- s''' is special
3697                 return "$from$delim$to$delim" if index($to, $delim) == -1;
3698             }
3699             $to =~ s[/][\\/]g;
3700             return "$from/$to/";
3701         }
3702     } else {
3703         for $delim ('/', '"', '#') { # note no '
3704             return "$delim$from$delim$to$delim"
3705                 if index($to . $from, $delim) == -1;
3706         }
3707         $from =~ s[/][\\/]g;
3708         $to =~ s[/][\\/]g;
3709         return "/$from/$to/";
3710     }
3711 }
3712
3713 # Only used by tr///, so backslashes hyphens
3714 sub pchr { # ASCII
3715     my($n) = @_;
3716     if ($n == ord '\\') {
3717         return '\\\\';
3718     } elsif ($n == ord "-") {
3719         return "\\-";
3720     } elsif ($n >= ord(' ') and $n <= ord('~')) {
3721         return chr($n);
3722     } elsif ($n == ord "\a") {
3723         return '\\a';
3724     } elsif ($n == ord "\b") {
3725         return '\\b';
3726     } elsif ($n == ord "\t") {
3727         return '\\t';
3728     } elsif ($n == ord "\n") {
3729         return '\\n';
3730     } elsif ($n == ord "\e") {
3731         return '\\e';
3732     } elsif ($n == ord "\f") {
3733         return '\\f';
3734     } elsif ($n == ord "\r") {
3735         return '\\r';
3736     } elsif ($n >= ord("\cA") and $n <= ord("\cZ")) {
3737         return '\\c' . chr(ord("@") + $n);
3738     } else {
3739 #       return '\x' . sprintf("%02x", $n);
3740         return '\\' . sprintf("%03o", $n);
3741     }
3742 }
3743
3744 sub collapse {
3745     my(@chars) = @_;
3746     my($str, $c, $tr) = ("");
3747     for ($c = 0; $c < @chars; $c++) {
3748         $tr = $chars[$c];
3749         $str .= pchr($tr);
3750         if ($c <= $#chars - 2 and $chars[$c + 1] == $tr + 1 and
3751             $chars[$c + 2] == $tr + 2)
3752         {
3753             for (; $c <= $#chars-1 and $chars[$c + 1] == $chars[$c] + 1; $c++)
3754               {}
3755             $str .= "-";
3756             $str .= pchr($chars[$c]);
3757         }
3758     }
3759     return $str;
3760 }
3761
3762 sub tr_decode_byte {
3763     my($table, $flags) = @_;
3764     my(@table) = unpack("s*", $table);
3765     splice @table, 0x100, 1;   # Number of subsequent elements
3766     my($c, $tr, @from, @to, @delfrom, $delhyphen);
3767     if ($table[ord "-"] != -1 and
3768         $table[ord("-") - 1] == -1 || $table[ord("-") + 1] == -1)
3769     {
3770         $tr = $table[ord "-"];
3771         $table[ord "-"] = -1;
3772         if ($tr >= 0) {
3773             @from = ord("-");
3774             @to = $tr;
3775         } else { # -2 ==> delete
3776             $delhyphen = 1;
3777         }
3778     }
3779     for ($c = 0; $c < @table; $c++) {
3780         $tr = $table[$c];
3781         if ($tr >= 0) {
3782             push @from, $c; push @to, $tr;
3783         } elsif ($tr == -2) {
3784             push @delfrom, $c;
3785         }
3786     }
3787     @from = (@from, @delfrom);
3788     if ($flags & OPpTRANS_COMPLEMENT) {
3789         my @newfrom = ();
3790         my %from;
3791         @from{@from} = (1) x @from;
3792         for ($c = 0; $c < 256; $c++) {
3793             push @newfrom, $c unless $from{$c};
3794         }
3795         @from = @newfrom;
3796     }
3797     unless ($flags & OPpTRANS_DELETE || !@to) {
3798         pop @to while $#to and $to[$#to] == $to[$#to -1];
3799     }
3800     my($from, $to);
3801     $from = collapse(@from);
3802     $to = collapse(@to);
3803     $from .= "-" if $delhyphen;
3804     return ($from, $to);
3805 }
3806
3807 sub tr_chr {
3808     my $x = shift;
3809     if ($x == ord "-") {
3810         return "\\-";
3811     } elsif ($x == ord "\\") {
3812         return "\\\\";
3813     } else {
3814         return chr $x;
3815     }
3816 }
3817
3818 # XXX This doesn't yet handle all cases correctly either
3819
3820 sub tr_decode_utf8 {
3821     my($swash_hv, $flags) = @_;
3822     my %swash = $swash_hv->ARRAY;
3823     my $final = undef;
3824     $final = $swash{'FINAL'}->IV if exists $swash{'FINAL'};
3825     my $none = $swash{"NONE"}->IV;
3826     my $extra = $none + 1;
3827     my(@from, @delfrom, @to);
3828     my $line;
3829     foreach $line (split /\n/, $swash{'LIST'}->PV) {
3830         my($min, $max, $result) = split(/\t/, $line);
3831         $min = hex $min;
3832         if (length $max) {
3833             $max = hex $max;
3834         } else {
3835             $max = $min;
3836         }
3837         $result = hex $result;
3838         if ($result == $extra) {
3839             push @delfrom, [$min, $max];
3840         } else {
3841             push @from, [$min, $max];
3842             push @to, [$result, $result + $max - $min];
3843         }
3844     }
3845     for my $i (0 .. $#from) {
3846         if ($from[$i][0] == ord '-') {
3847             unshift @from, splice(@from, $i, 1);
3848             unshift @to, splice(@to, $i, 1);
3849             last;
3850         } elsif ($from[$i][1] == ord '-') {
3851             $from[$i][1]--;
3852             $to[$i][1]--;
3853             unshift @from, ord '-';
3854             unshift @to, ord '-';
3855             last;
3856         }
3857     }
3858     for my $i (0 .. $#delfrom) {
3859         if ($delfrom[$i][0] == ord '-') {
3860             push @delfrom, splice(@delfrom, $i, 1);
3861             last;
3862         } elsif ($delfrom[$i][1] == ord '-') {
3863             $delfrom[$i][1]--;
3864             push @delfrom, ord '-';
3865             last;
3866         }
3867     }
3868     if (defined $final and $to[$#to][1] != $final) {
3869         push @to, [$final, $final];
3870     }
3871     push @from, @delfrom;
3872     if ($flags & OPpTRANS_COMPLEMENT) {
3873         my @newfrom;
3874         my $next = 0;
3875         for my $i (0 .. $#from) {
3876             push @newfrom, [$next, $from[$i][0] - 1];
3877             $next = $from[$i][1] + 1;
3878         }
3879         @from = ();
3880         for my $range (@newfrom) {
3881             if ($range->[0] <= $range->[1]) {
3882                 push @from, $range;
3883             }
3884         }
3885     }
3886     my($from, $to, $diff);
3887     for my $chunk (@from) {
3888         $diff = $chunk->[1] - $chunk->[0];
3889         if ($diff > 1) {
3890             $from .= tr_chr($chunk->[0]) . "-" . tr_chr($chunk->[1]);
3891         } elsif ($diff == 1) {
3892             $from .= tr_chr($chunk->[0]) . tr_chr($chunk->[1]);
3893         } else {
3894             $from .= tr_chr($chunk->[0]);
3895         }
3896     }
3897     for my $chunk (@to) {
3898         $diff = $chunk->[1] - $chunk->[0];
3899         if ($diff > 1) {
3900             $to .= tr_chr($chunk->[0]) . "-" . tr_chr($chunk->[1]);
3901         } elsif ($diff == 1) {
3902             $to .= tr_chr($chunk->[0]) . tr_chr($chunk->[1]);
3903         } else {
3904             $to .= tr_chr($chunk->[0]);
3905         }
3906     }
3907     #$final = sprintf("%04x", $final) if defined $final;
3908     #$none = sprintf("%04x", $none) if defined $none;
3909     #$extra = sprintf("%04x", $extra) if defined $extra;
3910     #print STDERR "final: $final\n none: $none\nextra: $extra\n";
3911     #print STDERR $swash{'LIST'}->PV;
3912     return (escape_str($from), escape_str($to));
3913 }
3914
3915 sub pp_trans {
3916     my $self = shift;
3917     my($op, $cx) = @_;
3918     my($from, $to);
3919     if (class($op) eq "PVOP") {
3920         ($from, $to) = tr_decode_byte($op->pv, $op->private);
3921     } else { # class($op) eq "SVOP"
3922         ($from, $to) = tr_decode_utf8($op->sv->RV, $op->private);
3923     }
3924     my $flags = "";
3925     $flags .= "c" if $op->private & OPpTRANS_COMPLEMENT;
3926     $flags .= "d" if $op->private & OPpTRANS_DELETE;
3927     $to = "" if $from eq $to and $flags eq "";
3928     $flags .= "s" if $op->private & OPpTRANS_SQUASH;
3929     return "tr" . double_delim($from, $to) . $flags;
3930 }
3931
3932 # Like dq(), but different
3933 sub re_dq {
3934     my $self = shift;
3935     my ($op, $extended) = @_;
3936
3937     my $type = $op->name;
3938     if ($type eq "const") {
3939         return '$[' if $op->private & OPpCONST_ARYBASE;
3940         my $unbacked = re_unback($self->const_sv($op)->as_string);
3941         return re_uninterp_extended(escape_extended_re($unbacked))
3942             if $extended;
3943         return re_uninterp(escape_str($unbacked));
3944     } elsif ($type eq "concat") {
3945         my $first = $self->re_dq($op->first, $extended);
3946         my $last  = $self->re_dq($op->last,  $extended);
3947
3948         # Disambiguate "${foo}bar", "${foo}{bar}", "${foo}[1]"
3949         ($last =~ /^[A-Z\\\^\[\]_?]/ &&
3950             $first =~ s/([\$@])\^$/${1}{^}/)  # "${^}W" etc
3951             || ($last =~ /^[{\[\w_]/ &&
3952                 $first =~ s/([\$@])([A-Za-z_]\w*)$/${1}{$2}/);
3953
3954         return $first . $last;
3955     } elsif ($type eq "uc") {
3956         return '\U' . $self->re_dq($op->first->sibling, $extended) . '\E';
3957     } elsif ($type eq "lc") {
3958         return '\L' . $self->re_dq($op->first->sibling, $extended) . '\E';
3959     } elsif ($type eq "ucfirst") {
3960         return '\u' . $self->re_dq($op->first->sibling, $extended);
3961     } elsif ($type eq "lcfirst") {
3962         return '\l' . $self->re_dq($op->first->sibling, $extended);
3963     } elsif ($type eq "quotemeta") {
3964         return '\Q' . $self->re_dq($op->first->sibling, $extended) . '\E';
3965     } elsif ($type eq "join") {
3966         return $self->deparse($op->last, 26); # was join($", @ary)
3967     } else {
3968         return $self->deparse($op, 26);
3969     }
3970 }
3971
3972 sub pure_string {
3973     my ($self, $op) = @_;
3974     return 0 if null $op;
3975     my $type = $op->name;
3976
3977     if ($type eq 'const') {
3978         return 1;
3979     }
3980     elsif ($type =~ /^[ul]c(first)?$/ || $type eq 'quotemeta') {
3981         return $self->pure_string($op->first->sibling);
3982     }
3983     elsif ($type eq 'join') {
3984         my $join_op = $op->first->sibling;  # Skip pushmark
3985         return 0 unless $join_op->name eq 'null' && $join_op->targ eq OP_RV2SV;
3986
3987         my $gvop = $join_op->first;
3988         return 0 unless $gvop->name eq 'gvsv';
3989         return 0 unless '"' eq $self->gv_name($self->gv_or_padgv($gvop));
3990
3991         return 0 unless ${$join_op->sibling} eq ${$op->last};
3992         return 0 unless $op->last->name =~ /^(rv2|pad)av$/;
3993     }
3994     elsif ($type eq 'concat') {
3995         return $self->pure_string($op->first)
3996             && $self->pure_string($op->last);
3997     }
3998     elsif (is_scalar($op) || $type =~ /^[ah]elem$/) {
3999         return 1;
4000     }
4001     elsif ($type eq "null" and $op->can('first') and not null $op->first and
4002            $op->first->name eq "null" and $op->first->can('first')
4003            and not null $op->first->first and
4004            $op->first->first->name eq "aelemfast") {
4005         return 1;
4006     }
4007     else {
4008         return 0;
4009     }
4010
4011     return 1;
4012 }
4013
4014 sub regcomp {
4015     my $self = shift;
4016     my($op, $cx, $extended) = @_;
4017     my $kid = $op->first;
4018     $kid = $kid->first if $kid->name eq "regcmaybe";
4019     $kid = $kid->first if $kid->name eq "regcreset";
4020     if ($kid->name eq "null" and !null($kid->first)
4021         and $kid->first->name eq 'pushmark')
4022     {
4023         my $str = '';
4024         $kid = $kid->first->sibling;
4025         while (!null($kid)) {
4026             $str .= $self->re_dq($kid, $extended);
4027             $kid = $kid->sibling;
4028         }
4029         return $str, 1;
4030     }
4031
4032     return ($self->re_dq($kid, $extended), 1) if $self->pure_string($kid);
4033     return ($self->deparse($kid, $cx), 0);
4034 }
4035
4036 sub pp_regcomp {
4037     my ($self, $op, $cx) = @_;
4038     return (($self->regcomp($op, $cx, 0))[0]);
4039 }
4040
4041 # osmic acid -- see osmium tetroxide
4042
4043 my %matchwords;
4044 map($matchwords{join "", sort split //, $_} = $_, 'cig', 'cog', 'cos', 'cogs',
4045     'cox', 'go', 'is', 'ism', 'iso', 'mig', 'mix', 'osmic', 'ox', 'sic',
4046     'sig', 'six', 'smog', 'so', 'soc', 'sog', 'xi');
4047
4048 sub matchop {
4049     my $self = shift;
4050     my($op, $cx, $name, $delim) = @_;
4051     my $kid = $op->first;
4052     my ($binop, $var, $re) = ("", "", "");
4053     if ($op->flags & OPf_STACKED) {
4054         $binop = 1;
4055         $var = $self->deparse($kid, 20);
4056         $kid = $kid->sibling;
4057     }
4058     my $quote = 1;
4059     my $extended = ($op->pmflags & PMf_EXTENDED);
4060     if (null $kid) {
4061         my $unbacked = re_unback($op->precomp);
4062         if ($extended) {
4063             $re = re_uninterp_extended(escape_extended_re($unbacked));
4064         } else {
4065             $re = re_uninterp(escape_str(re_unback($op->precomp)));
4066         }
4067     } elsif ($kid->name ne 'regcomp') {
4068         carp("found ".$kid->name." where regcomp expected");
4069     } else {
4070         ($re, $quote) = $self->regcomp($kid, 21, $extended);
4071     }
4072     my $flags = "";
4073     $flags .= "c" if $op->pmflags & PMf_CONTINUE;
4074     $flags .= "g" if $op->pmflags & PMf_GLOBAL;
4075     $flags .= "i" if $op->pmflags & PMf_FOLD;
4076     $flags .= "m" if $op->pmflags & PMf_MULTILINE;
4077     $flags .= "o" if $op->pmflags & PMf_KEEP;
4078     $flags .= "s" if $op->pmflags & PMf_SINGLELINE;
4079     $flags .= "x" if $op->pmflags & PMf_EXTENDED;
4080     $flags = $matchwords{$flags} if $matchwords{$flags};
4081     if ($op->pmflags & PMf_ONCE) { # only one kind of delimiter works here
4082         $re =~ s/\?/\\?/g;
4083         $re = "?$re?";
4084     } elsif ($quote) {
4085         $re = single_delim($name, $delim, $re);
4086     }
4087     $re = $re . $flags if $quote;
4088     if ($binop) {
4089         return $self->maybe_parens("$var =~ $re", $cx, 20);
4090     } else {
4091         return $re;
4092     }
4093 }
4094
4095 sub pp_match { matchop(@_, "m", "/") }
4096 sub pp_pushre { matchop(@_, "m", "/") }
4097 sub pp_qr { matchop(@_, "qr", "") }
4098
4099 sub pp_split {
4100     my $self = shift;
4101     my($op, $cx) = @_;
4102     my($kid, @exprs, $ary, $expr);
4103     $kid = $op->first;
4104
4105     # For our kid (an OP_PUSHRE), pmreplroot is never actually the
4106     # root of a replacement; it's either empty, or abused to point to
4107     # the GV for an array we split into (an optimization to save
4108     # assignment overhead). Depending on whether we're using ithreads,
4109     # this OP* holds either a GV* or a PADOFFSET. Luckily, B.xs
4110     # figures out for us which it is.
4111     my $replroot = $kid->pmreplroot;
4112     my $gv = 0;
4113     if (ref($replroot) eq "B::GV") {
4114         $gv = $replroot;
4115     } elsif (!ref($replroot) and $replroot > 0) {
4116         $gv = $self->padval($replroot);
4117     }
4118     $ary = $self->stash_variable('@', $self->gv_name($gv)) if $gv;
4119
4120     for (; !null($kid); $kid = $kid->sibling) {
4121         push @exprs, $self->deparse($kid, 6);
4122     }
4123
4124     # handle special case of split(), and split(" ") that compiles to /\s+/
4125     $kid = $op->first;
4126     if ($kid->flags & OPf_SPECIAL
4127         && $exprs[0] eq '/\\s+/'
4128         && $kid->pmflags & PMf_SKIPWHITE ) {
4129             $exprs[0] = '" "';
4130     }
4131
4132     $expr = "split(" . join(", ", @exprs) . ")";
4133     if ($ary) {
4134         return $self->maybe_parens("$ary = $expr", $cx, 7);
4135     } else {
4136         return $expr;
4137     }
4138 }
4139
4140 # oxime -- any of various compounds obtained chiefly by the action of
4141 # hydroxylamine on aldehydes and ketones and characterized by the
4142 # bivalent grouping C=NOH [Webster's Tenth]
4143
4144 my %substwords;
4145 map($substwords{join "", sort split //, $_} = $_, 'ego', 'egoism', 'em',
4146     'es', 'ex', 'exes', 'gee', 'go', 'goes', 'ie', 'ism', 'iso', 'me',
4147     'meese', 'meso', 'mig', 'mix', 'os', 'ox', 'oxime', 'see', 'seem',
4148     'seg', 'sex', 'sig', 'six', 'smog', 'sog', 'some', 'xi');
4149
4150 sub pp_subst {
4151     my $self = shift;
4152     my($op, $cx) = @_;
4153     my $kid = $op->first;
4154     my($binop, $var, $re, $repl) = ("", "", "", "");
4155     if ($op->flags & OPf_STACKED) {
4156         $binop = 1;
4157         $var = $self->deparse($kid, 20);
4158         $kid = $kid->sibling;
4159     }
4160     my $flags = "";
4161     if (null($op->pmreplroot)) {
4162         $repl = $self->dq($kid);
4163         $kid = $kid->sibling;
4164     } else {
4165         $repl = $op->pmreplroot->first; # skip substcont
4166         while ($repl->name eq "entereval") {
4167             $repl = $repl->first;
4168             $flags .= "e";
4169         }
4170         if ($op->pmflags & PMf_EVAL) {
4171             $repl = $self->deparse($repl->first, 0);
4172         } else {
4173             $repl = $self->dq($repl);
4174         }
4175     }
4176     my $extended = ($op->pmflags & PMf_EXTENDED);
4177     if (null $kid) {
4178         my $unbacked = re_unback($op->precomp);
4179         if ($extended) {
4180             $re = re_uninterp_extended(escape_extended_re($unbacked));
4181         }
4182         else {
4183             $re = re_uninterp(escape_str($unbacked));
4184         }
4185     } else {
4186         ($re) = $self->regcomp($kid, 1, $extended);
4187     }
4188     $flags .= "e" if $op->pmflags & PMf_EVAL;
4189     $flags .= "g" if $op->pmflags & PMf_GLOBAL;
4190     $flags .= "i" if $op->pmflags & PMf_FOLD;
4191     $flags .= "m" if $op->pmflags & PMf_MULTILINE;
4192     $flags .= "o" if $op->pmflags & PMf_KEEP;
4193     $flags .= "s" if $op->pmflags & PMf_SINGLELINE;
4194     $flags .= "x" if $extended;
4195     $flags = $substwords{$flags} if $substwords{$flags};
4196     if ($binop) {
4197         return $self->maybe_parens("$var =~ s"
4198                                    . double_delim($re, $repl) . $flags,
4199                                    $cx, 20);
4200     } else {
4201         return "s". double_delim($re, $repl) . $flags;
4202     }
4203 }
4204
4205 1;
4206 __END__
4207
4208 =head1 NAME
4209
4210 B::Deparse - Perl compiler backend to produce perl code
4211
4212 =head1 SYNOPSIS
4213
4214 B<perl> B<-MO=Deparse>[B<,-d>][B<,-f>I<FILE>][B<,-p>][B<,-q>][B<,-l>]
4215         [B<,-s>I<LETTERS>][B<,-x>I<LEVEL>] I<prog.pl>
4216
4217 =head1 DESCRIPTION
4218
4219 B::Deparse is a backend module for the Perl compiler that generates
4220 perl source code, based on the internal compiled structure that perl
4221 itself creates after parsing a program. The output of B::Deparse won't
4222 be exactly the same as the original source, since perl doesn't keep
4223 track of comments or whitespace, and there isn't a one-to-one
4224 correspondence between perl's syntactical constructions and their
4225 compiled form, but it will often be close. When you use the B<-p>
4226 option, the output also includes parentheses even when they are not
4227 required by precedence, which can make it easy to see if perl is
4228 parsing your expressions the way you intended.
4229
4230 While B::Deparse goes to some lengths to try to figure out what your
4231 original program was doing, some parts of the language can still trip
4232 it up; it still fails even on some parts of Perl's own test suite. If
4233 you encounter a failure other than the most common ones described in
4234 the BUGS section below, you can help contribute to B::Deparse's
4235 ongoing development by submitting a bug report with a small
4236 example.
4237
4238 =head1 OPTIONS
4239
4240 As with all compiler backend options, these must follow directly after
4241 the '-MO=Deparse', separated by a comma but not any white space.
4242
4243 =over 4
4244
4245 =item B<-d>
4246
4247 Output data values (when they appear as constants) using Data::Dumper.
4248 Without this option, B::Deparse will use some simple routines of its
4249 own for the same purpose. Currently, Data::Dumper is better for some
4250 kinds of data (such as complex structures with sharing and
4251 self-reference) while the built-in routines are better for others
4252 (such as odd floating-point values).
4253
4254 =item B<-f>I<FILE>
4255
4256 Normally, B::Deparse deparses the main code of a program, and all the subs
4257 defined in the same file. To include subs defined in other files, pass the
4258 B<-f> option with the filename. You can pass the B<-f> option several times, to
4259 include more than one secondary file.  (Most of the time you don't want to
4260 use it at all.)  You can also use this option to include subs which are
4261 defined in the scope of a B<#line> directive with two parameters.
4262
4263 =item B<-l>
4264
4265 Add '#line' declarations to the output based on the line and file
4266 locations of the original code.
4267
4268 =item B<-p>
4269
4270 Print extra parentheses. Without this option, B::Deparse includes
4271 parentheses in its output only when they are needed, based on the
4272 structure of your program. With B<-p>, it uses parentheses (almost)
4273 whenever they would be legal. This can be useful if you are used to
4274 LISP, or if you want to see how perl parses your input. If you say
4275
4276     if ($var & 0x7f == 65) {print "Gimme an A!"}
4277     print ($which ? $a : $b), "\n";
4278     $name = $ENV{USER} or "Bob";
4279
4280 C<B::Deparse,-p> will print
4281
4282     if (($var & 0)) {
4283         print('Gimme an A!')
4284     };
4285     (print(($which ? $a : $b)), '???');
4286     (($name = $ENV{'USER'}) or '???')
4287
4288 which probably isn't what you intended (the C<'???'> is a sign that
4289 perl optimized away a constant value).
4290
4291 =item B<-P>
4292
4293 Disable prototype checking. With this option, all function calls are
4294 deparsed as if no prototype was defined for them. In other words,
4295
4296     perl -MO=Deparse,-P -e 'sub foo (\@) { 1 } foo @x'
4297
4298 will print
4299
4300     sub foo (\@) {
4301         1;
4302     }
4303     &foo(\@x);
4304
4305 making clear how the parameters are actually passed to C<foo>.
4306
4307 =item B<-q>
4308
4309 Expand double-quoted strings into the corresponding combinations of
4310 concatenation, uc, ucfirst, lc, lcfirst, quotemeta, and join. For
4311 instance, print
4312
4313     print "Hello, $world, @ladies, \u$gentlemen\E, \u\L$me!";
4314
4315 as
4316
4317     print 'Hello, ' . $world . ', ' . join($", @ladies) . ', '
4318           . ucfirst($gentlemen) . ', ' . ucfirst(lc $me . '!');
4319
4320 Note that the expanded form represents the way perl handles such
4321 constructions internally -- this option actually turns off the reverse
4322 translation that B::Deparse usually does. On the other hand, note that
4323 C<$x = "$y"> is not the same as C<$x = $y>: the former makes the value
4324 of $y into a string before doing the assignment.
4325
4326 =item B<-s>I<LETTERS>
4327
4328 Tweak the style of B::Deparse's output. The letters should follow
4329 directly after the 's', with no space or punctuation. The following
4330 options are available:
4331
4332 =over 4
4333
4334 =item B<C>
4335
4336 Cuddle C<elsif>, C<else>, and C<continue> blocks. For example, print
4337
4338     if (...) {
4339          ...
4340     } else {
4341          ...
4342     }
4343
4344 instead of
4345
4346     if (...) {
4347          ...
4348     }
4349     else {
4350          ...
4351     }
4352
4353 The default is not to cuddle.
4354
4355 =item B<i>I<NUMBER>
4356
4357 Indent lines by multiples of I<NUMBER> columns. The default is 4 columns.
4358
4359 =item B<T>
4360
4361 Use tabs for each 8 columns of indent. The default is to use only spaces.
4362 For instance, if the style options are B<-si4T>, a line that's indented
4363 3 times will be preceded by one tab and four spaces; if the options were
4364 B<-si8T>, the same line would be preceded by three tabs.
4365
4366 =item B<v>I<STRING>B<.>
4367
4368 Print I<STRING> for the value of a constant that can't be determined
4369 because it was optimized away (mnemonic: this happens when a constant
4370 is used in B<v>oid context). The end of the string is marked by a period.
4371 The string should be a valid perl expression, generally a constant.
4372 Note that unless it's a number, it probably needs to be quoted, and on
4373 a command line quotes need to be protected from the shell. Some
4374 conventional values include 0, 1, 42, '', 'foo', and
4375 'Useless use of constant omitted' (which may need to be
4376 B<-sv"'Useless use of constant omitted'.">
4377 or something similar depending on your shell). The default is '???'.
4378 If you're using B::Deparse on a module or other file that's require'd,
4379 you shouldn't use a value that evaluates to false, since the customary
4380 true constant at the end of a module will be in void context when the
4381 file is compiled as a main program.
4382
4383 =back
4384
4385 =item B<-x>I<LEVEL>
4386
4387 Expand conventional syntax constructions into equivalent ones that expose
4388 their internal operation. I<LEVEL> should be a digit, with higher values
4389 meaning more expansion. As with B<-q>, this actually involves turning off
4390 special cases in B::Deparse's normal operations.
4391
4392 If I<LEVEL> is at least 3, C<for> loops will be translated into equivalent
4393 while loops with continue blocks; for instance
4394
4395     for ($i = 0; $i < 10; ++$i) {
4396         print $i;
4397     }
4398
4399 turns into
4400
4401     $i = 0;
4402     while ($i < 10) {
4403         print $i;
4404     } continue {
4405         ++$i
4406     }
4407
4408 Note that in a few cases this translation can't be perfectly carried back
4409 into the source code -- if the loop's initializer declares a my variable,
4410 for instance, it won't have the correct scope outside of the loop.
4411
4412 If I<LEVEL> is at least 5, C<use> declarations will be translated into
4413 C<BEGIN> blocks containing calls to C<require> and C<import>; for
4414 instance,
4415
4416     use strict 'refs';
4417
4418 turns into
4419
4420     sub BEGIN {
4421         require strict;
4422         do {
4423             'strict'->import('refs')
4424         };
4425     }
4426
4427 If I<LEVEL> is at least 7, C<if> statements will be translated into
4428 equivalent expressions using C<&&>, C<?:> and C<do {}>; for instance
4429
4430     print 'hi' if $nice;
4431     if ($nice) {
4432         print 'hi';
4433     }
4434     if ($nice) {
4435         print 'hi';
4436     } else {
4437         print 'bye';
4438     }
4439
4440 turns into
4441
4442     $nice and print 'hi';
4443     $nice and do { print 'hi' };
4444     $nice ? do { print 'hi' } : do { print 'bye' };
4445
4446 Long sequences of elsifs will turn into nested ternary operators, which
4447 B::Deparse doesn't know how to indent nicely.
4448
4449 =back
4450
4451 =head1 USING B::Deparse AS A MODULE
4452
4453 =head2 Synopsis
4454
4455     use B::Deparse;
4456     $deparse = B::Deparse->new("-p", "-sC");
4457     $body = $deparse->coderef2text(\&func);
4458     eval "sub func $body"; # the inverse operation
4459
4460 =head2 Description
4461
4462 B::Deparse can also be used on a sub-by-sub basis from other perl
4463 programs.
4464
4465 =head2 new
4466
4467     $deparse = B::Deparse->new(OPTIONS)
4468
4469 Create an object to store the state of a deparsing operation and any
4470 options. The options are the same as those that can be given on the
4471 command line (see L</OPTIONS>); options that are separated by commas
4472 after B<-MO=Deparse> should be given as separate strings. Some
4473 options, like B<-u>, don't make sense for a single subroutine, so
4474 don't pass them.
4475
4476 =head2 ambient_pragmas
4477
4478     $deparse->ambient_pragmas(strict => 'all', '$[' => $[);
4479
4480 The compilation of a subroutine can be affected by a few compiler
4481 directives, B<pragmas>. These are:
4482
4483 =over 4
4484
4485 =item *
4486
4487 use strict;
4488
4489 =item *
4490
4491 use warnings;
4492
4493 =item *
4494
4495 Assigning to the special variable $[
4496
4497 =item *
4498
4499 use integer;
4500
4501 =item *
4502
4503 use bytes;
4504
4505 =item *
4506
4507 use utf8;
4508
4509 =item *
4510
4511 use re;
4512
4513 =back
4514
4515 Ordinarily, if you use B::Deparse on a subroutine which has
4516 been compiled in the presence of one or more of these pragmas,
4517 the output will include statements to turn on the appropriate
4518 directives. So if you then compile the code returned by coderef2text,
4519 it will behave the same way as the subroutine which you deparsed.
4520
4521 However, you may know that you intend to use the results in a
4522 particular context, where some pragmas are already in scope. In
4523 this case, you use the B<ambient_pragmas> method to describe the
4524 assumptions you wish to make.
4525
4526 Not all of the options currently have any useful effect. See
4527 L</BUGS> for more details.
4528
4529 The parameters it accepts are:
4530
4531 =over 4
4532
4533 =item strict
4534
4535 Takes a string, possibly containing several values separated
4536 by whitespace. The special values "all" and "none" mean what you'd
4537 expect.
4538
4539     $deparse->ambient_pragmas(strict => 'subs refs');
4540
4541 =item $[
4542
4543 Takes a number, the value of the array base $[.
4544
4545 =item bytes
4546
4547 =item utf8
4548
4549 =item integer
4550
4551 If the value is true, then the appropriate pragma is assumed to
4552 be in the ambient scope, otherwise not.
4553
4554 =item re
4555
4556 Takes a string, possibly containing a whitespace-separated list of
4557 values. The values "all" and "none" are special. It's also permissible
4558 to pass an array reference here.
4559
4560     $deparser->ambient_pragmas(re => 'eval');
4561
4562
4563 =item warnings
4564
4565 Takes a string, possibly containing a whitespace-separated list of
4566 values. The values "all" and "none" are special, again. It's also
4567 permissible to pass an array reference here.
4568
4569     $deparser->ambient_pragmas(warnings => [qw[void io]]);
4570
4571 If one of the values is the string "FATAL", then all the warnings
4572 in that list will be considered fatal, just as with the B<warnings>
4573 pragma itself. Should you need to specify that some warnings are
4574 fatal, and others are merely enabled, you can pass the B<warnings>
4575 parameter twice:
4576
4577     $deparser->ambient_pragmas(
4578         warnings => 'all',
4579         warnings => [FATAL => qw/void io/],
4580     );
4581
4582 See L<perllexwarn> for more information about lexical warnings.
4583
4584 =item hint_bits
4585
4586 =item warning_bits
4587
4588 These two parameters are used to specify the ambient pragmas in
4589 the format used by the special variables $^H and ${^WARNING_BITS}.
4590
4591 They exist principally so that you can write code like:
4592
4593     { my ($hint_bits, $warning_bits);
4594     BEGIN {($hint_bits, $warning_bits) = ($^H, ${^WARNING_BITS})}
4595     $deparser->ambient_pragmas (
4596         hint_bits    => $hint_bits,
4597         warning_bits => $warning_bits,
4598         '$['         => 0 + $[
4599     ); }
4600
4601 which specifies that the ambient pragmas are exactly those which
4602 are in scope at the point of calling.
4603
4604 =back
4605
4606 =head2 coderef2text
4607
4608     $body = $deparse->coderef2text(\&func)
4609     $body = $deparse->coderef2text(sub ($$) { ... })
4610
4611 Return source code for the body of a subroutine (a block, optionally
4612 preceded by a prototype in parens), given a reference to the
4613 sub. Because a subroutine can have no names, or more than one name,
4614 this method doesn't return a complete subroutine definition -- if you
4615 want to eval the result, you should prepend "sub subname ", or "sub "
4616 for an anonymous function constructor. Unless the sub was defined in
4617 the main:: package, the code will include a package declaration.
4618
4619 =head1 BUGS
4620
4621 =over 4
4622
4623 =item *
4624
4625 The only pragmas to be completely supported are: C<use warnings>,
4626 C<use strict 'refs'>, C<use bytes>, and C<use integer>. (C<$[>, which
4627 behaves like a pragma, is also supported.)
4628
4629 Excepting those listed above, we're currently unable to guarantee that
4630 B::Deparse will produce a pragma at the correct point in the program.
4631 (Specifically, pragmas at the beginning of a block often appear right
4632 before the start of the block instead.)
4633 Since the effects of pragmas are often lexically scoped, this can mean
4634 that the pragma holds sway over a different portion of the program
4635 than in the input file.
4636
4637 =item *
4638
4639 In fact, the above is a specific instance of a more general problem:
4640 we can't guarantee to produce BEGIN blocks or C<use> declarations in
4641 exactly the right place. So if you use a module which affects compilation
4642 (such as by over-riding keywords, overloading constants or whatever)
4643 then the output code might not work as intended.
4644
4645 This is the most serious outstanding problem, and will require some help
4646 from the Perl core to fix.
4647
4648 =item *
4649
4650 If a keyword is over-ridden, and your program explicitly calls
4651 the built-in version by using CORE::keyword, the output of B::Deparse
4652 will not reflect this. If you run the resulting code, it will call
4653 the over-ridden version rather than the built-in one. (Maybe there
4654 should be an option to B<always> print keyword calls as C<CORE::name>.)
4655
4656 =item *
4657
4658 Some constants don't print correctly either with or without B<-d>.
4659 For instance, neither B::Deparse nor Data::Dumper know how to print
4660 dual-valued scalars correctly, as in:
4661
4662     use constant E2BIG => ($!=7); $y = E2BIG; print $y, 0+$y;
4663
4664 =item *
4665
4666 An input file that uses source filtering probably won't be deparsed into
4667 runnable code, because it will still include the B<use> declaration
4668 for the source filtering module, even though the code that is
4669 produced is already ordinary Perl which shouldn't be filtered again.
4670
4671 =item *
4672
4673 Optimised away statements are rendered as '???'. This includes statements that
4674 have a compile-time side-effect, such as the obscure
4675
4676     my $x if 0;
4677
4678 which is not, consequently, deparsed correctly.
4679
4680 =item *
4681
4682 There are probably many more bugs on non-ASCII platforms (EBCDIC).
4683
4684 =back
4685
4686 =head1 AUTHOR
4687
4688 Stephen McCamant <smcc@CSUA.Berkeley.EDU>, based on an earlier version
4689 by Malcolm Beattie <mbeattie@sable.ox.ac.uk>, with contributions from
4690 Gisle Aas, James Duncan, Albert Dvornik, Robin Houston, Dave Mitchell,
4691 Hugo van der Sanden, Gurusamy Sarathy, Nick Ing-Simmons, and Rafael
4692 Garcia-Suarez.
4693
4694 =cut