ext/B/B/Deparse.pm

   1 # B::Deparse.pm
   2 # Copyright (c) 1998-2000, 2002, 2003 Stephen McCamant. All rights reserved.
   3 # This module is free software; you can redistribute and/or modify
   4 # it under the same terms as Perl itself.
   5
   6 # This is based on the module of the same name by Malcolm Beattie,
   7 # but essentially none of his code remains.
   8
   9 package B::Deparse;
  10 use Carp;
  11 use B qw(class main_root main_start main_cv svref_2object opnumber perlstring
  12          OPf_WANT OPf_WANT_VOID OPf_WANT_SCALAR OPf_WANT_LIST
  13          OPf_KIDS OPf_REF OPf_STACKED OPf_SPECIAL OPf_MOD
  14          OPpLVAL_INTRO OPpOUR_INTRO OPpENTERSUB_AMPER OPpSLICE OPpCONST_BARE
  15          OPpTRANS_SQUASH OPpTRANS_DELETE OPpTRANS_COMPLEMENT OPpTARGET_MY
  16          OPpCONST_ARYBASE OPpEXISTS_SUB OPpSORT_NUMERIC OPpSORT_INTEGER
  17          OPpSORT_REVERSE
  18          SVf_IOK SVf_NOK SVf_ROK SVf_POK SVpad_OUR SVf_FAKE SVs_RMG SVs_SMG
  19          CVf_METHOD CVf_LOCKED CVf_LVALUE CVf_ASSERTION
  20          PMf_KEEP PMf_GLOBAL PMf_CONTINUE PMf_EVAL PMf_ONCE PMf_SKIPWHITE
  21          PMf_MULTILINE PMf_SINGLELINE PMf_FOLD PMf_EXTENDED);
  22 $VERSION = 0.65;
  23 use strict;
  24 use vars qw/$AUTOLOAD/;
  25 use warnings ();
  26
  27 # Changes between 0.50 and 0.51:
  28 # - fixed nulled leave with live enter in sort { }
  29 # - fixed reference constants (\"str")
  30 # - handle empty programs gracefully
  31 # - handle infinte loops (for (;;) {}, while (1) {})
  32 # - differentiate between `for my $x ...' and `my $x; for $x ...'
  33 # - various minor cleanups
  34 # - moved globals into an object
  35 # - added `-u', like B::C
  36 # - package declarations using cop_stash
  37 # - subs, formats and code sorted by cop_seq
  38 # Changes between 0.51 and 0.52:
  39 # - added pp_threadsv (special variables under USE_5005THREADS)
  40 # - added documentation
  41 # Changes between 0.52 and 0.53:
  42 # - many changes adding precedence contexts and associativity
  43 # - added `-p' and `-s' output style options
  44 # - various other minor fixes
  45 # Changes between 0.53 and 0.54:
  46 # - added support for new `for (1..100)' optimization,
  47 #   thanks to Gisle Aas
  48 # Changes between 0.54 and 0.55:
  49 # - added support for new qr// construct
  50 # - added support for new pp_regcreset OP
  51 # Changes between 0.55 and 0.56:
  52 # - tested on base/*.t, cmd/*.t, comp/*.t, io/*.t
  53 # - fixed $# on non-lexicals broken in last big rewrite
  54 # - added temporary fix for change in opcode of OP_STRINGIFY
  55 # - fixed problem in 0.54's for() patch in `for (@ary)'
  56 # - fixed precedence in conditional of ?:
  57 # - tweaked list paren elimination in `my($x) = @_'
  58 # - made continue-block detection trickier wrt. null ops
  59 # - fixed various prototype problems in pp_entersub
  60 # - added support for sub prototypes that never get GVs
  61 # - added unquoting for special filehandle first arg in truncate
  62 # - print doubled rv2gv (a bug) as `*{*GV}' instead of illegal `**GV'
  63 # - added semicolons at the ends of blocks
  64 # - added -l `#line' declaration option -- fixes cmd/subval.t 27,28
  65 # Changes between 0.56 and 0.561:
  66 # - fixed multiply-declared my var in pp_truncate (thanks to Sarathy)
  67 # - used new B.pm symbolic constants (done by Nick Ing-Simmons)
  68 # Changes between 0.561 and 0.57:
  69 # - stylistic changes to symbolic constant stuff
  70 # - handled scope in s///e replacement code
  71 # - added unquote option for expanding "" into concats, etc.
  72 # - split method and proto parts of pp_entersub into separate functions
  73 # - various minor cleanups
  74 # Changes after 0.57:
  75 # - added parens in \&foo (patch by Albert Dvornik)
  76 # Changes between 0.57 and 0.58:
  77 # - fixed `0' statements that weren't being printed
  78 # - added methods for use from other programs
  79 #   (based on patches from James Duncan and Hugo van der Sanden)
  80 # - added -si and -sT to control indenting (also based on a patch from Hugo)
  81 # - added -sv to print something else instead of '???'
  82 # - preliminary version of utf8 tr/// handling
  83 # Changes after 0.58:
  84 # - uses of $op->ppaddr changed to new $op->name (done by Sarathy)
  85 # - added support for Hugo's new OP_SETSTATE (like nextstate)
  86 # Changes between 0.58 and 0.59
  87 # - added support for Chip's OP_METHOD_NAMED
  88 # - added support for Ilya's OPpTARGET_MY optimization
  89 # - elided arrows before `()' subscripts when possible
  90 # Changes between 0.59 and 0.60
  91 # - support for method attribues was added
  92 # - some warnings fixed
  93 # - separate recognition of constant subs
  94 # - rewrote continue block handling, now recoginizing for loops
  95 # - added more control of expanding control structures
  96 # Changes between 0.60 and 0.61 (mostly by Robin Houston)
  97 # - many bug-fixes
  98 # - support for pragmas and 'use'
  99 # - support for the little-used $[ variable
 100 # - support for __DATA__ sections
 101 # - UTF8 support
 102 # - BEGIN, CHECK, INIT and END blocks
 103 # - scoping of subroutine declarations fixed
 104 # - compile-time output from the input program can be suppressed, so that the
 105 #   output is just the deparsed code. (a change to O.pm in fact)
 106 # - our() declarations
 107 # - *all* the known bugs are now listed in the BUGS section
 108 # - comprehensive test mechanism (TEST -deparse)
 109 # Changes between 0.62 and 0.63 (mostly by Rafael Garcia-Suarez)
 110 # - bug-fixes
 111 # - new switch -P
 112 # - support for command-line switches (-l, -0, etc.)
 113 # Changes between 0.63 and 0.64
 114 # - support for //, CHECK blocks, and assertions
 115 # - improved handling of foreach loops and lexicals
 116 # - option to use Data::Dumper for constants
 117 # - more bug fixes
 118 # - discovered lots more bugs not yet fixed
 119
 120 # Todo:
 121 #  (See also BUGS section at the end of this file)
 122 #
 123 # - finish tr/// changes
 124 # - add option for even more parens (generalize \&foo change)
 125 # - left/right context
 126 # - copy comments (look at real text with $^P?)
 127 # - avoid semis in one-statement blocks
 128 # - associativity of &&=, ||=, ?:
 129 # - ',' => '=>' (auto-unquote?)
 130 # - break long lines ("\r" as discretionary break?)
 131 # - configurable syntax highlighting: ANSI color, HTML, TeX, etc.
 132 # - more style options: brace style, hex vs. octal, quotes, ...
 133 # - print big ints as hex/octal instead of decimal (heuristic?)
 134 # - handle `my $x if 0'?
 135 # - version using op_next instead of op_first/sibling?
 136 # - avoid string copies (pass arrays, one big join?)
 137 # - here-docs?
 138
 139 # Current test.deparse failures
 140 # comp/assertions 38 - disabled assertions should be like "my($x) if 0"
 141 #    'sub f : assertion {}; no assertions; my $x=1; {f(my $x=2); print "$x\n"}'
 142 # comp/hints 6 - location of BEGIN blocks wrt. block openings
 143 # run/switchI 1 - missing -I switches entirely
 144 #    perl -Ifoo -e 'print @INC'
 145 # op/caller 2 - warning mask propagates backwards before warnings::register
 146 #    'use warnings; BEGIN {${^WARNING_BITS} eq "U"x12;} use warnings::register'
 147 # op/getpid 2 - can't assign to shared my() declaration (threads only)
 148 #    'my $x : shared = 5'
 149 # op/override 7 - parens on overriden require change v-string interpretation
 150 #    'BEGIN{*CORE::GLOBAL::require=sub {}} require v5.6'
 151 #    c.f. 'BEGIN { *f = sub {0} }; f 2'
 152 # op/pat 774 - losing Unicode-ness of Latin1-only strings
 153 #    'use charnames ":short"; $x="\N{latin:a with acute}"'
 154 # op/recurse 12 - missing parens on recursive call makes it look like method
 155 #    'sub f { f($x) }'
 156 # op/subst 90 - inconsistent handling of utf8 under "use utf8"
 157 # op/taint 29 - "use re 'taint'" deparsed in the wrong place wrt. block open
 158 # op/tiehandle compile - "use strict" deparsed in the wrong place
 159 # uni/tr_ several
 160 # ext/B/t/xref 11 - line numbers when we add newlines to one-line subs
 161 # ext/Data/Dumper/t/dumper compile
 162 # ext/DB_file/several
 163 # ext/Encode/several
 164 # ext/Ernno/Errno warnings
 165 # ext/IO/lib/IO/t/io_sel 23
 166 # ext/PerlIO/t/encoding compile
 167 # ext/POSIX/t/posix 6
 168 # ext/Socket/Socket 8
 169 # ext/Storable/t/croak compile
 170 # lib/Attribute/Handlers/t/multi compile
 171 # lib/bignum/ several
 172 # lib/charnames 35
 173 # lib/constant 32
 174 # lib/English 40
 175 # lib/ExtUtils/t/bytes 4
 176 # lib/File/DosGlob compile
 177 # lib/Filter/Simple/t/data 1
 178 # lib/Math/BigInt/t/constant 1
 179 # lib/Net/t/config Deparse-warning
 180 # lib/overload compile
 181 # lib/Switch/ several
 182 # lib/Symbol 4
 183 # lib/Test/Simple several
 184 # lib/Term/Complete
 185 # lib/Tie/File/t/29_downcopy 5
 186 # lib/vars 22
 187
 188 # Object fields (were globals):
 189 #
 190 # avoid_local:
 191 # (local($a), local($b)) and local($a, $b) have the same internal
 192 # representation but the short form looks better. We notice we can
 193 # use a large-scale local when checking the list, but need to prevent
 194 # individual locals too. This hash holds the addresses of OPs that
 195 # have already had their local-ness accounted for. The same thing
 196 # is done with my().
 197 #
 198 # curcv:
 199 # CV for current sub (or main program) being deparsed
 200 #
 201 # curcvlex:
 202 # Cached hash of lexical variables for curcv: keys are names,
 203 # each value is an array of pairs, indicating the cop_seq of scopes
 204 # in which a var of that name is valid.
 205 #
 206 # curcop:
 207 # COP for statement being deparsed
 208 #
 209 # curstash:
 210 # name of the current package for deparsed code
 211 #
 212 # subs_todo:
 213 # array of [cop_seq, CV, is_format?] for subs and formats we still
 214 # want to deparse
 215 #
 216 # protos_todo:
 217 # as above, but [name, prototype] for subs that never got a GV
 218 #
 219 # subs_done, forms_done:
 220 # keys are addresses of GVs for subs and formats we've already
 221 # deparsed (or at least put into subs_todo)
 222 #
 223 # subs_declared
 224 # keys are names of subs for which we've printed declarations.
 225 # That means we can omit parentheses from the arguments.
 226 #
 227 # subs_deparsed
 228 # Keeps track of fully qualified names of all deparsed subs.
 229 #
 230 # parens: -p
 231 # linenums: -l
 232 # unquote: -q
 233 # cuddle: ` ' or `\n', depending on -sC
 234 # indent_size: -si
 235 # use_tabs: -sT
 236 # ex_const: -sv
 237
 238 # A little explanation of how precedence contexts and associativity
 239 # work:
 240 #
 241 # deparse() calls each per-op subroutine with an argument $cx (short
 242 # for context, but not the same as the cx* in the perl core), which is
 243 # a number describing the op's parents in terms of precedence, whether
 244 # they're inside an expression or at statement level, etc.  (see
 245 # chart below). When ops with children call deparse on them, they pass
 246 # along their precedence. Fractional values are used to implement
 247 # associativity (`($x + $y) + $z' => `$x + $y + $y') and related
 248 # parentheses hacks. The major disadvantage of this scheme is that
 249 # it doesn't know about right sides and left sides, so say if you
 250 # assign a listop to a variable, it can't tell it's allowed to leave
 251 # the parens off the listop.
 252
 253 # Precedences:
 254 # 26             [TODO] inside interpolation context ("")
 255 # 25 left        terms and list operators (leftward)
 256 # 24 left        ->
 257 # 23 nonassoc    ++ --
 258 # 22 right       **
 259 # 21 right       ! ~ \ and unary + and -
 260 # 20 left        =~ !~
 261 # 19 left        * / % x
 262 # 18 left        + - .
 263 # 17 left        << >>
 264 # 16 nonassoc    named unary operators
 265 # 15 nonassoc    < > <= >= lt gt le ge
 266 # 14 nonassoc    == != <=> eq ne cmp
 267 # 13 left        &
 268 # 12 left        | ^
 269 # 11 left        &&
 270 # 10 left        ||
 271 #  9 nonassoc    ..  ...
 272 #  8 right       ?:
 273 #  7 right       = += -= *= etc.
 274 #  6 left        , =>
 275 #  5 nonassoc    list operators (rightward)
 276 #  4 right       not
 277 #  3 left        and
 278 #  2 left        or xor
 279 #  1             statement modifiers
 280 #  0.5           statements, but still print scopes as do { ... }
 281 #  0             statement level
 282
 283 # Nonprinting characters with special meaning:
 284 # \cS - steal parens (see maybe_parens_unop)
 285 # \n - newline and indent
 286 # \t - increase indent
 287 # \b - decrease indent (`outdent')
 288 # \f - flush left (no indent)
 289 # \cK - kill following semicolon, if any
 290
 291 sub null {
 292     my $op = shift;
 293     return class($op) eq "NULL";
 294 }
 295
 296 sub todo {
 297     my $self = shift;
 298     my($cv, $is_form) = @_;
 299     return unless ($cv->FILE eq $0 || exists $self->{files}{$cv->FILE});
 300     my $seq;
 301     if ($cv->OUTSIDE_SEQ) {
 302         $seq = $cv->OUTSIDE_SEQ;
 303     } elsif (!null($cv->START) and is_state($cv->START)) {
 304         $seq = $cv->START->cop_seq;
 305     } else {
 306         $seq = 0;
 307     }
 308     push @{$self->{'subs_todo'}}, [$seq, $cv, $is_form];
 309     unless ($is_form || class($cv->STASH) eq 'SPECIAL') {
 310         $self->{'subs_deparsed'}{$cv->STASH->NAME."::".$cv->GV->NAME} = 1;
 311     }
 312 }
 313
 314 sub next_todo {
 315     my $self = shift;
 316     my $ent = shift @{$self->{'subs_todo'}};
 317     my $cv = $ent->[1];
 318     my $gv = $cv->GV;
 319     my $name = $self->gv_name($gv);
 320     if ($ent->[2]) {
 321         return "format $name =\n"
 322             . $self->deparse_format($ent->[1]). "\n";
 323     } else {
 324         $self->{'subs_declared'}{$name} = 1;
 325         if ($name eq "BEGIN") {
 326             my $use_dec = $self->begin_is_use($cv);
 327             if (defined ($use_dec) and $self->{'expand'} < 5) {
 328                 return () if 0 == length($use_dec);
 329                 return $use_dec;
 330             }
 331         }
 332         my $l = '';
 333         if ($self->{'linenums'}) {
 334             my $line = $gv->LINE;
 335             my $file = $gv->FILE;
 336             $l = "\n\f#line $line \"$file\"\n";
 337         }
 338         my $p = '';
 339         if (class($cv->STASH) ne "SPECIAL") {
 340             my $stash = $cv->STASH->NAME;
 341             if ($stash ne $self->{'curstash'}) {
 342                 $p = "package $stash;\n";
 343                 $name = "$self->{'curstash'}::$name" unless $name =~ /::/;
 344                 $self->{'curstash'} = $stash;
 345             }
 346             $name =~ s/^\Q$stash\E:://;
 347         }
 348         return "${p}${l}sub $name " . $self->deparse_sub($cv);
 349     }
 350 }
 351
 352 # Return a "use" declaration for this BEGIN block, if appropriate
 353 sub begin_is_use {
 354     my ($self, $cv) = @_;
 355     my $root = $cv->ROOT;
 356     local @$self{qw'curcv curcvlex'} = ($cv);
 357 #require B::Debug;
 358 #B::walkoptree($cv->ROOT, "debug");
 359     my $lineseq = $root->first;
 360     return if $lineseq->name ne "lineseq";
 361
 362     my $req_op = $lineseq->first->sibling;
 363     return if $req_op->name ne "require";
 364
 365     my $module;
 366     if ($req_op->first->private & OPpCONST_BARE) {
 367         # Actually it should always be a bareword
 368         $module = $self->const_sv($req_op->first)->PV;
 369         $module =~ s[/][::]g;
 370         $module =~ s/.pm$//;
 371     }
 372     else {
 373         $module = $self->const($self->const_sv($req_op->first), 6);
 374     }
 375
 376     my $version;
 377     my $version_op = $req_op->sibling;
 378     return if class($version_op) eq "NULL";
 379     if ($version_op->name eq "lineseq") {
 380         # We have a version parameter; skip nextstate & pushmark
 381         my $constop = $version_op->first->next->next;
 382
 383         return unless $self->const_sv($constop)->PV eq $module;
 384         $constop = $constop->sibling;
 385         $version = $self->const_sv($constop);
 386         if (class($version) eq "IV") {
 387             $version = $version->int_value;
 388         } elsif (class($version) eq "NV") {
 389             $version = $version->NV;
 390         } elsif (class($version) ne "PVMG") {
 391             # Includes PVIV and PVNV
 392             $version = $version->PV;
 393         } else {
 394             # version specified as a v-string
 395             $version = 'v'.join '.', map ord, split //, $version->PV;
 396         }
 397         $constop = $constop->sibling;
 398         return if $constop->name ne "method_named";
 399         return if $self->const_sv($constop)->PV ne "VERSION";
 400     }
 401
 402     $lineseq = $version_op->sibling;
 403     return if $lineseq->name ne "lineseq";
 404     my $entersub = $lineseq->first->sibling;
 405     if ($entersub->name eq "stub") {
 406         return "use $module $version ();\n" if defined $version;
 407         return "use $module ();\n";
 408     }
 409     return if $entersub->name ne "entersub";
 410
 411     # See if there are import arguments
 412     my $args = '';
 413
 414     my $svop = $entersub->first->sibling; # Skip over pushmark
 415     return unless $self->const_sv($svop)->PV eq $module;
 416
 417     # Pull out the arguments
 418     for ($svop=$svop->sibling; $svop->name ne "method_named";
 419                 $svop = $svop->sibling) {
 420         $args .= ", " if length($args);
 421         $args .= $self->deparse($svop, 6);
 422     }
 423
 424     my $use = 'use';
 425     my $method_named = $svop;
 426     return if $method_named->name ne "method_named";
 427     my $method_name = $self->const_sv($method_named)->PV;
 428
 429     if ($method_name eq "unimport") {
 430         $use = 'no';
 431     }
 432
 433     # Certain pragmas are dealt with using hint bits,
 434     # so we ignore them here
 435     if ($module eq 'strict' || $module eq 'integer'
 436         || $module eq 'bytes' || $module eq 'warnings') {
 437         return "";
 438     }
 439
 440     if (defined $version && length $args) {
 441         return "$use $module $version ($args);\n";
 442     } elsif (defined $version) {
 443         return "$use $module $version;\n";
 444     } elsif (length $args) {
 445         return "$use $module ($args);\n";
 446     } else {
 447         return "$use $module;\n";
 448     }
 449 }
 450
 451 sub stash_subs {
 452     my ($self, $pack) = @_;
 453     my (@ret, $stash);
 454     if (!defined $pack) {
 455         $pack = '';
 456         $stash = \%::;
 457     }
 458     else {
 459         $pack =~ s/(::)?$/::/;
 460         no strict 'refs';
 461         $stash = \%$pack;
 462     }
 463     my %stash = svref_2object($stash)->ARRAY;
 464     while (my ($key, $val) = each %stash) {
 465         next if $key eq 'main::';       # avoid infinite recursion
 466         my $class = class($val);
 467         if ($class eq "PV") {
 468             # Just a prototype. As an ugly but fairly effective way
 469             # to find out if it belongs here is to see if the AUTOLOAD
 470             # (if any) for the stash was defined in one of our files.
 471             my $A = $stash{"AUTOLOAD"};
 472             if (defined ($A) && class($A) eq "GV" && defined($A->CV)
 473                 && class($A->CV) eq "CV") {
 474                 my $AF = $A->FILE;
 475                 next unless $AF eq $0 || exists $self->{'files'}{$AF};
 476             }
 477             push @{$self->{'protos_todo'}}, [$pack . $key, $val->PV];
 478         } elsif ($class eq "IV") {
 479             # Just a name. As above.
 480             my $A = $stash{"AUTOLOAD"};
 481             if (defined ($A) && class($A) eq "GV" && defined($A->CV)
 482                 && class($A->CV) eq "CV") {
 483                 my $AF = $A->FILE;
 484                 next unless $AF eq $0 || exists $self->{'files'}{$AF};
 485             }
 486             push @{$self->{'protos_todo'}}, [$pack . $key, undef];
 487         } elsif ($class eq "GV") {
 488             if (class(my $cv = $val->CV) ne "SPECIAL") {
 489                 next if $self->{'subs_done'}{$$val}++;
 490                 next if $$val != ${$cv->GV};   # Ignore imposters
 491                 $self->todo($cv, 0);
 492             }
 493             if (class(my $cv = $val->FORM) ne "SPECIAL") {
 494                 next if $self->{'forms_done'}{$$val}++;
 495                 next if $$val != ${$cv->GV};   # Ignore imposters
 496                 $self->todo($cv, 1);
 497             }
 498             if (class($val->HV) ne "SPECIAL" && $key =~ /::$/) {
 499                 $self->stash_subs($pack . $key);
 500             }
 501         }
 502     }
 503 }
 504
 505 sub print_protos {
 506     my $self = shift;
 507     my $ar;
 508     my @ret;
 509     foreach $ar (@{$self->{'protos_todo'}}) {
 510         my $proto = (defined $ar->[1] ? " (". $ar->[1] . ")" : "");
 511         push @ret, "sub " . $ar->[0] .  "$proto;\n";
 512     }
 513     delete $self->{'protos_todo'};
 514     return @ret;
 515 }
 516
 517 sub style_opts {
 518     my $self = shift;
 519     my $opts = shift;
 520     my $opt;
 521     while (length($opt = substr($opts, 0, 1))) {
 522         if ($opt eq "C") {
 523             $self->{'cuddle'} = " ";
 524             $opts = substr($opts, 1);
 525         } elsif ($opt eq "i") {
 526             $opts =~ s/^i(\d+)//;
 527             $self->{'indent_size'} = $1;
 528         } elsif ($opt eq "T") {
 529             $self->{'use_tabs'} = 1;
 530             $opts = substr($opts, 1);
 531         } elsif ($opt eq "v") {
 532             $opts =~ s/^v([^.]*)(.|$)//;
 533             $self->{'ex_const'} = $1;
 534         }
 535     }
 536 }
 537
 538 sub new {
 539     my $class = shift;
 540     my $self = bless {}, $class;
 541     $self->{'cuddle'} = "\n";
 542     $self->{'curcop'} = undef;
 543     $self->{'curstash'} = "main";
 544     $self->{'ex_const'} = "'???'";
 545     $self->{'expand'} = 0;
 546     $self->{'files'} = {};
 547     $self->{'indent_size'} = 4;
 548     $self->{'linenums'} = 0;
 549     $self->{'parens'} = 0;
 550     $self->{'subs_todo'} = [];
 551     $self->{'unquote'} = 0;
 552     $self->{'use_dumper'} = 0;
 553     $self->{'use_tabs'} = 0;
 554
 555     $self->{'ambient_arybase'} = 0;
 556     $self->{'ambient_warnings'} = undef; # Assume no lexical warnings
 557     $self->{'ambient_hints'} = 0;
 558     $self->init();
 559
 560     while (my $arg = shift @_) {
 561         if ($arg eq "-d") {
 562             $self->{'use_dumper'} = 1;
 563             require Data::Dumper;
 564         } elsif ($arg =~ /^-f(.*)/) {
 565             $self->{'files'}{$1} = 1;
 566         } elsif ($arg eq "-l") {
 567             $self->{'linenums'} = 1;
 568         } elsif ($arg eq "-p") {
 569             $self->{'parens'} = 1;
 570         } elsif ($arg eq "-P") {
 571             $self->{'noproto'} = 1;
 572         } elsif ($arg eq "-q") {
 573             $self->{'unquote'} = 1;
 574         } elsif (substr($arg, 0, 2) eq "-s") {
 575             $self->style_opts(substr $arg, 2);
 576         } elsif ($arg =~ /^-x(\d)$/) {
 577             $self->{'expand'} = $1;
 578         }
 579     }
 580     return $self;
 581 }
 582
 583 {
 584     # Mask out the bits that L<warnings::register> uses
 585     my $WARN_MASK;
 586     BEGIN {
 587         $WARN_MASK = $warnings::Bits{all} | $warnings::DeadBits{all};
 588     }
 589     sub WARN_MASK () {
 590         return $WARN_MASK;
 591     }
 592 }
 593
 594 # Initialise the contextual information, either from
 595 # defaults provided with the ambient_pragmas method,
 596 # or from perl's own defaults otherwise.
 597 sub init {
 598     my $self = shift;
 599
 600     $self->{'arybase'}  = $self->{'ambient_arybase'};
 601     $self->{'warnings'} = defined ($self->{'ambient_warnings'})
 602                                 ? $self->{'ambient_warnings'} & WARN_MASK
 603                                 : undef;
 604     $self->{'hints'}    = $self->{'ambient_hints'} & 0xFF;
 605
 606     # also a convenient place to clear out subs_declared
 607     delete $self->{'subs_declared'};
 608 }
 609
 610 sub compile {
 611     my(@args) = @_;
 612     return sub {
 613         my $self = B::Deparse->new(@args);
 614         # First deparse command-line args
 615         if (defined $^I) { # deparse -i
 616             print q(BEGIN { $^I = ).perlstring($^I).qq(; }\n);
 617         }
 618         if ($^W) { # deparse -w
 619             print qq(BEGIN { \$^W = $^W; }\n);
 620         }
 621         if ($/ ne "\n" or defined $O::savebackslash) { # deparse -l and -0
 622             my $fs = perlstring($/) || 'undef';
 623             my $bs = perlstring($O::savebackslash) || 'undef';
 624             print qq(BEGIN { \$/ = $fs; \$\\ = $bs; }\n);
 625         }
 626         my @BEGINs  = B::begin_av->isa("B::AV") ? B::begin_av->ARRAY : ();
 627         my @CHECKs  = B::check_av->isa("B::AV") ? B::check_av->ARRAY : ();
 628         my @INITs   = B::init_av->isa("B::AV") ? B::init_av->ARRAY : ();
 629         my @ENDs    = B::end_av->isa("B::AV") ? B::end_av->ARRAY : ();
 630         for my $block (@BEGINs, @CHECKs, @INITs, @ENDs) {
 631             $self->todo($block, 0);
 632         }
 633         $self->stash_subs();
 634         local($SIG{"__DIE__"}) =
 635           sub {
 636               if ($self->{'curcop'}) {
 637                   my $cop = $self->{'curcop'};
 638                   my($line, $file) = ($cop->line, $cop->file);
 639                   print STDERR "While deparsing $file near line $line,\n";
 640               }
 641             };
 642         $self->{'curcv'} = main_cv;
 643         $self->{'curcvlex'} = undef;
 644         print $self->print_protos;
 645         @{$self->{'subs_todo'}} =
 646           sort {$a->[0] <=> $b->[0]} @{$self->{'subs_todo'}};
 647         print $self->indent($self->deparse_root(main_root)), "\n"
 648           unless null main_root;
 649         my @text;
 650         while (scalar(@{$self->{'subs_todo'}})) {
 651             push @text, $self->next_todo;
 652         }
 653         print $self->indent(join("", @text)), "\n" if @text;
 654
 655         # Print __DATA__ section, if necessary
 656         no strict 'refs';
 657         my $laststash = defined $self->{'curcop'}
 658             ? $self->{'curcop'}->stash->NAME : $self->{'curstash'};
 659         if (defined *{$laststash."::DATA"}{IO}) {
 660             print "package $laststash;\n"
 661                 unless $laststash eq $self->{'curstash'};
 662             print "__DATA__\n";
 663             print readline(*{$laststash."::DATA"});
 664         }
 665     }
 666 }
 667
 668 sub coderef2text {
 669     my $self = shift;
 670     my $sub = shift;
 671     croak "Usage: ->coderef2text(CODEREF)" unless UNIVERSAL::isa($sub, "CODE");
 672
 673     $self->init();
 674     return $self->indent($self->deparse_sub(svref_2object($sub)));
 675 }
 676
 677 sub ambient_pragmas {
 678     my $self = shift;
 679     my ($arybase, $hint_bits, $warning_bits) = (0, 0);
 680
 681     while (@_ > 1) {
 682         my $name = shift();
 683         my $val  = shift();
 684
 685         if ($name eq 'strict') {
 686             require strict;
 687
 688             if ($val eq 'none') {
 689                 $hint_bits &= ~strict::bits(qw/refs subs vars/);
 690                 next();
 691             }
 692
 693             my @names;
 694             if ($val eq "all") {
 695                 @names = qw/refs subs vars/;
 696             }
 697             elsif (ref $val) {
 698                 @names = @$val;
 699             }
 700             else {
 701                 @names = split' ', $val;
 702             }
 703             $hint_bits |= strict::bits(@names);
 704         }
 705
 706         elsif ($name eq '$[') {
 707             $arybase = $val;
 708         }
 709
 710         elsif ($name eq 'integer'
 711             || $name eq 'bytes'
 712             || $name eq 'utf8') {
 713             require "$name.pm";
 714             if ($val) {
 715                 $hint_bits |= ${$::{"${name}::"}{"hint_bits"}};
 716             }
 717             else {
 718                 $hint_bits &= ~${$::{"${name}::"}{"hint_bits"}};
 719             }
 720         }
 721
 722         elsif ($name eq 're') {
 723             require re;
 724             if ($val eq 'none') {
 725                 $hint_bits &= ~re::bits(qw/taint eval/);
 726                 next();
 727             }
 728
 729             my @names;
 730             if ($val eq 'all') {
 731                 @names = qw/taint eval/;
 732             }
 733             elsif (ref $val) {
 734                 @names = @$val;
 735             }
 736             else {
 737                 @names = split' ',$val;
 738             }
 739             $hint_bits |= re::bits(@names);
 740         }
 741
 742         elsif ($name eq 'warnings') {
 743             if ($val eq 'none') {
 744                 $warning_bits = $warnings::NONE;
 745                 next();
 746             }
 747
 748             my @names;
 749             if (ref $val) {
 750                 @names = @$val;
 751             }
 752             else {
 753                 @names = split/\s+/, $val;
 754             }
 755
 756             $warning_bits = $warnings::NONE if !defined ($warning_bits);
 757             $warning_bits |= warnings::bits(@names);
 758         }
 759
 760         elsif ($name eq 'warning_bits') {
 761             $warning_bits = $val;
 762         }
 763
 764         elsif ($name eq 'hint_bits') {
 765             $hint_bits = $val;
 766         }
 767
 768         else {
 769             croak "Unknown pragma type: $name";
 770         }
 771     }
 772     if (@_) {
 773         croak "The ambient_pragmas method expects an even number of args";
 774     }
 775
 776     $self->{'ambient_arybase'} = $arybase;
 777     $self->{'ambient_warnings'} = $warning_bits;
 778     $self->{'ambient_hints'} = $hint_bits;
 779 }
 780
 781 # This method is the inner loop, so try to keep it simple
 782 sub deparse {
 783     my $self = shift;
 784     my($op, $cx) = @_;
 785
 786     Carp::confess("Null op in deparse") if !defined($op)
 787                                         || class($op) eq "NULL";
 788     my $meth = "pp_" . $op->name;
 789     return $self->$meth($op, $cx);
 790 }
 791
 792 sub indent {
 793     my $self = shift;
 794     my $txt = shift;
 795     my @lines = split(/\n/, $txt);
 796     my $leader = "";
 797     my $level = 0;
 798     my $line;
 799     for $line (@lines) {
 800         my $cmd = substr($line, 0, 1);
 801         if ($cmd eq "\t" or $cmd eq "\b") {
 802             $level += ($cmd eq "\t" ? 1 : -1) * $self->{'indent_size'};
 803             if ($self->{'use_tabs'}) {
 804                 $leader = "\t" x ($level / 8) . " " x ($level % 8);
 805             } else {
 806                 $leader = " " x $level;
 807             }
 808             $line = substr($line, 1);
 809         }
 810         if (substr($line, 0, 1) eq "\f") {
 811             $line = substr($line, 1); # no indent
 812         } else {
 813             $line = $leader . $line;
 814         }
 815         $line =~ s/\cK;?//g;
 816     }
 817     return join("\n", @lines);
 818 }
 819
 820 sub deparse_sub {
 821     my $self = shift;
 822     my $cv = shift;
 823     my $proto = "";
 824 Carp::confess("NULL in deparse_sub") if !defined($cv) || $cv->isa("B::NULL");
 825 Carp::confess("SPECIAL in deparse_sub") if $cv->isa("B::SPECIAL");
 826     local $self->{'curcop'} = $self->{'curcop'};
 827     if ($cv->FLAGS & SVf_POK) {
 828         $proto = "(". $cv->PV . ") ";
 829     }
 830     if ($cv->CvFLAGS & (CVf_METHOD|CVf_LOCKED|CVf_LVALUE|CVf_ASSERTION)) {
 831         $proto .= ": ";
 832         $proto .= "lvalue " if $cv->CvFLAGS & CVf_LVALUE;
 833         $proto .= "locked " if $cv->CvFLAGS & CVf_LOCKED;
 834         $proto .= "method " if $cv->CvFLAGS & CVf_METHOD;
 835         $proto .= "assertion " if $cv->CvFLAGS & CVf_ASSERTION;
 836     }
 837
 838     local($self->{'curcv'}) = $cv;
 839     local($self->{'curcvlex'});
 840     local(@$self{qw'curstash warnings hints'})
 841                 = @$self{qw'curstash warnings hints'};
 842     my $body;
 843     if (not null $cv->ROOT) {
 844         my $lineseq = $cv->ROOT->first;
 845         if ($lineseq->name eq "lineseq") {
 846             my @ops;
 847             for(my$o=$lineseq->first; $$o; $o=$o->sibling) {
 848                 push @ops, $o;
 849             }
 850             $body = $self->lineseq(undef, @ops).";";
 851             my $scope_en = $self->find_scope_en($lineseq);
 852             if (defined $scope_en) {
 853                 my $subs = join"", $self->seq_subs($scope_en);
 854                 $body .= ";\n$subs" if length($subs);
 855             }
 856         }
 857         else {
 858             $body = $self->deparse($cv->ROOT->first, 0);
 859         }
 860     }
 861     else {
 862         my $sv = $cv->const_sv;
 863         if ($$sv) {
 864             # uh-oh. inlinable sub... format it differently
 865             return $proto . "{ " . $self->const($sv, 0) . " }\n";
 866         } else { # XSUB? (or just a declaration)
 867             return "$proto;\n";
 868         }
 869     }
 870     return $proto ."{\n\t$body\n\b}" ."\n";
 871 }
 872
 873 sub deparse_format {
 874     my $self = shift;
 875     my $form = shift;
 876     my @text;
 877     local($self->{'curcv'}) = $form;
 878     local($self->{'curcvlex'});
 879     local($self->{'in_format'}) = 1;
 880     local(@$self{qw'curstash warnings hints'})
 881                 = @$self{qw'curstash warnings hints'};
 882     my $op = $form->ROOT;
 883     my $kid;
 884     return "\f." if $op->first->name eq 'stub'
 885                 || $op->first->name eq 'nextstate';
 886     $op = $op->first->first; # skip leavewrite, lineseq
 887     while (not null $op) {
 888         $op = $op->sibling; # skip nextstate
 889         my @exprs;
 890         $kid = $op->first->sibling; # skip pushmark
 891         push @text, "\f".$self->const_sv($kid)->PV;
 892         $kid = $kid->sibling;
 893         for (; not null $kid; $kid = $kid->sibling) {
 894             push @exprs, $self->deparse($kid, 0);
 895         }
 896         push @text, "\f".join(", ", @exprs)."\n" if @exprs;
 897         $op = $op->sibling;
 898     }
 899     return join("", @text) . "\f.";
 900 }
 901
 902 sub is_scope {
 903     my $op = shift;
 904     return $op->name eq "leave" || $op->name eq "scope"
 905       || $op->name eq "lineseq"
 906         || ($op->name eq "null" && class($op) eq "UNOP"
 907             && (is_scope($op->first) || $op->first->name eq "enter"));
 908 }
 909
 910 sub is_state {
 911     my $name = $_[0]->name;
 912     return $name eq "nextstate" || $name eq "dbstate" || $name eq "setstate";
 913 }
 914
 915 sub is_miniwhile { # check for one-line loop (`foo() while $y--')
 916     my $op = shift;
 917     return (!null($op) and null($op->sibling)
 918             and $op->name eq "null" and class($op) eq "UNOP"
 919             and (($op->first->name =~ /^(and|or)$/
 920                   and $op->first->first->sibling->name eq "lineseq")
 921                  or ($op->first->name eq "lineseq"
 922                      and not null $op->first->first->sibling
 923                      and $op->first->first->sibling->name eq "unstack")
 924                  ));
 925 }
 926
 927 # Check if the op and its sibling are the initialization and the rest of a
 928 # for (..;..;..) { ... } loop
 929 sub is_for_loop {
 930     my $op = shift;
 931     # This OP might be almost anything, though it won't be a
 932     # nextstate. (It's the initialization, so in the canonical case it
 933     # will be an sassign.) The sibling is a lineseq whose first child
 934     # is a nextstate and whose second is a leaveloop.
 935     my $lseq = $op->sibling;
 936     if (!is_state $op and !null($lseq) and $lseq->name eq "lineseq") {
 937         if ($lseq->first && !null($lseq->first) && is_state($lseq->first)
 938             && (my $sib = $lseq->first->sibling)) {
 939             return (!null($sib) && $sib->name eq "leaveloop");
 940         }
 941     }
 942     return 0;
 943 }
 944
 945 sub is_scalar {
 946     my $op = shift;
 947     return ($op->name eq "rv2sv" or
 948             $op->name eq "padsv" or
 949             $op->name eq "gv" or # only in array/hash constructs
 950             $op->flags & OPf_KIDS && !null($op->first)
 951               && $op->first->name eq "gvsv");
 952 }
 953
 954 sub maybe_parens {
 955     my $self = shift;
 956     my($text, $cx, $prec) = @_;
 957     if ($prec < $cx              # unary ops nest just fine
 958         or $prec == $cx and $cx != 4 and $cx != 16 and $cx != 21
 959         or $self->{'parens'})
 960     {
 961         $text = "($text)";
 962         # In a unop, let parent reuse our parens; see maybe_parens_unop
 963         $text = "\cS" . $text if $cx == 16;
 964         return $text;
 965     } else {
 966         return $text;
 967     }
 968 }
 969
 970 # same as above, but get around the `if it looks like a function' rule
 971 sub maybe_parens_unop {
 972     my $self = shift;
 973     my($name, $kid, $cx) = @_;
 974     if ($cx > 16 or $self->{'parens'}) {
 975         $kid =  $self->deparse($kid, 1);
 976         if ($name eq "umask" && $kid =~ /^\d+$/) {
 977             $kid = sprintf("%#o", $kid);
 978         }
 979         return "$name($kid)";
 980     } else {
 981         $kid = $self->deparse($kid, 16);
 982         if ($name eq "umask" && $kid =~ /^\d+$/) {
 983             $kid = sprintf("%#o", $kid);
 984         }
 985         if (substr($kid, 0, 1) eq "\cS") {
 986             # use kid's parens
 987             return $name . substr($kid, 1);
 988         } elsif (substr($kid, 0, 1) eq "(") {
 989             # avoid looks-like-a-function trap with extra parens
 990             # (`+' can lead to ambiguities)
 991             return "$name(" . $kid  . ")";
 992         } else {
 993             return "$name $kid";
 994         }
 995     }
 996 }
 997
 998 sub maybe_parens_func {
 999     my $self = shift;
1000     my($func, $text, $cx, $prec) = @_;
1001     if ($prec <= $cx or substr($text, 0, 1) eq "(" or $self->{'parens'}) {
1002         return "$func($text)";
1003     } else {
1004         return "$func $text";
1005     }
1006 }
1007
1008 sub maybe_local {
1009     my $self = shift;
1010     my($op, $cx, $text) = @_;
1011     my $our_intro = ($op->name =~ /^(gv|rv2)[ash]v$/) ? OPpOUR_INTRO : 0;
1012     if ($op->private & (OPpLVAL_INTRO|$our_intro)
1013         and not $self->{'avoid_local'}{$$op}) {
1014         my $our_local = ($op->private & OPpLVAL_INTRO) ? "local" : "our";
1015         if( $our_local eq 'our' ) {
1016             die "Unexpected our($text)\n" unless $text =~ /^\W(\w+::)*\w+\z/;
1017             $text =~ s/(\w+::)+//;
1018         }
1019         if (want_scalar($op)) {
1020             return "$our_local $text";
1021         } else {
1022             return $self->maybe_parens_func("$our_local", $text, $cx, 16);
1023         }
1024     } else {
1025         return $text;
1026     }
1027 }
1028
1029 sub maybe_targmy {
1030     my $self = shift;
1031     my($op, $cx, $func, @args) = @_;
1032     if ($op->private & OPpTARGET_MY) {
1033         my $var = $self->padname($op->targ);
1034         my $val = $func->($self, $op, 7, @args);
1035         return $self->maybe_parens("$var = $val", $cx, 7);
1036     } else {
1037         return $func->($self, $op, $cx, @args);
1038     }
1039 }
1040
1041 sub padname_sv {
1042     my $self = shift;
1043     my $targ = shift;
1044     return $self->{'curcv'}->PADLIST->ARRAYelt(0)->ARRAYelt($targ);
1045 }
1046
1047 sub maybe_my {
1048     my $self = shift;
1049     my($op, $cx, $text) = @_;
1050     if ($op->private & OPpLVAL_INTRO and not $self->{'avoid_local'}{$$op}) {
1051         if (want_scalar($op)) {
1052             return "my $text";
1053         } else {
1054             return $self->maybe_parens_func("my", $text, $cx, 16);
1055         }
1056     } else {
1057         return $text;
1058     }
1059 }
1060
1061 # The following OPs don't have functions:
1062
1063 # pp_padany -- does not exist after parsing
1064
1065 sub AUTOLOAD {
1066     if ($AUTOLOAD =~ s/^.*::pp_//) {
1067         warn "unexpected OP_".uc $AUTOLOAD;
1068         return "XXX";
1069     } else {
1070         die "Undefined subroutine $AUTOLOAD called";
1071     }
1072 }
1073
1074 sub DESTROY {}  #       Do not AUTOLOAD
1075
1076 # $root should be the op which represents the root of whatever
1077 # we're sequencing here. If it's undefined, then we don't append
1078 # any subroutine declarations to the deparsed ops, otherwise we
1079 # append appropriate declarations.
1080 sub lineseq {
1081     my($self, $root, @ops) = @_;
1082     my($expr, @exprs);
1083
1084     my $out_cop = $self->{'curcop'};
1085     my $out_seq = defined($out_cop) ? $out_cop->cop_seq : undef;
1086     my $limit_seq;
1087     if (defined $root) {
1088         $limit_seq = $out_seq;
1089         my $nseq = $self->find_scope_st($root->sibling) if ${$root->sibling};
1090         $limit_seq = $nseq if !defined($limit_seq)
1091                            or defined($nseq) && $nseq < $limit_seq;
1092     }
1093     $limit_seq = $self->{'limit_seq'}
1094         if defined($self->{'limit_seq'})
1095         && (!defined($limit_seq) || $self->{'limit_seq'} < $limit_seq);
1096     local $self->{'limit_seq'} = $limit_seq;
1097     for (my $i = 0; $i < @ops; $i++) {
1098         $expr = "";
1099         if (is_state $ops[$i]) {
1100             $expr = $self->deparse($ops[$i], 0);
1101             $i++;
1102             if ($i > $#ops) {
1103                 push @exprs, $expr;
1104                 last;
1105             }
1106         }
1107         if (!is_state $ops[$i] and (my $ls = $ops[$i+1]) and
1108             !null($ops[$i+1]) and $ops[$i+1]->name eq "lineseq")
1109         {
1110             if ($ls->first && !null($ls->first) && is_state($ls->first)
1111                 && (my $sib = $ls->first->sibling)) {
1112                 if (!null($sib) && $sib->name eq "leaveloop") {
1113                     push @exprs, $expr . $self->for_loop($ops[$i], 0);
1114                     $i++;
1115                     next;
1116                 }
1117             }
1118         }
1119         $expr .= $self->deparse($ops[$i], (@ops != 1)/2);
1120         $expr =~ s/;\n?\z//;
1121         push @exprs, $expr;
1122     }
1123     my $body = join(";\n", grep {length} @exprs);
1124     my $subs = "";
1125     if (defined $root && defined $limit_seq && !$self->{'in_format'}) {
1126         $subs = join "\n", $self->seq_subs($limit_seq);
1127     }
1128     return join(";\n", grep {length} $body, $subs);
1129 }
1130
1131 sub scopeop {
1132     my($real_block, $self, $op, $cx) = @_;
1133     my $kid;
1134     my @kids;
1135
1136     local(@$self{qw'curstash warnings hints'})
1137                 = @$self{qw'curstash warnings hints'} if $real_block;
1138     if ($real_block) {
1139         $kid = $op->first->sibling; # skip enter
1140         if (is_miniwhile($kid)) {
1141             my $top = $kid->first;
1142             my $name = $top->name;
1143             if ($name eq "and") {
1144                 $name = "while";
1145             } elsif ($name eq "or") {
1146                 $name = "until";
1147             } else { # no conditional -> while 1 or until 0
1148                 return $self->deparse($top->first, 1) . " while 1";
1149             }
1150             my $cond = $top->first;
1151             my $body = $cond->sibling->first; # skip lineseq
1152             $cond = $self->deparse($cond, 1);
1153             $body = $self->deparse($body, 1);
1154             return "$body $name $cond";
1155         }
1156     } else {
1157         $kid = $op->first;
1158     }
1159     for (; !null($kid); $kid = $kid->sibling) {
1160         push @kids, $kid;
1161     }
1162     if ($cx > 0) { # inside an expression, (a do {} while for lineseq)
1163         return "do {\n\t" . $self->lineseq($op, @kids) . "\n\b}";
1164     } else {
1165         my $lineseq = $self->lineseq($op, @kids);
1166         return (length ($lineseq) ? "$lineseq;" : "");
1167     }
1168 }
1169
1170 sub pp_scope { scopeop(0, @_); }
1171 sub pp_lineseq { scopeop(0, @_); }
1172 sub pp_leave { scopeop(1, @_); }
1173
1174 # This is a special case of scopeop and lineseq, for the case of the
1175 # main_root. The difference is that we print the output statements as
1176 # soon as we get them, for the sake of impatient users.
1177 sub deparse_root {
1178     my $self = shift;
1179     my($op) = @_;
1180     local(@$self{qw'curstash warnings hints'})
1181       = @$self{qw'curstash warnings hints'};
1182     my @kids;
1183     for (my $kid = $op->first->sibling; !null($kid); $kid = $kid->sibling) {
1184         push @kids, $kid;
1185     }
1186     for (my $i = 0; $i < @kids; $i++) {
1187         my $expr = "";
1188         if (is_state $kids[$i]) {
1189             $expr = $self->deparse($kids[$i], 0);
1190             $i++;
1191             if ($i > $#kids) {
1192                 print $self->indent($expr);
1193                 last;
1194             }
1195         }
1196         if (is_for_loop($kids[$i])) {
1197             $expr .= $self->for_loop($kids[$i], 0);
1198             $expr .= ";\n" unless $i == $#kids;
1199             print $self->indent($expr);
1200             $i++;
1201             next;
1202         }
1203         $expr .= $self->deparse($kids[$i], (@kids != 1)/2);
1204         $expr =~ s/;\n?\z//;
1205         $expr .= ";";
1206         print $self->indent($expr);
1207         print "\n" unless $i == $#kids;
1208     }
1209 }
1210
1211 # The BEGIN {} is used here because otherwise this code isn't executed
1212 # when you run B::Deparse on itself.
1213 my %globalnames;
1214 BEGIN { map($globalnames{$_}++, "SIG", "STDIN", "STDOUT", "STDERR", "INC",
1215             "ENV", "ARGV", "ARGVOUT", "_"); }
1216
1217 sub gv_name {
1218     my $self = shift;
1219     my $gv = shift;
1220 Carp::confess() unless ref($gv) eq "B::GV";
1221     my $stash = $gv->STASH->NAME;
1222     my $name = $gv->SAFENAME;
1223     if (($stash eq 'main' && $globalnames{$name})
1224         or ($stash eq $self->{'curstash'} && !$globalnames{$name})
1225         or $name =~ /^[^A-Za-z_]/)
1226     {
1227         $stash = "";
1228     } else {
1229         $stash = $stash . "::";
1230     }
1231     if ($name =~ /^(\^..|{)/) {
1232         $name = "{$name}";       # ${^WARNING_BITS}, etc and ${
1233     }
1234     return $stash . $name;
1235 }
1236
1237 # Return the name to use for a stash variable.
1238 # If a lexical with the same name is in scope, it may need to be
1239 # fully-qualified.
1240 sub stash_variable {
1241     my ($self, $prefix, $name) = @_;
1242
1243     return "$prefix$name" if $name =~ /::/;
1244
1245     unless ($prefix eq '$' || $prefix eq '@' || #'
1246             $prefix eq '%' || $prefix eq '$#') {
1247         return "$prefix$name";
1248     }
1249
1250     my $v = ($prefix eq '$#' ? '@' : $prefix) . $name;
1251     return $prefix .$self->{'curstash'}.'::'. $name if $self->lex_in_scope($v);
1252     return "$prefix$name";
1253 }
1254
1255 sub lex_in_scope {
1256     my ($self, $name) = @_;
1257     $self->populate_curcvlex() if !defined $self->{'curcvlex'};
1258
1259     return 0 if !defined($self->{'curcop'});
1260     my $seq = $self->{'curcop'}->cop_seq;
1261     return 0 if !exists $self->{'curcvlex'}{$name};
1262     for my $a (@{$self->{'curcvlex'}{$name}}) {
1263         my ($st, $en) = @$a;
1264         return 1 if $seq > $st && $seq <= $en;
1265     }
1266     return 0;
1267 }
1268
1269 sub populate_curcvlex {
1270     my $self = shift;
1271     for (my $cv = $self->{'curcv'}; class($cv) eq "CV"; $cv = $cv->OUTSIDE) {
1272         my $padlist = $cv->PADLIST;
1273         # an undef CV still in lexical chain
1274         next if class($padlist) eq "SPECIAL";
1275         my @padlist = $padlist->ARRAY;
1276         my @ns = $padlist[0]->ARRAY;
1277
1278         for (my $i=0; $i<@ns; ++$i) {
1279             next if class($ns[$i]) eq "SPECIAL";
1280             next if $ns[$i]->FLAGS & SVpad_OUR;  # Skip "our" vars
1281             if (class($ns[$i]) eq "PV") {
1282                 # Probably that pesky lexical @_
1283                 next;
1284             }
1285             my $name = $ns[$i]->PVX;
1286             my ($seq_st, $seq_en) =
1287                 ($ns[$i]->FLAGS & SVf_FAKE)
1288                     ? (0, 999999)
1289                     : ($ns[$i]->NVX, $ns[$i]->IVX);
1290
1291             push @{$self->{'curcvlex'}{$name}}, [$seq_st, $seq_en];
1292         }
1293     }
1294 }
1295
1296 sub find_scope_st { ((find_scope(@_))[0]); }
1297 sub find_scope_en { ((find_scope(@_))[1]); }
1298
1299 # Recurses down the tree, looking for pad variable introductions and COPs
1300 sub find_scope {
1301     my ($self, $op, $scope_st, $scope_en) = @_;
1302     carp("Undefined op in find_scope") if !defined $op;
1303     return ($scope_st, $scope_en) unless $op->flags & OPf_KIDS;
1304
1305     for (my $o=$op->first; $$o; $o=$o->sibling) {
1306         if ($o->name =~ /^pad.v$/ && $o->private & OPpLVAL_INTRO) {
1307             my $s = int($self->padname_sv($o->targ)->NVX);
1308             my $e = $self->padname_sv($o->targ)->IVX;
1309             $scope_st = $s if !defined($scope_st) || $s < $scope_st;
1310             $scope_en = $e if !defined($scope_en) || $e > $scope_en;
1311         }
1312         elsif (is_state($o)) {
1313             my $c = $o->cop_seq;
1314             $scope_st = $c if !defined($scope_st) || $c < $scope_st;
1315             $scope_en = $c if !defined($scope_en) || $c > $scope_en;
1316         }
1317         elsif ($o->flags & OPf_KIDS) {
1318             ($scope_st, $scope_en) =
1319                 $self->find_scope($o, $scope_st, $scope_en)
1320         }
1321     }
1322
1323     return ($scope_st, $scope_en);
1324 }
1325
1326 # Returns a list of subs which should be inserted before the COP
1327 sub cop_subs {
1328     my ($self, $op, $out_seq) = @_;
1329     my $seq = $op->cop_seq;
1330     # If we have nephews, then our sequence number indicates
1331     # the cop_seq of the end of some sort of scope.
1332     if (class($op->sibling) ne "NULL" && $op->sibling->flags & OPf_KIDS
1333         and my $nseq = $self->find_scope_st($op->sibling) ) {
1334         $seq = $nseq;
1335     }
1336     $seq = $out_seq if defined($out_seq) && $out_seq < $seq;
1337     return $self->seq_subs($seq);
1338 }
1339
1340 sub seq_subs {
1341     my ($self, $seq) = @_;
1342     my @text;
1343 #push @text, "# ($seq)\n";
1344
1345     return "" if !defined $seq;
1346     while (scalar(@{$self->{'subs_todo'}})
1347            and $seq > $self->{'subs_todo'}[0][0]) {
1348         push @text, $self->next_todo;
1349     }
1350     return @text;
1351 }
1352
1353 # Notice how subs and formats are inserted between statements here;
1354 # also $[ assignments and pragmas.
1355 sub pp_nextstate {
1356     my $self = shift;
1357     my($op, $cx) = @_;
1358     $self->{'curcop'} = $op;
1359     my @text;
1360     push @text, $self->cop_subs($op);
1361     push @text, $op->label . ": " if $op->label;
1362     my $stash = $op->stashpv;
1363     if ($stash ne $self->{'curstash'}) {
1364         push @text, "package $stash;\n";
1365         $self->{'curstash'} = $stash;
1366     }
1367
1368     if ($self->{'arybase'} != $op->arybase) {
1369         push @text, '$[ = '. $op->arybase .";\n";
1370         $self->{'arybase'} = $op->arybase;
1371     }
1372
1373     my $warnings = $op->warnings;
1374     my $warning_bits;
1375     if ($warnings->isa("B::SPECIAL") && $$warnings == 4) {
1376         $warning_bits = $warnings::Bits{"all"} & WARN_MASK;
1377     }
1378     elsif ($warnings->isa("B::SPECIAL") && $$warnings == 5) {
1379         $warning_bits = $warnings::NONE;
1380     }
1381     elsif ($warnings->isa("B::SPECIAL")) {
1382         $warning_bits = undef;
1383     }
1384     else {
1385         $warning_bits = $warnings->PV & WARN_MASK;
1386     }
1387
1388     if (defined ($warning_bits) and
1389        !defined($self->{warnings}) || $self->{'warnings'} ne $warning_bits) {
1390         push @text, declare_warnings($self->{'warnings'}, $warning_bits);
1391         $self->{'warnings'} = $warning_bits;
1392     }
1393
1394     if ($self->{'hints'} != $op->private) {
1395         push @text, declare_hints($self->{'hints'}, $op->private);
1396         $self->{'hints'} = $op->private;
1397     }
1398
1399     # This should go after of any branches that add statements, to
1400     # increase the chances that it refers to the same line it did in
1401     # the original program.
1402     if ($self->{'linenums'}) {
1403         push @text, "\f#line " . $op->line .
1404           ' "' . $op->file, qq'"\n';
1405     }
1406
1407     return join("", @text);
1408 }
1409
1410 sub declare_warnings {
1411     my ($from, $to) = @_;
1412     if (($to & WARN_MASK) eq warnings::bits("all")) {
1413         return "use warnings;\n";
1414     }
1415     elsif (($to & WARN_MASK) eq "\0"x length($to)) {
1416         return "no warnings;\n";
1417     }
1418     return "BEGIN {\${^WARNING_BITS} = ".perlstring($to)."}\n";
1419 }
1420
1421 sub declare_hints {
1422     my ($from, $to) = @_;
1423     my $use = $to   & ~$from;
1424     my $no  = $from & ~$to;
1425     my $decls = "";
1426     for my $pragma (hint_pragmas($use)) {
1427         $decls .= "use $pragma;\n";
1428     }
1429     for my $pragma (hint_pragmas($no)) {
1430         $decls .= "no $pragma;\n";
1431     }
1432     return $decls;
1433 }
1434
1435 sub hint_pragmas {
1436     my ($bits) = @_;
1437     my @pragmas;
1438     push @pragmas, "integer" if $bits & 0x1;
1439     push @pragmas, "strict 'refs'" if $bits & 0x2;
1440     push @pragmas, "bytes" if $bits & 0x8;
1441     return @pragmas;
1442 }
1443
1444 sub pp_dbstate { pp_nextstate(@_) }
1445 sub pp_setstate { pp_nextstate(@_) }
1446
1447 sub pp_unstack { return "" } # see also leaveloop
1448
1449 sub baseop {
1450     my $self = shift;
1451     my($op, $cx, $name) = @_;
1452     return $name;
1453 }
1454
1455 sub pp_stub {
1456     my $self = shift;
1457     my($op, $cx, $name) = @_;
1458     if ($cx >= 1) {
1459         return "()";
1460     }
1461     else {
1462         return "();";
1463     }
1464 }
1465 sub pp_wantarray { baseop(@_, "wantarray") }
1466 sub pp_fork { baseop(@_, "fork") }
1467 sub pp_wait { maybe_targmy(@_, \&baseop, "wait") }
1468 sub pp_getppid { maybe_targmy(@_, \&baseop, "getppid") }
1469 sub pp_time { maybe_targmy(@_, \&baseop, "time") }
1470 sub pp_tms { baseop(@_, "times") }
1471 sub pp_ghostent { baseop(@_, "gethostent") }
1472 sub pp_gnetent { baseop(@_, "getnetent") }
1473 sub pp_gprotoent { baseop(@_, "getprotoent") }
1474 sub pp_gservent { baseop(@_, "getservent") }
1475 sub pp_ehostent { baseop(@_, "endhostent") }
1476 sub pp_enetent { baseop(@_, "endnetent") }
1477 sub pp_eprotoent { baseop(@_, "endprotoent") }
1478 sub pp_eservent { baseop(@_, "endservent") }
1479 sub pp_gpwent { baseop(@_, "getpwent") }
1480 sub pp_spwent { baseop(@_, "setpwent") }
1481 sub pp_epwent { baseop(@_, "endpwent") }
1482 sub pp_ggrent { baseop(@_, "getgrent") }
1483 sub pp_sgrent { baseop(@_, "setgrent") }
1484 sub pp_egrent { baseop(@_, "endgrent") }
1485 sub pp_getlogin { baseop(@_, "getlogin") }
1486
1487 sub POSTFIX () { 1 }
1488
1489 # I couldn't think of a good short name, but this is the category of
1490 # symbolic unary operators with interesting precedence
1491
1492 sub pfixop {
1493     my $self = shift;
1494     my($op, $cx, $name, $prec, $flags) = (@_, 0);
1495     my $kid = $op->first;
1496     $kid = $self->deparse($kid, $prec);
1497     return $self->maybe_parens(($flags & POSTFIX) ? "$kid$name" : "$name$kid",
1498                                $cx, $prec);
1499 }
1500
1501 sub pp_preinc { pfixop(@_, "++", 23) }
1502 sub pp_predec { pfixop(@_, "--", 23) }
1503 sub pp_postinc { maybe_targmy(@_, \&pfixop, "++", 23, POSTFIX) }
1504 sub pp_postdec { maybe_targmy(@_, \&pfixop, "--", 23, POSTFIX) }
1505 sub pp_i_preinc { pfixop(@_, "++", 23) }
1506 sub pp_i_predec { pfixop(@_, "--", 23) }
1507 sub pp_i_postinc { maybe_targmy(@_, \&pfixop, "++", 23, POSTFIX) }
1508 sub pp_i_postdec { maybe_targmy(@_, \&pfixop, "--", 23, POSTFIX) }
1509 sub pp_complement { maybe_targmy(@_, \&pfixop, "~", 21) }
1510
1511 sub pp_negate { maybe_targmy(@_, \&real_negate) }
1512 sub real_negate {
1513     my $self = shift;
1514     my($op, $cx) = @_;
1515     if ($op->first->name =~ /^(i_)?negate$/) {
1516         # avoid --$x
1517         $self->pfixop($op, $cx, "-", 21.5);
1518     } else {
1519         $self->pfixop($op, $cx, "-", 21);
1520     }
1521 }
1522 sub pp_i_negate { pp_negate(@_) }
1523
1524 sub pp_not {
1525     my $self = shift;
1526     my($op, $cx) = @_;
1527     if ($cx <= 4) {
1528         $self->pfixop($op, $cx, "not ", 4);
1529     } else {
1530         $self->pfixop($op, $cx, "!", 21);
1531     }
1532 }
1533
1534 sub unop {
1535     my $self = shift;
1536     my($op, $cx, $name) = @_;
1537     my $kid;
1538     if ($op->flags & OPf_KIDS) {
1539         $kid = $op->first;
1540         if (defined prototype("CORE::$name")
1541            && prototype("CORE::$name") =~ /^;?\*/
1542            && $kid->name eq "rv2gv") {
1543             $kid = $kid->first;
1544         }
1545
1546         return $self->maybe_parens_unop($name, $kid, $cx);
1547     } else {
1548         return $name .  ($op->flags & OPf_SPECIAL ? "()" : "");
1549     }
1550 }
1551
1552 sub pp_chop { maybe_targmy(@_, \&unop, "chop") }
1553 sub pp_chomp { maybe_targmy(@_, \&unop, "chomp") }
1554 sub pp_schop { maybe_targmy(@_, \&unop, "chop") }
1555 sub pp_schomp { maybe_targmy(@_, \&unop, "chomp") }
1556 sub pp_defined { unop(@_, "defined") }
1557 sub pp_undef { unop(@_, "undef") }
1558 sub pp_study { unop(@_, "study") }
1559 sub pp_ref { unop(@_, "ref") }
1560 sub pp_pos { maybe_local(@_, unop(@_, "pos")) }
1561
1562 sub pp_sin { maybe_targmy(@_, \&unop, "sin") }
1563 sub pp_cos { maybe_targmy(@_, \&unop, "cos") }
1564 sub pp_rand { maybe_targmy(@_, \&unop, "rand") }
1565 sub pp_srand { unop(@_, "srand") }
1566 sub pp_exp { maybe_targmy(@_, \&unop, "exp") }
1567 sub pp_log { maybe_targmy(@_, \&unop, "log") }
1568 sub pp_sqrt { maybe_targmy(@_, \&unop, "sqrt") }
1569 sub pp_int { maybe_targmy(@_, \&unop, "int") }
1570 sub pp_hex { maybe_targmy(@_, \&unop, "hex") }
1571 sub pp_oct { maybe_targmy(@_, \&unop, "oct") }
1572 sub pp_abs { maybe_targmy(@_, \&unop, "abs") }
1573
1574 sub pp_length { maybe_targmy(@_, \&unop, "length") }
1575 sub pp_ord { maybe_targmy(@_, \&unop, "ord") }
1576 sub pp_chr { maybe_targmy(@_, \&unop, "chr") }
1577
1578 sub pp_each { unop(@_, "each") }
1579 sub pp_values { unop(@_, "values") }
1580 sub pp_keys { unop(@_, "keys") }
1581 sub pp_pop { unop(@_, "pop") }
1582 sub pp_shift { unop(@_, "shift") }
1583
1584 sub pp_caller { unop(@_, "caller") }
1585 sub pp_reset { unop(@_, "reset") }
1586 sub pp_exit { unop(@_, "exit") }
1587 sub pp_prototype { unop(@_, "prototype") }
1588
1589 sub pp_close { unop(@_, "close") }
1590 sub pp_fileno { unop(@_, "fileno") }
1591 sub pp_umask { unop(@_, "umask") }
1592 sub pp_untie { unop(@_, "untie") }
1593 sub pp_tied { unop(@_, "tied") }
1594 sub pp_dbmclose { unop(@_, "dbmclose") }
1595 sub pp_getc { unop(@_, "getc") }
1596 sub pp_eof { unop(@_, "eof") }
1597 sub pp_tell { unop(@_, "tell") }
1598 sub pp_getsockname { unop(@_, "getsockname") }
1599 sub pp_getpeername { unop(@_, "getpeername") }
1600
1601 sub pp_chdir { maybe_targmy(@_, \&unop, "chdir") }
1602 sub pp_chroot { maybe_targmy(@_, \&unop, "chroot") }
1603 sub pp_readlink { unop(@_, "readlink") }
1604 sub pp_rmdir { maybe_targmy(@_, \&unop, "rmdir") }
1605 sub pp_readdir { unop(@_, "readdir") }
1606 sub pp_telldir { unop(@_, "telldir") }
1607 sub pp_rewinddir { unop(@_, "rewinddir") }
1608 sub pp_closedir { unop(@_, "closedir") }
1609 sub pp_getpgrp { maybe_targmy(@_, \&unop, "getpgrp") }
1610 sub pp_localtime { unop(@_, "localtime") }
1611 sub pp_gmtime { unop(@_, "gmtime") }
1612 sub pp_alarm { unop(@_, "alarm") }
1613 sub pp_sleep { maybe_targmy(@_, \&unop, "sleep") }
1614
1615 sub pp_dofile { unop(@_, "do") }
1616 sub pp_entereval { unop(@_, "eval") }
1617
1618 sub pp_ghbyname { unop(@_, "gethostbyname") }
1619 sub pp_gnbyname { unop(@_, "getnetbyname") }
1620 sub pp_gpbyname { unop(@_, "getprotobyname") }
1621 sub pp_shostent { unop(@_, "sethostent") }
1622 sub pp_snetent { unop(@_, "setnetent") }
1623 sub pp_sprotoent { unop(@_, "setprotoent") }
1624 sub pp_sservent { unop(@_, "setservent") }
1625 sub pp_gpwnam { unop(@_, "getpwnam") }
1626 sub pp_gpwuid { unop(@_, "getpwuid") }
1627 sub pp_ggrnam { unop(@_, "getgrnam") }
1628 sub pp_ggrgid { unop(@_, "getgrgid") }
1629
1630 sub pp_lock { unop(@_, "lock") }
1631
1632 sub pp_exists {
1633     my $self = shift;
1634     my($op, $cx) = @_;
1635     my $arg;
1636     if ($op->private & OPpEXISTS_SUB) {
1637         # Checking for the existence of a subroutine
1638         return $self->maybe_parens_func("exists",
1639                                 $self->pp_rv2cv($op->first, 16), $cx, 16);
1640     }
1641     if ($op->flags & OPf_SPECIAL) {
1642         # Array element, not hash element
1643         return $self->maybe_parens_func("exists",
1644                                 $self->pp_aelem($op->first, 16), $cx, 16);
1645     }
1646     return $self->maybe_parens_func("exists", $self->pp_helem($op->first, 16),
1647                                     $cx, 16);
1648 }
1649
1650 sub pp_delete {
1651     my $self = shift;
1652     my($op, $cx) = @_;
1653     my $arg;
1654     if ($op->private & OPpSLICE) {
1655         if ($op->flags & OPf_SPECIAL) {
1656             # Deleting from an array, not a hash
1657             return $self->maybe_parens_func("delete",
1658                                         $self->pp_aslice($op->first, 16),
1659                                         $cx, 16);
1660         }
1661         return $self->maybe_parens_func("delete",
1662                                         $self->pp_hslice($op->first, 16),
1663                                         $cx, 16);
1664     } else {
1665         if ($op->flags & OPf_SPECIAL) {
1666             # Deleting from an array, not a hash
1667             return $self->maybe_parens_func("delete",
1668                                         $self->pp_aelem($op->first, 16),
1669                                         $cx, 16);
1670         }
1671         return $self->maybe_parens_func("delete",
1672                                         $self->pp_helem($op->first, 16),
1673                                         $cx, 16);
1674     }
1675 }
1676
1677 sub pp_require {
1678     my $self = shift;
1679     my($op, $cx) = @_;
1680     if (class($op) eq "UNOP" and $op->first->name eq "const"
1681         and $op->first->private & OPpCONST_BARE)
1682     {
1683         my $name = $self->const_sv($op->first)->PV;
1684         $name =~ s[/][::]g;
1685         $name =~ s/\.pm//g;
1686         return "require $name";
1687     } else {
1688         $self->unop($op, $cx, "require");
1689     }
1690 }
1691
1692 sub pp_scalar {
1693     my $self = shift;
1694     my($op, $cv) = @_;
1695     my $kid = $op->first;
1696     if (not null $kid->sibling) {
1697         # XXX Was a here-doc
1698         return $self->dquote($op);
1699     }
1700     $self->unop(@_, "scalar");
1701 }
1702
1703
1704 sub padval {
1705     my $self = shift;
1706     my $targ = shift;
1707     return $self->{'curcv'}->PADLIST->ARRAYelt(1)->ARRAYelt($targ);
1708 }
1709
1710 sub pp_refgen {
1711     my $self = shift;
1712     my($op, $cx) = @_;
1713     my $kid = $op->first;
1714     if ($kid->name eq "null") {
1715         $kid = $kid->first;
1716         if ($kid->name eq "anonlist" || $kid->name eq "anonhash") {
1717             my($pre, $post) = @{{"anonlist" => ["[","]"],
1718                                  "anonhash" => ["{","}"]}->{$kid->name}};
1719             my($expr, @exprs);
1720             $kid = $kid->first->sibling; # skip pushmark
1721             for (; !null($kid); $kid = $kid->sibling) {
1722                 $expr = $self->deparse($kid, 6);
1723                 push @exprs, $expr;
1724             }
1725             return $pre . join(", ", @exprs) . $post;
1726         } elsif (!null($kid->sibling) and
1727                  $kid->sibling->name eq "anoncode") {
1728             return "sub " .
1729                 $self->deparse_sub($self->padval($kid->sibling->targ));
1730         } elsif ($kid->name eq "pushmark") {
1731             my $sib_name = $kid->sibling->name;
1732             if ($sib_name =~ /^(pad|rv2)[ah]v$/
1733                 and not $kid->sibling->flags & OPf_REF)
1734             {
1735                 # The @a in \(@a) isn't in ref context, but only when the
1736                 # parens are there.
1737                 return "\\(" . $self->pp_list($op->first) . ")";
1738             } elsif ($sib_name eq 'entersub') {
1739                 my $text = $self->deparse($kid->sibling, 1);
1740                 # Always show parens for \(&func()), but only with -p otherwise
1741                 $text = "($text)" if $self->{'parens'}
1742                                  or $kid->sibling->private & OPpENTERSUB_AMPER;
1743                 return "\\$text";
1744             }
1745         }
1746     }
1747     $self->pfixop($op, $cx, "\\", 20);
1748 }
1749
1750 sub pp_srefgen { pp_refgen(@_) }
1751
1752 sub pp_readline {
1753     my $self = shift;
1754     my($op, $cx) = @_;
1755     my $kid = $op->first;
1756     $kid = $kid->first if $kid->name eq "rv2gv"; # <$fh>
1757     return "<" . $self->deparse($kid, 1) . ">" if is_scalar($kid);
1758     return $self->unop($op, $cx, "readline");
1759 }
1760
1761 sub pp_rcatline {
1762     my $self = shift;
1763     my($op) = @_;
1764     return "<" . $self->gv_name($self->gv_or_padgv($op)) . ">";
1765 }
1766
1767 # Unary operators that can occur as pseudo-listops inside double quotes
1768 sub dq_unop {
1769     my $self = shift;
1770     my($op, $cx, $name, $prec, $flags) = (@_, 0, 0);
1771     my $kid;
1772     if ($op->flags & OPf_KIDS) {
1773        $kid = $op->first;
1774        # If there's more than one kid, the first is an ex-pushmark.
1775        $kid = $kid->sibling if not null $kid->sibling;
1776        return $self->maybe_parens_unop($name, $kid, $cx);
1777     } else {
1778        return $name .  ($op->flags & OPf_SPECIAL ? "()" : "");
1779     }
1780 }
1781
1782 sub pp_ucfirst { dq_unop(@_, "ucfirst") }
1783 sub pp_lcfirst { dq_unop(@_, "lcfirst") }
1784 sub pp_uc { dq_unop(@_, "uc") }
1785 sub pp_lc { dq_unop(@_, "lc") }
1786 sub pp_quotemeta { maybe_targmy(@_, \&dq_unop, "quotemeta") }
1787
1788 sub loopex {
1789     my $self = shift;
1790     my ($op, $cx, $name) = @_;
1791     if (class($op) eq "PVOP") {
1792         return "$name " . $op->pv;
1793     } elsif (class($op) eq "OP") {
1794         return $name;
1795     } elsif (class($op) eq "UNOP") {
1796         # Note -- loop exits are actually exempt from the
1797         # looks-like-a-func rule, but a few extra parens won't hurt
1798         return $self->maybe_parens_unop($name, $op->first, $cx);
1799     }
1800 }
1801
1802 sub pp_last { loopex(@_, "last") }
1803 sub pp_next { loopex(@_, "next") }
1804 sub pp_redo { loopex(@_, "redo") }
1805 sub pp_goto { loopex(@_, "goto") }
1806 sub pp_dump { loopex(@_, "dump") }
1807
1808 sub ftst {
1809     my $self = shift;
1810     my($op, $cx, $name) = @_;
1811     if (class($op) eq "UNOP") {
1812         # Genuine `-X' filetests are exempt from the LLAFR, but not
1813         # l?stat(); for the sake of clarity, give'em all parens
1814         return $self->maybe_parens_unop($name, $op->first, $cx);
1815     } elsif (class($op) =~ /^(SV|PAD)OP$/) {
1816         return $self->maybe_parens_func($name, $self->pp_gv($op, 1), $cx, 16);
1817     } else { # I don't think baseop filetests ever survive ck_ftst, but...
1818         return $name;
1819     }
1820 }
1821
1822 sub pp_lstat    { ftst(@_, "lstat") }
1823 sub pp_stat     { ftst(@_, "stat") }
1824 sub pp_ftrread  { ftst(@_, "-R") }
1825 sub pp_ftrwrite { ftst(@_, "-W") }
1826 sub pp_ftrexec  { ftst(@_, "-X") }
1827 sub pp_fteread  { ftst(@_, "-r") }
1828 sub pp_ftewrite { ftst(@_, "-w") }
1829 sub pp_fteexec  { ftst(@_, "-x") }
1830 sub pp_ftis     { ftst(@_, "-e") }
1831 sub pp_fteowned { ftst(@_, "-O") }
1832 sub pp_ftrowned { ftst(@_, "-o") }
1833 sub pp_ftzero   { ftst(@_, "-z") }
1834 sub pp_ftsize   { ftst(@_, "-s") }
1835 sub pp_ftmtime  { ftst(@_, "-M") }
1836 sub pp_ftatime  { ftst(@_, "-A") }
1837 sub pp_ftctime  { ftst(@_, "-C") }
1838 sub pp_ftsock   { ftst(@_, "-S") }
1839 sub pp_ftchr    { ftst(@_, "-c") }
1840 sub pp_ftblk    { ftst(@_, "-b") }
1841 sub pp_ftfile   { ftst(@_, "-f") }
1842 sub pp_ftdir    { ftst(@_, "-d") }
1843 sub pp_ftpipe   { ftst(@_, "-p") }
1844 sub pp_ftlink   { ftst(@_, "-l") }
1845 sub pp_ftsuid   { ftst(@_, "-u") }
1846 sub pp_ftsgid   { ftst(@_, "-g") }
1847 sub pp_ftsvtx   { ftst(@_, "-k") }
1848 sub pp_fttty    { ftst(@_, "-t") }
1849 sub pp_fttext   { ftst(@_, "-T") }
1850 sub pp_ftbinary { ftst(@_, "-B") }
1851
1852 sub SWAP_CHILDREN () { 1 }
1853 sub ASSIGN () { 2 } # has OP= variant
1854 sub LIST_CONTEXT () { 4 } # Assignment is in list context
1855
1856 my(%left, %right);
1857
1858 sub assoc_class {
1859     my $op = shift;
1860     my $name = $op->name;
1861     if ($name eq "concat" and $op->first->name eq "concat") {
1862         # avoid spurious `=' -- see comment in pp_concat
1863         return "concat";
1864     }
1865     if ($name eq "null" and class($op) eq "UNOP"
1866         and $op->first->name =~ /^(and|x?or)$/
1867         and null $op->first->sibling)
1868     {
1869         # Like all conditional constructs, OP_ANDs and OP_ORs are topped
1870         # with a null that's used as the common end point of the two
1871         # flows of control. For precedence purposes, ignore it.
1872         # (COND_EXPRs have these too, but we don't bother with
1873         # their associativity).
1874         return assoc_class($op->first);
1875     }
1876     return $name . ($op->flags & OPf_STACKED ? "=" : "");
1877 }
1878
1879 # Left associative operators, like `+', for which
1880 # $a + $b + $c is equivalent to ($a + $b) + $c
1881
1882 BEGIN {
1883     %left = ('multiply' => 19, 'i_multiply' => 19,
1884              'divide' => 19, 'i_divide' => 19,
1885              'modulo' => 19, 'i_modulo' => 19,
1886              'repeat' => 19,
1887              'add' => 18, 'i_add' => 18,
1888              'subtract' => 18, 'i_subtract' => 18,
1889              'concat' => 18,
1890              'left_shift' => 17, 'right_shift' => 17,
1891              'bit_and' => 13,
1892              'bit_or' => 12, 'bit_xor' => 12,
1893              'and' => 3,
1894              'or' => 2, 'xor' => 2,
1895             );
1896 }
1897
1898 sub deparse_binop_left {
1899     my $self = shift;
1900     my($op, $left, $prec) = @_;
1901     if ($left{assoc_class($op)} && $left{assoc_class($left)}
1902         and $left{assoc_class($op)} == $left{assoc_class($left)})
1903     {
1904         return $self->deparse($left, $prec - .00001);
1905     } else {
1906         return $self->deparse($left, $prec);
1907     }
1908 }
1909
1910 # Right associative operators, like `=', for which
1911 # $a = $b = $c is equivalent to $a = ($b = $c)
1912
1913 BEGIN {
1914     %right = ('pow' => 22,
1915               'sassign=' => 7, 'aassign=' => 7,
1916               'multiply=' => 7, 'i_multiply=' => 7,
1917               'divide=' => 7, 'i_divide=' => 7,
1918               'modulo=' => 7, 'i_modulo=' => 7,
1919               'repeat=' => 7,
1920               'add=' => 7, 'i_add=' => 7,
1921               'subtract=' => 7, 'i_subtract=' => 7,
1922               'concat=' => 7,
1923               'left_shift=' => 7, 'right_shift=' => 7,
1924               'bit_and=' => 7,
1925               'bit_or=' => 7, 'bit_xor=' => 7,
1926               'andassign' => 7,
1927               'orassign' => 7,
1928              );
1929 }
1930
1931 sub deparse_binop_right {
1932     my $self = shift;
1933     my($op, $right, $prec) = @_;
1934     if ($right{assoc_class($op)} && $right{assoc_class($right)}
1935         and $right{assoc_class($op)} == $right{assoc_class($right)})
1936     {
1937         return $self->deparse($right, $prec - .00001);
1938     } else {
1939         return $self->deparse($right, $prec);
1940     }
1941 }
1942
1943 sub binop {
1944     my $self = shift;
1945     my ($op, $cx, $opname, $prec, $flags) = (@_, 0);
1946     my $left = $op->first;
1947     my $right = $op->last;
1948     my $eq = "";
1949     if ($op->flags & OPf_STACKED && $flags & ASSIGN) {
1950         $eq = "=";
1951         $prec = 7;
1952     }
1953     if ($flags & SWAP_CHILDREN) {
1954         ($left, $right) = ($right, $left);
1955     }
1956     $left = $self->deparse_binop_left($op, $left, $prec);
1957     $left = "($left)" if $flags & LIST_CONTEXT
1958                 && $left !~ /^(my|our|local|)[\@\(]/;
1959     $right = $self->deparse_binop_right($op, $right, $prec);
1960     return $self->maybe_parens("$left $opname$eq $right", $cx, $prec);
1961 }
1962
1963 sub pp_add { maybe_targmy(@_, \&binop, "+", 18, ASSIGN) }
1964 sub pp_multiply { maybe_targmy(@_, \&binop, "*", 19, ASSIGN) }
1965 sub pp_subtract { maybe_targmy(@_, \&binop, "-",18,  ASSIGN) }
1966 sub pp_divide { maybe_targmy(@_, \&binop, "/", 19, ASSIGN) }
1967 sub pp_modulo { maybe_targmy(@_, \&binop, "%", 19, ASSIGN) }
1968 sub pp_i_add { maybe_targmy(@_, \&binop, "+", 18, ASSIGN) }
1969 sub pp_i_multiply { maybe_targmy(@_, \&binop, "*", 19, ASSIGN) }
1970 sub pp_i_subtract { maybe_targmy(@_, \&binop, "-", 18, ASSIGN) }
1971 sub pp_i_divide { maybe_targmy(@_, \&binop, "/", 19, ASSIGN) }
1972 sub pp_i_modulo { maybe_targmy(@_, \&binop, "%", 19, ASSIGN) }
1973 sub pp_pow { maybe_targmy(@_, \&binop, "**", 22, ASSIGN) }
1974
1975 sub pp_left_shift { maybe_targmy(@_, \&binop, "<<", 17, ASSIGN) }
1976 sub pp_right_shift { maybe_targmy(@_, \&binop, ">>", 17, ASSIGN) }
1977 sub pp_bit_and { maybe_targmy(@_, \&binop, "&", 13, ASSIGN) }
1978 sub pp_bit_or { maybe_targmy(@_, \&binop, "|", 12, ASSIGN) }
1979 sub pp_bit_xor { maybe_targmy(@_, \&binop, "^", 12, ASSIGN) }
1980
1981 sub pp_eq { binop(@_, "==", 14) }
1982 sub pp_ne { binop(@_, "!=", 14) }
1983 sub pp_lt { binop(@_, "<", 15) }
1984 sub pp_gt { binop(@_, ">", 15) }
1985 sub pp_ge { binop(@_, ">=", 15) }
1986 sub pp_le { binop(@_, "<=", 15) }
1987 sub pp_ncmp { binop(@_, "<=>", 14) }
1988 sub pp_i_eq { binop(@_, "==", 14) }
1989 sub pp_i_ne { binop(@_, "!=", 14) }
1990 sub pp_i_lt { binop(@_, "<", 15) }
1991 sub pp_i_gt { binop(@_, ">", 15) }
1992 sub pp_i_ge { binop(@_, ">=", 15) }
1993 sub pp_i_le { binop(@_, "<=", 15) }
1994 sub pp_i_ncmp { binop(@_, "<=>", 14) }
1995
1996 sub pp_seq { binop(@_, "eq", 14) }
1997 sub pp_sne { binop(@_, "ne", 14) }
1998 sub pp_slt { binop(@_, "lt", 15) }
1999 sub pp_sgt { binop(@_, "gt", 15) }
2000 sub pp_sge { binop(@_, "ge", 15) }
2001 sub pp_sle { binop(@_, "le", 15) }
2002 sub pp_scmp { binop(@_, "cmp", 14) }
2003
2004 sub pp_sassign { binop(@_, "=", 7, SWAP_CHILDREN) }
2005 sub pp_aassign { binop(@_, "=", 7, SWAP_CHILDREN | LIST_CONTEXT) }
2006
2007 # `.' is special because concats-of-concats are optimized to save copying
2008 # by making all but the first concat stacked. The effect is as if the
2009 # programmer had written `($a . $b) .= $c', except legal.
2010 sub pp_concat { maybe_targmy(@_, \&real_concat) }
2011 sub real_concat {
2012     my $self = shift;
2013     my($op, $cx) = @_;
2014     my $left = $op->first;
2015     my $right = $op->last;
2016     my $eq = "";
2017     my $prec = 18;
2018     if ($op->flags & OPf_STACKED and $op->first->name ne "concat") {
2019         $eq = "=";
2020         $prec = 7;
2021     }
2022     $left = $self->deparse_binop_left($op, $left, $prec);
2023     $right = $self->deparse_binop_right($op, $right, $prec);
2024     return $self->maybe_parens("$left .$eq $right", $cx, $prec);
2025 }
2026
2027 # `x' is weird when the left arg is a list
2028 sub pp_repeat {
2029     my $self = shift;
2030     my($op, $cx) = @_;
2031     my $left = $op->first;
2032     my $right = $op->last;
2033     my $eq = "";
2034     my $prec = 19;
2035     if ($op->flags & OPf_STACKED) {
2036         $eq = "=";
2037         $prec = 7;
2038     }
2039     if (null($right)) { # list repeat; count is inside left-side ex-list
2040         my $kid = $left->first->sibling; # skip pushmark
2041         my @exprs;
2042         for (; !null($kid->sibling); $kid = $kid->sibling) {
2043             push @exprs, $self->deparse($kid, 6);
2044         }
2045         $right = $kid;
2046         $left = "(" . join(", ", @exprs). ")";
2047     } else {
2048         $left = $self->deparse_binop_left($op, $left, $prec);
2049     }
2050     $right = $self->deparse_binop_right($op, $right, $prec);
2051     return $self->maybe_parens("$left x$eq $right", $cx, $prec);
2052 }
2053
2054 sub range {
2055     my $self = shift;
2056     my ($op, $cx, $type) = @_;
2057     my $left = $op->first;
2058     my $right = $left->sibling;
2059     $left = $self->deparse($left, 9);
2060     $right = $self->deparse($right, 9);
2061     return $self->maybe_parens("$left $type $right", $cx, 9);
2062 }
2063
2064 sub pp_flop {
2065     my $self = shift;
2066     my($op, $cx) = @_;
2067     my $flip = $op->first;
2068     my $type = ($flip->flags & OPf_SPECIAL) ? "..." : "..";
2069     return $self->range($flip->first, $cx, $type);
2070 }
2071
2072 # one-line while/until is handled in pp_leave
2073
2074 sub logop {
2075     my $self = shift;
2076     my ($op, $cx, $lowop, $lowprec, $highop, $highprec, $blockname) = @_;
2077     my $left = $op->first;
2078     my $right = $op->first->sibling;
2079     if ($cx < 1 and is_scope($right) and $blockname
2080         and $self->{'expand'} < 7)
2081     { # if ($a) {$b}
2082         $left = $self->deparse($left, 1);
2083         $right = $self->deparse($right, 0);
2084         return "$blockname ($left) {\n\t$right\n\b}\cK";
2085     } elsif ($cx < 1 and $blockname and not $self->{'parens'}
2086              and $self->{'expand'} < 7) { # $b if $a
2087         $right = $self->deparse($right, 1);
2088         $left = $self->deparse($left, 1);
2089         return "$right $blockname $left";
2090     } elsif ($cx > $lowprec and $highop) { # $a && $b
2091         $left = $self->deparse_binop_left($op, $left, $highprec);
2092         $right = $self->deparse_binop_right($op, $right, $highprec);
2093         return $self->maybe_parens("$left $highop $right", $cx, $highprec);
2094     } else { # $a and $b
2095         $left = $self->deparse_binop_left($op, $left, $lowprec);
2096         $right = $self->deparse_binop_right($op, $right, $lowprec);
2097         return $self->maybe_parens("$left $lowop $right", $cx, $lowprec);
2098     }
2099 }
2100
2101 sub pp_and { logop(@_, "and", 3, "&&", 11, "if") }
2102 sub pp_or  { logop(@_, "or",  2, "||", 10, "unless") }
2103 sub pp_dor { logop(@_, "err", 2, "//", 10, "") }
2104
2105 # xor is syntactically a logop, but it's really a binop (contrary to
2106 # old versions of opcode.pl). Syntax is what matters here.
2107 sub pp_xor { logop(@_, "xor", 2, "",   0,  "") }
2108
2109 sub logassignop {
2110     my $self = shift;
2111     my ($op, $cx, $opname) = @_;
2112     my $left = $op->first;
2113     my $right = $op->first->sibling->first; # skip sassign
2114     $left = $self->deparse($left, 7);
2115     $right = $self->deparse($right, 7);
2116     return $self->maybe_parens("$left $opname $right", $cx, 7);
2117 }
2118
2119 sub pp_andassign { logassignop(@_, "&&=") }
2120 sub pp_orassign  { logassignop(@_, "||=") }
2121 sub pp_dorassign { logassignop(@_, "//=") }
2122
2123 sub listop {
2124     my $self = shift;
2125     my($op, $cx, $name) = @_;
2126     my(@exprs);
2127     my $parens = ($cx >= 5) || $self->{'parens'};
2128     my $kid = $op->first->sibling;
2129     return $name if null $kid;
2130     my $first;
2131     $name = "socketpair" if $name eq "sockpair";
2132     my $proto = prototype("CORE::$name");
2133     if (defined $proto
2134         && $proto =~ /^;?\*/
2135         && $kid->name eq "rv2gv") {
2136         $first = $self->deparse($kid->first, 6);
2137     }
2138     else {
2139         $first = $self->deparse($kid, 6);
2140     }
2141     if ($name eq "chmod" && $first =~ /^\d+$/) {
2142         $first = sprintf("%#o", $first);
2143     }
2144     $first = "+$first" if not $parens and substr($first, 0, 1) eq "(";
2145     push @exprs, $first;
2146     $kid = $kid->sibling;
2147     if (defined $proto && $proto =~ /^\*\*/ && $kid->name eq "rv2gv") {
2148         push @exprs, $self->deparse($kid->first, 6);
2149         $kid = $kid->sibling;
2150     }
2151     for (; !null($kid); $kid = $kid->sibling) {
2152         push @exprs, $self->deparse($kid, 6);
2153     }
2154     if ($parens) {
2155         return "$name(" . join(", ", @exprs) . ")";
2156     } else {
2157         return "$name " . join(", ", @exprs);
2158     }
2159 }
2160
2161 sub pp_bless { listop(@_, "bless") }
2162 sub pp_atan2 { maybe_targmy(@_, \&listop, "atan2") }
2163 sub pp_substr { maybe_local(@_, listop(@_, "substr")) }
2164 sub pp_vec { maybe_local(@_, listop(@_, "vec")) }
2165 sub pp_index { maybe_targmy(@_, \&listop, "index") }
2166 sub pp_rindex { maybe_targmy(@_, \&listop, "rindex") }
2167 sub pp_sprintf { maybe_targmy(@_, \&listop, "sprintf") }
2168 sub pp_formline { listop(@_, "formline") } # see also deparse_format
2169 sub pp_crypt { maybe_targmy(@_, \&listop, "crypt") }
2170 sub pp_unpack { listop(@_, "unpack") }
2171 sub pp_pack { listop(@_, "pack") }
2172 sub pp_join { maybe_targmy(@_, \&listop, "join") }
2173 sub pp_splice { listop(@_, "splice") }
2174 sub pp_push { maybe_targmy(@_, \&listop, "push") }
2175 sub pp_unshift { maybe_targmy(@_, \&listop, "unshift") }
2176 sub pp_reverse { listop(@_, "reverse") }
2177 sub pp_warn { listop(@_, "warn") }
2178 sub pp_die { listop(@_, "die") }
2179 # Actually, return is exempt from the LLAFR (see examples in this very
2180 # module!), but for consistency's sake, ignore that fact
2181 sub pp_return { listop(@_, "return") }
2182 sub pp_open { listop(@_, "open") }
2183 sub pp_pipe_op { listop(@_, "pipe") }
2184 sub pp_tie { listop(@_, "tie") }
2185 sub pp_binmode { listop(@_, "binmode") }
2186 sub pp_dbmopen { listop(@_, "dbmopen") }
2187 sub pp_sselect { listop(@_, "select") }
2188 sub pp_select { listop(@_, "select") }
2189 sub pp_read { listop(@_, "read") }
2190 sub pp_sysopen { listop(@_, "sysopen") }
2191 sub pp_sysseek { listop(@_, "sysseek") }
2192 sub pp_sysread { listop(@_, "sysread") }
2193 sub pp_syswrite { listop(@_, "syswrite") }
2194 sub pp_send { listop(@_, "send") }
2195 sub pp_recv { listop(@_, "recv") }
2196 sub pp_seek { listop(@_, "seek") }
2197 sub pp_fcntl { listop(@_, "fcntl") }
2198 sub pp_ioctl { listop(@_, "ioctl") }
2199 sub pp_flock { maybe_targmy(@_, \&listop, "flock") }
2200 sub pp_socket { listop(@_, "socket") }
2201 sub pp_sockpair { listop(@_, "sockpair") }
2202 sub pp_bind { listop(@_, "bind") }
2203 sub pp_connect { listop(@_, "connect") }
2204 sub pp_listen { listop(@_, "listen") }
2205 sub pp_accept { listop(@_, "accept") }
2206 sub pp_shutdown { listop(@_, "shutdown") }
2207 sub pp_gsockopt { listop(@_, "getsockopt") }
2208 sub pp_ssockopt { listop(@_, "setsockopt") }
2209 sub pp_chown { maybe_targmy(@_, \&listop, "chown") }
2210 sub pp_unlink { maybe_targmy(@_, \&listop, "unlink") }
2211 sub pp_chmod { maybe_targmy(@_, \&listop, "chmod") }
2212 sub pp_utime { maybe_targmy(@_, \&listop, "utime") }
2213 sub pp_rename { maybe_targmy(@_, \&listop, "rename") }
2214 sub pp_link { maybe_targmy(@_, \&listop, "link") }
2215 sub pp_symlink { maybe_targmy(@_, \&listop, "symlink") }
2216 sub pp_mkdir { maybe_targmy(@_, \&listop, "mkdir") }
2217 sub pp_open_dir { listop(@_, "opendir") }
2218 sub pp_seekdir { listop(@_, "seekdir") }
2219 sub pp_waitpid { maybe_targmy(@_, \&listop, "waitpid") }
2220 sub pp_system { maybe_targmy(@_, \&listop, "system") }
2221 sub pp_exec { maybe_targmy(@_, \&listop, "exec") }
2222 sub pp_kill { maybe_targmy(@_, \&listop, "kill") }
2223 sub pp_setpgrp { maybe_targmy(@_, \&listop, "setpgrp") }
2224 sub pp_getpriority { maybe_targmy(@_, \&listop, "getpriority") }
2225 sub pp_setpriority { maybe_targmy(@_, \&listop, "setpriority") }
2226 sub pp_shmget { listop(@_, "shmget") }
2227 sub pp_shmctl { listop(@_, "shmctl") }
2228 sub pp_shmread { listop(@_, "shmread") }
2229 sub pp_shmwrite { listop(@_, "shmwrite") }
2230 sub pp_msgget { listop(@_, "msgget") }
2231 sub pp_msgctl { listop(@_, "msgctl") }
2232 sub pp_msgsnd { listop(@_, "msgsnd") }
2233 sub pp_msgrcv { listop(@_, "msgrcv") }
2234 sub pp_semget { listop(@_, "semget") }
2235 sub pp_semctl { listop(@_, "semctl") }
2236 sub pp_semop { listop(@_, "semop") }
2237 sub pp_ghbyaddr { listop(@_, "gethostbyaddr") }
2238 sub pp_gnbyaddr { listop(@_, "getnetbyaddr") }
2239 sub pp_gpbynumber { listop(@_, "getprotobynumber") }
2240 sub pp_gsbyname { listop(@_, "getservbyname") }
2241 sub pp_gsbyport { listop(@_, "getservbyport") }
2242 sub pp_syscall { listop(@_, "syscall") }
2243
2244 sub pp_glob {
2245     my $self = shift;
2246     my($op, $cx) = @_;
2247     my $text = $self->dq($op->first->sibling);  # skip pushmark
2248     if ($text =~ /^\$?(\w|::|\`)+$/ # could look like a readline
2249         or $text =~ /[<>]/) {
2250         return 'glob(' . single_delim('qq', '"', $text) . ')';
2251     } else {
2252         return '<' . $text . '>';
2253     }
2254 }
2255
2256 # Truncate is special because OPf_SPECIAL makes a bareword first arg
2257 # be a filehandle. This could probably be better fixed in the core
2258 # by moving the GV lookup into ck_truc.
2259
2260 sub pp_truncate {
2261     my $self = shift;
2262     my($op, $cx) = @_;
2263     my(@exprs);
2264     my $parens = ($cx >= 5) || $self->{'parens'};
2265     my $kid = $op->first->sibling;
2266     my $fh;
2267     if ($op->flags & OPf_SPECIAL) {
2268         # $kid is an OP_CONST
2269         $fh = $self->const_sv($kid)->PV;
2270     } else {
2271         $fh = $self->deparse($kid, 6);
2272         $fh = "+$fh" if not $parens and substr($fh, 0, 1) eq "(";
2273     }
2274     my $len = $self->deparse($kid->sibling, 6);
2275     if ($parens) {
2276         return "truncate($fh, $len)";
2277     } else {
2278         return "truncate $fh, $len";
2279     }
2280 }
2281
2282 sub indirop {
2283     my $self = shift;
2284     my($op, $cx, $name) = @_;
2285     my($expr, @exprs);
2286     my $kid = $op->first->sibling;
2287     my $indir = "";
2288     if ($op->flags & OPf_STACKED) {
2289         $indir = $kid;
2290         $indir = $indir->first; # skip rv2gv
2291         if (is_scope($indir)) {
2292             $indir = "{" . $self->deparse($indir, 0) . "}";
2293             $indir = "{;}" if $indir eq "{}";
2294         } elsif ($indir->name eq "const" && $indir->private & OPpCONST_BARE) {
2295             $indir = $self->const_sv($indir)->PV;
2296         } else {
2297             $indir = $self->deparse($indir, 24);
2298         }
2299         $indir = $indir . " ";
2300         $kid = $kid->sibling;
2301     }
2302     if ($name eq "sort" && $op->private & (OPpSORT_NUMERIC | OPpSORT_INTEGER)) {
2303         $indir = ($op->private & OPpSORT_REVERSE) ? '{$b <=> $a} '
2304                                                   : '{$a <=> $b} ';
2305     }
2306     elsif ($name eq "sort" && $op->private & OPpSORT_REVERSE) {
2307         $indir = '{$b cmp $a} ';
2308     }
2309     for (; !null($kid); $kid = $kid->sibling) {
2310         $expr = $self->deparse($kid, 6);
2311         push @exprs, $expr;
2312     }
2313     my $args = $indir . join(", ", @exprs);
2314     if ($indir ne "" and $name eq "sort") {
2315         # We don't want to say "sort(f 1, 2, 3)", since perl -w will
2316         # give bareword warnings in that case. Therefore if context
2317         # requires, we'll put parens around the outside "(sort f 1, 2,
2318         # 3)". Unfortunately, we'll currently think the parens are
2319         # neccessary more often that they really are, because we don't
2320         # distinguish which side of an assignment we're on.
2321         if ($cx >= 5) {
2322             return "($name $args)";
2323         } else {
2324             return "$name $args";
2325         }
2326     } else {
2327         return $self->maybe_parens_func($name, $args, $cx, 5);
2328     }
2329
2330 }
2331
2332 sub pp_prtf { indirop(@_, "printf") }
2333 sub pp_print { indirop(@_, "print") }
2334 sub pp_sort { indirop(@_, "sort") }
2335
2336 sub mapop {
2337     my $self = shift;
2338     my($op, $cx, $name) = @_;
2339     my($expr, @exprs);
2340     my $kid = $op->first; # this is the (map|grep)start
2341     $kid = $kid->first->sibling; # skip a pushmark
2342     my $code = $kid->first; # skip a null
2343     if (is_scope $code) {
2344         $code = "{" . $self->deparse($code, 0) . "} ";
2345     } else {
2346         $code = $self->deparse($code, 24) . ", ";
2347     }
2348     $kid = $kid->sibling;
2349     for (; !null($kid); $kid = $kid->sibling) {
2350         $expr = $self->deparse($kid, 6);
2351         push @exprs, $expr if defined $expr;
2352     }
2353     return $self->maybe_parens_func($name, $code . join(", ", @exprs), $cx, 5);
2354 }
2355
2356 sub pp_mapwhile { mapop(@_, "map") }
2357 sub pp_grepwhile { mapop(@_, "grep") }
2358
2359 sub pp_list {
2360     my $self = shift;
2361     my($op, $cx) = @_;
2362     my($expr, @exprs);
2363     my $kid = $op->first->sibling; # skip pushmark
2364     my $lop;
2365     my $local = "either"; # could be local(...), my(...) or our(...)
2366     for ($lop = $kid; !null($lop); $lop = $lop->sibling) {
2367         # This assumes that no other private flags equal 128, and that
2368         # OPs that store things other than flags in their op_private,
2369         # like OP_AELEMFAST, won't be immediate children of a list.
2370         #
2371         # OP_ENTERSUB can break this logic, so check for it.
2372         # I suspect that open and exit can too.
2373
2374         if (!($lop->private & (OPpLVAL_INTRO|OPpOUR_INTRO)
2375                 or $lop->name eq "undef")
2376             or $lop->name eq "entersub"
2377             or $lop->name eq "exit"
2378             or $lop->name eq "open")
2379         {
2380             $local = ""; # or not
2381             last;
2382         }
2383         if ($lop->name =~ /^pad[ash]v$/) { # my()
2384             ($local = "", last) if $local eq "local" || $local eq "our";
2385             $local = "my";
2386         } elsif ($lop->name =~ /^(gv|rv2)[ash]v$/
2387                         && $lop->private & OPpOUR_INTRO
2388                 or $lop->name eq "null" && $lop->first->name eq "gvsv"
2389                         && $lop->first->private & OPpOUR_INTRO) { # our()
2390             ($local = "", last) if $local eq "my" || $local eq "local";
2391             $local = "our";
2392         } elsif ($lop->name ne "undef") { # local()
2393             ($local = "", last) if $local eq "my" || $local eq "our";
2394             $local = "local";
2395         }
2396     }
2397     $local = "" if $local eq "either"; # no point if it's all undefs
2398     return $self->deparse($kid, $cx) if null $kid->sibling and not $local;
2399     for (; !null($kid); $kid = $kid->sibling) {
2400         if ($local) {
2401             if (class($kid) eq "UNOP" and $kid->first->name eq "gvsv") {
2402                 $lop = $kid->first;
2403             } else {
2404                 $lop = $kid;
2405             }
2406             $self->{'avoid_local'}{$$lop}++;
2407             $expr = $self->deparse($kid, 6);
2408             delete $self->{'avoid_local'}{$$lop};
2409         } else {
2410             $expr = $self->deparse($kid, 6);
2411         }
2412         push @exprs, $expr;
2413     }
2414     if ($local) {
2415         return "$local(" . join(", ", @exprs) . ")";
2416     } else {
2417         return $self->maybe_parens( join(", ", @exprs), $cx, 6);
2418     }
2419 }
2420
2421 sub is_ifelse_cont {
2422     my $op = shift;
2423     return ($op->name eq "null" and class($op) eq "UNOP"
2424             and $op->first->name =~ /^(and|cond_expr)$/
2425             and is_scope($op->first->first->sibling));
2426 }
2427
2428 sub pp_cond_expr {
2429     my $self = shift;
2430     my($op, $cx) = @_;
2431     my $cond = $op->first;
2432     my $true = $cond->sibling;
2433     my $false = $true->sibling;
2434     my $cuddle = $self->{'cuddle'};
2435     unless ($cx < 1 and (is_scope($true) and $true->name ne "null") and
2436             (is_scope($false) || is_ifelse_cont($false))
2437             and $self->{'expand'} < 7) {
2438         $cond = $self->deparse($cond, 8);
2439         $true = $self->deparse($true, 8);
2440         $false = $self->deparse($false, 8);
2441         return $self->maybe_parens("$cond ? $true : $false", $cx, 8);
2442     }
2443
2444     $cond = $self->deparse($cond, 1);
2445     $true = $self->deparse($true, 0);
2446     my $head = "if ($cond) {\n\t$true\n\b}";
2447     my @elsifs;
2448     while (!null($false) and is_ifelse_cont($false)) {
2449         my $newop = $false->first;
2450         my $newcond = $newop->first;
2451         my $newtrue = $newcond->sibling;
2452         $false = $newtrue->sibling; # last in chain is OP_AND => no else
2453         $newcond = $self->deparse($newcond, 1);
2454         $newtrue = $self->deparse($newtrue, 0);
2455         push @elsifs, "elsif ($newcond) {\n\t$newtrue\n\b}";
2456     }
2457     if (!null($false)) {
2458         $false = $cuddle . "else {\n\t" .
2459           $self->deparse($false, 0) . "\n\b}\cK";
2460     } else {
2461         $false = "\cK";
2462     }
2463     return $head . join($cuddle, "", @elsifs) . $false;
2464 }
2465
2466 sub loop_common {
2467     my $self = shift;
2468     my($op, $cx, $init) = @_;
2469     my $enter = $op->first;
2470     my $kid = $enter->sibling;
2471     local(@$self{qw'curstash warnings hints'})
2472                 = @$self{qw'curstash warnings hints'};
2473     my $head = "";
2474     my $bare = 0;
2475     my $body;
2476     my $cond = undef;
2477     if ($kid->name eq "lineseq") { # bare or infinite loop
2478         if ($kid->last->name eq "unstack") { # infinite
2479             $head = "while (1) "; # Can't use for(;;) if there's a continue
2480             $cond = "";
2481         } else {
2482             $bare = 1;
2483         }
2484         $body = $kid;
2485     } elsif ($enter->name eq "enteriter") { # foreach
2486         my $ary = $enter->first->sibling; # first was pushmark
2487         my $var = $ary->sibling;
2488         if ($enter->flags & OPf_STACKED
2489             and not null $ary->first->sibling->sibling)
2490         {
2491             $ary = $self->deparse($ary->first->sibling, 9) . " .. " .
2492               $self->deparse($ary->first->sibling->sibling, 9);
2493         } else {
2494             $ary = $self->deparse($ary, 1);
2495         }
2496         if (null $var) {
2497             if ($enter->flags & OPf_SPECIAL) { # thread special var
2498                 $var = $self->pp_threadsv($enter, 1);
2499             } else { # regular my() variable
2500                 $var = $self->pp_padsv($enter, 1);
2501             }
2502         } elsif ($var->name eq "rv2gv") {
2503             $var = $self->pp_rv2sv($var, 1);
2504             if ($enter->private & OPpOUR_INTRO) {
2505                 # our declarations don't have package names
2506                 $var =~ s/^(.).*::/$1/;
2507                 $var = "our $var";
2508             }
2509         } elsif ($var->name eq "gv") {
2510             $var = "\$" . $self->deparse($var, 1);
2511         }
2512         $head = "foreach $var ($ary) ";
2513         $body = $kid->first->first->sibling; # skip OP_AND and OP_ITER
2514     } elsif ($kid->name eq "null") { # while/until
2515         $kid = $kid->first;
2516         my $name = {"and" => "while", "or" => "until"}->{$kid->name};
2517         $cond = $self->deparse($kid->first, 1);
2518         $head = "$name ($cond) ";
2519         $body = $kid->first->sibling;
2520     } elsif ($kid->name eq "stub") { # bare and empty
2521         return "{;}"; # {} could be a hashref
2522     }
2523     # If there isn't a continue block, then the next pointer for the loop
2524     # will point to the unstack, which is kid's last child, except
2525     # in a bare loop, when it will point to the leaveloop. When neither of
2526     # these conditions hold, then the second-to-last child is the continue
2527     # block (or the last in a bare loop).
2528     my $cont_start = $enter->nextop;
2529     my $cont;
2530     if ($$cont_start != $$op && ${$cont_start} != ${$body->last}) {
2531         if ($bare) {
2532             $cont = $body->last;
2533         } else {
2534             $cont = $body->first;
2535             while (!null($cont->sibling->sibling)) {
2536                 $cont = $cont->sibling;
2537             }
2538         }
2539         my $state = $body->first;
2540         my $cuddle = $self->{'cuddle'};
2541         my @states;
2542         for (; $$state != $$cont; $state = $state->sibling) {
2543             push @states, $state;
2544         }
2545         $body = $self->lineseq(undef, @states);
2546         if (defined $cond and not is_scope $cont and $self->{'expand'} < 3) {
2547             $head = "for ($init; $cond; " . $self->deparse($cont, 1) .") ";
2548             $cont = "\cK";
2549         } else {
2550             $cont = $cuddle . "continue {\n\t" .
2551               $self->deparse($cont, 0) . "\n\b}\cK";
2552         }
2553     } else {
2554         return "" if !defined $body;
2555         if (length $init) {
2556             $head = "for ($init; $cond;) ";
2557         }
2558         $cont = "\cK";
2559         $body = $self->deparse($body, 0);
2560     }
2561     $body =~ s/;?$/;\n/;
2562
2563     return $head . "{\n\t" . $body . "\b}" . $cont;
2564 }
2565
2566 sub pp_leaveloop { loop_common(@_, "") }
2567
2568 sub for_loop {
2569     my $self = shift;
2570     my($op, $cx) = @_;
2571     my $init = $self->deparse($op, 1);
2572     return $self->loop_common($op->sibling->first->sibling, $cx, $init);
2573 }
2574
2575 sub pp_leavetry {
2576     my $self = shift;
2577     return "eval {\n\t" . $self->pp_leave(@_) . "\n\b}";
2578 }
2579
2580 BEGIN { eval "sub OP_CONST () {" . opnumber("const") . "}" }
2581 BEGIN { eval "sub OP_STRINGIFY () {" . opnumber("stringify") . "}" }
2582 BEGIN { eval "sub OP_RV2SV () {" . opnumber("rv2sv") . "}" }
2583 BEGIN { eval "sub OP_LIST () {" . opnumber("list") . "}" }
2584
2585 sub pp_null {
2586     my $self = shift;
2587     my($op, $cx) = @_;
2588     if (class($op) eq "OP") {
2589         # old value is lost
2590         return $self->{'ex_const'} if $op->targ == OP_CONST;
2591     } elsif ($op->first->name eq "pushmark") {
2592         return $self->pp_list($op, $cx);
2593     } elsif ($op->first->name eq "enter") {
2594         return $self->pp_leave($op, $cx);
2595     } elsif ($op->targ == OP_STRINGIFY) {
2596         return $self->dquote($op, $cx);
2597     } elsif (!null($op->first->sibling) and
2598              $op->first->sibling->name eq "readline" and
2599              $op->first->sibling->flags & OPf_STACKED) {
2600         return $self->maybe_parens($self->deparse($op->first, 7) . " = "
2601                                    . $self->deparse($op->first->sibling, 7),
2602                                    $cx, 7);
2603     } elsif (!null($op->first->sibling) and
2604              $op->first->sibling->name eq "trans" and
2605              $op->first->sibling->flags & OPf_STACKED) {
2606         return $self->maybe_parens($self->deparse($op->first, 20) . " =~ "
2607                                    . $self->deparse($op->first->sibling, 20),
2608                                    $cx, 20);
2609     } elsif ($op->flags & OPf_SPECIAL && $cx < 1 && !$op->targ) {
2610         return "do {\n\t". $self->deparse($op->first, $cx) ."\n\b};";
2611     } elsif (!null($op->first->sibling) and
2612              $op->first->sibling->name eq "null" and
2613              class($op->first->sibling) eq "UNOP" and
2614              $op->first->sibling->first->flags & OPf_STACKED and
2615              $op->first->sibling->first->name eq "rcatline") {
2616         return $self->maybe_parens($self->deparse($op->first, 18) . " .= "
2617                                    . $self->deparse($op->first->sibling, 18),
2618                                    $cx, 18);
2619     } else {
2620         return $self->deparse($op->first, $cx);
2621     }
2622 }
2623
2624 sub padname {
2625     my $self = shift;
2626     my $targ = shift;
2627     return $self->padname_sv($targ)->PVX;
2628 }
2629
2630 sub padany {
2631     my $self = shift;
2632     my $op = shift;
2633     return substr($self->padname($op->targ), 1); # skip $/@/%
2634 }
2635
2636 sub pp_padsv {
2637     my $self = shift;
2638     my($op, $cx) = @_;
2639     return $self->maybe_my($op, $cx, $self->padname($op->targ));
2640 }
2641
2642 sub pp_padav { pp_padsv(@_) }
2643 sub pp_padhv { pp_padsv(@_) }
2644
2645 my @threadsv_names;
2646
2647 BEGIN {
2648     @threadsv_names = ("_", "1", "2", "3", "4", "5", "6", "7", "8", "9",
2649                        "&", "`", "'", "+", "/", ".", ",", "\\", '"', ";",
2650                        "^", "-", "%", "=", "|", "~", ":", "^A", "^E",
2651                        "!", "@");
2652 }
2653
2654 sub pp_threadsv {
2655     my $self = shift;
2656     my($op, $cx) = @_;
2657     return $self->maybe_local($op, $cx, "\$" .  $threadsv_names[$op->targ]);
2658 }
2659
2660 sub gv_or_padgv {
2661     my $self = shift;
2662     my $op = shift;
2663     if (class($op) eq "PADOP") {
2664         return $self->padval($op->padix);
2665     } else { # class($op) eq "SVOP"
2666         return $op->gv;
2667     }
2668 }
2669
2670 sub pp_gvsv {
2671     my $self = shift;
2672     my($op, $cx) = @_;
2673     my $gv = $self->gv_or_padgv($op);
2674     return $self->maybe_local($op, $cx, $self->stash_variable("\$",
2675                                  $self->gv_name($gv)));
2676 }
2677
2678 sub pp_gv {
2679     my $self = shift;
2680     my($op, $cx) = @_;
2681     my $gv = $self->gv_or_padgv($op);
2682     return $self->gv_name($gv);
2683 }
2684
2685 sub pp_aelemfast {
2686     my $self = shift;
2687     my($op, $cx) = @_;
2688     my $gv = $self->gv_or_padgv($op);
2689     my $name = $self->gv_name($gv);
2690     $name = $self->{'curstash'}."::$name"
2691         if $name !~ /::/ && $self->lex_in_scope('@'.$name);
2692
2693     return "\$" . $name . "[" .
2694                   ($op->private + $self->{'arybase'}) . "]";
2695 }
2696
2697 sub rv2x {
2698     my $self = shift;
2699     my($op, $cx, $type) = @_;
2700
2701     if (class($op) eq 'NULL' || !$op->can("first")) {
2702         carp("Unexpected op in pp_rv2x");
2703         return 'XXX';
2704     }
2705     my $kid = $op->first;
2706     if ($kid->name eq "gv") {
2707         return $self->stash_variable($type, $self->deparse($kid, 0));
2708     } elsif (is_scalar $kid) {
2709         my $str = $self->deparse($kid, 0);
2710         if ($str =~ /^\$([^\w\d])\z/) {
2711             # "$$+" isn't a legal way to write the scalar dereference
2712             # of $+, since the lexer can't tell you aren't trying to
2713             # do something like "$$ + 1" to get one more than your
2714             # PID. Either "${$+}" or "$${+}" are workable
2715             # disambiguations, but if the programmer did the former,
2716             # they'd be in the "else" clause below rather than here.
2717             # It's not clear if this should somehow be unified with
2718             # the code in dq and re_dq that also adds lexer
2719             # disambiguation braces.
2720             $str = '$' . "{$1}"; #'
2721         }
2722         return $type . $str;
2723     } else {
2724         return $type . "{" . $self->deparse($kid, 0) . "}";
2725     }
2726 }
2727
2728 sub pp_rv2sv { maybe_local(@_, rv2x(@_, "\$")) }
2729 sub pp_rv2hv { maybe_local(@_, rv2x(@_, "%")) }
2730 sub pp_rv2gv { maybe_local(@_, rv2x(@_, "*")) }
2731
2732 # skip rv2av
2733 sub pp_av2arylen {
2734     my $self = shift;
2735     my($op, $cx) = @_;
2736     if ($op->first->name eq "padav") {
2737         return $self->maybe_local($op, $cx, '$#' . $self->padany($op->first));
2738     } else {
2739         return $self->maybe_local($op, $cx,
2740                                   $self->rv2x($op->first, $cx, '$#'));
2741     }
2742 }
2743
2744 # skip down to the old, ex-rv2cv
2745 sub pp_rv2cv {
2746     my ($self, $op, $cx) = @_;
2747     if (!null($op->first) && $op->first->name eq 'null' &&
2748         $op->first->targ eq OP_LIST)
2749     {
2750         return $self->rv2x($op->first->first->sibling, $cx, "&")
2751     }
2752     else {
2753         return $self->rv2x($op, $cx, "")
2754     }
2755 }
2756
2757 sub list_const {
2758     my $self = shift;
2759     my($cx, @list) = @_;
2760     my @a = map $self->const($_, 6), @list;
2761     if (@a == 0) {
2762         return "()";
2763     } elsif (@a == 1) {
2764         return $a[0];
2765     } elsif ( @a > 2 and !grep(!/^-?\d+$/, @a)) {
2766         # collapse (-1,0,1,2) into (-1..2)
2767         my ($s, $e) = @a[0,-1];
2768         my $i = $s;
2769         return $self->maybe_parens("$s..$e", $cx, 9)
2770           unless grep $i++ != $_, @a;
2771     }
2772     return $self->maybe_parens(join(", ", @a), $cx, 6);
2773 }
2774
2775 sub pp_rv2av {
2776     my $self = shift;
2777     my($op, $cx) = @_;
2778     my $kid = $op->first;
2779     if ($kid->name eq "const") { # constant list
2780         my $av = $self->const_sv($kid);
2781         return $self->list_const($cx, $av->ARRAY);
2782     } else {
2783         return $self->maybe_local($op, $cx, $self->rv2x($op, $cx, "\@"));
2784     }
2785  }
2786
2787 sub is_subscriptable {
2788     my $op = shift;
2789     if ($op->name =~ /^[ahg]elem/) {
2790         return 1;
2791     } elsif ($op->name eq "entersub") {
2792         my $kid = $op->first;
2793         return 0 unless null $kid->sibling;
2794         $kid = $kid->first;
2795         $kid = $kid->sibling until null $kid->sibling;
2796         return 0 if is_scope($kid);
2797         $kid = $kid->first;
2798         return 0 if $kid->name eq "gv";
2799         return 0 if is_scalar($kid);
2800         return is_subscriptable($kid);
2801     } else {
2802         return 0;
2803     }
2804 }
2805
2806 sub elem {
2807     my $self = shift;
2808     my ($op, $cx, $left, $right, $padname) = @_;
2809     my($array, $idx) = ($op->first, $op->first->sibling);
2810     unless ($array->name eq $padname) { # Maybe this has been fixed
2811         $array = $array->first; # skip rv2av (or ex-rv2av in _53+)
2812     }
2813     if ($array->name eq $padname) {
2814         $array = $self->padany($array);
2815     } elsif (is_scope($array)) { # ${expr}[0]
2816         $array = "{" . $self->deparse($array, 0) . "}";
2817     } elsif ($array->name eq "gv") {
2818         $array = $self->gv_name($self->gv_or_padgv($array));
2819         if ($array !~ /::/) {
2820             my $prefix = ($left eq '[' ? '@' : '%');
2821             $array = $self->{curstash}.'::'.$array
2822                 if $self->lex_in_scope($prefix . $array);
2823         }
2824     } elsif (is_scalar $array) { # $x[0], $$x[0], ...
2825         $array = $self->deparse($array, 24);
2826     } else {
2827         # $x[20][3]{hi} or expr->[20]
2828         my $arrow = is_subscriptable($array) ? "" : "->";
2829         return $self->deparse($array, 24) . $arrow .
2830             $left . $self->deparse($idx, 1) . $right;
2831     }
2832     $idx = $self->deparse($idx, 1);
2833
2834     # Outer parens in an array index will confuse perl
2835     # if we're interpolating in a regular expression, i.e.
2836     # /$x$foo[(-1)]/ is *not* the same as /$x$foo[-1]/
2837     #
2838     # If $self->{parens}, then an initial '(' will
2839     # definitely be paired with a final ')'. If
2840     # !$self->{parens}, the misleading parens won't
2841     # have been added in the first place.
2842     #
2843     # [You might think that we could get "(...)...(...)"
2844     # where the initial and final parens do not match
2845     # each other. But we can't, because the above would
2846     # only happen if there's an infix binop between the
2847     # two pairs of parens, and *that* means that the whole
2848     # expression would be parenthesized as well.]
2849     #
2850     $idx =~ s/^\((.*)\)$/$1/ if $self->{'parens'};
2851
2852     # Hash-element braces will autoquote a bareword inside themselves.
2853     # We need to make sure that C<$hash{warn()}> doesn't come out as
2854     # C<$hash{warn}>, which has a quite different meaning. Currently
2855     # B::Deparse will always quote strings, even if the string was a
2856     # bareword in the original (i.e. the OPpCONST_BARE flag is ignored
2857     # for constant strings.) So we can cheat slightly here - if we see
2858     # a bareword, we know that it is supposed to be a function call.
2859     #
2860     $idx =~ s/^([A-Za-z_]\w*)$/$1()/;
2861
2862     return "\$" . $array . $left . $idx . $right;
2863 }
2864
2865 sub pp_aelem { maybe_local(@_, elem(@_, "[", "]", "padav")) }
2866 sub pp_helem { maybe_local(@_, elem(@_, "{", "}", "padhv")) }
2867
2868 sub pp_gelem {
2869     my $self = shift;
2870     my($op, $cx) = @_;
2871     my($glob, $part) = ($op->first, $op->last);
2872     $glob = $glob->first; # skip rv2gv
2873     $glob = $glob->first if $glob->name eq "rv2gv"; # this one's a bug
2874     my $scope = is_scope($glob);
2875     $glob = $self->deparse($glob, 0);
2876     $part = $self->deparse($part, 1);
2877     return "*" . ($scope ? "{$glob}" : $glob) . "{$part}";
2878 }
2879
2880 sub slice {
2881     my $self = shift;
2882     my ($op, $cx, $left, $right, $regname, $padname) = @_;
2883     my $last;
2884     my(@elems, $kid, $array, $list);
2885     if (class($op) eq "LISTOP") {
2886         $last = $op->last;
2887     } else { # ex-hslice inside delete()
2888         for ($kid = $op->first; !null $kid->sibling; $kid = $kid->sibling) {}
2889         $last = $kid;
2890     }
2891     $array = $last;
2892     $array = $array->first
2893         if $array->name eq $regname or $array->name eq "null";
2894     if (is_scope($array)) {
2895         $array = "{" . $self->deparse($array, 0) . "}";
2896     } elsif ($array->name eq $padname) {
2897         $array = $self->padany($array);
2898     } else {
2899         $array = $self->deparse($array, 24);
2900     }
2901     $kid = $op->first->sibling; # skip pushmark
2902     if ($kid->name eq "list") {
2903         $kid = $kid->first->sibling; # skip list, pushmark
2904         for (; !null $kid; $kid = $kid->sibling) {
2905             push @elems, $self->deparse($kid, 6);
2906         }
2907         $list = join(", ", @elems);
2908     } else {
2909         $list = $self->deparse($kid, 1);
2910     }
2911     return "\@" . $array . $left . $list . $right;
2912 }
2913
2914 sub pp_aslice { maybe_local(@_, slice(@_, "[", "]", "rv2av", "padav")) }
2915 sub pp_hslice { maybe_local(@_, slice(@_, "{", "}", "rv2hv", "padhv")) }
2916
2917 sub pp_lslice {
2918     my $self = shift;
2919     my($op, $cx) = @_;
2920     my $idx = $op->first;
2921     my $list = $op->last;
2922     my(@elems, $kid);
2923     $list = $self->deparse($list, 1);
2924     $idx = $self->deparse($idx, 1);
2925     return "($list)" . "[$idx]";
2926 }
2927
2928 sub want_scalar {
2929     my $op = shift;
2930     return ($op->flags & OPf_WANT) == OPf_WANT_SCALAR;
2931 }
2932
2933 sub want_list {
2934     my $op = shift;
2935     return ($op->flags & OPf_WANT) == OPf_WANT_LIST;
2936 }
2937
2938 sub method {
2939     my $self = shift;
2940     my($op, $cx) = @_;
2941     my $kid = $op->first->sibling; # skip pushmark
2942     my($meth, $obj, @exprs);
2943     if ($kid->name eq "list" and want_list $kid) {
2944         # When an indirect object isn't a bareword but the args are in
2945         # parens, the parens aren't part of the method syntax (the LLAFR
2946         # doesn't apply), but they make a list with OPf_PARENS set that
2947         # doesn't get flattened by the append_elem that adds the method,
2948         # making a (object, arg1, arg2, ...) list where the object
2949         # usually is. This can be distinguished from
2950         # `($obj, $arg1, $arg2)->meth()' (which is legal if $arg2 is an
2951         # object) because in the later the list is in scalar context
2952         # as the left side of -> always is, while in the former
2953         # the list is in list context as method arguments always are.
2954         # (Good thing there aren't method prototypes!)
2955         $meth = $kid->sibling;
2956         $kid = $kid->first->sibling; # skip pushmark
2957         $obj = $kid;
2958         $kid = $kid->sibling;
2959         for (; not null $kid; $kid = $kid->sibling) {
2960             push @exprs, $self->deparse($kid, 6);
2961         }
2962     } else {
2963         $obj = $kid;
2964         $kid = $kid->sibling;
2965         for (; !null ($kid->sibling) && $kid->name ne "method_named";
2966               $kid = $kid->sibling) {
2967             push @exprs, $self->deparse($kid, 6);
2968         }
2969         $meth = $kid;
2970     }
2971     $obj = $self->deparse($obj, 24);
2972     if ($meth->name eq "method_named") {
2973         $meth = $self->const_sv($meth)->PV;
2974     } else {
2975         $meth = $meth->first;
2976         if ($meth->name eq "const") {
2977             # As of 5.005_58, this case is probably obsoleted by the
2978             # method_named case above
2979             $meth = $self->const_sv($meth)->PV; # needs to be bare
2980         } else {
2981             $meth = $self->deparse($meth, 1);
2982         }
2983     }
2984     my $args = join(", ", @exprs);
2985     $kid = $obj . "->" . $meth;
2986     if (length $args) {
2987         return $kid . "(" . $args . ")"; # parens mandatory
2988     } else {
2989         return $kid;
2990     }
2991 }
2992
2993 # returns "&" if the prototype doesn't match the args,
2994 # or ("", $args_after_prototype_demunging) if it does.
2995 sub check_proto {
2996     my $self = shift;
2997     return "&" if $self->{'noproto'};
2998     my($proto, @args) = @_;
2999     my($arg, $real);
3000     my $doneok = 0;
3001     my @reals;
3002     # An unbackslashed @ or % gobbles up the rest of the args
3003     1 while $proto =~ s/(?<!\\)([@%])[^\]]+$/$1/;
3004     while ($proto) {
3005         $proto =~ s/^(\\?[\$\@&%*]|\\\[[\$\@&%*]+\]|;)//;
3006         my $chr = $1;
3007         if ($chr eq "") {
3008             return "&" if @args;
3009         } elsif ($chr eq ";") {
3010             $doneok = 1;
3011         } elsif ($chr eq "@" or $chr eq "%") {
3012             push @reals, map($self->deparse($_, 6), @args);
3013             @args = ();
3014         } else {
3015             $arg = shift @args;
3016             last unless $arg;
3017             if ($chr eq "\$") {
3018                 if (want_scalar $arg) {
3019                     push @reals, $self->deparse($arg, 6);
3020                 } else {
3021                     return "&";
3022                 }
3023             } elsif ($chr eq "&") {
3024                 if ($arg->name =~ /^(s?refgen|undef)$/) {
3025                     push @reals, $self->deparse($arg, 6);
3026                 } else {
3027                     return "&";
3028                 }
3029             } elsif ($chr eq "*") {
3030                 if ($arg->name =~ /^s?refgen$/
3031                     and $arg->first->first->name eq "rv2gv")
3032                   {
3033                       $real = $arg->first->first; # skip refgen, null
3034                       if ($real->first->name eq "gv") {
3035                           push @reals, $self->deparse($real, 6);
3036                       } else {
3037                           push @reals, $self->deparse($real->first, 6);
3038                       }
3039                   } else {
3040                       return "&";
3041                   }
3042             } elsif (substr($chr, 0, 1) eq "\\") {
3043                 $chr =~ tr/\\[]//d;
3044                 if ($arg->name =~ /^s?refgen$/ and
3045                     !null($real = $arg->first) and
3046                     ($chr =~ /\$/ && is_scalar($real->first)
3047                      or ($chr =~ /@/
3048                          && class($real->first->sibling) ne 'NULL'
3049                          && $real->first->sibling->name
3050                          =~ /^(rv2|pad)av$/)
3051                      or ($chr =~ /%/
3052                          && class($real->first->sibling) ne 'NULL'
3053                          && $real->first->sibling->name
3054                          =~ /^(rv2|pad)hv$/)
3055                      #or ($chr =~ /&/ # This doesn't work
3056                      #   && $real->first->name eq "rv2cv")
3057                      or ($chr =~ /\*/
3058                          && $real->first->name eq "rv2gv")))
3059                   {
3060                       push @reals, $self->deparse($real, 6);
3061                   } else {
3062                       return "&";
3063                   }
3064             }
3065        }
3066     }
3067     return "&" if $proto and !$doneok; # too few args and no `;'
3068     return "&" if @args;               # too many args
3069     return ("", join ", ", @reals);
3070 }
3071
3072 sub pp_entersub {
3073     my $self = shift;
3074     my($op, $cx) = @_;
3075     return $self->method($op, $cx) unless null $op->first->sibling;
3076     my $prefix = "";
3077     my $amper = "";
3078     my($kid, @exprs);
3079     if ($op->flags & OPf_SPECIAL && !($op->flags & OPf_MOD)) {
3080         $prefix = "do ";
3081     } elsif ($op->private & OPpENTERSUB_AMPER) {
3082         $amper = "&";
3083     }
3084     $kid = $op->first;
3085     $kid = $kid->first->sibling; # skip ex-list, pushmark
3086     for (; not null $kid->sibling; $kid = $kid->sibling) {
3087         push @exprs, $kid;
3088     }
3089     my $simple = 0;
3090     my $proto = undef;
3091     if (is_scope($kid)) {
3092         $amper = "&";
3093         $kid = "{" . $self->deparse($kid, 0) . "}";
3094     } elsif ($kid->first->name eq "gv") {
3095         my $gv = $self->gv_or_padgv($kid->first);
3096         if (class($gv->CV) ne "SPECIAL") {
3097             $proto = $gv->CV->PV if $gv->CV->FLAGS & SVf_POK;
3098         }
3099         $simple = 1; # only calls of named functions can be prototyped
3100         $kid = $self->deparse($kid, 24);
3101     } elsif (is_scalar ($kid->first) && $kid->first->name ne 'rv2cv') {
3102         $amper = "&";
3103         $kid = $self->deparse($kid, 24);
3104     } else {
3105         $prefix = "";
3106         my $arrow = is_subscriptable($kid->first) ? "" : "->";
3107         $kid = $self->deparse($kid, 24) . $arrow;
3108     }
3109
3110     # Doesn't matter how many prototypes there are, if
3111     # they haven't happened yet!
3112     my $declared;
3113     {
3114         no strict 'refs';
3115         no warnings 'uninitialized';
3116         $declared = exists $self->{'subs_declared'}{$kid}
3117             || (
3118                  defined &{ %{$self->{'curstash'}."::"}->{$kid} }
3119                  && !exists
3120                      $self->{'subs_deparsed'}{$self->{'curstash'}."::".$kid}
3121                  && defined prototype $self->{'curstash'}."::".$kid
3122                );
3123         if (!$declared && defined($proto)) {
3124             # Avoid "too early to check prototype" warning
3125             ($amper, $proto) = ('&');
3126         }
3127     }
3128
3129     my $args;
3130     if ($declared and defined $proto and not $amper) {
3131         ($amper, $args) = $self->check_proto($proto, @exprs);
3132         if ($amper eq "&") {
3133             $args = join(", ", map($self->deparse($_, 6), @exprs));
3134         }
3135     } else {
3136         $args = join(", ", map($self->deparse($_, 6), @exprs));
3137     }
3138     if ($prefix or $amper) {
3139         if ($op->flags & OPf_STACKED) {
3140             return $prefix . $amper . $kid . "(" . $args . ")";
3141         } else {
3142             return $prefix . $amper. $kid;
3143         }
3144     } else {
3145         # glob() invocations can be translated into calls of
3146         # CORE::GLOBAL::glob with a second parameter, a number.
3147         # Reverse this.
3148         if ($kid eq "CORE::GLOBAL::glob") {
3149             $kid = "glob";
3150             $args =~ s/\s*,[^,]+$//;
3151         }
3152
3153         # It's a syntax error to call CORE::GLOBAL::foo without a prefix,
3154         # so it must have been translated from a keyword call. Translate
3155         # it back.
3156         $kid =~ s/^CORE::GLOBAL:://;
3157
3158         my $dproto = defined($proto) ? $proto : "undefined";
3159         if (!$declared) {
3160             return "$kid(" . $args . ")";
3161         } elsif ($dproto eq "") {
3162             return $kid;
3163         } elsif ($dproto eq "\$" and is_scalar($exprs[0])) {
3164             # is_scalar is an excessively conservative test here:
3165             # really, we should be comparing to the precedence of the
3166             # top operator of $exprs[0] (ala unop()), but that would
3167             # take some major code restructuring to do right.
3168             return $self->maybe_parens_func($kid, $args, $cx, 16);
3169         } elsif ($dproto ne '$' and defined($proto) || $simple) { #'
3170             return $self->maybe_parens_func($kid, $args, $cx, 5);
3171         } else {
3172             return "$kid(" . $args . ")";
3173         }
3174     }
3175 }
3176
3177 sub pp_enterwrite { unop(@_, "write") }
3178
3179 # escape things that cause interpolation in double quotes,
3180 # but not character escapes
3181 sub uninterp {
3182     my($str) = @_;
3183     $str =~ s/(^|\G|[^\\])((?:\\\\)*)([\$\@]|\\[uUlLQE])/$1$2\\$3/g;
3184     return $str;
3185 }
3186
3187 {
3188 my $bal;
3189 BEGIN {
3190     use re "eval";
3191     # Matches any string which is balanced with respect to {braces}
3192     $bal = qr(
3193       (?:
3194         [^\\{}]
3195       | \\\\
3196       | \\[{}]
3197       | \{(??{$bal})\}
3198       )*
3199     )x;
3200 }
3201
3202 # the same, but treat $|, $), $( and $ at the end of the string differently
3203 sub re_uninterp {
3204     my($str) = @_;
3205
3206     $str =~ s/
3207           ( ^|\G                  # $1
3208           | [^\\]
3209           )
3210
3211           (                       # $2
3212             (?:\\\\)*
3213           )
3214
3215           (                       # $3
3216             (\(\?\??\{$bal\}\))   # $4
3217           | [\$\@]
3218             (?!\||\)|\(|$)
3219           | \\[uUlLQE]
3220           )
3221
3222         /defined($4) && length($4) ? "$1$2$4" : "$1$2\\$3"/xeg;
3223
3224     return $str;
3225 }
3226
3227 # This is for regular expressions with the /x modifier
3228 # We have to leave comments unmangled.
3229 sub re_uninterp_extended {
3230     my($str) = @_;
3231
3232     $str =~ s/
3233           ( ^|\G                  # $1
3234           | [^\\]
3235           )
3236
3237           (                       # $2
3238             (?:\\\\)*
3239           )
3240
3241           (                       # $3
3242             ( \(\?\??\{$bal\}\)   # $4  (skip over (?{}) and (??{}) blocks)
3243             | \#[^\n]*            #     (skip over comments)
3244             )
3245           | [\$\@]
3246             (?!\||\)|\(|$|\s)
3247           | \\[uUlLQE]
3248           )
3249
3250         /defined($4) && length($4) ? "$1$2$4" : "$1$2\\$3"/xeg;
3251
3252     return $str;
3253 }
3254 }
3255
3256 my %unctrl = # portable to to EBCDIC
3257     (
3258      "\c@" => '\c@',    # unused
3259      "\cA" => '\cA',
3260      "\cB" => '\cB',
3261      "\cC" => '\cC',
3262      "\cD" => '\cD',
3263      "\cE" => '\cE',
3264      "\cF" => '\cF',
3265      "\cG" => '\cG',
3266      "\cH" => '\cH',
3267      "\cI" => '\cI',
3268      "\cJ" => '\cJ',
3269      "\cK" => '\cK',
3270      "\cL" => '\cL',
3271      "\cM" => '\cM',
3272      "\cN" => '\cN',
3273      "\cO" => '\cO',
3274      "\cP" => '\cP',
3275      "\cQ" => '\cQ',
3276      "\cR" => '\cR',
3277      "\cS" => '\cS',
3278      "\cT" => '\cT',
3279      "\cU" => '\cU',
3280      "\cV" => '\cV',
3281      "\cW" => '\cW',
3282      "\cX" => '\cX',
3283      "\cY" => '\cY',
3284      "\cZ" => '\cZ',
3285      "\c[" => '\c[',    # unused
3286      "\c\\" => '\c\\',  # unused
3287      "\c]" => '\c]',    # unused
3288      "\c_" => '\c_',    # unused
3289     );
3290
3291 # character escapes, but not delimiters that might need to be escaped
3292 sub escape_str { # ASCII, UTF8
3293     my($str) = @_;
3294     $str =~ s/(.)/ord($1) > 255 ? sprintf("\\x{%x}", ord($1)) : $1/eg;
3295     $str =~ s/\a/\\a/g;
3296 #    $str =~ s/\cH/\\b/g; # \b means something different in a regex
3297     $str =~ s/\t/\\t/g;
3298     $str =~ s/\n/\\n/g;
3299     $str =~ s/\e/\\e/g;
3300     $str =~ s/\f/\\f/g;
3301     $str =~ s/\r/\\r/g;
3302     $str =~ s/([\cA-\cZ])/$unctrl{$1}/ge;
3303     $str =~ s/([[:^print:]])/sprintf("\\%03o", ord($1))/ge;
3304     return $str;
3305 }
3306
3307 # For regexes with the /x modifier.
3308 # Leave whitespace unmangled.
3309 sub escape_extended_re {
3310     my($str) = @_;
3311     $str =~ s/(.)/ord($1) > 255 ? sprintf("\\x{%x}", ord($1)) : $1/eg;
3312     $str =~ s/([[:^print:]])/
3313         ($1 =~ y! \t\n!!) ? $1 : sprintf("\\%03o", ord($1))/ge;
3314     $str =~ s/\n/\n\f/g;
3315     return $str;
3316 }
3317
3318 # Don't do this for regexen
3319 sub unback {
3320     my($str) = @_;
3321     $str =~ s/\\/\\\\/g;
3322     return $str;
3323 }
3324
3325 # Remove backslashes which precede literal control characters,
3326 # to avoid creating ambiguity when we escape the latter.
3327 sub re_unback {
3328     my($str) = @_;
3329
3330     # the insane complexity here is due to the behaviour of "\c\"
3331     $str =~ s/(^|[^\\]|\\c\\)(?<!\\c)\\(\\\\)*(?=[[:^print:]])/$1$2/g;
3332     return $str;
3333 }
3334
3335 sub balanced_delim {
3336     my($str) = @_;
3337     my @str = split //, $str;
3338     my($ar, $open, $close, $fail, $c, $cnt);
3339     for $ar (['[',']'], ['(',')'], ['<','>'], ['{','}']) {
3340         ($open, $close) = @$ar;
3341         $fail = 0; $cnt = 0;
3342         for $c (@str) {
3343             if ($c eq $open) {
3344                 $cnt++;
3345             } elsif ($c eq $close) {
3346                 $cnt--;
3347                 if ($cnt < 0) {
3348                     # qq()() isn't ")("
3349                     $fail = 1;
3350                     last;
3351                 }
3352             }
3353         }
3354         $fail = 1 if $cnt != 0;
3355         return ($open, "$open$str$close") if not $fail;
3356     }
3357     return ("", $str);
3358 }
3359
3360 sub single_delim {
3361     my($q, $default, $str) = @_;
3362     return "$default$str$default" if $default and index($str, $default) == -1;
3363     if ($q ne 'qr') {
3364         (my $succeed, $str) = balanced_delim($str);
3365         return "$q$str" if $succeed;
3366     }
3367     for my $delim ('/', '"', '#') {
3368         return "$q$delim" . $str . $delim if index($str, $delim) == -1;
3369     }
3370     if ($default) {
3371         $str =~ s/$default/\\$default/g;
3372         return "$default$str$default";
3373     } else {
3374         $str =~ s[/][\\/]g;
3375         return "$q/$str/";
3376     }
3377 }
3378
3379 my $max_prec;
3380 BEGIN { $max_prec = int(0.999 + 8*length(pack("F", 42))*log(2)/log(10)); }
3381
3382 # Split a floating point number into an integer mantissa and a binary
3383 # exponent. Assumes you've already made sure the number isn't zero or
3384 # some weird infinity or NaN.
3385 sub split_float {
3386     my($f) = @_;
3387     my $exponent = 0;
3388     if ($f == int($f)) {
3389         while ($f % 2 == 0) {
3390             $f /= 2;
3391             $exponent++;
3392         }
3393     } else {
3394         while ($f != int($f)) {
3395             $f *= 2;
3396             $exponent--;
3397         }
3398     }
3399     my $mantissa = sprintf("%.0f", $f);
3400     return ($mantissa, $exponent);
3401 }
3402
3403 sub const {
3404     my $self = shift;
3405     my($sv, $cx) = @_;
3406     if ($self->{'use_dumper'}) {
3407         return $self->const_dumper($sv, $cx);
3408     }
3409     if (class($sv) eq "SPECIAL") {
3410         # sv_undef, sv_yes, sv_no
3411         return ('undef', '1', $self->maybe_parens("!1", $cx, 21))[$$sv-1];
3412     } elsif (class($sv) eq "NULL") {
3413        return 'undef';
3414     }
3415     # convert a version object into the "v1.2.3" string in its V magic
3416     if ($sv->FLAGS & SVs_RMG) {
3417         for (my $mg = $sv->MAGIC; $mg; $mg = $mg->MOREMAGIC) {
3418             return $mg->PTR if $mg->TYPE eq 'V';
3419         }
3420     }
3421
3422     if ($sv->FLAGS & SVf_IOK) {
3423         my $str = $sv->int_value;
3424         $str = $self->maybe_parens($str, $cx, 21) if $str < 0;
3425         return $str;
3426     } elsif ($sv->FLAGS & SVf_NOK) {
3427         my $nv = $sv->NV;
3428         if ($nv == 0) {
3429             if (pack("F", $nv) eq pack("F", 0)) {
3430                 # positive zero
3431                 return "0";
3432             } else {
3433                 # negative zero
3434                 return $self->maybe_parens("-.0", $cx, 21);
3435             }
3436         } elsif (1/$nv == 0) {
3437             if ($nv > 0) {
3438                 # positive infinity
3439                 return $self->maybe_parens("9**9**9", $cx, 22);
3440             } else {
3441                 # negative infinity
3442                 return $self->maybe_parens("-9**9**9", $cx, 21);
3443             }
3444         } elsif ($nv != $nv) {
3445             # NaN
3446             if (pack("F", $nv) eq pack("F", sin(9**9**9))) {
3447                 # the normal kind
3448                 return "sin(9**9**9)";
3449             } elsif (pack("F", $nv) eq pack("F", -sin(9**9**9))) {
3450                 # the inverted kind
3451                 return $self->maybe_parens("-sin(9**9**9)", $cx, 21);
3452             } else {
3453                 # some other kind
3454                 my $hex = unpack("h*", pack("F", $nv));
3455                 return qq'unpack("F", pack("h*", "$hex"))';
3456             }
3457         }
3458         # first, try the default stringification
3459         my $str = "$nv";
3460         if ($str != $nv) {
3461             # failing that, try using more precision
3462             $str = sprintf("%.${max_prec}g", $nv);
3463 #           if (pack("F", $str) ne pack("F", $nv)) {
3464             if ($str != $nv) {
3465                 # not representable in decimal with whatever sprintf()
3466                 # and atof() Perl is using here.
3467                 my($mant, $exp) = split_float($nv);
3468                 return $self->maybe_parens("$mant * 2**$exp", $cx, 19);
3469             }
3470         }
3471         $str = $self->maybe_parens($str, $cx, 21) if $nv < 0;
3472         return $str;
3473     } elsif ($sv->FLAGS & SVf_ROK && $sv->can("RV")) {
3474         my $ref = $sv->RV;
3475         if (class($ref) eq "AV") {
3476             return "[" . $self->list_const(2, $ref->ARRAY) . "]";
3477         } elsif (class($ref) eq "HV") {
3478             my %hash = $ref->ARRAY;
3479             my @elts;
3480             for my $k (sort keys %hash) {
3481                 push @elts, "$k => " . $self->const($hash{$k}, 6);
3482             }
3483             return "{" . join(", ", @elts) . "}";
3484         } elsif (class($ref) eq "CV") {
3485             return "sub " . $self->deparse_sub($ref);
3486         }
3487         if ($ref->FLAGS & SVs_SMG) {
3488             for (my $mg = $ref->MAGIC; $mg; $mg = $mg->MOREMAGIC) {
3489                 if ($mg->TYPE eq 'r') {
3490                     my $re = re_uninterp(escape_str(re_unback($mg->precomp)));
3491                     return single_delim("qr", "", $re);
3492                 }
3493             }
3494         }
3495
3496         return $self->maybe_parens("\\" . $self->const($ref, 20), $cx, 20);
3497     } elsif ($sv->FLAGS & SVf_POK) {
3498         my $str = $sv->PV;
3499         if ($str =~ /[^ -~]/) { # ASCII for non-printing
3500             return single_delim("qq", '"', uninterp escape_str unback $str);
3501         } else {
3502             return single_delim("q", "'", unback $str);
3503         }
3504     } else {
3505         return "undef";
3506     }
3507 }
3508
3509 sub const_dumper {
3510     my $self = shift;
3511     my($sv, $cx) = @_;
3512     my $ref = $sv->object_2svref();
3513     my $dumper = Data::Dumper->new([$$ref], ['$v']);
3514     $dumper->Purity(1)->Terse(1)->Deparse(1)->Indent(0)->Useqq(1)->Sortkeys(1);
3515     my $str = $dumper->Dump();
3516     if ($str =~ /^\$v/) {
3517         return '${my ' . $str . ' \$v}';
3518     } else {
3519         return $str;
3520     }
3521 }
3522
3523 sub const_sv {
3524     my $self = shift;
3525     my $op = shift;
3526     my $sv = $op->sv;
3527     # the constant could be in the pad (under useithreads)
3528     $sv = $self->padval($op->targ) unless $$sv;
3529     return $sv;
3530 }
3531
3532 sub pp_const {
3533     my $self = shift;
3534     my($op, $cx) = @_;
3535     if ($op->private & OPpCONST_ARYBASE) {
3536         return '$[';
3537     }
3538 #    if ($op->private & OPpCONST_BARE) { # trouble with `=>' autoquoting
3539 #       return $self->const_sv($op)->PV;
3540 #    }
3541     my $sv = $self->const_sv($op);
3542     return $self->const($sv, $cx);
3543 }
3544
3545 sub dq {
3546     my $self = shift;
3547     my $op = shift;
3548     my $type = $op->name;
3549     if ($type eq "const") {
3550         return '$[' if $op->private & OPpCONST_ARYBASE;
3551         return uninterp(escape_str(unback($self->const_sv($op)->as_string)));
3552     } elsif ($type eq "concat") {
3553         my $first = $self->dq($op->first);
3554         my $last  = $self->dq($op->last);
3555
3556         # Disambiguate "${foo}bar", "${foo}{bar}", "${foo}[1]", "$foo\::bar"
3557         ($last =~ /^[A-Z\\\^\[\]_?]/ &&
3558             $first =~ s/([\$@])\^$/${1}{^}/)  # "${^}W" etc
3559             || ($last =~ /^[:'{\[\w_]/ && #'
3560                 $first =~ s/([\$@])([A-Za-z_]\w*)$/${1}{$2}/);
3561
3562         return $first . $last;
3563     } elsif ($type eq "uc") {
3564         return '\U' . $self->dq($op->first->sibling) . '\E';
3565     } elsif ($type eq "lc") {
3566         return '\L' . $self->dq($op->first->sibling) . '\E';
3567     } elsif ($type eq "ucfirst") {
3568         return '\u' . $self->dq($op->first->sibling);
3569     } elsif ($type eq "lcfirst") {
3570         return '\l' . $self->dq($op->first->sibling);
3571     } elsif ($type eq "quotemeta") {
3572         return '\Q' . $self->dq($op->first->sibling) . '\E';
3573     } elsif ($type eq "join") {
3574         return $self->deparse($op->last, 26); # was join($", @ary)
3575     } else {
3576         return $self->deparse($op, 26);
3577     }
3578 }
3579
3580 sub pp_backtick {
3581     my $self = shift;
3582     my($op, $cx) = @_;
3583     # skip pushmark
3584     return single_delim("qx", '`', $self->dq($op->first->sibling));
3585 }
3586
3587 sub dquote {
3588     my $self = shift;
3589     my($op, $cx) = @_;
3590     my $kid = $op->first->sibling; # skip ex-stringify, pushmark
3591     return $self->deparse($kid, $cx) if $self->{'unquote'};
3592     $self->maybe_targmy($kid, $cx,
3593                         sub {single_delim("qq", '"', $self->dq($_[1]))});
3594 }
3595
3596 # OP_STRINGIFY is a listop, but it only ever has one arg
3597 sub pp_stringify { maybe_targmy(@_, \&dquote) }
3598
3599 # tr/// and s/// (and tr[][], tr[]//, tr###, etc)
3600 # note that tr(from)/to/ is OK, but not tr/from/(to)
3601 sub double_delim {
3602     my($from, $to) = @_;
3603     my($succeed, $delim);
3604     if ($from !~ m[/] and $to !~ m[/]) {
3605         return "/$from/$to/";
3606     } elsif (($succeed, $from) = balanced_delim($from) and $succeed) {
3607         if (($succeed, $to) = balanced_delim($to) and $succeed) {
3608             return "$from$to";
3609         } else {
3610             for $delim ('/', '"', '#') { # note no `'' -- s''' is special
3611                 return "$from$delim$to$delim" if index($to, $delim) == -1;
3612             }
3613             $to =~ s[/][\\/]g;
3614             return "$from/$to/";
3615         }
3616     } else {
3617         for $delim ('/', '"', '#') { # note no '
3618             return "$delim$from$delim$to$delim"
3619                 if index($to . $from, $delim) == -1;
3620         }
3621         $from =~ s[/][\\/]g;
3622         $to =~ s[/][\\/]g;
3623         return "/$from/$to/";
3624     }
3625 }
3626
3627 # Only used by tr///, so backslashes hyphens
3628 sub pchr { # ASCII
3629     my($n) = @_;
3630     if ($n == ord '\\') {
3631         return '\\\\';
3632     } elsif ($n == ord "-") {
3633         return "\\-";
3634     } elsif ($n >= ord(' ') and $n <= ord('~')) {
3635         return chr($n);
3636     } elsif ($n == ord "\a") {
3637         return '\\a';
3638     } elsif ($n == ord "\b") {
3639         return '\\b';
3640     } elsif ($n == ord "\t") {
3641         return '\\t';
3642     } elsif ($n == ord "\n") {
3643         return '\\n';
3644     } elsif ($n == ord "\e") {
3645         return '\\e';
3646     } elsif ($n == ord "\f") {
3647         return '\\f';
3648     } elsif ($n == ord "\r") {
3649         return '\\r';
3650     } elsif ($n >= ord("\cA") and $n <= ord("\cZ")) {
3651         return '\\c' . chr(ord("@") + $n);
3652     } else {
3653 #       return '\x' . sprintf("%02x", $n);
3654         return '\\' . sprintf("%03o", $n);
3655     }
3656 }
3657
3658 sub collapse {
3659     my(@chars) = @_;
3660     my($str, $c, $tr) = ("");
3661     for ($c = 0; $c < @chars; $c++) {
3662         $tr = $chars[$c];
3663         $str .= pchr($tr);
3664         if ($c <= $#chars - 2 and $chars[$c + 1] == $tr + 1 and
3665             $chars[$c + 2] == $tr + 2)
3666         {
3667             for (; $c <= $#chars-1 and $chars[$c + 1] == $chars[$c] + 1; $c++)
3668               {}
3669             $str .= "-";
3670             $str .= pchr($chars[$c]);
3671         }
3672     }
3673     return $str;
3674 }
3675
3676 sub tr_decode_byte {
3677     my($table, $flags) = @_;
3678     my(@table) = unpack("s*", $table);
3679     splice @table, 0x100, 1;   # Number of subsequent elements
3680     my($c, $tr, @from, @to, @delfrom, $delhyphen);
3681     if ($table[ord "-"] != -1 and
3682         $table[ord("-") - 1] == -1 || $table[ord("-") + 1] == -1)
3683     {
3684         $tr = $table[ord "-"];
3685         $table[ord "-"] = -1;
3686         if ($tr >= 0) {
3687             @from = ord("-");
3688             @to = $tr;
3689         } else { # -2 ==> delete
3690             $delhyphen = 1;
3691         }
3692     }
3693     for ($c = 0; $c < @table; $c++) {
3694         $tr = $table[$c];
3695         if ($tr >= 0) {
3696             push @from, $c; push @to, $tr;
3697         } elsif ($tr == -2) {
3698             push @delfrom, $c;
3699         }
3700     }
3701     @from = (@from, @delfrom);
3702     if ($flags & OPpTRANS_COMPLEMENT) {
3703         my @newfrom = ();
3704         my %from;
3705         @from{@from} = (1) x @from;
3706         for ($c = 0; $c < 256; $c++) {
3707             push @newfrom, $c unless $from{$c};
3708         }
3709         @from = @newfrom;
3710     }
3711     unless ($flags & OPpTRANS_DELETE || !@to) {
3712         pop @to while $#to and $to[$#to] == $to[$#to -1];
3713     }
3714     my($from, $to);
3715     $from = collapse(@from);
3716     $to = collapse(@to);
3717     $from .= "-" if $delhyphen;
3718     return ($from, $to);
3719 }
3720
3721 sub tr_chr {
3722     my $x = shift;
3723     if ($x == ord "-") {
3724         return "\\-";
3725     } elsif ($x == ord "\\") {
3726         return "\\\\";
3727     } else {
3728         return chr $x;
3729     }
3730 }
3731
3732 # XXX This doesn't yet handle all cases correctly either
3733
3734 sub tr_decode_utf8 {
3735     my($swash_hv, $flags) = @_;
3736     my %swash = $swash_hv->ARRAY;
3737     my $final = undef;
3738     $final = $swash{'FINAL'}->IV if exists $swash{'FINAL'};
3739     my $none = $swash{"NONE"}->IV;
3740     my $extra = $none + 1;
3741     my(@from, @delfrom, @to);
3742     my $line;
3743     foreach $line (split /\n/, $swash{'LIST'}->PV) {
3744         my($min, $max, $result) = split(/\t/, $line);
3745         $min = hex $min;
3746         if (length $max) {
3747             $max = hex $max;
3748         } else {
3749             $max = $min;
3750         }
3751         $result = hex $result;
3752         if ($result == $extra) {
3753             push @delfrom, [$min, $max];
3754         } else {
3755             push @from, [$min, $max];
3756             push @to, [$result, $result + $max - $min];
3757         }
3758     }
3759     for my $i (0 .. $#from) {
3760         if ($from[$i][0] == ord '-') {
3761             unshift @from, splice(@from, $i, 1);
3762             unshift @to, splice(@to, $i, 1);
3763             last;
3764         } elsif ($from[$i][1] == ord '-') {
3765             $from[$i][1]--;
3766             $to[$i][1]--;
3767             unshift @from, ord '-';
3768             unshift @to, ord '-';
3769             last;
3770         }
3771     }
3772     for my $i (0 .. $#delfrom) {
3773         if ($delfrom[$i][0] == ord '-') {
3774             push @delfrom, splice(@delfrom, $i, 1);
3775             last;
3776         } elsif ($delfrom[$i][1] == ord '-') {
3777             $delfrom[$i][1]--;
3778             push @delfrom, ord '-';
3779             last;
3780         }
3781     }
3782     if (defined $final and $to[$#to][1] != $final) {
3783         push @to, [$final, $final];
3784     }
3785     push @from, @delfrom;
3786     if ($flags & OPpTRANS_COMPLEMENT) {
3787         my @newfrom;
3788         my $next = 0;
3789         for my $i (0 .. $#from) {
3790             push @newfrom, [$next, $from[$i][0] - 1];
3791             $next = $from[$i][1] + 1;
3792         }
3793         @from = ();
3794         for my $range (@newfrom) {
3795             if ($range->[0] <= $range->[1]) {
3796                 push @from, $range;
3797             }
3798         }
3799     }
3800     my($from, $to, $diff);
3801     for my $chunk (@from) {
3802         $diff = $chunk->[1] - $chunk->[0];
3803         if ($diff > 1) {
3804             $from .= tr_chr($chunk->[0]) . "-" . tr_chr($chunk->[1]);
3805         } elsif ($diff == 1) {
3806             $from .= tr_chr($chunk->[0]) . tr_chr($chunk->[1]);
3807         } else {
3808             $from .= tr_chr($chunk->[0]);
3809         }
3810     }
3811     for my $chunk (@to) {
3812         $diff = $chunk->[1] - $chunk->[0];
3813         if ($diff > 1) {
3814             $to .= tr_chr($chunk->[0]) . "-" . tr_chr($chunk->[1]);
3815         } elsif ($diff == 1) {
3816             $to .= tr_chr($chunk->[0]) . tr_chr($chunk->[1]);
3817         } else {
3818             $to .= tr_chr($chunk->[0]);
3819         }
3820     }
3821     #$final = sprintf("%04x", $final) if defined $final;
3822     #$none = sprintf("%04x", $none) if defined $none;
3823     #$extra = sprintf("%04x", $extra) if defined $extra;
3824     #print STDERR "final: $final\n none: $none\nextra: $extra\n";
3825     #print STDERR $swash{'LIST'}->PV;
3826     return (escape_str($from), escape_str($to));
3827 }
3828
3829 sub pp_trans {
3830     my $self = shift;
3831     my($op, $cx) = @_;
3832     my($from, $to);
3833     if (class($op) eq "PVOP") {
3834         ($from, $to) = tr_decode_byte($op->pv, $op->private);
3835     } else { # class($op) eq "SVOP"
3836         ($from, $to) = tr_decode_utf8($op->sv->RV, $op->private);
3837     }
3838     my $flags = "";
3839     $flags .= "c" if $op->private & OPpTRANS_COMPLEMENT;
3840     $flags .= "d" if $op->private & OPpTRANS_DELETE;
3841     $to = "" if $from eq $to and $flags eq "";
3842     $flags .= "s" if $op->private & OPpTRANS_SQUASH;
3843     return "tr" . double_delim($from, $to) . $flags;
3844 }
3845
3846 # Like dq(), but different
3847 sub re_dq {
3848     my $self = shift;
3849     my ($op, $extended) = @_;
3850
3851     my $type = $op->name;
3852     if ($type eq "const") {
3853         return '$[' if $op->private & OPpCONST_ARYBASE;
3854         my $unbacked = re_unback($self->const_sv($op)->as_string);
3855         return re_uninterp_extended(escape_extended_re($unbacked))
3856             if $extended;
3857         return re_uninterp(escape_str($unbacked));
3858     } elsif ($type eq "concat") {
3859         my $first = $self->re_dq($op->first, $extended);
3860         my $last  = $self->re_dq($op->last,  $extended);
3861
3862         # Disambiguate "${foo}bar", "${foo}{bar}", "${foo}[1]"
3863         ($last =~ /^[A-Z\\\^\[\]_?]/ &&
3864             $first =~ s/([\$@])\^$/${1}{^}/)  # "${^}W" etc
3865             || ($last =~ /^[{\[\w_]/ &&
3866                 $first =~ s/([\$@])([A-Za-z_]\w*)$/${1}{$2}/);
3867
3868         return $first . $last;
3869     } elsif ($type eq "uc") {
3870         return '\U' . $self->re_dq($op->first->sibling, $extended) . '\E';
3871     } elsif ($type eq "lc") {
3872         return '\L' . $self->re_dq($op->first->sibling, $extended) . '\E';
3873     } elsif ($type eq "ucfirst") {
3874         return '\u' . $self->re_dq($op->first->sibling, $extended);
3875     } elsif ($type eq "lcfirst") {
3876         return '\l' . $self->re_dq($op->first->sibling, $extended);
3877     } elsif ($type eq "quotemeta") {
3878         return '\Q' . $self->re_dq($op->first->sibling, $extended) . '\E';
3879     } elsif ($type eq "join") {
3880         return $self->deparse($op->last, 26); # was join($", @ary)
3881     } else {
3882         return $self->deparse($op, 26);
3883     }
3884 }
3885
3886 sub pure_string {
3887     my ($self, $op) = @_;
3888     return 0 if null $op;
3889     my $type = $op->name;
3890
3891     if ($type eq 'const') {
3892         return 1;
3893     }
3894     elsif ($type =~ /^[ul]c(first)?$/ || $type eq 'quotemeta') {
3895         return $self->pure_string($op->first->sibling);
3896     }
3897     elsif ($type eq 'join') {
3898         my $join_op = $op->first->sibling;  # Skip pushmark
3899         return 0 unless $join_op->name eq 'null' && $join_op->targ eq OP_RV2SV;
3900
3901         my $gvop = $join_op->first;
3902         return 0 unless $gvop->name eq 'gvsv';
3903         return 0 unless '"' eq $self->gv_name($self->gv_or_padgv($gvop));
3904
3905         return 0 unless ${$join_op->sibling} eq ${$op->last};
3906         return 0 unless $op->last->name =~ /^(rv2|pad)av$/;
3907     }
3908     elsif ($type eq 'concat') {
3909         return $self->pure_string($op->first)
3910             && $self->pure_string($op->last);
3911     }
3912     elsif (is_scalar($op) || $type =~ /^[ah]elem$/) {
3913         return 1;
3914     }
3915     elsif ($type eq "null" and $op->can('first') and not null $op->first and
3916            $op->first->name eq "null" and $op->first->can('first')
3917            and not null $op->first->first and
3918            $op->first->first->name eq "aelemfast") {
3919         return 1;
3920     }
3921     else {
3922         return 0;
3923     }
3924
3925     return 1;
3926 }
3927
3928 sub regcomp {
3929     my $self = shift;
3930     my($op, $cx, $extended) = @_;
3931     my $kid = $op->first;
3932     $kid = $kid->first if $kid->name eq "regcmaybe";
3933     $kid = $kid->first if $kid->name eq "regcreset";
3934     return ($self->re_dq($kid, $extended), 1) if $self->pure_string($kid);
3935     return ($self->deparse($kid, $cx), 0);
3936 }
3937
3938 sub pp_regcomp {
3939     my ($self, $op, $cx) = @_;
3940     return (($self->regcomp($op, $cx, 0))[0]);
3941 }
3942
3943 # osmic acid -- see osmium tetroxide
3944
3945 my %matchwords;
3946 map($matchwords{join "", sort split //, $_} = $_, 'cig', 'cog', 'cos', 'cogs',
3947     'cox', 'go', 'is', 'ism', 'iso', 'mig', 'mix', 'osmic', 'ox', 'sic',
3948     'sig', 'six', 'smog', 'so', 'soc', 'sog', 'xi');
3949
3950 sub matchop {
3951     my $self = shift;
3952     my($op, $cx, $name, $delim) = @_;
3953     my $kid = $op->first;
3954     my ($binop, $var, $re) = ("", "", "");
3955     if ($op->flags & OPf_STACKED) {
3956         $binop = 1;
3957         $var = $self->deparse($kid, 20);
3958         $kid = $kid->sibling;
3959     }
3960     my $quote = 1;
3961     my $extended = ($op->pmflags & PMf_EXTENDED);
3962     if (null $kid) {
3963         my $unbacked = re_unback($op->precomp);
3964         if ($extended) {
3965             $re = re_uninterp_extended(escape_extended_re($unbacked));
3966         } else {
3967             $re = re_uninterp(escape_str(re_unback($op->precomp)));
3968         }
3969     } elsif ($kid->name ne 'regcomp') {
3970         carp("found ".$kid->name." where regcomp expected");
3971     } else {
3972         ($re, $quote) = $self->regcomp($kid, 21, $extended);
3973     }
3974     my $flags = "";
3975     $flags .= "c" if $op->pmflags & PMf_CONTINUE;
3976     $flags .= "g" if $op->pmflags & PMf_GLOBAL;
3977     $flags .= "i" if $op->pmflags & PMf_FOLD;
3978     $flags .= "m" if $op->pmflags & PMf_MULTILINE;
3979     $flags .= "o" if $op->pmflags & PMf_KEEP;
3980     $flags .= "s" if $op->pmflags & PMf_SINGLELINE;
3981     $flags .= "x" if $op->pmflags & PMf_EXTENDED;
3982     $flags = $matchwords{$flags} if $matchwords{$flags};
3983     if ($op->pmflags & PMf_ONCE) { # only one kind of delimiter works here
3984         $re =~ s/\?/\\?/g;
3985         $re = "?$re?";
3986     } elsif ($quote) {
3987         $re = single_delim($name, $delim, $re);
3988     }
3989     $re = $re . $flags if $quote;
3990     if ($binop) {
3991         return $self->maybe_parens("$var =~ $re", $cx, 20);
3992     } else {
3993         return $re;
3994     }
3995 }
3996
3997 sub pp_match { matchop(@_, "m", "/") }
3998 sub pp_pushre { matchop(@_, "m", "/") }
3999 sub pp_qr { matchop(@_, "qr", "") }
4000
4001 sub pp_split {
4002     my $self = shift;
4003     my($op, $cx) = @_;
4004     my($kid, @exprs, $ary, $expr);
4005     $kid = $op->first;
4006
4007     # For our kid (an OP_PUSHRE), pmreplroot is never actually the
4008     # root of a replacement; it's either empty, or abused to point to
4009     # the GV for an array we split into (an optimization to save
4010     # assignment overhead). Depending on whether we're using ithreads,
4011     # this OP* holds either a GV* or a PADOFFSET. Luckily, B.xs
4012     # figures out for us which it is.
4013     my $replroot = $kid->pmreplroot;
4014     my $gv = 0;
4015     if (ref($replroot) eq "B::GV") {
4016         $gv = $replroot;
4017     } elsif (!ref($replroot) and $replroot > 0) {
4018         $gv = $self->padval($replroot);
4019     }
4020     $ary = $self->stash_variable('@', $self->gv_name($gv)) if $gv;
4021
4022     for (; !null($kid); $kid = $kid->sibling) {
4023         push @exprs, $self->deparse($kid, 6);
4024     }
4025
4026     # handle special case of split(), and split(" ") that compiles to /\s+/
4027     $kid = $op->first;
4028     if ($kid->flags & OPf_SPECIAL
4029         && $exprs[0] eq '/\\s+/'
4030         && $kid->pmflags & PMf_SKIPWHITE ) {
4031             $exprs[0] = '" "';
4032     }
4033
4034     $expr = "split(" . join(", ", @exprs) . ")";
4035     if ($ary) {
4036         return $self->maybe_parens("$ary = $expr", $cx, 7);
4037     } else {
4038         return $expr;
4039     }
4040 }
4041
4042 # oxime -- any of various compounds obtained chiefly by the action of
4043 # hydroxylamine on aldehydes and ketones and characterized by the
4044 # bivalent grouping C=NOH [Webster's Tenth]
4045
4046 my %substwords;
4047 map($substwords{join "", sort split //, $_} = $_, 'ego', 'egoism', 'em',
4048     'es', 'ex', 'exes', 'gee', 'go', 'goes', 'ie', 'ism', 'iso', 'me',
4049     'meese', 'meso', 'mig', 'mix', 'os', 'ox', 'oxime', 'see', 'seem',
4050     'seg', 'sex', 'sig', 'six', 'smog', 'sog', 'some', 'xi');
4051
4052 sub pp_subst {
4053     my $self = shift;
4054     my($op, $cx) = @_;
4055     my $kid = $op->first;
4056     my($binop, $var, $re, $repl) = ("", "", "", "");
4057     if ($op->flags & OPf_STACKED) {
4058         $binop = 1;
4059         $var = $self->deparse($kid, 20);
4060         $kid = $kid->sibling;
4061     }
4062     my $flags = "";
4063     if (null($op->pmreplroot)) {
4064         $repl = $self->dq($kid);
4065         $kid = $kid->sibling;
4066     } else {
4067         $repl = $op->pmreplroot->first; # skip substcont
4068         while ($repl->name eq "entereval") {
4069             $repl = $repl->first;
4070             $flags .= "e";
4071         }
4072         if ($op->pmflags & PMf_EVAL) {
4073             $repl = $self->deparse($repl->first, 0);
4074         } else {
4075             $repl = $self->dq($repl);
4076         }
4077     }
4078     my $extended = ($op->pmflags & PMf_EXTENDED);
4079     if (null $kid) {
4080         my $unbacked = re_unback($op->precomp);
4081         if ($extended) {
4082             $re = re_uninterp_extended(escape_extended_re($unbacked));
4083         }
4084         else {
4085             $re = re_uninterp(escape_str($unbacked));
4086         }
4087     } else {
4088         ($re) = $self->regcomp($kid, 1, $extended);
4089     }
4090     $flags .= "e" if $op->pmflags & PMf_EVAL;
4091     $flags .= "g" if $op->pmflags & PMf_GLOBAL;
4092     $flags .= "i" if $op->pmflags & PMf_FOLD;
4093     $flags .= "m" if $op->pmflags & PMf_MULTILINE;
4094     $flags .= "o" if $op->pmflags & PMf_KEEP;
4095     $flags .= "s" if $op->pmflags & PMf_SINGLELINE;
4096     $flags .= "x" if $extended;
4097     $flags = $substwords{$flags} if $substwords{$flags};
4098     if ($binop) {
4099         return $self->maybe_parens("$var =~ s"
4100                                    . double_delim($re, $repl) . $flags,
4101                                    $cx, 20);
4102     } else {
4103         return "s". double_delim($re, $repl) . $flags;
4104     }
4105 }
4106
4107 1;
4108 __END__
4109
4110 =head1 NAME
4111
4112 B::Deparse - Perl compiler backend to produce perl code
4113
4114 =head1 SYNOPSIS
4115
4116 B<perl> B<-MO=Deparse>[B<,-d>][B<,-f>I<FILE>][B<,-p>][B<,-q>][B<,-l>]
4117         [B<,-s>I<LETTERS>][B<,-x>I<LEVEL>] I<prog.pl>
4118
4119 =head1 DESCRIPTION
4120
4121 B::Deparse is a backend module for the Perl compiler that generates
4122 perl source code, based on the internal compiled structure that perl
4123 itself creates after parsing a program. The output of B::Deparse won't
4124 be exactly the same as the original source, since perl doesn't keep
4125 track of comments or whitespace, and there isn't a one-to-one
4126 correspondence between perl's syntactical constructions and their
4127 compiled form, but it will often be close. When you use the B<-p>
4128 option, the output also includes parentheses even when they are not
4129 required by precedence, which can make it easy to see if perl is
4130 parsing your expressions the way you intended.
4131
4132 While B::Deparse goes to some lengths to try to figure out what your
4133 original program was doing, some parts of the language can still trip
4134 it up; it still fails even on some parts of Perl's own test suite. If
4135 you encounter a failure other than the most common ones described in
4136 the BUGS section below, you can help contribute to B::Deparse's
4137 ongoing development by submitting a bug report with a small
4138 example.
4139
4140 =head1 OPTIONS
4141
4142 As with all compiler backend options, these must follow directly after
4143 the '-MO=Deparse', separated by a comma but not any white space.
4144
4145 =over 4
4146
4147 =item B<-d>
4148
4149 Output data values (when they appear as constants) using Data::Dumper.
4150 Without this option, B::Deparse will use some simple routines of its
4151 own for the same purpose. Currently, Data::Dumper is better for some
4152 kinds of data (such as complex structures with sharing and
4153 self-reference) while the built-in routines are better for others
4154 (such as odd floating-point values).
4155
4156 =item B<-f>I<FILE>
4157
4158 Normally, B::Deparse deparses the main code of a program, and all the subs
4159 defined in the same file. To include subs defined in other files, pass the
4160 B<-f> option with the filename. You can pass the B<-f> option several times, to
4161 include more than one secondary file.  (Most of the time you don't want to
4162 use it at all.)  You can also use this option to include subs which are
4163 defined in the scope of a B<#line> directive with two parameters.
4164
4165 =item B<-l>
4166
4167 Add '#line' declarations to the output based on the line and file
4168 locations of the original code.
4169
4170 =item B<-p>
4171
4172 Print extra parentheses. Without this option, B::Deparse includes
4173 parentheses in its output only when they are needed, based on the
4174 structure of your program. With B<-p>, it uses parentheses (almost)
4175 whenever they would be legal. This can be useful if you are used to
4176 LISP, or if you want to see how perl parses your input. If you say
4177
4178     if ($var & 0x7f == 65) {print "Gimme an A!"}
4179     print ($which ? $a : $b), "\n";
4180     $name = $ENV{USER} or "Bob";
4181
4182 C<B::Deparse,-p> will print
4183
4184     if (($var & 0)) {
4185         print('Gimme an A!')
4186     };
4187     (print(($which ? $a : $b)), '???');
4188     (($name = $ENV{'USER'}) or '???')
4189
4190 which probably isn't what you intended (the C<'???'> is a sign that
4191 perl optimized away a constant value).
4192
4193 =item B<-P>
4194
4195 Disable prototype checking. With this option, all function calls are
4196 deparsed as if no prototype was defined for them. In other words,
4197
4198     perl -MO=Deparse,-P -e 'sub foo (\@) { 1 } foo @x'
4199
4200 will print
4201
4202     sub foo (\@) {
4203         1;
4204     }
4205     &foo(\@x);
4206
4207 making clear how the parameters are actually passed to C<foo>.
4208
4209 =item B<-q>
4210
4211 Expand double-quoted strings into the corresponding combinations of
4212 concatenation, uc, ucfirst, lc, lcfirst, quotemeta, and join. For
4213 instance, print
4214
4215     print "Hello, $world, @ladies, \u$gentlemen\E, \u\L$me!";
4216
4217 as
4218
4219     print 'Hello, ' . $world . ', ' . join($", @ladies) . ', '
4220           . ucfirst($gentlemen) . ', ' . ucfirst(lc $me . '!');
4221
4222 Note that the expanded form represents the way perl handles such
4223 constructions internally -- this option actually turns off the reverse
4224 translation that B::Deparse usually does. On the other hand, note that
4225 C<$x = "$y"> is not the same as C<$x = $y>: the former makes the value
4226 of $y into a string before doing the assignment.
4227
4228 =item B<-s>I<LETTERS>
4229
4230 Tweak the style of B::Deparse's output. The letters should follow
4231 directly after the 's', with no space or punctuation. The following
4232 options are available:
4233
4234 =over 4
4235
4236 =item B<C>
4237
4238 Cuddle C<elsif>, C<else>, and C<continue> blocks. For example, print
4239
4240     if (...) {
4241          ...
4242     } else {
4243          ...
4244     }
4245
4246 instead of
4247
4248     if (...) {
4249          ...
4250     }
4251     else {
4252          ...
4253     }
4254
4255 The default is not to cuddle.
4256
4257 =item B<i>I<NUMBER>
4258
4259 Indent lines by multiples of I<NUMBER> columns. The default is 4 columns.
4260
4261 =item B<T>
4262
4263 Use tabs for each 8 columns of indent. The default is to use only spaces.
4264 For instance, if the style options are B<-si4T>, a line that's indented
4265 3 times will be preceded by one tab and four spaces; if the options were
4266 B<-si8T>, the same line would be preceded by three tabs.
4267
4268 =item B<v>I<STRING>B<.>
4269
4270 Print I<STRING> for the value of a constant that can't be determined
4271 because it was optimized away (mnemonic: this happens when a constant
4272 is used in B<v>oid context). The end of the string is marked by a period.
4273 The string should be a valid perl expression, generally a constant.
4274 Note that unless it's a number, it probably needs to be quoted, and on
4275 a command line quotes need to be protected from the shell. Some
4276 conventional values include 0, 1, 42, '', 'foo', and
4277 'Useless use of constant omitted' (which may need to be
4278 B<-sv"'Useless use of constant omitted'.">
4279 or something similar depending on your shell). The default is '???'.
4280 If you're using B::Deparse on a module or other file that's require'd,
4281 you shouldn't use a value that evaluates to false, since the customary
4282 true constant at the end of a module will be in void context when the
4283 file is compiled as a main program.
4284
4285 =back
4286
4287 =item B<-x>I<LEVEL>
4288
4289 Expand conventional syntax constructions into equivalent ones that expose
4290 their internal operation. I<LEVEL> should be a digit, with higher values
4291 meaning more expansion. As with B<-q>, this actually involves turning off
4292 special cases in B::Deparse's normal operations.
4293
4294 If I<LEVEL> is at least 3, C<for> loops will be translated into equivalent
4295 while loops with continue blocks; for instance
4296
4297     for ($i = 0; $i < 10; ++$i) {
4298         print $i;
4299     }
4300
4301 turns into
4302
4303     $i = 0;
4304     while ($i < 10) {
4305         print $i;
4306     } continue {
4307         ++$i
4308     }
4309
4310 Note that in a few cases this translation can't be perfectly carried back
4311 into the source code -- if the loop's initializer declares a my variable,
4312 for instance, it won't have the correct scope outside of the loop.
4313
4314 If I<LEVEL> is at least 5, C<use> declarations will be translated into
4315 C<BEGIN> blocks containing calls to C<require> and C<import>; for
4316 instance,
4317
4318     use strict 'refs';
4319
4320 turns into
4321
4322     sub BEGIN {
4323         require strict;
4324         do {
4325             'strict'->import('refs')
4326         };
4327     }
4328
4329 If I<LEVEL> is at least 7, C<if> statements will be translated into
4330 equivalent expressions using C<&&>, C<?:> and C<do {}>; for instance
4331
4332     print 'hi' if $nice;
4333     if ($nice) {
4334         print 'hi';
4335     }
4336     if ($nice) {
4337         print 'hi';
4338     } else {
4339         print 'bye';
4340     }
4341
4342 turns into
4343
4344     $nice and print 'hi';
4345     $nice and do { print 'hi' };
4346     $nice ? do { print 'hi' } : do { print 'bye' };
4347
4348 Long sequences of elsifs will turn into nested ternary operators, which
4349 B::Deparse doesn't know how to indent nicely.
4350
4351 =back
4352
4353 =head1 USING B::Deparse AS A MODULE
4354
4355 =head2 Synopsis
4356
4357     use B::Deparse;
4358     $deparse = B::Deparse->new("-p", "-sC");
4359     $body = $deparse->coderef2text(\&func);
4360     eval "sub func $body"; # the inverse operation
4361
4362 =head2 Description
4363
4364 B::Deparse can also be used on a sub-by-sub basis from other perl
4365 programs.
4366
4367 =head2 new
4368
4369     $deparse = B::Deparse->new(OPTIONS)
4370
4371 Create an object to store the state of a deparsing operation and any
4372 options. The options are the same as those that can be given on the
4373 command line (see L</OPTIONS>); options that are separated by commas
4374 after B<-MO=Deparse> should be given as separate strings. Some
4375 options, like B<-u>, don't make sense for a single subroutine, so
4376 don't pass them.
4377
4378 =head2 ambient_pragmas
4379
4380     $deparse->ambient_pragmas(strict => 'all', '$[' => $[);
4381
4382 The compilation of a subroutine can be affected by a few compiler
4383 directives, B<pragmas>. These are:
4384
4385 =over 4
4386
4387 =item *
4388
4389 use strict;
4390
4391 =item *
4392
4393 use warnings;
4394
4395 =item *
4396
4397 Assigning to the special variable $[
4398
4399 =item *
4400
4401 use integer;
4402
4403 =item *
4404
4405 use bytes;
4406
4407 =item *
4408
4409 use utf8;
4410
4411 =item *
4412
4413 use re;
4414
4415 =back
4416
4417 Ordinarily, if you use B::Deparse on a subroutine which has
4418 been compiled in the presence of one or more of these pragmas,
4419 the output will include statements to turn on the appropriate
4420 directives. So if you then compile the code returned by coderef2text,
4421 it will behave the same way as the subroutine which you deparsed.
4422
4423 However, you may know that you intend to use the results in a
4424 particular context, where some pragmas are already in scope. In
4425 this case, you use the B<ambient_pragmas> method to describe the
4426 assumptions you wish to make.
4427
4428 Not all of the options currently have any useful effect. See
4429 L</BUGS> for more details.
4430
4431 The parameters it accepts are:
4432
4433 =over 4
4434
4435 =item strict
4436
4437 Takes a string, possibly containing several values separated
4438 by whitespace. The special values "all" and "none" mean what you'd
4439 expect.
4440
4441     $deparse->ambient_pragmas(strict => 'subs refs');
4442
4443 =item $[
4444
4445 Takes a number, the value of the array base $[.
4446
4447 =item bytes
4448
4449 =item utf8
4450
4451 =item integer
4452
4453 If the value is true, then the appropriate pragma is assumed to
4454 be in the ambient scope, otherwise not.
4455
4456 =item re
4457
4458 Takes a string, possibly containing a whitespace-separated list of
4459 values. The values "all" and "none" are special. It's also permissible
4460 to pass an array reference here.
4461
4462     $deparser->ambient_pragmas(re => 'eval');
4463
4464
4465 =item warnings
4466
4467 Takes a string, possibly containing a whitespace-separated list of
4468 values. The values "all" and "none" are special, again. It's also
4469 permissible to pass an array reference here.
4470
4471     $deparser->ambient_pragmas(warnings => [qw[void io]]);
4472
4473 If one of the values is the string "FATAL", then all the warnings
4474 in that list will be considered fatal, just as with the B<warnings>
4475 pragma itself. Should you need to specify that some warnings are
4476 fatal, and others are merely enabled, you can pass the B<warnings>
4477 parameter twice:
4478
4479     $deparser->ambient_pragmas(
4480         warnings => 'all',
4481         warnings => [FATAL => qw/void io/],
4482     );
4483
4484 See L<perllexwarn> for more information about lexical warnings.
4485
4486 =item hint_bits
4487
4488 =item warning_bits
4489
4490 These two parameters are used to specify the ambient pragmas in
4491 the format used by the special variables $^H and ${^WARNING_BITS}.
4492
4493 They exist principally so that you can write code like:
4494
4495     { my ($hint_bits, $warning_bits);
4496     BEGIN {($hint_bits, $warning_bits) = ($^H, ${^WARNING_BITS})}
4497     $deparser->ambient_pragmas (
4498         hint_bits    => $hint_bits,
4499         warning_bits => $warning_bits,
4500         '$['         => 0 + $[
4501     ); }
4502
4503 which specifies that the ambient pragmas are exactly those which
4504 are in scope at the point of calling.
4505
4506 =back
4507
4508 =head2 coderef2text
4509
4510     $body = $deparse->coderef2text(\&func)
4511     $body = $deparse->coderef2text(sub ($$) { ... })
4512
4513 Return source code for the body of a subroutine (a block, optionally
4514 preceded by a prototype in parens), given a reference to the
4515 sub. Because a subroutine can have no names, or more than one name,
4516 this method doesn't return a complete subroutine definition -- if you
4517 want to eval the result, you should prepend "sub subname ", or "sub "
4518 for an anonymous function constructor. Unless the sub was defined in
4519 the main:: package, the code will include a package declaration.
4520
4521 =head1 BUGS
4522
4523 =over 4
4524
4525 =item *
4526
4527 The only pragmas to be completely supported are: C<use warnings>,
4528 C<use strict 'refs'>, C<use bytes>, and C<use integer>. (C<$[>, which
4529 behaves like a pragma, is also supported.)
4530
4531 Excepting those listed above, we're currently unable to guarantee that
4532 B::Deparse will produce a pragma at the correct point in the program.
4533 (Specifically, pragmas at the beginning of a block often appear right
4534 before the start of the block instead.)
4535 Since the effects of pragmas are often lexically scoped, this can mean
4536 that the pragma holds sway over a different portion of the program
4537 than in the input file.
4538
4539 =item *
4540
4541 In fact, the above is a specific instance of a more general problem:
4542 we can't guarantee to produce BEGIN blocks or C<use> declarations in
4543 exactly the right place. So if you use a module which affects compilation
4544 (such as by over-riding keywords, overloading constants or whatever)
4545 then the output code might not work as intended.
4546
4547 This is the most serious outstanding problem, and will require some help
4548 from the Perl core to fix.
4549
4550 =item *
4551
4552 If a keyword is over-ridden, and your program explicitly calls
4553 the built-in version by using CORE::keyword, the output of B::Deparse
4554 will not reflect this. If you run the resulting code, it will call
4555 the over-ridden version rather than the built-in one. (Maybe there
4556 should be an option to B<always> print keyword calls as C<CORE::name>.)
4557
4558 =item *
4559
4560 Some constants don't print correctly either with or without B<-d>.
4561 For instance, neither B::Deparse nor Data::Dumper know how to print
4562 dual-valued scalars correctly, as in:
4563
4564     use constant E2BIG => ($!=7); $y = E2BIG; print $y, 0+$y;
4565
4566 =item *
4567
4568 An input file that uses source filtering probably won't be deparsed into
4569 runnable code, because it will still include the B<use> declaration
4570 for the source filtering module, even though the code that is
4571 produced is already ordinary Perl which shouldn't be filtered again.
4572
4573 =item *
4574
4575 There are probably many more bugs on non-ASCII platforms (EBCDIC).
4576
4577 =back
4578
4579 =head1 AUTHOR
4580
4581 Stephen McCamant <smcc@CSUA.Berkeley.EDU>, based on an earlier version
4582 by Malcolm Beattie <mbeattie@sable.ox.ac.uk>, with contributions from
4583 Gisle Aas, James Duncan, Albert Dvornik, Robin Houston, Dave Mitchell,
4584 Hugo van der Sanden, Gurusamy Sarathy, Nick Ing-Simmons, and Rafael
4585 Garcia-Suarez.
4586
4587 =cut