ext/B/B/Deparse.pm

   1 # B::Deparse.pm
   2 # Copyright (c) 1998, 1999, 2000 Stephen McCamant. All rights reserved.
   3 # This module is free software; you can redistribute and/or modify
   4 # it under the same terms as Perl itself.
   5
   6 # This is based on the module of the same name by Malcolm Beattie,
   7 # but essentially none of his code remains.
   8
   9 package B::Deparse;
  10 use Carp;
  11 use B qw(class main_root main_start main_cv svref_2object opnumber perlstring
  12          OPf_WANT OPf_WANT_VOID OPf_WANT_SCALAR OPf_WANT_LIST
  13          OPf_KIDS OPf_REF OPf_STACKED OPf_SPECIAL OPf_MOD
  14          OPpLVAL_INTRO OPpOUR_INTRO OPpENTERSUB_AMPER OPpSLICE OPpCONST_BARE
  15          OPpTRANS_SQUASH OPpTRANS_DELETE OPpTRANS_COMPLEMENT OPpTARGET_MY
  16          OPpCONST_ARYBASE OPpEXISTS_SUB OPpSORT_NUMERIC OPpSORT_INTEGER
  17          OPpSORT_REVERSE
  18          SVf_IOK SVf_NOK SVf_ROK SVf_POK SVpad_OUR
  19          CVf_METHOD CVf_LOCKED CVf_LVALUE
  20          PMf_KEEP PMf_GLOBAL PMf_CONTINUE PMf_EVAL PMf_ONCE PMf_SKIPWHITE
  21          PMf_MULTILINE PMf_SINGLELINE PMf_FOLD PMf_EXTENDED);
  22 $VERSION = 0.63;
  23 use strict;
  24 use vars qw/$AUTOLOAD/;
  25 use warnings ();
  26
  27 # Changes between 0.50 and 0.51:
  28 # - fixed nulled leave with live enter in sort { }
  29 # - fixed reference constants (\"str")
  30 # - handle empty programs gracefully
  31 # - handle infinte loops (for (;;) {}, while (1) {})
  32 # - differentiate between `for my $x ...' and `my $x; for $x ...'
  33 # - various minor cleanups
  34 # - moved globals into an object
  35 # - added `-u', like B::C
  36 # - package declarations using cop_stash
  37 # - subs, formats and code sorted by cop_seq
  38 # Changes between 0.51 and 0.52:
  39 # - added pp_threadsv (special variables under USE_5005THREADS)
  40 # - added documentation
  41 # Changes between 0.52 and 0.53:
  42 # - many changes adding precedence contexts and associativity
  43 # - added `-p' and `-s' output style options
  44 # - various other minor fixes
  45 # Changes between 0.53 and 0.54:
  46 # - added support for new `for (1..100)' optimization,
  47 #   thanks to Gisle Aas
  48 # Changes between 0.54 and 0.55:
  49 # - added support for new qr// construct
  50 # - added support for new pp_regcreset OP
  51 # Changes between 0.55 and 0.56:
  52 # - tested on base/*.t, cmd/*.t, comp/*.t, io/*.t
  53 # - fixed $# on non-lexicals broken in last big rewrite
  54 # - added temporary fix for change in opcode of OP_STRINGIFY
  55 # - fixed problem in 0.54's for() patch in `for (@ary)'
  56 # - fixed precedence in conditional of ?:
  57 # - tweaked list paren elimination in `my($x) = @_'
  58 # - made continue-block detection trickier wrt. null ops
  59 # - fixed various prototype problems in pp_entersub
  60 # - added support for sub prototypes that never get GVs
  61 # - added unquoting for special filehandle first arg in truncate
  62 # - print doubled rv2gv (a bug) as `*{*GV}' instead of illegal `**GV'
  63 # - added semicolons at the ends of blocks
  64 # - added -l `#line' declaration option -- fixes cmd/subval.t 27,28
  65 # Changes between 0.56 and 0.561:
  66 # - fixed multiply-declared my var in pp_truncate (thanks to Sarathy)
  67 # - used new B.pm symbolic constants (done by Nick Ing-Simmons)
  68 # Changes between 0.561 and 0.57:
  69 # - stylistic changes to symbolic constant stuff
  70 # - handled scope in s///e replacement code
  71 # - added unquote option for expanding "" into concats, etc.
  72 # - split method and proto parts of pp_entersub into separate functions
  73 # - various minor cleanups
  74 # Changes after 0.57:
  75 # - added parens in \&foo (patch by Albert Dvornik)
  76 # Changes between 0.57 and 0.58:
  77 # - fixed `0' statements that weren't being printed
  78 # - added methods for use from other programs
  79 #   (based on patches from James Duncan and Hugo van der Sanden)
  80 # - added -si and -sT to control indenting (also based on a patch from Hugo)
  81 # - added -sv to print something else instead of '???'
  82 # - preliminary version of utf8 tr/// handling
  83 # Changes after 0.58:
  84 # - uses of $op->ppaddr changed to new $op->name (done by Sarathy)
  85 # - added support for Hugo's new OP_SETSTATE (like nextstate)
  86 # Changes between 0.58 and 0.59
  87 # - added support for Chip's OP_METHOD_NAMED
  88 # - added support for Ilya's OPpTARGET_MY optimization
  89 # - elided arrows before `()' subscripts when possible
  90 # Changes between 0.59 and 0.60
  91 # - support for method attribues was added
  92 # - some warnings fixed
  93 # - separate recognition of constant subs
  94 # - rewrote continue block handling, now recoginizing for loops
  95 # - added more control of expanding control structures
  96 # Changes between 0.60 and 0.61 (mostly by Robin Houston)
  97 # - many bug-fixes
  98 # - support for pragmas and 'use'
  99 # - support for the little-used $[ variable
 100 # - support for __DATA__ sections
 101 # - UTF8 support
 102 # - BEGIN, CHECK, INIT and END blocks
 103 # - scoping of subroutine declarations fixed
 104 # - compile-time output from the input program can be suppressed, so that the
 105 #   output is just the deparsed code. (a change to O.pm in fact)
 106 # - our() declarations
 107 # - *all* the known bugs are now listed in the BUGS section
 108 # - comprehensive test mechanism (TEST -deparse)
 109 # Changes between 0.62 and 0.63 (mostly by Rafael Garcia-Suarez)
 110 # - bug-fixes
 111 # - new switch -P
 112 # - support for command-line switches (-l, -0, etc.)
 113
 114 # Todo:
 115 #  (See also BUGS section at the end of this file)
 116 #
 117 # - finish tr/// changes
 118 # - add option for even more parens (generalize \&foo change)
 119 # - left/right context
 120 # - treat top-level block specially for incremental output
 121 # - copy comments (look at real text with $^P?)
 122 # - avoid semis in one-statement blocks
 123 # - associativity of &&=, ||=, ?:
 124 # - ',' => '=>' (auto-unquote?)
 125 # - break long lines ("\r" as discretionary break?)
 126 # - configurable syntax highlighting: ANSI color, HTML, TeX, etc.
 127 # - more style options: brace style, hex vs. octal, quotes, ...
 128 # - print big ints as hex/octal instead of decimal (heuristic?)
 129 # - handle `my $x if 0'?
 130 # - coordinate with Data::Dumper (both directions? see previous)
 131 # - version using op_next instead of op_first/sibling?
 132 # - avoid string copies (pass arrays, one big join?)
 133 # - here-docs?
 134
 135 # Tests that will always fail:
 136 # (see t/TEST for the short list)
 137
 138 # Object fields (were globals):
 139 #
 140 # avoid_local:
 141 # (local($a), local($b)) and local($a, $b) have the same internal
 142 # representation but the short form looks better. We notice we can
 143 # use a large-scale local when checking the list, but need to prevent
 144 # individual locals too. This hash holds the addresses of OPs that
 145 # have already had their local-ness accounted for. The same thing
 146 # is done with my().
 147 #
 148 # curcv:
 149 # CV for current sub (or main program) being deparsed
 150 #
 151 # curcvlex:
 152 # Cached hash of lexical variables for curcv: keys are names,
 153 # each value is an array of pairs, indicating the cop_seq of scopes
 154 # in which a var of that name is valid.
 155 #
 156 # curcop:
 157 # COP for statement being deparsed
 158 #
 159 # curstash:
 160 # name of the current package for deparsed code
 161 #
 162 # subs_todo:
 163 # array of [cop_seq, CV, is_format?] for subs and formats we still
 164 # want to deparse
 165 #
 166 # protos_todo:
 167 # as above, but [name, prototype] for subs that never got a GV
 168 #
 169 # subs_done, forms_done:
 170 # keys are addresses of GVs for subs and formats we've already
 171 # deparsed (or at least put into subs_todo)
 172 #
 173 # subs_declared
 174 # keys are names of subs for which we've printed declarations.
 175 # That means we can omit parentheses from the arguments.
 176 #
 177 # subs_deparsed
 178 # Keeps track of fully qualified names of all deparsed subs.
 179 #
 180 # parens: -p
 181 # linenums: -l
 182 # unquote: -q
 183 # cuddle: ` ' or `\n', depending on -sC
 184 # indent_size: -si
 185 # use_tabs: -sT
 186 # ex_const: -sv
 187
 188 # A little explanation of how precedence contexts and associativity
 189 # work:
 190 #
 191 # deparse() calls each per-op subroutine with an argument $cx (short
 192 # for context, but not the same as the cx* in the perl core), which is
 193 # a number describing the op's parents in terms of precedence, whether
 194 # they're inside an expression or at statement level, etc.  (see
 195 # chart below). When ops with children call deparse on them, they pass
 196 # along their precedence. Fractional values are used to implement
 197 # associativity (`($x + $y) + $z' => `$x + $y + $y') and related
 198 # parentheses hacks. The major disadvantage of this scheme is that
 199 # it doesn't know about right sides and left sides, so say if you
 200 # assign a listop to a variable, it can't tell it's allowed to leave
 201 # the parens off the listop.
 202
 203 # Precedences:
 204 # 26             [TODO] inside interpolation context ("")
 205 # 25 left        terms and list operators (leftward)
 206 # 24 left        ->
 207 # 23 nonassoc    ++ --
 208 # 22 right       **
 209 # 21 right       ! ~ \ and unary + and -
 210 # 20 left        =~ !~
 211 # 19 left        * / % x
 212 # 18 left        + - .
 213 # 17 left        << >>
 214 # 16 nonassoc    named unary operators
 215 # 15 nonassoc    < > <= >= lt gt le ge
 216 # 14 nonassoc    == != <=> eq ne cmp
 217 # 13 left        &
 218 # 12 left        | ^
 219 # 11 left        &&
 220 # 10 left        ||
 221 #  9 nonassoc    ..  ...
 222 #  8 right       ?:
 223 #  7 right       = += -= *= etc.
 224 #  6 left        , =>
 225 #  5 nonassoc    list operators (rightward)
 226 #  4 right       not
 227 #  3 left        and
 228 #  2 left        or xor
 229 #  1             statement modifiers
 230 #  0             statement level
 231
 232 # Also, lineseq may pass a fourth parameter to the pp_ routines:
 233 # if present, the fourth parameter is passed on by deparse.
 234 #
 235 # If present and true, it means that the op exists directly as
 236 # part of a lineseq. Currently it's only used by scopeop to
 237 # decide whether its results need to be enclosed in a do {} block.
 238
 239 # Nonprinting characters with special meaning:
 240 # \cS - steal parens (see maybe_parens_unop)
 241 # \n - newline and indent
 242 # \t - increase indent
 243 # \b - decrease indent (`outdent')
 244 # \f - flush left (no indent)
 245 # \cK - kill following semicolon, if any
 246
 247 sub null {
 248     my $op = shift;
 249     return class($op) eq "NULL";
 250 }
 251
 252 sub todo {
 253     my $self = shift;
 254     my($cv, $is_form) = @_;
 255     return unless ($cv->FILE eq $0 || exists $self->{files}{$cv->FILE});
 256     my $seq;
 257     if (!null($cv->START) and is_state($cv->START)) {
 258         $seq = $cv->START->cop_seq;
 259     } else {
 260         $seq = 0;
 261     }
 262     push @{$self->{'subs_todo'}}, [$seq, $cv, $is_form];
 263     unless ($is_form || class($cv->STASH) eq 'SPECIAL') {
 264         $self->{'subs_deparsed'}{$cv->STASH->NAME."::".$cv->GV->NAME} = 1;
 265     }
 266 }
 267
 268 sub next_todo {
 269     my $self = shift;
 270     my $ent = shift @{$self->{'subs_todo'}};
 271     my $cv = $ent->[1];
 272     my $gv = $cv->GV;
 273     my $name = $self->gv_name($gv);
 274     if ($ent->[2]) {
 275         return "format $name =\n"
 276             . $self->deparse_format($ent->[1]). "\n";
 277     } else {
 278         $self->{'subs_declared'}{$name} = 1;
 279         if ($name eq "BEGIN") {
 280             my $use_dec = $self->begin_is_use($cv);
 281             if (defined ($use_dec)) {
 282                 return () if 0 == length($use_dec);
 283                 return $use_dec;
 284             }
 285         }
 286         my $l = '';
 287         if ($self->{'linenums'}) {
 288             my $line = $gv->LINE;
 289             my $file = $gv->FILE;
 290             $l = "\n\f#line $line \"$file\"\n";
 291         }
 292         return "${l}sub $name " . $self->deparse_sub($cv);
 293     }
 294 }
 295
 296 # Return a "use" declaration for this BEGIN block, if appropriate
 297 sub begin_is_use {
 298     my ($self, $cv) = @_;
 299     my $root = $cv->ROOT;
 300     local @$self{qw'curcv curcvlex'} = ($cv);
 301 #require B::Debug;
 302 #B::walkoptree($cv->ROOT, "debug");
 303     my $lineseq = $root->first;
 304     return if $lineseq->name ne "lineseq";
 305
 306     my $req_op = $lineseq->first->sibling;
 307     return if $req_op->name ne "require";
 308
 309     my $module;
 310     if ($req_op->first->private & OPpCONST_BARE) {
 311         # Actually it should always be a bareword
 312         $module = $self->const_sv($req_op->first)->PV;
 313         $module =~ s[/][::]g;
 314         $module =~ s/.pm$//;
 315     }
 316     else {
 317         $module = const($self->const_sv($req_op->first));
 318     }
 319
 320     my $version;
 321     my $version_op = $req_op->sibling;
 322     return if class($version_op) eq "NULL";
 323     if ($version_op->name eq "lineseq") {
 324         # We have a version parameter; skip nextstate & pushmark
 325         my $constop = $version_op->first->next->next;
 326
 327         return unless $self->const_sv($constop)->PV eq $module;
 328         $constop = $constop->sibling;
 329         $version = $self->const_sv($constop)->int_value;
 330         $constop = $constop->sibling;
 331         return if $constop->name ne "method_named";
 332         return if $self->const_sv($constop)->PV ne "VERSION";
 333     }
 334
 335     $lineseq = $version_op->sibling;
 336     return if $lineseq->name ne "lineseq";
 337     my $entersub = $lineseq->first->sibling;
 338     if ($entersub->name eq "stub") {
 339         return "use $module $version ();\n" if defined $version;
 340         return "use $module ();\n";
 341     }
 342     return if $entersub->name ne "entersub";
 343
 344     # See if there are import arguments
 345     my $args = '';
 346
 347     my $svop = $entersub->first->sibling; # Skip over pushmark
 348     return unless $self->const_sv($svop)->PV eq $module;
 349
 350     # Pull out the arguments
 351     for ($svop=$svop->sibling; $svop->name ne "method_named";
 352                 $svop = $svop->sibling) {
 353         $args .= ", " if length($args);
 354         $args .= $self->deparse($svop, 6);
 355     }
 356
 357     my $use = 'use';
 358     my $method_named = $svop;
 359     return if $method_named->name ne "method_named";
 360     my $method_name = $self->const_sv($method_named)->PV;
 361
 362     if ($method_name eq "unimport") {
 363         $use = 'no';
 364     }
 365
 366     # Certain pragmas are dealt with using hint bits,
 367     # so we ignore them here
 368     if ($module eq 'strict' || $module eq 'integer'
 369         || $module eq 'bytes' || $module eq 'warnings') {
 370         return "";
 371     }
 372
 373     if (defined $version && length $args) {
 374         return "$use $module $version ($args);\n";
 375     } elsif (defined $version) {
 376         return "$use $module $version;\n";
 377     } elsif (length $args) {
 378         return "$use $module ($args);\n";
 379     } else {
 380         return "$use $module;\n";
 381     }
 382 }
 383
 384 sub stash_subs {
 385     my ($self, $pack) = @_;
 386     my (@ret, $stash);
 387     if (!defined $pack) {
 388         $pack = '';
 389         $stash = \%::;
 390     }
 391     else {
 392         $pack =~ s/(::)?$/::/;
 393         no strict 'refs';
 394         $stash = \%$pack;
 395     }
 396     my %stash = svref_2object($stash)->ARRAY;
 397     while (my ($key, $val) = each %stash) {
 398         next if $key eq 'main::';       # avoid infinite recursion
 399         my $class = class($val);
 400         if ($class eq "PV") {
 401             # Just a prototype. As an ugly but fairly effective way
 402             # to find out if it belongs here is to see if the AUTOLOAD
 403             # (if any) for the stash was defined in one of our files.
 404             my $A = $stash{"AUTOLOAD"};
 405             if (defined ($A) && class($A) eq "GV" && defined($A->CV)
 406                 && class($A->CV) eq "CV") {
 407                 my $AF = $A->FILE;
 408                 next unless $AF eq $0 || exists $self->{'files'}{$AF};
 409             }
 410             push @{$self->{'protos_todo'}}, [$pack . $key, $val->PV];
 411         } elsif ($class eq "IV") {
 412             # Just a name. As above.
 413             my $A = $stash{"AUTOLOAD"};
 414             if (defined ($A) && class($A) eq "GV" && defined($A->CV)
 415                 && class($A->CV) eq "CV") {
 416                 my $AF = $A->FILE;
 417                 next unless $AF eq $0 || exists $self->{'files'}{$AF};
 418             }
 419             push @{$self->{'protos_todo'}}, [$pack . $key, undef];
 420         } elsif ($class eq "GV") {
 421             if (class(my $cv = $val->CV) ne "SPECIAL") {
 422                 next if $self->{'subs_done'}{$$val}++;
 423                 next if $$val != ${$cv->GV};   # Ignore imposters
 424                 $self->todo($cv, 0);
 425             }
 426             if (class(my $cv = $val->FORM) ne "SPECIAL") {
 427                 next if $self->{'forms_done'}{$$val}++;
 428                 next if $$val != ${$cv->GV};   # Ignore imposters
 429                 $self->todo($cv, 1);
 430             }
 431             if (class($val->HV) ne "SPECIAL" && $key =~ /::$/) {
 432                 $self->stash_subs($pack . $key);
 433             }
 434         }
 435     }
 436 }
 437
 438 sub print_protos {
 439     my $self = shift;
 440     my $ar;
 441     my @ret;
 442     foreach $ar (@{$self->{'protos_todo'}}) {
 443         my $proto = (defined $ar->[1] ? " (". $ar->[1] . ")" : "");
 444         push @ret, "sub " . $ar->[0] .  "$proto;\n";
 445     }
 446     delete $self->{'protos_todo'};
 447     return @ret;
 448 }
 449
 450 sub style_opts {
 451     my $self = shift;
 452     my $opts = shift;
 453     my $opt;
 454     while (length($opt = substr($opts, 0, 1))) {
 455         if ($opt eq "C") {
 456             $self->{'cuddle'} = " ";
 457             $opts = substr($opts, 1);
 458         } elsif ($opt eq "i") {
 459             $opts =~ s/^i(\d+)//;
 460             $self->{'indent_size'} = $1;
 461         } elsif ($opt eq "T") {
 462             $self->{'use_tabs'} = 1;
 463             $opts = substr($opts, 1);
 464         } elsif ($opt eq "v") {
 465             $opts =~ s/^v([^.]*)(.|$)//;
 466             $self->{'ex_const'} = $1;
 467         }
 468     }
 469 }
 470
 471 sub new {
 472     my $class = shift;
 473     my $self = bless {}, $class;
 474     $self->{'subs_todo'} = [];
 475     $self->{'files'} = {};
 476     $self->{'curstash'} = "main";
 477     $self->{'curcop'} = undef;
 478     $self->{'cuddle'} = "\n";
 479     $self->{'indent_size'} = 4;
 480     $self->{'use_tabs'} = 0;
 481     $self->{'expand'} = 0;
 482     $self->{'unquote'} = 0;
 483     $self->{'linenums'} = 0;
 484     $self->{'parens'} = 0;
 485     $self->{'ex_const'} = "'???'";
 486
 487     $self->{'ambient_arybase'} = 0;
 488     $self->{'ambient_warnings'} = undef; # Assume no lexical warnings
 489     $self->{'ambient_hints'} = 0;
 490     $self->init();
 491
 492     while (my $arg = shift @_) {
 493         if ($arg =~ /^-f(.*)/) {
 494             $self->{'files'}{$1} = 1;
 495         } elsif ($arg eq "-p") {
 496             $self->{'parens'} = 1;
 497         } elsif ($arg eq "-P") {
 498             $self->{'noproto'} = 1;
 499         } elsif ($arg eq "-l") {
 500             $self->{'linenums'} = 1;
 501         } elsif ($arg eq "-q") {
 502             $self->{'unquote'} = 1;
 503         } elsif (substr($arg, 0, 2) eq "-s") {
 504             $self->style_opts(substr $arg, 2);
 505         } elsif ($arg =~ /^-x(\d)$/) {
 506             $self->{'expand'} = $1;
 507         }
 508     }
 509     return $self;
 510 }
 511
 512 {
 513     # Mask out the bits that L<warnings::register> uses
 514     my $WARN_MASK;
 515     BEGIN {
 516         $WARN_MASK = $warnings::Bits{all} | $warnings::DeadBits{all};
 517     }
 518     sub WARN_MASK () {
 519         return $WARN_MASK;
 520     }
 521 }
 522
 523 # Initialise the contextual information, either from
 524 # defaults provided with the ambient_pragmas method,
 525 # or from perl's own defaults otherwise.
 526 sub init {
 527     my $self = shift;
 528
 529     $self->{'arybase'}  = $self->{'ambient_arybase'};
 530     $self->{'warnings'} = defined ($self->{'ambient_warnings'})
 531                                 ? $self->{'ambient_warnings'} & WARN_MASK
 532                                 : undef;
 533     $self->{'hints'}    = $self->{'ambient_hints'} & 0xFF;
 534
 535     # also a convenient place to clear out subs_declared
 536     delete $self->{'subs_declared'};
 537 }
 538
 539 sub compile {
 540     my(@args) = @_;
 541     return sub {
 542         my $self = B::Deparse->new(@args);
 543         # First deparse command-line args
 544         if (defined $^I) { # deparse -i
 545             print q(BEGIN { $^I = ).perlstring($^I).qq(; }\n);
 546         }
 547         if ($^W) { # deparse -w
 548             print qq(BEGIN { \$^W = $^W; }\n);
 549         }
 550         if ($/ ne "\n" or defined $O::savebackslash) { # deparse -l and -0
 551             my $fs = perlstring($/) || 'undef';
 552             my $bs = perlstring($O::savebackslash) || 'undef';
 553             print qq(BEGIN { \$/ = $fs; \$\\ = $bs; }\n);
 554         }
 555         my @BEGINs  = B::begin_av->isa("B::AV") ? B::begin_av->ARRAY : ();
 556         my @INITs   = B::init_av->isa("B::AV") ? B::init_av->ARRAY : ();
 557         my @ENDs    = B::end_av->isa("B::AV") ? B::end_av->ARRAY : ();
 558         for my $block (@BEGINs, @INITs, @ENDs) {
 559             $self->todo($block, 0);
 560         }
 561         $self->stash_subs();
 562         $self->{'curcv'} = main_cv;
 563         $self->{'curcvlex'} = undef;
 564         print $self->print_protos;
 565         @{$self->{'subs_todo'}} =
 566           sort {$a->[0] <=> $b->[0]} @{$self->{'subs_todo'}};
 567         print $self->indent($self->deparse(main_root, 0)), "\n"
 568           unless null main_root;
 569         my @text;
 570         while (scalar(@{$self->{'subs_todo'}})) {
 571             push @text, $self->next_todo;
 572         }
 573         print $self->indent(join("", @text)), "\n" if @text;
 574
 575         # Print __DATA__ section, if necessary
 576         no strict 'refs';
 577         my $laststash = defined $self->{'curcop'}
 578             ? $self->{'curcop'}->stash->NAME : $self->{'curstash'};
 579         if (defined *{$laststash."::DATA"}{IO}) {
 580             print "__DATA__\n";
 581             print readline(*{$laststash."::DATA"});
 582         }
 583     }
 584 }
 585
 586 sub coderef2text {
 587     my $self = shift;
 588     my $sub = shift;
 589     croak "Usage: ->coderef2text(CODEREF)" unless UNIVERSAL::isa($sub, "CODE");
 590
 591     $self->init();
 592     return $self->indent($self->deparse_sub(svref_2object($sub)));
 593 }
 594
 595 sub ambient_pragmas {
 596     my $self = shift;
 597     my ($arybase, $hint_bits, $warning_bits) = (0, 0);
 598
 599     while (@_ > 1) {
 600         my $name = shift();
 601         my $val  = shift();
 602
 603         if ($name eq 'strict') {
 604             require strict;
 605
 606             if ($val eq 'none') {
 607                 $hint_bits &= ~strict::bits(qw/refs subs vars/);
 608                 next();
 609             }
 610
 611             my @names;
 612             if ($val eq "all") {
 613                 @names = qw/refs subs vars/;
 614             }
 615             elsif (ref $val) {
 616                 @names = @$val;
 617             }
 618             else {
 619                 @names = split' ', $val;
 620             }
 621             $hint_bits |= strict::bits(@names);
 622         }
 623
 624         elsif ($name eq '$[') {
 625             $arybase = $val;
 626         }
 627
 628         elsif ($name eq 'integer'
 629             || $name eq 'bytes'
 630             || $name eq 'utf8') {
 631             require "$name.pm";
 632             if ($val) {
 633                 $hint_bits |= ${$::{"${name}::"}{"hint_bits"}};
 634             }
 635             else {
 636                 $hint_bits &= ~${$::{"${name}::"}{"hint_bits"}};
 637             }
 638         }
 639
 640         elsif ($name eq 're') {
 641             require re;
 642             if ($val eq 'none') {
 643                 $hint_bits &= ~re::bits(qw/taint eval/);
 644                 next();
 645             }
 646
 647             my @names;
 648             if ($val eq 'all') {
 649                 @names = qw/taint eval/;
 650             }
 651             elsif (ref $val) {
 652                 @names = @$val;
 653             }
 654             else {
 655                 @names = split' ',$val;
 656             }
 657             $hint_bits |= re::bits(@names);
 658         }
 659
 660         elsif ($name eq 'warnings') {
 661             if ($val eq 'none') {
 662                 $warning_bits = $warnings::NONE;
 663                 next();
 664             }
 665
 666             my @names;
 667             if (ref $val) {
 668                 @names = @$val;
 669             }
 670             else {
 671                 @names = split/\s+/, $val;
 672             }
 673
 674             $warning_bits = $warnings::NONE if !defined ($warning_bits);
 675             $warning_bits |= warnings::bits(@names);
 676         }
 677
 678         elsif ($name eq 'warning_bits') {
 679             $warning_bits = $val;
 680         }
 681
 682         elsif ($name eq 'hint_bits') {
 683             $hint_bits = $val;
 684         }
 685
 686         else {
 687             croak "Unknown pragma type: $name";
 688         }
 689     }
 690     if (@_) {
 691         croak "The ambient_pragmas method expects an even number of args";
 692     }
 693
 694     $self->{'ambient_arybase'} = $arybase;
 695     $self->{'ambient_warnings'} = $warning_bits;
 696     $self->{'ambient_hints'} = $hint_bits;
 697 }
 698
 699 sub deparse {
 700     my $self = shift;
 701     my($op, $cx, $flags) = @_;
 702
 703     Carp::confess("Null op in deparse") if !defined($op)
 704                                         || class($op) eq "NULL";
 705     my $meth = "pp_" . $op->name;
 706     if (is_scope($op)) {
 707         return $self->$meth($op, $cx, $flags);
 708     }
 709     return $self->$meth($op, $cx);
 710 }
 711
 712 sub indent {
 713     my $self = shift;
 714     my $txt = shift;
 715     my @lines = split(/\n/, $txt);
 716     my $leader = "";
 717     my $level = 0;
 718     my $line;
 719     for $line (@lines) {
 720         my $cmd = substr($line, 0, 1);
 721         if ($cmd eq "\t" or $cmd eq "\b") {
 722             $level += ($cmd eq "\t" ? 1 : -1) * $self->{'indent_size'};
 723             if ($self->{'use_tabs'}) {
 724                 $leader = "\t" x ($level / 8) . " " x ($level % 8);
 725             } else {
 726                 $leader = " " x $level;
 727             }
 728             $line = substr($line, 1);
 729         }
 730         if (substr($line, 0, 1) eq "\f") {
 731             $line = substr($line, 1); # no indent
 732         } else {
 733             $line = $leader . $line;
 734         }
 735         $line =~ s/\cK;?//g;
 736     }
 737     return join("\n", @lines);
 738 }
 739
 740 sub deparse_sub {
 741     my $self = shift;
 742     my $cv = shift;
 743     my $proto = "";
 744 Carp::confess("NULL in deparse_sub") if !defined($cv) || $cv->isa("B::NULL");
 745 Carp::confess("SPECIAL in deparse_sub") if $cv->isa("B::SPECIAL");
 746     local $self->{'curcop'} = $self->{'curcop'};
 747     if ($cv->FLAGS & SVf_POK) {
 748         $proto = "(". $cv->PV . ") ";
 749     }
 750     if ($cv->CvFLAGS & (CVf_METHOD|CVf_LOCKED|CVf_LVALUE)) {
 751         $proto .= ": ";
 752         $proto .= "lvalue " if $cv->CvFLAGS & CVf_LVALUE;
 753         $proto .= "locked " if $cv->CvFLAGS & CVf_LOCKED;
 754         $proto .= "method " if $cv->CvFLAGS & CVf_METHOD;
 755     }
 756
 757     local($self->{'curcv'}) = $cv;
 758     local($self->{'curcvlex'});
 759     local(@$self{qw'curstash warnings hints'})
 760                 = @$self{qw'curstash warnings hints'};
 761     my $body;
 762     if (not null $cv->ROOT) {
 763         my $lineseq = $cv->ROOT->first;
 764         if ($lineseq->name eq "lineseq") {
 765             my @ops;
 766             for(my$o=$lineseq->first; $$o; $o=$o->sibling) {
 767                 push @ops, $o;
 768             }
 769             $body = $self->lineseq(undef, @ops).";";
 770             my $scope_en = $self->find_scope_en($lineseq);
 771             if (defined $scope_en) {
 772                 my $subs = join"", $self->seq_subs($scope_en);
 773                 $body .= ";\n$subs" if length($subs);
 774             }
 775         }
 776         else {
 777             $body = $self->deparse($cv->ROOT->first, 0);
 778         }
 779     }
 780     else {
 781         my $sv = $cv->const_sv;
 782         if ($$sv) {
 783             # uh-oh. inlinable sub... format it differently
 784             return $proto . "{ " . const($sv) . " }\n";
 785         } else { # XSUB? (or just a declaration)
 786             return "$proto;\n";
 787         }
 788     }
 789     return $proto ."{\n\t$body\n\b}" ."\n";
 790 }
 791
 792 sub deparse_format {
 793     my $self = shift;
 794     my $form = shift;
 795     my @text;
 796     local($self->{'curcv'}) = $form;
 797     local($self->{'curcvlex'});
 798     local($self->{'in_format'}) = 1;
 799     local(@$self{qw'curstash warnings hints'})
 800                 = @$self{qw'curstash warnings hints'};
 801     my $op = $form->ROOT;
 802     my $kid;
 803     return "\f." if $op->first->name eq 'stub'
 804                 || $op->first->name eq 'nextstate';
 805     $op = $op->first->first; # skip leavewrite, lineseq
 806     while (not null $op) {
 807         $op = $op->sibling; # skip nextstate
 808         my @exprs;
 809         $kid = $op->first->sibling; # skip pushmark
 810         push @text, "\f".$self->const_sv($kid)->PV;
 811         $kid = $kid->sibling;
 812         for (; not null $kid; $kid = $kid->sibling) {
 813             push @exprs, $self->deparse($kid, 0);
 814         }
 815         push @text, "\f".join(", ", @exprs)."\n" if @exprs;
 816         $op = $op->sibling;
 817     }
 818     return join("", @text) . "\f.";
 819 }
 820
 821 sub is_scope {
 822     my $op = shift;
 823     return $op->name eq "leave" || $op->name eq "scope"
 824       || $op->name eq "lineseq"
 825         || ($op->name eq "null" && class($op) eq "UNOP"
 826             && (is_scope($op->first) || $op->first->name eq "enter"));
 827 }
 828
 829 sub is_state {
 830     my $name = $_[0]->name;
 831     return $name eq "nextstate" || $name eq "dbstate" || $name eq "setstate";
 832 }
 833
 834 sub is_miniwhile { # check for one-line loop (`foo() while $y--')
 835     my $op = shift;
 836     return (!null($op) and null($op->sibling)
 837             and $op->name eq "null" and class($op) eq "UNOP"
 838             and (($op->first->name =~ /^(and|or)$/
 839                   and $op->first->first->sibling->name eq "lineseq")
 840                  or ($op->first->name eq "lineseq"
 841                      and not null $op->first->first->sibling
 842                      and $op->first->first->sibling->name eq "unstack")
 843                  ));
 844 }
 845
 846 sub is_scalar {
 847     my $op = shift;
 848     return ($op->name eq "rv2sv" or
 849             $op->name eq "padsv" or
 850             $op->name eq "gv" or # only in array/hash constructs
 851             $op->flags & OPf_KIDS && !null($op->first)
 852               && $op->first->name eq "gvsv");
 853 }
 854
 855 sub maybe_parens {
 856     my $self = shift;
 857     my($text, $cx, $prec) = @_;
 858     if ($prec < $cx              # unary ops nest just fine
 859         or $prec == $cx and $cx != 4 and $cx != 16 and $cx != 21
 860         or $self->{'parens'})
 861     {
 862         $text = "($text)";
 863         # In a unop, let parent reuse our parens; see maybe_parens_unop
 864         $text = "\cS" . $text if $cx == 16;
 865         return $text;
 866     } else {
 867         return $text;
 868     }
 869 }
 870
 871 # same as above, but get around the `if it looks like a function' rule
 872 sub maybe_parens_unop {
 873     my $self = shift;
 874     my($name, $kid, $cx) = @_;
 875     if ($cx > 16 or $self->{'parens'}) {
 876         $kid =  $self->deparse($kid, 1);
 877         if ($name eq "umask" && $kid =~ /^\d+$/) {
 878             $kid = sprintf("%#o", $kid);
 879         }
 880         return "$name($kid)";
 881     } else {
 882         $kid = $self->deparse($kid, 16);
 883         if ($name eq "umask" && $kid =~ /^\d+$/) {
 884             $kid = sprintf("%#o", $kid);
 885         }
 886         if (substr($kid, 0, 1) eq "\cS") {
 887             # use kid's parens
 888             return $name . substr($kid, 1);
 889         } elsif (substr($kid, 0, 1) eq "(") {
 890             # avoid looks-like-a-function trap with extra parens
 891             # (`+' can lead to ambiguities)
 892             return "$name(" . $kid  . ")";
 893         } else {
 894             return "$name $kid";
 895         }
 896     }
 897 }
 898
 899 sub maybe_parens_func {
 900     my $self = shift;
 901     my($func, $text, $cx, $prec) = @_;
 902     if ($prec <= $cx or substr($text, 0, 1) eq "(" or $self->{'parens'}) {
 903         return "$func($text)";
 904     } else {
 905         return "$func $text";
 906     }
 907 }
 908
 909 sub maybe_local {
 910     my $self = shift;
 911     my($op, $cx, $text) = @_;
 912     my $our_intro = ($op->name =~ /^(gv|rv2)[ash]v$/) ? OPpOUR_INTRO : 0;
 913     if ($op->private & (OPpLVAL_INTRO|$our_intro)
 914         and not $self->{'avoid_local'}{$$op}) {
 915         my $our_local = ($op->private & OPpLVAL_INTRO) ? "local" : "our";
 916         if (want_scalar($op)) {
 917             return "$our_local $text";
 918         } else {
 919             return $self->maybe_parens_func("$our_local", $text, $cx, 16);
 920         }
 921     } else {
 922         return $text;
 923     }
 924 }
 925
 926 sub maybe_targmy {
 927     my $self = shift;
 928     my($op, $cx, $func, @args) = @_;
 929     if ($op->private & OPpTARGET_MY) {
 930         my $var = $self->padname($op->targ);
 931         my $val = $func->($self, $op, 7, @args);
 932         return $self->maybe_parens("$var = $val", $cx, 7);
 933     } else {
 934         return $func->($self, $op, $cx, @args);
 935     }
 936 }
 937
 938 sub padname_sv {
 939     my $self = shift;
 940     my $targ = shift;
 941     return (($self->{'curcv'}->PADLIST->ARRAY)[0]->ARRAY)[$targ];
 942 }
 943
 944 sub maybe_my {
 945     my $self = shift;
 946     my($op, $cx, $text) = @_;
 947     if ($op->private & OPpLVAL_INTRO and not $self->{'avoid_local'}{$$op}) {
 948         if (want_scalar($op)) {
 949             return "my $text";
 950         } else {
 951             return $self->maybe_parens_func("my", $text, $cx, 16);
 952         }
 953     } else {
 954         return $text;
 955     }
 956 }
 957
 958 # The following OPs don't have functions:
 959
 960 # pp_padany -- does not exist after parsing
 961
 962 sub AUTOLOAD {
 963     if ($AUTOLOAD =~ s/^.*::pp_//) {
 964         warn "unexpected OP_".uc $AUTOLOAD;
 965         return "XXX";
 966     } else {
 967         die "Undefined subroutine $AUTOLOAD called";
 968     }
 969 }
 970
 971 sub DESTROY {}  #       Do not AUTOLOAD
 972
 973 # $root should be the op which represents the root of whatever
 974 # we're sequencing here. If it's undefined, then we don't append
 975 # any subroutine declarations to the deparsed ops, otherwise we
 976 # append appropriate declarations.
 977 sub lineseq {
 978     my($self, $root, @ops) = @_;
 979     my($expr, @exprs);
 980
 981     my $out_cop = $self->{'curcop'};
 982     my $out_seq = defined($out_cop) ? $out_cop->cop_seq : undef;
 983     my $limit_seq;
 984     if (defined $root) {
 985         $limit_seq = $out_seq;
 986         my $nseq = $self->find_scope_st($root->sibling) if ${$root->sibling};
 987         $limit_seq = $nseq if !defined($limit_seq)
 988                            or defined($nseq) && $nseq < $limit_seq;
 989     }
 990     $limit_seq = $self->{'limit_seq'}
 991         if defined($self->{'limit_seq'})
 992         && (!defined($limit_seq) || $self->{'limit_seq'} < $limit_seq);
 993     local $self->{'limit_seq'} = $limit_seq;
 994     for (my $i = 0; $i < @ops; $i++) {
 995         $expr = "";
 996         if (is_state $ops[$i]) {
 997             $expr = $self->deparse($ops[$i], 0);
 998             $i++;
 999             if ($i > $#ops) {
1000                 push @exprs, $expr;
1001                 last;
1002             }
1003         }
1004         if (!is_state $ops[$i] and (my $ls = $ops[$i+1]) and
1005             !null($ops[$i+1]) and $ops[$i+1]->name eq "lineseq")
1006         {
1007             if ($ls->first && !null($ls->first) && is_state($ls->first)
1008                 && (my $sib = $ls->first->sibling)) {
1009                 if (!null($sib) && $sib->name eq "leaveloop") {
1010                     push @exprs, $expr . $self->for_loop($ops[$i], 0);
1011                     $i++;
1012                     next;
1013                 }
1014             }
1015         }
1016         $expr .= $self->deparse($ops[$i], 0, (@ops != 1));
1017         $expr =~ s/;\n?\z//;
1018         push @exprs, $expr;
1019     }
1020     my $body = join(";\n", grep {length} @exprs);
1021     my $subs = "";
1022     if (defined $root && defined $limit_seq && !$self->{'in_format'}) {
1023         $subs = join "\n", $self->seq_subs($limit_seq);
1024     }
1025     return join(";\n", grep {length} $body, $subs);
1026 }
1027
1028 sub scopeop {
1029     my($real_block, $self, $op, $cx, $flags) = @_;
1030     my $kid;
1031     my @kids;
1032
1033     local(@$self{qw'curstash warnings hints'})
1034                 = @$self{qw'curstash warnings hints'} if $real_block;
1035     if ($real_block) {
1036         $kid = $op->first->sibling; # skip enter
1037         if (is_miniwhile($kid)) {
1038             my $top = $kid->first;
1039             my $name = $top->name;
1040             if ($name eq "and") {
1041                 $name = "while";
1042             } elsif ($name eq "or") {
1043                 $name = "until";
1044             } else { # no conditional -> while 1 or until 0
1045                 return $self->deparse($top->first, 1) . " while 1";
1046             }
1047             my $cond = $top->first;
1048             my $body = $cond->sibling->first; # skip lineseq
1049             $cond = $self->deparse($cond, 1);
1050             $body = $self->deparse($body, 1);
1051             return "$body $name $cond";
1052         }
1053     } else {
1054         $kid = $op->first;
1055     }
1056     for (; !null($kid); $kid = $kid->sibling) {
1057         push @kids, $kid;
1058     }
1059     if ($flags || $cx > 0) { # inside an expression, (a do {} while for lineseq)
1060         return "do {\n\t" . $self->lineseq($op, @kids) . "\n\b}";
1061     } else {
1062         my $lineseq = $self->lineseq($op, @kids);
1063         return (length ($lineseq) ? "$lineseq;" : "");
1064     }
1065 }
1066
1067 sub pp_scope { scopeop(0, @_); }
1068 sub pp_lineseq { scopeop(0, @_); }
1069 sub pp_leave { scopeop(1, @_); }
1070
1071 # The BEGIN {} is used here because otherwise this code isn't executed
1072 # when you run B::Deparse on itself.
1073 my %globalnames;
1074 BEGIN { map($globalnames{$_}++, "SIG", "STDIN", "STDOUT", "STDERR", "INC",
1075             "ENV", "ARGV", "ARGVOUT", "_"); }
1076
1077 sub gv_name {
1078     my $self = shift;
1079     my $gv = shift;
1080 Carp::confess() if $gv->isa("B::CV");
1081     my $stash = $gv->STASH->NAME;
1082     my $name = $gv->SAFENAME;
1083     if (($stash eq 'main' && $globalnames{$name})
1084         or ($stash eq $self->{'curstash'} && !$globalnames{$name})
1085         or $name =~ /^[^A-Za-z_]/)
1086     {
1087         $stash = "";
1088     } else {
1089         $stash = $stash . "::";
1090     }
1091     if ($name =~ /^(\^..|{)/) {
1092         $name = "{$name}";       # ${^WARNING_BITS}, etc and ${
1093     }
1094     return $stash . $name;
1095 }
1096
1097 # Return the name to use for a stash variable.
1098 # If a lexical with the same name is in scope, it may need to be
1099 # fully-qualified.
1100 sub stash_variable {
1101     my ($self, $prefix, $name) = @_;
1102
1103     return "$prefix$name" if $name =~ /::/;
1104
1105     unless ($prefix eq '$' || $prefix eq '@' ||
1106             $prefix eq '%' || $prefix eq '$#') {
1107         return "$prefix$name";
1108     }
1109
1110     my $v = ($prefix eq '$#' ? '@' : $prefix) . $name;
1111     return $prefix .$self->{'curstash'}.'::'. $name if $self->lex_in_scope($v);
1112     return "$prefix$name";
1113 }
1114
1115 sub lex_in_scope {
1116     my ($self, $name) = @_;
1117     $self->populate_curcvlex() if !defined $self->{'curcvlex'};
1118
1119     return 0 if !defined($self->{'curcop'});
1120     my $seq = $self->{'curcop'}->cop_seq;
1121     return 0 if !exists $self->{'curcvlex'}{$name};
1122     for my $a (@{$self->{'curcvlex'}{$name}}) {
1123         my ($st, $en) = @$a;
1124         return 1 if $seq > $st && $seq <= $en;
1125     }
1126     return 0;
1127 }
1128
1129 sub populate_curcvlex {
1130     my $self = shift;
1131     for (my $cv = $self->{'curcv'}; class($cv) eq "CV"; $cv = $cv->OUTSIDE) {
1132         my @padlist = $cv->PADLIST->ARRAY;
1133         my @ns = $padlist[0]->ARRAY;
1134
1135         for (my $i=0; $i<@ns; ++$i) {
1136             next if class($ns[$i]) eq "SPECIAL";
1137             next if $ns[$i]->FLAGS & SVpad_OUR;  # Skip "our" vars
1138             if (class($ns[$i]) eq "PV") {
1139                 # Probably that pesky lexical @_
1140                 next;
1141             }
1142             my $name = $ns[$i]->PVX;
1143             my $seq_st = $ns[$i]->NVX;
1144             my $seq_en = int($ns[$i]->IVX);
1145
1146             push @{$self->{'curcvlex'}{$name}}, [$seq_st, $seq_en];
1147         }
1148     }
1149 }
1150
1151 sub find_scope_st { ((find_scope(@_))[0]); }
1152 sub find_scope_en { ((find_scope(@_))[1]); }
1153
1154 # Recurses down the tree, looking for pad variable introductions and COPs
1155 sub find_scope {
1156     my ($self, $op, $scope_st, $scope_en) = @_;
1157     carp("Undefined op in find_scope") if !defined $op;
1158     return ($scope_st, $scope_en) unless $op->flags & OPf_KIDS;
1159
1160     for (my $o=$op->first; $$o; $o=$o->sibling) {
1161         if ($o->name =~ /^pad.v$/ && $o->private & OPpLVAL_INTRO) {
1162             my $s = int($self->padname_sv($o->targ)->NVX);
1163             my $e = $self->padname_sv($o->targ)->IVX;
1164             $scope_st = $s if !defined($scope_st) || $s < $scope_st;
1165             $scope_en = $e if !defined($scope_en) || $e > $scope_en;
1166         }
1167         elsif (is_state($o)) {
1168             my $c = $o->cop_seq;
1169             $scope_st = $c if !defined($scope_st) || $c < $scope_st;
1170             $scope_en = $c if !defined($scope_en) || $c > $scope_en;
1171         }
1172         elsif ($o->flags & OPf_KIDS) {
1173             ($scope_st, $scope_en) =
1174                 $self->find_scope($o, $scope_st, $scope_en)
1175         }
1176     }
1177
1178     return ($scope_st, $scope_en);
1179 }
1180
1181 # Returns a list of subs which should be inserted before the COP
1182 sub cop_subs {
1183     my ($self, $op, $out_seq) = @_;
1184     my $seq = $op->cop_seq;
1185     # If we have nephews, then our sequence number indicates
1186     # the cop_seq of the end of some sort of scope.
1187     if (class($op->sibling) ne "NULL" && $op->sibling->flags & OPf_KIDS
1188         and my $nseq = $self->find_scope_st($op->sibling) ) {
1189         $seq = $nseq;
1190     }
1191     $seq = $out_seq if defined($out_seq) && $out_seq < $seq;
1192     return $self->seq_subs($seq);
1193 }
1194
1195 sub seq_subs {
1196     my ($self, $seq) = @_;
1197     my @text;
1198 #push @text, "# ($seq)\n";
1199
1200     return "" if !defined $seq;
1201     while (scalar(@{$self->{'subs_todo'}})
1202            and $seq > $self->{'subs_todo'}[0][0]) {
1203         push @text, $self->next_todo;
1204     }
1205     return @text;
1206 }
1207
1208 # Notice how subs and formats are inserted between statements here;
1209 # also $[ assignments and pragmas.
1210 sub pp_nextstate {
1211     my $self = shift;
1212     my($op, $cx) = @_;
1213     $self->{'curcop'} = $op;
1214     my @text;
1215     push @text, $self->cop_subs($op);
1216     push @text, $op->label . ": " if $op->label;
1217     my $stash = $op->stashpv;
1218     if ($stash ne $self->{'curstash'}) {
1219         push @text, "package $stash;\n";
1220         $self->{'curstash'} = $stash;
1221     }
1222     if ($self->{'linenums'}) {
1223         push @text, "\f#line " . $op->line .
1224           ' "' . $op->file, qq'"\n';
1225     }
1226
1227     if ($self->{'arybase'} != $op->arybase) {
1228         push @text, '$[ = '. $op->arybase .";\n";
1229         $self->{'arybase'} = $op->arybase;
1230     }
1231
1232     my $warnings = $op->warnings;
1233     my $warning_bits;
1234     if ($warnings->isa("B::SPECIAL") && $$warnings == 4) {
1235         $warning_bits = $warnings::Bits{"all"} & WARN_MASK;
1236     }
1237     elsif ($warnings->isa("B::SPECIAL") && $$warnings == 5) {
1238         $warning_bits = $warnings::NONE;
1239     }
1240     elsif ($warnings->isa("B::SPECIAL")) {
1241         $warning_bits = undef;
1242     }
1243     else {
1244         $warning_bits = $warnings->PV & WARN_MASK;
1245     }
1246
1247     if (defined ($warning_bits) and
1248        !defined($self->{warnings}) || $self->{'warnings'} ne $warning_bits) {
1249         push @text, declare_warnings($self->{'warnings'}, $warning_bits);
1250         $self->{'warnings'} = $warning_bits;
1251     }
1252
1253     if ($self->{'hints'} != $op->private) {
1254         push @text, declare_hints($self->{'hints'}, $op->private);
1255         $self->{'hints'} = $op->private;
1256     }
1257
1258     return join("", @text);
1259 }
1260
1261 sub declare_warnings {
1262     my ($from, $to) = @_;
1263     if (($to & WARN_MASK) eq warnings::bits("all")) {
1264         return "use warnings;\n";
1265     }
1266     elsif (($to & WARN_MASK) eq "\0"x length($to)) {
1267         return "no warnings;\n";
1268     }
1269     return "BEGIN {\${^WARNING_BITS} = ".perlstring($to)."}\n";
1270 }
1271
1272 sub declare_hints {
1273     my ($from, $to) = @_;
1274     my $use = $to   & ~$from;
1275     my $no  = $from & ~$to;
1276     my $decls = "";
1277     for my $pragma (hint_pragmas($use)) {
1278         $decls .= "use $pragma;\n";
1279     }
1280     for my $pragma (hint_pragmas($no)) {
1281         $decls .= "no $pragma;\n";
1282     }
1283     return $decls;
1284 }
1285
1286 sub hint_pragmas {
1287     my ($bits) = @_;
1288     my @pragmas;
1289     push @pragmas, "integer" if $bits & 0x1;
1290     push @pragmas, "strict 'refs'" if $bits & 0x2;
1291     push @pragmas, "bytes" if $bits & 0x8;
1292     return @pragmas;
1293 }
1294
1295 sub pp_dbstate { pp_nextstate(@_) }
1296 sub pp_setstate { pp_nextstate(@_) }
1297
1298 sub pp_unstack { return "" } # see also leaveloop
1299
1300 sub baseop {
1301     my $self = shift;
1302     my($op, $cx, $name) = @_;
1303     return $name;
1304 }
1305
1306 sub pp_stub {
1307     my $self = shift;
1308     my($op, $cx, $name) = @_;
1309     if ($cx) {
1310         return "()";
1311     }
1312     else {
1313         return "();";
1314     }
1315 }
1316 sub pp_wantarray { baseop(@_, "wantarray") }
1317 sub pp_fork { baseop(@_, "fork") }
1318 sub pp_wait { maybe_targmy(@_, \&baseop, "wait") }
1319 sub pp_getppid { maybe_targmy(@_, \&baseop, "getppid") }
1320 sub pp_time { maybe_targmy(@_, \&baseop, "time") }
1321 sub pp_tms { baseop(@_, "times") }
1322 sub pp_ghostent { baseop(@_, "gethostent") }
1323 sub pp_gnetent { baseop(@_, "getnetent") }
1324 sub pp_gprotoent { baseop(@_, "getprotoent") }
1325 sub pp_gservent { baseop(@_, "getservent") }
1326 sub pp_ehostent { baseop(@_, "endhostent") }
1327 sub pp_enetent { baseop(@_, "endnetent") }
1328 sub pp_eprotoent { baseop(@_, "endprotoent") }
1329 sub pp_eservent { baseop(@_, "endservent") }
1330 sub pp_gpwent { baseop(@_, "getpwent") }
1331 sub pp_spwent { baseop(@_, "setpwent") }
1332 sub pp_epwent { baseop(@_, "endpwent") }
1333 sub pp_ggrent { baseop(@_, "getgrent") }
1334 sub pp_sgrent { baseop(@_, "setgrent") }
1335 sub pp_egrent { baseop(@_, "endgrent") }
1336 sub pp_getlogin { baseop(@_, "getlogin") }
1337
1338 sub POSTFIX () { 1 }
1339
1340 # I couldn't think of a good short name, but this is the category of
1341 # symbolic unary operators with interesting precedence
1342
1343 sub pfixop {
1344     my $self = shift;
1345     my($op, $cx, $name, $prec, $flags) = (@_, 0);
1346     my $kid = $op->first;
1347     $kid = $self->deparse($kid, $prec);
1348     return $self->maybe_parens(($flags & POSTFIX) ? "$kid$name" : "$name$kid",
1349                                $cx, $prec);
1350 }
1351
1352 sub pp_preinc { pfixop(@_, "++", 23) }
1353 sub pp_predec { pfixop(@_, "--", 23) }
1354 sub pp_postinc { maybe_targmy(@_, \&pfixop, "++", 23, POSTFIX) }
1355 sub pp_postdec { maybe_targmy(@_, \&pfixop, "--", 23, POSTFIX) }
1356 sub pp_i_preinc { pfixop(@_, "++", 23) }
1357 sub pp_i_predec { pfixop(@_, "--", 23) }
1358 sub pp_i_postinc { maybe_targmy(@_, \&pfixop, "++", 23, POSTFIX) }
1359 sub pp_i_postdec { maybe_targmy(@_, \&pfixop, "--", 23, POSTFIX) }
1360 sub pp_complement { maybe_targmy(@_, \&pfixop, "~", 21) }
1361
1362 sub pp_negate { maybe_targmy(@_, \&real_negate) }
1363 sub real_negate {
1364     my $self = shift;
1365     my($op, $cx) = @_;
1366     if ($op->first->name =~ /^(i_)?negate$/) {
1367         # avoid --$x
1368         $self->pfixop($op, $cx, "-", 21.5);
1369     } else {
1370         $self->pfixop($op, $cx, "-", 21);
1371     }
1372 }
1373 sub pp_i_negate { pp_negate(@_) }
1374
1375 sub pp_not {
1376     my $self = shift;
1377     my($op, $cx) = @_;
1378     if ($cx <= 4) {
1379         $self->pfixop($op, $cx, "not ", 4);
1380     } else {
1381         $self->pfixop($op, $cx, "!", 21);
1382     }
1383 }
1384
1385 sub unop {
1386     my $self = shift;
1387     my($op, $cx, $name) = @_;
1388     my $kid;
1389     if ($op->flags & OPf_KIDS) {
1390         $kid = $op->first;
1391         if (defined prototype("CORE::$name")
1392            && prototype("CORE::$name") =~ /^;?\*/
1393            && $kid->name eq "rv2gv") {
1394             $kid = $kid->first;
1395         }
1396
1397         return $self->maybe_parens_unop($name, $kid, $cx);
1398     } else {
1399         return $name .  ($op->flags & OPf_SPECIAL ? "()" : "");
1400     }
1401 }
1402
1403 sub pp_chop { maybe_targmy(@_, \&unop, "chop") }
1404 sub pp_chomp { maybe_targmy(@_, \&unop, "chomp") }
1405 sub pp_schop { maybe_targmy(@_, \&unop, "chop") }
1406 sub pp_schomp { maybe_targmy(@_, \&unop, "chomp") }
1407 sub pp_defined { unop(@_, "defined") }
1408 sub pp_undef { unop(@_, "undef") }
1409 sub pp_study { unop(@_, "study") }
1410 sub pp_ref { unop(@_, "ref") }
1411 sub pp_pos { maybe_local(@_, unop(@_, "pos")) }
1412
1413 sub pp_sin { maybe_targmy(@_, \&unop, "sin") }
1414 sub pp_cos { maybe_targmy(@_, \&unop, "cos") }
1415 sub pp_rand { maybe_targmy(@_, \&unop, "rand") }
1416 sub pp_srand { unop(@_, "srand") }
1417 sub pp_exp { maybe_targmy(@_, \&unop, "exp") }
1418 sub pp_log { maybe_targmy(@_, \&unop, "log") }
1419 sub pp_sqrt { maybe_targmy(@_, \&unop, "sqrt") }
1420 sub pp_int { maybe_targmy(@_, \&unop, "int") }
1421 sub pp_hex { maybe_targmy(@_, \&unop, "hex") }
1422 sub pp_oct { maybe_targmy(@_, \&unop, "oct") }
1423 sub pp_abs { maybe_targmy(@_, \&unop, "abs") }
1424
1425 sub pp_length { maybe_targmy(@_, \&unop, "length") }
1426 sub pp_ord { maybe_targmy(@_, \&unop, "ord") }
1427 sub pp_chr { maybe_targmy(@_, \&unop, "chr") }
1428
1429 sub pp_each { unop(@_, "each") }
1430 sub pp_values { unop(@_, "values") }
1431 sub pp_keys { unop(@_, "keys") }
1432 sub pp_pop { unop(@_, "pop") }
1433 sub pp_shift { unop(@_, "shift") }
1434
1435 sub pp_caller { unop(@_, "caller") }
1436 sub pp_reset { unop(@_, "reset") }
1437 sub pp_exit { unop(@_, "exit") }
1438 sub pp_prototype { unop(@_, "prototype") }
1439
1440 sub pp_close { unop(@_, "close") }
1441 sub pp_fileno { unop(@_, "fileno") }
1442 sub pp_umask { unop(@_, "umask") }
1443 sub pp_untie { unop(@_, "untie") }
1444 sub pp_tied { unop(@_, "tied") }
1445 sub pp_dbmclose { unop(@_, "dbmclose") }
1446 sub pp_getc { unop(@_, "getc") }
1447 sub pp_eof { unop(@_, "eof") }
1448 sub pp_tell { unop(@_, "tell") }
1449 sub pp_getsockname { unop(@_, "getsockname") }
1450 sub pp_getpeername { unop(@_, "getpeername") }
1451
1452 sub pp_chdir { maybe_targmy(@_, \&unop, "chdir") }
1453 sub pp_chroot { maybe_targmy(@_, \&unop, "chroot") }
1454 sub pp_readlink { unop(@_, "readlink") }
1455 sub pp_rmdir { maybe_targmy(@_, \&unop, "rmdir") }
1456 sub pp_readdir { unop(@_, "readdir") }
1457 sub pp_telldir { unop(@_, "telldir") }
1458 sub pp_rewinddir { unop(@_, "rewinddir") }
1459 sub pp_closedir { unop(@_, "closedir") }
1460 sub pp_getpgrp { maybe_targmy(@_, \&unop, "getpgrp") }
1461 sub pp_localtime { unop(@_, "localtime") }
1462 sub pp_gmtime { unop(@_, "gmtime") }
1463 sub pp_alarm { unop(@_, "alarm") }
1464 sub pp_sleep { maybe_targmy(@_, \&unop, "sleep") }
1465
1466 sub pp_dofile { unop(@_, "do") }
1467 sub pp_entereval { unop(@_, "eval") }
1468
1469 sub pp_ghbyname { unop(@_, "gethostbyname") }
1470 sub pp_gnbyname { unop(@_, "getnetbyname") }
1471 sub pp_gpbyname { unop(@_, "getprotobyname") }
1472 sub pp_shostent { unop(@_, "sethostent") }
1473 sub pp_snetent { unop(@_, "setnetent") }
1474 sub pp_sprotoent { unop(@_, "setprotoent") }
1475 sub pp_sservent { unop(@_, "setservent") }
1476 sub pp_gpwnam { unop(@_, "getpwnam") }
1477 sub pp_gpwuid { unop(@_, "getpwuid") }
1478 sub pp_ggrnam { unop(@_, "getgrnam") }
1479 sub pp_ggrgid { unop(@_, "getgrgid") }
1480
1481 sub pp_lock { unop(@_, "lock") }
1482
1483 sub pp_exists {
1484     my $self = shift;
1485     my($op, $cx) = @_;
1486     my $arg;
1487     if ($op->private & OPpEXISTS_SUB) {
1488         # Checking for the existence of a subroutine
1489         return $self->maybe_parens_func("exists",
1490                                 $self->pp_rv2cv($op->first, 16), $cx, 16);
1491     }
1492     if ($op->flags & OPf_SPECIAL) {
1493         # Array element, not hash element
1494         return $self->maybe_parens_func("exists",
1495                                 $self->pp_aelem($op->first, 16), $cx, 16);
1496     }
1497     return $self->maybe_parens_func("exists", $self->pp_helem($op->first, 16),
1498                                     $cx, 16);
1499 }
1500
1501 sub pp_delete {
1502     my $self = shift;
1503     my($op, $cx) = @_;
1504     my $arg;
1505     if ($op->private & OPpSLICE) {
1506         if ($op->flags & OPf_SPECIAL) {
1507             # Deleting from an array, not a hash
1508             return $self->maybe_parens_func("delete",
1509                                         $self->pp_aslice($op->first, 16),
1510                                         $cx, 16);
1511         }
1512         return $self->maybe_parens_func("delete",
1513                                         $self->pp_hslice($op->first, 16),
1514                                         $cx, 16);
1515     } else {
1516         if ($op->flags & OPf_SPECIAL) {
1517             # Deleting from an array, not a hash
1518             return $self->maybe_parens_func("delete",
1519                                         $self->pp_aelem($op->first, 16),
1520                                         $cx, 16);
1521         }
1522         return $self->maybe_parens_func("delete",
1523                                         $self->pp_helem($op->first, 16),
1524                                         $cx, 16);
1525     }
1526 }
1527
1528 sub pp_require {
1529     my $self = shift;
1530     my($op, $cx) = @_;
1531     if (class($op) eq "UNOP" and $op->first->name eq "const"
1532         and $op->first->private & OPpCONST_BARE)
1533     {
1534         my $name = $self->const_sv($op->first)->PV;
1535         $name =~ s[/][::]g;
1536         $name =~ s/\.pm//g;
1537         return "require $name";
1538     } else {
1539         $self->unop($op, $cx, "require");
1540     }
1541 }
1542
1543 sub pp_scalar {
1544     my $self = shift;
1545     my($op, $cv) = @_;
1546     my $kid = $op->first;
1547     if (not null $kid->sibling) {
1548         # XXX Was a here-doc
1549         return $self->dquote($op);
1550     }
1551     $self->unop(@_, "scalar");
1552 }
1553
1554
1555 sub padval {
1556     my $self = shift;
1557     my $targ = shift;
1558     return (($self->{'curcv'}->PADLIST->ARRAY)[1]->ARRAY)[$targ];
1559 }
1560
1561 sub pp_refgen {
1562     my $self = shift;
1563     my($op, $cx) = @_;
1564     my $kid = $op->first;
1565     if ($kid->name eq "null") {
1566         $kid = $kid->first;
1567         if ($kid->name eq "anonlist" || $kid->name eq "anonhash") {
1568             my($pre, $post) = @{{"anonlist" => ["[","]"],
1569                                  "anonhash" => ["{","}"]}->{$kid->name}};
1570             my($expr, @exprs);
1571             $kid = $kid->first->sibling; # skip pushmark
1572             for (; !null($kid); $kid = $kid->sibling) {
1573                 $expr = $self->deparse($kid, 6);
1574                 push @exprs, $expr;
1575             }
1576             return $pre . join(", ", @exprs) . $post;
1577         } elsif (!null($kid->sibling) and
1578                  $kid->sibling->name eq "anoncode") {
1579             return "sub " .
1580                 $self->deparse_sub($self->padval($kid->sibling->targ));
1581         } elsif ($kid->name eq "pushmark") {
1582             my $sib_name = $kid->sibling->name;
1583             if ($sib_name =~ /^(pad|rv2)[ah]v$/
1584                 and not $kid->sibling->flags & OPf_REF)
1585             {
1586                 # The @a in \(@a) isn't in ref context, but only when the
1587                 # parens are there.
1588                 return "\\(" . $self->deparse($kid->sibling, 1) . ")";
1589             } elsif ($sib_name eq 'entersub') {
1590                 my $text = $self->deparse($kid->sibling, 1);
1591                 # Always show parens for \(&func()), but only with -p otherwise
1592                 $text = "($text)" if $self->{'parens'}
1593                                  or $kid->sibling->private & OPpENTERSUB_AMPER;
1594                 return "\\$text";
1595             }
1596         }
1597     }
1598     $self->pfixop($op, $cx, "\\", 20);
1599 }
1600
1601 sub pp_srefgen { pp_refgen(@_) }
1602
1603 sub pp_readline {
1604     my $self = shift;
1605     my($op, $cx) = @_;
1606     my $kid = $op->first;
1607     $kid = $kid->first if $kid->name eq "rv2gv"; # <$fh>
1608     return "<" . $self->deparse($kid, 1) . ">" if is_scalar($kid);
1609     return $self->unop($op, $cx, "readline");
1610 }
1611
1612 sub pp_rcatline {
1613     my $self = shift;
1614     my($op) = @_;
1615     return "<" . $self->gv_name($op->gv) . ">";
1616 }
1617
1618 # Unary operators that can occur as pseudo-listops inside double quotes
1619 sub dq_unop {
1620     my $self = shift;
1621     my($op, $cx, $name, $prec, $flags) = (@_, 0, 0);
1622     my $kid;
1623     if ($op->flags & OPf_KIDS) {
1624        $kid = $op->first;
1625        # If there's more than one kid, the first is an ex-pushmark.
1626        $kid = $kid->sibling if not null $kid->sibling;
1627        return $self->maybe_parens_unop($name, $kid, $cx);
1628     } else {
1629        return $name .  ($op->flags & OPf_SPECIAL ? "()" : "");
1630     }
1631 }
1632
1633 sub pp_ucfirst { dq_unop(@_, "ucfirst") }
1634 sub pp_lcfirst { dq_unop(@_, "lcfirst") }
1635 sub pp_uc { dq_unop(@_, "uc") }
1636 sub pp_lc { dq_unop(@_, "lc") }
1637 sub pp_quotemeta { maybe_targmy(@_, \&dq_unop, "quotemeta") }
1638
1639 sub loopex {
1640     my $self = shift;
1641     my ($op, $cx, $name) = @_;
1642     if (class($op) eq "PVOP") {
1643         return "$name " . $op->pv;
1644     } elsif (class($op) eq "OP") {
1645         return $name;
1646     } elsif (class($op) eq "UNOP") {
1647         # Note -- loop exits are actually exempt from the
1648         # looks-like-a-func rule, but a few extra parens won't hurt
1649         return $self->maybe_parens_unop($name, $op->first, $cx);
1650     }
1651 }
1652
1653 sub pp_last { loopex(@_, "last") }
1654 sub pp_next { loopex(@_, "next") }
1655 sub pp_redo { loopex(@_, "redo") }
1656 sub pp_goto { loopex(@_, "goto") }
1657 sub pp_dump { loopex(@_, "dump") }
1658
1659 sub ftst {
1660     my $self = shift;
1661     my($op, $cx, $name) = @_;
1662     if (class($op) eq "UNOP") {
1663         # Genuine `-X' filetests are exempt from the LLAFR, but not
1664         # l?stat(); for the sake of clarity, give'em all parens
1665         return $self->maybe_parens_unop($name, $op->first, $cx);
1666     } elsif (class($op) eq "SVOP") {
1667         return $self->maybe_parens_func($name, $self->pp_gv($op, 1), $cx, 16);
1668     } else { # I don't think baseop filetests ever survive ck_ftst, but...
1669         return $name;
1670     }
1671 }
1672
1673 sub pp_lstat { ftst(@_, "lstat") }
1674 sub pp_stat { ftst(@_, "stat") }
1675 sub pp_ftrread { ftst(@_, "-R") }
1676 sub pp_ftrwrite { ftst(@_, "-W") }
1677 sub pp_ftrexec { ftst(@_, "-X") }
1678 sub pp_fteread { ftst(@_, "-r") }
1679 sub pp_ftewrite { ftst(@_, "-w") }
1680 sub pp_fteexec { ftst(@_, "-x") }
1681 sub pp_ftis { ftst(@_, "-e") }
1682 sub pp_fteowned { ftst(@_, "-O") }
1683 sub pp_ftrowned { ftst(@_, "-o") }
1684 sub pp_ftzero { ftst(@_, "-z") }
1685 sub pp_ftsize { ftst(@_, "-s") }
1686 sub pp_ftmtime { ftst(@_, "-M") }
1687 sub pp_ftatime { ftst(@_, "-A") }
1688 sub pp_ftctime { ftst(@_, "-C") }
1689 sub pp_ftsock { ftst(@_, "-S") }
1690 sub pp_ftchr { ftst(@_, "-c") }
1691 sub pp_ftblk { ftst(@_, "-b") }
1692 sub pp_ftfile { ftst(@_, "-f") }
1693 sub pp_ftdir { ftst(@_, "-d") }
1694 sub pp_ftpipe { ftst(@_, "-p") }
1695 sub pp_ftlink { ftst(@_, "-l") }
1696 sub pp_ftsuid { ftst(@_, "-u") }
1697 sub pp_ftsgid { ftst(@_, "-g") }
1698 sub pp_ftsvtx { ftst(@_, "-k") }
1699 sub pp_fttty { ftst(@_, "-t") }
1700 sub pp_fttext { ftst(@_, "-T") }
1701 sub pp_ftbinary { ftst(@_, "-B") }
1702
1703 sub SWAP_CHILDREN () { 1 }
1704 sub ASSIGN () { 2 } # has OP= variant
1705 sub LIST_CONTEXT () { 4 } # Assignment is in list context
1706
1707 my(%left, %right);
1708
1709 sub assoc_class {
1710     my $op = shift;
1711     my $name = $op->name;
1712     if ($name eq "concat" and $op->first->name eq "concat") {
1713         # avoid spurious `=' -- see comment in pp_concat
1714         return "concat";
1715     }
1716     if ($name eq "null" and class($op) eq "UNOP"
1717         and $op->first->name =~ /^(and|x?or)$/
1718         and null $op->first->sibling)
1719     {
1720         # Like all conditional constructs, OP_ANDs and OP_ORs are topped
1721         # with a null that's used as the common end point of the two
1722         # flows of control. For precedence purposes, ignore it.
1723         # (COND_EXPRs have these too, but we don't bother with
1724         # their associativity).
1725         return assoc_class($op->first);
1726     }
1727     return $name . ($op->flags & OPf_STACKED ? "=" : "");
1728 }
1729
1730 # Left associative operators, like `+', for which
1731 # $a + $b + $c is equivalent to ($a + $b) + $c
1732
1733 BEGIN {
1734     %left = ('multiply' => 19, 'i_multiply' => 19,
1735              'divide' => 19, 'i_divide' => 19,
1736              'modulo' => 19, 'i_modulo' => 19,
1737              'repeat' => 19,
1738              'add' => 18, 'i_add' => 18,
1739              'subtract' => 18, 'i_subtract' => 18,
1740              'concat' => 18,
1741              'left_shift' => 17, 'right_shift' => 17,
1742              'bit_and' => 13,
1743              'bit_or' => 12, 'bit_xor' => 12,
1744              'and' => 3,
1745              'or' => 2, 'xor' => 2,
1746             );
1747 }
1748
1749 sub deparse_binop_left {
1750     my $self = shift;
1751     my($op, $left, $prec) = @_;
1752     if ($left{assoc_class($op)} && $left{assoc_class($left)}
1753         and $left{assoc_class($op)} == $left{assoc_class($left)})
1754     {
1755         return $self->deparse($left, $prec - .00001);
1756     } else {
1757         return $self->deparse($left, $prec);
1758     }
1759 }
1760
1761 # Right associative operators, like `=', for which
1762 # $a = $b = $c is equivalent to $a = ($b = $c)
1763
1764 BEGIN {
1765     %right = ('pow' => 22,
1766               'sassign=' => 7, 'aassign=' => 7,
1767               'multiply=' => 7, 'i_multiply=' => 7,
1768               'divide=' => 7, 'i_divide=' => 7,
1769               'modulo=' => 7, 'i_modulo=' => 7,
1770               'repeat=' => 7,
1771               'add=' => 7, 'i_add=' => 7,
1772               'subtract=' => 7, 'i_subtract=' => 7,
1773               'concat=' => 7,
1774               'left_shift=' => 7, 'right_shift=' => 7,
1775               'bit_and=' => 7,
1776               'bit_or=' => 7, 'bit_xor=' => 7,
1777               'andassign' => 7,
1778               'orassign' => 7,
1779              );
1780 }
1781
1782 sub deparse_binop_right {
1783     my $self = shift;
1784     my($op, $right, $prec) = @_;
1785     if ($right{assoc_class($op)} && $right{assoc_class($right)}
1786         and $right{assoc_class($op)} == $right{assoc_class($right)})
1787     {
1788         return $self->deparse($right, $prec - .00001);
1789     } else {
1790         return $self->deparse($right, $prec);
1791     }
1792 }
1793
1794 sub binop {
1795     my $self = shift;
1796     my ($op, $cx, $opname, $prec, $flags) = (@_, 0);
1797     my $left = $op->first;
1798     my $right = $op->last;
1799     my $eq = "";
1800     if ($op->flags & OPf_STACKED && $flags & ASSIGN) {
1801         $eq = "=";
1802         $prec = 7;
1803     }
1804     if ($flags & SWAP_CHILDREN) {
1805         ($left, $right) = ($right, $left);
1806     }
1807     $left = $self->deparse_binop_left($op, $left, $prec);
1808     $left = "($left)" if $flags & LIST_CONTEXT
1809                 && $left !~ /^(my|our|local|)[\@\(]/;
1810     $right = $self->deparse_binop_right($op, $right, $prec);
1811     return $self->maybe_parens("$left $opname$eq $right", $cx, $prec);
1812 }
1813
1814 sub pp_add { maybe_targmy(@_, \&binop, "+", 18, ASSIGN) }
1815 sub pp_multiply { maybe_targmy(@_, \&binop, "*", 19, ASSIGN) }
1816 sub pp_subtract { maybe_targmy(@_, \&binop, "-",18,  ASSIGN) }
1817 sub pp_divide { maybe_targmy(@_, \&binop, "/", 19, ASSIGN) }
1818 sub pp_modulo { maybe_targmy(@_, \&binop, "%", 19, ASSIGN) }
1819 sub pp_i_add { maybe_targmy(@_, \&binop, "+", 18, ASSIGN) }
1820 sub pp_i_multiply { maybe_targmy(@_, \&binop, "*", 19, ASSIGN) }
1821 sub pp_i_subtract { maybe_targmy(@_, \&binop, "-", 18, ASSIGN) }
1822 sub pp_i_divide { maybe_targmy(@_, \&binop, "/", 19, ASSIGN) }
1823 sub pp_i_modulo { maybe_targmy(@_, \&binop, "%", 19, ASSIGN) }
1824 sub pp_pow { maybe_targmy(@_, \&binop, "**", 22, ASSIGN) }
1825
1826 sub pp_left_shift { maybe_targmy(@_, \&binop, "<<", 17, ASSIGN) }
1827 sub pp_right_shift { maybe_targmy(@_, \&binop, ">>", 17, ASSIGN) }
1828 sub pp_bit_and { maybe_targmy(@_, \&binop, "&", 13, ASSIGN) }
1829 sub pp_bit_or { maybe_targmy(@_, \&binop, "|", 12, ASSIGN) }
1830 sub pp_bit_xor { maybe_targmy(@_, \&binop, "^", 12, ASSIGN) }
1831
1832 sub pp_eq { binop(@_, "==", 14) }
1833 sub pp_ne { binop(@_, "!=", 14) }
1834 sub pp_lt { binop(@_, "<", 15) }
1835 sub pp_gt { binop(@_, ">", 15) }
1836 sub pp_ge { binop(@_, ">=", 15) }
1837 sub pp_le { binop(@_, "<=", 15) }
1838 sub pp_ncmp { binop(@_, "<=>", 14) }
1839 sub pp_i_eq { binop(@_, "==", 14) }
1840 sub pp_i_ne { binop(@_, "!=", 14) }
1841 sub pp_i_lt { binop(@_, "<", 15) }
1842 sub pp_i_gt { binop(@_, ">", 15) }
1843 sub pp_i_ge { binop(@_, ">=", 15) }
1844 sub pp_i_le { binop(@_, "<=", 15) }
1845 sub pp_i_ncmp { binop(@_, "<=>", 14) }
1846
1847 sub pp_seq { binop(@_, "eq", 14) }
1848 sub pp_sne { binop(@_, "ne", 14) }
1849 sub pp_slt { binop(@_, "lt", 15) }
1850 sub pp_sgt { binop(@_, "gt", 15) }
1851 sub pp_sge { binop(@_, "ge", 15) }
1852 sub pp_sle { binop(@_, "le", 15) }
1853 sub pp_scmp { binop(@_, "cmp", 14) }
1854
1855 sub pp_sassign { binop(@_, "=", 7, SWAP_CHILDREN) }
1856 sub pp_aassign { binop(@_, "=", 7, SWAP_CHILDREN | LIST_CONTEXT) }
1857
1858 # `.' is special because concats-of-concats are optimized to save copying
1859 # by making all but the first concat stacked. The effect is as if the
1860 # programmer had written `($a . $b) .= $c', except legal.
1861 sub pp_concat { maybe_targmy(@_, \&real_concat) }
1862 sub real_concat {
1863     my $self = shift;
1864     my($op, $cx) = @_;
1865     my $left = $op->first;
1866     my $right = $op->last;
1867     my $eq = "";
1868     my $prec = 18;
1869     if ($op->flags & OPf_STACKED and $op->first->name ne "concat") {
1870         $eq = "=";
1871         $prec = 7;
1872     }
1873     $left = $self->deparse_binop_left($op, $left, $prec);
1874     $right = $self->deparse_binop_right($op, $right, $prec);
1875     return $self->maybe_parens("$left .$eq $right", $cx, $prec);
1876 }
1877
1878 # `x' is weird when the left arg is a list
1879 sub pp_repeat {
1880     my $self = shift;
1881     my($op, $cx) = @_;
1882     my $left = $op->first;
1883     my $right = $op->last;
1884     my $eq = "";
1885     my $prec = 19;
1886     if ($op->flags & OPf_STACKED) {
1887         $eq = "=";
1888         $prec = 7;
1889     }
1890     if (null($right)) { # list repeat; count is inside left-side ex-list
1891         my $kid = $left->first->sibling; # skip pushmark
1892         my @exprs;
1893         for (; !null($kid->sibling); $kid = $kid->sibling) {
1894             push @exprs, $self->deparse($kid, 6);
1895         }
1896         $right = $kid;
1897         $left = "(" . join(", ", @exprs). ")";
1898     } else {
1899         $left = $self->deparse_binop_left($op, $left, $prec);
1900     }
1901     $right = $self->deparse_binop_right($op, $right, $prec);
1902     return $self->maybe_parens("$left x$eq $right", $cx, $prec);
1903 }
1904
1905 sub range {
1906     my $self = shift;
1907     my ($op, $cx, $type) = @_;
1908     my $left = $op->first;
1909     my $right = $left->sibling;
1910     $left = $self->deparse($left, 9);
1911     $right = $self->deparse($right, 9);
1912     return $self->maybe_parens("$left $type $right", $cx, 9);
1913 }
1914
1915 sub pp_flop {
1916     my $self = shift;
1917     my($op, $cx) = @_;
1918     my $flip = $op->first;
1919     my $type = ($flip->flags & OPf_SPECIAL) ? "..." : "..";
1920     return $self->range($flip->first, $cx, $type);
1921 }
1922
1923 # one-line while/until is handled in pp_leave
1924
1925 sub logop {
1926     my $self = shift;
1927     my ($op, $cx, $lowop, $lowprec, $highop, $highprec, $blockname) = @_;
1928     my $left = $op->first;
1929     my $right = $op->first->sibling;
1930     if ($cx == 0 and is_scope($right) and $blockname
1931         and $self->{'expand'} < 7)
1932     { # if ($a) {$b}
1933         $left = $self->deparse($left, 1);
1934         $right = $self->deparse($right, 0);
1935         return "$blockname ($left) {\n\t$right\n\b}\cK";
1936     } elsif ($cx == 0 and $blockname and not $self->{'parens'}
1937              and $self->{'expand'} < 7) { # $b if $a
1938         $right = $self->deparse($right, 1);
1939         $left = $self->deparse($left, 1);
1940         return "$right $blockname $left";
1941     } elsif ($cx > $lowprec and $highop) { # $a && $b
1942         $left = $self->deparse_binop_left($op, $left, $highprec);
1943         $right = $self->deparse_binop_right($op, $right, $highprec);
1944         return $self->maybe_parens("$left $highop $right", $cx, $highprec);
1945     } else { # $a and $b
1946         $left = $self->deparse_binop_left($op, $left, $lowprec);
1947         $right = $self->deparse_binop_right($op, $right, $lowprec);
1948         return $self->maybe_parens("$left $lowop $right", $cx, $lowprec);
1949     }
1950 }
1951
1952 sub pp_and { logop(@_, "and", 3, "&&", 11, "if") }
1953 sub pp_or  { logop(@_, "or",  2, "||", 10, "unless") }
1954 sub pp_dor { logop(@_, "err", 2, "//", 10, "") }
1955
1956 # xor is syntactically a logop, but it's really a binop (contrary to
1957 # old versions of opcode.pl). Syntax is what matters here.
1958 sub pp_xor { logop(@_, "xor", 2, "",   0,  "") }
1959
1960 sub logassignop {
1961     my $self = shift;
1962     my ($op, $cx, $opname) = @_;
1963     my $left = $op->first;
1964     my $right = $op->first->sibling->first; # skip sassign
1965     $left = $self->deparse($left, 7);
1966     $right = $self->deparse($right, 7);
1967     return $self->maybe_parens("$left $opname $right", $cx, 7);
1968 }
1969
1970 sub pp_andassign { logassignop(@_, "&&=") }
1971 sub pp_orassign  { logassignop(@_, "||=") }
1972 sub pp_dorassign { logassignop(@_, "//=") }
1973
1974 sub listop {
1975     my $self = shift;
1976     my($op, $cx, $name) = @_;
1977     my(@exprs);
1978     my $parens = ($cx >= 5) || $self->{'parens'};
1979     my $kid = $op->first->sibling;
1980     return $name if null $kid;
1981     my $first;
1982     $name = "socketpair" if $name eq "sockpair";
1983     if (defined prototype("CORE::$name")
1984         && prototype("CORE::$name") =~ /^;?\*/
1985         && $kid->name eq "rv2gv") {
1986         $first = $self->deparse($kid->first, 6);
1987     }
1988     else {
1989         $first = $self->deparse($kid, 6);
1990     }
1991     if ($name eq "chmod" && $first =~ /^\d+$/) {
1992         $first = sprintf("%#o", $first);
1993     }
1994     $first = "+$first" if not $parens and substr($first, 0, 1) eq "(";
1995     push @exprs, $first;
1996     $kid = $kid->sibling;
1997     for (; !null($kid); $kid = $kid->sibling) {
1998         push @exprs, $self->deparse($kid, 6);
1999     }
2000     if ($parens) {
2001         return "$name(" . join(", ", @exprs) . ")";
2002     } else {
2003         return "$name " . join(", ", @exprs);
2004     }
2005 }
2006
2007 sub pp_bless { listop(@_, "bless") }
2008 sub pp_atan2 { maybe_targmy(@_, \&listop, "atan2") }
2009 sub pp_substr { maybe_local(@_, listop(@_, "substr")) }
2010 sub pp_vec { maybe_local(@_, listop(@_, "vec")) }
2011 sub pp_index { maybe_targmy(@_, \&listop, "index") }
2012 sub pp_rindex { maybe_targmy(@_, \&listop, "rindex") }
2013 sub pp_sprintf { maybe_targmy(@_, \&listop, "sprintf") }
2014 sub pp_formline { listop(@_, "formline") } # see also deparse_format
2015 sub pp_crypt { maybe_targmy(@_, \&listop, "crypt") }
2016 sub pp_unpack { listop(@_, "unpack") }
2017 sub pp_pack { listop(@_, "pack") }
2018 sub pp_join { maybe_targmy(@_, \&listop, "join") }
2019 sub pp_splice { listop(@_, "splice") }
2020 sub pp_push { maybe_targmy(@_, \&listop, "push") }
2021 sub pp_unshift { maybe_targmy(@_, \&listop, "unshift") }
2022 sub pp_reverse { listop(@_, "reverse") }
2023 sub pp_warn { listop(@_, "warn") }
2024 sub pp_die { listop(@_, "die") }
2025 # Actually, return is exempt from the LLAFR (see examples in this very
2026 # module!), but for consistency's sake, ignore that fact
2027 sub pp_return { listop(@_, "return") }
2028 sub pp_open { listop(@_, "open") }
2029 sub pp_pipe_op { listop(@_, "pipe") }
2030 sub pp_tie { listop(@_, "tie") }
2031 sub pp_binmode { listop(@_, "binmode") }
2032 sub pp_dbmopen { listop(@_, "dbmopen") }
2033 sub pp_sselect { listop(@_, "select") }
2034 sub pp_select { listop(@_, "select") }
2035 sub pp_read { listop(@_, "read") }
2036 sub pp_sysopen { listop(@_, "sysopen") }
2037 sub pp_sysseek { listop(@_, "sysseek") }
2038 sub pp_sysread { listop(@_, "sysread") }
2039 sub pp_syswrite { listop(@_, "syswrite") }
2040 sub pp_send { listop(@_, "send") }
2041 sub pp_recv { listop(@_, "recv") }
2042 sub pp_seek { listop(@_, "seek") }
2043 sub pp_fcntl { listop(@_, "fcntl") }
2044 sub pp_ioctl { listop(@_, "ioctl") }
2045 sub pp_flock { maybe_targmy(@_, \&listop, "flock") }
2046 sub pp_socket { listop(@_, "socket") }
2047 sub pp_sockpair { listop(@_, "sockpair") }
2048 sub pp_bind { listop(@_, "bind") }
2049 sub pp_connect { listop(@_, "connect") }
2050 sub pp_listen { listop(@_, "listen") }
2051 sub pp_accept { listop(@_, "accept") }
2052 sub pp_shutdown { listop(@_, "shutdown") }
2053 sub pp_gsockopt { listop(@_, "getsockopt") }
2054 sub pp_ssockopt { listop(@_, "setsockopt") }
2055 sub pp_chown { maybe_targmy(@_, \&listop, "chown") }
2056 sub pp_unlink { maybe_targmy(@_, \&listop, "unlink") }
2057 sub pp_chmod { maybe_targmy(@_, \&listop, "chmod") }
2058 sub pp_utime { maybe_targmy(@_, \&listop, "utime") }
2059 sub pp_rename { maybe_targmy(@_, \&listop, "rename") }
2060 sub pp_link { maybe_targmy(@_, \&listop, "link") }
2061 sub pp_symlink { maybe_targmy(@_, \&listop, "symlink") }
2062 sub pp_mkdir { maybe_targmy(@_, \&listop, "mkdir") }
2063 sub pp_open_dir { listop(@_, "opendir") }
2064 sub pp_seekdir { listop(@_, "seekdir") }
2065 sub pp_waitpid { maybe_targmy(@_, \&listop, "waitpid") }
2066 sub pp_system { maybe_targmy(@_, \&listop, "system") }
2067 sub pp_exec { maybe_targmy(@_, \&listop, "exec") }
2068 sub pp_kill { maybe_targmy(@_, \&listop, "kill") }
2069 sub pp_setpgrp { maybe_targmy(@_, \&listop, "setpgrp") }
2070 sub pp_getpriority { maybe_targmy(@_, \&listop, "getpriority") }
2071 sub pp_setpriority { maybe_targmy(@_, \&listop, "setpriority") }
2072 sub pp_shmget { listop(@_, "shmget") }
2073 sub pp_shmctl { listop(@_, "shmctl") }
2074 sub pp_shmread { listop(@_, "shmread") }
2075 sub pp_shmwrite { listop(@_, "shmwrite") }
2076 sub pp_msgget { listop(@_, "msgget") }
2077 sub pp_msgctl { listop(@_, "msgctl") }
2078 sub pp_msgsnd { listop(@_, "msgsnd") }
2079 sub pp_msgrcv { listop(@_, "msgrcv") }
2080 sub pp_semget { listop(@_, "semget") }
2081 sub pp_semctl { listop(@_, "semctl") }
2082 sub pp_semop { listop(@_, "semop") }
2083 sub pp_ghbyaddr { listop(@_, "gethostbyaddr") }
2084 sub pp_gnbyaddr { listop(@_, "getnetbyaddr") }
2085 sub pp_gpbynumber { listop(@_, "getprotobynumber") }
2086 sub pp_gsbyname { listop(@_, "getservbyname") }
2087 sub pp_gsbyport { listop(@_, "getservbyport") }
2088 sub pp_syscall { listop(@_, "syscall") }
2089
2090 sub pp_glob {
2091     my $self = shift;
2092     my($op, $cx) = @_;
2093     my $text = $self->dq($op->first->sibling);  # skip pushmark
2094     if ($text =~ /^\$?(\w|::|\`)+$/ # could look like a readline
2095         or $text =~ /[<>]/) {
2096         return 'glob(' . single_delim('qq', '"', $text) . ')';
2097     } else {
2098         return '<' . $text . '>';
2099     }
2100 }
2101
2102 # Truncate is special because OPf_SPECIAL makes a bareword first arg
2103 # be a filehandle. This could probably be better fixed in the core
2104 # by moving the GV lookup into ck_truc.
2105
2106 sub pp_truncate {
2107     my $self = shift;
2108     my($op, $cx) = @_;
2109     my(@exprs);
2110     my $parens = ($cx >= 5) || $self->{'parens'};
2111     my $kid = $op->first->sibling;
2112     my $fh;
2113     if ($op->flags & OPf_SPECIAL) {
2114         # $kid is an OP_CONST
2115         $fh = $self->const_sv($kid)->PV;
2116     } else {
2117         $fh = $self->deparse($kid, 6);
2118         $fh = "+$fh" if not $parens and substr($fh, 0, 1) eq "(";
2119     }
2120     my $len = $self->deparse($kid->sibling, 6);
2121     if ($parens) {
2122         return "truncate($fh, $len)";
2123     } else {
2124         return "truncate $fh, $len";
2125     }
2126 }
2127
2128 sub indirop {
2129     my $self = shift;
2130     my($op, $cx, $name) = @_;
2131     my($expr, @exprs);
2132     my $kid = $op->first->sibling;
2133     my $indir = "";
2134     if ($op->flags & OPf_STACKED) {
2135         $indir = $kid;
2136         $indir = $indir->first; # skip rv2gv
2137         if (is_scope($indir)) {
2138             $indir = "{" . $self->deparse($indir, 0) . "}";
2139         } elsif ($indir->name eq "const" && $indir->private & OPpCONST_BARE) {
2140             $indir = $self->const_sv($indir)->PV;
2141         } else {
2142             $indir = $self->deparse($indir, 24);
2143         }
2144         $indir = $indir . " ";
2145         $kid = $kid->sibling;
2146     }
2147     if ($name eq "sort" && $op->private & (OPpSORT_NUMERIC | OPpSORT_INTEGER)) {
2148         $indir = ($op->private & OPpSORT_REVERSE) ? '{$b <=> $a} '
2149                                                   : '{$a <=> $b} ';
2150     }
2151     elsif ($name eq "sort" && $op->private & OPpSORT_REVERSE) {
2152         $indir = '{$b cmp $a} ';
2153     }
2154     for (; !null($kid); $kid = $kid->sibling) {
2155         $expr = $self->deparse($kid, 6);
2156         push @exprs, $expr;
2157     }
2158     return $self->maybe_parens_func($name, $indir . join(", ", @exprs),
2159                                     $cx, 5);
2160 }
2161
2162 sub pp_prtf { indirop(@_, "printf") }
2163 sub pp_print { indirop(@_, "print") }
2164 sub pp_sort { indirop(@_, "sort") }
2165
2166 sub mapop {
2167     my $self = shift;
2168     my($op, $cx, $name) = @_;
2169     my($expr, @exprs);
2170     my $kid = $op->first; # this is the (map|grep)start
2171     $kid = $kid->first->sibling; # skip a pushmark
2172     my $code = $kid->first; # skip a null
2173     if (is_scope $code) {
2174         $code = "{" . $self->deparse($code, 0) . "} ";
2175     } else {
2176         $code = $self->deparse($code, 24) . ", ";
2177     }
2178     $kid = $kid->sibling;
2179     for (; !null($kid); $kid = $kid->sibling) {
2180         $expr = $self->deparse($kid, 6);
2181         push @exprs, $expr if defined $expr;
2182     }
2183     return $self->maybe_parens_func($name, $code . join(", ", @exprs), $cx, 5);
2184 }
2185
2186 sub pp_mapwhile { mapop(@_, "map") }
2187 sub pp_grepwhile { mapop(@_, "grep") }
2188
2189 sub pp_list {
2190     my $self = shift;
2191     my($op, $cx) = @_;
2192     my($expr, @exprs);
2193     my $kid = $op->first->sibling; # skip pushmark
2194     my $lop;
2195     my $local = "either"; # could be local(...), my(...) or our(...)
2196     for ($lop = $kid; !null($lop); $lop = $lop->sibling) {
2197         # This assumes that no other private flags equal 128, and that
2198         # OPs that store things other than flags in their op_private,
2199         # like OP_AELEMFAST, won't be immediate children of a list.
2200         #
2201         # OP_ENTERSUB can break this logic, so check for it.
2202         # I suspect that open and exit can too.
2203
2204         if (!($lop->private & (OPpLVAL_INTRO|OPpOUR_INTRO)
2205                 or $lop->name eq "undef")
2206             or $lop->name eq "entersub"
2207             or $lop->name eq "exit"
2208             or $lop->name eq "open")
2209         {
2210             $local = ""; # or not
2211             last;
2212         }
2213         if ($lop->name =~ /^pad[ash]v$/) { # my()
2214             ($local = "", last) if $local eq "local" || $local eq "our";
2215             $local = "my";
2216         } elsif ($lop->name =~ /^(gv|rv2)[ash]v$/
2217                         && $lop->private & OPpOUR_INTRO
2218                 or $lop->name eq "null" && $lop->first->name eq "gvsv"
2219                         && $lop->first->private & OPpOUR_INTRO) { # our()
2220             ($local = "", last) if $local eq "my" || $local eq "local";
2221             $local = "our";
2222         } elsif ($lop->name ne "undef") { # local()
2223             ($local = "", last) if $local eq "my" || $local eq "our";
2224             $local = "local";
2225         }
2226     }
2227     $local = "" if $local eq "either"; # no point if it's all undefs
2228     return $self->deparse($kid, $cx) if null $kid->sibling and not $local;
2229     for (; !null($kid); $kid = $kid->sibling) {
2230         if ($local) {
2231             if (class($kid) eq "UNOP" and $kid->first->name eq "gvsv") {
2232                 $lop = $kid->first;
2233             } else {
2234                 $lop = $kid;
2235             }
2236             $self->{'avoid_local'}{$$lop}++;
2237             $expr = $self->deparse($kid, 6);
2238             delete $self->{'avoid_local'}{$$lop};
2239         } else {
2240             $expr = $self->deparse($kid, 6);
2241         }
2242         push @exprs, $expr;
2243     }
2244     if ($local) {
2245         return "$local(" . join(", ", @exprs) . ")";
2246     } else {
2247         return $self->maybe_parens( join(", ", @exprs), $cx, 6);
2248     }
2249 }
2250
2251 sub is_ifelse_cont {
2252     my $op = shift;
2253     return ($op->name eq "null" and class($op) eq "UNOP"
2254             and $op->first->name =~ /^(and|cond_expr)$/
2255             and is_scope($op->first->first->sibling));
2256 }
2257
2258 sub pp_cond_expr {
2259     my $self = shift;
2260     my($op, $cx) = @_;
2261     my $cond = $op->first;
2262     my $true = $cond->sibling;
2263     my $false = $true->sibling;
2264     my $cuddle = $self->{'cuddle'};
2265     unless ($cx == 0 and (is_scope($true) and $true->name ne "null") and
2266             (is_scope($false) || is_ifelse_cont($false))
2267             and $self->{'expand'} < 7) {
2268         $cond = $self->deparse($cond, 8);
2269         $true = $self->deparse($true, 8);
2270         $false = $self->deparse($false, 8);
2271         return $self->maybe_parens("$cond ? $true : $false", $cx, 8);
2272     }
2273
2274     $cond = $self->deparse($cond, 1);
2275     $true = $self->deparse($true, 0);
2276     my $head = "if ($cond) {\n\t$true\n\b}";
2277     my @elsifs;
2278     while (!null($false) and is_ifelse_cont($false)) {
2279         my $newop = $false->first;
2280         my $newcond = $newop->first;
2281         my $newtrue = $newcond->sibling;
2282         $false = $newtrue->sibling; # last in chain is OP_AND => no else
2283         $newcond = $self->deparse($newcond, 1);
2284         $newtrue = $self->deparse($newtrue, 0);
2285         push @elsifs, "elsif ($newcond) {\n\t$newtrue\n\b}";
2286     }
2287     if (!null($false)) {
2288         $false = $cuddle . "else {\n\t" .
2289           $self->deparse($false, 0) . "\n\b}\cK";
2290     } else {
2291         $false = "\cK";
2292     }
2293     return $head . join($cuddle, "", @elsifs) . $false;
2294 }
2295
2296 sub loop_common {
2297     my $self = shift;
2298     my($op, $cx, $init) = @_;
2299     my $enter = $op->first;
2300     my $kid = $enter->sibling;
2301     local(@$self{qw'curstash warnings hints'})
2302                 = @$self{qw'curstash warnings hints'};
2303     my $head = "";
2304     my $bare = 0;
2305     my $body;
2306     my $cond = undef;
2307     if ($kid->name eq "lineseq") { # bare or infinite loop
2308         if (is_state $kid->last) { # infinite
2309             $head = "while (1) "; # Can't use for(;;) if there's a continue
2310             $cond = "";
2311         } else {
2312             $bare = 1;
2313         }
2314         $body = $kid;
2315     } elsif ($enter->name eq "enteriter") { # foreach
2316         my $ary = $enter->first->sibling; # first was pushmark
2317         my $var = $ary->sibling;
2318         if ($enter->flags & OPf_STACKED
2319             and not null $ary->first->sibling->sibling)
2320         {
2321             $ary = $self->deparse($ary->first->sibling, 9) . " .. " .
2322               $self->deparse($ary->first->sibling->sibling, 9);
2323         } else {
2324             $ary = $self->deparse($ary, 1);
2325         }
2326         if (null $var) {
2327             if ($enter->flags & OPf_SPECIAL) { # thread special var
2328                 $var = $self->pp_threadsv($enter, 1);
2329             } else { # regular my() variable
2330                 $var = $self->pp_padsv($enter, 1);
2331                 if ($self->padname_sv($enter->targ)->IVX ==
2332                     $kid->first->first->sibling->last->cop_seq)
2333                 {
2334                     # If the scope of this variable closes at the last
2335                     # statement of the loop, it must have been
2336                     # declared here.
2337                     $var = "my " . $var;
2338                 }
2339             }
2340         } elsif ($var->name eq "rv2gv") {
2341             $var = $self->pp_rv2sv($var, 1);
2342         } elsif ($var->name eq "gv") {
2343             $var = "\$" . $self->deparse($var, 1);
2344         }
2345         $head = "foreach $var ($ary) ";
2346         $body = $kid->first->first->sibling; # skip OP_AND and OP_ITER
2347     } elsif ($kid->name eq "null") { # while/until
2348         $kid = $kid->first;
2349         my $name = {"and" => "while", "or" => "until"}->{$kid->name};
2350         $cond = $self->deparse($kid->first, 1);
2351         $head = "$name ($cond) ";
2352         $body = $kid->first->sibling;
2353     } elsif ($kid->name eq "stub") { # bare and empty
2354         return "{;}"; # {} could be a hashref
2355     }
2356     # If there isn't a continue block, then the next pointer for the loop
2357     # will point to the unstack, which is kid's penultimate child, except
2358     # in a bare loop, when it will point to the leaveloop. When neither of
2359     # these conditions hold, then the third-to-last child in the continue
2360     # block (or the last in a bare loop).
2361     my $cont_start = $enter->nextop;
2362     my $cont;
2363     if ($$cont_start != $$op && ${$cont_start->sibling} != ${$body->last}) {
2364         if ($bare) {
2365             $cont = $body->last;
2366         } else {
2367             $cont = $body->first;
2368             while (!null($cont->sibling->sibling->sibling)) {
2369                 $cont = $cont->sibling;
2370             }
2371         }
2372         my $state = $body->first;
2373         my $cuddle = $self->{'cuddle'};
2374         my @states;
2375         for (; $$state != $$cont; $state = $state->sibling) {
2376             push @states, $state;
2377         }
2378         $body = $self->lineseq(undef, @states);
2379         if (defined $cond and not is_scope $cont and $self->{'expand'} < 3) {
2380             $head = "for ($init; $cond; " . $self->deparse($cont, 1) .") ";
2381             $cont = "\cK";
2382         } else {
2383             $cont = $cuddle . "continue {\n\t" .
2384               $self->deparse($cont, 0) . "\n\b}\cK";
2385         }
2386     } else {
2387         return "" if !defined $body;
2388         if (length $init) {
2389             $head = "for ($init; $cond;) ";
2390         }
2391         $cont = "\cK";
2392         $body = $self->deparse($body, 0);
2393     }
2394     $body =~ s/;?$/;\n/;
2395
2396     return $head . "{\n\t" . $body . "\b}" . $cont;
2397 }
2398
2399 sub pp_leaveloop { loop_common(@_, "") }
2400
2401 sub for_loop {
2402     my $self = shift;
2403     my($op, $cx) = @_;
2404     my $init = $self->deparse($op, 1);
2405     return $self->loop_common($op->sibling->first->sibling, $cx, $init);
2406 }
2407
2408 sub pp_leavetry {
2409     my $self = shift;
2410     return "eval {\n\t" . $self->pp_leave(@_) . "\n\b}";
2411 }
2412
2413 BEGIN { eval "sub OP_CONST () {" . opnumber("const") . "}" }
2414 BEGIN { eval "sub OP_STRINGIFY () {" . opnumber("stringify") . "}" }
2415 BEGIN { eval "sub OP_RV2SV () {" . opnumber("rv2sv") . "}" }
2416 BEGIN { eval "sub OP_LIST () {" . opnumber("list") . "}" }
2417
2418 sub pp_null {
2419     my $self = shift;
2420     my($op, $cx) = @_;
2421     if (class($op) eq "OP") {
2422         # old value is lost
2423         return $self->{'ex_const'} if $op->targ == OP_CONST;
2424     } elsif ($op->first->name eq "pushmark") {
2425         return $self->pp_list($op, $cx);
2426     } elsif ($op->first->name eq "enter") {
2427         return $self->pp_leave($op, $cx);
2428     } elsif ($op->targ == OP_STRINGIFY) {
2429         return $self->dquote($op, $cx);
2430     } elsif (!null($op->first->sibling) and
2431              $op->first->sibling->name eq "readline" and
2432              $op->first->sibling->flags & OPf_STACKED) {
2433         return $self->maybe_parens($self->deparse($op->first, 7) . " = "
2434                                    . $self->deparse($op->first->sibling, 7),
2435                                    $cx, 7);
2436     } elsif (!null($op->first->sibling) and
2437              $op->first->sibling->name eq "trans" and
2438              $op->first->sibling->flags & OPf_STACKED) {
2439         return $self->maybe_parens($self->deparse($op->first, 20) . " =~ "
2440                                    . $self->deparse($op->first->sibling, 20),
2441                                    $cx, 20);
2442     } elsif ($op->flags & OPf_SPECIAL && $cx == 0 && !$op->targ) {
2443         return "do {\n\t". $self->deparse($op->first, $cx) ."\n\b};";
2444     } elsif (!null($op->first->sibling) and
2445              $op->first->sibling->name eq "null" and
2446              class($op->first->sibling) eq "UNOP" and
2447              $op->first->sibling->first->flags & OPf_STACKED and
2448              $op->first->sibling->first->name eq "rcatline") {
2449         return $self->maybe_parens($self->deparse($op->first, 18) . " .= "
2450                                    . $self->deparse($op->first->sibling, 18),
2451                                    $cx, 18);
2452     } else {
2453         return $self->deparse($op->first, $cx);
2454     }
2455 }
2456
2457 sub padname {
2458     my $self = shift;
2459     my $targ = shift;
2460     return $self->padname_sv($targ)->PVX;
2461 }
2462
2463 sub padany {
2464     my $self = shift;
2465     my $op = shift;
2466     return substr($self->padname($op->targ), 1); # skip $/@/%
2467 }
2468
2469 sub pp_padsv {
2470     my $self = shift;
2471     my($op, $cx) = @_;
2472     return $self->maybe_my($op, $cx, $self->padname($op->targ));
2473 }
2474
2475 sub pp_padav { pp_padsv(@_) }
2476 sub pp_padhv { pp_padsv(@_) }
2477
2478 my @threadsv_names;
2479
2480 BEGIN {
2481     @threadsv_names = ("_", "1", "2", "3", "4", "5", "6", "7", "8", "9",
2482                        "&", "`", "'", "+", "/", ".", ",", "\\", '"', ";",
2483                        "^", "-", "%", "=", "|", "~", ":", "^A", "^E",
2484                        "!", "@");
2485 }
2486
2487 sub pp_threadsv {
2488     my $self = shift;
2489     my($op, $cx) = @_;
2490     return $self->maybe_local($op, $cx, "\$" .  $threadsv_names[$op->targ]);
2491 }
2492
2493 sub gv_or_padgv {
2494     my $self = shift;
2495     my $op = shift;
2496     if (class($op) eq "PADOP") {
2497         return $self->padval($op->padix);
2498     } else { # class($op) eq "SVOP"
2499         return $op->gv;
2500     }
2501 }
2502
2503 sub pp_gvsv {
2504     my $self = shift;
2505     my($op, $cx) = @_;
2506     my $gv = $self->gv_or_padgv($op);
2507     return $self->maybe_local($op, $cx, $self->stash_variable("\$",
2508                                  $self->gv_name($gv)));
2509 }
2510
2511 sub pp_gv {
2512     my $self = shift;
2513     my($op, $cx) = @_;
2514     my $gv = $self->gv_or_padgv($op);
2515     return $self->gv_name($gv);
2516 }
2517
2518 sub pp_aelemfast {
2519     my $self = shift;
2520     my($op, $cx) = @_;
2521     my $gv = $self->gv_or_padgv($op);
2522     my $name = $self->gv_name($gv);
2523     $name = $self->{'curstash'}."::$name"
2524         if $name !~ /::/ && $self->lex_in_scope('@'.$name);
2525
2526     return "\$" . $name . "[" .
2527                   ($op->private + $self->{'arybase'}) . "]";
2528 }
2529
2530 sub rv2x {
2531     my $self = shift;
2532     my($op, $cx, $type) = @_;
2533
2534     if (class($op) eq 'NULL' || !$op->can("first")) {
2535         carp("Unexpected op in pp_rv2x");
2536         return 'XXX';
2537     }
2538     my $kid = $op->first;
2539     my $str = $self->deparse($kid, 0);
2540     return $self->stash_variable($type, $str) if is_scalar($kid);
2541     return $type ."{$str}";
2542 }
2543
2544 sub pp_rv2sv { maybe_local(@_, rv2x(@_, "\$")) }
2545 sub pp_rv2hv { maybe_local(@_, rv2x(@_, "%")) }
2546 sub pp_rv2gv { maybe_local(@_, rv2x(@_, "*")) }
2547
2548 # skip rv2av
2549 sub pp_av2arylen {
2550     my $self = shift;
2551     my($op, $cx) = @_;
2552     if ($op->first->name eq "padav") {
2553         return $self->maybe_local($op, $cx, '$#' . $self->padany($op->first));
2554     } else {
2555         return $self->maybe_local($op, $cx,
2556                                   $self->rv2x($op->first, $cx, '$#'));
2557     }
2558 }
2559
2560 # skip down to the old, ex-rv2cv
2561 sub pp_rv2cv {
2562     my ($self, $op, $cx) = @_;
2563     if (!null($op->first) && $op->first->name eq 'null' &&
2564         $op->first->targ eq OP_LIST)
2565     {
2566         return $self->rv2x($op->first->first->sibling, $cx, "&")
2567     }
2568     else {
2569         return $self->rv2x($op, $cx, "")
2570     }
2571 }
2572
2573 sub pp_rv2av {
2574     my $self = shift;
2575     my($op, $cx) = @_;
2576     my $kid = $op->first;
2577     if ($kid->name eq "const") { # constant list
2578         my $av = $self->const_sv($kid);
2579         return "(" . join(", ", map(const($_), $av->ARRAY)) . ")";
2580     } else {
2581         return $self->maybe_local($op, $cx, $self->rv2x($op, $cx, "\@"));
2582     }
2583  }
2584
2585 sub is_subscriptable {
2586     my $op = shift;
2587     if ($op->name =~ /^[ahg]elem/) {
2588         return 1;
2589     } elsif ($op->name eq "entersub") {
2590         my $kid = $op->first;
2591         return 0 unless null $kid->sibling;
2592         $kid = $kid->first;
2593         $kid = $kid->sibling until null $kid->sibling;
2594         return 0 if is_scope($kid);
2595         $kid = $kid->first;
2596         return 0 if $kid->name eq "gv";
2597         return 0 if is_scalar($kid);
2598         return is_subscriptable($kid);
2599     } else {
2600         return 0;
2601     }
2602 }
2603
2604 sub elem {
2605     my $self = shift;
2606     my ($op, $cx, $left, $right, $padname) = @_;
2607     my($array, $idx) = ($op->first, $op->first->sibling);
2608     unless ($array->name eq $padname) { # Maybe this has been fixed
2609         $array = $array->first; # skip rv2av (or ex-rv2av in _53+)
2610     }
2611     if ($array->name eq $padname) {
2612         $array = $self->padany($array);
2613     } elsif (is_scope($array)) { # ${expr}[0]
2614         $array = "{" . $self->deparse($array, 0) . "}";
2615     } elsif ($array->name eq "gv") {
2616         $array = $self->gv_name($self->gv_or_padgv($array));
2617         if ($array !~ /::/) {
2618             my $prefix = ($left eq '[' ? '@' : '%');
2619             $array = $self->{curstash}.'::'.$array
2620                 if $self->lex_in_scope($prefix . $array);
2621         }
2622     } elsif (is_scalar $array) { # $x[0], $$x[0], ...
2623         $array = $self->deparse($array, 24);
2624     } else {
2625         # $x[20][3]{hi} or expr->[20]
2626         my $arrow = is_subscriptable($array) ? "" : "->";
2627         return $self->deparse($array, 24) . $arrow .
2628             $left . $self->deparse($idx, 1) . $right;
2629     }
2630     $idx = $self->deparse($idx, 1);
2631
2632     # Outer parens in an array index will confuse perl
2633     # if we're interpolating in a regular expression, i.e.
2634     # /$x$foo[(-1)]/ is *not* the same as /$x$foo[-1]/
2635     #
2636     # If $self->{parens}, then an initial '(' will
2637     # definitely be paired with a final ')'. If
2638     # !$self->{parens}, the misleading parens won't
2639     # have been added in the first place.
2640     #
2641     # [You might think that we could get "(...)...(...)"
2642     # where the initial and final parens do not match
2643     # each other. But we can't, because the above would
2644     # only happen if there's an infix binop between the
2645     # two pairs of parens, and *that* means that the whole
2646     # expression would be parenthesized as well.]
2647     #
2648     $idx =~ s/^\((.*)\)$/$1/ if $self->{'parens'};
2649
2650     # Hash-element braces will autoquote a bareword inside themselves.
2651     # We need to make sure that C<$hash{warn()}> doesn't come out as
2652     # C<$hash{warn}>, which has a quite different meaning. Currently
2653     # B::Deparse will always quote strings, even if the string was a
2654     # bareword in the original (i.e. the OPpCONST_BARE flag is ignored
2655     # for constant strings.) So we can cheat slightly here - if we see
2656     # a bareword, we know that it is supposed to be a function call.
2657     #
2658     $idx =~ s/^([A-Za-z_]\w*)$/$1()/;
2659
2660     return "\$" . $array . $left . $idx . $right;
2661 }
2662
2663 sub pp_aelem { maybe_local(@_, elem(@_, "[", "]", "padav")) }
2664 sub pp_helem { maybe_local(@_, elem(@_, "{", "}", "padhv")) }
2665
2666 sub pp_gelem {
2667     my $self = shift;
2668     my($op, $cx) = @_;
2669     my($glob, $part) = ($op->first, $op->last);
2670     $glob = $glob->first; # skip rv2gv
2671     $glob = $glob->first if $glob->name eq "rv2gv"; # this one's a bug
2672     my $scope = is_scope($glob);
2673     $glob = $self->deparse($glob, 0);
2674     $part = $self->deparse($part, 1);
2675     return "*" . ($scope ? "{$glob}" : $glob) . "{$part}";
2676 }
2677
2678 sub slice {
2679     my $self = shift;
2680     my ($op, $cx, $left, $right, $regname, $padname) = @_;
2681     my $last;
2682     my(@elems, $kid, $array, $list);
2683     if (class($op) eq "LISTOP") {
2684         $last = $op->last;
2685     } else { # ex-hslice inside delete()
2686         for ($kid = $op->first; !null $kid->sibling; $kid = $kid->sibling) {}
2687         $last = $kid;
2688     }
2689     $array = $last;
2690     $array = $array->first
2691         if $array->name eq $regname or $array->name eq "null";
2692     if (is_scope($array)) {
2693         $array = "{" . $self->deparse($array, 0) . "}";
2694     } elsif ($array->name eq $padname) {
2695         $array = $self->padany($array);
2696     } else {
2697         $array = $self->deparse($array, 24);
2698     }
2699     $kid = $op->first->sibling; # skip pushmark
2700     if ($kid->name eq "list") {
2701         $kid = $kid->first->sibling; # skip list, pushmark
2702         for (; !null $kid; $kid = $kid->sibling) {
2703             push @elems, $self->deparse($kid, 6);
2704         }
2705         $list = join(", ", @elems);
2706     } else {
2707         $list = $self->deparse($kid, 1);
2708     }
2709     return "\@" . $array . $left . $list . $right;
2710 }
2711
2712 sub pp_aslice { maybe_local(@_, slice(@_, "[", "]", "rv2av", "padav")) }
2713 sub pp_hslice { maybe_local(@_, slice(@_, "{", "}", "rv2hv", "padhv")) }
2714
2715 sub pp_lslice {
2716     my $self = shift;
2717     my($op, $cx) = @_;
2718     my $idx = $op->first;
2719     my $list = $op->last;
2720     my(@elems, $kid);
2721     $list = $self->deparse($list, 1);
2722     $idx = $self->deparse($idx, 1);
2723     return "($list)" . "[$idx]";
2724 }
2725
2726 sub want_scalar {
2727     my $op = shift;
2728     return ($op->flags & OPf_WANT) == OPf_WANT_SCALAR;
2729 }
2730
2731 sub want_list {
2732     my $op = shift;
2733     return ($op->flags & OPf_WANT) == OPf_WANT_LIST;
2734 }
2735
2736 sub method {
2737     my $self = shift;
2738     my($op, $cx) = @_;
2739     my $kid = $op->first->sibling; # skip pushmark
2740     my($meth, $obj, @exprs);
2741     if ($kid->name eq "list" and want_list $kid) {
2742         # When an indirect object isn't a bareword but the args are in
2743         # parens, the parens aren't part of the method syntax (the LLAFR
2744         # doesn't apply), but they make a list with OPf_PARENS set that
2745         # doesn't get flattened by the append_elem that adds the method,
2746         # making a (object, arg1, arg2, ...) list where the object
2747         # usually is. This can be distinguished from
2748         # `($obj, $arg1, $arg2)->meth()' (which is legal if $arg2 is an
2749         # object) because in the later the list is in scalar context
2750         # as the left side of -> always is, while in the former
2751         # the list is in list context as method arguments always are.
2752         # (Good thing there aren't method prototypes!)
2753         $meth = $kid->sibling;
2754         $kid = $kid->first->sibling; # skip pushmark
2755         $obj = $kid;
2756         $kid = $kid->sibling;
2757         for (; not null $kid; $kid = $kid->sibling) {
2758             push @exprs, $self->deparse($kid, 6);
2759         }
2760     } else {
2761         $obj = $kid;
2762         $kid = $kid->sibling;
2763         for (; !null ($kid->sibling) && $kid->name ne "method_named";
2764               $kid = $kid->sibling) {
2765             push @exprs, $self->deparse($kid, 6);
2766         }
2767         $meth = $kid;
2768     }
2769     $obj = $self->deparse($obj, 24);
2770     if ($meth->name eq "method_named") {
2771         $meth = $self->const_sv($meth)->PV;
2772     } else {
2773         $meth = $meth->first;
2774         if ($meth->name eq "const") {
2775             # As of 5.005_58, this case is probably obsoleted by the
2776             # method_named case above
2777             $meth = $self->const_sv($meth)->PV; # needs to be bare
2778         } else {
2779             $meth = $self->deparse($meth, 1);
2780         }
2781     }
2782     my $args = join(", ", @exprs);
2783     $kid = $obj . "->" . $meth;
2784     if (length $args) {
2785         return $kid . "(" . $args . ")"; # parens mandatory
2786     } else {
2787         return $kid;
2788     }
2789 }
2790
2791 # returns "&" if the prototype doesn't match the args,
2792 # or ("", $args_after_prototype_demunging) if it does.
2793 sub check_proto {
2794     my $self = shift;
2795     return "&" if $self->{'noproto'};
2796     my($proto, @args) = @_;
2797     my($arg, $real);
2798     my $doneok = 0;
2799     my @reals;
2800     # An unbackslashed @ or % gobbles up the rest of the args
2801     1 while $proto =~ s/(?<!\\)([@%])[^\]]+$/$1/;
2802     while ($proto) {
2803         $proto =~ s/^(\\?[\$\@&%*]|\\\[[\$\@&%*]+\]|;)//;
2804         my $chr = $1;
2805         if ($chr eq "") {
2806             return "&" if @args;
2807         } elsif ($chr eq ";") {
2808             $doneok = 1;
2809         } elsif ($chr eq "@" or $chr eq "%") {
2810             push @reals, map($self->deparse($_, 6), @args);
2811             @args = ();
2812         } else {
2813             $arg = shift @args;
2814             last unless $arg;
2815             if ($chr eq "\$") {
2816                 if (want_scalar $arg) {
2817                     push @reals, $self->deparse($arg, 6);
2818                 } else {
2819                     return "&";
2820                 }
2821             } elsif ($chr eq "&") {
2822                 if ($arg->name =~ /^(s?refgen|undef)$/) {
2823                     push @reals, $self->deparse($arg, 6);
2824                 } else {
2825                     return "&";
2826                 }
2827             } elsif ($chr eq "*") {
2828                 if ($arg->name =~ /^s?refgen$/
2829                     and $arg->first->first->name eq "rv2gv")
2830                   {
2831                       $real = $arg->first->first; # skip refgen, null
2832                       if ($real->first->name eq "gv") {
2833                           push @reals, $self->deparse($real, 6);
2834                       } else {
2835                           push @reals, $self->deparse($real->first, 6);
2836                       }
2837                   } else {
2838                       return "&";
2839                   }
2840             } elsif (substr($chr, 0, 1) eq "\\") {
2841                 $chr =~ tr/\\[]//d;
2842                 if ($arg->name =~ /^s?refgen$/ and
2843                     !null($real = $arg->first) and
2844                     ($chr =~ /\$/ && is_scalar($real->first)
2845                      or ($chr =~ /@/
2846                          && class($real->first->sibling) ne 'NULL'
2847                          && $real->first->sibling->name
2848                          =~ /^(rv2|pad)av$/)
2849                      or ($chr =~ /%/
2850                          && class($real->first->sibling) ne 'NULL'
2851                          && $real->first->sibling->name
2852                          =~ /^(rv2|pad)hv$/)
2853                      #or ($chr =~ /&/ # This doesn't work
2854                      #   && $real->first->name eq "rv2cv")
2855                      or ($chr =~ /\*/
2856                          && $real->first->name eq "rv2gv")))
2857                   {
2858                       push @reals, $self->deparse($real, 6);
2859                   } else {
2860                       return "&";
2861                   }
2862             }
2863        }
2864     }
2865     return "&" if $proto and !$doneok; # too few args and no `;'
2866     return "&" if @args;               # too many args
2867     return ("", join ", ", @reals);
2868 }
2869
2870 sub pp_entersub {
2871     my $self = shift;
2872     my($op, $cx) = @_;
2873     return $self->method($op, $cx) unless null $op->first->sibling;
2874     my $prefix = "";
2875     my $amper = "";
2876     my($kid, @exprs);
2877     if ($op->flags & OPf_SPECIAL && !($op->flags & OPf_MOD)) {
2878         $prefix = "do ";
2879     } elsif ($op->private & OPpENTERSUB_AMPER) {
2880         $amper = "&";
2881     }
2882     $kid = $op->first;
2883     $kid = $kid->first->sibling; # skip ex-list, pushmark
2884     for (; not null $kid->sibling; $kid = $kid->sibling) {
2885         push @exprs, $kid;
2886     }
2887     my $simple = 0;
2888     my $proto = undef;
2889     if (is_scope($kid)) {
2890         $amper = "&";
2891         $kid = "{" . $self->deparse($kid, 0) . "}";
2892     } elsif ($kid->first->name eq "gv") {
2893         my $gv = $self->gv_or_padgv($kid->first);
2894         if (class($gv->CV) ne "SPECIAL") {
2895             $proto = $gv->CV->PV if $gv->CV->FLAGS & SVf_POK;
2896         }
2897         $simple = 1; # only calls of named functions can be prototyped
2898         $kid = $self->deparse($kid, 24);
2899     } elsif (is_scalar ($kid->first) && $kid->first->name ne 'rv2cv') {
2900         $amper = "&";
2901         $kid = $self->deparse($kid, 24);
2902     } else {
2903         $prefix = "";
2904         my $arrow = is_subscriptable($kid->first) ? "" : "->";
2905         $kid = $self->deparse($kid, 24) . $arrow;
2906     }
2907
2908     # Doesn't matter how many prototypes there are, if
2909     # they haven't happened yet!
2910     my $declared;
2911     {
2912         no strict 'refs';
2913         no warnings 'uninitialized';
2914         $declared = exists $self->{'subs_declared'}{$kid}
2915             || (
2916                  defined &{ %{$self->{'curstash'}."::"}->{$kid} }
2917                  && !exists
2918                      $self->{'subs_deparsed'}{$self->{'curstash'}."::".$kid}
2919                  && defined prototype $self->{'curstash'}."::".$kid
2920                );
2921         if (!$declared && defined($proto)) {
2922             # Avoid "too early to check prototype" warning
2923             ($amper, $proto) = ('&');
2924         }
2925     }
2926
2927     my $args;
2928     if ($declared and defined $proto and not $amper) {
2929         ($amper, $args) = $self->check_proto($proto, @exprs);
2930         if ($amper eq "&") {
2931             $args = join(", ", map($self->deparse($_, 6), @exprs));
2932         }
2933     } else {
2934         $args = join(", ", map($self->deparse($_, 6), @exprs));
2935     }
2936     if ($prefix or $amper) {
2937         if ($op->flags & OPf_STACKED) {
2938             return $prefix . $amper . $kid . "(" . $args . ")";
2939         } else {
2940             return $prefix . $amper. $kid;
2941         }
2942     } else {
2943         # glob() invocations can be translated into calls of
2944         # CORE::GLOBAL::glob with a second parameter, a number.
2945         # Reverse this.
2946         if ($kid eq "CORE::GLOBAL::glob") {
2947             $kid = "glob";
2948             $args =~ s/\s*,[^,]+$//;
2949         }
2950
2951         # It's a syntax error to call CORE::GLOBAL::foo without a prefix,
2952         # so it must have been translated from a keyword call. Translate
2953         # it back.
2954         $kid =~ s/^CORE::GLOBAL:://;
2955
2956         if (!$declared) {
2957             return "$kid(" . $args . ")";
2958         } elsif (defined $proto and $proto eq "") {
2959             return $kid;
2960         } elsif (defined $proto and $proto eq "\$" and is_scalar($exprs[0])) {
2961             return $self->maybe_parens_func($kid, $args, $cx, 16);
2962         } elsif (defined($proto) && $proto or $simple) {
2963             return $self->maybe_parens_func($kid, $args, $cx, 5);
2964         } else {
2965             return "$kid(" . $args . ")";
2966         }
2967     }
2968 }
2969
2970 sub pp_enterwrite { unop(@_, "write") }
2971
2972 # escape things that cause interpolation in double quotes,
2973 # but not character escapes
2974 sub uninterp {
2975     my($str) = @_;
2976     $str =~ s/(^|\G|[^\\])((?:\\\\)*)([\$\@]|\\[uUlLQE])/$1$2\\$3/g;
2977     return $str;
2978 }
2979
2980 {
2981 my $bal;
2982 BEGIN {
2983     use re "eval";
2984     # Matches any string which is balanced with respect to {braces}
2985     $bal = qr(
2986       (?:
2987         [^\\{}]
2988       | \\\\
2989       | \\[{}]
2990       | \{(??{$bal})\}
2991       )*
2992     )x;
2993 }
2994
2995 # the same, but treat $|, $), $( and $ at the end of the string differently
2996 sub re_uninterp {
2997     my($str) = @_;
2998
2999     $str =~ s/
3000           ( ^|\G                  # $1
3001           | [^\\]
3002           )
3003
3004           (                       # $2
3005             (?:\\\\)*
3006           )
3007
3008           (                       # $3
3009             (\(\?\??\{$bal\}\))   # $4
3010           | [\$\@]
3011             (?!\||\)|\(|$)
3012           | \\[uUlLQE]
3013           )
3014
3015         /length($4) ? "$1$2$4" : "$1$2\\$3"/xeg;
3016
3017     return $str;
3018 }
3019
3020 # This is for regular expressions with the /x modifier
3021 # We have to leave comments unmangled.
3022 sub re_uninterp_extended {
3023     my($str) = @_;
3024
3025     $str =~ s/
3026           ( ^|\G                  # $1
3027           | [^\\]
3028           )
3029
3030           (                       # $2
3031             (?:\\\\)*
3032           )
3033
3034           (                       # $3
3035             ( \(\?\??\{$bal\}\)   # $4  (skip over (?{}) and (??{}) blocks)
3036             | \#[^\n]*            #     (skip over comments)
3037             )
3038           | [\$\@]
3039             (?!\||\)|\(|$|\s)
3040           | \\[uUlLQE]
3041           )
3042
3043         /length($4) ? "$1$2$4" : "$1$2\\$3"/xeg;
3044
3045     return $str;
3046 }
3047 }
3048
3049 my %unctrl = # portable to to EBCDIC
3050     (
3051      "\c@" => '\c@',    # unused
3052      "\cA" => '\cA',
3053      "\cB" => '\cB',
3054      "\cC" => '\cC',
3055      "\cD" => '\cD',
3056      "\cE" => '\cE',
3057      "\cF" => '\cF',
3058      "\cG" => '\cG',
3059      "\cH" => '\cH',
3060      "\cI" => '\cI',
3061      "\cJ" => '\cJ',
3062      "\cK" => '\cK',
3063      "\cL" => '\cL',
3064      "\cM" => '\cM',
3065      "\cN" => '\cN',
3066      "\cO" => '\cO',
3067      "\cP" => '\cP',
3068      "\cQ" => '\cQ',
3069      "\cR" => '\cR',
3070      "\cS" => '\cS',
3071      "\cT" => '\cT',
3072      "\cU" => '\cU',
3073      "\cV" => '\cV',
3074      "\cW" => '\cW',
3075      "\cX" => '\cX',
3076      "\cY" => '\cY',
3077      "\cZ" => '\cZ',
3078      "\c[" => '\c[',    # unused
3079      "\c\\" => '\c\\',  # unused
3080      "\c]" => '\c]',    # unused
3081      "\c_" => '\c_',    # unused
3082     );
3083
3084 # character escapes, but not delimiters that might need to be escaped
3085 sub escape_str { # ASCII, UTF8
3086     my($str) = @_;
3087     $str =~ s/(.)/ord($1) > 255 ? sprintf("\\x{%x}", ord($1)) : $1/eg;
3088     $str =~ s/\a/\\a/g;
3089 #    $str =~ s/\cH/\\b/g; # \b means something different in a regex
3090     $str =~ s/\t/\\t/g;
3091     $str =~ s/\n/\\n/g;
3092     $str =~ s/\e/\\e/g;
3093     $str =~ s/\f/\\f/g;
3094     $str =~ s/\r/\\r/g;
3095     $str =~ s/([\cA-\cZ])/$unctrl{$1}/ge;
3096     $str =~ s/([[:^print:]])/sprintf("\\%03o", ord($1))/ge;
3097     return $str;
3098 }
3099
3100 # For regexes with the /x modifier.
3101 # Leave whitespace unmangled.
3102 sub escape_extended_re {
3103     my($str) = @_;
3104     $str =~ s/(.)/ord($1) > 255 ? sprintf("\\x{%x}", ord($1)) : $1/eg;
3105     $str =~ s/([[:^print:]])/
3106         ($1 =~ y! \t\n!!) ? $1 : sprintf("\\%03o", ord($1))/ge;
3107     $str =~ s/\n/\n\f/g;
3108     return $str;
3109 }
3110
3111 # Don't do this for regexen
3112 sub unback {
3113     my($str) = @_;
3114     $str =~ s/\\/\\\\/g;
3115     return $str;
3116 }
3117
3118 # Remove backslashes which precede literal control characters,
3119 # to avoid creating ambiguity when we escape the latter.
3120 sub re_unback {
3121     my($str) = @_;
3122
3123     # the insane complexity here is due to the behaviour of "\c\"
3124     $str =~ s/(^|[^\\]|\\c\\)(?<!\\c)\\(\\\\)*(?=[[:^print:]])/$1$2/g;
3125     return $str;
3126 }
3127
3128 sub balanced_delim {
3129     my($str) = @_;
3130     my @str = split //, $str;
3131     my($ar, $open, $close, $fail, $c, $cnt);
3132     for $ar (['[',']'], ['(',')'], ['<','>'], ['{','}']) {
3133         ($open, $close) = @$ar;
3134         $fail = 0; $cnt = 0;
3135         for $c (@str) {
3136             if ($c eq $open) {
3137                 $cnt++;
3138             } elsif ($c eq $close) {
3139                 $cnt--;
3140                 if ($cnt < 0) {
3141                     # qq()() isn't ")("
3142                     $fail = 1;
3143                     last;
3144                 }
3145             }
3146         }
3147         $fail = 1 if $cnt != 0;
3148         return ($open, "$open$str$close") if not $fail;
3149     }
3150     return ("", $str);
3151 }
3152
3153 sub single_delim {
3154     my($q, $default, $str) = @_;
3155     return "$default$str$default" if $default and index($str, $default) == -1;
3156     if ($q ne 'qr') {
3157         (my $succeed, $str) = balanced_delim($str);
3158         return "$q$str" if $succeed;
3159     }
3160     for my $delim ('/', '"', '#') {
3161         return "$q$delim" . $str . $delim if index($str, $delim) == -1;
3162     }
3163     if ($default) {
3164         $str =~ s/$default/\\$default/g;
3165         return "$default$str$default";
3166     } else {
3167         $str =~ s[/][\\/]g;
3168         return "$q/$str/";
3169     }
3170 }
3171
3172 sub const {
3173     my $sv = shift;
3174     if (class($sv) eq "SPECIAL") {
3175         return ('undef', '1', '0')[$$sv-1]; # sv_undef, sv_yes, sv_no
3176     } elsif (class($sv) eq "NULL") {
3177        return 'undef';
3178     } elsif ($sv->FLAGS & SVf_IOK) {
3179         return $sv->int_value;
3180     } elsif ($sv->FLAGS & SVf_NOK) {
3181         # try the default stringification
3182         my $r = "".$sv->NV;
3183         if ($r =~ /e/) {
3184             # If it's in scientific notation, we might have lost information
3185             return sprintf("%.20e", $sv->NV);
3186         }
3187         return $r;
3188     } elsif ($sv->FLAGS & SVf_ROK && $sv->can("RV")) {
3189         return "\\(" . const($sv->RV) . ")"; # constant folded
3190     } elsif ($sv->FLAGS & SVf_POK) {
3191         my $str = $sv->PV;
3192         if ($str =~ /[^ -~]/) { # ASCII for non-printing
3193             return single_delim("qq", '"', uninterp escape_str unback $str);
3194         } else {
3195             return single_delim("q", "'", unback $str);
3196         }
3197     } else {
3198         return "undef";
3199     }
3200 }
3201
3202 sub const_sv {
3203     my $self = shift;
3204     my $op = shift;
3205     my $sv = $op->sv;
3206     # the constant could be in the pad (under useithreads)
3207     $sv = $self->padval($op->targ) unless $$sv;
3208     return $sv;
3209 }
3210
3211 sub pp_const {
3212     my $self = shift;
3213     my($op, $cx) = @_;
3214     if ($op->private & OPpCONST_ARYBASE) {
3215         return '$[';
3216     }
3217 #    if ($op->private & OPpCONST_BARE) { # trouble with `=>' autoquoting
3218 #       return $self->const_sv($op)->PV;
3219 #    }
3220     my $sv = $self->const_sv($op);
3221 #    return const($sv);
3222     my $c = const $sv;
3223     return $c =~ /^-\d/ ? $self->maybe_parens($c, $cx, 21) : $c;
3224 }
3225
3226 sub dq {
3227     my $self = shift;
3228     my $op = shift;
3229     my $type = $op->name;
3230     if ($type eq "const") {
3231         return '$[' if $op->private & OPpCONST_ARYBASE;
3232         return uninterp(escape_str(unback($self->const_sv($op)->as_string)));
3233     } elsif ($type eq "concat") {
3234         my $first = $self->dq($op->first);
3235         my $last  = $self->dq($op->last);
3236
3237         # Disambiguate "${foo}bar", "${foo}{bar}", "${foo}[1]"
3238         ($last =~ /^[A-Z\\\^\[\]_?]/ &&
3239             $first =~ s/([\$@])\^$/${1}{^}/)  # "${^}W" etc
3240             || ($last =~ /^[{\[\w_]/ &&
3241                 $first =~ s/([\$@])([A-Za-z_]\w*)$/${1}{$2}/);
3242
3243         return $first . $last;
3244     } elsif ($type eq "uc") {
3245         return '\U' . $self->dq($op->first->sibling) . '\E';
3246     } elsif ($type eq "lc") {
3247         return '\L' . $self->dq($op->first->sibling) . '\E';
3248     } elsif ($type eq "ucfirst") {
3249         return '\u' . $self->dq($op->first->sibling);
3250     } elsif ($type eq "lcfirst") {
3251         return '\l' . $self->dq($op->first->sibling);
3252     } elsif ($type eq "quotemeta") {
3253         return '\Q' . $self->dq($op->first->sibling) . '\E';
3254     } elsif ($type eq "join") {
3255         return $self->deparse($op->last, 26); # was join($", @ary)
3256     } else {
3257         return $self->deparse($op, 26);
3258     }
3259 }
3260
3261 sub pp_backtick {
3262     my $self = shift;
3263     my($op, $cx) = @_;
3264     # skip pushmark
3265     return single_delim("qx", '`', $self->dq($op->first->sibling));
3266 }
3267
3268 sub dquote {
3269     my $self = shift;
3270     my($op, $cx) = @_;
3271     my $kid = $op->first->sibling; # skip ex-stringify, pushmark
3272     return $self->deparse($kid, $cx) if $self->{'unquote'};
3273     $self->maybe_targmy($kid, $cx,
3274                         sub {single_delim("qq", '"', $self->dq($_[1]))});
3275 }
3276
3277 # OP_STRINGIFY is a listop, but it only ever has one arg
3278 sub pp_stringify { maybe_targmy(@_, \&dquote) }
3279
3280 # tr/// and s/// (and tr[][], tr[]//, tr###, etc)
3281 # note that tr(from)/to/ is OK, but not tr/from/(to)
3282 sub double_delim {
3283     my($from, $to) = @_;
3284     my($succeed, $delim);
3285     if ($from !~ m[/] and $to !~ m[/]) {
3286         return "/$from/$to/";
3287     } elsif (($succeed, $from) = balanced_delim($from) and $succeed) {
3288         if (($succeed, $to) = balanced_delim($to) and $succeed) {
3289             return "$from$to";
3290         } else {
3291             for $delim ('/', '"', '#') { # note no `'' -- s''' is special
3292                 return "$from$delim$to$delim" if index($to, $delim) == -1;
3293             }
3294             $to =~ s[/][\\/]g;
3295             return "$from/$to/";
3296         }
3297     } else {
3298         for $delim ('/', '"', '#') { # note no '
3299             return "$delim$from$delim$to$delim"
3300                 if index($to . $from, $delim) == -1;
3301         }
3302         $from =~ s[/][\\/]g;
3303         $to =~ s[/][\\/]g;
3304         return "/$from/$to/";
3305     }
3306 }
3307
3308 # Only used by tr///, so backslashes hyphens
3309 sub pchr { # ASCII
3310     my($n) = @_;
3311     if ($n == ord '\\') {
3312         return '\\\\';
3313     } elsif ($n == ord "-") {
3314         return "\\-";
3315     } elsif ($n >= ord(' ') and $n <= ord('~')) {
3316         return chr($n);
3317     } elsif ($n == ord "\a") {
3318         return '\\a';
3319     } elsif ($n == ord "\b") {
3320         return '\\b';
3321     } elsif ($n == ord "\t") {
3322         return '\\t';
3323     } elsif ($n == ord "\n") {
3324         return '\\n';
3325     } elsif ($n == ord "\e") {
3326         return '\\e';
3327     } elsif ($n == ord "\f") {
3328         return '\\f';
3329     } elsif ($n == ord "\r") {
3330         return '\\r';
3331     } elsif ($n >= ord("\cA") and $n <= ord("\cZ")) {
3332         return '\\c' . chr(ord("@") + $n);
3333     } else {
3334 #       return '\x' . sprintf("%02x", $n);
3335         return '\\' . sprintf("%03o", $n);
3336     }
3337 }
3338
3339 sub collapse {
3340     my(@chars) = @_;
3341     my($str, $c, $tr) = ("");
3342     for ($c = 0; $c < @chars; $c++) {
3343         $tr = $chars[$c];
3344         $str .= pchr($tr);
3345         if ($c <= $#chars - 2 and $chars[$c + 1] == $tr + 1 and
3346             $chars[$c + 2] == $tr + 2)
3347         {
3348             for (; $c <= $#chars-1 and $chars[$c + 1] == $chars[$c] + 1; $c++)
3349               {}
3350             $str .= "-";
3351             $str .= pchr($chars[$c]);
3352         }
3353     }
3354     return $str;
3355 }
3356
3357 sub tr_decode_byte {
3358     my($table, $flags) = @_;
3359     my(@table) = unpack("s*", $table);
3360     splice @table, 0x100, 1;   # Number of subsequent elements
3361     my($c, $tr, @from, @to, @delfrom, $delhyphen);
3362     if ($table[ord "-"] != -1 and
3363         $table[ord("-") - 1] == -1 || $table[ord("-") + 1] == -1)
3364     {
3365         $tr = $table[ord "-"];
3366         $table[ord "-"] = -1;
3367         if ($tr >= 0) {
3368             @from = ord("-");
3369             @to = $tr;
3370         } else { # -2 ==> delete
3371             $delhyphen = 1;
3372         }
3373     }
3374     for ($c = 0; $c < @table; $c++) {
3375         $tr = $table[$c];
3376         if ($tr >= 0) {
3377             push @from, $c; push @to, $tr;
3378         } elsif ($tr == -2) {
3379             push @delfrom, $c;
3380         }
3381     }
3382     @from = (@from, @delfrom);
3383     if ($flags & OPpTRANS_COMPLEMENT) {
3384         my @newfrom = ();
3385         my %from;
3386         @from{@from} = (1) x @from;
3387         for ($c = 0; $c < 256; $c++) {
3388             push @newfrom, $c unless $from{$c};
3389         }
3390         @from = @newfrom;
3391     }
3392     unless ($flags & OPpTRANS_DELETE || !@to) {
3393         pop @to while $#to and $to[$#to] == $to[$#to -1];
3394     }
3395     my($from, $to);
3396     $from = collapse(@from);
3397     $to = collapse(@to);
3398     $from .= "-" if $delhyphen;
3399     return ($from, $to);
3400 }
3401
3402 sub tr_chr {
3403     my $x = shift;
3404     if ($x == ord "-") {
3405         return "\\-";
3406     } elsif ($x == ord "\\") {
3407         return "\\\\";
3408     } else {
3409         return chr $x;
3410     }
3411 }
3412
3413 # XXX This doesn't yet handle all cases correctly either
3414
3415 sub tr_decode_utf8 {
3416     my($swash_hv, $flags) = @_;
3417     my %swash = $swash_hv->ARRAY;
3418     my $final = undef;
3419     $final = $swash{'FINAL'}->IV if exists $swash{'FINAL'};
3420     my $none = $swash{"NONE"}->IV;
3421     my $extra = $none + 1;
3422     my(@from, @delfrom, @to);
3423     my $line;
3424     foreach $line (split /\n/, $swash{'LIST'}->PV) {
3425         my($min, $max, $result) = split(/\t/, $line);
3426         $min = hex $min;
3427         if (length $max) {
3428             $max = hex $max;
3429         } else {
3430             $max = $min;
3431         }
3432         $result = hex $result;
3433         if ($result == $extra) {
3434             push @delfrom, [$min, $max];
3435         } else {
3436             push @from, [$min, $max];
3437             push @to, [$result, $result + $max - $min];
3438         }
3439     }
3440     for my $i (0 .. $#from) {
3441         if ($from[$i][0] == ord '-') {
3442             unshift @from, splice(@from, $i, 1);
3443             unshift @to, splice(@to, $i, 1);
3444             last;
3445         } elsif ($from[$i][1] == ord '-') {
3446             $from[$i][1]--;
3447             $to[$i][1]--;
3448             unshift @from, ord '-';
3449             unshift @to, ord '-';
3450             last;
3451         }
3452     }
3453     for my $i (0 .. $#delfrom) {
3454         if ($delfrom[$i][0] == ord '-') {
3455             push @delfrom, splice(@delfrom, $i, 1);
3456             last;
3457         } elsif ($delfrom[$i][1] == ord '-') {
3458             $delfrom[$i][1]--;
3459             push @delfrom, ord '-';
3460             last;
3461         }
3462     }
3463     if (defined $final and $to[$#to][1] != $final) {
3464         push @to, [$final, $final];
3465     }
3466     push @from, @delfrom;
3467     if ($flags & OPpTRANS_COMPLEMENT) {
3468         my @newfrom;
3469         my $next = 0;
3470         for my $i (0 .. $#from) {
3471             push @newfrom, [$next, $from[$i][0] - 1];
3472             $next = $from[$i][1] + 1;
3473         }
3474         @from = ();
3475         for my $range (@newfrom) {
3476             if ($range->[0] <= $range->[1]) {
3477                 push @from, $range;
3478             }
3479         }
3480     }
3481     my($from, $to, $diff);
3482     for my $chunk (@from) {
3483         $diff = $chunk->[1] - $chunk->[0];
3484         if ($diff > 1) {
3485             $from .= tr_chr($chunk->[0]) . "-" . tr_chr($chunk->[1]);
3486         } elsif ($diff == 1) {
3487             $from .= tr_chr($chunk->[0]) . tr_chr($chunk->[1]);
3488         } else {
3489             $from .= tr_chr($chunk->[0]);
3490         }
3491     }
3492     for my $chunk (@to) {
3493         $diff = $chunk->[1] - $chunk->[0];
3494         if ($diff > 1) {
3495             $to .= tr_chr($chunk->[0]) . "-" . tr_chr($chunk->[1]);
3496         } elsif ($diff == 1) {
3497             $to .= tr_chr($chunk->[0]) . tr_chr($chunk->[1]);
3498         } else {
3499             $to .= tr_chr($chunk->[0]);
3500         }
3501     }
3502     #$final = sprintf("%04x", $final) if defined $final;
3503     #$none = sprintf("%04x", $none) if defined $none;
3504     #$extra = sprintf("%04x", $extra) if defined $extra;
3505     #print STDERR "final: $final\n none: $none\nextra: $extra\n";
3506     #print STDERR $swash{'LIST'}->PV;
3507     return (escape_str($from), escape_str($to));
3508 }
3509
3510 sub pp_trans {
3511     my $self = shift;
3512     my($op, $cx) = @_;
3513     my($from, $to);
3514     if (class($op) eq "PVOP") {
3515         ($from, $to) = tr_decode_byte($op->pv, $op->private);
3516     } else { # class($op) eq "SVOP"
3517         ($from, $to) = tr_decode_utf8($op->sv->RV, $op->private);
3518     }
3519     my $flags = "";
3520     $flags .= "c" if $op->private & OPpTRANS_COMPLEMENT;
3521     $flags .= "d" if $op->private & OPpTRANS_DELETE;
3522     $to = "" if $from eq $to and $flags eq "";
3523     $flags .= "s" if $op->private & OPpTRANS_SQUASH;
3524     return "tr" . double_delim($from, $to) . $flags;
3525 }
3526
3527 # Like dq(), but different
3528 sub re_dq {
3529     my $self = shift;
3530     my ($op, $extended) = @_;
3531
3532     my $type = $op->name;
3533     if ($type eq "const") {
3534         return '$[' if $op->private & OPpCONST_ARYBASE;
3535         my $unbacked = re_unback($self->const_sv($op)->as_string);
3536         return re_uninterp_extended(escape_extended_re($unbacked))
3537             if $extended;
3538         return re_uninterp(escape_str($unbacked));
3539     } elsif ($type eq "concat") {
3540         my $first = $self->re_dq($op->first, $extended);
3541         my $last  = $self->re_dq($op->last,  $extended);
3542
3543         # Disambiguate "${foo}bar", "${foo}{bar}", "${foo}[1]"
3544         ($last =~ /^[A-Z\\\^\[\]_?]/ &&
3545             $first =~ s/([\$@])\^$/${1}{^}/)  # "${^}W" etc
3546             || ($last =~ /^[{\[\w_]/ &&
3547                 $first =~ s/([\$@])([A-Za-z_]\w*)$/${1}{$2}/);
3548
3549         return $first . $last;
3550     } elsif ($type eq "uc") {
3551         return '\U' . $self->re_dq($op->first->sibling, $extended) . '\E';
3552     } elsif ($type eq "lc") {
3553         return '\L' . $self->re_dq($op->first->sibling, $extended) . '\E';
3554     } elsif ($type eq "ucfirst") {
3555         return '\u' . $self->re_dq($op->first->sibling, $extended);
3556     } elsif ($type eq "lcfirst") {
3557         return '\l' . $self->re_dq($op->first->sibling, $extended);
3558     } elsif ($type eq "quotemeta") {
3559         return '\Q' . $self->re_dq($op->first->sibling, $extended) . '\E';
3560     } elsif ($type eq "join") {
3561         return $self->deparse($op->last, 26); # was join($", @ary)
3562     } else {
3563         return $self->deparse($op, 26);
3564     }
3565 }
3566
3567 sub pure_string {
3568     my ($self, $op) = @_;
3569     my $type = $op->name;
3570
3571     if ($type eq 'const') {
3572         return 1;
3573     }
3574     elsif ($type =~ /^[ul]c(first)?$/ || $type eq 'quotemeta') {
3575         return $self->pure_string($op->first->sibling);
3576     }
3577     elsif ($type eq 'join') {
3578         my $join_op = $op->first->sibling;  # Skip pushmark
3579         return 0 unless $join_op->name eq 'null' && $join_op->targ eq OP_RV2SV;
3580
3581         my $gvop = $join_op->first;
3582         return 0 unless $gvop->name eq 'gvsv';
3583         return 0 unless '"' eq $self->gv_name($self->gv_or_padgv($gvop));
3584
3585         return 0 unless ${$join_op->sibling} eq ${$op->last};
3586         return 0 unless $op->last->name =~ /^(rv2|pad)av$/;
3587     }
3588     elsif ($type eq 'concat') {
3589         return $self->pure_string($op->first)
3590             && $self->pure_string($op->last);
3591     }
3592     elsif (is_scalar($op) || $type =~ /^[ah]elem(fast)?$/) {
3593         return 1;
3594     }
3595     else {
3596         return 0;
3597     }
3598
3599     return 1;
3600 }
3601
3602 sub regcomp {
3603     my $self = shift;
3604     my($op, $cx, $extended) = @_;
3605     my $kid = $op->first;
3606     $kid = $kid->first if $kid->name eq "regcmaybe";
3607     $kid = $kid->first if $kid->name eq "regcreset";
3608     return ($self->re_dq($kid, $extended), 1) if $self->pure_string($kid);
3609     return ($self->deparse($kid, $cx), 0);
3610 }
3611
3612 sub pp_regcomp {
3613     my ($self, $op, $cx) = @_;
3614     return (($self->regcomp($op, $cx, 0))[0]);
3615 }
3616
3617 # osmic acid -- see osmium tetroxide
3618
3619 my %matchwords;
3620 map($matchwords{join "", sort split //, $_} = $_, 'cig', 'cog', 'cos', 'cogs',
3621     'cox', 'go', 'is', 'ism', 'iso', 'mig', 'mix', 'osmic', 'ox', 'sic',
3622     'sig', 'six', 'smog', 'so', 'soc', 'sog', 'xi');
3623
3624 sub matchop {
3625     my $self = shift;
3626     my($op, $cx, $name, $delim) = @_;
3627     my $kid = $op->first;
3628     my ($binop, $var, $re) = ("", "", "");
3629     if ($op->flags & OPf_STACKED) {
3630         $binop = 1;
3631         $var = $self->deparse($kid, 20);
3632         $kid = $kid->sibling;
3633     }
3634     my $quote = 1;
3635     my $extended = ($op->pmflags & PMf_EXTENDED);
3636     if (null $kid) {
3637         my $unbacked = re_unback($op->precomp);
3638         if ($extended) {
3639             $re = re_uninterp_extended(escape_extended_re($unbacked));
3640         } else {
3641             $re = re_uninterp(escape_str(re_unback($op->precomp)));
3642         }
3643     } elsif ($kid->name ne 'regcomp') {
3644         carp("found ".$kid->name." where regcomp expected");
3645     } else {
3646         ($re, $quote) = $self->regcomp($kid, 1, $extended);
3647     }
3648     my $flags = "";
3649     $flags .= "c" if $op->pmflags & PMf_CONTINUE;
3650     $flags .= "g" if $op->pmflags & PMf_GLOBAL;
3651     $flags .= "i" if $op->pmflags & PMf_FOLD;
3652     $flags .= "m" if $op->pmflags & PMf_MULTILINE;
3653     $flags .= "o" if $op->pmflags & PMf_KEEP;
3654     $flags .= "s" if $op->pmflags & PMf_SINGLELINE;
3655     $flags .= "x" if $op->pmflags & PMf_EXTENDED;
3656     $flags = $matchwords{$flags} if $matchwords{$flags};
3657     if ($op->pmflags & PMf_ONCE) { # only one kind of delimiter works here
3658         $re =~ s/\?/\\?/g;
3659         $re = "?$re?";
3660     } elsif ($quote) {
3661         $re = single_delim($name, $delim, $re);
3662     }
3663     $re = $re . $flags if $quote;
3664     if ($binop) {
3665         return $self->maybe_parens("$var =~ $re", $cx, 20);
3666     } else {
3667         return $re;
3668     }
3669 }
3670
3671 sub pp_match { matchop(@_, "m", "/") }
3672 sub pp_pushre { matchop(@_, "m", "/") }
3673 sub pp_qr { matchop(@_, "qr", "") }
3674
3675 sub pp_split {
3676     my $self = shift;
3677     my($op, $cx) = @_;
3678     my($kid, @exprs, $ary, $expr);
3679     $kid = $op->first;
3680     # under ithreads pmreplroot is an integer, not an SV
3681     my $replroot = $kid->pmreplroot;
3682     if ( ( ref($replroot) && $$replroot ) ||
3683          ( !ref($replroot) && $replroot ) ) {
3684         $ary = $self->stash_variable('@', $self->gv_name($kid->pmreplroot));
3685     }
3686     for (; !null($kid); $kid = $kid->sibling) {
3687         push @exprs, $self->deparse($kid, 6);
3688     }
3689
3690     # handle special case of split(), and split(" ") that compiles to /\s+/
3691     $kid = $op->first;
3692     if ($kid->flags & OPf_SPECIAL
3693         && $exprs[0] eq '/\\s+/'
3694         && $kid->pmflags & PMf_SKIPWHITE ) {
3695             $exprs[0] = '" "';
3696     }
3697
3698     $expr = "split(" . join(", ", @exprs) . ")";
3699     if ($ary) {
3700         return $self->maybe_parens("$ary = $expr", $cx, 7);
3701     } else {
3702         return $expr;
3703     }
3704 }
3705
3706 # oxime -- any of various compounds obtained chiefly by the action of
3707 # hydroxylamine on aldehydes and ketones and characterized by the
3708 # bivalent grouping C=NOH [Webster's Tenth]
3709
3710 my %substwords;
3711 map($substwords{join "", sort split //, $_} = $_, 'ego', 'egoism', 'em',
3712     'es', 'ex', 'exes', 'gee', 'go', 'goes', 'ie', 'ism', 'iso', 'me',
3713     'meese', 'meso', 'mig', 'mix', 'os', 'ox', 'oxime', 'see', 'seem',
3714     'seg', 'sex', 'sig', 'six', 'smog', 'sog', 'some', 'xi');
3715
3716 sub pp_subst {
3717     my $self = shift;
3718     my($op, $cx) = @_;
3719     my $kid = $op->first;
3720     my($binop, $var, $re, $repl) = ("", "", "", "");
3721     if ($op->flags & OPf_STACKED) {
3722         $binop = 1;
3723         $var = $self->deparse($kid, 20);
3724         $kid = $kid->sibling;
3725     }
3726     my $flags = "";
3727     if (null($op->pmreplroot)) {
3728         $repl = $self->dq($kid);
3729         $kid = $kid->sibling;
3730     } else {
3731         $repl = $op->pmreplroot->first; # skip substcont
3732         while ($repl->name eq "entereval") {
3733             $repl = $repl->first;
3734             $flags .= "e";
3735         }
3736         if ($op->pmflags & PMf_EVAL) {
3737             $repl = $self->deparse($repl, 0);
3738         } else {
3739             $repl = $self->dq($repl);
3740         }
3741     }
3742     my $extended = ($op->pmflags & PMf_EXTENDED);
3743     if (null $kid) {
3744         my $unbacked = re_unback($op->precomp);
3745         if ($extended) {
3746             $re = re_uninterp_extended(escape_extended_re($unbacked));
3747         }
3748         else {
3749             $re = re_uninterp(escape_str($unbacked));
3750         }
3751     } else {
3752         ($re) = $self->regcomp($kid, 1, $extended);
3753     }
3754     $flags .= "e" if $op->pmflags & PMf_EVAL;
3755     $flags .= "g" if $op->pmflags & PMf_GLOBAL;
3756     $flags .= "i" if $op->pmflags & PMf_FOLD;
3757     $flags .= "m" if $op->pmflags & PMf_MULTILINE;
3758     $flags .= "o" if $op->pmflags & PMf_KEEP;
3759     $flags .= "s" if $op->pmflags & PMf_SINGLELINE;
3760     $flags .= "x" if $extended;
3761     $flags = $substwords{$flags} if $substwords{$flags};
3762     if ($binop) {
3763         return $self->maybe_parens("$var =~ s"
3764                                    . double_delim($re, $repl) . $flags,
3765                                    $cx, 20);
3766     } else {
3767         return "s". double_delim($re, $repl) . $flags;
3768     }
3769 }
3770
3771 1;
3772 __END__
3773
3774 =head1 NAME
3775
3776 B::Deparse - Perl compiler backend to produce perl code
3777
3778 =head1 SYNOPSIS
3779
3780 B<perl> B<-MO=Deparse>[B<,-u>I<PACKAGE>][B<,-p>][B<,-q>][B<,-l>]
3781         [B<,-s>I<LETTERS>][B<,-x>I<LEVEL>] I<prog.pl>
3782
3783 =head1 DESCRIPTION
3784
3785 B::Deparse is a backend module for the Perl compiler that generates
3786 perl source code, based on the internal compiled structure that perl
3787 itself creates after parsing a program. The output of B::Deparse won't
3788 be exactly the same as the original source, since perl doesn't keep
3789 track of comments or whitespace, and there isn't a one-to-one
3790 correspondence between perl's syntactical constructions and their
3791 compiled form, but it will often be close. When you use the B<-p>
3792 option, the output also includes parentheses even when they are not
3793 required by precedence, which can make it easy to see if perl is
3794 parsing your expressions the way you intended.
3795
3796 Please note that this module is mainly new and untested code and is
3797 still under development, so it may change in the future.
3798
3799 =head1 OPTIONS
3800
3801 As with all compiler backend options, these must follow directly after
3802 the '-MO=Deparse', separated by a comma but not any white space.
3803
3804 =over 4
3805
3806 =item B<-l>
3807
3808 Add '#line' declarations to the output based on the line and file
3809 locations of the original code.
3810
3811 =item B<-p>
3812
3813 Print extra parentheses. Without this option, B::Deparse includes
3814 parentheses in its output only when they are needed, based on the
3815 structure of your program. With B<-p>, it uses parentheses (almost)
3816 whenever they would be legal. This can be useful if you are used to
3817 LISP, or if you want to see how perl parses your input. If you say
3818
3819     if ($var & 0x7f == 65) {print "Gimme an A!"}
3820     print ($which ? $a : $b), "\n";
3821     $name = $ENV{USER} or "Bob";
3822
3823 C<B::Deparse,-p> will print
3824
3825     if (($var & 0)) {
3826         print('Gimme an A!')
3827     };
3828     (print(($which ? $a : $b)), '???');
3829     (($name = $ENV{'USER'}) or '???')
3830
3831 which probably isn't what you intended (the C<'???'> is a sign that
3832 perl optimized away a constant value).
3833
3834 =item B<-P>
3835
3836 Disable prototype checking. With this option, all function calls are
3837 deparsed as if no prototype was defined for them. In other words,
3838
3839     perl -MO=Deparse,-P -e 'sub foo (\@) { 1 } foo @x'
3840
3841 will print
3842
3843     sub foo (\@) {
3844         1;
3845     }
3846     &foo(\@x);
3847
3848 making clear how the parameters are actually passed to C<foo>.
3849
3850 =item B<-q>
3851
3852 Expand double-quoted strings into the corresponding combinations of
3853 concatenation, uc, ucfirst, lc, lcfirst, quotemeta, and join. For
3854 instance, print
3855
3856     print "Hello, $world, @ladies, \u$gentlemen\E, \u\L$me!";
3857
3858 as
3859
3860     print 'Hello, ' . $world . ', ' . join($", @ladies) . ', '
3861           . ucfirst($gentlemen) . ', ' . ucfirst(lc $me . '!');
3862
3863 Note that the expanded form represents the way perl handles such
3864 constructions internally -- this option actually turns off the reverse
3865 translation that B::Deparse usually does. On the other hand, note that
3866 C<$x = "$y"> is not the same as C<$x = $y>: the former makes the value
3867 of $y into a string before doing the assignment.
3868
3869 =item B<-f>I<FILE>
3870
3871 Normally, B::Deparse deparses the main code of a program, and all the subs
3872 defined in the same file. To include subs defined in other files, pass the
3873 B<-f> option with the filename. You can pass the B<-f> option several times, to
3874 include more than one secondary file.  (Most of the time you don't want to
3875 use it at all.)  You can also use this option to include subs which are
3876 defined in the scope of a B<#line> directive with two parameters.
3877
3878 =item B<-s>I<LETTERS>
3879
3880 Tweak the style of B::Deparse's output. The letters should follow
3881 directly after the 's', with no space or punctuation. The following
3882 options are available:
3883
3884 =over 4
3885
3886 =item B<C>
3887
3888 Cuddle C<elsif>, C<else>, and C<continue> blocks. For example, print
3889
3890     if (...) {
3891          ...
3892     } else {
3893          ...
3894     }
3895
3896 instead of
3897
3898     if (...) {
3899          ...
3900     }
3901     else {
3902          ...
3903     }
3904
3905 The default is not to cuddle.
3906
3907 =item B<i>I<NUMBER>
3908
3909 Indent lines by multiples of I<NUMBER> columns. The default is 4 columns.
3910
3911 =item B<T>
3912
3913 Use tabs for each 8 columns of indent. The default is to use only spaces.
3914 For instance, if the style options are B<-si4T>, a line that's indented
3915 3 times will be preceded by one tab and four spaces; if the options were
3916 B<-si8T>, the same line would be preceded by three tabs.
3917
3918 =item B<v>I<STRING>B<.>
3919
3920 Print I<STRING> for the value of a constant that can't be determined
3921 because it was optimized away (mnemonic: this happens when a constant
3922 is used in B<v>oid context). The end of the string is marked by a period.
3923 The string should be a valid perl expression, generally a constant.
3924 Note that unless it's a number, it probably needs to be quoted, and on
3925 a command line quotes need to be protected from the shell. Some
3926 conventional values include 0, 1, 42, '', 'foo', and
3927 'Useless use of constant omitted' (which may need to be
3928 B<-sv"'Useless use of constant omitted'.">
3929 or something similar depending on your shell). The default is '???'.
3930 If you're using B::Deparse on a module or other file that's require'd,
3931 you shouldn't use a value that evaluates to false, since the customary
3932 true constant at the end of a module will be in void context when the
3933 file is compiled as a main program.
3934
3935 =back
3936
3937 =item B<-x>I<LEVEL>
3938
3939 Expand conventional syntax constructions into equivalent ones that expose
3940 their internal operation. I<LEVEL> should be a digit, with higher values
3941 meaning more expansion. As with B<-q>, this actually involves turning off
3942 special cases in B::Deparse's normal operations.
3943
3944 If I<LEVEL> is at least 3, for loops will be translated into equivalent
3945 while loops with continue blocks; for instance
3946
3947     for ($i = 0; $i < 10; ++$i) {
3948         print $i;
3949     }
3950
3951 turns into
3952
3953     $i = 0;
3954     while ($i < 10) {
3955         print $i;
3956     } continue {
3957         ++$i
3958     }
3959
3960 Note that in a few cases this translation can't be perfectly carried back
3961 into the source code -- if the loop's initializer declares a my variable,
3962 for instance, it won't have the correct scope outside of the loop.
3963
3964 If I<LEVEL> is at least 7, if statements will be translated into equivalent
3965 expressions using C<&&>, C<?:> and C<do {}>; for instance
3966
3967     print 'hi' if $nice;
3968     if ($nice) {
3969         print 'hi';
3970     }
3971     if ($nice) {
3972         print 'hi';
3973     } else {
3974         print 'bye';
3975     }
3976
3977 turns into
3978
3979     $nice and print 'hi';
3980     $nice and do { print 'hi' };
3981     $nice ? do { print 'hi' } : do { print 'bye' };
3982
3983 Long sequences of elsifs will turn into nested ternary operators, which
3984 B::Deparse doesn't know how to indent nicely.
3985
3986 =back
3987
3988 =head1 USING B::Deparse AS A MODULE
3989
3990 =head2 Synopsis
3991
3992     use B::Deparse;
3993     $deparse = B::Deparse->new("-p", "-sC");
3994     $body = $deparse->coderef2text(\&func);
3995     eval "sub func $body"; # the inverse operation
3996
3997 =head2 Description
3998
3999 B::Deparse can also be used on a sub-by-sub basis from other perl
4000 programs.
4001
4002 =head2 new
4003
4004     $deparse = B::Deparse->new(OPTIONS)
4005
4006 Create an object to store the state of a deparsing operation and any
4007 options. The options are the same as those that can be given on the
4008 command line (see L</OPTIONS>); options that are separated by commas
4009 after B<-MO=Deparse> should be given as separate strings. Some
4010 options, like B<-u>, don't make sense for a single subroutine, so
4011 don't pass them.
4012
4013 =head2 ambient_pragmas
4014
4015     $deparse->ambient_pragmas(strict => 'all', '$[' => $[);
4016
4017 The compilation of a subroutine can be affected by a few compiler
4018 directives, B<pragmas>. These are:
4019
4020 =over 4
4021
4022 =item *
4023
4024 use strict;
4025
4026 =item *
4027
4028 use warnings;
4029
4030 =item *
4031
4032 Assigning to the special variable $[
4033
4034 =item *
4035
4036 use integer;
4037
4038 =item *
4039
4040 use bytes;
4041
4042 =item *
4043
4044 use utf8;
4045
4046 =item *
4047
4048 use re;
4049
4050 =back
4051
4052 Ordinarily, if you use B::Deparse on a subroutine which has
4053 been compiled in the presence of one or more of these pragmas,
4054 the output will include statements to turn on the appropriate
4055 directives. So if you then compile the code returned by coderef2text,
4056 it will behave the same way as the subroutine which you deparsed.
4057
4058 However, you may know that you intend to use the results in a
4059 particular context, where some pragmas are already in scope. In
4060 this case, you use the B<ambient_pragmas> method to describe the
4061 assumptions you wish to make.
4062
4063 Not all of the options currently have any useful effect. See
4064 L</BUGS> for more details.
4065
4066 The parameters it accepts are:
4067
4068 =over 4
4069
4070 =item strict
4071
4072 Takes a string, possibly containing several values separated
4073 by whitespace. The special values "all" and "none" mean what you'd
4074 expect.
4075
4076     $deparse->ambient_pragmas(strict => 'subs refs');
4077
4078 =item $[
4079
4080 Takes a number, the value of the array base $[.
4081
4082 =item bytes
4083
4084 =item utf8
4085
4086 =item integer
4087
4088 If the value is true, then the appropriate pragma is assumed to
4089 be in the ambient scope, otherwise not.
4090
4091 =item re
4092
4093 Takes a string, possibly containing a whitespace-separated list of
4094 values. The values "all" and "none" are special. It's also permissible
4095 to pass an array reference here.
4096
4097     $deparser->ambient_pragmas(re => 'eval');
4098
4099
4100 =item warnings
4101
4102 Takes a string, possibly containing a whitespace-separated list of
4103 values. The values "all" and "none" are special, again. It's also
4104 permissible to pass an array reference here.
4105
4106     $deparser->ambient_pragmas(warnings => [qw[void io]]);
4107
4108 If one of the values is the string "FATAL", then all the warnings
4109 in that list will be considered fatal, just as with the B<warnings>
4110 pragma itself. Should you need to specify that some warnings are
4111 fatal, and others are merely enabled, you can pass the B<warnings>
4112 parameter twice:
4113
4114     $deparser->ambient_pragmas(
4115         warnings => 'all',
4116         warnings => [FATAL => qw/void io/],
4117     );
4118
4119 See L<perllexwarn> for more information about lexical warnings.
4120
4121 =item hint_bits
4122
4123 =item warning_bits
4124
4125 These two parameters are used to specify the ambient pragmas in
4126 the format used by the special variables $^H and ${^WARNING_BITS}.
4127
4128 They exist principally so that you can write code like:
4129
4130     { my ($hint_bits, $warning_bits);
4131     BEGIN {($hint_bits, $warning_bits) = ($^H, ${^WARNING_BITS})}
4132     $deparser->ambient_pragmas (
4133         hint_bits    => $hint_bits,
4134         warning_bits => $warning_bits,
4135         '$['         => 0 + $[
4136     ); }
4137
4138 which specifies that the ambient pragmas are exactly those which
4139 are in scope at the point of calling.
4140
4141 =back
4142
4143 =head2 coderef2text
4144
4145     $body = $deparse->coderef2text(\&func)
4146     $body = $deparse->coderef2text(sub ($$) { ... })
4147
4148 Return source code for the body of a subroutine (a block, optionally
4149 preceded by a prototype in parens), given a reference to the
4150 sub. Because a subroutine can have no names, or more than one name,
4151 this method doesn't return a complete subroutine definition -- if you
4152 want to eval the result, you should prepend "sub subname ", or "sub "
4153 for an anonymous function constructor. Unless the sub was defined in
4154 the main:: package, the code will include a package declaration.
4155
4156 =head1 BUGS
4157
4158 =over 4
4159
4160 =item *
4161
4162 The only pragmas to be completely supported are: C<use warnings>,
4163 C<use strict 'refs'>, C<use bytes>, and C<use integer>. (C<$[>, which
4164 behaves like a pragma, is also supported.)
4165
4166 Excepting those listed above, we're currently unable to guarantee that
4167 B::Deparse will produce a pragma at the correct point in the program.
4168 Since the effects of pragmas are often lexically scoped, this can mean
4169 that the pragma holds sway over a different portion of the program
4170 than in the input file.
4171
4172 =item *
4173
4174 In fact, the above is a specific instance of a more general problem:
4175 we can't guarantee to produce BEGIN blocks or C<use> declarations in
4176 exactly the right place. So if you use a module which affects compilation
4177 (such as by over-riding keywords, overloading constants or whatever)
4178 then the output code might not work as intended.
4179
4180 This is the most serious outstanding problem, and will be very hard
4181 to fix.
4182
4183 =item *
4184
4185 If a keyword is over-ridden, and your program explicitly calls
4186 the built-in version by using CORE::keyword, the output of B::Deparse
4187 will not reflect this. If you run the resulting code, it will call
4188 the over-ridden version rather than the built-in one. (Maybe there
4189 should be an option to B<always> print keyword calls as C<CORE::name>.)
4190
4191 =item *
4192
4193 C<sort foo (1, 2, 3)> comes out as C<sort (foo 1, 2, 3)>, which
4194 causes perl to issue a warning.
4195
4196 The obvious fix doesn't work, because these are different:
4197
4198     print (FOO 1, 2, 3), 4, 5, 6;
4199     print FOO (1, 2, 3), 4, 5, 6;
4200
4201 =item *
4202
4203 Constants (other than simple strings or numbers) don't work properly.
4204 Pathological examples that fail (and probably always will) include:
4205
4206     use constant E2BIG => ($!=7);
4207     use constant x=>\$x; print x
4208
4209 The following could (and should) be made to work:
4210
4211     use constant regex => qr/blah/;
4212     print regex;
4213
4214 =item *
4215
4216 An input file that uses source filtering probably won't be deparsed into
4217 runnable code, because it will still include the B<use> declaration
4218 for the source filtering module, even though the code that is
4219 produced is already ordinary Perl which shouldn't be filtered again.
4220
4221 =item *
4222
4223 There are probably many more bugs on non-ASCII platforms (EBCDIC).
4224
4225 =back
4226
4227 =head1 AUTHOR
4228
4229 Stephen McCamant <smcc@CSUA.Berkeley.EDU>, based on an earlier
4230 version by Malcolm Beattie <mbeattie@sable.ox.ac.uk>, with
4231 contributions from Gisle Aas, James Duncan, Albert Dvornik, Robin
4232 Houston, Hugo van der Sanden, Gurusamy Sarathy, Nick Ing-Simmons,
4233 and Rafael Garcia-Suarez.
4234
4235 =cut