ext/B/B/Deparse.pm

   1 # B::Deparse.pm
   2 # Copyright (c) 1998, 1999, 2000 Stephen McCamant. All rights reserved.
   3 # This module is free software; you can redistribute and/or modify
   4 # it under the same terms as Perl itself.
   5
   6 # This is based on the module of the same name by Malcolm Beattie,
   7 # but essentially none of his code remains.
   8
   9 package B::Deparse;
  10 use Carp;
  11 use B qw(class main_root main_start main_cv svref_2object opnumber cstring
  12          OPf_WANT OPf_WANT_VOID OPf_WANT_SCALAR OPf_WANT_LIST
  13          OPf_KIDS OPf_REF OPf_STACKED OPf_SPECIAL OPf_MOD
  14          OPpLVAL_INTRO OPpOUR_INTRO OPpENTERSUB_AMPER OPpSLICE OPpCONST_BARE
  15          OPpTRANS_SQUASH OPpTRANS_DELETE OPpTRANS_COMPLEMENT OPpTARGET_MY
  16          OPpCONST_ARYBASE OPpEXISTS_SUB OPpSORT_NUMERIC OPpSORT_INTEGER
  17          OPpSORT_REVERSE
  18          SVf_IOK SVf_NOK SVf_ROK SVf_POK SVpad_OUR
  19          CVf_METHOD CVf_LOCKED CVf_LVALUE
  20          PMf_KEEP PMf_GLOBAL PMf_CONTINUE PMf_EVAL PMf_ONCE PMf_SKIPWHITE
  21          PMf_MULTILINE PMf_SINGLELINE PMf_FOLD PMf_EXTENDED);
  22 $VERSION = 0.62;
  23 use strict;
  24 use vars qw/$AUTOLOAD/;
  25 use warnings ();
  26
  27 # Changes between 0.50 and 0.51:
  28 # - fixed nulled leave with live enter in sort { }
  29 # - fixed reference constants (\"str")
  30 # - handle empty programs gracefully
  31 # - handle infinte loops (for (;;) {}, while (1) {})
  32 # - differentiate between `for my $x ...' and `my $x; for $x ...'
  33 # - various minor cleanups
  34 # - moved globals into an object
  35 # - added `-u', like B::C
  36 # - package declarations using cop_stash
  37 # - subs, formats and code sorted by cop_seq
  38 # Changes between 0.51 and 0.52:
  39 # - added pp_threadsv (special variables under USE_5005THREADS)
  40 # - added documentation
  41 # Changes between 0.52 and 0.53:
  42 # - many changes adding precedence contexts and associativity
  43 # - added `-p' and `-s' output style options
  44 # - various other minor fixes
  45 # Changes between 0.53 and 0.54:
  46 # - added support for new `for (1..100)' optimization,
  47 #   thanks to Gisle Aas
  48 # Changes between 0.54 and 0.55:
  49 # - added support for new qr// construct
  50 # - added support for new pp_regcreset OP
  51 # Changes between 0.55 and 0.56:
  52 # - tested on base/*.t, cmd/*.t, comp/*.t, io/*.t
  53 # - fixed $# on non-lexicals broken in last big rewrite
  54 # - added temporary fix for change in opcode of OP_STRINGIFY
  55 # - fixed problem in 0.54's for() patch in `for (@ary)'
  56 # - fixed precedence in conditional of ?:
  57 # - tweaked list paren elimination in `my($x) = @_'
  58 # - made continue-block detection trickier wrt. null ops
  59 # - fixed various prototype problems in pp_entersub
  60 # - added support for sub prototypes that never get GVs
  61 # - added unquoting for special filehandle first arg in truncate
  62 # - print doubled rv2gv (a bug) as `*{*GV}' instead of illegal `**GV'
  63 # - added semicolons at the ends of blocks
  64 # - added -l `#line' declaration option -- fixes cmd/subval.t 27,28
  65 # Changes between 0.56 and 0.561:
  66 # - fixed multiply-declared my var in pp_truncate (thanks to Sarathy)
  67 # - used new B.pm symbolic constants (done by Nick Ing-Simmons)
  68 # Changes between 0.561 and 0.57:
  69 # - stylistic changes to symbolic constant stuff
  70 # - handled scope in s///e replacement code
  71 # - added unquote option for expanding "" into concats, etc.
  72 # - split method and proto parts of pp_entersub into separate functions
  73 # - various minor cleanups
  74 # Changes after 0.57:
  75 # - added parens in \&foo (patch by Albert Dvornik)
  76 # Changes between 0.57 and 0.58:
  77 # - fixed `0' statements that weren't being printed
  78 # - added methods for use from other programs
  79 #   (based on patches from James Duncan and Hugo van der Sanden)
  80 # - added -si and -sT to control indenting (also based on a patch from Hugo)
  81 # - added -sv to print something else instead of '???'
  82 # - preliminary version of utf8 tr/// handling
  83 # Changes after 0.58:
  84 # - uses of $op->ppaddr changed to new $op->name (done by Sarathy)
  85 # - added support for Hugo's new OP_SETSTATE (like nextstate)
  86 # Changes between 0.58 and 0.59
  87 # - added support for Chip's OP_METHOD_NAMED
  88 # - added support for Ilya's OPpTARGET_MY optimization
  89 # - elided arrows before `()' subscripts when possible
  90 # Changes between 0.59 and 0.60
  91 # - support for method attribues was added
  92 # - some warnings fixed
  93 # - separate recognition of constant subs
  94 # - rewrote continue block handling, now recoginizing for loops
  95 # - added more control of expanding control structures
  96 # Changes between 0.60 and 0.61 (mostly by Robin Houston)
  97 # - many bug-fixes
  98 # - support for pragmas and 'use'
  99 # - support for the little-used $[ variable
 100 # - support for __DATA__ sections
 101 # - UTF8 support
 102 # - BEGIN, CHECK, INIT and END blocks
 103 # - scoping of subroutine declarations fixed
 104 # - compile-time output from the input program can be suppressed, so that the
 105 #   output is just the deparsed code. (a change to O.pm in fact)
 106 # - our() declarations
 107 # - *all* the known bugs are now listed in the BUGS section
 108 # - comprehensive test mechanism (TEST -deparse)
 109
 110 # Todo:
 111 #  (See also BUGS section at the end of this file)
 112 #
 113 # - finish tr/// changes
 114 # - add option for even more parens (generalize \&foo change)
 115 # - left/right context
 116 # - treat top-level block specially for incremental output
 117 # - copy comments (look at real text with $^P?)
 118 # - avoid semis in one-statement blocks
 119 # - associativity of &&=, ||=, ?:
 120 # - ',' => '=>' (auto-unquote?)
 121 # - break long lines ("\r" as discretionary break?)
 122 # - configurable syntax highlighting: ANSI color, HTML, TeX, etc.
 123 # - more style options: brace style, hex vs. octal, quotes, ...
 124 # - print big ints as hex/octal instead of decimal (heuristic?)
 125 # - handle `my $x if 0'?
 126 # - coordinate with Data::Dumper (both directions? see previous)
 127 # - version using op_next instead of op_first/sibling?
 128 # - avoid string copies (pass arrays, one big join?)
 129 # - here-docs?
 130
 131 # Tests that will always fail:
 132 # (see t/TEST for the short list)
 133
 134 # Object fields (were globals):
 135 #
 136 # avoid_local:
 137 # (local($a), local($b)) and local($a, $b) have the same internal
 138 # representation but the short form looks better. We notice we can
 139 # use a large-scale local when checking the list, but need to prevent
 140 # individual locals too. This hash holds the addresses of OPs that
 141 # have already had their local-ness accounted for. The same thing
 142 # is done with my().
 143 #
 144 # curcv:
 145 # CV for current sub (or main program) being deparsed
 146 #
 147 # curcvlex:
 148 # Cached hash of lexical variables for curcv: keys are names,
 149 # each value is an array of pairs, indicating the cop_seq of scopes
 150 # in which a var of that name is valid.
 151 #
 152 # curcop:
 153 # COP for statement being deparsed
 154 #
 155 # curstash:
 156 # name of the current package for deparsed code
 157 #
 158 # subs_todo:
 159 # array of [cop_seq, CV, is_format?] for subs and formats we still
 160 # want to deparse
 161 #
 162 # protos_todo:
 163 # as above, but [name, prototype] for subs that never got a GV
 164 #
 165 # subs_done, forms_done:
 166 # keys are addresses of GVs for subs and formats we've already
 167 # deparsed (or at least put into subs_todo)
 168 #
 169 # subs_declared
 170 # keys are names of subs for which we've printed declarations.
 171 # That means we can omit parentheses from the arguments.
 172 #
 173 # subs_deparsed
 174 # Keeps track of fully qualified names of all deparsed subs.
 175 #
 176 # parens: -p
 177 # linenums: -l
 178 # unquote: -q
 179 # cuddle: ` ' or `\n', depending on -sC
 180 # indent_size: -si
 181 # use_tabs: -sT
 182 # ex_const: -sv
 183
 184 # A little explanation of how precedence contexts and associativity
 185 # work:
 186 #
 187 # deparse() calls each per-op subroutine with an argument $cx (short
 188 # for context, but not the same as the cx* in the perl core), which is
 189 # a number describing the op's parents in terms of precedence, whether
 190 # they're inside an expression or at statement level, etc.  (see
 191 # chart below). When ops with children call deparse on them, they pass
 192 # along their precedence. Fractional values are used to implement
 193 # associativity (`($x + $y) + $z' => `$x + $y + $y') and related
 194 # parentheses hacks. The major disadvantage of this scheme is that
 195 # it doesn't know about right sides and left sides, so say if you
 196 # assign a listop to a variable, it can't tell it's allowed to leave
 197 # the parens off the listop.
 198
 199 # Precedences:
 200 # 26             [TODO] inside interpolation context ("")
 201 # 25 left        terms and list operators (leftward)
 202 # 24 left        ->
 203 # 23 nonassoc    ++ --
 204 # 22 right       **
 205 # 21 right       ! ~ \ and unary + and -
 206 # 20 left        =~ !~
 207 # 19 left        * / % x
 208 # 18 left        + - .
 209 # 17 left        << >>
 210 # 16 nonassoc    named unary operators
 211 # 15 nonassoc    < > <= >= lt gt le ge
 212 # 14 nonassoc    == != <=> eq ne cmp
 213 # 13 left        &
 214 # 12 left        | ^
 215 # 11 left        &&
 216 # 10 left        ||
 217 #  9 nonassoc    ..  ...
 218 #  8 right       ?:
 219 #  7 right       = += -= *= etc.
 220 #  6 left        , =>
 221 #  5 nonassoc    list operators (rightward)
 222 #  4 right       not
 223 #  3 left        and
 224 #  2 left        or xor
 225 #  1             statement modifiers
 226 #  0             statement level
 227
 228 # Also, lineseq may pass a fourth parameter to the pp_ routines:
 229 # if present, the fourth parameter is passed on by deparse.
 230 #
 231 # If present and true, it means that the op exists directly as
 232 # part of a lineseq. Currently it's only used by scopeop to
 233 # decide whether its results need to be enclosed in a do {} block.
 234
 235 # Nonprinting characters with special meaning:
 236 # \cS - steal parens (see maybe_parens_unop)
 237 # \n - newline and indent
 238 # \t - increase indent
 239 # \b - decrease indent (`outdent')
 240 # \f - flush left (no indent)
 241 # \cK - kill following semicolon, if any
 242
 243 sub null {
 244     my $op = shift;
 245     return class($op) eq "NULL";
 246 }
 247
 248 sub todo {
 249     my $self = shift;
 250     my($cv, $is_form) = @_;
 251     return unless ($cv->FILE eq $0 || exists $self->{files}{$cv->FILE});
 252     my $seq;
 253     if (!null($cv->START) and is_state($cv->START)) {
 254         $seq = $cv->START->cop_seq;
 255     } else {
 256         $seq = 0;
 257     }
 258     push @{$self->{'subs_todo'}}, [$seq, $cv, $is_form];
 259     unless ($is_form || class($cv->STASH) eq 'SPECIAL') {
 260         $self->{'subs_deparsed'}{$cv->STASH->NAME."::".$cv->GV->NAME} = 1;
 261     }
 262 }
 263
 264 sub next_todo {
 265     my $self = shift;
 266     my $ent = shift @{$self->{'subs_todo'}};
 267     my $cv = $ent->[1];
 268     my $gv = $cv->GV;
 269     my $name = $self->gv_name($gv);
 270     if ($ent->[2]) {
 271         return "format $name =\n"
 272             . $self->deparse_format($ent->[1]). "\n";
 273     } else {
 274         $self->{'subs_declared'}{$name} = 1;
 275         if ($name eq "BEGIN") {
 276             my $use_dec = $self->begin_is_use($cv);
 277             if (defined ($use_dec)) {
 278                 return () if 0 == length($use_dec);
 279                 return $use_dec;
 280             }
 281         }
 282         my $l = '';
 283         if ($self->{'linenums'}) {
 284             my $line = $gv->LINE;
 285             my $file = $gv->FILE;
 286             $l = "\n\f#line $line \"$file\"\n";
 287         }
 288         return "${l}sub $name " . $self->deparse_sub($cv);
 289     }
 290 }
 291
 292 # Return a "use" declaration for this BEGIN block, if appropriate
 293 sub begin_is_use {
 294     my ($self, $cv) = @_;
 295     my $root = $cv->ROOT;
 296     local @$self{qw'curcv curcvlex'} = ($cv);
 297 #require B::Debug;
 298 #B::walkoptree($cv->ROOT, "debug");
 299     my $lineseq = $root->first;
 300     return if $lineseq->name ne "lineseq";
 301
 302     my $req_op = $lineseq->first->sibling;
 303     return if $req_op->name ne "require";
 304
 305     my $module;
 306     if ($req_op->first->private & OPpCONST_BARE) {
 307         # Actually it should always be a bareword
 308         $module = $self->const_sv($req_op->first)->PV;
 309         $module =~ s[/][::]g;
 310         $module =~ s/.pm$//;
 311     }
 312     else {
 313         $module = const($self->const_sv($req_op->first));
 314     }
 315
 316     my $version;
 317     my $version_op = $req_op->sibling;
 318     return if class($version_op) eq "NULL";
 319     if ($version_op->name eq "lineseq") {
 320         # We have a version parameter; skip nextstate & pushmark
 321         my $constop = $version_op->first->next->next;
 322
 323         return unless $self->const_sv($constop)->PV eq $module;
 324         $constop = $constop->sibling;
 325         $version = $self->const_sv($constop)->int_value;
 326         $constop = $constop->sibling;
 327         return if $constop->name ne "method_named";
 328         return if $self->const_sv($constop)->PV ne "VERSION";
 329     }
 330
 331     $lineseq = $version_op->sibling;
 332     return if $lineseq->name ne "lineseq";
 333     my $entersub = $lineseq->first->sibling;
 334     if ($entersub->name eq "stub") {
 335         return "use $module $version ();\n" if defined $version;
 336         return "use $module ();\n";
 337     }
 338     return if $entersub->name ne "entersub";
 339
 340     # See if there are import arguments
 341     my $args = '';
 342
 343     my $svop = $entersub->first->sibling; # Skip over pushmark
 344     return unless $self->const_sv($svop)->PV eq $module;
 345
 346     # Pull out the arguments
 347     for ($svop=$svop->sibling; $svop->name ne "method_named";
 348                 $svop = $svop->sibling) {
 349         $args .= ", " if length($args);
 350         $args .= $self->deparse($svop, 6);
 351     }
 352
 353     my $use = 'use';
 354     my $method_named = $svop;
 355     return if $method_named->name ne "method_named";
 356     my $method_name = $self->const_sv($method_named)->PV;
 357
 358     if ($method_name eq "unimport") {
 359         $use = 'no';
 360     }
 361
 362     # Certain pragmas are dealt with using hint bits,
 363     # so we ignore them here
 364     if ($module eq 'strict' || $module eq 'integer'
 365         || $module eq 'bytes' || $module eq 'warnings') {
 366         return "";
 367     }
 368
 369     if (defined $version && length $args) {
 370         return "$use $module $version ($args);\n";
 371     } elsif (defined $version) {
 372         return "$use $module $version;\n";
 373     } elsif (length $args) {
 374         return "$use $module ($args);\n";
 375     } else {
 376         return "$use $module;\n";
 377     }
 378 }
 379
 380 sub stash_subs {
 381     my ($self, $pack) = @_;
 382     my (@ret, $stash);
 383     if (!defined $pack) {
 384         $pack = '';
 385         $stash = \%::;
 386     }
 387     else {
 388         $pack =~ s/(::)?$/::/;
 389         no strict 'refs';
 390         $stash = \%$pack;
 391     }
 392     my %stash = svref_2object($stash)->ARRAY;
 393     while (my ($key, $val) = each %stash) {
 394         next if $key eq 'main::';       # avoid infinite recursion
 395         my $class = class($val);
 396         if ($class eq "PV") {
 397             # Just a prototype. As an ugly but fairly effective way
 398             # to find out if it belongs here is to see if the AUTOLOAD
 399             # (if any) for the stash was defined in one of our files.
 400             my $A = $stash{"AUTOLOAD"};
 401             if (defined ($A) && class($A) eq "GV" && defined($A->CV)
 402                 && class($A->CV) eq "CV") {
 403                 my $AF = $A->FILE;
 404                 next unless $AF eq $0 || exists $self->{'files'}{$AF};
 405             }
 406             push @{$self->{'protos_todo'}}, [$pack . $key, $val->PV];
 407         } elsif ($class eq "IV") {
 408             # Just a name. As above.
 409             my $A = $stash{"AUTOLOAD"};
 410             if (defined ($A) && class($A) eq "GV" && defined($A->CV)
 411                 && class($A->CV) eq "CV") {
 412                 my $AF = $A->FILE;
 413                 next unless $AF eq $0 || exists $self->{'files'}{$AF};
 414             }
 415             push @{$self->{'protos_todo'}}, [$pack . $key, undef];
 416         } elsif ($class eq "GV") {
 417             if (class(my $cv = $val->CV) ne "SPECIAL") {
 418                 next if $self->{'subs_done'}{$$val}++;
 419                 next if $$val != ${$cv->GV};   # Ignore imposters
 420                 $self->todo($cv, 0);
 421             }
 422             if (class(my $cv = $val->FORM) ne "SPECIAL") {
 423                 next if $self->{'forms_done'}{$$val}++;
 424                 next if $$val != ${$cv->GV};   # Ignore imposters
 425                 $self->todo($cv, 1);
 426             }
 427             if (class($val->HV) ne "SPECIAL" && $key =~ /::$/) {
 428                 $self->stash_subs($pack . $key);
 429             }
 430         }
 431     }
 432 }
 433
 434 sub print_protos {
 435     my $self = shift;
 436     my $ar;
 437     my @ret;
 438     foreach $ar (@{$self->{'protos_todo'}}) {
 439         my $proto = (defined $ar->[1] ? " (". $ar->[1] . ")" : "");
 440         push @ret, "sub " . $ar->[0] .  "$proto;\n";
 441     }
 442     delete $self->{'protos_todo'};
 443     return @ret;
 444 }
 445
 446 sub style_opts {
 447     my $self = shift;
 448     my $opts = shift;
 449     my $opt;
 450     while (length($opt = substr($opts, 0, 1))) {
 451         if ($opt eq "C") {
 452             $self->{'cuddle'} = " ";
 453             $opts = substr($opts, 1);
 454         } elsif ($opt eq "i") {
 455             $opts =~ s/^i(\d+)//;
 456             $self->{'indent_size'} = $1;
 457         } elsif ($opt eq "T") {
 458             $self->{'use_tabs'} = 1;
 459             $opts = substr($opts, 1);
 460         } elsif ($opt eq "v") {
 461             $opts =~ s/^v([^.]*)(.|$)//;
 462             $self->{'ex_const'} = $1;
 463         }
 464     }
 465 }
 466
 467 sub new {
 468     my $class = shift;
 469     my $self = bless {}, $class;
 470     $self->{'subs_todo'} = [];
 471     $self->{'files'} = {};
 472     $self->{'curstash'} = "main";
 473     $self->{'curcop'} = undef;
 474     $self->{'cuddle'} = "\n";
 475     $self->{'indent_size'} = 4;
 476     $self->{'use_tabs'} = 0;
 477     $self->{'expand'} = 0;
 478     $self->{'unquote'} = 0;
 479     $self->{'linenums'} = 0;
 480     $self->{'parens'} = 0;
 481     $self->{'ex_const'} = "'???'";
 482
 483     $self->{'ambient_arybase'} = 0;
 484     $self->{'ambient_warnings'} = undef; # Assume no lexical warnings
 485     $self->{'ambient_hints'} = 0;
 486     $self->init();
 487
 488     while (my $arg = shift @_) {
 489         if ($arg =~ /^-f(.*)/) {
 490             $self->{'files'}{$1} = 1;
 491         } elsif ($arg eq "-p") {
 492             $self->{'parens'} = 1;
 493         } elsif ($arg eq "-P") {
 494             $self->{'noproto'} = 1;
 495         } elsif ($arg eq "-l") {
 496             $self->{'linenums'} = 1;
 497         } elsif ($arg eq "-q") {
 498             $self->{'unquote'} = 1;
 499         } elsif (substr($arg, 0, 2) eq "-s") {
 500             $self->style_opts(substr $arg, 2);
 501         } elsif ($arg =~ /^-x(\d)$/) {
 502             $self->{'expand'} = $1;
 503         }
 504     }
 505     return $self;
 506 }
 507
 508 {
 509     # Mask out the bits that L<warnings::register> uses
 510     my $WARN_MASK;
 511     BEGIN {
 512         $WARN_MASK = $warnings::Bits{all} | $warnings::DeadBits{all};
 513     }
 514     sub WARN_MASK () {
 515         return $WARN_MASK;
 516     }
 517 }
 518
 519 # Initialise the contextual information, either from
 520 # defaults provided with the ambient_pragmas method,
 521 # or from perl's own defaults otherwise.
 522 sub init {
 523     my $self = shift;
 524
 525     $self->{'arybase'}  = $self->{'ambient_arybase'};
 526     $self->{'warnings'} = defined ($self->{'ambient_warnings'})
 527                                 ? $self->{'ambient_warnings'} & WARN_MASK
 528                                 : undef;
 529     $self->{'hints'}    = $self->{'ambient_hints'} & 0xFF;
 530
 531     # also a convenient place to clear out subs_declared
 532     delete $self->{'subs_declared'};
 533 }
 534
 535 sub compile {
 536     my(@args) = @_;
 537     return sub {
 538         my $self = B::Deparse->new(@args);
 539         # First deparse command-line args
 540         if (defined $^I) { # deparse -i
 541             print q(BEGIN { $^I = ).cstring($^I).qq(; }\n);
 542         }
 543         if ($^W) { # deparse -w
 544             print qq(BEGIN { \$^W = $^W; }\n);
 545         }
 546         if ($/ ne "\n" or defined $O::savebackslash) { # deparse -l and -0
 547             my $fs = cstring($/) || 'undef';
 548             my $bs = cstring($O::savebackslash) || 'undef';
 549             print qq(BEGIN { \$/ = $fs; \$\\ = $bs; }\n);
 550         }
 551         my @BEGINs  = B::begin_av->isa("B::AV") ? B::begin_av->ARRAY : ();
 552         my @INITs   = B::init_av->isa("B::AV") ? B::init_av->ARRAY : ();
 553         my @ENDs    = B::end_av->isa("B::AV") ? B::end_av->ARRAY : ();
 554         for my $block (@BEGINs, @INITs, @ENDs) {
 555             $self->todo($block, 0);
 556         }
 557         $self->stash_subs();
 558         $self->{'curcv'} = main_cv;
 559         $self->{'curcvlex'} = undef;
 560         print $self->print_protos;
 561         @{$self->{'subs_todo'}} =
 562           sort {$a->[0] <=> $b->[0]} @{$self->{'subs_todo'}};
 563         print $self->indent($self->deparse(main_root, 0)), "\n"
 564           unless null main_root;
 565         my @text;
 566         while (scalar(@{$self->{'subs_todo'}})) {
 567             push @text, $self->next_todo;
 568         }
 569         print $self->indent(join("", @text)), "\n" if @text;
 570
 571         # Print __DATA__ section, if necessary
 572         no strict 'refs';
 573         my $laststash = defined $self->{'curcop'}
 574             ? $self->{'curcop'}->stash->NAME : $self->{'curstash'};
 575         if (defined *{$laststash."::DATA"}{IO}) {
 576             print "__DATA__\n";
 577             print readline(*{$laststash."::DATA"});
 578         }
 579     }
 580 }
 581
 582 sub coderef2text {
 583     my $self = shift;
 584     my $sub = shift;
 585     croak "Usage: ->coderef2text(CODEREF)" unless ref($sub) eq "CODE";
 586
 587     $self->init();
 588     return $self->indent($self->deparse_sub(svref_2object($sub)));
 589 }
 590
 591 sub ambient_pragmas {
 592     my $self = shift;
 593     my ($arybase, $hint_bits, $warning_bits) = (0, 0);
 594
 595     while (@_ > 1) {
 596         my $name = shift();
 597         my $val  = shift();
 598
 599         if ($name eq 'strict') {
 600             require strict;
 601
 602             if ($val eq 'none') {
 603                 $hint_bits &= ~strict::bits(qw/refs subs vars/);
 604                 next();
 605             }
 606
 607             my @names;
 608             if ($val eq "all") {
 609                 @names = qw/refs subs vars/;
 610             }
 611             elsif (ref $val) {
 612                 @names = @$val;
 613             }
 614             else {
 615                 @names = split' ', $val;
 616             }
 617             $hint_bits |= strict::bits(@names);
 618         }
 619
 620         elsif ($name eq '$[') {
 621             $arybase = $val;
 622         }
 623
 624         elsif ($name eq 'integer'
 625             || $name eq 'bytes'
 626             || $name eq 'utf8') {
 627             require "$name.pm";
 628             if ($val) {
 629                 $hint_bits |= ${$::{"${name}::"}{"hint_bits"}};
 630             }
 631             else {
 632                 $hint_bits &= ~${$::{"${name}::"}{"hint_bits"}};
 633             }
 634         }
 635
 636         elsif ($name eq 're') {
 637             require re;
 638             if ($val eq 'none') {
 639                 $hint_bits &= ~re::bits(qw/taint eval/);
 640                 next();
 641             }
 642
 643             my @names;
 644             if ($val eq 'all') {
 645                 @names = qw/taint eval/;
 646             }
 647             elsif (ref $val) {
 648                 @names = @$val;
 649             }
 650             else {
 651                 @names = split' ',$val;
 652             }
 653             $hint_bits |= re::bits(@names);
 654         }
 655
 656         elsif ($name eq 'warnings') {
 657             if ($val eq 'none') {
 658                 $warning_bits = $warnings::NONE;
 659                 next();
 660             }
 661
 662             my @names;
 663             if (ref $val) {
 664                 @names = @$val;
 665             }
 666             else {
 667                 @names = split/\s+/, $val;
 668             }
 669
 670             $warning_bits = $warnings::NONE if !defined ($warning_bits);
 671             $warning_bits |= warnings::bits(@names);
 672         }
 673
 674         elsif ($name eq 'warning_bits') {
 675             $warning_bits = $val;
 676         }
 677
 678         elsif ($name eq 'hint_bits') {
 679             $hint_bits = $val;
 680         }
 681
 682         else {
 683             croak "Unknown pragma type: $name";
 684         }
 685     }
 686     if (@_) {
 687         croak "The ambient_pragmas method expects an even number of args";
 688     }
 689
 690     $self->{'ambient_arybase'} = $arybase;
 691     $self->{'ambient_warnings'} = $warning_bits;
 692     $self->{'ambient_hints'} = $hint_bits;
 693 }
 694
 695 sub deparse {
 696     my $self = shift;
 697     my($op, $cx, $flags) = @_;
 698
 699     Carp::confess("Null op in deparse") if !defined($op)
 700                                         || class($op) eq "NULL";
 701     my $meth = "pp_" . $op->name;
 702     if (is_scope($op)) {
 703         return $self->$meth($op, $cx, $flags);
 704     }
 705     return $self->$meth($op, $cx);
 706 }
 707
 708 sub indent {
 709     my $self = shift;
 710     my $txt = shift;
 711     my @lines = split(/\n/, $txt);
 712     my $leader = "";
 713     my $level = 0;
 714     my $line;
 715     for $line (@lines) {
 716         my $cmd = substr($line, 0, 1);
 717         if ($cmd eq "\t" or $cmd eq "\b") {
 718             $level += ($cmd eq "\t" ? 1 : -1) * $self->{'indent_size'};
 719             if ($self->{'use_tabs'}) {
 720                 $leader = "\t" x ($level / 8) . " " x ($level % 8);
 721             } else {
 722                 $leader = " " x $level;
 723             }
 724             $line = substr($line, 1);
 725         }
 726         if (substr($line, 0, 1) eq "\f") {
 727             $line = substr($line, 1); # no indent
 728         } else {
 729             $line = $leader . $line;
 730         }
 731         $line =~ s/\cK;?//g;
 732     }
 733     return join("\n", @lines);
 734 }
 735
 736 sub deparse_sub {
 737     my $self = shift;
 738     my $cv = shift;
 739     my $proto = "";
 740 Carp::confess("NULL in deparse_sub") if !defined($cv) || $cv->isa("B::NULL");
 741 Carp::confess("SPECIAL in deparse_sub") if $cv->isa("B::SPECIAL");
 742     local $self->{'curcop'} = $self->{'curcop'};
 743     if ($cv->FLAGS & SVf_POK) {
 744         $proto = "(". $cv->PV . ") ";
 745     }
 746     if ($cv->CvFLAGS & (CVf_METHOD|CVf_LOCKED|CVf_LVALUE)) {
 747         $proto .= ": ";
 748         $proto .= "lvalue " if $cv->CvFLAGS & CVf_LVALUE;
 749         $proto .= "locked " if $cv->CvFLAGS & CVf_LOCKED;
 750         $proto .= "method " if $cv->CvFLAGS & CVf_METHOD;
 751     }
 752
 753     local($self->{'curcv'}) = $cv;
 754     local($self->{'curcvlex'});
 755     local(@$self{qw'curstash warnings hints'})
 756                 = @$self{qw'curstash warnings hints'};
 757     my $body;
 758     if (not null $cv->ROOT) {
 759         my $lineseq = $cv->ROOT->first;
 760         if ($lineseq->name eq "lineseq") {
 761             my @ops;
 762             for(my$o=$lineseq->first; $$o; $o=$o->sibling) {
 763                 push @ops, $o;
 764             }
 765             $body = $self->lineseq(undef, @ops).";";
 766             my $scope_en = $self->find_scope_en($lineseq);
 767             if (defined $scope_en) {
 768                 my $subs = join"", $self->seq_subs($scope_en);
 769                 $body .= ";\n$subs" if length($subs);
 770             }
 771         }
 772         else {
 773             $body = $self->deparse($cv->ROOT->first, 0);
 774         }
 775     }
 776     else {
 777         my $sv = $cv->const_sv;
 778         if ($$sv) {
 779             # uh-oh. inlinable sub... format it differently
 780             return $proto . "{ " . const($sv) . " }\n";
 781         } else { # XSUB? (or just a declaration)
 782             return "$proto;\n";
 783         }
 784     }
 785     return $proto ."{\n\t$body\n\b}" ."\n";
 786 }
 787
 788 sub deparse_format {
 789     my $self = shift;
 790     my $form = shift;
 791     my @text;
 792     local($self->{'curcv'}) = $form;
 793     local($self->{'curcvlex'});
 794     local($self->{'in_format'}) = 1;
 795     local(@$self{qw'curstash warnings hints'})
 796                 = @$self{qw'curstash warnings hints'};
 797     my $op = $form->ROOT;
 798     my $kid;
 799     return "\f." if $op->first->name eq 'stub'
 800                 || $op->first->name eq 'nextstate';
 801     $op = $op->first->first; # skip leavewrite, lineseq
 802     while (not null $op) {
 803         $op = $op->sibling; # skip nextstate
 804         my @exprs;
 805         $kid = $op->first->sibling; # skip pushmark
 806         push @text, "\f".$self->const_sv($kid)->PV;
 807         $kid = $kid->sibling;
 808         for (; not null $kid; $kid = $kid->sibling) {
 809             push @exprs, $self->deparse($kid, 0);
 810         }
 811         push @text, "\f".join(", ", @exprs)."\n" if @exprs;
 812         $op = $op->sibling;
 813     }
 814     return join("", @text) . "\f.";
 815 }
 816
 817 sub is_scope {
 818     my $op = shift;
 819     return $op->name eq "leave" || $op->name eq "scope"
 820       || $op->name eq "lineseq"
 821         || ($op->name eq "null" && class($op) eq "UNOP"
 822             && (is_scope($op->first) || $op->first->name eq "enter"));
 823 }
 824
 825 sub is_state {
 826     my $name = $_[0]->name;
 827     return $name eq "nextstate" || $name eq "dbstate" || $name eq "setstate";
 828 }
 829
 830 sub is_miniwhile { # check for one-line loop (`foo() while $y--')
 831     my $op = shift;
 832     return (!null($op) and null($op->sibling)
 833             and $op->name eq "null" and class($op) eq "UNOP"
 834             and (($op->first->name =~ /^(and|or)$/
 835                   and $op->first->first->sibling->name eq "lineseq")
 836                  or ($op->first->name eq "lineseq"
 837                      and not null $op->first->first->sibling
 838                      and $op->first->first->sibling->name eq "unstack")
 839                  ));
 840 }
 841
 842 sub is_scalar {
 843     my $op = shift;
 844     return ($op->name eq "rv2sv" or
 845             $op->name eq "padsv" or
 846             $op->name eq "gv" or # only in array/hash constructs
 847             $op->flags & OPf_KIDS && !null($op->first)
 848               && $op->first->name eq "gvsv");
 849 }
 850
 851 sub maybe_parens {
 852     my $self = shift;
 853     my($text, $cx, $prec) = @_;
 854     if ($prec < $cx              # unary ops nest just fine
 855         or $prec == $cx and $cx != 4 and $cx != 16 and $cx != 21
 856         or $self->{'parens'})
 857     {
 858         $text = "($text)";
 859         # In a unop, let parent reuse our parens; see maybe_parens_unop
 860         $text = "\cS" . $text if $cx == 16;
 861         return $text;
 862     } else {
 863         return $text;
 864     }
 865 }
 866
 867 # same as above, but get around the `if it looks like a function' rule
 868 sub maybe_parens_unop {
 869     my $self = shift;
 870     my($name, $kid, $cx) = @_;
 871     if ($cx > 16 or $self->{'parens'}) {
 872         $kid =  $self->deparse($kid, 1);
 873         if ($name eq "umask" && $kid =~ /^\d+$/) {
 874             $kid = sprintf("%#o", $kid);
 875         }
 876         return "$name($kid)";
 877     } else {
 878         $kid = $self->deparse($kid, 16);
 879         if ($name eq "umask" && $kid =~ /^\d+$/) {
 880             $kid = sprintf("%#o", $kid);
 881         }
 882         if (substr($kid, 0, 1) eq "\cS") {
 883             # use kid's parens
 884             return $name . substr($kid, 1);
 885         } elsif (substr($kid, 0, 1) eq "(") {
 886             # avoid looks-like-a-function trap with extra parens
 887             # (`+' can lead to ambiguities)
 888             return "$name(" . $kid  . ")";
 889         } else {
 890             return "$name $kid";
 891         }
 892     }
 893 }
 894
 895 sub maybe_parens_func {
 896     my $self = shift;
 897     my($func, $text, $cx, $prec) = @_;
 898     if ($prec <= $cx or substr($text, 0, 1) eq "(" or $self->{'parens'}) {
 899         return "$func($text)";
 900     } else {
 901         return "$func $text";
 902     }
 903 }
 904
 905 sub maybe_local {
 906     my $self = shift;
 907     my($op, $cx, $text) = @_;
 908     my $our_intro = ($op->name =~ /^(gv|rv2)[ash]v$/) ? OPpOUR_INTRO : 0;
 909     if ($op->private & (OPpLVAL_INTRO|$our_intro)
 910         and not $self->{'avoid_local'}{$$op}) {
 911         my $our_local = ($op->private & OPpLVAL_INTRO) ? "local" : "our";
 912         if (want_scalar($op)) {
 913             return "$our_local $text";
 914         } else {
 915             return $self->maybe_parens_func("$our_local", $text, $cx, 16);
 916         }
 917     } else {
 918         return $text;
 919     }
 920 }
 921
 922 sub maybe_targmy {
 923     my $self = shift;
 924     my($op, $cx, $func, @args) = @_;
 925     if ($op->private & OPpTARGET_MY) {
 926         my $var = $self->padname($op->targ);
 927         my $val = $func->($self, $op, 7, @args);
 928         return $self->maybe_parens("$var = $val", $cx, 7);
 929     } else {
 930         return $func->($self, $op, $cx, @args);
 931     }
 932 }
 933
 934 sub padname_sv {
 935     my $self = shift;
 936     my $targ = shift;
 937     return (($self->{'curcv'}->PADLIST->ARRAY)[0]->ARRAY)[$targ];
 938 }
 939
 940 sub maybe_my {
 941     my $self = shift;
 942     my($op, $cx, $text) = @_;
 943     if ($op->private & OPpLVAL_INTRO and not $self->{'avoid_local'}{$$op}) {
 944         if (want_scalar($op)) {
 945             return "my $text";
 946         } else {
 947             return $self->maybe_parens_func("my", $text, $cx, 16);
 948         }
 949     } else {
 950         return $text;
 951     }
 952 }
 953
 954 # The following OPs don't have functions:
 955
 956 # pp_padany -- does not exist after parsing
 957
 958 sub AUTOLOAD {
 959     if ($AUTOLOAD =~ s/^.*::pp_//) {
 960         warn "unexpected OP_".uc $AUTOLOAD;
 961         return "XXX";
 962     } else {
 963         die "Undefined subroutine $AUTOLOAD called";
 964     }
 965 }
 966
 967 # $root should be the op which represents the root of whatever
 968 # we're sequencing here. If it's undefined, then we don't append
 969 # any subroutine declarations to the deparsed ops, otherwise we
 970 # append appropriate declarations.
 971 sub lineseq {
 972     my($self, $root, @ops) = @_;
 973     my($expr, @exprs);
 974
 975     my $out_cop = $self->{'curcop'};
 976     my $out_seq = defined($out_cop) ? $out_cop->cop_seq : undef;
 977     my $limit_seq;
 978     if (defined $root) {
 979         $limit_seq = $out_seq;
 980         my $nseq = $self->find_scope_st($root->sibling) if ${$root->sibling};
 981         $limit_seq = $nseq if !defined($limit_seq)
 982                            or defined($nseq) && $nseq < $limit_seq;
 983     }
 984     $limit_seq = $self->{'limit_seq'}
 985         if defined($self->{'limit_seq'})
 986         && (!defined($limit_seq) || $self->{'limit_seq'} < $limit_seq);
 987     local $self->{'limit_seq'} = $limit_seq;
 988     for (my $i = 0; $i < @ops; $i++) {
 989         $expr = "";
 990         if (is_state $ops[$i]) {
 991             $expr = $self->deparse($ops[$i], 0);
 992             $i++;
 993             if ($i > $#ops) {
 994                 push @exprs, $expr;
 995                 last;
 996             }
 997         }
 998         if (!is_state $ops[$i] and (my $ls = $ops[$i+1]) and
 999             !null($ops[$i+1]) and $ops[$i+1]->name eq "lineseq")
1000         {
1001             if ($ls->first && !null($ls->first) && is_state($ls->first)
1002                 && (my $sib = $ls->first->sibling)) {
1003                 if (!null($sib) && $sib->name eq "leaveloop") {
1004                     push @exprs, $expr . $self->for_loop($ops[$i], 0);
1005                     $i++;
1006                     next;
1007                 }
1008             }
1009         }
1010         $expr .= $self->deparse($ops[$i], 0, (@ops != 1));
1011         $expr =~ s/;\n?\z//;
1012         push @exprs, $expr;
1013     }
1014     my $body = join(";\n", grep {length} @exprs);
1015     my $subs = "";
1016     if (defined $root && defined $limit_seq && !$self->{'in_format'}) {
1017         $subs = join "\n", $self->seq_subs($limit_seq);
1018     }
1019     return join(";\n", grep {length} $body, $subs);
1020 }
1021
1022 sub scopeop {
1023     my($real_block, $self, $op, $cx, $flags) = @_;
1024     my $kid;
1025     my @kids;
1026
1027     local(@$self{qw'curstash warnings hints'})
1028                 = @$self{qw'curstash warnings hints'} if $real_block;
1029     if ($real_block) {
1030         $kid = $op->first->sibling; # skip enter
1031         if (is_miniwhile($kid)) {
1032             my $top = $kid->first;
1033             my $name = $top->name;
1034             if ($name eq "and") {
1035                 $name = "while";
1036             } elsif ($name eq "or") {
1037                 $name = "until";
1038             } else { # no conditional -> while 1 or until 0
1039                 return $self->deparse($top->first, 1) . " while 1";
1040             }
1041             my $cond = $top->first;
1042             my $body = $cond->sibling->first; # skip lineseq
1043             $cond = $self->deparse($cond, 1);
1044             $body = $self->deparse($body, 1);
1045             return "$body $name $cond";
1046         }
1047     } else {
1048         $kid = $op->first;
1049     }
1050     for (; !null($kid); $kid = $kid->sibling) {
1051         push @kids, $kid;
1052     }
1053     if ($flags || $cx > 0) { # inside an expression, (a do {} while for lineseq)
1054         return "do {\n\t" . $self->lineseq($op, @kids) . "\n\b}";
1055     } else {
1056         my $lineseq = $self->lineseq($op, @kids);
1057         return (length ($lineseq) ? "$lineseq;" : "");
1058     }
1059 }
1060
1061 sub pp_scope { scopeop(0, @_); }
1062 sub pp_lineseq { scopeop(0, @_); }
1063 sub pp_leave { scopeop(1, @_); }
1064
1065 # The BEGIN {} is used here because otherwise this code isn't executed
1066 # when you run B::Deparse on itself.
1067 my %globalnames;
1068 BEGIN { map($globalnames{$_}++, "SIG", "STDIN", "STDOUT", "STDERR", "INC",
1069             "ENV", "ARGV", "ARGVOUT", "_"); }
1070
1071 sub gv_name {
1072     my $self = shift;
1073     my $gv = shift;
1074 Carp::confess() if $gv->isa("B::CV");
1075     my $stash = $gv->STASH->NAME;
1076     my $name = $gv->SAFENAME;
1077     if ($stash eq $self->{'curstash'} or $globalnames{$name}
1078         or $name =~ /^[^A-Za-z_]/)
1079     {
1080         $stash = "";
1081     } else {
1082         $stash = $stash . "::";
1083     }
1084     if ($name =~ /^(\^..|{)/) {
1085         $name = "{$name}";       # ${^WARNING_BITS}, etc and ${
1086     }
1087     return $stash . $name;
1088 }
1089
1090 # Return the name to use for a stash variable.
1091 # If a lexical with the same name is in scope, it may need to be
1092 # fully-qualified.
1093 sub stash_variable {
1094     my ($self, $prefix, $name) = @_;
1095
1096     return "$prefix$name" if $name =~ /::/;
1097
1098     unless ($prefix eq '$' || $prefix eq '@' ||
1099             $prefix eq '%' || $prefix eq '$#') {
1100         return "$prefix$name";
1101     }
1102
1103     my $v = ($prefix eq '$#' ? '@' : $prefix) . $name;
1104     return $prefix .$self->{'curstash'}.'::'. $name if $self->lex_in_scope($v);
1105     return "$prefix$name";
1106 }
1107
1108 sub lex_in_scope {
1109     my ($self, $name) = @_;
1110     $self->populate_curcvlex() if !defined $self->{'curcvlex'};
1111
1112     return 0 if !defined($self->{'curcop'});
1113     my $seq = $self->{'curcop'}->cop_seq;
1114     return 0 if !exists $self->{'curcvlex'}{$name};
1115     for my $a (@{$self->{'curcvlex'}{$name}}) {
1116         my ($st, $en) = @$a;
1117         return 1 if $seq > $st && $seq <= $en;
1118     }
1119     return 0;
1120 }
1121
1122 sub populate_curcvlex {
1123     my $self = shift;
1124     for (my $cv = $self->{'curcv'}; class($cv) eq "CV"; $cv = $cv->OUTSIDE) {
1125         my @padlist = $cv->PADLIST->ARRAY;
1126         my @ns = $padlist[0]->ARRAY;
1127
1128         for (my $i=0; $i<@ns; ++$i) {
1129             next if class($ns[$i]) eq "SPECIAL";
1130             next if $ns[$i]->FLAGS & SVpad_OUR;  # Skip "our" vars
1131             if (class($ns[$i]) eq "PV") {
1132                 # Probably that pesky lexical @_
1133                 next;
1134             }
1135             my $name = $ns[$i]->PVX;
1136             my $seq_st = $ns[$i]->NVX;
1137             my $seq_en = int($ns[$i]->IVX);
1138
1139             push @{$self->{'curcvlex'}{$name}}, [$seq_st, $seq_en];
1140         }
1141     }
1142 }
1143
1144 sub find_scope_st { ((find_scope(@_))[0]); }
1145 sub find_scope_en { ((find_scope(@_))[1]); }
1146
1147 # Recurses down the tree, looking for pad variable introductions and COPs
1148 sub find_scope {
1149     my ($self, $op, $scope_st, $scope_en) = @_;
1150     carp("Undefined op in find_scope") if !defined $op;
1151     return ($scope_st, $scope_en) unless $op->flags & OPf_KIDS;
1152
1153     for (my $o=$op->first; $$o; $o=$o->sibling) {
1154         if ($o->name =~ /^pad.v$/ && $o->private & OPpLVAL_INTRO) {
1155             my $s = int($self->padname_sv($o->targ)->NVX);
1156             my $e = $self->padname_sv($o->targ)->IVX;
1157             $scope_st = $s if !defined($scope_st) || $s < $scope_st;
1158             $scope_en = $e if !defined($scope_en) || $e > $scope_en;
1159         }
1160         elsif (is_state($o)) {
1161             my $c = $o->cop_seq;
1162             $scope_st = $c if !defined($scope_st) || $c < $scope_st;
1163             $scope_en = $c if !defined($scope_en) || $c > $scope_en;
1164         }
1165         elsif ($o->flags & OPf_KIDS) {
1166             ($scope_st, $scope_en) =
1167                 $self->find_scope($o, $scope_st, $scope_en)
1168         }
1169     }
1170
1171     return ($scope_st, $scope_en);
1172 }
1173
1174 # Returns a list of subs which should be inserted before the COP
1175 sub cop_subs {
1176     my ($self, $op, $out_seq) = @_;
1177     my $seq = $op->cop_seq;
1178     # If we have nephews, then our sequence number indicates
1179     # the cop_seq of the end of some sort of scope.
1180     if (class($op->sibling) ne "NULL" && $op->sibling->flags & OPf_KIDS
1181         and my $nseq = $self->find_scope_st($op->sibling) ) {
1182         $seq = $nseq;
1183     }
1184     $seq = $out_seq if defined($out_seq) && $out_seq < $seq;
1185     return $self->seq_subs($seq);
1186 }
1187
1188 sub seq_subs {
1189     my ($self, $seq) = @_;
1190     my @text;
1191 #push @text, "# ($seq)\n";
1192
1193     return "" if !defined $seq;
1194     while (scalar(@{$self->{'subs_todo'}})
1195            and $seq > $self->{'subs_todo'}[0][0]) {
1196         push @text, $self->next_todo;
1197     }
1198     return @text;
1199 }
1200
1201 # Notice how subs and formats are inserted between statements here;
1202 # also $[ assignments and pragmas.
1203 sub pp_nextstate {
1204     my $self = shift;
1205     my($op, $cx) = @_;
1206     $self->{'curcop'} = $op;
1207     my @text;
1208     push @text, $self->cop_subs($op);
1209     push @text, $op->label . ": " if $op->label;
1210     my $stash = $op->stashpv;
1211     if ($stash ne $self->{'curstash'}) {
1212         push @text, "package $stash;\n";
1213         $self->{'curstash'} = $stash;
1214     }
1215     if ($self->{'linenums'}) {
1216         push @text, "\f#line " . $op->line .
1217           ' "' . $op->file, qq'"\n';
1218     }
1219
1220     if ($self->{'arybase'} != $op->arybase) {
1221         push @text, '$[ = '. $op->arybase .";\n";
1222         $self->{'arybase'} = $op->arybase;
1223     }
1224
1225     my $warnings = $op->warnings;
1226     my $warning_bits;
1227     if ($warnings->isa("B::SPECIAL") && $$warnings == 4) {
1228         $warning_bits = $warnings::Bits{"all"} & WARN_MASK;
1229     }
1230     elsif ($warnings->isa("B::SPECIAL") && $$warnings == 5) {
1231         $warning_bits = $warnings::NONE;
1232     }
1233     elsif ($warnings->isa("B::SPECIAL")) {
1234         $warning_bits = undef;
1235     }
1236     else {
1237         $warning_bits = $warnings->PV & WARN_MASK;
1238     }
1239
1240     if (defined ($warning_bits) and
1241        !defined($self->{warnings}) || $self->{'warnings'} ne $warning_bits) {
1242         push @text, declare_warnings($self->{'warnings'}, $warning_bits);
1243         $self->{'warnings'} = $warning_bits;
1244     }
1245
1246     if ($self->{'hints'} != $op->private) {
1247         push @text, declare_hints($self->{'hints'}, $op->private);
1248         $self->{'hints'} = $op->private;
1249     }
1250
1251     return join("", @text);
1252 }
1253
1254 sub declare_warnings {
1255     my ($from, $to) = @_;
1256     if (($to & WARN_MASK) eq warnings::bits("all")) {
1257         return "use warnings;\n";
1258     }
1259     elsif (($to & WARN_MASK) eq "\0"x length($to)) {
1260         return "no warnings;\n";
1261     }
1262     return "BEGIN {\${^WARNING_BITS} = ".cstring($to)."}\n";
1263 }
1264
1265 sub declare_hints {
1266     my ($from, $to) = @_;
1267     my $use = $to   & ~$from;
1268     my $no  = $from & ~$to;
1269     my $decls = "";
1270     for my $pragma (hint_pragmas($use)) {
1271         $decls .= "use $pragma;\n";
1272     }
1273     for my $pragma (hint_pragmas($no)) {
1274         $decls .= "no $pragma;\n";
1275     }
1276     return $decls;
1277 }
1278
1279 sub hint_pragmas {
1280     my ($bits) = @_;
1281     my @pragmas;
1282     push @pragmas, "integer" if $bits & 0x1;
1283     push @pragmas, "strict 'refs'" if $bits & 0x2;
1284     push @pragmas, "bytes" if $bits & 0x8;
1285     return @pragmas;
1286 }
1287
1288 sub pp_dbstate { pp_nextstate(@_) }
1289 sub pp_setstate { pp_nextstate(@_) }
1290
1291 sub pp_unstack { return "" } # see also leaveloop
1292
1293 sub baseop {
1294     my $self = shift;
1295     my($op, $cx, $name) = @_;
1296     return $name;
1297 }
1298
1299 sub pp_stub {
1300     my $self = shift;
1301     my($op, $cx, $name) = @_;
1302     if ($cx) {
1303         return "()";
1304     }
1305     else {
1306         return "();";
1307     }
1308 }
1309 sub pp_wantarray { baseop(@_, "wantarray") }
1310 sub pp_fork { baseop(@_, "fork") }
1311 sub pp_wait { maybe_targmy(@_, \&baseop, "wait") }
1312 sub pp_getppid { maybe_targmy(@_, \&baseop, "getppid") }
1313 sub pp_time { maybe_targmy(@_, \&baseop, "time") }
1314 sub pp_tms { baseop(@_, "times") }
1315 sub pp_ghostent { baseop(@_, "gethostent") }
1316 sub pp_gnetent { baseop(@_, "getnetent") }
1317 sub pp_gprotoent { baseop(@_, "getprotoent") }
1318 sub pp_gservent { baseop(@_, "getservent") }
1319 sub pp_ehostent { baseop(@_, "endhostent") }
1320 sub pp_enetent { baseop(@_, "endnetent") }
1321 sub pp_eprotoent { baseop(@_, "endprotoent") }
1322 sub pp_eservent { baseop(@_, "endservent") }
1323 sub pp_gpwent { baseop(@_, "getpwent") }
1324 sub pp_spwent { baseop(@_, "setpwent") }
1325 sub pp_epwent { baseop(@_, "endpwent") }
1326 sub pp_ggrent { baseop(@_, "getgrent") }
1327 sub pp_sgrent { baseop(@_, "setgrent") }
1328 sub pp_egrent { baseop(@_, "endgrent") }
1329 sub pp_getlogin { baseop(@_, "getlogin") }
1330
1331 sub POSTFIX () { 1 }
1332
1333 # I couldn't think of a good short name, but this is the category of
1334 # symbolic unary operators with interesting precedence
1335
1336 sub pfixop {
1337     my $self = shift;
1338     my($op, $cx, $name, $prec, $flags) = (@_, 0);
1339     my $kid = $op->first;
1340     $kid = $self->deparse($kid, $prec);
1341     return $self->maybe_parens(($flags & POSTFIX) ? "$kid$name" : "$name$kid",
1342                                $cx, $prec);
1343 }
1344
1345 sub pp_preinc { pfixop(@_, "++", 23) }
1346 sub pp_predec { pfixop(@_, "--", 23) }
1347 sub pp_postinc { maybe_targmy(@_, \&pfixop, "++", 23, POSTFIX) }
1348 sub pp_postdec { maybe_targmy(@_, \&pfixop, "--", 23, POSTFIX) }
1349 sub pp_i_preinc { pfixop(@_, "++", 23) }
1350 sub pp_i_predec { pfixop(@_, "--", 23) }
1351 sub pp_i_postinc { maybe_targmy(@_, \&pfixop, "++", 23, POSTFIX) }
1352 sub pp_i_postdec { maybe_targmy(@_, \&pfixop, "--", 23, POSTFIX) }
1353 sub pp_complement { maybe_targmy(@_, \&pfixop, "~", 21) }
1354
1355 sub pp_negate { maybe_targmy(@_, \&real_negate) }
1356 sub real_negate {
1357     my $self = shift;
1358     my($op, $cx) = @_;
1359     if ($op->first->name =~ /^(i_)?negate$/) {
1360         # avoid --$x
1361         $self->pfixop($op, $cx, "-", 21.5);
1362     } else {
1363         $self->pfixop($op, $cx, "-", 21);
1364     }
1365 }
1366 sub pp_i_negate { pp_negate(@_) }
1367
1368 sub pp_not {
1369     my $self = shift;
1370     my($op, $cx) = @_;
1371     if ($cx <= 4) {
1372         $self->pfixop($op, $cx, "not ", 4);
1373     } else {
1374         $self->pfixop($op, $cx, "!", 21);
1375     }
1376 }
1377
1378 sub unop {
1379     my $self = shift;
1380     my($op, $cx, $name) = @_;
1381     my $kid;
1382     if ($op->flags & OPf_KIDS) {
1383         $kid = $op->first;
1384         if (defined prototype("CORE::$name")
1385            && prototype("CORE::$name") =~ /^;?\*/
1386            && $kid->name eq "rv2gv") {
1387             $kid = $kid->first;
1388         }
1389
1390         return $self->maybe_parens_unop($name, $kid, $cx);
1391     } else {
1392         return $name .  ($op->flags & OPf_SPECIAL ? "()" : "");
1393     }
1394 }
1395
1396 sub pp_chop { maybe_targmy(@_, \&unop, "chop") }
1397 sub pp_chomp { maybe_targmy(@_, \&unop, "chomp") }
1398 sub pp_schop { maybe_targmy(@_, \&unop, "chop") }
1399 sub pp_schomp { maybe_targmy(@_, \&unop, "chomp") }
1400 sub pp_defined { unop(@_, "defined") }
1401 sub pp_undef { unop(@_, "undef") }
1402 sub pp_study { unop(@_, "study") }
1403 sub pp_ref { unop(@_, "ref") }
1404 sub pp_pos { maybe_local(@_, unop(@_, "pos")) }
1405
1406 sub pp_sin { maybe_targmy(@_, \&unop, "sin") }
1407 sub pp_cos { maybe_targmy(@_, \&unop, "cos") }
1408 sub pp_rand { maybe_targmy(@_, \&unop, "rand") }
1409 sub pp_srand { unop(@_, "srand") }
1410 sub pp_exp { maybe_targmy(@_, \&unop, "exp") }
1411 sub pp_log { maybe_targmy(@_, \&unop, "log") }
1412 sub pp_sqrt { maybe_targmy(@_, \&unop, "sqrt") }
1413 sub pp_int { maybe_targmy(@_, \&unop, "int") }
1414 sub pp_hex { maybe_targmy(@_, \&unop, "hex") }
1415 sub pp_oct { maybe_targmy(@_, \&unop, "oct") }
1416 sub pp_abs { maybe_targmy(@_, \&unop, "abs") }
1417
1418 sub pp_length { maybe_targmy(@_, \&unop, "length") }
1419 sub pp_ord { maybe_targmy(@_, \&unop, "ord") }
1420 sub pp_chr { maybe_targmy(@_, \&unop, "chr") }
1421
1422 sub pp_each { unop(@_, "each") }
1423 sub pp_values { unop(@_, "values") }
1424 sub pp_keys { unop(@_, "keys") }
1425 sub pp_pop { unop(@_, "pop") }
1426 sub pp_shift { unop(@_, "shift") }
1427
1428 sub pp_caller { unop(@_, "caller") }
1429 sub pp_reset { unop(@_, "reset") }
1430 sub pp_exit { unop(@_, "exit") }
1431 sub pp_prototype { unop(@_, "prototype") }
1432
1433 sub pp_close { unop(@_, "close") }
1434 sub pp_fileno { unop(@_, "fileno") }
1435 sub pp_umask { unop(@_, "umask") }
1436 sub pp_untie { unop(@_, "untie") }
1437 sub pp_tied { unop(@_, "tied") }
1438 sub pp_dbmclose { unop(@_, "dbmclose") }
1439 sub pp_getc { unop(@_, "getc") }
1440 sub pp_eof { unop(@_, "eof") }
1441 sub pp_tell { unop(@_, "tell") }
1442 sub pp_getsockname { unop(@_, "getsockname") }
1443 sub pp_getpeername { unop(@_, "getpeername") }
1444
1445 sub pp_chdir { maybe_targmy(@_, \&unop, "chdir") }
1446 sub pp_chroot { maybe_targmy(@_, \&unop, "chroot") }
1447 sub pp_readlink { unop(@_, "readlink") }
1448 sub pp_rmdir { maybe_targmy(@_, \&unop, "rmdir") }
1449 sub pp_readdir { unop(@_, "readdir") }
1450 sub pp_telldir { unop(@_, "telldir") }
1451 sub pp_rewinddir { unop(@_, "rewinddir") }
1452 sub pp_closedir { unop(@_, "closedir") }
1453 sub pp_getpgrp { maybe_targmy(@_, \&unop, "getpgrp") }
1454 sub pp_localtime { unop(@_, "localtime") }
1455 sub pp_gmtime { unop(@_, "gmtime") }
1456 sub pp_alarm { unop(@_, "alarm") }
1457 sub pp_sleep { maybe_targmy(@_, \&unop, "sleep") }
1458
1459 sub pp_dofile { unop(@_, "do") }
1460 sub pp_entereval { unop(@_, "eval") }
1461
1462 sub pp_ghbyname { unop(@_, "gethostbyname") }
1463 sub pp_gnbyname { unop(@_, "getnetbyname") }
1464 sub pp_gpbyname { unop(@_, "getprotobyname") }
1465 sub pp_shostent { unop(@_, "sethostent") }
1466 sub pp_snetent { unop(@_, "setnetent") }
1467 sub pp_sprotoent { unop(@_, "setprotoent") }
1468 sub pp_sservent { unop(@_, "setservent") }
1469 sub pp_gpwnam { unop(@_, "getpwnam") }
1470 sub pp_gpwuid { unop(@_, "getpwuid") }
1471 sub pp_ggrnam { unop(@_, "getgrnam") }
1472 sub pp_ggrgid { unop(@_, "getgrgid") }
1473
1474 sub pp_lock { unop(@_, "lock") }
1475
1476 sub pp_exists {
1477     my $self = shift;
1478     my($op, $cx) = @_;
1479     my $arg;
1480     if ($op->private & OPpEXISTS_SUB) {
1481         # Checking for the existence of a subroutine
1482         return $self->maybe_parens_func("exists",
1483                                 $self->pp_rv2cv($op->first, 16), $cx, 16);
1484     }
1485     if ($op->flags & OPf_SPECIAL) {
1486         # Array element, not hash element
1487         return $self->maybe_parens_func("exists",
1488                                 $self->pp_aelem($op->first, 16), $cx, 16);
1489     }
1490     return $self->maybe_parens_func("exists", $self->pp_helem($op->first, 16),
1491                                     $cx, 16);
1492 }
1493
1494 sub pp_delete {
1495     my $self = shift;
1496     my($op, $cx) = @_;
1497     my $arg;
1498     if ($op->private & OPpSLICE) {
1499         if ($op->flags & OPf_SPECIAL) {
1500             # Deleting from an array, not a hash
1501             return $self->maybe_parens_func("delete",
1502                                         $self->pp_aslice($op->first, 16),
1503                                         $cx, 16);
1504         }
1505         return $self->maybe_parens_func("delete",
1506                                         $self->pp_hslice($op->first, 16),
1507                                         $cx, 16);
1508     } else {
1509         if ($op->flags & OPf_SPECIAL) {
1510             # Deleting from an array, not a hash
1511             return $self->maybe_parens_func("delete",
1512                                         $self->pp_aelem($op->first, 16),
1513                                         $cx, 16);
1514         }
1515         return $self->maybe_parens_func("delete",
1516                                         $self->pp_helem($op->first, 16),
1517                                         $cx, 16);
1518     }
1519 }
1520
1521 sub pp_require {
1522     my $self = shift;
1523     my($op, $cx) = @_;
1524     if (class($op) eq "UNOP" and $op->first->name eq "const"
1525         and $op->first->private & OPpCONST_BARE)
1526     {
1527         my $name = $self->const_sv($op->first)->PV;
1528         $name =~ s[/][::]g;
1529         $name =~ s/\.pm//g;
1530         return "require $name";
1531     } else {
1532         $self->unop($op, $cx, "require");
1533     }
1534 }
1535
1536 sub pp_scalar {
1537     my $self = shift;
1538     my($op, $cv) = @_;
1539     my $kid = $op->first;
1540     if (not null $kid->sibling) {
1541         # XXX Was a here-doc
1542         return $self->dquote($op);
1543     }
1544     $self->unop(@_, "scalar");
1545 }
1546
1547
1548 sub padval {
1549     my $self = shift;
1550     my $targ = shift;
1551     return (($self->{'curcv'}->PADLIST->ARRAY)[1]->ARRAY)[$targ];
1552 }
1553
1554 sub pp_refgen {
1555     my $self = shift;
1556     my($op, $cx) = @_;
1557     my $kid = $op->first;
1558     if ($kid->name eq "null") {
1559         $kid = $kid->first;
1560         if ($kid->name eq "anonlist" || $kid->name eq "anonhash") {
1561             my($pre, $post) = @{{"anonlist" => ["[","]"],
1562                                  "anonhash" => ["{","}"]}->{$kid->name}};
1563             my($expr, @exprs);
1564             $kid = $kid->first->sibling; # skip pushmark
1565             for (; !null($kid); $kid = $kid->sibling) {
1566                 $expr = $self->deparse($kid, 6);
1567                 push @exprs, $expr;
1568             }
1569             return $pre . join(", ", @exprs) . $post;
1570         } elsif (!null($kid->sibling) and
1571                  $kid->sibling->name eq "anoncode") {
1572             return "sub " .
1573                 $self->deparse_sub($self->padval($kid->sibling->targ));
1574         } elsif ($kid->name eq "pushmark") {
1575             my $sib_name = $kid->sibling->name;
1576             if ($sib_name =~ /^(pad|rv2)[ah]v$/
1577                 and not $kid->sibling->flags & OPf_REF)
1578             {
1579                 # The @a in \(@a) isn't in ref context, but only when the
1580                 # parens are there.
1581                 return "\\(" . $self->deparse($kid->sibling, 1) . ")";
1582             } elsif ($sib_name eq 'entersub') {
1583                 my $text = $self->deparse($kid->sibling, 1);
1584                 # Always show parens for \(&func()), but only with -p otherwise
1585                 $text = "($text)" if $self->{'parens'}
1586                                  or $kid->sibling->private & OPpENTERSUB_AMPER;
1587                 return "\\$text";
1588             }
1589         }
1590     }
1591     $self->pfixop($op, $cx, "\\", 20);
1592 }
1593
1594 sub pp_srefgen { pp_refgen(@_) }
1595
1596 sub pp_readline {
1597     my $self = shift;
1598     my($op, $cx) = @_;
1599     my $kid = $op->first;
1600     $kid = $kid->first if $kid->name eq "rv2gv"; # <$fh>
1601     return "<" . $self->deparse($kid, 1) . ">" if is_scalar($kid);
1602     return $self->unop($op, $cx, "readline");
1603 }
1604
1605 sub pp_rcatline {
1606     my $self = shift;
1607     my($op) = @_;
1608     return "<" . $self->gv_name($op->gv) . ">";
1609 }
1610
1611 # Unary operators that can occur as pseudo-listops inside double quotes
1612 sub dq_unop {
1613     my $self = shift;
1614     my($op, $cx, $name, $prec, $flags) = (@_, 0, 0);
1615     my $kid;
1616     if ($op->flags & OPf_KIDS) {
1617        $kid = $op->first;
1618        # If there's more than one kid, the first is an ex-pushmark.
1619        $kid = $kid->sibling if not null $kid->sibling;
1620        return $self->maybe_parens_unop($name, $kid, $cx);
1621     } else {
1622        return $name .  ($op->flags & OPf_SPECIAL ? "()" : "");
1623     }
1624 }
1625
1626 sub pp_ucfirst { dq_unop(@_, "ucfirst") }
1627 sub pp_lcfirst { dq_unop(@_, "lcfirst") }
1628 sub pp_uc { dq_unop(@_, "uc") }
1629 sub pp_lc { dq_unop(@_, "lc") }
1630 sub pp_quotemeta { maybe_targmy(@_, \&dq_unop, "quotemeta") }
1631
1632 sub loopex {
1633     my $self = shift;
1634     my ($op, $cx, $name) = @_;
1635     if (class($op) eq "PVOP") {
1636         return "$name " . $op->pv;
1637     } elsif (class($op) eq "OP") {
1638         return $name;
1639     } elsif (class($op) eq "UNOP") {
1640         # Note -- loop exits are actually exempt from the
1641         # looks-like-a-func rule, but a few extra parens won't hurt
1642         return $self->maybe_parens_unop($name, $op->first, $cx);
1643     }
1644 }
1645
1646 sub pp_last { loopex(@_, "last") }
1647 sub pp_next { loopex(@_, "next") }
1648 sub pp_redo { loopex(@_, "redo") }
1649 sub pp_goto { loopex(@_, "goto") }
1650 sub pp_dump { loopex(@_, "dump") }
1651
1652 sub ftst {
1653     my $self = shift;
1654     my($op, $cx, $name) = @_;
1655     if (class($op) eq "UNOP") {
1656         # Genuine `-X' filetests are exempt from the LLAFR, but not
1657         # l?stat(); for the sake of clarity, give'em all parens
1658         return $self->maybe_parens_unop($name, $op->first, $cx);
1659     } elsif (class($op) eq "SVOP") {
1660         return $self->maybe_parens_func($name, $self->pp_gv($op, 1), $cx, 16);
1661     } else { # I don't think baseop filetests ever survive ck_ftst, but...
1662         return $name;
1663     }
1664 }
1665
1666 sub pp_lstat { ftst(@_, "lstat") }
1667 sub pp_stat { ftst(@_, "stat") }
1668 sub pp_ftrread { ftst(@_, "-R") }
1669 sub pp_ftrwrite { ftst(@_, "-W") }
1670 sub pp_ftrexec { ftst(@_, "-X") }
1671 sub pp_fteread { ftst(@_, "-r") }
1672 sub pp_ftewrite { ftst(@_, "-w") }
1673 sub pp_fteexec { ftst(@_, "-x") }
1674 sub pp_ftis { ftst(@_, "-e") }
1675 sub pp_fteowned { ftst(@_, "-O") }
1676 sub pp_ftrowned { ftst(@_, "-o") }
1677 sub pp_ftzero { ftst(@_, "-z") }
1678 sub pp_ftsize { ftst(@_, "-s") }
1679 sub pp_ftmtime { ftst(@_, "-M") }
1680 sub pp_ftatime { ftst(@_, "-A") }
1681 sub pp_ftctime { ftst(@_, "-C") }
1682 sub pp_ftsock { ftst(@_, "-S") }
1683 sub pp_ftchr { ftst(@_, "-c") }
1684 sub pp_ftblk { ftst(@_, "-b") }
1685 sub pp_ftfile { ftst(@_, "-f") }
1686 sub pp_ftdir { ftst(@_, "-d") }
1687 sub pp_ftpipe { ftst(@_, "-p") }
1688 sub pp_ftlink { ftst(@_, "-l") }
1689 sub pp_ftsuid { ftst(@_, "-u") }
1690 sub pp_ftsgid { ftst(@_, "-g") }
1691 sub pp_ftsvtx { ftst(@_, "-k") }
1692 sub pp_fttty { ftst(@_, "-t") }
1693 sub pp_fttext { ftst(@_, "-T") }
1694 sub pp_ftbinary { ftst(@_, "-B") }
1695
1696 sub SWAP_CHILDREN () { 1 }
1697 sub ASSIGN () { 2 } # has OP= variant
1698 sub LIST_CONTEXT () { 4 } # Assignment is in list context
1699
1700 my(%left, %right);
1701
1702 sub assoc_class {
1703     my $op = shift;
1704     my $name = $op->name;
1705     if ($name eq "concat" and $op->first->name eq "concat") {
1706         # avoid spurious `=' -- see comment in pp_concat
1707         return "concat";
1708     }
1709     if ($name eq "null" and class($op) eq "UNOP"
1710         and $op->first->name =~ /^(and|x?or)$/
1711         and null $op->first->sibling)
1712     {
1713         # Like all conditional constructs, OP_ANDs and OP_ORs are topped
1714         # with a null that's used as the common end point of the two
1715         # flows of control. For precedence purposes, ignore it.
1716         # (COND_EXPRs have these too, but we don't bother with
1717         # their associativity).
1718         return assoc_class($op->first);
1719     }
1720     return $name . ($op->flags & OPf_STACKED ? "=" : "");
1721 }
1722
1723 # Left associative operators, like `+', for which
1724 # $a + $b + $c is equivalent to ($a + $b) + $c
1725
1726 BEGIN {
1727     %left = ('multiply' => 19, 'i_multiply' => 19,
1728              'divide' => 19, 'i_divide' => 19,
1729              'modulo' => 19, 'i_modulo' => 19,
1730              'repeat' => 19,
1731              'add' => 18, 'i_add' => 18,
1732              'subtract' => 18, 'i_subtract' => 18,
1733              'concat' => 18,
1734              'left_shift' => 17, 'right_shift' => 17,
1735              'bit_and' => 13,
1736              'bit_or' => 12, 'bit_xor' => 12,
1737              'and' => 3,
1738              'or' => 2, 'xor' => 2,
1739             );
1740 }
1741
1742 sub deparse_binop_left {
1743     my $self = shift;
1744     my($op, $left, $prec) = @_;
1745     if ($left{assoc_class($op)} && $left{assoc_class($left)}
1746         and $left{assoc_class($op)} == $left{assoc_class($left)})
1747     {
1748         return $self->deparse($left, $prec - .00001);
1749     } else {
1750         return $self->deparse($left, $prec);
1751     }
1752 }
1753
1754 # Right associative operators, like `=', for which
1755 # $a = $b = $c is equivalent to $a = ($b = $c)
1756
1757 BEGIN {
1758     %right = ('pow' => 22,
1759               'sassign=' => 7, 'aassign=' => 7,
1760               'multiply=' => 7, 'i_multiply=' => 7,
1761               'divide=' => 7, 'i_divide=' => 7,
1762               'modulo=' => 7, 'i_modulo=' => 7,
1763               'repeat=' => 7,
1764               'add=' => 7, 'i_add=' => 7,
1765               'subtract=' => 7, 'i_subtract=' => 7,
1766               'concat=' => 7,
1767               'left_shift=' => 7, 'right_shift=' => 7,
1768               'bit_and=' => 7,
1769               'bit_or=' => 7, 'bit_xor=' => 7,
1770               'andassign' => 7,
1771               'orassign' => 7,
1772              );
1773 }
1774
1775 sub deparse_binop_right {
1776     my $self = shift;
1777     my($op, $right, $prec) = @_;
1778     if ($right{assoc_class($op)} && $right{assoc_class($right)}
1779         and $right{assoc_class($op)} == $right{assoc_class($right)})
1780     {
1781         return $self->deparse($right, $prec - .00001);
1782     } else {
1783         return $self->deparse($right, $prec);
1784     }
1785 }
1786
1787 sub binop {
1788     my $self = shift;
1789     my ($op, $cx, $opname, $prec, $flags) = (@_, 0);
1790     my $left = $op->first;
1791     my $right = $op->last;
1792     my $eq = "";
1793     if ($op->flags & OPf_STACKED && $flags & ASSIGN) {
1794         $eq = "=";
1795         $prec = 7;
1796     }
1797     if ($flags & SWAP_CHILDREN) {
1798         ($left, $right) = ($right, $left);
1799     }
1800     $left = $self->deparse_binop_left($op, $left, $prec);
1801     $left = "($left)" if $flags & LIST_CONTEXT
1802                 && $left !~ /^(my|our|local|)[\@\(]/;
1803     $right = $self->deparse_binop_right($op, $right, $prec);
1804     return $self->maybe_parens("$left $opname$eq $right", $cx, $prec);
1805 }
1806
1807 sub pp_add { maybe_targmy(@_, \&binop, "+", 18, ASSIGN) }
1808 sub pp_multiply { maybe_targmy(@_, \&binop, "*", 19, ASSIGN) }
1809 sub pp_subtract { maybe_targmy(@_, \&binop, "-",18,  ASSIGN) }
1810 sub pp_divide { maybe_targmy(@_, \&binop, "/", 19, ASSIGN) }
1811 sub pp_modulo { maybe_targmy(@_, \&binop, "%", 19, ASSIGN) }
1812 sub pp_i_add { maybe_targmy(@_, \&binop, "+", 18, ASSIGN) }
1813 sub pp_i_multiply { maybe_targmy(@_, \&binop, "*", 19, ASSIGN) }
1814 sub pp_i_subtract { maybe_targmy(@_, \&binop, "-", 18, ASSIGN) }
1815 sub pp_i_divide { maybe_targmy(@_, \&binop, "/", 19, ASSIGN) }
1816 sub pp_i_modulo { maybe_targmy(@_, \&binop, "%", 19, ASSIGN) }
1817 sub pp_pow { maybe_targmy(@_, \&binop, "**", 22, ASSIGN) }
1818
1819 sub pp_left_shift { maybe_targmy(@_, \&binop, "<<", 17, ASSIGN) }
1820 sub pp_right_shift { maybe_targmy(@_, \&binop, ">>", 17, ASSIGN) }
1821 sub pp_bit_and { maybe_targmy(@_, \&binop, "&", 13, ASSIGN) }
1822 sub pp_bit_or { maybe_targmy(@_, \&binop, "|", 12, ASSIGN) }
1823 sub pp_bit_xor { maybe_targmy(@_, \&binop, "^", 12, ASSIGN) }
1824
1825 sub pp_eq { binop(@_, "==", 14) }
1826 sub pp_ne { binop(@_, "!=", 14) }
1827 sub pp_lt { binop(@_, "<", 15) }
1828 sub pp_gt { binop(@_, ">", 15) }
1829 sub pp_ge { binop(@_, ">=", 15) }
1830 sub pp_le { binop(@_, "<=", 15) }
1831 sub pp_ncmp { binop(@_, "<=>", 14) }
1832 sub pp_i_eq { binop(@_, "==", 14) }
1833 sub pp_i_ne { binop(@_, "!=", 14) }
1834 sub pp_i_lt { binop(@_, "<", 15) }
1835 sub pp_i_gt { binop(@_, ">", 15) }
1836 sub pp_i_ge { binop(@_, ">=", 15) }
1837 sub pp_i_le { binop(@_, "<=", 15) }
1838 sub pp_i_ncmp { binop(@_, "<=>", 14) }
1839
1840 sub pp_seq { binop(@_, "eq", 14) }
1841 sub pp_sne { binop(@_, "ne", 14) }
1842 sub pp_slt { binop(@_, "lt", 15) }
1843 sub pp_sgt { binop(@_, "gt", 15) }
1844 sub pp_sge { binop(@_, "ge", 15) }
1845 sub pp_sle { binop(@_, "le", 15) }
1846 sub pp_scmp { binop(@_, "cmp", 14) }
1847
1848 sub pp_sassign { binop(@_, "=", 7, SWAP_CHILDREN) }
1849 sub pp_aassign { binop(@_, "=", 7, SWAP_CHILDREN | LIST_CONTEXT) }
1850
1851 # `.' is special because concats-of-concats are optimized to save copying
1852 # by making all but the first concat stacked. The effect is as if the
1853 # programmer had written `($a . $b) .= $c', except legal.
1854 sub pp_concat { maybe_targmy(@_, \&real_concat) }
1855 sub real_concat {
1856     my $self = shift;
1857     my($op, $cx) = @_;
1858     my $left = $op->first;
1859     my $right = $op->last;
1860     my $eq = "";
1861     my $prec = 18;
1862     if ($op->flags & OPf_STACKED and $op->first->name ne "concat") {
1863         $eq = "=";
1864         $prec = 7;
1865     }
1866     $left = $self->deparse_binop_left($op, $left, $prec);
1867     $right = $self->deparse_binop_right($op, $right, $prec);
1868     return $self->maybe_parens("$left .$eq $right", $cx, $prec);
1869 }
1870
1871 # `x' is weird when the left arg is a list
1872 sub pp_repeat {
1873     my $self = shift;
1874     my($op, $cx) = @_;
1875     my $left = $op->first;
1876     my $right = $op->last;
1877     my $eq = "";
1878     my $prec = 19;
1879     if ($op->flags & OPf_STACKED) {
1880         $eq = "=";
1881         $prec = 7;
1882     }
1883     if (null($right)) { # list repeat; count is inside left-side ex-list
1884         my $kid = $left->first->sibling; # skip pushmark
1885         my @exprs;
1886         for (; !null($kid->sibling); $kid = $kid->sibling) {
1887             push @exprs, $self->deparse($kid, 6);
1888         }
1889         $right = $kid;
1890         $left = "(" . join(", ", @exprs). ")";
1891     } else {
1892         $left = $self->deparse_binop_left($op, $left, $prec);
1893     }
1894     $right = $self->deparse_binop_right($op, $right, $prec);
1895     return $self->maybe_parens("$left x$eq $right", $cx, $prec);
1896 }
1897
1898 sub range {
1899     my $self = shift;
1900     my ($op, $cx, $type) = @_;
1901     my $left = $op->first;
1902     my $right = $left->sibling;
1903     $left = $self->deparse($left, 9);
1904     $right = $self->deparse($right, 9);
1905     return $self->maybe_parens("$left $type $right", $cx, 9);
1906 }
1907
1908 sub pp_flop {
1909     my $self = shift;
1910     my($op, $cx) = @_;
1911     my $flip = $op->first;
1912     my $type = ($flip->flags & OPf_SPECIAL) ? "..." : "..";
1913     return $self->range($flip->first, $cx, $type);
1914 }
1915
1916 # one-line while/until is handled in pp_leave
1917
1918 sub logop {
1919     my $self = shift;
1920     my ($op, $cx, $lowop, $lowprec, $highop, $highprec, $blockname) = @_;
1921     my $left = $op->first;
1922     my $right = $op->first->sibling;
1923     if ($cx == 0 and is_scope($right) and $blockname
1924         and $self->{'expand'} < 7)
1925     { # if ($a) {$b}
1926         $left = $self->deparse($left, 1);
1927         $right = $self->deparse($right, 0);
1928         return "$blockname ($left) {\n\t$right\n\b}\cK";
1929     } elsif ($cx == 0 and $blockname and not $self->{'parens'}
1930              and $self->{'expand'} < 7) { # $b if $a
1931         $right = $self->deparse($right, 1);
1932         $left = $self->deparse($left, 1);
1933         return "$right $blockname $left";
1934     } elsif ($cx > $lowprec and $highop) { # $a && $b
1935         $left = $self->deparse_binop_left($op, $left, $highprec);
1936         $right = $self->deparse_binop_right($op, $right, $highprec);
1937         return $self->maybe_parens("$left $highop $right", $cx, $highprec);
1938     } else { # $a and $b
1939         $left = $self->deparse_binop_left($op, $left, $lowprec);
1940         $right = $self->deparse_binop_right($op, $right, $lowprec);
1941         return $self->maybe_parens("$left $lowop $right", $cx, $lowprec);
1942     }
1943 }
1944
1945 sub pp_and { logop(@_, "and", 3, "&&", 11, "if") }
1946 sub pp_or  { logop(@_, "or",  2, "||", 10, "unless") }
1947
1948 # xor is syntactically a logop, but it's really a binop (contrary to
1949 # old versions of opcode.pl). Syntax is what matters here.
1950 sub pp_xor { logop(@_, "xor", 2, "",   0,  "") }
1951
1952 sub logassignop {
1953     my $self = shift;
1954     my ($op, $cx, $opname) = @_;
1955     my $left = $op->first;
1956     my $right = $op->first->sibling->first; # skip sassign
1957     $left = $self->deparse($left, 7);
1958     $right = $self->deparse($right, 7);
1959     return $self->maybe_parens("$left $opname $right", $cx, 7);
1960 }
1961
1962 sub pp_andassign { logassignop(@_, "&&=") }
1963 sub pp_orassign { logassignop(@_, "||=") }
1964
1965 sub listop {
1966     my $self = shift;
1967     my($op, $cx, $name) = @_;
1968     my(@exprs);
1969     my $parens = ($cx >= 5) || $self->{'parens'};
1970     my $kid = $op->first->sibling;
1971     return $name if null $kid;
1972     my $first;
1973     $name = "socketpair" if $name eq "sockpair";
1974     if (defined prototype("CORE::$name")
1975         && prototype("CORE::$name") =~ /^;?\*/
1976         && $kid->name eq "rv2gv") {
1977         $first = $self->deparse($kid->first, 6);
1978     }
1979     else {
1980         $first = $self->deparse($kid, 6);
1981     }
1982     if ($name eq "chmod" && $first =~ /^\d+$/) {
1983         $first = sprintf("%#o", $first);
1984     }
1985     $first = "+$first" if not $parens and substr($first, 0, 1) eq "(";
1986     push @exprs, $first;
1987     $kid = $kid->sibling;
1988     for (; !null($kid); $kid = $kid->sibling) {
1989         push @exprs, $self->deparse($kid, 6);
1990     }
1991     if ($parens) {
1992         return "$name(" . join(", ", @exprs) . ")";
1993     } else {
1994         return "$name " . join(", ", @exprs);
1995     }
1996 }
1997
1998 sub pp_bless { listop(@_, "bless") }
1999 sub pp_atan2 { maybe_targmy(@_, \&listop, "atan2") }
2000 sub pp_substr { maybe_local(@_, listop(@_, "substr")) }
2001 sub pp_vec { maybe_local(@_, listop(@_, "vec")) }
2002 sub pp_index { maybe_targmy(@_, \&listop, "index") }
2003 sub pp_rindex { maybe_targmy(@_, \&listop, "rindex") }
2004 sub pp_sprintf { maybe_targmy(@_, \&listop, "sprintf") }
2005 sub pp_formline { listop(@_, "formline") } # see also deparse_format
2006 sub pp_crypt { maybe_targmy(@_, \&listop, "crypt") }
2007 sub pp_unpack { listop(@_, "unpack") }
2008 sub pp_pack { listop(@_, "pack") }
2009 sub pp_join { maybe_targmy(@_, \&listop, "join") }
2010 sub pp_splice { listop(@_, "splice") }
2011 sub pp_push { maybe_targmy(@_, \&listop, "push") }
2012 sub pp_unshift { maybe_targmy(@_, \&listop, "unshift") }
2013 sub pp_reverse { listop(@_, "reverse") }
2014 sub pp_warn { listop(@_, "warn") }
2015 sub pp_die { listop(@_, "die") }
2016 # Actually, return is exempt from the LLAFR (see examples in this very
2017 # module!), but for consistency's sake, ignore that fact
2018 sub pp_return { listop(@_, "return") }
2019 sub pp_open { listop(@_, "open") }
2020 sub pp_pipe_op { listop(@_, "pipe") }
2021 sub pp_tie { listop(@_, "tie") }
2022 sub pp_binmode { listop(@_, "binmode") }
2023 sub pp_dbmopen { listop(@_, "dbmopen") }
2024 sub pp_sselect { listop(@_, "select") }
2025 sub pp_select { listop(@_, "select") }
2026 sub pp_read { listop(@_, "read") }
2027 sub pp_sysopen { listop(@_, "sysopen") }
2028 sub pp_sysseek { listop(@_, "sysseek") }
2029 sub pp_sysread { listop(@_, "sysread") }
2030 sub pp_syswrite { listop(@_, "syswrite") }
2031 sub pp_send { listop(@_, "send") }
2032 sub pp_recv { listop(@_, "recv") }
2033 sub pp_seek { listop(@_, "seek") }
2034 sub pp_fcntl { listop(@_, "fcntl") }
2035 sub pp_ioctl { listop(@_, "ioctl") }
2036 sub pp_flock { maybe_targmy(@_, \&listop, "flock") }
2037 sub pp_socket { listop(@_, "socket") }
2038 sub pp_sockpair { listop(@_, "sockpair") }
2039 sub pp_bind { listop(@_, "bind") }
2040 sub pp_connect { listop(@_, "connect") }
2041 sub pp_listen { listop(@_, "listen") }
2042 sub pp_accept { listop(@_, "accept") }
2043 sub pp_shutdown { listop(@_, "shutdown") }
2044 sub pp_gsockopt { listop(@_, "getsockopt") }
2045 sub pp_ssockopt { listop(@_, "setsockopt") }
2046 sub pp_chown { maybe_targmy(@_, \&listop, "chown") }
2047 sub pp_unlink { maybe_targmy(@_, \&listop, "unlink") }
2048 sub pp_chmod { maybe_targmy(@_, \&listop, "chmod") }
2049 sub pp_utime { maybe_targmy(@_, \&listop, "utime") }
2050 sub pp_rename { maybe_targmy(@_, \&listop, "rename") }
2051 sub pp_link { maybe_targmy(@_, \&listop, "link") }
2052 sub pp_symlink { maybe_targmy(@_, \&listop, "symlink") }
2053 sub pp_mkdir { maybe_targmy(@_, \&listop, "mkdir") }
2054 sub pp_open_dir { listop(@_, "opendir") }
2055 sub pp_seekdir { listop(@_, "seekdir") }
2056 sub pp_waitpid { maybe_targmy(@_, \&listop, "waitpid") }
2057 sub pp_system { maybe_targmy(@_, \&listop, "system") }
2058 sub pp_exec { maybe_targmy(@_, \&listop, "exec") }
2059 sub pp_kill { maybe_targmy(@_, \&listop, "kill") }
2060 sub pp_setpgrp { maybe_targmy(@_, \&listop, "setpgrp") }
2061 sub pp_getpriority { maybe_targmy(@_, \&listop, "getpriority") }
2062 sub pp_setpriority { maybe_targmy(@_, \&listop, "setpriority") }
2063 sub pp_shmget { listop(@_, "shmget") }
2064 sub pp_shmctl { listop(@_, "shmctl") }
2065 sub pp_shmread { listop(@_, "shmread") }
2066 sub pp_shmwrite { listop(@_, "shmwrite") }
2067 sub pp_msgget { listop(@_, "msgget") }
2068 sub pp_msgctl { listop(@_, "msgctl") }
2069 sub pp_msgsnd { listop(@_, "msgsnd") }
2070 sub pp_msgrcv { listop(@_, "msgrcv") }
2071 sub pp_semget { listop(@_, "semget") }
2072 sub pp_semctl { listop(@_, "semctl") }
2073 sub pp_semop { listop(@_, "semop") }
2074 sub pp_ghbyaddr { listop(@_, "gethostbyaddr") }
2075 sub pp_gnbyaddr { listop(@_, "getnetbyaddr") }
2076 sub pp_gpbynumber { listop(@_, "getprotobynumber") }
2077 sub pp_gsbyname { listop(@_, "getservbyname") }
2078 sub pp_gsbyport { listop(@_, "getservbyport") }
2079 sub pp_syscall { listop(@_, "syscall") }
2080
2081 sub pp_glob {
2082     my $self = shift;
2083     my($op, $cx) = @_;
2084     my $text = $self->dq($op->first->sibling);  # skip pushmark
2085     if ($text =~ /^\$?(\w|::|\`)+$/ # could look like a readline
2086         or $text =~ /[<>]/) {
2087         return 'glob(' . single_delim('qq', '"', $text) . ')';
2088     } else {
2089         return '<' . $text . '>';
2090     }
2091 }
2092
2093 # Truncate is special because OPf_SPECIAL makes a bareword first arg
2094 # be a filehandle. This could probably be better fixed in the core
2095 # by moving the GV lookup into ck_truc.
2096
2097 sub pp_truncate {
2098     my $self = shift;
2099     my($op, $cx) = @_;
2100     my(@exprs);
2101     my $parens = ($cx >= 5) || $self->{'parens'};
2102     my $kid = $op->first->sibling;
2103     my $fh;
2104     if ($op->flags & OPf_SPECIAL) {
2105         # $kid is an OP_CONST
2106         $fh = $self->const_sv($kid)->PV;
2107     } else {
2108         $fh = $self->deparse($kid, 6);
2109         $fh = "+$fh" if not $parens and substr($fh, 0, 1) eq "(";
2110     }
2111     my $len = $self->deparse($kid->sibling, 6);
2112     if ($parens) {
2113         return "truncate($fh, $len)";
2114     } else {
2115         return "truncate $fh, $len";
2116     }
2117 }
2118
2119 sub indirop {
2120     my $self = shift;
2121     my($op, $cx, $name) = @_;
2122     my($expr, @exprs);
2123     my $kid = $op->first->sibling;
2124     my $indir = "";
2125     if ($op->flags & OPf_STACKED) {
2126         $indir = $kid;
2127         $indir = $indir->first; # skip rv2gv
2128         if (is_scope($indir)) {
2129             $indir = "{" . $self->deparse($indir, 0) . "}";
2130         } elsif ($indir->name eq "const" && $indir->private & OPpCONST_BARE) {
2131             $indir = $self->const_sv($indir)->PV;
2132         } else {
2133             $indir = $self->deparse($indir, 24);
2134         }
2135         $indir = $indir . " ";
2136         $kid = $kid->sibling;
2137     }
2138     if ($name eq "sort" && $op->private & (OPpSORT_NUMERIC | OPpSORT_INTEGER)) {
2139         $indir = ($op->private & OPpSORT_REVERSE) ? '{$b <=> $a} '
2140                                                   : '{$a <=> $b} ';
2141     }
2142     elsif ($name eq "sort" && $op->private & OPpSORT_REVERSE) {
2143         $indir = '{$b cmp $a} ';
2144     }
2145     for (; !null($kid); $kid = $kid->sibling) {
2146         $expr = $self->deparse($kid, 6);
2147         push @exprs, $expr;
2148     }
2149     return $self->maybe_parens_func($name, $indir . join(", ", @exprs),
2150                                     $cx, 5);
2151 }
2152
2153 sub pp_prtf { indirop(@_, "printf") }
2154 sub pp_print { indirop(@_, "print") }
2155 sub pp_sort { indirop(@_, "sort") }
2156
2157 sub mapop {
2158     my $self = shift;
2159     my($op, $cx, $name) = @_;
2160     my($expr, @exprs);
2161     my $kid = $op->first; # this is the (map|grep)start
2162     $kid = $kid->first->sibling; # skip a pushmark
2163     my $code = $kid->first; # skip a null
2164     if (is_scope $code) {
2165         $code = "{" . $self->deparse($code, 0) . "} ";
2166     } else {
2167         $code = $self->deparse($code, 24) . ", ";
2168     }
2169     $kid = $kid->sibling;
2170     for (; !null($kid); $kid = $kid->sibling) {
2171         $expr = $self->deparse($kid, 6);
2172         push @exprs, $expr if $expr;
2173     }
2174     return $self->maybe_parens_func($name, $code . join(", ", @exprs), $cx, 5);
2175 }
2176
2177 sub pp_mapwhile { mapop(@_, "map") }
2178 sub pp_grepwhile { mapop(@_, "grep") }
2179
2180 sub pp_list {
2181     my $self = shift;
2182     my($op, $cx) = @_;
2183     my($expr, @exprs);
2184     my $kid = $op->first->sibling; # skip pushmark
2185     my $lop;
2186     my $local = "either"; # could be local(...), my(...) or our(...)
2187     for ($lop = $kid; !null($lop); $lop = $lop->sibling) {
2188         # This assumes that no other private flags equal 128, and that
2189         # OPs that store things other than flags in their op_private,
2190         # like OP_AELEMFAST, won't be immediate children of a list.
2191         #
2192         # OP_ENTERSUB can break this logic, so check for it.
2193         # I suspect that open and exit can too.
2194
2195         if (!($lop->private & (OPpLVAL_INTRO|OPpOUR_INTRO)
2196                 or $lop->name eq "undef")
2197             or $lop->name eq "entersub"
2198             or $lop->name eq "exit"
2199             or $lop->name eq "open")
2200         {
2201             $local = ""; # or not
2202             last;
2203         }
2204         if ($lop->name =~ /^pad[ash]v$/) { # my()
2205             ($local = "", last) if $local eq "local" || $local eq "our";
2206             $local = "my";
2207         } elsif ($lop->name =~ /^(gv|rv2)[ash]v$/
2208                         && $lop->private & OPpOUR_INTRO
2209                 or $lop->name eq "null" && $lop->first->name eq "gvsv"
2210                         && $lop->first->private & OPpOUR_INTRO) { # our()
2211             ($local = "", last) if $local eq "my" || $local eq "local";
2212             $local = "our";
2213         } elsif ($lop->name ne "undef") { # local()
2214             ($local = "", last) if $local eq "my" || $local eq "our";
2215             $local = "local";
2216         }
2217     }
2218     $local = "" if $local eq "either"; # no point if it's all undefs
2219     return $self->deparse($kid, $cx) if null $kid->sibling and not $local;
2220     for (; !null($kid); $kid = $kid->sibling) {
2221         if ($local) {
2222             if (class($kid) eq "UNOP" and $kid->first->name eq "gvsv") {
2223                 $lop = $kid->first;
2224             } else {
2225                 $lop = $kid;
2226             }
2227             $self->{'avoid_local'}{$$lop}++;
2228             $expr = $self->deparse($kid, 6);
2229             delete $self->{'avoid_local'}{$$lop};
2230         } else {
2231             $expr = $self->deparse($kid, 6);
2232         }
2233         push @exprs, $expr;
2234     }
2235     if ($local) {
2236         return "$local(" . join(", ", @exprs) . ")";
2237     } else {
2238         return $self->maybe_parens( join(", ", @exprs), $cx, 6);
2239     }
2240 }
2241
2242 sub is_ifelse_cont {
2243     my $op = shift;
2244     return ($op->name eq "null" and class($op) eq "UNOP"
2245             and $op->first->name =~ /^(and|cond_expr)$/
2246             and is_scope($op->first->first->sibling));
2247 }
2248
2249 sub pp_cond_expr {
2250     my $self = shift;
2251     my($op, $cx) = @_;
2252     my $cond = $op->first;
2253     my $true = $cond->sibling;
2254     my $false = $true->sibling;
2255     my $cuddle = $self->{'cuddle'};
2256     unless ($cx == 0 and (is_scope($true) and $true->name ne "null") and
2257             (is_scope($false) || is_ifelse_cont($false))
2258             and $self->{'expand'} < 7) {
2259         $cond = $self->deparse($cond, 8);
2260         $true = $self->deparse($true, 8);
2261         $false = $self->deparse($false, 8);
2262         return $self->maybe_parens("$cond ? $true : $false", $cx, 8);
2263     }
2264
2265     $cond = $self->deparse($cond, 1);
2266     $true = $self->deparse($true, 0);
2267     my $head = "if ($cond) {\n\t$true\n\b}";
2268     my @elsifs;
2269     while (!null($false) and is_ifelse_cont($false)) {
2270         my $newop = $false->first;
2271         my $newcond = $newop->first;
2272         my $newtrue = $newcond->sibling;
2273         $false = $newtrue->sibling; # last in chain is OP_AND => no else
2274         $newcond = $self->deparse($newcond, 1);
2275         $newtrue = $self->deparse($newtrue, 0);
2276         push @elsifs, "elsif ($newcond) {\n\t$newtrue\n\b}";
2277     }
2278     if (!null($false)) {
2279         $false = $cuddle . "else {\n\t" .
2280           $self->deparse($false, 0) . "\n\b}\cK";
2281     } else {
2282         $false = "\cK";
2283     }
2284     return $head . join($cuddle, "", @elsifs) . $false;
2285 }
2286
2287 sub loop_common {
2288     my $self = shift;
2289     my($op, $cx, $init) = @_;
2290     my $enter = $op->first;
2291     my $kid = $enter->sibling;
2292     local(@$self{qw'curstash warnings hints'})
2293                 = @$self{qw'curstash warnings hints'};
2294     my $head = "";
2295     my $bare = 0;
2296     my $body;
2297     my $cond = undef;
2298     if ($kid->name eq "lineseq") { # bare or infinite loop
2299         if (is_state $kid->last) { # infinite
2300             $head = "while (1) "; # Can't use for(;;) if there's a continue
2301             $cond = "";
2302         } else {
2303             $bare = 1;
2304         }
2305         $body = $kid;
2306     } elsif ($enter->name eq "enteriter") { # foreach
2307         my $ary = $enter->first->sibling; # first was pushmark
2308         my $var = $ary->sibling;
2309         if ($enter->flags & OPf_STACKED
2310             and not null $ary->first->sibling->sibling)
2311         {
2312             $ary = $self->deparse($ary->first->sibling, 9) . " .. " .
2313               $self->deparse($ary->first->sibling->sibling, 9);
2314         } else {
2315             $ary = $self->deparse($ary, 1);
2316         }
2317         if (null $var) {
2318             if ($enter->flags & OPf_SPECIAL) { # thread special var
2319                 $var = $self->pp_threadsv($enter, 1);
2320             } else { # regular my() variable
2321                 $var = $self->pp_padsv($enter, 1);
2322                 if ($self->padname_sv($enter->targ)->IVX ==
2323                     $kid->first->first->sibling->last->cop_seq)
2324                 {
2325                     # If the scope of this variable closes at the last
2326                     # statement of the loop, it must have been
2327                     # declared here.
2328                     $var = "my " . $var;
2329                 }
2330             }
2331         } elsif ($var->name eq "rv2gv") {
2332             $var = $self->pp_rv2sv($var, 1);
2333         } elsif ($var->name eq "gv") {
2334             $var = "\$" . $self->deparse($var, 1);
2335         }
2336         $head = "foreach $var ($ary) ";
2337         $body = $kid->first->first->sibling; # skip OP_AND and OP_ITER
2338     } elsif ($kid->name eq "null") { # while/until
2339         $kid = $kid->first;
2340         my $name = {"and" => "while", "or" => "until"}->{$kid->name};
2341         $cond = $self->deparse($kid->first, 1);
2342         $head = "$name ($cond) ";
2343         $body = $kid->first->sibling;
2344     } elsif ($kid->name eq "stub") { # bare and empty
2345         return "{;}"; # {} could be a hashref
2346     }
2347     # If there isn't a continue block, then the next pointer for the loop
2348     # will point to the unstack, which is kid's penultimate child, except
2349     # in a bare loop, when it will point to the leaveloop. When neither of
2350     # these conditions hold, then the third-to-last child in the continue
2351     # block (or the last in a bare loop).
2352     my $cont_start = $enter->nextop;
2353     my $cont;
2354     if ($$cont_start != $$op && ${$cont_start->sibling} != ${$body->last}) {
2355         if ($bare) {
2356             $cont = $body->last;
2357         } else {
2358             $cont = $body->first;
2359             while (!null($cont->sibling->sibling->sibling)) {
2360                 $cont = $cont->sibling;
2361             }
2362         }
2363         my $state = $body->first;
2364         my $cuddle = $self->{'cuddle'};
2365         my @states;
2366         for (; $$state != $$cont; $state = $state->sibling) {
2367             push @states, $state;
2368         }
2369         $body = $self->lineseq(undef, @states);
2370         if (defined $cond and not is_scope $cont and $self->{'expand'} < 3) {
2371             $head = "for ($init; $cond; " . $self->deparse($cont, 1) .") ";
2372             $cont = "\cK";
2373         } else {
2374             $cont = $cuddle . "continue {\n\t" .
2375               $self->deparse($cont, 0) . "\n\b}\cK";
2376         }
2377     } else {
2378         return "" if !defined $body;
2379         if (length $init) {
2380             $head = "for ($init; $cond;) ";
2381         }
2382         $cont = "\cK";
2383         $body = $self->deparse($body, 0);
2384     }
2385     $body =~ s/;?$/;\n/;
2386
2387     return $head . "{\n\t" . $body . "\b}" . $cont;
2388 }
2389
2390 sub pp_leaveloop { loop_common(@_, "") }
2391
2392 sub for_loop {
2393     my $self = shift;
2394     my($op, $cx) = @_;
2395     my $init = $self->deparse($op, 1);
2396     return $self->loop_common($op->sibling->first->sibling, $cx, $init);
2397 }
2398
2399 sub pp_leavetry {
2400     my $self = shift;
2401     return "eval {\n\t" . $self->pp_leave(@_) . "\n\b}";
2402 }
2403
2404 BEGIN { eval "sub OP_CONST () {" . opnumber("const") . "}" }
2405 BEGIN { eval "sub OP_STRINGIFY () {" . opnumber("stringify") . "}" }
2406 BEGIN { eval "sub OP_RV2SV () {" . opnumber("rv2sv") . "}" }
2407 BEGIN { eval "sub OP_LIST () {" . opnumber("list") . "}" }
2408
2409 sub pp_null {
2410     my $self = shift;
2411     my($op, $cx) = @_;
2412     if (class($op) eq "OP") {
2413         # old value is lost
2414         return $self->{'ex_const'} if $op->targ == OP_CONST;
2415     } elsif ($op->first->name eq "pushmark") {
2416         return $self->pp_list($op, $cx);
2417     } elsif ($op->first->name eq "enter") {
2418         return $self->pp_leave($op, $cx);
2419     } elsif ($op->targ == OP_STRINGIFY) {
2420         return $self->dquote($op, $cx);
2421     } elsif (!null($op->first->sibling) and
2422              $op->first->sibling->name eq "readline" and
2423              $op->first->sibling->flags & OPf_STACKED) {
2424         return $self->maybe_parens($self->deparse($op->first, 7) . " = "
2425                                    . $self->deparse($op->first->sibling, 7),
2426                                    $cx, 7);
2427     } elsif (!null($op->first->sibling) and
2428              $op->first->sibling->name eq "trans" and
2429              $op->first->sibling->flags & OPf_STACKED) {
2430         return $self->maybe_parens($self->deparse($op->first, 20) . " =~ "
2431                                    . $self->deparse($op->first->sibling, 20),
2432                                    $cx, 20);
2433     } elsif ($op->flags & OPf_SPECIAL && $cx == 0 && !$op->targ) {
2434         return "do {\n\t". $self->deparse($op->first, $cx) ."\n\b};";
2435     } elsif (!null($op->first->sibling) and
2436              $op->first->sibling->name eq "null" and
2437              class($op->first->sibling) eq "UNOP" and
2438              $op->first->sibling->first->flags & OPf_STACKED and
2439              $op->first->sibling->first->name eq "rcatline") {
2440         return $self->maybe_parens($self->deparse($op->first, 18) . " .= "
2441                                    . $self->deparse($op->first->sibling, 18),
2442                                    $cx, 18);
2443     } else {
2444         return $self->deparse($op->first, $cx);
2445     }
2446 }
2447
2448 sub padname {
2449     my $self = shift;
2450     my $targ = shift;
2451     return $self->padname_sv($targ)->PVX;
2452 }
2453
2454 sub padany {
2455     my $self = shift;
2456     my $op = shift;
2457     return substr($self->padname($op->targ), 1); # skip $/@/%
2458 }
2459
2460 sub pp_padsv {
2461     my $self = shift;
2462     my($op, $cx) = @_;
2463     return $self->maybe_my($op, $cx, $self->padname($op->targ));
2464 }
2465
2466 sub pp_padav { pp_padsv(@_) }
2467 sub pp_padhv { pp_padsv(@_) }
2468
2469 my @threadsv_names;
2470
2471 BEGIN {
2472     @threadsv_names = ("_", "1", "2", "3", "4", "5", "6", "7", "8", "9",
2473                        "&", "`", "'", "+", "/", ".", ",", "\\", '"', ";",
2474                        "^", "-", "%", "=", "|", "~", ":", "^A", "^E",
2475                        "!", "@");
2476 }
2477
2478 sub pp_threadsv {
2479     my $self = shift;
2480     my($op, $cx) = @_;
2481     return $self->maybe_local($op, $cx, "\$" .  $threadsv_names[$op->targ]);
2482 }
2483
2484 sub gv_or_padgv {
2485     my $self = shift;
2486     my $op = shift;
2487     if (class($op) eq "PADOP") {
2488         return $self->padval($op->padix);
2489     } else { # class($op) eq "SVOP"
2490         return $op->gv;
2491     }
2492 }
2493
2494 sub pp_gvsv {
2495     my $self = shift;
2496     my($op, $cx) = @_;
2497     my $gv = $self->gv_or_padgv($op);
2498     return $self->maybe_local($op, $cx, $self->stash_variable("\$",
2499                                  $self->gv_name($gv)));
2500 }
2501
2502 sub pp_gv {
2503     my $self = shift;
2504     my($op, $cx) = @_;
2505     my $gv = $self->gv_or_padgv($op);
2506     return $self->gv_name($gv);
2507 }
2508
2509 sub pp_aelemfast {
2510     my $self = shift;
2511     my($op, $cx) = @_;
2512     my $gv = $self->gv_or_padgv($op);
2513     my $name = $self->gv_name($gv);
2514     $name = $self->{'curstash'}."::$name"
2515         if $name !~ /::/ && $self->lex_in_scope('@'.$name);
2516
2517     return "\$" . $name . "[" .
2518                   ($op->private + $self->{'arybase'}) . "]";
2519 }
2520
2521 sub rv2x {
2522     my $self = shift;
2523     my($op, $cx, $type) = @_;
2524
2525     if (class($op) eq 'NULL' || !$op->can("first")) {
2526         carp("Unexpected op in pp_rv2x");
2527         return 'XXX';
2528     }
2529     my $kid = $op->first;
2530     my $str = $self->deparse($kid, 0);
2531     return $self->stash_variable($type, $str) if is_scalar($kid);
2532     return $type ."{$str}";
2533 }
2534
2535 sub pp_rv2sv { maybe_local(@_, rv2x(@_, "\$")) }
2536 sub pp_rv2hv { maybe_local(@_, rv2x(@_, "%")) }
2537 sub pp_rv2gv { maybe_local(@_, rv2x(@_, "*")) }
2538
2539 # skip rv2av
2540 sub pp_av2arylen {
2541     my $self = shift;
2542     my($op, $cx) = @_;
2543     if ($op->first->name eq "padav") {
2544         return $self->maybe_local($op, $cx, '$#' . $self->padany($op->first));
2545     } else {
2546         return $self->maybe_local($op, $cx,
2547                                   $self->rv2x($op->first, $cx, '$#'));
2548     }
2549 }
2550
2551 # skip down to the old, ex-rv2cv
2552 sub pp_rv2cv {
2553     my ($self, $op, $cx) = @_;
2554     if (!null($op->first) && $op->first->name eq 'null' &&
2555         $op->first->targ eq OP_LIST)
2556     {
2557         return $self->rv2x($op->first->first->sibling, $cx, "&")
2558     }
2559     else {
2560         return $self->rv2x($op, $cx, "")
2561     }
2562 }
2563
2564 sub pp_rv2av {
2565     my $self = shift;
2566     my($op, $cx) = @_;
2567     my $kid = $op->first;
2568     if ($kid->name eq "const") { # constant list
2569         my $av = $self->const_sv($kid);
2570         return "(" . join(", ", map(const($_), $av->ARRAY)) . ")";
2571     } else {
2572         return $self->maybe_local($op, $cx, $self->rv2x($op, $cx, "\@"));
2573     }
2574  }
2575
2576 sub is_subscriptable {
2577     my $op = shift;
2578     if ($op->name =~ /^[ahg]elem/) {
2579         return 1;
2580     } elsif ($op->name eq "entersub") {
2581         my $kid = $op->first;
2582         return 0 unless null $kid->sibling;
2583         $kid = $kid->first;
2584         $kid = $kid->sibling until null $kid->sibling;
2585         return 0 if is_scope($kid);
2586         $kid = $kid->first;
2587         return 0 if $kid->name eq "gv";
2588         return 0 if is_scalar($kid);
2589         return is_subscriptable($kid);
2590     } else {
2591         return 0;
2592     }
2593 }
2594
2595 sub elem {
2596     my $self = shift;
2597     my ($op, $cx, $left, $right, $padname) = @_;
2598     my($array, $idx) = ($op->first, $op->first->sibling);
2599     unless ($array->name eq $padname) { # Maybe this has been fixed
2600         $array = $array->first; # skip rv2av (or ex-rv2av in _53+)
2601     }
2602     if ($array->name eq $padname) {
2603         $array = $self->padany($array);
2604     } elsif (is_scope($array)) { # ${expr}[0]
2605         $array = "{" . $self->deparse($array, 0) . "}";
2606     } elsif ($array->name eq "gv") {
2607         $array = $self->gv_name($self->gv_or_padgv($array));
2608         if ($array !~ /::/) {
2609             my $prefix = ($left eq '[' ? '@' : '%');
2610             $array = $self->{curstash}.'::'.$array
2611                 if $self->lex_in_scope($prefix . $array);
2612         }
2613     } elsif (is_scalar $array) { # $x[0], $$x[0], ...
2614         $array = $self->deparse($array, 24);
2615     } else {
2616         # $x[20][3]{hi} or expr->[20]
2617         my $arrow = is_subscriptable($array) ? "" : "->";
2618         return $self->deparse($array, 24) . $arrow .
2619             $left . $self->deparse($idx, 1) . $right;
2620     }
2621     $idx = $self->deparse($idx, 1);
2622
2623     # Outer parens in an array index will confuse perl
2624     # if we're interpolating in a regular expression, i.e.
2625     # /$x$foo[(-1)]/ is *not* the same as /$x$foo[-1]/
2626     #
2627     # If $self->{parens}, then an initial '(' will
2628     # definitely be paired with a final ')'. If
2629     # !$self->{parens}, the misleading parens won't
2630     # have been added in the first place.
2631     #
2632     # [You might think that we could get "(...)...(...)"
2633     # where the initial and final parens do not match
2634     # each other. But we can't, because the above would
2635     # only happen if there's an infix binop between the
2636     # two pairs of parens, and *that* means that the whole
2637     # expression would be parenthesized as well.]
2638     #
2639     $idx =~ s/^\((.*)\)$/$1/ if $self->{'parens'};
2640
2641     # Hash-element braces will autoquote a bareword inside themselves.
2642     # We need to make sure that C<$hash{warn()}> doesn't come out as
2643     # C<$hash{warn}>, which has a quite different meaning. Currently
2644     # B::Deparse will always quote strings, even if the string was a
2645     # bareword in the original (i.e. the OPpCONST_BARE flag is ignored
2646     # for constant strings.) So we can cheat slightly here - if we see
2647     # a bareword, we know that it is supposed to be a function call.
2648     #
2649     $idx =~ s/^([A-Za-z_]\w*)$/$1()/;
2650
2651     return "\$" . $array . $left . $idx . $right;
2652 }
2653
2654 sub pp_aelem { maybe_local(@_, elem(@_, "[", "]", "padav")) }
2655 sub pp_helem { maybe_local(@_, elem(@_, "{", "}", "padhv")) }
2656
2657 sub pp_gelem {
2658     my $self = shift;
2659     my($op, $cx) = @_;
2660     my($glob, $part) = ($op->first, $op->last);
2661     $glob = $glob->first; # skip rv2gv
2662     $glob = $glob->first if $glob->name eq "rv2gv"; # this one's a bug
2663     my $scope = is_scope($glob);
2664     $glob = $self->deparse($glob, 0);
2665     $part = $self->deparse($part, 1);
2666     return "*" . ($scope ? "{$glob}" : $glob) . "{$part}";
2667 }
2668
2669 sub slice {
2670     my $self = shift;
2671     my ($op, $cx, $left, $right, $regname, $padname) = @_;
2672     my $last;
2673     my(@elems, $kid, $array, $list);
2674     if (class($op) eq "LISTOP") {
2675         $last = $op->last;
2676     } else { # ex-hslice inside delete()
2677         for ($kid = $op->first; !null $kid->sibling; $kid = $kid->sibling) {}
2678         $last = $kid;
2679     }
2680     $array = $last;
2681     $array = $array->first
2682         if $array->name eq $regname or $array->name eq "null";
2683     if (is_scope($array)) {
2684         $array = "{" . $self->deparse($array, 0) . "}";
2685     } elsif ($array->name eq $padname) {
2686         $array = $self->padany($array);
2687     } else {
2688         $array = $self->deparse($array, 24);
2689     }
2690     $kid = $op->first->sibling; # skip pushmark
2691     if ($kid->name eq "list") {
2692         $kid = $kid->first->sibling; # skip list, pushmark
2693         for (; !null $kid; $kid = $kid->sibling) {
2694             push @elems, $self->deparse($kid, 6);
2695         }
2696         $list = join(", ", @elems);
2697     } else {
2698         $list = $self->deparse($kid, 1);
2699     }
2700     return "\@" . $array . $left . $list . $right;
2701 }
2702
2703 sub pp_aslice { maybe_local(@_, slice(@_, "[", "]", "rv2av", "padav")) }
2704 sub pp_hslice { maybe_local(@_, slice(@_, "{", "}", "rv2hv", "padhv")) }
2705
2706 sub pp_lslice {
2707     my $self = shift;
2708     my($op, $cx) = @_;
2709     my $idx = $op->first;
2710     my $list = $op->last;
2711     my(@elems, $kid);
2712     $list = $self->deparse($list, 1);
2713     $idx = $self->deparse($idx, 1);
2714     return "($list)" . "[$idx]";
2715 }
2716
2717 sub want_scalar {
2718     my $op = shift;
2719     return ($op->flags & OPf_WANT) == OPf_WANT_SCALAR;
2720 }
2721
2722 sub want_list {
2723     my $op = shift;
2724     return ($op->flags & OPf_WANT) == OPf_WANT_LIST;
2725 }
2726
2727 sub method {
2728     my $self = shift;
2729     my($op, $cx) = @_;
2730     my $kid = $op->first->sibling; # skip pushmark
2731     my($meth, $obj, @exprs);
2732     if ($kid->name eq "list" and want_list $kid) {
2733         # When an indirect object isn't a bareword but the args are in
2734         # parens, the parens aren't part of the method syntax (the LLAFR
2735         # doesn't apply), but they make a list with OPf_PARENS set that
2736         # doesn't get flattened by the append_elem that adds the method,
2737         # making a (object, arg1, arg2, ...) list where the object
2738         # usually is. This can be distinguished from
2739         # `($obj, $arg1, $arg2)->meth()' (which is legal if $arg2 is an
2740         # object) because in the later the list is in scalar context
2741         # as the left side of -> always is, while in the former
2742         # the list is in list context as method arguments always are.
2743         # (Good thing there aren't method prototypes!)
2744         $meth = $kid->sibling;
2745         $kid = $kid->first->sibling; # skip pushmark
2746         $obj = $kid;
2747         $kid = $kid->sibling;
2748         for (; not null $kid; $kid = $kid->sibling) {
2749             push @exprs, $self->deparse($kid, 6);
2750         }
2751     } else {
2752         $obj = $kid;
2753         $kid = $kid->sibling;
2754         for (; !null ($kid->sibling) && $kid->name ne "method_named";
2755               $kid = $kid->sibling) {
2756             push @exprs, $self->deparse($kid, 6);
2757         }
2758         $meth = $kid;
2759     }
2760     $obj = $self->deparse($obj, 24);
2761     if ($meth->name eq "method_named") {
2762         $meth = $self->const_sv($meth)->PV;
2763     } else {
2764         $meth = $meth->first;
2765         if ($meth->name eq "const") {
2766             # As of 5.005_58, this case is probably obsoleted by the
2767             # method_named case above
2768             $meth = $self->const_sv($meth)->PV; # needs to be bare
2769         } else {
2770             $meth = $self->deparse($meth, 1);
2771         }
2772     }
2773     my $args = join(", ", @exprs);
2774     $kid = $obj . "->" . $meth;
2775     if (length $args) {
2776         return $kid . "(" . $args . ")"; # parens mandatory
2777     } else {
2778         return $kid;
2779     }
2780 }
2781
2782 # returns "&" if the prototype doesn't match the args,
2783 # or ("", $args_after_prototype_demunging) if it does.
2784 sub check_proto {
2785     my $self = shift;
2786     return "&" if $self->{'noproto'};
2787     my($proto, @args) = @_;
2788     my($arg, $real);
2789     my $doneok = 0;
2790     my @reals;
2791     # An unbackslashed @ or % gobbles up the rest of the args
2792     1 while $proto =~ s/(?<!\\)([@%])[^\]]+$/$1/;
2793     while ($proto) {
2794         $proto =~ s/^(\\?[\$\@&%*]|\\\[[\$\@&%*]+\]|;)//;
2795         my $chr = $1;
2796         if ($chr eq "") {
2797             return "&" if @args;
2798         } elsif ($chr eq ";") {
2799             $doneok = 1;
2800         } elsif ($chr eq "@" or $chr eq "%") {
2801             push @reals, map($self->deparse($_, 6), @args);
2802             @args = ();
2803         } else {
2804             $arg = shift @args;
2805             last unless $arg;
2806             if ($chr eq "\$") {
2807                 if (want_scalar $arg) {
2808                     push @reals, $self->deparse($arg, 6);
2809                 } else {
2810                     return "&";
2811                 }
2812             } elsif ($chr eq "&") {
2813                 if ($arg->name =~ /^(s?refgen|undef)$/) {
2814                     push @reals, $self->deparse($arg, 6);
2815                 } else {
2816                     return "&";
2817                 }
2818             } elsif ($chr eq "*") {
2819                 if ($arg->name =~ /^s?refgen$/
2820                     and $arg->first->first->name eq "rv2gv")
2821                   {
2822                       $real = $arg->first->first; # skip refgen, null
2823                       if ($real->first->name eq "gv") {
2824                           push @reals, $self->deparse($real, 6);
2825                       } else {
2826                           push @reals, $self->deparse($real->first, 6);
2827                       }
2828                   } else {
2829                       return "&";
2830                   }
2831             } elsif (substr($chr, 0, 1) eq "\\") {
2832                 $chr =~ tr/\\[]//d;
2833                 if ($arg->name =~ /^s?refgen$/ and
2834                     !null($real = $arg->first) and
2835                     ($chr =~ /\$/ && is_scalar($real->first)
2836                      or ($chr =~ /@/
2837                          && class($real->first->sibling) ne 'NULL'
2838                          && $real->first->sibling->name
2839                          =~ /^(rv2|pad)av$/)
2840                      or ($chr =~ /%/
2841                          && class($real->first->sibling) ne 'NULL'
2842                          && $real->first->sibling->name
2843                          =~ /^(rv2|pad)hv$/)
2844                      #or ($chr =~ /&/ # This doesn't work
2845                      #   && $real->first->name eq "rv2cv")
2846                      or ($chr =~ /\*/
2847                          && $real->first->name eq "rv2gv")))
2848                   {
2849                       push @reals, $self->deparse($real, 6);
2850                   } else {
2851                       return "&";
2852                   }
2853             }
2854        }
2855     }
2856     return "&" if $proto and !$doneok; # too few args and no `;'
2857     return "&" if @args;               # too many args
2858     return ("", join ", ", @reals);
2859 }
2860
2861 sub pp_entersub {
2862     my $self = shift;
2863     my($op, $cx) = @_;
2864     return $self->method($op, $cx) unless null $op->first->sibling;
2865     my $prefix = "";
2866     my $amper = "";
2867     my($kid, @exprs);
2868     if ($op->flags & OPf_SPECIAL && !($op->flags & OPf_MOD)) {
2869         $prefix = "do ";
2870     } elsif ($op->private & OPpENTERSUB_AMPER) {
2871         $amper = "&";
2872     }
2873     $kid = $op->first;
2874     $kid = $kid->first->sibling; # skip ex-list, pushmark
2875     for (; not null $kid->sibling; $kid = $kid->sibling) {
2876         push @exprs, $kid;
2877     }
2878     my $simple = 0;
2879     my $proto = undef;
2880     if (is_scope($kid)) {
2881         $amper = "&";
2882         $kid = "{" . $self->deparse($kid, 0) . "}";
2883     } elsif ($kid->first->name eq "gv") {
2884         my $gv = $self->gv_or_padgv($kid->first);
2885         if (class($gv->CV) ne "SPECIAL") {
2886             $proto = $gv->CV->PV if $gv->CV->FLAGS & SVf_POK;
2887         }
2888         $simple = 1; # only calls of named functions can be prototyped
2889         $kid = $self->deparse($kid, 24);
2890     } elsif (is_scalar ($kid->first) && $kid->first->name ne 'rv2cv') {
2891         $amper = "&";
2892         $kid = $self->deparse($kid, 24);
2893     } else {
2894         $prefix = "";
2895         my $arrow = is_subscriptable($kid->first) ? "" : "->";
2896         $kid = $self->deparse($kid, 24) . $arrow;
2897     }
2898
2899     # Doesn't matter how many prototypes there are, if
2900     # they haven't happened yet!
2901     my $declared;
2902     {
2903         no strict 'refs';
2904         no warnings 'uninitialized';
2905         $declared = exists $self->{'subs_declared'}{$kid}
2906             || (
2907                  defined &{ %{$self->{'curstash'}."::"}->{$kid} }
2908                  && !exists
2909                      $self->{'subs_deparsed'}{$self->{'curstash'}."::".$kid}
2910                  && defined prototype $self->{'curstash'}."::".$kid
2911                );
2912         if (!$declared && defined($proto)) {
2913             # Avoid "too early to check prototype" warning
2914             ($amper, $proto) = ('&');
2915         }
2916     }
2917
2918     my $args;
2919     if ($declared and defined $proto and not $amper) {
2920         ($amper, $args) = $self->check_proto($proto, @exprs);
2921         if ($amper eq "&") {
2922             $args = join(", ", map($self->deparse($_, 6), @exprs));
2923         }
2924     } else {
2925         $args = join(", ", map($self->deparse($_, 6), @exprs));
2926     }
2927     if ($prefix or $amper) {
2928         if ($op->flags & OPf_STACKED) {
2929             return $prefix . $amper . $kid . "(" . $args . ")";
2930         } else {
2931             return $prefix . $amper. $kid;
2932         }
2933     } else {
2934         # glob() invocations can be translated into calls of
2935         # CORE::GLOBAL::glob with a second parameter, a number.
2936         # Reverse this.
2937         if ($kid eq "CORE::GLOBAL::glob") {
2938             $kid = "glob";
2939             $args =~ s/\s*,[^,]+$//;
2940         }
2941
2942         # It's a syntax error to call CORE::GLOBAL::foo without a prefix,
2943         # so it must have been translated from a keyword call. Translate
2944         # it back.
2945         $kid =~ s/^CORE::GLOBAL:://;
2946
2947         if (!$declared) {
2948             return "$kid(" . $args . ")";
2949         } elsif (defined $proto and $proto eq "") {
2950             return $kid;
2951         } elsif (defined $proto and $proto eq "\$" and is_scalar($exprs[0])) {
2952             return $self->maybe_parens_func($kid, $args, $cx, 16);
2953         } elsif (defined($proto) && $proto or $simple) {
2954             return $self->maybe_parens_func($kid, $args, $cx, 5);
2955         } else {
2956             return "$kid(" . $args . ")";
2957         }
2958     }
2959 }
2960
2961 sub pp_enterwrite { unop(@_, "write") }
2962
2963 # escape things that cause interpolation in double quotes,
2964 # but not character escapes
2965 sub uninterp {
2966     my($str) = @_;
2967     $str =~ s/(^|\G|[^\\])((?:\\\\)*)([\$\@]|\\[uUlLQE])/$1$2\\$3/g;
2968     return $str;
2969 }
2970
2971 {
2972 my $bal;
2973 BEGIN {
2974     use re "eval";
2975     # Matches any string which is balanced with respect to {braces}
2976     $bal = qr(
2977       (?:
2978         [^\\{}]
2979       | \\\\
2980       | \\[{}]
2981       | \{(??{$bal})\}
2982       )*
2983     )x;
2984 }
2985
2986 # the same, but treat $|, $), $( and $ at the end of the string differently
2987 sub re_uninterp {
2988     my($str) = @_;
2989
2990     $str =~ s/
2991           ( ^|\G                  # $1
2992           | [^\\]
2993           )
2994
2995           (                       # $2
2996             (?:\\\\)*
2997           )
2998
2999           (                       # $3
3000             (\(\?\??\{$bal\}\))   # $4
3001           | [\$\@]
3002             (?!\||\)|\(|$)
3003           | \\[uUlLQE]
3004           )
3005
3006         /length($4) ? "$1$2$4" : "$1$2\\$3"/xeg;
3007
3008     return $str;
3009 }
3010
3011 # This is for regular expressions with the /x modifier
3012 # We have to leave comments unmangled.
3013 sub re_uninterp_extended {
3014     my($str) = @_;
3015
3016     $str =~ s/
3017           ( ^|\G                  # $1
3018           | [^\\]
3019           )
3020
3021           (                       # $2
3022             (?:\\\\)*
3023           )
3024
3025           (                       # $3
3026             ( \(\?\??\{$bal\}\)   # $4  (skip over (?{}) and (??{}) blocks)
3027             | \#[^\n]*            #     (skip over comments)
3028             )
3029           | [\$\@]
3030             (?!\||\)|\(|$)
3031           | \\[uUlLQE]
3032           )
3033
3034         /length($4) ? "$1$2$4" : "$1$2\\$3"/xeg;
3035
3036     return $str;
3037 }
3038 }
3039
3040 # character escapes, but not delimiters that might need to be escaped
3041 sub escape_str { # ASCII, UTF8
3042     my($str) = @_;
3043     $str =~ s/(.)/ord($1) > 255 ? sprintf("\\x{%x}", ord($1)) : $1/eg;
3044     $str =~ s/\a/\\a/g;
3045 #    $str =~ s/\cH/\\b/g; # \b means something different in a regex
3046     $str =~ s/\t/\\t/g;
3047     $str =~ s/\n/\\n/g;
3048     $str =~ s/\e/\\e/g;
3049     $str =~ s/\f/\\f/g;
3050     $str =~ s/\r/\\r/g;
3051     $str =~ s/([\cA-\cZ])/sprintf("\\c%c", ord('@') + ord($1))/ge;
3052     $str =~ s/([[:^print:]])/sprintf("\\%03o", ord($1))/ge;
3053     return $str;
3054 }
3055
3056 # For regexes with the /x modifier.
3057 # Leave whitespace unmangled.
3058 sub escape_extended_re {
3059     my($str) = @_;
3060     $str =~ s/(.)/ord($1) > 255 ? sprintf("\\x{%x}", ord($1)) : $1/eg;
3061     $str =~ s/([[:^print:]])/
3062         ($1 =~ y! \t\n!!) ? $1 : sprintf("\\%03o", ord($1))/ge;
3063     $str =~ s/\n/\n\f/g;
3064     return $str;
3065 }
3066
3067 # Don't do this for regexen
3068 sub unback {
3069     my($str) = @_;
3070     $str =~ s/\\/\\\\/g;
3071     return $str;
3072 }
3073
3074 # Remove backslashes which precede literal control characters,
3075 # to avoid creating ambiguity when we escape the latter.
3076 sub re_unback {
3077     my($str) = @_;
3078
3079     # the insane complexity here is due to the behaviour of "\c\"
3080     $str =~ s/(^|[^\\]|\\c\\)(?<!\\c)\\(\\\\)*(?=[[:^print:]])/$1$2/g;
3081     return $str;
3082 }
3083
3084 sub balanced_delim {
3085     my($str) = @_;
3086     my @str = split //, $str;
3087     my($ar, $open, $close, $fail, $c, $cnt);
3088     for $ar (['[',']'], ['(',')'], ['<','>'], ['{','}']) {
3089         ($open, $close) = @$ar;
3090         $fail = 0; $cnt = 0;
3091         for $c (@str) {
3092             if ($c eq $open) {
3093                 $cnt++;
3094             } elsif ($c eq $close) {
3095                 $cnt--;
3096                 if ($cnt < 0) {
3097                     # qq()() isn't ")("
3098                     $fail = 1;
3099                     last;
3100                 }
3101             }
3102         }
3103         $fail = 1 if $cnt != 0;
3104         return ($open, "$open$str$close") if not $fail;
3105     }
3106     return ("", $str);
3107 }
3108
3109 sub single_delim {
3110     my($q, $default, $str) = @_;
3111     return "$default$str$default" if $default and index($str, $default) == -1;
3112     if ($q ne 'qr') {
3113         (my $succeed, $str) = balanced_delim($str);
3114         return "$q$str" if $succeed;
3115     }
3116     for my $delim ('/', '"', '#') {
3117         return "$q$delim" . $str . $delim if index($str, $delim) == -1;
3118     }
3119     if ($default) {
3120         $str =~ s/$default/\\$default/g;
3121         return "$default$str$default";
3122     } else {
3123         $str =~ s[/][\\/]g;
3124         return "$q/$str/";
3125     }
3126 }
3127
3128 sub const {
3129     my $sv = shift;
3130     if (class($sv) eq "SPECIAL") {
3131         return ('undef', '1', '0')[$$sv-1]; # sv_undef, sv_yes, sv_no
3132     } elsif (class($sv) eq "NULL") {
3133        return 'undef';
3134     } elsif ($sv->FLAGS & SVf_IOK) {
3135         return $sv->int_value;
3136     } elsif ($sv->FLAGS & SVf_NOK) {
3137         # try the default stringification
3138         my $r = "".$sv->NV;
3139         if ($r =~ /e/) {
3140             # If it's in scientific notation, we might have lost information
3141             return sprintf("%.20e", $sv->NV);
3142         }
3143         return $r;
3144     } elsif ($sv->FLAGS & SVf_ROK && $sv->can("RV")) {
3145         return "\\(" . const($sv->RV) . ")"; # constant folded
3146     } elsif ($sv->FLAGS & SVf_POK) {
3147         my $str = $sv->PV;
3148         if ($str =~ /[^ -~]/) { # ASCII for non-printing
3149             return single_delim("qq", '"', uninterp escape_str unback $str);
3150         } else {
3151             return single_delim("q", "'", unback $str);
3152         }
3153     } else {
3154         return "undef";
3155     }
3156 }
3157
3158 sub const_sv {
3159     my $self = shift;
3160     my $op = shift;
3161     my $sv = $op->sv;
3162     # the constant could be in the pad (under useithreads)
3163     $sv = $self->padval($op->targ) unless $$sv;
3164     return $sv;
3165 }
3166
3167 sub pp_const {
3168     my $self = shift;
3169     my($op, $cx) = @_;
3170     if ($op->private & OPpCONST_ARYBASE) {
3171         return '$[';
3172     }
3173 #    if ($op->private & OPpCONST_BARE) { # trouble with `=>' autoquoting
3174 #       return $self->const_sv($op)->PV;
3175 #    }
3176     my $sv = $self->const_sv($op);
3177 #    return const($sv);
3178     my $c = const $sv;
3179     return $c =~ /^-\d/ ? $self->maybe_parens($c, $cx, 21) : $c;
3180 }
3181
3182 sub dq {
3183     my $self = shift;
3184     my $op = shift;
3185     my $type = $op->name;
3186     if ($type eq "const") {
3187         return '$[' if $op->private & OPpCONST_ARYBASE;
3188         return uninterp(escape_str(unback($self->const_sv($op)->as_string)));
3189     } elsif ($type eq "concat") {
3190         my $first = $self->dq($op->first);
3191         my $last  = $self->dq($op->last);
3192
3193         # Disambiguate "${foo}bar", "${foo}{bar}", "${foo}[1]"
3194         ($last =~ /^[A-Z\\\^\[\]_?]/ &&
3195             $first =~ s/([\$@])\^$/${1}{^}/)  # "${^}W" etc
3196             || ($last =~ /^[{\[\w_]/ &&
3197                 $first =~ s/([\$@])([A-Za-z_]\w*)$/${1}{$2}/);
3198
3199         return $first . $last;
3200     } elsif ($type eq "uc") {
3201         return '\U' . $self->dq($op->first->sibling) . '\E';
3202     } elsif ($type eq "lc") {
3203         return '\L' . $self->dq($op->first->sibling) . '\E';
3204     } elsif ($type eq "ucfirst") {
3205         return '\u' . $self->dq($op->first->sibling);
3206     } elsif ($type eq "lcfirst") {
3207         return '\l' . $self->dq($op->first->sibling);
3208     } elsif ($type eq "quotemeta") {
3209         return '\Q' . $self->dq($op->first->sibling) . '\E';
3210     } elsif ($type eq "join") {
3211         return $self->deparse($op->last, 26); # was join($", @ary)
3212     } else {
3213         return $self->deparse($op, 26);
3214     }
3215 }
3216
3217 sub pp_backtick {
3218     my $self = shift;
3219     my($op, $cx) = @_;
3220     # skip pushmark
3221     return single_delim("qx", '`', $self->dq($op->first->sibling));
3222 }
3223
3224 sub dquote {
3225     my $self = shift;
3226     my($op, $cx) = @_;
3227     my $kid = $op->first->sibling; # skip ex-stringify, pushmark
3228     return $self->deparse($kid, $cx) if $self->{'unquote'};
3229     $self->maybe_targmy($kid, $cx,
3230                         sub {single_delim("qq", '"', $self->dq($_[1]))});
3231 }
3232
3233 # OP_STRINGIFY is a listop, but it only ever has one arg
3234 sub pp_stringify { maybe_targmy(@_, \&dquote) }
3235
3236 # tr/// and s/// (and tr[][], tr[]//, tr###, etc)
3237 # note that tr(from)/to/ is OK, but not tr/from/(to)
3238 sub double_delim {
3239     my($from, $to) = @_;
3240     my($succeed, $delim);
3241     if ($from !~ m[/] and $to !~ m[/]) {
3242         return "/$from/$to/";
3243     } elsif (($succeed, $from) = balanced_delim($from) and $succeed) {
3244         if (($succeed, $to) = balanced_delim($to) and $succeed) {
3245             return "$from$to";
3246         } else {
3247             for $delim ('/', '"', '#') { # note no `'' -- s''' is special
3248                 return "$from$delim$to$delim" if index($to, $delim) == -1;
3249             }
3250             $to =~ s[/][\\/]g;
3251             return "$from/$to/";
3252         }
3253     } else {
3254         for $delim ('/', '"', '#') { # note no '
3255             return "$delim$from$delim$to$delim"
3256                 if index($to . $from, $delim) == -1;
3257         }
3258         $from =~ s[/][\\/]g;
3259         $to =~ s[/][\\/]g;
3260         return "/$from/$to/";
3261     }
3262 }
3263
3264 # Only used by tr///, so backslashes hyphens
3265 sub pchr { # ASCII
3266     my($n) = @_;
3267     if ($n == ord '\\') {
3268         return '\\\\';
3269     } elsif ($n == ord "-") {
3270         return "\\-";
3271     } elsif ($n >= ord(' ') and $n <= ord('~')) {
3272         return chr($n);
3273     } elsif ($n == ord "\a") {
3274         return '\\a';
3275     } elsif ($n == ord "\b") {
3276         return '\\b';
3277     } elsif ($n == ord "\t") {
3278         return '\\t';
3279     } elsif ($n == ord "\n") {
3280         return '\\n';
3281     } elsif ($n == ord "\e") {
3282         return '\\e';
3283     } elsif ($n == ord "\f") {
3284         return '\\f';
3285     } elsif ($n == ord "\r") {
3286         return '\\r';
3287     } elsif ($n >= ord("\cA") and $n <= ord("\cZ")) {
3288         return '\\c' . chr(ord("@") + $n);
3289     } else {
3290 #       return '\x' . sprintf("%02x", $n);
3291         return '\\' . sprintf("%03o", $n);
3292     }
3293 }
3294
3295 sub collapse {
3296     my(@chars) = @_;
3297     my($str, $c, $tr) = ("");
3298     for ($c = 0; $c < @chars; $c++) {
3299         $tr = $chars[$c];
3300         $str .= pchr($tr);
3301         if ($c <= $#chars - 2 and $chars[$c + 1] == $tr + 1 and
3302             $chars[$c + 2] == $tr + 2)
3303         {
3304             for (; $c <= $#chars-1 and $chars[$c + 1] == $chars[$c] + 1; $c++)
3305               {}
3306             $str .= "-";
3307             $str .= pchr($chars[$c]);
3308         }
3309     }
3310     return $str;
3311 }
3312
3313 sub tr_decode_byte {
3314     my($table, $flags) = @_;
3315     my(@table) = unpack("s*", $table);
3316     splice @table, 0x100, 1;   # Number of subsequent elements
3317     my($c, $tr, @from, @to, @delfrom, $delhyphen);
3318     if ($table[ord "-"] != -1 and
3319         $table[ord("-") - 1] == -1 || $table[ord("-") + 1] == -1)
3320     {
3321         $tr = $table[ord "-"];
3322         $table[ord "-"] = -1;
3323         if ($tr >= 0) {
3324             @from = ord("-");
3325             @to = $tr;
3326         } else { # -2 ==> delete
3327             $delhyphen = 1;
3328         }
3329     }
3330     for ($c = 0; $c < @table; $c++) {
3331         $tr = $table[$c];
3332         if ($tr >= 0) {
3333             push @from, $c; push @to, $tr;
3334         } elsif ($tr == -2) {
3335             push @delfrom, $c;
3336         }
3337     }
3338     @from = (@from, @delfrom);
3339     if ($flags & OPpTRANS_COMPLEMENT) {
3340         my @newfrom = ();
3341         my %from;
3342         @from{@from} = (1) x @from;
3343         for ($c = 0; $c < 256; $c++) {
3344             push @newfrom, $c unless $from{$c};
3345         }
3346         @from = @newfrom;
3347     }
3348     unless ($flags & OPpTRANS_DELETE || !@to) {
3349         pop @to while $#to and $to[$#to] == $to[$#to -1];
3350     }
3351     my($from, $to);
3352     $from = collapse(@from);
3353     $to = collapse(@to);
3354     $from .= "-" if $delhyphen;
3355     return ($from, $to);
3356 }
3357
3358 sub tr_chr {
3359     my $x = shift;
3360     if ($x == ord "-") {
3361         return "\\-";
3362     } elsif ($x == ord "\\") {
3363         return "\\\\";
3364     } else {
3365         return chr $x;
3366     }
3367 }
3368
3369 # XXX This doesn't yet handle all cases correctly either
3370
3371 sub tr_decode_utf8 {
3372     my($swash_hv, $flags) = @_;
3373     my %swash = $swash_hv->ARRAY;
3374     my $final = undef;
3375     $final = $swash{'FINAL'}->IV if exists $swash{'FINAL'};
3376     my $none = $swash{"NONE"}->IV;
3377     my $extra = $none + 1;
3378     my(@from, @delfrom, @to);
3379     my $line;
3380     foreach $line (split /\n/, $swash{'LIST'}->PV) {
3381         my($min, $max, $result) = split(/\t/, $line);
3382         $min = hex $min;
3383         if (length $max) {
3384             $max = hex $max;
3385         } else {
3386             $max = $min;
3387         }
3388         $result = hex $result;
3389         if ($result == $extra) {
3390             push @delfrom, [$min, $max];
3391         } else {
3392             push @from, [$min, $max];
3393             push @to, [$result, $result + $max - $min];
3394         }
3395     }
3396     for my $i (0 .. $#from) {
3397         if ($from[$i][0] == ord '-') {
3398             unshift @from, splice(@from, $i, 1);
3399             unshift @to, splice(@to, $i, 1);
3400             last;
3401         } elsif ($from[$i][1] == ord '-') {
3402             $from[$i][1]--;
3403             $to[$i][1]--;
3404             unshift @from, ord '-';
3405             unshift @to, ord '-';
3406             last;
3407         }
3408     }
3409     for my $i (0 .. $#delfrom) {
3410         if ($delfrom[$i][0] == ord '-') {
3411             push @delfrom, splice(@delfrom, $i, 1);
3412             last;
3413         } elsif ($delfrom[$i][1] == ord '-') {
3414             $delfrom[$i][1]--;
3415             push @delfrom, ord '-';
3416             last;
3417         }
3418     }
3419     if (defined $final and $to[$#to][1] != $final) {
3420         push @to, [$final, $final];
3421     }
3422     push @from, @delfrom;
3423     if ($flags & OPpTRANS_COMPLEMENT) {
3424         my @newfrom;
3425         my $next = 0;
3426         for my $i (0 .. $#from) {
3427             push @newfrom, [$next, $from[$i][0] - 1];
3428             $next = $from[$i][1] + 1;
3429         }
3430         @from = ();
3431         for my $range (@newfrom) {
3432             if ($range->[0] <= $range->[1]) {
3433                 push @from, $range;
3434             }
3435         }
3436     }
3437     my($from, $to, $diff);
3438     for my $chunk (@from) {
3439         $diff = $chunk->[1] - $chunk->[0];
3440         if ($diff > 1) {
3441             $from .= tr_chr($chunk->[0]) . "-" . tr_chr($chunk->[1]);
3442         } elsif ($diff == 1) {
3443             $from .= tr_chr($chunk->[0]) . tr_chr($chunk->[1]);
3444         } else {
3445             $from .= tr_chr($chunk->[0]);
3446         }
3447     }
3448     for my $chunk (@to) {
3449         $diff = $chunk->[1] - $chunk->[0];
3450         if ($diff > 1) {
3451             $to .= tr_chr($chunk->[0]) . "-" . tr_chr($chunk->[1]);
3452         } elsif ($diff == 1) {
3453             $to .= tr_chr($chunk->[0]) . tr_chr($chunk->[1]);
3454         } else {
3455             $to .= tr_chr($chunk->[0]);
3456         }
3457     }
3458     #$final = sprintf("%04x", $final) if defined $final;
3459     #$none = sprintf("%04x", $none) if defined $none;
3460     #$extra = sprintf("%04x", $extra) if defined $extra;
3461     #print STDERR "final: $final\n none: $none\nextra: $extra\n";
3462     #print STDERR $swash{'LIST'}->PV;
3463     return (escape_str($from), escape_str($to));
3464 }
3465
3466 sub pp_trans {
3467     my $self = shift;
3468     my($op, $cx) = @_;
3469     my($from, $to);
3470     if (class($op) eq "PVOP") {
3471         ($from, $to) = tr_decode_byte($op->pv, $op->private);
3472     } else { # class($op) eq "SVOP"
3473         ($from, $to) = tr_decode_utf8($op->sv->RV, $op->private);
3474     }
3475     my $flags = "";
3476     $flags .= "c" if $op->private & OPpTRANS_COMPLEMENT;
3477     $flags .= "d" if $op->private & OPpTRANS_DELETE;
3478     $to = "" if $from eq $to and $flags eq "";
3479     $flags .= "s" if $op->private & OPpTRANS_SQUASH;
3480     return "tr" . double_delim($from, $to) . $flags;
3481 }
3482
3483 # Like dq(), but different
3484 sub re_dq {
3485     my $self = shift;
3486     my ($op, $extended) = @_;
3487
3488     my $type = $op->name;
3489     if ($type eq "const") {
3490         return '$[' if $op->private & OPpCONST_ARYBASE;
3491         my $unbacked = re_unback($self->const_sv($op)->as_string);
3492         return re_uninterp_extended(escape_extended_re($unbacked))
3493             if $extended;
3494         return re_uninterp(escape_str($unbacked));
3495     } elsif ($type eq "concat") {
3496         my $first = $self->re_dq($op->first, $extended);
3497         my $last  = $self->re_dq($op->last,  $extended);
3498
3499         # Disambiguate "${foo}bar", "${foo}{bar}", "${foo}[1]"
3500         ($last =~ /^[A-Z\\\^\[\]_?]/ &&
3501             $first =~ s/([\$@])\^$/${1}{^}/)  # "${^}W" etc
3502             || ($last =~ /^[{\[\w_]/ &&
3503                 $first =~ s/([\$@])([A-Za-z_]\w*)$/${1}{$2}/);
3504
3505         return $first . $last;
3506     } elsif ($type eq "uc") {
3507         return '\U' . $self->re_dq($op->first->sibling, $extended) . '\E';
3508     } elsif ($type eq "lc") {
3509         return '\L' . $self->re_dq($op->first->sibling, $extended) . '\E';
3510     } elsif ($type eq "ucfirst") {
3511         return '\u' . $self->re_dq($op->first->sibling, $extended);
3512     } elsif ($type eq "lcfirst") {
3513         return '\l' . $self->re_dq($op->first->sibling, $extended);
3514     } elsif ($type eq "quotemeta") {
3515         return '\Q' . $self->re_dq($op->first->sibling, $extended) . '\E';
3516     } elsif ($type eq "join") {
3517         return $self->deparse($op->last, 26); # was join($", @ary)
3518     } else {
3519         return $self->deparse($op, 26);
3520     }
3521 }
3522
3523 sub pure_string {
3524     my ($self, $op) = @_;
3525     my $type = $op->name;
3526
3527     if ($type eq 'const') {
3528         return 1;
3529     }
3530     elsif ($type =~ /^[ul]c(first)?$/ || $type eq 'quotemeta') {
3531         return $self->pure_string($op->first->sibling);
3532     }
3533     elsif ($type eq 'join') {
3534         my $join_op = $op->first->sibling;  # Skip pushmark
3535         return 0 unless $join_op->name eq 'null' && $join_op->targ eq OP_RV2SV;
3536
3537         my $gvop = $join_op->first;
3538         return 0 unless $gvop->name eq 'gvsv';
3539         return 0 unless '"' eq $self->gv_name($self->gv_or_padgv($gvop));
3540
3541         return 0 unless ${$join_op->sibling} eq ${$op->last};
3542         return 0 unless $op->last->name =~ /^(rv2|pad)av$/;
3543     }
3544     elsif ($type eq 'concat') {
3545         return $self->pure_string($op->first)
3546             && $self->pure_string($op->last);
3547     }
3548     elsif (is_scalar($op) || $type =~ /^[ah]elem(fast)?$/) {
3549         return 1;
3550     }
3551     else {
3552         return 0;
3553     }
3554
3555     return 1;
3556 }
3557
3558 sub regcomp {
3559     my $self = shift;
3560     my($op, $cx, $extended) = @_;
3561     my $kid = $op->first;
3562     $kid = $kid->first if $kid->name eq "regcmaybe";
3563     $kid = $kid->first if $kid->name eq "regcreset";
3564     return ($self->re_dq($kid, $extended), 1) if $self->pure_string($kid);
3565     return ($self->deparse($kid, $cx), 0);
3566 }
3567
3568 sub pp_regcomp {
3569     my ($self, $op, $cx) = @_;
3570     return (($self->regcomp($op, $cx, 0))[0]);
3571 }
3572
3573 # osmic acid -- see osmium tetroxide
3574
3575 my %matchwords;
3576 map($matchwords{join "", sort split //, $_} = $_, 'cig', 'cog', 'cos', 'cogs',
3577     'cox', 'go', 'is', 'ism', 'iso', 'mig', 'mix', 'osmic', 'ox', 'sic',
3578     'sig', 'six', 'smog', 'so', 'soc', 'sog', 'xi');
3579
3580 sub matchop {
3581     my $self = shift;
3582     my($op, $cx, $name, $delim) = @_;
3583     my $kid = $op->first;
3584     my ($binop, $var, $re) = ("", "", "");
3585     if ($op->flags & OPf_STACKED) {
3586         $binop = 1;
3587         $var = $self->deparse($kid, 20);
3588         $kid = $kid->sibling;
3589     }
3590     my $quote = 1;
3591     my $extended = ($op->pmflags & PMf_EXTENDED);
3592     if (null $kid) {
3593         my $unbacked = re_unback($op->precomp);
3594         if ($extended) {
3595             $re = re_uninterp_extended(escape_extended_re($unbacked));
3596         } else {
3597             $re = re_uninterp(escape_str(re_unback($op->precomp)));
3598         }
3599     } elsif ($kid->name ne 'regcomp') {
3600         carp("found ".$kid->name." where regcomp expected");
3601     } else {
3602         ($re, $quote) = $self->regcomp($kid, 1, $extended);
3603     }
3604     my $flags = "";
3605     $flags .= "c" if $op->pmflags & PMf_CONTINUE;
3606     $flags .= "g" if $op->pmflags & PMf_GLOBAL;
3607     $flags .= "i" if $op->pmflags & PMf_FOLD;
3608     $flags .= "m" if $op->pmflags & PMf_MULTILINE;
3609     $flags .= "o" if $op->pmflags & PMf_KEEP;
3610     $flags .= "s" if $op->pmflags & PMf_SINGLELINE;
3611     $flags .= "x" if $op->pmflags & PMf_EXTENDED;
3612     $flags = $matchwords{$flags} if $matchwords{$flags};
3613     if ($op->pmflags & PMf_ONCE) { # only one kind of delimiter works here
3614         $re =~ s/\?/\\?/g;
3615         $re = "?$re?";
3616     } elsif ($quote) {
3617         $re = single_delim($name, $delim, $re);
3618     }
3619     $re = $re . $flags if $quote;
3620     if ($binop) {
3621         return $self->maybe_parens("$var =~ $re", $cx, 20);
3622     } else {
3623         return $re;
3624     }
3625 }
3626
3627 sub pp_match { matchop(@_, "m", "/") }
3628 sub pp_pushre { matchop(@_, "m", "/") }
3629 sub pp_qr { matchop(@_, "qr", "") }
3630
3631 sub pp_split {
3632     my $self = shift;
3633     my($op, $cx) = @_;
3634     my($kid, @exprs, $ary, $expr);
3635     $kid = $op->first;
3636     # under ithreads pmreplroot is an integer, not an SV
3637     my $replroot = $kid->pmreplroot;
3638     if ( ( ref($replroot) && $$replroot ) ||
3639          ( !ref($replroot) && $replroot ) ) {
3640         $ary = $self->stash_variable('@', $self->gv_name($kid->pmreplroot));
3641     }
3642     for (; !null($kid); $kid = $kid->sibling) {
3643         push @exprs, $self->deparse($kid, 6);
3644     }
3645
3646     # handle special case of split(), and split(" ") that compiles to /\s+/
3647     $kid = $op->first;
3648     if ($kid->flags & OPf_SPECIAL
3649         && $exprs[0] eq '/\\s+/'
3650         && $kid->pmflags & PMf_SKIPWHITE ) {
3651             $exprs[0] = '" "';
3652     }
3653
3654     $expr = "split(" . join(", ", @exprs) . ")";
3655     if ($ary) {
3656         return $self->maybe_parens("$ary = $expr", $cx, 7);
3657     } else {
3658         return $expr;
3659     }
3660 }
3661
3662 # oxime -- any of various compounds obtained chiefly by the action of
3663 # hydroxylamine on aldehydes and ketones and characterized by the
3664 # bivalent grouping C=NOH [Webster's Tenth]
3665
3666 my %substwords;
3667 map($substwords{join "", sort split //, $_} = $_, 'ego', 'egoism', 'em',
3668     'es', 'ex', 'exes', 'gee', 'go', 'goes', 'ie', 'ism', 'iso', 'me',
3669     'meese', 'meso', 'mig', 'mix', 'os', 'ox', 'oxime', 'see', 'seem',
3670     'seg', 'sex', 'sig', 'six', 'smog', 'sog', 'some', 'xi');
3671
3672 sub pp_subst {
3673     my $self = shift;
3674     my($op, $cx) = @_;
3675     my $kid = $op->first;
3676     my($binop, $var, $re, $repl) = ("", "", "", "");
3677     if ($op->flags & OPf_STACKED) {
3678         $binop = 1;
3679         $var = $self->deparse($kid, 20);
3680         $kid = $kid->sibling;
3681     }
3682     my $flags = "";
3683     if (null($op->pmreplroot)) {
3684         $repl = $self->dq($kid);
3685         $kid = $kid->sibling;
3686     } else {
3687         $repl = $op->pmreplroot->first; # skip substcont
3688         while ($repl->name eq "entereval") {
3689             $repl = $repl->first;
3690             $flags .= "e";
3691         }
3692         if ($op->pmflags & PMf_EVAL) {
3693             $repl = $self->deparse($repl, 0);
3694         } else {
3695             $repl = $self->dq($repl);
3696         }
3697     }
3698     my $extended = ($op->pmflags & PMf_EXTENDED);
3699     if (null $kid) {
3700         my $unbacked = re_unback($op->precomp);
3701         if ($extended) {
3702             $re = re_uninterp_extended(escape_extended_re($unbacked));
3703         }
3704         else {
3705             $re = re_uninterp(escape_str($unbacked));
3706         }
3707     } else {
3708         ($re) = $self->regcomp($kid, 1, $extended);
3709     }
3710     $flags .= "e" if $op->pmflags & PMf_EVAL;
3711     $flags .= "g" if $op->pmflags & PMf_GLOBAL;
3712     $flags .= "i" if $op->pmflags & PMf_FOLD;
3713     $flags .= "m" if $op->pmflags & PMf_MULTILINE;
3714     $flags .= "o" if $op->pmflags & PMf_KEEP;
3715     $flags .= "s" if $op->pmflags & PMf_SINGLELINE;
3716     $flags .= "x" if $extended;
3717     $flags = $substwords{$flags} if $substwords{$flags};
3718     if ($binop) {
3719         return $self->maybe_parens("$var =~ s"
3720                                    . double_delim($re, $repl) . $flags,
3721                                    $cx, 20);
3722     } else {
3723         return "s". double_delim($re, $repl) . $flags;
3724     }
3725 }
3726
3727 1;
3728 __END__
3729
3730 =head1 NAME
3731
3732 B::Deparse - Perl compiler backend to produce perl code
3733
3734 =head1 SYNOPSIS
3735
3736 B<perl> B<-MO=Deparse>[B<,-u>I<PACKAGE>][B<,-p>][B<,-q>][B<,-l>]
3737         [B<,-s>I<LETTERS>][B<,-x>I<LEVEL>] I<prog.pl>
3738
3739 =head1 DESCRIPTION
3740
3741 B::Deparse is a backend module for the Perl compiler that generates
3742 perl source code, based on the internal compiled structure that perl
3743 itself creates after parsing a program. The output of B::Deparse won't
3744 be exactly the same as the original source, since perl doesn't keep
3745 track of comments or whitespace, and there isn't a one-to-one
3746 correspondence between perl's syntactical constructions and their
3747 compiled form, but it will often be close. When you use the B<-p>
3748 option, the output also includes parentheses even when they are not
3749 required by precedence, which can make it easy to see if perl is
3750 parsing your expressions the way you intended.
3751
3752 Please note that this module is mainly new and untested code and is
3753 still under development, so it may change in the future.
3754
3755 =head1 OPTIONS
3756
3757 As with all compiler backend options, these must follow directly after
3758 the '-MO=Deparse', separated by a comma but not any white space.
3759
3760 =over 4
3761
3762 =item B<-l>
3763
3764 Add '#line' declarations to the output based on the line and file
3765 locations of the original code.
3766
3767 =item B<-p>
3768
3769 Print extra parentheses. Without this option, B::Deparse includes
3770 parentheses in its output only when they are needed, based on the
3771 structure of your program. With B<-p>, it uses parentheses (almost)
3772 whenever they would be legal. This can be useful if you are used to
3773 LISP, or if you want to see how perl parses your input. If you say
3774
3775     if ($var & 0x7f == 65) {print "Gimme an A!"}
3776     print ($which ? $a : $b), "\n";
3777     $name = $ENV{USER} or "Bob";
3778
3779 C<B::Deparse,-p> will print
3780
3781     if (($var & 0)) {
3782         print('Gimme an A!')
3783     };
3784     (print(($which ? $a : $b)), '???');
3785     (($name = $ENV{'USER'}) or '???')
3786
3787 which probably isn't what you intended (the C<'???'> is a sign that
3788 perl optimized away a constant value).
3789
3790 =item B<-P>
3791
3792 Disable prototype checking. With this option, all function calls are
3793 deparsed as if no prototype was defined for them. In other words,
3794
3795     perl -MO=Deparse,-P -e 'sub foo (\@) { 1 } foo @x'
3796
3797 will print
3798
3799     sub foo (\@) {
3800         1;
3801     }
3802     &foo(\@x);
3803
3804 making clear how the parameters are actually passed to C<foo>.
3805
3806 =item B<-q>
3807
3808 Expand double-quoted strings into the corresponding combinations of
3809 concatenation, uc, ucfirst, lc, lcfirst, quotemeta, and join. For
3810 instance, print
3811
3812     print "Hello, $world, @ladies, \u$gentlemen\E, \u\L$me!";
3813
3814 as
3815
3816     print 'Hello, ' . $world . ', ' . join($", @ladies) . ', '
3817           . ucfirst($gentlemen) . ', ' . ucfirst(lc $me . '!');
3818
3819 Note that the expanded form represents the way perl handles such
3820 constructions internally -- this option actually turns off the reverse
3821 translation that B::Deparse usually does. On the other hand, note that
3822 C<$x = "$y"> is not the same as C<$x = $y>: the former makes the value
3823 of $y into a string before doing the assignment.
3824
3825 =item B<-f>I<FILE>
3826
3827 Normally, B::Deparse deparses the main code of a program, and all the subs
3828 defined in the same file. To include subs defined in other files, pass the
3829 B<-f> option with the filename. You can pass the B<-f> option several times, to
3830 include more than one secondary file.  (Most of the time you don't want to
3831 use it at all.)  You can also use this option to include subs which are
3832 defined in the scope of a B<#line> directive with two parameters.
3833
3834 =item B<-s>I<LETTERS>
3835
3836 Tweak the style of B::Deparse's output. The letters should follow
3837 directly after the 's', with no space or punctuation. The following
3838 options are available:
3839
3840 =over 4
3841
3842 =item B<C>
3843
3844 Cuddle C<elsif>, C<else>, and C<continue> blocks. For example, print
3845
3846     if (...) {
3847          ...
3848     } else {
3849          ...
3850     }
3851
3852 instead of
3853
3854     if (...) {
3855          ...
3856     }
3857     else {
3858          ...
3859     }
3860
3861 The default is not to cuddle.
3862
3863 =item B<i>I<NUMBER>
3864
3865 Indent lines by multiples of I<NUMBER> columns. The default is 4 columns.
3866
3867 =item B<T>
3868
3869 Use tabs for each 8 columns of indent. The default is to use only spaces.
3870 For instance, if the style options are B<-si4T>, a line that's indented
3871 3 times will be preceded by one tab and four spaces; if the options were
3872 B<-si8T>, the same line would be preceded by three tabs.
3873
3874 =item B<v>I<STRING>B<.>
3875
3876 Print I<STRING> for the value of a constant that can't be determined
3877 because it was optimized away (mnemonic: this happens when a constant
3878 is used in B<v>oid context). The end of the string is marked by a period.
3879 The string should be a valid perl expression, generally a constant.
3880 Note that unless it's a number, it probably needs to be quoted, and on
3881 a command line quotes need to be protected from the shell. Some
3882 conventional values include 0, 1, 42, '', 'foo', and
3883 'Useless use of constant omitted' (which may need to be
3884 B<-sv"'Useless use of constant omitted'.">
3885 or something similar depending on your shell). The default is '???'.
3886 If you're using B::Deparse on a module or other file that's require'd,
3887 you shouldn't use a value that evaluates to false, since the customary
3888 true constant at the end of a module will be in void context when the
3889 file is compiled as a main program.
3890
3891 =back
3892
3893 =item B<-x>I<LEVEL>
3894
3895 Expand conventional syntax constructions into equivalent ones that expose
3896 their internal operation. I<LEVEL> should be a digit, with higher values
3897 meaning more expansion. As with B<-q>, this actually involves turning off
3898 special cases in B::Deparse's normal operations.
3899
3900 If I<LEVEL> is at least 3, for loops will be translated into equivalent
3901 while loops with continue blocks; for instance
3902
3903     for ($i = 0; $i < 10; ++$i) {
3904         print $i;
3905     }
3906
3907 turns into
3908
3909     $i = 0;
3910     while ($i < 10) {
3911         print $i;
3912     } continue {
3913         ++$i
3914     }
3915
3916 Note that in a few cases this translation can't be perfectly carried back
3917 into the source code -- if the loop's initializer declares a my variable,
3918 for instance, it won't have the correct scope outside of the loop.
3919
3920 If I<LEVEL> is at least 7, if statements will be translated into equivalent
3921 expressions using C<&&>, C<?:> and C<do {}>; for instance
3922
3923     print 'hi' if $nice;
3924     if ($nice) {
3925         print 'hi';
3926     }
3927     if ($nice) {
3928         print 'hi';
3929     } else {
3930         print 'bye';
3931     }
3932
3933 turns into
3934
3935     $nice and print 'hi';
3936     $nice and do { print 'hi' };
3937     $nice ? do { print 'hi' } : do { print 'bye' };
3938
3939 Long sequences of elsifs will turn into nested ternary operators, which
3940 B::Deparse doesn't know how to indent nicely.
3941
3942 =back
3943
3944 =head1 USING B::Deparse AS A MODULE
3945
3946 =head2 Synopsis
3947
3948     use B::Deparse;
3949     $deparse = B::Deparse->new("-p", "-sC");
3950     $body = $deparse->coderef2text(\&func);
3951     eval "sub func $body"; # the inverse operation
3952
3953 =head2 Description
3954
3955 B::Deparse can also be used on a sub-by-sub basis from other perl
3956 programs.
3957
3958 =head2 new
3959
3960     $deparse = B::Deparse->new(OPTIONS)
3961
3962 Create an object to store the state of a deparsing operation and any
3963 options. The options are the same as those that can be given on the
3964 command line (see L</OPTIONS>); options that are separated by commas
3965 after B<-MO=Deparse> should be given as separate strings. Some
3966 options, like B<-u>, don't make sense for a single subroutine, so
3967 don't pass them.
3968
3969 =head2 ambient_pragmas
3970
3971     $deparse->ambient_pragmas(strict => 'all', '$[' => $[);
3972
3973 The compilation of a subroutine can be affected by a few compiler
3974 directives, B<pragmas>. These are:
3975
3976 =over 4
3977
3978 =item *
3979
3980 use strict;
3981
3982 =item *
3983
3984 use warnings;
3985
3986 =item *
3987
3988 Assigning to the special variable $[
3989
3990 =item *
3991
3992 use integer;
3993
3994 =item *
3995
3996 use bytes;
3997
3998 =item *
3999
4000 use utf8;
4001
4002 =item *
4003
4004 use re;
4005
4006 =back
4007
4008 Ordinarily, if you use B::Deparse on a subroutine which has
4009 been compiled in the presence of one or more of these pragmas,
4010 the output will include statements to turn on the appropriate
4011 directives. So if you then compile the code returned by coderef2text,
4012 it will behave the same way as the subroutine which you deparsed.
4013
4014 However, you may know that you intend to use the results in a
4015 particular context, where some pragmas are already in scope. In
4016 this case, you use the B<ambient_pragmas> method to describe the
4017 assumptions you wish to make.
4018
4019 Not all of the options currently have any useful effect. See
4020 L</BUGS> for more details.
4021
4022 The parameters it accepts are:
4023
4024 =over 4
4025
4026 =item strict
4027
4028 Takes a string, possibly containing several values separated
4029 by whitespace. The special values "all" and "none" mean what you'd
4030 expect.
4031
4032     $deparse->ambient_pragmas(strict => 'subs refs');
4033
4034 =item $[
4035
4036 Takes a number, the value of the array base $[.
4037
4038 =item bytes
4039
4040 =item utf8
4041
4042 =item integer
4043
4044 If the value is true, then the appropriate pragma is assumed to
4045 be in the ambient scope, otherwise not.
4046
4047 =item re
4048
4049 Takes a string, possibly containing a whitespace-separated list of
4050 values. The values "all" and "none" are special. It's also permissible
4051 to pass an array reference here.
4052
4053     $deparser->ambient_pragmas(re => 'eval');
4054
4055
4056 =item warnings
4057
4058 Takes a string, possibly containing a whitespace-separated list of
4059 values. The values "all" and "none" are special, again. It's also
4060 permissible to pass an array reference here.
4061
4062     $deparser->ambient_pragmas(warnings => [qw[void io]]);
4063
4064 If one of the values is the string "FATAL", then all the warnings
4065 in that list will be considered fatal, just as with the B<warnings>
4066 pragma itself. Should you need to specify that some warnings are
4067 fatal, and others are merely enabled, you can pass the B<warnings>
4068 parameter twice:
4069
4070     $deparser->ambient_pragmas(
4071         warnings => 'all',
4072         warnings => [FATAL => qw/void io/],
4073     );
4074
4075 See L<perllexwarn> for more information about lexical warnings.
4076
4077 =item hint_bits
4078
4079 =item warning_bits
4080
4081 These two parameters are used to specify the ambient pragmas in
4082 the format used by the special variables $^H and ${^WARNING_BITS}.
4083
4084 They exist principally so that you can write code like:
4085
4086     { my ($hint_bits, $warning_bits);
4087     BEGIN {($hint_bits, $warning_bits) = ($^H, ${^WARNING_BITS})}
4088     $deparser->ambient_pragmas (
4089         hint_bits    => $hint_bits,
4090         warning_bits => $warning_bits,
4091         '$['         => 0 + $[
4092     ); }
4093
4094 which specifies that the ambient pragmas are exactly those which
4095 are in scope at the point of calling.
4096
4097 =back
4098
4099 =head2 coderef2text
4100
4101     $body = $deparse->coderef2text(\&func)
4102     $body = $deparse->coderef2text(sub ($$) { ... })
4103
4104 Return source code for the body of a subroutine (a block, optionally
4105 preceded by a prototype in parens), given a reference to the
4106 sub. Because a subroutine can have no names, or more than one name,
4107 this method doesn't return a complete subroutine definition -- if you
4108 want to eval the result, you should prepend "sub subname ", or "sub "
4109 for an anonymous function constructor. Unless the sub was defined in
4110 the main:: package, the code will include a package declaration.
4111
4112 =head1 BUGS
4113
4114 =over 4
4115
4116 =item *
4117
4118 The only pragmas to be completely supported are: C<use warnings>,
4119 C<use strict 'refs'>, C<use bytes>, and C<use integer>. (C<$[>, which
4120 behaves like a pragma, is also supported.)
4121
4122 Excepting those listed above, we're currently unable to guarantee that
4123 B::Deparse will produce a pragma at the correct point in the program.
4124 Since the effects of pragmas are often lexically scoped, this can mean
4125 that the pragma holds sway over a different portion of the program
4126 than in the input file.
4127
4128 =item *
4129
4130 In fact, the above is a specific instance of a more general problem:
4131 we can't guarantee to produce BEGIN blocks or C<use> declarations in
4132 exactly the right place. So if you use a module which affects compilation
4133 (such as by over-riding keywords, overloading constants or whatever)
4134 then the output code might not work as intended.
4135
4136 This is the most serious outstanding problem, and will be very hard
4137 to fix.
4138
4139 =item *
4140
4141 If a keyword is over-ridden, and your program explicitly calls
4142 the built-in version by using CORE::keyword, the output of B::Deparse
4143 will not reflect this. If you run the resulting code, it will call
4144 the over-ridden version rather than the built-in one. (Maybe there
4145 should be an option to B<always> print keyword calls as C<CORE::name>.)
4146
4147 =item *
4148
4149 C<sort foo (1, 2, 3)> comes out as C<sort (foo 1, 2, 3)>, which
4150 causes perl to issue a warning.
4151
4152 The obvious fix doesn't work, because these are different:
4153
4154     print (FOO 1, 2, 3), 4, 5, 6;
4155     print FOO (1, 2, 3), 4, 5, 6;
4156
4157 =item *
4158
4159 Constants (other than simple strings or numbers) don't work properly.
4160 Pathological examples that fail (and probably always will) include:
4161
4162     use constant E2BIG => ($!=7);
4163     use constant x=>\$x; print x
4164
4165 The following could (and should) be made to work:
4166
4167     use constant regex => qr/blah/;
4168     print regex;
4169
4170 =item *
4171
4172 An input file that uses source filtering probably won't be deparsed into
4173 runnable code, because it will still include the B<use> declaration
4174 for the source filtering module, even though the code that is
4175 produced is already ordinary Perl which shouldn't be filtered again.
4176
4177 =item *
4178
4179 There are probably many more bugs on non-ASCII platforms (EBCDIC).
4180
4181 =back
4182
4183 =head1 AUTHOR
4184
4185 Stephen McCamant <smcc@CSUA.Berkeley.EDU>, based on an earlier
4186 version by Malcolm Beattie <mbeattie@sable.ox.ac.uk>, with
4187 contributions from Gisle Aas, James Duncan, Albert Dvornik, Robin
4188 Houston, Hugo van der Sanden, Gurusamy Sarathy, Nick Ing-Simmons,
4189 and Rafael Garcia-Suarez.
4190
4191 =cut